cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVMConfig)
   3
   4 macro(add_llvm_library name)
   5   llvm_process_sources( ALL_FILES ${ARGN} )
   6   add_library( ${name} ${ALL_FILES} )
   7   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
   8   set_property( GLOBAL APPEND PROPERTY LLVM_LIB_TARGETS ${name} )
   9   if( LLVM_COMMON_DEPENDS )
  10     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  11   endif( LLVM_COMMON_DEPENDS )
  12
  13   if( BUILD_SHARED_LIBS )
  14     get_system_libs(sl)
  15     target_link_libraries( ${name} ${sl} )
  16   endif()
  17
  18   install(TARGETS ${name}
  19     LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  20     ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  21   # The LLVM Target library shall be built before its sublibraries
  22   # (asmprinter, etc) because those may use tablegenned files which
  23   # generation is triggered by the main LLVM target library. Necessary
  24   # for parallel builds:
  25   if( CURRENT_LLVM_TARGET )
  26     add_dependencies(${name} ${CURRENT_LLVM_TARGET})
  27   endif()
  28 endmacro(add_llvm_library name)
  29
  30
  31 macro(add_llvm_loadable_module name)
  32   if( NOT LLVM_ON_UNIX OR CYGWIN )
  33     message(STATUS "Loadable modules not supported on this platform.
  34 ${name} ignored.")
  35     # Add empty "phony" target
  36     add_custom_target(${name})
  37   else()
  38     llvm_process_sources( ALL_FILES ${ARGN} )
  39     if (MODULE)
  40       set(libkind MODULE)
  41     else()
  42       set(libkind SHARED)
  43     endif()
  44
  45     add_library( ${name} ${libkind} ${ALL_FILES} )
  46     set_target_properties( ${name} PROPERTIES PREFIX "" )
  47
  48     if (APPLE)
  49       # Darwin-specific linker flags for loadable modules.
  50       set_target_properties(${name} PROPERTIES
  51         LINK_FLAGS "-Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
  52     endif()
  53
  54     install(TARGETS ${name}
  55       LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  56       ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  57   endif()
  58 endmacro(add_llvm_loadable_module name)
  59
  60
  61 macro(add_llvm_executable name)
  62   llvm_process_sources( ALL_FILES ${ARGN} )
  63   if( EXCLUDE_FROM_ALL )
  64     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
  65   else()
  66     add_executable(${name} ${ALL_FILES})
  67   endif()
  68   set(EXCLUDE_FROM_ALL OFF)
  69   if( LLVM_USED_LIBS )
  70     foreach(lib ${LLVM_USED_LIBS})
  71       target_link_libraries( ${name} ${lib} )
  72     endforeach(lib)
  73   endif( LLVM_USED_LIBS )
  74   if( LLVM_LINK_COMPONENTS )
  75     llvm_config(${name} ${LLVM_LINK_COMPONENTS})
  76   endif( LLVM_LINK_COMPONENTS )
  77   if( LLVM_COMMON_DEPENDS )
  78     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  79   endif( LLVM_COMMON_DEPENDS )
  80   if( NOT MINGW )
  81     get_system_libs(llvm_system_libs)
  82     if( llvm_system_libs )
  83       target_link_libraries(${name} ${llvm_system_libs})
  84     endif()
  85   endif()
  86 endmacro(add_llvm_executable name)
  87
  88
  89 macro(add_llvm_tool name)
  90   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR})
  91   if( NOT LLVM_BUILD_TOOLS )
  92     set(EXCLUDE_FROM_ALL ON)
  93   endif()
  94   add_llvm_executable(${name} ${ARGN})
  95   if( LLVM_BUILD_TOOLS )
  96     install(TARGETS ${name} RUNTIME DESTINATION bin)
  97   endif()
  98 endmacro(add_llvm_tool name)
  99
 100
 101 macro(add_llvm_example name)
 102 #  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_EXAMPLES_BINARY_DIR})
 103   if( NOT LLVM_BUILD_EXAMPLES )
 104     set(EXCLUDE_FROM_ALL ON)
 105   endif()
 106   add_llvm_executable(${name} ${ARGN})
 107   if( LLVM_BUILD_EXAMPLES )
 108     install(TARGETS ${name} RUNTIME DESTINATION examples)
 109   endif()
 110 endmacro(add_llvm_example name)
 111
 112
 113 macro(add_llvm_target target_name)
 114   if( TABLEGEN_OUTPUT )
 115     add_custom_target(${target_name}Table_gen
 116       DEPENDS ${TABLEGEN_OUTPUT})
 117     add_dependencies(${target_name}Table_gen ${LLVM_COMMON_DEPENDS})
 118   endif( TABLEGEN_OUTPUT )
 119   include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR})
 120   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 121   if ( TABLEGEN_OUTPUT )
 122     add_dependencies(LLVM${target_name} ${target_name}Table_gen)
 123   endif (TABLEGEN_OUTPUT)
 124   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 125 endmacro(add_llvm_target)