cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   if(LLVM_REQUIRES_EH)
  12     set(LLVM_REQUIRES_RTTI ON)
  13   else()
  14     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  15       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  16     elseif(MSVC)
  17       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  18       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  19     endif()
  20   endif()
  21
  22   if(NOT LLVM_REQUIRES_RTTI)
  23     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  24     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  25       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  26     elseif (MSVC)
  27       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  28     endif ()
  29   endif()
  30
  31   # Assume that;
  32   #   - LLVM_COMPILE_FLAGS is list.
  33   #   - PROPERTY COMPILE_FLAGS is string.
  34   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  35
  36   if(update_src_props)
  37     foreach(fn ${sources})
  38       get_filename_component(suf ${fn} EXT)
  39       if("${suf}" STREQUAL ".cpp")
  40         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  41           COMPILE_FLAGS "${target_compile_flags}")
  42       endif()
  43     endforeach()
  44   else()
  45     # Update target props, since all sources are C++.
  46     set_property(TARGET ${name} APPEND_STRING PROPERTY
  47       COMPILE_FLAGS "${target_compile_flags}")
  48   endif()
  49
  50   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  51 endfunction()
  52
  53 function(add_llvm_symbol_exports target_name export_file)
  54   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  55     set(native_export_file "${target_name}.exports")
  56     add_custom_command(OUTPUT ${native_export_file}
  57       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  58       DEPENDS ${export_file}
  59       VERBATIM
  60       COMMENT "Creating export file for ${target_name}")
  61     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  62                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  63   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  64     # Gold and BFD ld require a version script rather than a plain list.
  65     set(native_export_file "${target_name}.exports")
  66     # FIXME: Don't write the "local:" line on OpenBSD.
  67     add_custom_command(OUTPUT ${native_export_file}
  68       COMMAND echo "{" > ${native_export_file}
  69       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  70       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  71       COMMAND echo "  local: *;" >> ${native_export_file}
  72       COMMAND echo "};" >> ${native_export_file}
  73       DEPENDS ${export_file}
  74       VERBATIM
  75       COMMENT "Creating export file for ${target_name}")
  76     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  77                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  78   else()
  79     set(native_export_file "${target_name}.def")
  80
  81     set(CAT "type")
  82     if(CYGWIN)
  83       set(CAT "cat")
  84     endif()
  85
  86     # Using ${export_file} in add_custom_command directly confuses cmd.exe.
  87     file(TO_NATIVE_PATH ${export_file} export_file_backslashes)
  88
  89     add_custom_command(OUTPUT ${native_export_file}
  90       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
  91       COMMAND ${CAT} ${export_file_backslashes} >> ${native_export_file}
  92       DEPENDS ${export_file}
  93       VERBATIM
  94       COMMENT "Creating export file for ${target_name}")
  95     if(CYGWIN OR MINGW)
  96       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  97                    LINK_FLAGS " ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  98     else()
  99       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 100                    LINK_FLAGS " /DEF:${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 101     endif()
 102   endif()
 103
 104   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 105   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 106
 107   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 108   foreach(src ${srcs})
 109     get_filename_component(extension ${src} EXT)
 110     if(extension STREQUAL ".cpp")
 111       set(first_source_file ${src})
 112       break()
 113     endif()
 114   endforeach()
 115
 116   # Force re-linking when the exports file changes. Actually, it
 117   # forces recompilation of the source file. The LINK_DEPENDS target
 118   # property only works for makefile-based generators.
 119   # FIXME: This is not safe because this will create the same target
 120   # ${native_export_file} in several different file:
 121   # - One where we emitted ${target_name}_exports
 122   # - One where we emitted the build command for the following object.
 123   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 124   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 125
 126   set_property(DIRECTORY APPEND
 127     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 128
 129   add_dependencies(${target_name} ${target_name}_exports)
 130 endfunction(add_llvm_symbol_exports)
 131
 132 function(add_dead_strip target_name)
 133   if(NOT LLVM_NO_DEAD_STRIP)
 134     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 135       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 136                    LINK_FLAGS " -Wl,-dead_strip")
 137     elseif(NOT WIN32)
 138       # Object files are compiled with -ffunction-data-sections.
 139       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 140                    LINK_FLAGS " -Wl,--gc-sections")
 141     endif()
 142   endif()
 143 endfunction(add_dead_strip)
 144
 145 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 146 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 147 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 148 function(set_output_directory target bindir libdir)
 149   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 150     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 151       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 152       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 153       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 154       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 155       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 156       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 157     endforeach()
 158   else()
 159     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 160     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 161     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${libdir})
 162   endif()
 163 endfunction()
 164
 165 # llvm_add_library(name sources...
 166 #   MODULE;SHARED;STATIC
 167 #     STATIC by default w/o BUILD_SHARED_LIBS.
 168 #     SHARED by default w/  BUILD_SHARED_LIBS.
 169 #   OUTPUT_NAME name
 170 #     Corresponds to OUTPUT_NAME in target properties.
 171 #   DEPENDS targets...
 172 #     Same semantics as add_dependencies().
 173 #   LINK_COMPONENTS components...
 174 #     Same as the variable LLVM_LINK_COMPONENTS.
 175 #   LINK_LIBS lib_targets...
 176 #     Same semantics as target_link_libraries().
 177 #   ADDITIONAL_HEADERS (implemented in LLVMProcessSources)
 178 #     May specify header files for IDE generators.
 179 #   )
 180 function(llvm_add_library name)
 181   cmake_parse_arguments(ARG
 182     "MODULE;SHARED;STATIC"
 183     "OUTPUT_NAME"
 184     "DEPENDS;LINK_COMPONENTS;LINK_LIBS"
 185     ${ARGN})
 186   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 187   llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS})
 188
 189   if(ARG_MODULE)
 190     if(ARG_SHARED OR ARG_STATIC)
 191       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 192     endif()
 193   else()
 194     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 195       set(ARG_SHARED TRUE)
 196     endif()
 197     if(NOT ARG_SHARED)
 198       set(ARG_STATIC TRUE)
 199     endif()
 200   endif()
 201
 202   if(ARG_MODULE)
 203     add_library(${name} MODULE ${ALL_FILES})
 204   elseif(ARG_SHARED)
 205     add_library(${name} SHARED ${ALL_FILES})
 206   else()
 207     add_library(${name} STATIC ${ALL_FILES})
 208   endif()
 209   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 210   llvm_update_compile_flags(${name})
 211   add_dead_strip( ${name} )
 212   if(ARG_OUTPUT_NAME)
 213     set_target_properties(${name}
 214       PROPERTIES
 215       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 216       )
 217   endif()
 218
 219   if(ARG_MODULE)
 220     set_property(TARGET ${name} PROPERTY SUFFIX ${LLVM_PLUGIN_EXT})
 221   endif()
 222
 223   if(ARG_SHARED)
 224     if (MSVC)
 225       set_target_properties(${name}
 226         PROPERTIES
 227         IMPORT_SUFFIX ".imp")
 228     endif ()
 229   endif()
 230
 231   if(ARG_MODULE OR ARG_SHARED)
 232     if (LLVM_EXPORTED_SYMBOL_FILE)
 233       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 234     endif()
 235   endif()
 236
 237   target_link_libraries(${name} ${ARG_LINK_LIBS})
 238
 239   llvm_config(${name} ${ARG_LINK_COMPONENTS} ${LLVM_LINK_COMPONENTS})
 240
 241   # Ensure that the system libraries always comes last on the
 242   # list. Without this, linking the unit tests on MinGW fails.
 243   link_system_libs( ${name} )
 244
 245   if(LLVM_COMMON_DEPENDS)
 246     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 247   endif()
 248 endfunction()
 249
 250 macro(add_llvm_library name)
 251   if( BUILD_SHARED_LIBS )
 252     llvm_add_library(${name} SHARED ${ARGN})
 253   else()
 254     llvm_add_library(${name} ${ARGN})
 255   endif()
 256   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 257
 258   if( EXCLUDE_FROM_ALL )
 259     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 260   else()
 261     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 262       install(TARGETS ${name}
 263         EXPORT LLVMExports
 264         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 265         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 266     endif()
 267     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 268   endif()
 269   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 270
 271   # Add the explicit dependency information for this library.
 272   #
 273   # It would be nice to verify that we have the dependencies for this library
 274   # name, but using get_property(... SET) doesn't suffice to determine if a
 275   # property has been set to an empty value.
 276   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 277   target_link_libraries(${name} ${lib_deps})
 278 endmacro(add_llvm_library name)
 279
 280 macro(add_llvm_loadable_module name)
 281   if( NOT LLVM_ON_UNIX OR CYGWIN )
 282     message(STATUS "Loadable modules not supported on this platform.
 283 ${name} ignored.")
 284     # Add empty "phony" target
 285     add_custom_target(${name})
 286   else()
 287     llvm_add_library(${name} MODULE ${ARGN})
 288     set_target_properties( ${name} PROPERTIES PREFIX "" )
 289
 290     if (APPLE)
 291       # Darwin-specific linker flags for loadable modules.
 292       set_property(TARGET ${name} APPEND_STRING PROPERTY
 293         LINK_FLAGS " -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 294     endif()
 295
 296     if( EXCLUDE_FROM_ALL )
 297       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 298     else()
 299       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 300         install(TARGETS ${name}
 301           EXPORT LLVMExports
 302           LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 303           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 304       endif()
 305       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 306     endif()
 307   endif()
 308
 309   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 310 endmacro(add_llvm_loadable_module name)
 311
 312
 313 macro(add_llvm_executable name)
 314   llvm_process_sources( ALL_FILES ${ARGN} )
 315   if( EXCLUDE_FROM_ALL )
 316     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 317   else()
 318     add_executable(${name} ${ALL_FILES})
 319   endif()
 320   llvm_update_compile_flags(${name})
 321   add_dead_strip( ${name} )
 322
 323   if (LLVM_EXPORTED_SYMBOL_FILE)
 324     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 325   endif(LLVM_EXPORTED_SYMBOL_FILE)
 326
 327   set(EXCLUDE_FROM_ALL OFF)
 328   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 329   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 330   if( LLVM_COMMON_DEPENDS )
 331     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 332   endif( LLVM_COMMON_DEPENDS )
 333   link_system_libs( ${name} )
 334 endmacro(add_llvm_executable name)
 335
 336
 337 set (LLVM_TOOLCHAIN_TOOLS
 338   llvm-ar
 339   llvm-objdump
 340   )
 341
 342 macro(add_llvm_tool name)
 343   if( NOT LLVM_BUILD_TOOLS )
 344     set(EXCLUDE_FROM_ALL ON)
 345   endif()
 346   add_llvm_executable(${name} ${ARGN})
 347
 348   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 349   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 350     if( LLVM_BUILD_TOOLS )
 351       install(TARGETS ${name}
 352               EXPORT LLVMExports
 353               RUNTIME DESTINATION bin)
 354     endif()
 355   endif()
 356   if( LLVM_BUILD_TOOLS )
 357     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 358   endif()
 359   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 360 endmacro(add_llvm_tool name)
 361
 362
 363 macro(add_llvm_example name)
 364   if( NOT LLVM_BUILD_EXAMPLES )
 365     set(EXCLUDE_FROM_ALL ON)
 366   endif()
 367   add_llvm_executable(${name} ${ARGN})
 368   if( LLVM_BUILD_EXAMPLES )
 369     install(TARGETS ${name} RUNTIME DESTINATION examples)
 370   endif()
 371   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 372 endmacro(add_llvm_example name)
 373
 374
 375 macro(add_llvm_utility name)
 376   add_llvm_executable(${name} ${ARGN})
 377   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 378 endmacro(add_llvm_utility name)
 379
 380
 381 macro(add_llvm_target target_name)
 382   include_directories(BEFORE
 383     ${CMAKE_CURRENT_BINARY_DIR}
 384     ${CMAKE_CURRENT_SOURCE_DIR})
 385   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 386   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 387 endmacro(add_llvm_target)
 388
 389 # Add external project that may want to be built as part of llvm such as Clang,
 390 # lld, and Polly. This adds two options. One for the source directory of the
 391 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 392 # enable or disable building it with everything else.
 393 # Additional parameter can be specified as the name of directory.
 394 macro(add_llvm_external_project name)
 395   set(add_llvm_external_dir "${ARGN}")
 396   if("${add_llvm_external_dir}" STREQUAL "")
 397     set(add_llvm_external_dir ${name})
 398   endif()
 399   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 400   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 401   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 402   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 403       CACHE PATH "Path to ${name} source directory")
 404   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 405       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 406     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 407            "Whether to build ${name} as part of LLVM" ON)
 408     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 409       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 410     endif()
 411   endif()
 412 endmacro(add_llvm_external_project)
 413
 414 macro(add_llvm_tool_subdirectory name)
 415   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 416   add_subdirectory(${name})
 417 endmacro(add_llvm_tool_subdirectory)
 418
 419 macro(ignore_llvm_tool_subdirectory name)
 420   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 421 endmacro(ignore_llvm_tool_subdirectory)
 422
 423 function(add_llvm_implicit_external_projects)
 424   set(list_of_implicit_subdirs "")
 425   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 426   foreach(dir ${sub-dirs})
 427     if(IS_DIRECTORY "${dir}")
 428       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 429       if( tool_subdir_ignore EQUAL -1
 430           AND EXISTS "${dir}/CMakeLists.txt")
 431         get_filename_component(fn "${dir}" NAME)
 432         list(APPEND list_of_implicit_subdirs "${fn}")
 433       endif()
 434     endif()
 435   endforeach()
 436
 437   foreach(external_proj ${list_of_implicit_subdirs})
 438     add_llvm_external_project("${external_proj}")
 439   endforeach()
 440 endfunction(add_llvm_implicit_external_projects)
 441
 442 # Generic support for adding a unittest.
 443 function(add_unittest test_suite test_name)
 444   if( NOT LLVM_BUILD_TESTS )
 445     set(EXCLUDE_FROM_ALL ON)
 446   endif()
 447
 448   # Visual Studio 2012 only supports up to 8 template parameters in
 449   # std::tr1::tuple by default, but gtest requires 10
 450   if (MSVC AND MSVC_VERSION EQUAL 1700)
 451     list(APPEND LLVM_COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 452   endif ()
 453
 454   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 455   if (NOT LLVM_ENABLE_THREADS)
 456     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 457   endif ()
 458
 459   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 460     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 461   endif ()
 462
 463   set(LLVM_REQUIRES_RTTI OFF)
 464
 465   add_llvm_executable(${test_name} ${ARGN})
 466   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 467   set_output_directory(${test_name} ${outdir} ${outdir})
 468   target_link_libraries(${test_name}
 469     gtest
 470     gtest_main
 471     LLVMSupport # gtest needs it for raw_ostream.
 472     )
 473
 474   add_dependencies(${test_suite} ${test_name})
 475   get_target_property(test_suite_folder ${test_suite} FOLDER)
 476   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 477     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 478   endif ()
 479 endfunction()
 480
 481 # This function provides an automatic way to 'configure'-like generate a file
 482 # based on a set of common and custom variables, specifically targeting the
 483 # variables needed for the 'lit.site.cfg' files. This function bundles the
 484 # common variables that any Lit instance is likely to need, and custom
 485 # variables can be passed in.
 486 function(configure_lit_site_cfg input output)
 487   foreach(c ${LLVM_TARGETS_TO_BUILD})
 488     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 489   endforeach(c)
 490   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 491
 492   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 493
 494   if(BUILD_SHARED_LIBS)
 495     set(LLVM_SHARED_LIBS_ENABLED "1")
 496   else()
 497     set(LLVM_SHARED_LIBS_ENABLED "0")
 498   endif(BUILD_SHARED_LIBS)
 499
 500   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 501     set(SHLIBPATH_VAR "DYLD_LIBRARY_PATH")
 502   else() # Default for all other unix like systems.
 503     # CMake hardcodes the library locaction using rpath.
 504     # Therefore LD_LIBRARY_PATH is not required to run binaries in the
 505     # build dir. We pass it anyways.
 506     set(SHLIBPATH_VAR "LD_LIBRARY_PATH")
 507   endif()
 508
 509   # Configuration-time: See Unit/lit.site.cfg.in
 510   if (CMAKE_CFG_INTDIR STREQUAL ".")
 511     set(LLVM_BUILD_MODE ".")
 512   else ()
 513     set(LLVM_BUILD_MODE "%(build_mode)s")
 514   endif ()
 515
 516   # They below might not be the build tree but provided binary tree.
 517   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 518   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 519   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 520   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 521
 522   # SHLIBDIR points the build tree.
 523   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 524
 525   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 526   set(ENABLE_SHARED ${LLVM_SHARED_LIBS_ENABLED})
 527   set(SHLIBPATH_VAR ${SHLIBPATH_VAR})
 528
 529   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 530     set(ENABLE_ASSERTIONS "1")
 531   else()
 532     set(ENABLE_ASSERTIONS "0")
 533   endif()
 534
 535   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 536   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 537
 538   if (CLANG_ENABLE_ARCMT)
 539     set(ENABLE_CLANG_ARCMT "1")
 540   else()
 541     set(ENABLE_CLANG_ARCMT "0")
 542   endif()
 543   if (CLANG_ENABLE_REWRITER)
 544     set(ENABLE_CLANG_REWRITER "1")
 545   else()
 546     set(ENABLE_CLANG_REWRITER "0")
 547   endif()
 548   if (CLANG_ENABLE_STATIC_ANALYZER)
 549     set(ENABLE_CLANG_STATIC_ANALYZER "1")
 550   else()
 551     set(ENABLE_CLANG_STATIC_ANALYZER "0")
 552   endif()
 553
 554   configure_file(${input} ${output} @ONLY)
 555 endfunction()
 556
 557 # A raw function to create a lit target. This is used to implement the testuite
 558 # management functions.
 559 function(add_lit_target target comment)
 560   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 561   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 562   separate_arguments(LIT_ARGS)
 563   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 564     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 565   endif ()
 566   set(LIT_COMMAND
 567     ${PYTHON_EXECUTABLE}
 568     ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py
 569     ${LIT_ARGS}
 570     )
 571   foreach(param ${ARG_PARAMS})
 572     list(APPEND LIT_COMMAND --param ${param})
 573   endforeach()
 574   if( ARG_DEPENDS )
 575     add_custom_target(${target}
 576       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 577       COMMENT "${comment}"
 578       )
 579     add_dependencies(${target} ${ARG_DEPENDS})
 580   else()
 581     add_custom_target(${target}
 582       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 583     message(STATUS "${target} does nothing.")
 584   endif()
 585
 586   # Tests should be excluded from "Build Solution".
 587   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 588 endfunction()
 589
 590 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 591 function(add_lit_testsuite target comment)
 592   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 593
 594   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 595   if(NOT EXCLUDE_FROM_ALL)
 596     # Register the testsuites, params and depends for the global check rule.
 597     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 598     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 599     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 600     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 601   endif()
 602
 603   # Produce a specific suffixed check rule.
 604   add_lit_target(${target} ${comment}
 605     ${ARG_DEFAULT_ARGS}
 606     PARAMS ${ARG_PARAMS}
 607     DEPENDS ${ARG_DEPENDS}
 608     ARGS ${ARG_ARGS}
 609     )
 610 endfunction()