cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   if(LLVM_REQUIRES_EH)
  12     set(LLVM_REQUIRES_RTTI ON)
  13   else()
  14     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  15       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  16     elseif(MSVC)
  17       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  18       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  19     endif()
  20   endif()
  21
  22   if(NOT LLVM_REQUIRES_RTTI)
  23     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  24     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  25       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  26     elseif (MSVC)
  27       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  28     endif ()
  29   endif()
  30
  31   # Assume that;
  32   #   - LLVM_COMPILE_FLAGS is list.
  33   #   - PROPERTY COMPILE_FLAGS is string.
  34   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  35
  36   if(update_src_props)
  37     foreach(fn ${sources})
  38       get_filename_component(suf ${fn} EXT)
  39       if("${suf}" STREQUAL ".cpp")
  40         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  41           COMPILE_FLAGS "${target_compile_flags}")
  42       endif()
  43     endforeach()
  44   else()
  45     # Update target props, since all sources are C++.
  46     set_property(TARGET ${name} APPEND_STRING PROPERTY
  47       COMPILE_FLAGS "${target_compile_flags}")
  48   endif()
  49
  50   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  51 endfunction()
  52
  53 function(add_llvm_symbol_exports target_name export_file)
  54   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  55     set(native_export_file "${target_name}.exports")
  56     add_custom_command(OUTPUT ${native_export_file}
  57       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  58       DEPENDS ${export_file}
  59       VERBATIM
  60       COMMENT "Creating export file for ${target_name}")
  61     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  62                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  63   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  64     # Gold and BFD ld require a version script rather than a plain list.
  65     set(native_export_file "${target_name}.exports")
  66     # FIXME: Don't write the "local:" line on OpenBSD.
  67     add_custom_command(OUTPUT ${native_export_file}
  68       COMMAND echo "{" > ${native_export_file}
  69       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  70       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  71       COMMAND echo "  local: *;" >> ${native_export_file}
  72       COMMAND echo "};" >> ${native_export_file}
  73       DEPENDS ${export_file}
  74       VERBATIM
  75       COMMENT "Creating export file for ${target_name}")
  76     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  77                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  78   else()
  79     set(native_export_file "${target_name}.def")
  80
  81     set(CAT "type")
  82     if(CYGWIN)
  83       set(CAT "cat")
  84     endif()
  85
  86     # Using ${export_file} in add_custom_command directly confuses cmd.exe.
  87     file(TO_NATIVE_PATH ${export_file} export_file_backslashes)
  88
  89     add_custom_command(OUTPUT ${native_export_file}
  90       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
  91       COMMAND ${CAT} ${export_file_backslashes} >> ${native_export_file}
  92       DEPENDS ${export_file}
  93       VERBATIM
  94       COMMENT "Creating export file for ${target_name}")
  95     if(CYGWIN OR MINGW)
  96       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  97                    LINK_FLAGS " ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  98     else()
  99       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 100                    LINK_FLAGS " /DEF:${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 101     endif()
 102   endif()
 103
 104   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 105   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 106
 107   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 108   foreach(src ${srcs})
 109     get_filename_component(extension ${src} EXT)
 110     if(extension STREQUAL ".cpp")
 111       set(first_source_file ${src})
 112       break()
 113     endif()
 114   endforeach()
 115
 116   # Force re-linking when the exports file changes. Actually, it
 117   # forces recompilation of the source file. The LINK_DEPENDS target
 118   # property only works for makefile-based generators.
 119   # FIXME: This is not safe because this will create the same target
 120   # ${native_export_file} in several different file:
 121   # - One where we emitted ${target_name}_exports
 122   # - One where we emitted the build command for the following object.
 123   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 124   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 125
 126   set_property(DIRECTORY APPEND
 127     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 128
 129   add_dependencies(${target_name} ${target_name}_exports)
 130
 131   # Add dependency to *_exports later -- CMake issue 14747
 132   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 133   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 134 endfunction(add_llvm_symbol_exports)
 135
 136 function(add_dead_strip target_name)
 137   if(NOT LLVM_NO_DEAD_STRIP)
 138     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 139       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 140                    LINK_FLAGS " -Wl,-dead_strip")
 141     elseif(NOT WIN32)
 142       # Object files are compiled with -ffunction-data-sections.
 143       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 144                    LINK_FLAGS " -Wl,--gc-sections")
 145     endif()
 146   endif()
 147 endfunction(add_dead_strip)
 148
 149 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 150 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 151 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 152 function(set_output_directory target bindir libdir)
 153   # Do nothing if *_OUTPUT_INTDIR is empty.
 154   if("${bindir}" STREQUAL "")
 155     return()
 156   endif()
 157
 158   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 159   # It affects output of add_library(MODULE).
 160   if(WIN32 OR CYGWIN)
 161     # DLL platform
 162     set(moddir ${bindir})
 163   else()
 164     set(moddir ${libdir})
 165   endif()
 166   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 167     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 168       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 169       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 170       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 171       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 172       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 173       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 174       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 175     endforeach()
 176   else()
 177     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 178     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 179     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 180   endif()
 181 endfunction()
 182
 183 # llvm_add_library(name sources...
 184 #   SHARED;STATIC
 185 #     STATIC by default w/o BUILD_SHARED_LIBS.
 186 #     SHARED by default w/  BUILD_SHARED_LIBS.
 187 #   MODULE
 188 #     Target ${name} might not be created on unsupported platforms.
 189 #     Check with "if(TARGET ${name})".
 190 #   OUTPUT_NAME name
 191 #     Corresponds to OUTPUT_NAME in target properties.
 192 #   DEPENDS targets...
 193 #     Same semantics as add_dependencies().
 194 #   LINK_COMPONENTS components...
 195 #     Same as the variable LLVM_LINK_COMPONENTS.
 196 #   LINK_LIBS lib_targets...
 197 #     Same semantics as target_link_libraries().
 198 #   ADDITIONAL_HEADERS
 199 #     May specify header files for IDE generators.
 200 #   )
 201 function(llvm_add_library name)
 202   cmake_parse_arguments(ARG
 203     "MODULE;SHARED;STATIC"
 204     "OUTPUT_NAME"
 205     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 206     ${ARGN})
 207   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 208   if(ARG_ADDITIONAL_HEADERS)
 209     # Pass through ADDITIONAL_HEADERS.
 210     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 211   endif()
 212   if(ARG_OBJLIBS)
 213     set(ALL_FILES ${ARG_OBJLIBS})
 214   else()
 215     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 216   endif()
 217
 218   if(ARG_MODULE)
 219     if(ARG_SHARED OR ARG_STATIC)
 220       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 221     endif()
 222     if(NOT LLVM_ENABLE_PLUGINS)
 223       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 224       return()
 225     endif()
 226   else()
 227     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 228       set(ARG_SHARED TRUE)
 229     endif()
 230     if(NOT ARG_SHARED)
 231       set(ARG_STATIC TRUE)
 232     endif()
 233   endif()
 234
 235   # Generate objlib
 236   if(ARG_SHARED AND ARG_STATIC)
 237     # Generate an obj library for both targets.
 238     set(obj_name "obj.${name}")
 239     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 240       ${ALL_FILES}
 241       )
 242     llvm_update_compile_flags(${obj_name})
 243     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 244
 245     # Do add_dependencies(obj) later due to CMake issue 14747.
 246     list(APPEND objlibs ${obj_name})
 247
 248     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 249   endif()
 250
 251   if(ARG_SHARED AND ARG_STATIC)
 252     # static
 253     set(name_static "${name}_static")
 254     if(ARG_OUTPUT_NAME)
 255       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 256     endif()
 257     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 258     llvm_add_library(${name_static} STATIC
 259       ${output_name}
 260       OBJLIBS ${ALL_FILES} # objlib
 261       LINK_LIBS ${ARG_LINK_LIBS}
 262       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 263       )
 264     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 265     set(ARG_STATIC)
 266   endif()
 267
 268   if(ARG_MODULE)
 269     add_library(${name} MODULE ${ALL_FILES})
 270   elseif(ARG_SHARED)
 271     add_library(${name} SHARED ${ALL_FILES})
 272   else()
 273     add_library(${name} STATIC ${ALL_FILES})
 274   endif()
 275   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 276   llvm_update_compile_flags(${name})
 277   add_dead_strip( ${name} )
 278   if(ARG_OUTPUT_NAME)
 279     set_target_properties(${name}
 280       PROPERTIES
 281       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 282       )
 283   endif()
 284
 285   if(ARG_MODULE)
 286     set_target_properties(${name} PROPERTIES
 287       PREFIX ""
 288       SUFFIX ${LLVM_PLUGIN_EXT}
 289       )
 290   endif()
 291
 292   if(ARG_SHARED)
 293     if(WIN32)
 294       set_target_properties(${name} PROPERTIES
 295         PREFIX ""
 296         )
 297     endif()
 298     if (MSVC)
 299       set_target_properties(${name}
 300         PROPERTIES
 301         IMPORT_SUFFIX ".imp")
 302     endif ()
 303   endif()
 304
 305   if(ARG_MODULE OR ARG_SHARED)
 306     if (LLVM_EXPORTED_SYMBOL_FILE)
 307       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 308     endif()
 309   endif()
 310
 311   # Add the explicit dependency information for this library.
 312   #
 313   # It would be nice to verify that we have the dependencies for this library
 314   # name, but using get_property(... SET) doesn't suffice to determine if a
 315   # property has been set to an empty value.
 316   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 317
 318   llvm_map_components_to_libnames(llvm_libs
 319     ${ARG_LINK_COMPONENTS}
 320     ${LLVM_LINK_COMPONENTS}
 321     )
 322
 323   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 324     # Link libs w/o keywords, assuming PUBLIC.
 325     target_link_libraries(${name}
 326       ${ARG_LINK_LIBS}
 327       ${lib_deps}
 328       ${llvm_libs}
 329       )
 330   elseif(ARG_STATIC)
 331     target_link_libraries(${name} INTERFACE
 332       ${ARG_LINK_LIBS}
 333       ${lib_deps}
 334       ${llvm_libs}
 335       )
 336   elseif(ARG_SHARED AND BUILD_SHARED_LIBS)
 337     # FIXME: It may be PRIVATE since SO knows its dependent libs.
 338     target_link_libraries(${name} PUBLIC
 339       ${ARG_LINK_LIBS}
 340       ${lib_deps}
 341       ${llvm_libs}
 342       )
 343   else()
 344     # MODULE|SHARED
 345     target_link_libraries(${name} PRIVATE
 346       ${ARG_LINK_LIBS}
 347       ${lib_deps}
 348       ${llvm_libs}
 349       )
 350   endif()
 351
 352   if(LLVM_COMMON_DEPENDS)
 353     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 354     # Add dependencies also to objlibs.
 355     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 356     foreach(objlib ${objlibs})
 357       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 358     endforeach()
 359   endif()
 360 endfunction()
 361
 362 macro(add_llvm_library name)
 363   if( BUILD_SHARED_LIBS )
 364     llvm_add_library(${name} SHARED ${ARGN})
 365   else()
 366     llvm_add_library(${name} ${ARGN})
 367   endif()
 368   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 369
 370   if( EXCLUDE_FROM_ALL )
 371     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 372   else()
 373     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 374       install(TARGETS ${name}
 375         EXPORT LLVMExports
 376         RUNTIME DESTINATION bin
 377         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 378         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 379     endif()
 380     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 381   endif()
 382   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 383 endmacro(add_llvm_library name)
 384
 385 macro(add_llvm_loadable_module name)
 386   llvm_add_library(${name} MODULE ${ARGN})
 387   if(NOT TARGET ${name})
 388     # Add empty "phony" target
 389     add_custom_target(${name})
 390   else()
 391     if( EXCLUDE_FROM_ALL )
 392       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 393     else()
 394       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 395         if(WIN32 OR CYGWIN)
 396           # DLL platform
 397           set(dlldir "bin")
 398         else()
 399           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 400         endif()
 401         install(TARGETS ${name}
 402           EXPORT LLVMExports
 403           LIBRARY DESTINATION ${dlldir}
 404           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 405       endif()
 406       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 407     endif()
 408   endif()
 409
 410   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 411 endmacro(add_llvm_loadable_module name)
 412
 413
 414 macro(add_llvm_executable name)
 415   llvm_process_sources( ALL_FILES ${ARGN} )
 416   if( EXCLUDE_FROM_ALL )
 417     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 418   else()
 419     add_executable(${name} ${ALL_FILES})
 420   endif()
 421   llvm_update_compile_flags(${name})
 422   add_dead_strip( ${name} )
 423
 424   if (LLVM_EXPORTED_SYMBOL_FILE)
 425     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 426   endif(LLVM_EXPORTED_SYMBOL_FILE)
 427
 428   set(EXCLUDE_FROM_ALL OFF)
 429   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 430   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 431   if( LLVM_COMMON_DEPENDS )
 432     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 433   endif( LLVM_COMMON_DEPENDS )
 434 endmacro(add_llvm_executable name)
 435
 436
 437 set (LLVM_TOOLCHAIN_TOOLS
 438   llvm-ar
 439   llvm-objdump
 440   )
 441
 442 macro(add_llvm_tool name)
 443   if( NOT LLVM_BUILD_TOOLS )
 444     set(EXCLUDE_FROM_ALL ON)
 445   endif()
 446   add_llvm_executable(${name} ${ARGN})
 447
 448   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 449   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 450     if( LLVM_BUILD_TOOLS )
 451       install(TARGETS ${name}
 452               EXPORT LLVMExports
 453               RUNTIME DESTINATION bin)
 454     endif()
 455   endif()
 456   if( LLVM_BUILD_TOOLS )
 457     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 458   endif()
 459   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 460 endmacro(add_llvm_tool name)
 461
 462
 463 macro(add_llvm_example name)
 464   if( NOT LLVM_BUILD_EXAMPLES )
 465     set(EXCLUDE_FROM_ALL ON)
 466   endif()
 467   add_llvm_executable(${name} ${ARGN})
 468   if( LLVM_BUILD_EXAMPLES )
 469     install(TARGETS ${name} RUNTIME DESTINATION examples)
 470   endif()
 471   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 472 endmacro(add_llvm_example name)
 473
 474
 475 macro(add_llvm_utility name)
 476   add_llvm_executable(${name} ${ARGN})
 477   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 478 endmacro(add_llvm_utility name)
 479
 480
 481 macro(add_llvm_target target_name)
 482   include_directories(BEFORE
 483     ${CMAKE_CURRENT_BINARY_DIR}
 484     ${CMAKE_CURRENT_SOURCE_DIR})
 485   add_llvm_library(LLVM${target_name} ${ARGN})
 486   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 487 endmacro(add_llvm_target)
 488
 489 # Add external project that may want to be built as part of llvm such as Clang,
 490 # lld, and Polly. This adds two options. One for the source directory of the
 491 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 492 # enable or disable building it with everything else.
 493 # Additional parameter can be specified as the name of directory.
 494 macro(add_llvm_external_project name)
 495   set(add_llvm_external_dir "${ARGN}")
 496   if("${add_llvm_external_dir}" STREQUAL "")
 497     set(add_llvm_external_dir ${name})
 498   endif()
 499   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 500   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 501   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 502   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 503       CACHE PATH "Path to ${name} source directory")
 504   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 505       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 506     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 507            "Whether to build ${name} as part of LLVM" ON)
 508     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 509       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 510     endif()
 511   endif()
 512 endmacro(add_llvm_external_project)
 513
 514 macro(add_llvm_tool_subdirectory name)
 515   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 516   add_subdirectory(${name})
 517 endmacro(add_llvm_tool_subdirectory)
 518
 519 macro(ignore_llvm_tool_subdirectory name)
 520   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 521 endmacro(ignore_llvm_tool_subdirectory)
 522
 523 function(add_llvm_implicit_external_projects)
 524   set(list_of_implicit_subdirs "")
 525   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 526   foreach(dir ${sub-dirs})
 527     if(IS_DIRECTORY "${dir}")
 528       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 529       if( tool_subdir_ignore EQUAL -1
 530           AND EXISTS "${dir}/CMakeLists.txt")
 531         get_filename_component(fn "${dir}" NAME)
 532         list(APPEND list_of_implicit_subdirs "${fn}")
 533       endif()
 534     endif()
 535   endforeach()
 536
 537   foreach(external_proj ${list_of_implicit_subdirs})
 538     add_llvm_external_project("${external_proj}")
 539   endforeach()
 540 endfunction(add_llvm_implicit_external_projects)
 541
 542 # Generic support for adding a unittest.
 543 function(add_unittest test_suite test_name)
 544   if( NOT LLVM_BUILD_TESTS )
 545     set(EXCLUDE_FROM_ALL ON)
 546   endif()
 547
 548   # Visual Studio 2012 only supports up to 8 template parameters in
 549   # std::tr1::tuple by default, but gtest requires 10
 550   if (MSVC AND MSVC_VERSION EQUAL 1700)
 551     list(APPEND LLVM_COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 552   endif ()
 553
 554   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 555   if (NOT LLVM_ENABLE_THREADS)
 556     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 557   endif ()
 558
 559   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 560     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 561   endif ()
 562
 563   set(LLVM_REQUIRES_RTTI OFF)
 564
 565   add_llvm_executable(${test_name} ${ARGN})
 566   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 567   set_output_directory(${test_name} ${outdir} ${outdir})
 568   target_link_libraries(${test_name}
 569     gtest
 570     gtest_main
 571     LLVMSupport # gtest needs it for raw_ostream.
 572     )
 573
 574   add_dependencies(${test_suite} ${test_name})
 575   get_target_property(test_suite_folder ${test_suite} FOLDER)
 576   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 577     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 578   endif ()
 579 endfunction()
 580
 581 # This function provides an automatic way to 'configure'-like generate a file
 582 # based on a set of common and custom variables, specifically targeting the
 583 # variables needed for the 'lit.site.cfg' files. This function bundles the
 584 # common variables that any Lit instance is likely to need, and custom
 585 # variables can be passed in.
 586 function(configure_lit_site_cfg input output)
 587   foreach(c ${LLVM_TARGETS_TO_BUILD})
 588     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 589   endforeach(c)
 590   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 591
 592   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 593
 594   # Configuration-time: See Unit/lit.site.cfg.in
 595   if (CMAKE_CFG_INTDIR STREQUAL ".")
 596     set(LLVM_BUILD_MODE ".")
 597   else ()
 598     set(LLVM_BUILD_MODE "%(build_mode)s")
 599   endif ()
 600
 601   # They below might not be the build tree but provided binary tree.
 602   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 603   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 604   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 605   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 606
 607   # SHLIBDIR points the build tree.
 608   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 609
 610   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 611   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 612   # plugins. We may rename it.
 613   if(LLVM_ENABLE_PLUGINS)
 614     set(ENABLE_SHARED "1")
 615   else()
 616     set(ENABLE_SHARED "0")
 617   endif()
 618
 619   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 620     set(ENABLE_ASSERTIONS "1")
 621   else()
 622     set(ENABLE_ASSERTIONS "0")
 623   endif()
 624
 625   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 626   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 627
 628   if (CLANG_ENABLE_ARCMT)
 629     set(ENABLE_CLANG_ARCMT "1")
 630   else()
 631     set(ENABLE_CLANG_ARCMT "0")
 632   endif()
 633   if (CLANG_ENABLE_REWRITER)
 634     set(ENABLE_CLANG_REWRITER "1")
 635   else()
 636     set(ENABLE_CLANG_REWRITER "0")
 637   endif()
 638   if (CLANG_ENABLE_STATIC_ANALYZER)
 639     set(ENABLE_CLANG_STATIC_ANALYZER "1")
 640   else()
 641     set(ENABLE_CLANG_STATIC_ANALYZER "0")
 642   endif()
 643
 644   configure_file(${input} ${output} @ONLY)
 645 endfunction()
 646
 647 # A raw function to create a lit target. This is used to implement the testuite
 648 # management functions.
 649 function(add_lit_target target comment)
 650   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 651   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 652   separate_arguments(LIT_ARGS)
 653   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 654     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 655   endif ()
 656   if (LLVM_MAIN_SRC_DIR)
 657     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 658   else()
 659     find_program(LIT_COMMAND llvm-lit)
 660   endif ()
 661   list(APPEND LIT_COMMAND ${LIT_ARGS})
 662   foreach(param ${ARG_PARAMS})
 663     list(APPEND LIT_COMMAND --param ${param})
 664   endforeach()
 665   if( ARG_DEPENDS )
 666     add_custom_target(${target}
 667       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 668       COMMENT "${comment}"
 669       )
 670     add_dependencies(${target} ${ARG_DEPENDS})
 671   else()
 672     add_custom_target(${target}
 673       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 674     message(STATUS "${target} does nothing.")
 675   endif()
 676
 677   # Tests should be excluded from "Build Solution".
 678   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 679 endfunction()
 680
 681 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 682 function(add_lit_testsuite target comment)
 683   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 684
 685   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 686   if(NOT EXCLUDE_FROM_ALL)
 687     # Register the testsuites, params and depends for the global check rule.
 688     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 689     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 690     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 691     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 692   endif()
 693
 694   # Produce a specific suffixed check rule.
 695   add_lit_target(${target} ${comment}
 696     ${ARG_DEFAULT_ARGS}
 697     PARAMS ${ARG_PARAMS}
 698     DEPENDS ${ARG_DEPENDS}
 699     ARGS ${ARG_ARGS}
 700     )
 701 endfunction()