cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3 include(DetermineGCCCompatible)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25   endif()
  26
  27   # LLVM_REQUIRES_RTTI is an internal flag that individual
  28   # targets can use to force RTTI
  29   set(LLVM_CONFIG_HAS_RTTI YES CACHE INTERNAL "")
  30   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  31     set(LLVM_CONFIG_HAS_RTTI NO CACHE INTERNAL "")
  32     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  33     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  34       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  35     elseif (MSVC)
  36       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  37     endif ()
  38   endif()
  39
  40   # Assume that;
  41   #   - LLVM_COMPILE_FLAGS is list.
  42   #   - PROPERTY COMPILE_FLAGS is string.
  43   string(REPLACE ";" " " target_compile_flags " ${LLVM_COMPILE_FLAGS}")
  44
  45   if(update_src_props)
  46     foreach(fn ${sources})
  47       get_filename_component(suf ${fn} EXT)
  48       if("${suf}" STREQUAL ".cpp")
  49         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  50           COMPILE_FLAGS "${target_compile_flags}")
  51       endif()
  52     endforeach()
  53   else()
  54     # Update target props, since all sources are C++.
  55     set_property(TARGET ${name} APPEND_STRING PROPERTY
  56       COMPILE_FLAGS "${target_compile_flags}")
  57   endif()
  58
  59   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  60 endfunction()
  61
  62 function(add_llvm_symbol_exports target_name export_file)
  63   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  64     set(native_export_file "${target_name}.exports")
  65     add_custom_command(OUTPUT ${native_export_file}
  66       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  67       DEPENDS ${export_file}
  68       VERBATIM
  69       COMMENT "Creating export file for ${target_name}")
  70     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  71                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  72   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  73     # Gold and BFD ld require a version script rather than a plain list.
  74     set(native_export_file "${target_name}.exports")
  75     # FIXME: Don't write the "local:" line on OpenBSD.
  76     add_custom_command(OUTPUT ${native_export_file}
  77       COMMAND echo "{" > ${native_export_file}
  78       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  79       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  80       COMMAND echo "  local: *;" >> ${native_export_file}
  81       COMMAND echo "};" >> ${native_export_file}
  82       DEPENDS ${export_file}
  83       VERBATIM
  84       COMMENT "Creating export file for ${target_name}")
  85     if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  86       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  87                    LINK_FLAGS "  -Wl,-M,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  88     else()
  89       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  90                    LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  91     endif()
  92   else()
  93     set(native_export_file "${target_name}.def")
  94
  95     add_custom_command(OUTPUT ${native_export_file}
  96       COMMAND ${PYTHON_EXECUTABLE} -c "import sys;print(''.join(['EXPORTS\\n']+sys.stdin.readlines(),))"
  97         < ${export_file} > ${native_export_file}
  98       DEPENDS ${export_file}
  99       VERBATIM
 100       COMMENT "Creating export file for ${target_name}")
 101     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 102     if(MSVC)
 103       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 104     endif()
 105     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 106                  LINK_FLAGS " ${export_file_linker_flag}")
 107   endif()
 108
 109   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 110   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 111
 112   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 113   foreach(src ${srcs})
 114     get_filename_component(extension ${src} EXT)
 115     if(extension STREQUAL ".cpp")
 116       set(first_source_file ${src})
 117       break()
 118     endif()
 119   endforeach()
 120
 121   # Force re-linking when the exports file changes. Actually, it
 122   # forces recompilation of the source file. The LINK_DEPENDS target
 123   # property only works for makefile-based generators.
 124   # FIXME: This is not safe because this will create the same target
 125   # ${native_export_file} in several different file:
 126   # - One where we emitted ${target_name}_exports
 127   # - One where we emitted the build command for the following object.
 128   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 129   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 130
 131   set_property(DIRECTORY APPEND
 132     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 133
 134   add_dependencies(${target_name} ${target_name}_exports)
 135
 136   # Add dependency to *_exports later -- CMake issue 14747
 137   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 138   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 139 endfunction(add_llvm_symbol_exports)
 140
 141 if(NOT WIN32 AND NOT APPLE)
 142   execute_process(
 143     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 144     OUTPUT_VARIABLE stdout
 145     ERROR_QUIET
 146     )
 147   if("${stdout}" MATCHES "GNU gold")
 148     set(LLVM_LINKER_IS_GOLD ON)
 149   endif()
 150 endif()
 151
 152 function(add_link_opts target_name)
 153   # Don't use linker optimizations in debug builds since it slows down the
 154   # linker in a context where the optimizations are not important.
 155   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 156
 157     # Pass -O3 to the linker. This enabled different optimizations on different
 158     # linkers.
 159     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin|SunOS" OR WIN32))
 160       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 161                    LINK_FLAGS " -Wl,-O3")
 162     endif()
 163
 164     if(LLVM_LINKER_IS_GOLD)
 165       # With gold gc-sections is always safe.
 166       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 167                    LINK_FLAGS " -Wl,--gc-sections")
 168       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 169       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 170     endif()
 171
 172     if(NOT LLVM_NO_DEAD_STRIP)
 173       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 174         # ld64's implementation of -dead_strip breaks tools that use plugins.
 175         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 176                      LINK_FLAGS " -Wl,-dead_strip")
 177       elseif(${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 178         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 179                      LINK_FLAGS " -Wl,-z -Wl,discard-unused=sections")
 180       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 181         # Object files are compiled with -ffunction-data-sections.
 182         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 183         # tools that use plugins. Always pass --gc-sections once we require
 184         # a newer linker.
 185         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 186                      LINK_FLAGS " -Wl,--gc-sections")
 187       endif()
 188     endif()
 189   endif()
 190 endfunction(add_link_opts)
 191
 192 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 193 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 194 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 195 function(set_output_directory target)
 196   cmake_parse_arguments(ARG "" "BINARY_DIR;LIBRARY_DIR" "" ${ARGN})
 197
 198   # module_dir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 199   # It affects output of add_library(MODULE).
 200   if(WIN32 OR CYGWIN)
 201     # DLL platform
 202     set(module_dir ${ARG_BINARY_DIR})
 203   else()
 204     set(module_dir ${ARG_LIBRARY_DIR})
 205   endif()
 206   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 207     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 208       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 209       if(ARG_BINARY_DIR)
 210         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${ARG_BINARY_DIR})
 211         set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 212       endif()
 213       if(ARG_LIBRARY_DIR)
 214         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${ARG_LIBRARY_DIR})
 215         set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 216       endif()
 217       if(module_dir)
 218         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${module_dir})
 219         set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 220       endif()
 221     endforeach()
 222   else()
 223     if(ARG_BINARY_DIR)
 224       set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${ARG_BINARY_DIR})
 225     endif()
 226     if(ARG_LIBRARY_DIR)
 227       set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${ARG_LIBRARY_DIR})
 228     endif()
 229     if(module_dir)
 230       set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${module_dir})
 231     endif()
 232   endif()
 233 endfunction()
 234
 235 # If on Windows and building with MSVC, add the resource script containing the
 236 # VERSIONINFO data to the project.  This embeds version resource information
 237 # into the output .exe or .dll.
 238 # TODO: Enable for MinGW Windows builds too.
 239 #
 240 function(add_windows_version_resource_file OUT_VAR)
 241   set(sources ${ARGN})
 242   if (MSVC)
 243     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 244     if(EXISTS ${resource_file})
 245       set(sources ${sources} ${resource_file})
 246       source_group("Resource Files" ${resource_file})
 247       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 248     endif()
 249   endif(MSVC)
 250
 251   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 252 endfunction(add_windows_version_resource_file)
 253
 254 # set_windows_version_resource_properties(name resource_file...
 255 #   VERSION_MAJOR int
 256 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 257 #   VERSION_MINOR int
 258 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 259 #   VERSION_PATCHLEVEL int
 260 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 261 #   VERSION_STRING
 262 #     Optional version string (defaults to PACKAGE_VERSION)
 263 #   PRODUCT_NAME
 264 #     Optional product name string (defaults to "LLVM")
 265 #   )
 266 function(set_windows_version_resource_properties name resource_file)
 267   cmake_parse_arguments(ARG
 268     ""
 269     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 270     ""
 271     ${ARGN})
 272
 273   if (NOT DEFINED ARG_VERSION_MAJOR)
 274     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 275   endif()
 276
 277   if (NOT DEFINED ARG_VERSION_MINOR)
 278     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 279   endif()
 280
 281   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 282     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 283   endif()
 284
 285   if (NOT DEFINED ARG_VERSION_STRING)
 286     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 287   endif()
 288
 289   if (NOT DEFINED ARG_PRODUCT_NAME)
 290     set(ARG_PRODUCT_NAME "LLVM")
 291   endif()
 292
 293   set_property(SOURCE ${resource_file}
 294                PROPERTY COMPILE_FLAGS /nologo)
 295   set_property(SOURCE ${resource_file}
 296                PROPERTY COMPILE_DEFINITIONS
 297                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 298                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 299                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 300                "RC_VERSION_FIELD_4=0"
 301                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 302                "RC_INTERNAL_NAME=\"${name}\""
 303                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 304                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 305 endfunction(set_windows_version_resource_properties)
 306
 307 # llvm_add_library(name sources...
 308 #   SHARED;STATIC
 309 #     STATIC by default w/o BUILD_SHARED_LIBS.
 310 #     SHARED by default w/  BUILD_SHARED_LIBS.
 311 #   MODULE
 312 #     Target ${name} might not be created on unsupported platforms.
 313 #     Check with "if(TARGET ${name})".
 314 #   DISABLE_LLVM_LINK_LLVM_DYLIB
 315 #     Do not link this library to libLLVM, even if
 316 #     LLVM_LINK_LLVM_DYLIB is enabled.
 317 #   OUTPUT_NAME name
 318 #     Corresponds to OUTPUT_NAME in target properties.
 319 #   DEPENDS targets...
 320 #     Same semantics as add_dependencies().
 321 #   LINK_COMPONENTS components...
 322 #     Same as the variable LLVM_LINK_COMPONENTS.
 323 #   LINK_LIBS lib_targets...
 324 #     Same semantics as target_link_libraries().
 325 #   ADDITIONAL_HEADERS
 326 #     May specify header files for IDE generators.
 327 #   SONAME
 328 #     Should set SONAME link flags and create symlinks
 329 #   )
 330 function(llvm_add_library name)
 331   cmake_parse_arguments(ARG
 332     "MODULE;SHARED;STATIC;DISABLE_LLVM_LINK_LLVM_DYLIB;SONAME"
 333     "OUTPUT_NAME"
 334     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 335     ${ARGN})
 336   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 337   if(ARG_ADDITIONAL_HEADERS)
 338     # Pass through ADDITIONAL_HEADERS.
 339     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 340   endif()
 341   if(ARG_OBJLIBS)
 342     set(ALL_FILES ${ARG_OBJLIBS})
 343   else()
 344     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 345   endif()
 346
 347   if(ARG_MODULE)
 348     if(ARG_SHARED OR ARG_STATIC)
 349       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 350     endif()
 351     if(NOT LLVM_ENABLE_PLUGINS)
 352       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 353       return()
 354     endif()
 355   else()
 356     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 357       set(ARG_SHARED TRUE)
 358     endif()
 359     if(NOT ARG_SHARED)
 360       set(ARG_STATIC TRUE)
 361     endif()
 362   endif()
 363
 364   # Generate objlib
 365   if(ARG_SHARED AND ARG_STATIC)
 366     # Generate an obj library for both targets.
 367     set(obj_name "obj.${name}")
 368     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 369       ${ALL_FILES}
 370       )
 371     llvm_update_compile_flags(${obj_name})
 372     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 373
 374     # Do add_dependencies(obj) later due to CMake issue 14747.
 375     list(APPEND objlibs ${obj_name})
 376
 377     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 378   endif()
 379
 380   if(ARG_SHARED AND ARG_STATIC)
 381     # static
 382     set(name_static "${name}_static")
 383     if(ARG_OUTPUT_NAME)
 384       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 385     endif()
 386     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 387     llvm_add_library(${name_static} STATIC
 388       ${output_name}
 389       OBJLIBS ${ALL_FILES} # objlib
 390       LINK_LIBS ${ARG_LINK_LIBS}
 391       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 392       )
 393     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 394     set(ARG_STATIC)
 395   endif()
 396
 397   if(ARG_MODULE)
 398     add_library(${name} MODULE ${ALL_FILES})
 399   elseif(ARG_SHARED)
 400     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 401     add_library(${name} SHARED ${ALL_FILES})
 402   else()
 403     add_library(${name} STATIC ${ALL_FILES})
 404   endif()
 405
 406   if(DEFINED windows_resource_file)
 407     set_windows_version_resource_properties(${name} ${windows_resource_file})
 408     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 409   endif()
 410
 411   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 412   # $<TARGET_OBJECTS> doesn't require compile flags.
 413   if(NOT obj_name)
 414     llvm_update_compile_flags(${name})
 415   endif()
 416   add_link_opts( ${name} )
 417   if(ARG_OUTPUT_NAME)
 418     set_target_properties(${name}
 419       PROPERTIES
 420       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 421       )
 422   endif()
 423
 424   if(ARG_MODULE)
 425     set_target_properties(${name} PROPERTIES
 426       PREFIX ""
 427       SUFFIX ${LLVM_PLUGIN_EXT}
 428       )
 429   endif()
 430
 431   if(ARG_SHARED)
 432     if(WIN32)
 433       set_target_properties(${name} PROPERTIES
 434         PREFIX ""
 435         )
 436     endif()
 437   endif()
 438
 439   if(ARG_MODULE OR ARG_SHARED)
 440     # Do not add -Dname_EXPORTS to the command-line when building files in this
 441     # target. Doing so is actively harmful for the modules build because it
 442     # creates extra module variants, and not useful because we don't use these
 443     # macros.
 444     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 445
 446     if (LLVM_EXPORTED_SYMBOL_FILE)
 447       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 448     endif()
 449   endif()
 450
 451   if(ARG_SHARED AND UNIX)
 452     if(NOT APPLE AND ARG_SONAME)
 453       get_target_property(output_name ${name} OUTPUT_NAME)
 454       if(${output_name} STREQUAL "output_name-NOTFOUND")
 455         set(output_name ${name})
 456       endif()
 457       set(library_name ${output_name}-${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}${LLVM_VERSION_SUFFIX})
 458       set(api_name ${output_name}-${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 459       set_target_properties(${name} PROPERTIES OUTPUT_NAME ${library_name})
 460       llvm_install_library_symlink(${api_name} ${library_name} SHARED
 461         COMPONENT ${name}
 462         ALWAYS_GENERATE)
 463       llvm_install_library_symlink(${output_name} ${library_name} SHARED
 464         COMPONENT ${name}
 465         ALWAYS_GENERATE)
 466     endif()
 467   endif()
 468
 469   # Add the explicit dependency information for this library.
 470   #
 471   # It would be nice to verify that we have the dependencies for this library
 472   # name, but using get_property(... SET) doesn't suffice to determine if a
 473   # property has been set to an empty value.
 474   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 475
 476   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_STATIC AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 477     set(llvm_libs LLVM)
 478   else()
 479     llvm_map_components_to_libnames(llvm_libs
 480       ${ARG_LINK_COMPONENTS}
 481       ${LLVM_LINK_COMPONENTS}
 482       )
 483   endif()
 484
 485   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 486     # Link libs w/o keywords, assuming PUBLIC.
 487     target_link_libraries(${name}
 488       ${ARG_LINK_LIBS}
 489       ${lib_deps}
 490       ${llvm_libs}
 491       )
 492   elseif(ARG_STATIC)
 493     target_link_libraries(${name} INTERFACE
 494       ${ARG_LINK_LIBS}
 495       ${lib_deps}
 496       ${llvm_libs}
 497       )
 498   else()
 499     # We can use PRIVATE since SO knows its dependent libs.
 500     target_link_libraries(${name} PRIVATE
 501       ${ARG_LINK_LIBS}
 502       ${lib_deps}
 503       ${llvm_libs}
 504       )
 505   endif()
 506
 507   if(LLVM_COMMON_DEPENDS)
 508     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 509     # Add dependencies also to objlibs.
 510     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 511     foreach(objlib ${objlibs})
 512       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 513     endforeach()
 514   endif()
 515 endfunction()
 516
 517 macro(add_llvm_library name)
 518   cmake_parse_arguments(ARG
 519     "SHARED"
 520     ""
 521     ""
 522     ${ARGN})
 523   if( BUILD_SHARED_LIBS )
 524     llvm_add_library(${name} SHARED ${ARGN})
 525   else()
 526     llvm_add_library(${name} ${ARGN})
 527   endif()
 528   # The gtest libraries should not be installed or exported as a target
 529   if ("${name}" STREQUAL gtest OR "${name}" STREQUAL gtest_main)
 530     set(_is_gtest TRUE)
 531   else()
 532     set(_is_gtest FALSE)
 533     set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 534   endif()
 535
 536   if( EXCLUDE_FROM_ALL )
 537     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 538   elseif(NOT _is_gtest)
 539     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 540       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 541         if(WIN32 OR CYGWIN)
 542           set(install_type RUNTIME)
 543         else()
 544           set(install_type LIBRARY)
 545         endif()
 546       else()
 547         set(install_type ARCHIVE)
 548       endif()
 549
 550       install(TARGETS ${name}
 551             EXPORT LLVMExports
 552             ${install_type} DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 553             COMPONENT ${name})
 554
 555       if (NOT CMAKE_CONFIGURATION_TYPES)
 556         add_custom_target(install-${name}
 557                           DEPENDS ${name}
 558                           COMMAND "${CMAKE_COMMAND}"
 559                                   -DCMAKE_INSTALL_COMPONENT=${name}
 560                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 561       endif()
 562     endif()
 563     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 564   endif()
 565   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 566 endmacro(add_llvm_library name)
 567
 568 macro(add_llvm_loadable_module name)
 569   llvm_add_library(${name} MODULE ${ARGN})
 570   if(NOT TARGET ${name})
 571     # Add empty "phony" target
 572     add_custom_target(${name})
 573   else()
 574     if( EXCLUDE_FROM_ALL )
 575       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 576     else()
 577       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 578         if(WIN32 OR CYGWIN)
 579           # DLL platform
 580           set(dlldir "bin")
 581         else()
 582           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 583         endif()
 584         install(TARGETS ${name}
 585           EXPORT LLVMExports
 586           LIBRARY DESTINATION ${dlldir}
 587           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 588       endif()
 589       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 590     endif()
 591   endif()
 592
 593   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 594 endmacro(add_llvm_loadable_module name)
 595
 596
 597 macro(add_llvm_executable name)
 598   cmake_parse_arguments(ARG "DISABLE_LLVM_LINK_LLVM_DYLIB" "" "" ${ARGN})
 599   llvm_process_sources( ALL_FILES ${ARG_UNPARSED_ARGUMENTS} )
 600
 601   # Generate objlib
 602   if(LLVM_ENABLE_OBJLIB)
 603     # Generate an obj library for both targets.
 604     set(obj_name "obj.${name}")
 605     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 606       ${ALL_FILES}
 607       )
 608     llvm_update_compile_flags(${obj_name})
 609     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 610
 611     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 612   endif()
 613
 614   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 615
 616   if(XCODE)
 617     # Note: the dummy.cpp source file provides no definitions. However,
 618     # it forces Xcode to properly link the static library.
 619     list(APPEND ALL_FILES "${LLVM_MAIN_SRC_DIR}/cmake/dummy.cpp")
 620   endif()
 621
 622   if( EXCLUDE_FROM_ALL )
 623     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 624   else()
 625     add_executable(${name} ${ALL_FILES})
 626   endif()
 627
 628   if(DEFINED windows_resource_file)
 629     set_windows_version_resource_properties(${name} ${windows_resource_file})
 630   endif()
 631
 632   # $<TARGET_OBJECTS> doesn't require compile flags.
 633   if(NOT LLVM_ENABLE_OBJLIB)
 634     llvm_update_compile_flags(${name})
 635   endif()
 636   add_link_opts( ${name} )
 637
 638   # Do not add -Dname_EXPORTS to the command-line when building files in this
 639   # target. Doing so is actively harmful for the modules build because it
 640   # creates extra module variants, and not useful because we don't use these
 641   # macros.
 642   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 643
 644   if (LLVM_EXPORTED_SYMBOL_FILE)
 645     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 646   endif(LLVM_EXPORTED_SYMBOL_FILE)
 647
 648   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 649     set(USE_SHARED USE_SHARED)
 650   endif()
 651
 652   set(EXCLUDE_FROM_ALL OFF)
 653   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 654   llvm_config( ${name} ${USE_SHARED} ${LLVM_LINK_COMPONENTS} )
 655   if( LLVM_COMMON_DEPENDS )
 656     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 657   endif( LLVM_COMMON_DEPENDS )
 658 endmacro(add_llvm_executable name)
 659
 660 function(export_executable_symbols target)
 661   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 662     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 663     if (APPLE)
 664       set_target_properties(${target} PROPERTIES
 665         LINK_FLAGS "-rdynamic")
 666     endif()
 667   endif()
 668 endfunction()
 669
 670 if(NOT LLVM_TOOLCHAIN_TOOLS)
 671   set (LLVM_TOOLCHAIN_TOOLS
 672     llvm-ar
 673     llvm-ranlib
 674     llvm-lib
 675     llvm-objdump
 676     )
 677 endif()
 678
 679 macro(add_llvm_tool name)
 680   if( NOT LLVM_BUILD_TOOLS )
 681     set(EXCLUDE_FROM_ALL ON)
 682   endif()
 683   add_llvm_executable(${name} ${ARGN})
 684
 685   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 686   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 687     if( LLVM_BUILD_TOOLS )
 688       install(TARGETS ${name}
 689               EXPORT LLVMExports
 690               RUNTIME DESTINATION bin
 691               COMPONENT ${name})
 692
 693       if (NOT CMAKE_CONFIGURATION_TYPES)
 694         add_custom_target(install-${name}
 695                           DEPENDS ${name}
 696                           COMMAND "${CMAKE_COMMAND}"
 697                                   -DCMAKE_INSTALL_COMPONENT=${name}
 698                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 699       endif()
 700     endif()
 701   endif()
 702   if( LLVM_BUILD_TOOLS )
 703     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 704   endif()
 705   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 706 endmacro(add_llvm_tool name)
 707
 708
 709 macro(add_llvm_example name)
 710   if( NOT LLVM_BUILD_EXAMPLES )
 711     set(EXCLUDE_FROM_ALL ON)
 712   endif()
 713   add_llvm_executable(${name} ${ARGN})
 714   if( LLVM_BUILD_EXAMPLES )
 715     install(TARGETS ${name} RUNTIME DESTINATION examples)
 716   endif()
 717   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 718 endmacro(add_llvm_example name)
 719
 720
 721 macro(add_llvm_utility name)
 722   add_llvm_executable(${name} DISABLE_LLVM_LINK_LLVM_DYLIB ${ARGN})
 723   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 724   if( LLVM_INSTALL_UTILS )
 725     install (TARGETS ${name}
 726       RUNTIME DESTINATION bin
 727       COMPONENT ${name})
 728     if (NOT CMAKE_CONFIGURATION_TYPES)
 729       add_custom_target(install-${name}
 730                         DEPENDS ${name}
 731                         COMMAND "${CMAKE_COMMAND}"
 732                                 -DCMAKE_INSTALL_COMPONENT=${name}
 733                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 734     endif()
 735   endif()
 736 endmacro(add_llvm_utility name)
 737
 738
 739 macro(add_llvm_target target_name)
 740   include_directories(BEFORE
 741     ${CMAKE_CURRENT_BINARY_DIR}
 742     ${CMAKE_CURRENT_SOURCE_DIR})
 743   add_llvm_library(LLVM${target_name} ${ARGN})
 744   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 745 endmacro(add_llvm_target)
 746
 747 function(canonicalize_tool_name name output)
 748   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/" "" nameStrip ${name})
 749   string(REPLACE "-" "_" nameUNDERSCORE ${nameStrip})
 750   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 751   set(${output} "${nameUPPER}" PARENT_SCOPE)
 752 endfunction(canonicalize_tool_name)
 753
 754 # Custom add_subdirectory wrapper
 755 # Takes in a project name (i.e. LLVM), the the subdirectory name, and an
 756 # and an optional path if it differs from the name.
 757 macro(add_llvm_subdirectory project type name)
 758   set(add_llvm_external_dir "${ARGN}")
 759   if("${add_llvm_external_dir}" STREQUAL "")
 760     set(add_llvm_external_dir ${name})
 761   endif()
 762   canonicalize_tool_name(${name} nameUPPER)
 763   if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}/CMakeLists.txt)
 764     # Treat it as in-tree subproject.
 765     option(${project}_${type}_${nameUPPER}_BUILD
 766            "Whether to build ${name} as part of ${project}" On)
 767     mark_as_advanced(${project}_${type}_${name}_BUILD)
 768     if(${project}_${type}_${nameUPPER}_BUILD)
 769       add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir} ${add_llvm_external_dir})
 770       # Don't process it in add_llvm_implicit_projects().
 771       set(${project}_${type}_${nameUPPER}_BUILD OFF)
 772     endif()
 773   else()
 774     set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR
 775       "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}"
 776       CACHE PATH "Path to ${name} source directory")
 777     set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT ON)
 778     if(NOT LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR OR NOT EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 779       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 780     endif()
 781     if("${LLVM_EXTERNAL_${nameUPPER}_BUILD}" STREQUAL "OFF")
 782       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 783     endif()
 784     option(${project}_${type}_${nameUPPER}_BUILD
 785       "Whether to build ${name} as part of LLVM"
 786       ${${project}_${type}_${nameUPPER}_BUILD_DEFAULT})
 787     if (${project}_${type}_${nameUPPER}_BUILD)
 788       if(EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 789         add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 790       elseif(NOT "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}" STREQUAL "")
 791         message(WARNING "Nonexistent directory for ${name}: ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}")
 792       endif()
 793       # FIXME: It'd be redundant.
 794       set(${project}_${type}_${nameUPPER}_BUILD Off)
 795     endif()
 796   endif()
 797 endmacro()
 798
 799 # Add external project that may want to be built as part of llvm such as Clang,
 800 # lld, and Polly. This adds two options. One for the source directory of the
 801 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 802 # enable or disable building it with everything else.
 803 # Additional parameter can be specified as the name of directory.
 804 macro(add_llvm_external_project name)
 805   add_llvm_subdirectory(LLVM TOOL ${name} ${ARGN})
 806 endmacro()
 807
 808 macro(add_llvm_tool_subdirectory name)
 809   add_llvm_external_project(${name})
 810 endmacro(add_llvm_tool_subdirectory)
 811
 812 function(get_project_name_from_src_var var output)
 813   string(REGEX MATCH "LLVM_EXTERNAL_(.*)_SOURCE_DIR"
 814          MACHED_TOOL "${var}")
 815   if(MACHED_TOOL)
 816     set(${output} ${CMAKE_MATCH_1} PARENT_SCOPE)
 817   else()
 818     set(${output} PARENT_SCOPE)
 819   endif()
 820 endfunction()
 821
 822 function(create_subdirectory_options project type)
 823   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 824   foreach(dir ${sub-dirs})
 825     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 826       canonicalize_tool_name(${dir} name)
 827       option(${project}_${type}_${name}_BUILD
 828            "Whether to build ${name} as part of ${project}" On)
 829       mark_as_advanced(${project}_${type}_${name}_BUILD)
 830     endif()
 831   endforeach()
 832 endfunction(create_subdirectory_options)
 833
 834 function(create_llvm_tool_options)
 835   create_subdirectory_options(LLVM TOOL)
 836 endfunction(create_llvm_tool_options)
 837
 838 function(add_llvm_implicit_projects)
 839   set(list_of_implicit_subdirs "")
 840   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 841   foreach(dir ${sub-dirs})
 842     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 843       canonicalize_tool_name(${dir} name)
 844       if (LLVM_TOOL_${name}_BUILD)
 845         get_filename_component(fn "${dir}" NAME)
 846         list(APPEND list_of_implicit_subdirs "${fn}")
 847       endif()
 848     endif()
 849   endforeach()
 850
 851   foreach(external_proj ${list_of_implicit_subdirs})
 852     add_llvm_external_project("${external_proj}")
 853   endforeach()
 854 endfunction(add_llvm_implicit_projects)
 855
 856 # Generic support for adding a unittest.
 857 function(add_unittest test_suite test_name)
 858   if( NOT LLVM_BUILD_TESTS )
 859     set(EXCLUDE_FROM_ALL ON)
 860   endif()
 861
 862   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 863   if (NOT LLVM_ENABLE_THREADS)
 864     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 865   endif ()
 866
 867   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 868     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 869   endif ()
 870
 871   set(LLVM_REQUIRES_RTTI OFF)
 872
 873   add_llvm_executable(${test_name} ${ARGN})
 874   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 875   set_output_directory(${test_name} BINARY_DIR ${outdir} LIBRARY_DIR ${outdir})
 876   target_link_libraries(${test_name}
 877     gtest
 878     gtest_main
 879     LLVMSupport # gtest needs it for raw_ostream.
 880     )
 881
 882   add_dependencies(${test_suite} ${test_name})
 883   get_target_property(test_suite_folder ${test_suite} FOLDER)
 884   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 885     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 886   endif ()
 887 endfunction()
 888
 889 function(llvm_add_go_executable binary pkgpath)
 890   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 891
 892   if(LLVM_BINDINGS MATCHES "go")
 893     # FIXME: This should depend only on the libraries Go needs.
 894     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 895     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 896     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 897     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 898     set(cppflags "")
 899     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 900     foreach(d ${include_dirs})
 901       set(cppflags "${cppflags} -I${d}")
 902     endforeach(d)
 903     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 904     if (LLVM_LINK_LLVM_DYLIB)
 905       set(linkmode "dylib")
 906     else()
 907       set(linkmode "component-libs")
 908     endif()
 909     add_custom_command(OUTPUT ${binpath}
 910       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "go=${GO_EXECUTABLE}" "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}" "linkmode=${linkmode}"
 911               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 912       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 913               ${llvmlibs} ${ARG_DEPENDS}
 914       COMMENT "Building Go executable ${binary}"
 915       VERBATIM)
 916     if (ARG_ALL)
 917       add_custom_target(${binary} ALL DEPENDS ${binpath})
 918     else()
 919       add_custom_target(${binary} DEPENDS ${binpath})
 920     endif()
 921   endif()
 922 endfunction()
 923
 924 # This function provides an automatic way to 'configure'-like generate a file
 925 # based on a set of common and custom variables, specifically targeting the
 926 # variables needed for the 'lit.site.cfg' files. This function bundles the
 927 # common variables that any Lit instance is likely to need, and custom
 928 # variables can be passed in.
 929 function(configure_lit_site_cfg input output)
 930   foreach(c ${LLVM_TARGETS_TO_BUILD})
 931     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 932   endforeach(c)
 933   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 934
 935   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 936
 937   # Configuration-time: See Unit/lit.site.cfg.in
 938   if (CMAKE_CFG_INTDIR STREQUAL ".")
 939     set(LLVM_BUILD_MODE ".")
 940   else ()
 941     set(LLVM_BUILD_MODE "%(build_mode)s")
 942   endif ()
 943
 944   # They below might not be the build tree but provided binary tree.
 945   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 946   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 947   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 948   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 949
 950   # SHLIBDIR points the build tree.
 951   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 952
 953   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 954   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 955   # plugins. We may rename it.
 956   if(LLVM_ENABLE_PLUGINS)
 957     set(ENABLE_SHARED "1")
 958   else()
 959     set(ENABLE_SHARED "0")
 960   endif()
 961
 962   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 963     set(ENABLE_ASSERTIONS "1")
 964   else()
 965     set(ENABLE_ASSERTIONS "0")
 966   endif()
 967
 968   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 969   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 970
 971   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 972   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 973   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 974
 975   configure_file(${input} ${output} @ONLY)
 976 endfunction()
 977
 978 # A raw function to create a lit target. This is used to implement the testuite
 979 # management functions.
 980 function(add_lit_target target comment)
 981   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 982   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 983   separate_arguments(LIT_ARGS)
 984   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 985     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 986   endif ()
 987   if (LLVM_MAIN_SRC_DIR)
 988     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 989   else()
 990     find_program(LIT_COMMAND llvm-lit)
 991   endif ()
 992   list(APPEND LIT_COMMAND ${LIT_ARGS})
 993   foreach(param ${ARG_PARAMS})
 994     list(APPEND LIT_COMMAND --param ${param})
 995   endforeach()
 996   if (ARG_UNPARSED_ARGUMENTS)
 997     add_custom_target(${target}
 998       COMMAND ${LIT_COMMAND} ${ARG_UNPARSED_ARGUMENTS}
 999       COMMENT "${comment}"
1000       ${cmake_3_2_USES_TERMINAL}
1001       )
1002   else()
1003     add_custom_target(${target}
1004       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
1005     message(STATUS "${target} does nothing.")
1006   endif()
1007   if (ARG_DEPENDS)
1008     add_dependencies(${target} ${ARG_DEPENDS})
1009   endif()
1010
1011   # Tests should be excluded from "Build Solution".
1012   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
1013 endfunction()
1014
1015 # A function to add a set of lit test suites to be driven through 'check-*' targets.
1016 function(add_lit_testsuite target comment)
1017   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1018
1019   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
1020   if(NOT EXCLUDE_FROM_ALL)
1021     # Register the testsuites, params and depends for the global check rule.
1022     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_UNPARSED_ARGUMENTS})
1023     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
1024     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
1025     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
1026   endif()
1027
1028   # Produce a specific suffixed check rule.
1029   add_lit_target(${target} ${comment}
1030     ${ARG_UNPARSED_ARGUMENTS}
1031     PARAMS ${ARG_PARAMS}
1032     DEPENDS ${ARG_DEPENDS}
1033     ARGS ${ARG_ARGS}
1034     )
1035 endfunction()
1036
1037 function(add_lit_testsuites project directory)
1038   if (NOT CMAKE_CONFIGURATION_TYPES)
1039     cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1040     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
1041     set(lit_suites)
1042     foreach(f ${litCfg})
1043       get_filename_component(dir ${f} DIRECTORY)
1044       set(lit_suites ${lit_suites} ${dir})
1045     endforeach()
1046     list(REMOVE_DUPLICATES lit_suites)
1047     foreach(dir ${lit_suites})
1048       string(REPLACE ${directory} "" name_slash ${dir})
1049       if (name_slash)
1050         string(REPLACE "/" "-" name_slash ${name_slash})
1051         string(REPLACE "\\" "-" name_dashes ${name_slash})
1052         string(TOLOWER "${project}${name_dashes}" name_var)
1053         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
1054           ${dir}
1055           PARAMS ${ARG_PARAMS}
1056           DEPENDS ${ARG_DEPENDS}
1057           ARGS ${ARG_ARGS}
1058         )
1059       endif()
1060     endforeach()
1061   endif()
1062 endfunction()
1063
1064 function(llvm_install_library_symlink name dest type)
1065   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "COMPONENT" "" ${ARGN})
1066   foreach(path ${CMAKE_MODULE_PATH})
1067     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1068       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1069       break()
1070     endif()
1071   endforeach()
1072
1073   set(component ${ARG_COMPONENT})
1074   if(NOT component)
1075     set(component ${name})
1076   endif()
1077
1078   set(full_name ${CMAKE_${type}_LIBRARY_PREFIX}${name}${CMAKE_${type}_LIBRARY_SUFFIX})
1079   set(full_dest ${CMAKE_${type}_LIBRARY_PREFIX}${dest}${CMAKE_${type}_LIBRARY_SUFFIX})
1080
1081   set(output_dir lib${LLVM_LIBDIR_SUFFIX})
1082   if(WIN32 AND "${type}" STREQUAL "SHARED")
1083     set(output_dir bin)
1084   endif()
1085
1086   install(SCRIPT ${INSTALL_SYMLINK}
1087           CODE "install_symlink(${full_name} ${full_dest} ${output_dir})"
1088           COMPONENT ${component})
1089
1090   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1091     add_custom_target(install-${name}
1092                       DEPENDS ${name} ${dest} install-${dest}
1093                       COMMAND "${CMAKE_COMMAND}"
1094                               -DCMAKE_INSTALL_COMPONENT=${name}
1095                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1096   endif()
1097 endfunction()
1098
1099 function(llvm_install_symlink name dest)
1100   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1101   foreach(path ${CMAKE_MODULE_PATH})
1102     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1103       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1104       break()
1105     endif()
1106   endforeach()
1107
1108   if(ARG_ALWAYS_GENERATE)
1109     set(component ${dest})
1110   else()
1111     set(component ${name})
1112   endif()
1113
1114   set(full_name ${name}${CMAKE_EXECUTABLE_SUFFIX})
1115   set(full_dest ${dest}${CMAKE_EXECUTABLE_SUFFIX})
1116
1117   install(SCRIPT ${INSTALL_SYMLINK}
1118           CODE "install_symlink(${full_name} ${full_dest} bin)"
1119           COMPONENT ${component})
1120
1121   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1122     add_custom_target(install-${name}
1123                       DEPENDS ${name} ${dest} install-${dest}
1124                       COMMAND "${CMAKE_COMMAND}"
1125                               -DCMAKE_INSTALL_COMPONENT=${name}
1126                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1127   endif()
1128 endfunction()
1129
1130 function(add_llvm_tool_symlink name dest)
1131   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1132   if(UNIX)
1133     set(LLVM_LINK_OR_COPY create_symlink)
1134     set(dest_binary "${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1135   else()
1136     set(LLVM_LINK_OR_COPY copy)
1137     set(dest_binary "${LLVM_RUNTIME_OUTPUT_INTDIR}/${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1138   endif()
1139
1140   set(output_path "${LLVM_RUNTIME_OUTPUT_INTDIR}/${name}${CMAKE_EXECUTABLE_SUFFIX}")
1141
1142   if(ARG_ALWAYS_GENERATE)
1143     set_property(DIRECTORY APPEND PROPERTY
1144       ADDITIONAL_MAKE_CLEAN_FILES ${dest_binary})
1145     add_custom_command(TARGET ${dest} POST_BUILD
1146       COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}")
1147   else()
1148     add_custom_command(OUTPUT ${output_path}
1149                      COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}"
1150                      DEPENDS ${dest})
1151     add_custom_target(${name} ALL DEPENDS ${output_path})
1152     set_target_properties(${name} PROPERTIES FOLDER Tools)
1153
1154     # Make sure the parent tool is a toolchain tool, otherwise exclude this tool
1155     list(FIND LLVM_TOOLCHAIN_TOOLS ${dest} LLVM_IS_${dest}_TOOLCHAIN_TOOL)
1156     if (NOT LLVM_IS_${dest}_TOOLCHAIN_TOOL GREATER -1)
1157       set(LLVM_IS_${name}_TOOLCHAIN_TOOL ${LLVM_IS_${dest}_TOOLCHAIN_TOOL})
1158     else()
1159       list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
1160     endif()
1161
1162     # LLVM_IS_${name}_TOOLCHAIN_TOOL will only be greater than -1 if both this
1163     # tool and its parent tool are in LLVM_TOOLCHAIN_TOOLS
1164     if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1165       if( LLVM_BUILD_TOOLS )
1166         llvm_install_symlink(${name} ${dest})
1167       endif()
1168     endif()
1169   endif()
1170 endfunction()