cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3
   4 function(llvm_update_compile_flags name)
   5   get_property(sources TARGET ${name} PROPERTY SOURCES)
   6   if("${sources}" MATCHES "\\.c(;|$)")
   7     set(update_src_props ON)
   8   endif()
   9
  10   # LLVM_REQUIRES_EH is an internal flag that individual
  11   # targets can use to force EH
  12   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  13     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  14       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  15       set(LLVM_REQUIRES_RTTI ON)
  16     endif()
  17   else()
  18     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  19       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  20     elseif(MSVC)
  21       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  22       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  23     endif()
  24     if (CLANG_CL)
  25       # FIXME: Remove this once clang-cl supports SEH
  26       list(APPEND LLVM_COMPILE_DEFINITIONS "GTEST_HAS_SEH=0")
  27     endif()
  28   endif()
  29
  30   # LLVM_REQUIRES_RTTI is an internal flag that individual
  31   # targets can use to force RTTI
  32   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  33     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  34     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  35       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  36     elseif (MSVC)
  37       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  38     endif ()
  39   endif()
  40
  41   # Assume that;
  42   #   - LLVM_COMPILE_FLAGS is list.
  43   #   - PROPERTY COMPILE_FLAGS is string.
  44   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  45
  46   if(update_src_props)
  47     foreach(fn ${sources})
  48       get_filename_component(suf ${fn} EXT)
  49       if("${suf}" STREQUAL ".cpp")
  50         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  51           COMPILE_FLAGS "${target_compile_flags}")
  52       endif()
  53     endforeach()
  54   else()
  55     # Update target props, since all sources are C++.
  56     set_property(TARGET ${name} APPEND_STRING PROPERTY
  57       COMPILE_FLAGS "${target_compile_flags}")
  58   endif()
  59
  60   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  61 endfunction()
  62
  63 function(add_llvm_symbol_exports target_name export_file)
  64   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  65     set(native_export_file "${target_name}.exports")
  66     add_custom_command(OUTPUT ${native_export_file}
  67       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  68       DEPENDS ${export_file}
  69       VERBATIM
  70       COMMENT "Creating export file for ${target_name}")
  71     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  72                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  73   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  74     # Gold and BFD ld require a version script rather than a plain list.
  75     set(native_export_file "${target_name}.exports")
  76     # FIXME: Don't write the "local:" line on OpenBSD.
  77     add_custom_command(OUTPUT ${native_export_file}
  78       COMMAND echo "{" > ${native_export_file}
  79       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  80       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  81       COMMAND echo "  local: *;" >> ${native_export_file}
  82       COMMAND echo "};" >> ${native_export_file}
  83       DEPENDS ${export_file}
  84       VERBATIM
  85       COMMENT "Creating export file for ${target_name}")
  86     if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  87       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  88                    LINK_FLAGS "  -Wl,-M,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  89     else()
  90       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  91                    LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  92     endif()
  93   else()
  94     set(native_export_file "${target_name}.def")
  95
  96     set(CAT "cat")
  97     set(export_file_nativeslashes ${export_file})
  98     if(WIN32 AND NOT CYGWIN AND NOT MSYS)
  99       set(CAT "type")
 100       # Convert ${export_file} to native format (backslashes) for "type"
 101       # Does not use file(TO_NATIVE_PATH) as it doesn't create a native
 102       # path but a build-system specific format (see CMake bug
 103       # http://public.kitware.com/Bug/print_bug_page.php?bug_id=5939 )
 104       string(REPLACE / \\ export_file_nativeslashes ${export_file})
 105     endif()
 106
 107     add_custom_command(OUTPUT ${native_export_file}
 108       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
 109       COMMAND ${CAT} ${export_file_nativeslashes} >> ${native_export_file}
 110       DEPENDS ${export_file}
 111       VERBATIM
 112       COMMENT "Creating export file for ${target_name}")
 113     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 114     if(MSVC)
 115       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 116     endif()
 117     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 118                  LINK_FLAGS " ${export_file_linker_flag}")
 119   endif()
 120
 121   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 122   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 123
 124   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 125   foreach(src ${srcs})
 126     get_filename_component(extension ${src} EXT)
 127     if(extension STREQUAL ".cpp")
 128       set(first_source_file ${src})
 129       break()
 130     endif()
 131   endforeach()
 132
 133   # Force re-linking when the exports file changes. Actually, it
 134   # forces recompilation of the source file. The LINK_DEPENDS target
 135   # property only works for makefile-based generators.
 136   # FIXME: This is not safe because this will create the same target
 137   # ${native_export_file} in several different file:
 138   # - One where we emitted ${target_name}_exports
 139   # - One where we emitted the build command for the following object.
 140   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 141   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 142
 143   set_property(DIRECTORY APPEND
 144     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 145
 146   add_dependencies(${target_name} ${target_name}_exports)
 147
 148   # Add dependency to *_exports later -- CMake issue 14747
 149   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 150   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 151 endfunction(add_llvm_symbol_exports)
 152
 153 if(NOT WIN32 AND NOT APPLE)
 154   execute_process(
 155     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 156     OUTPUT_VARIABLE stdout
 157     ERROR_QUIET
 158     )
 159   if("${stdout}" MATCHES "GNU gold")
 160     set(LLVM_LINKER_IS_GOLD ON)
 161   endif()
 162 endif()
 163
 164 function(add_link_opts target_name)
 165   # Don't use linker optimizations in debug builds since it slows down the
 166   # linker in a context where the optimizations are not important.
 167   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 168
 169     # Pass -O3 to the linker. This enabled different optimizations on different
 170     # linkers.
 171     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin|SunOS" OR WIN32))
 172       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 173                    LINK_FLAGS " -Wl,-O3")
 174     endif()
 175
 176     if(LLVM_LINKER_IS_GOLD)
 177       # With gold gc-sections is always safe.
 178       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 179                    LINK_FLAGS " -Wl,--gc-sections")
 180       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 181       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 182     endif()
 183
 184     if(NOT LLVM_NO_DEAD_STRIP)
 185       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 186         # ld64's implementation of -dead_strip breaks tools that use plugins.
 187         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 188                      LINK_FLAGS " -Wl,-dead_strip")
 189       elseif(${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 190         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 191                      LINK_FLAGS " -Wl,-z -Wl,discard-unused=sections")
 192       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 193         # Object files are compiled with -ffunction-data-sections.
 194         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 195         # tools that use plugins. Always pass --gc-sections once we require
 196         # a newer linker.
 197         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 198                      LINK_FLAGS " -Wl,--gc-sections")
 199       endif()
 200     endif()
 201   endif()
 202 endfunction(add_link_opts)
 203
 204 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 205 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 206 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 207 function(set_output_directory target bindir libdir)
 208   # Do nothing if *_OUTPUT_INTDIR is empty.
 209   if("${bindir}" STREQUAL "")
 210     return()
 211   endif()
 212
 213   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 214   # It affects output of add_library(MODULE).
 215   if(WIN32 OR CYGWIN)
 216     # DLL platform
 217     set(moddir ${bindir})
 218   else()
 219     set(moddir ${libdir})
 220   endif()
 221   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 222     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 223       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 224       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 225       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 226       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 227       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 228       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 229       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 230     endforeach()
 231   else()
 232     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 233     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 234     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 235   endif()
 236 endfunction()
 237
 238 # If on Windows and building with MSVC, add the resource script containing the
 239 # VERSIONINFO data to the project.  This embeds version resource information
 240 # into the output .exe or .dll.
 241 # TODO: Enable for MinGW Windows builds too.
 242 #
 243 function(add_windows_version_resource_file OUT_VAR)
 244   set(sources ${ARGN})
 245   if (MSVC)
 246     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 247     if(EXISTS ${resource_file})
 248       set(sources ${sources} ${resource_file})
 249       source_group("Resource Files" ${resource_file})
 250       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 251     endif()
 252   endif(MSVC)
 253
 254   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 255 endfunction(add_windows_version_resource_file)
 256
 257 # set_windows_version_resource_properties(name resource_file...
 258 #   VERSION_MAJOR int
 259 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 260 #   VERSION_MINOR int
 261 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 262 #   VERSION_PATCHLEVEL int
 263 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 264 #   VERSION_STRING
 265 #     Optional version string (defaults to PACKAGE_VERSION)
 266 #   PRODUCT_NAME
 267 #     Optional product name string (defaults to "LLVM")
 268 #   )
 269 function(set_windows_version_resource_properties name resource_file)
 270   cmake_parse_arguments(ARG
 271     ""
 272     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 273     ""
 274     ${ARGN})
 275
 276   if (NOT DEFINED ARG_VERSION_MAJOR)
 277     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 278   endif()
 279
 280   if (NOT DEFINED ARG_VERSION_MINOR)
 281     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 282   endif()
 283
 284   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 285     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 286   endif()
 287
 288   if (NOT DEFINED ARG_VERSION_STRING)
 289     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 290   endif()
 291
 292   if (NOT DEFINED ARG_PRODUCT_NAME)
 293     set(ARG_PRODUCT_NAME "LLVM")
 294   endif()
 295
 296   set_property(SOURCE ${resource_file}
 297                PROPERTY COMPILE_FLAGS /nologo)
 298   set_property(SOURCE ${resource_file}
 299                PROPERTY COMPILE_DEFINITIONS
 300                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 301                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 302                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 303                "RC_VERSION_FIELD_4=0"
 304                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 305                "RC_INTERNAL_NAME=\"${name}\""
 306                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 307                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 308 endfunction(set_windows_version_resource_properties)
 309
 310 # llvm_add_library(name sources...
 311 #   SHARED;STATIC
 312 #     STATIC by default w/o BUILD_SHARED_LIBS.
 313 #     SHARED by default w/  BUILD_SHARED_LIBS.
 314 #   MODULE
 315 #     Target ${name} might not be created on unsupported platforms.
 316 #     Check with "if(TARGET ${name})".
 317 #   OUTPUT_NAME name
 318 #     Corresponds to OUTPUT_NAME in target properties.
 319 #   DEPENDS targets...
 320 #     Same semantics as add_dependencies().
 321 #   LINK_COMPONENTS components...
 322 #     Same as the variable LLVM_LINK_COMPONENTS.
 323 #   LINK_LIBS lib_targets...
 324 #     Same semantics as target_link_libraries().
 325 #   ADDITIONAL_HEADERS
 326 #     May specify header files for IDE generators.
 327 #   )
 328 function(llvm_add_library name)
 329   cmake_parse_arguments(ARG
 330     "MODULE;SHARED;STATIC"
 331     "OUTPUT_NAME"
 332     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 333     ${ARGN})
 334   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 335   if(ARG_ADDITIONAL_HEADERS)
 336     # Pass through ADDITIONAL_HEADERS.
 337     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 338   endif()
 339   if(ARG_OBJLIBS)
 340     set(ALL_FILES ${ARG_OBJLIBS})
 341   else()
 342     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 343   endif()
 344
 345   if(ARG_MODULE)
 346     if(ARG_SHARED OR ARG_STATIC)
 347       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 348     endif()
 349     if(NOT LLVM_ENABLE_PLUGINS)
 350       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 351       return()
 352     endif()
 353   else()
 354     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 355       set(ARG_SHARED TRUE)
 356     endif()
 357     if(NOT ARG_SHARED)
 358       set(ARG_STATIC TRUE)
 359     endif()
 360   endif()
 361
 362   # Generate objlib
 363   if(ARG_SHARED AND ARG_STATIC)
 364     # Generate an obj library for both targets.
 365     set(obj_name "obj.${name}")
 366     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 367       ${ALL_FILES}
 368       )
 369     llvm_update_compile_flags(${obj_name})
 370     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 371
 372     # Do add_dependencies(obj) later due to CMake issue 14747.
 373     list(APPEND objlibs ${obj_name})
 374
 375     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 376   endif()
 377
 378   if(ARG_SHARED AND ARG_STATIC)
 379     # static
 380     set(name_static "${name}_static")
 381     if(ARG_OUTPUT_NAME)
 382       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 383     endif()
 384     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 385     llvm_add_library(${name_static} STATIC
 386       ${output_name}
 387       OBJLIBS ${ALL_FILES} # objlib
 388       LINK_LIBS ${ARG_LINK_LIBS}
 389       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 390       )
 391     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 392     set(ARG_STATIC)
 393   endif()
 394
 395   if(ARG_MODULE)
 396     add_library(${name} MODULE ${ALL_FILES})
 397   elseif(ARG_SHARED)
 398     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 399     add_library(${name} SHARED ${ALL_FILES})
 400   else()
 401     add_library(${name} STATIC ${ALL_FILES})
 402   endif()
 403
 404   if(DEFINED windows_resource_file)
 405     set_windows_version_resource_properties(${name} ${windows_resource_file})
 406     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 407   endif()
 408
 409   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 410   llvm_update_compile_flags(${name})
 411   add_link_opts( ${name} )
 412   if(ARG_OUTPUT_NAME)
 413     set_target_properties(${name}
 414       PROPERTIES
 415       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 416       )
 417   endif()
 418
 419   if(ARG_MODULE)
 420     set_target_properties(${name} PROPERTIES
 421       PREFIX ""
 422       SUFFIX ${LLVM_PLUGIN_EXT}
 423       )
 424   endif()
 425
 426   if(ARG_SHARED)
 427     if(WIN32)
 428       set_target_properties(${name} PROPERTIES
 429         PREFIX ""
 430         )
 431     endif()
 432
 433     set_target_properties(${name}
 434       PROPERTIES
 435       SOVERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}
 436       VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 437   endif()
 438
 439   if(ARG_MODULE OR ARG_SHARED)
 440     # Do not add -Dname_EXPORTS to the command-line when building files in this
 441     # target. Doing so is actively harmful for the modules build because it
 442     # creates extra module variants, and not useful because we don't use these
 443     # macros.
 444     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 445
 446     if (LLVM_EXPORTED_SYMBOL_FILE)
 447       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 448     endif()
 449   endif()
 450
 451   # Add the explicit dependency information for this library.
 452   #
 453   # It would be nice to verify that we have the dependencies for this library
 454   # name, but using get_property(... SET) doesn't suffice to determine if a
 455   # property has been set to an empty value.
 456   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 457
 458   llvm_map_components_to_libnames(llvm_libs
 459     ${ARG_LINK_COMPONENTS}
 460     ${LLVM_LINK_COMPONENTS}
 461     )
 462
 463   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 464     # Link libs w/o keywords, assuming PUBLIC.
 465     target_link_libraries(${name}
 466       ${ARG_LINK_LIBS}
 467       ${lib_deps}
 468       ${llvm_libs}
 469       )
 470   elseif(ARG_STATIC)
 471     target_link_libraries(${name} INTERFACE
 472       ${ARG_LINK_LIBS}
 473       ${lib_deps}
 474       ${llvm_libs}
 475       )
 476   else()
 477     # We can use PRIVATE since SO knows its dependent libs.
 478     target_link_libraries(${name} PRIVATE
 479       ${ARG_LINK_LIBS}
 480       ${lib_deps}
 481       ${llvm_libs}
 482       )
 483   endif()
 484
 485   if(LLVM_COMMON_DEPENDS)
 486     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 487     # Add dependencies also to objlibs.
 488     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 489     foreach(objlib ${objlibs})
 490       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 491     endforeach()
 492   endif()
 493 endfunction()
 494
 495 macro(add_llvm_library name)
 496   cmake_parse_arguments(ARG
 497     "SHARED"
 498     ""
 499     ""
 500     ${ARGN})
 501   if( BUILD_SHARED_LIBS )
 502     llvm_add_library(${name} SHARED ${ARGN})
 503   else()
 504     llvm_add_library(${name} ${ARGN})
 505   endif()
 506   # The gtest libraries should not be installed or exported as a target
 507   if ("${name}" STREQUAL gtest OR "${name}" STREQUAL gtest_main)
 508     set(_is_gtest TRUE)
 509   else()
 510     set(_is_gtest FALSE)
 511     set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 512   endif()
 513
 514   if( EXCLUDE_FROM_ALL )
 515     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 516   elseif(NOT _is_gtest)
 517     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 518       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 519         if(WIN32 OR CYGWIN)
 520           set(install_type RUNTIME)
 521         else()
 522           set(install_type LIBRARY)
 523         endif()
 524       else()
 525         set(install_type ARCHIVE)
 526       endif()
 527
 528       install(TARGETS ${name}
 529             EXPORT LLVMExports
 530             ${install_type} DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 531             COMPONENT ${name})
 532
 533       if (NOT CMAKE_CONFIGURATION_TYPES)
 534         add_custom_target(install-${name}
 535                           DEPENDS ${name}
 536                           COMMAND "${CMAKE_COMMAND}"
 537                                   -DCMAKE_INSTALL_COMPONENT=${name}
 538                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 539       endif()
 540     endif()
 541     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 542   endif()
 543   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 544 endmacro(add_llvm_library name)
 545
 546 macro(add_llvm_loadable_module name)
 547   llvm_add_library(${name} MODULE ${ARGN})
 548   if(NOT TARGET ${name})
 549     # Add empty "phony" target
 550     add_custom_target(${name})
 551   else()
 552     if( EXCLUDE_FROM_ALL )
 553       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 554     else()
 555       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 556         if(WIN32 OR CYGWIN)
 557           # DLL platform
 558           set(dlldir "bin")
 559         else()
 560           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 561         endif()
 562         install(TARGETS ${name}
 563           EXPORT LLVMExports
 564           LIBRARY DESTINATION ${dlldir}
 565           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 566       endif()
 567       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 568     endif()
 569   endif()
 570
 571   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 572 endmacro(add_llvm_loadable_module name)
 573
 574
 575 macro(add_llvm_executable name)
 576   llvm_process_sources( ALL_FILES ${ARGN} )
 577   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 578
 579   if( EXCLUDE_FROM_ALL )
 580     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 581   else()
 582     add_executable(${name} ${ALL_FILES})
 583   endif()
 584
 585   if(DEFINED windows_resource_file)
 586     set_windows_version_resource_properties(${name} ${windows_resource_file})
 587   endif()
 588
 589   llvm_update_compile_flags(${name})
 590   add_link_opts( ${name} )
 591
 592   # Do not add -Dname_EXPORTS to the command-line when building files in this
 593   # target. Doing so is actively harmful for the modules build because it
 594   # creates extra module variants, and not useful because we don't use these
 595   # macros.
 596   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 597
 598   if (LLVM_EXPORTED_SYMBOL_FILE)
 599     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 600   endif(LLVM_EXPORTED_SYMBOL_FILE)
 601
 602   set(EXCLUDE_FROM_ALL OFF)
 603   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 604   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 605   if( LLVM_COMMON_DEPENDS )
 606     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 607   endif( LLVM_COMMON_DEPENDS )
 608 endmacro(add_llvm_executable name)
 609
 610 function(export_executable_symbols target)
 611   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 612     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 613   endif()
 614 endfunction()
 615
 616
 617 set (LLVM_TOOLCHAIN_TOOLS
 618   llvm-ar
 619   llvm-objdump
 620   )
 621
 622 macro(add_llvm_tool name)
 623   if( NOT LLVM_BUILD_TOOLS )
 624     set(EXCLUDE_FROM_ALL ON)
 625   endif()
 626   add_llvm_executable(${name} ${ARGN})
 627
 628   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 629   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 630     if( LLVM_BUILD_TOOLS )
 631       install(TARGETS ${name}
 632               EXPORT LLVMExports
 633               RUNTIME DESTINATION bin
 634               COMPONENT ${name})
 635
 636       if (NOT CMAKE_CONFIGURATION_TYPES)
 637         add_custom_target(install-${name}
 638                           DEPENDS ${name}
 639                           COMMAND "${CMAKE_COMMAND}"
 640                                   -DCMAKE_INSTALL_COMPONENT=${name}
 641                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 642       endif()
 643     endif()
 644   endif()
 645   if( LLVM_BUILD_TOOLS )
 646     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 647   endif()
 648   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 649 endmacro(add_llvm_tool name)
 650
 651
 652 macro(add_llvm_example name)
 653   if( NOT LLVM_BUILD_EXAMPLES )
 654     set(EXCLUDE_FROM_ALL ON)
 655   endif()
 656   add_llvm_executable(${name} ${ARGN})
 657   if( LLVM_BUILD_EXAMPLES )
 658     install(TARGETS ${name} RUNTIME DESTINATION examples)
 659   endif()
 660   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 661 endmacro(add_llvm_example name)
 662
 663
 664 macro(add_llvm_utility name)
 665   add_llvm_executable(${name} ${ARGN})
 666   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 667   if( LLVM_INSTALL_UTILS )
 668     install (TARGETS ${name}
 669       RUNTIME DESTINATION bin
 670       COMPONENT ${name})
 671     if (NOT CMAKE_CONFIGURATION_TYPES)
 672       add_custom_target(install-${name}
 673                         DEPENDS ${name}
 674                         COMMAND "${CMAKE_COMMAND}"
 675                                 -DCMAKE_INSTALL_COMPONENT=${name}
 676                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 677     endif()
 678   endif()
 679 endmacro(add_llvm_utility name)
 680
 681
 682 macro(add_llvm_target target_name)
 683   include_directories(BEFORE
 684     ${CMAKE_CURRENT_BINARY_DIR}
 685     ${CMAKE_CURRENT_SOURCE_DIR})
 686   add_llvm_library(LLVM${target_name} ${ARGN})
 687   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 688 endmacro(add_llvm_target)
 689
 690 # Add external project that may want to be built as part of llvm such as Clang,
 691 # lld, and Polly. This adds two options. One for the source directory of the
 692 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 693 # enable or disable building it with everything else.
 694 # Additional parameter can be specified as the name of directory.
 695 macro(add_llvm_external_project name)
 696   set(add_llvm_external_dir "${ARGN}")
 697   if("${add_llvm_external_dir}" STREQUAL "")
 698     set(add_llvm_external_dir ${name})
 699   endif()
 700   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 701   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 702   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 703   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 704       CACHE PATH "Path to ${name} source directory")
 705   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 706       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 707     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 708            "Whether to build ${name} as part of LLVM" ON)
 709     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 710       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 711     endif()
 712   endif()
 713 endmacro(add_llvm_external_project)
 714
 715 macro(add_llvm_tool_subdirectory name)
 716   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 717   add_subdirectory(${name})
 718 endmacro(add_llvm_tool_subdirectory)
 719
 720 macro(ignore_llvm_tool_subdirectory name)
 721   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 722 endmacro(ignore_llvm_tool_subdirectory)
 723
 724 function(add_llvm_implicit_external_projects)
 725   set(list_of_implicit_subdirs "")
 726   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 727   foreach(dir ${sub-dirs})
 728     if(IS_DIRECTORY "${dir}")
 729       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 730       if( tool_subdir_ignore EQUAL -1
 731           AND EXISTS "${dir}/CMakeLists.txt")
 732         get_filename_component(fn "${dir}" NAME)
 733         list(APPEND list_of_implicit_subdirs "${fn}")
 734       endif()
 735     endif()
 736   endforeach()
 737
 738   foreach(external_proj ${list_of_implicit_subdirs})
 739     add_llvm_external_project("${external_proj}")
 740   endforeach()
 741 endfunction(add_llvm_implicit_external_projects)
 742
 743 # Generic support for adding a unittest.
 744 function(add_unittest test_suite test_name)
 745   if( NOT LLVM_BUILD_TESTS )
 746     set(EXCLUDE_FROM_ALL ON)
 747   endif()
 748
 749   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 750   if (NOT LLVM_ENABLE_THREADS)
 751     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 752   endif ()
 753
 754   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 755     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 756   endif ()
 757
 758   set(LLVM_REQUIRES_RTTI OFF)
 759
 760   add_llvm_executable(${test_name} ${ARGN})
 761   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 762   set_output_directory(${test_name} ${outdir} ${outdir})
 763   target_link_libraries(${test_name}
 764     gtest
 765     gtest_main
 766     LLVMSupport # gtest needs it for raw_ostream.
 767     )
 768
 769   add_dependencies(${test_suite} ${test_name})
 770   get_target_property(test_suite_folder ${test_suite} FOLDER)
 771   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 772     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 773   endif ()
 774 endfunction()
 775
 776 function(llvm_add_go_executable binary pkgpath)
 777   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 778
 779   if(LLVM_BINDINGS MATCHES "go")
 780     # FIXME: This should depend only on the libraries Go needs.
 781     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 782     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 783     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 784     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 785     set(cppflags "")
 786     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 787     foreach(d ${include_dirs})
 788       set(cppflags "${cppflags} -I${d}")
 789     endforeach(d)
 790     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 791     add_custom_command(OUTPUT ${binpath}
 792       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}"
 793               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 794       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 795               ${llvmlibs} ${ARG_DEPENDS}
 796       COMMENT "Building Go executable ${binary}"
 797       VERBATIM)
 798     if (ARG_ALL)
 799       add_custom_target(${binary} ALL DEPENDS ${binpath})
 800     else()
 801       add_custom_target(${binary} DEPENDS ${binpath})
 802     endif()
 803   endif()
 804 endfunction()
 805
 806 # This function provides an automatic way to 'configure'-like generate a file
 807 # based on a set of common and custom variables, specifically targeting the
 808 # variables needed for the 'lit.site.cfg' files. This function bundles the
 809 # common variables that any Lit instance is likely to need, and custom
 810 # variables can be passed in.
 811 function(configure_lit_site_cfg input output)
 812   foreach(c ${LLVM_TARGETS_TO_BUILD})
 813     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 814   endforeach(c)
 815   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 816
 817   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 818
 819   # Configuration-time: See Unit/lit.site.cfg.in
 820   if (CMAKE_CFG_INTDIR STREQUAL ".")
 821     set(LLVM_BUILD_MODE ".")
 822   else ()
 823     set(LLVM_BUILD_MODE "%(build_mode)s")
 824   endif ()
 825
 826   # They below might not be the build tree but provided binary tree.
 827   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 828   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 829   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 830   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 831
 832   # SHLIBDIR points the build tree.
 833   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 834
 835   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 836   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 837   # plugins. We may rename it.
 838   if(LLVM_ENABLE_PLUGINS)
 839     set(ENABLE_SHARED "1")
 840   else()
 841     set(ENABLE_SHARED "0")
 842   endif()
 843
 844   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 845     set(ENABLE_ASSERTIONS "1")
 846   else()
 847     set(ENABLE_ASSERTIONS "0")
 848   endif()
 849
 850   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 851   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 852
 853   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 854   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 855   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 856
 857   configure_file(${input} ${output} @ONLY)
 858 endfunction()
 859
 860 # A raw function to create a lit target. This is used to implement the testuite
 861 # management functions.
 862 function(add_lit_target target comment)
 863   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 864   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 865   separate_arguments(LIT_ARGS)
 866   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 867     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 868   endif ()
 869   if (LLVM_MAIN_SRC_DIR)
 870     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 871   else()
 872     find_program(LIT_COMMAND llvm-lit)
 873   endif ()
 874   list(APPEND LIT_COMMAND ${LIT_ARGS})
 875   foreach(param ${ARG_PARAMS})
 876     list(APPEND LIT_COMMAND --param ${param})
 877   endforeach()
 878   if (ARG_UNPARSED_ARGUMENTS)
 879     add_custom_target(${target}
 880       COMMAND ${LIT_COMMAND} ${ARG_UNPARSED_ARGUMENTS}
 881       COMMENT "${comment}"
 882       ${cmake_3_2_USES_TERMINAL}
 883       )
 884   else()
 885     add_custom_target(${target}
 886       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 887     message(STATUS "${target} does nothing.")
 888   endif()
 889   if (ARG_DEPENDS)
 890     add_dependencies(${target} ${ARG_DEPENDS})
 891   endif()
 892
 893   # Tests should be excluded from "Build Solution".
 894   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 895 endfunction()
 896
 897 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 898 function(add_lit_testsuite target comment)
 899   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 900
 901   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 902   if(NOT EXCLUDE_FROM_ALL)
 903     # Register the testsuites, params and depends for the global check rule.
 904     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_UNPARSED_ARGUMENTS})
 905     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 906     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 907     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 908   endif()
 909
 910   # Produce a specific suffixed check rule.
 911   add_lit_target(${target} ${comment}
 912     ${ARG_UNPARSED_ARGUMENTS}
 913     PARAMS ${ARG_PARAMS}
 914     DEPENDS ${ARG_DEPENDS}
 915     ARGS ${ARG_ARGS}
 916     )
 917 endfunction()
 918
 919 function(add_lit_testsuites project directory)
 920   if (NOT CMAKE_CONFIGURATION_TYPES)
 921     cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 922     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
 923     set(lit_suites)
 924     foreach(f ${litCfg})
 925       get_filename_component(dir ${f} DIRECTORY)
 926       set(lit_suites ${lit_suites} ${dir})
 927     endforeach()
 928     list(REMOVE_DUPLICATES lit_suites)
 929     foreach(dir ${lit_suites})
 930       string(REPLACE ${directory} "" name_slash ${dir})
 931       if (name_slash)
 932         string(REPLACE "/" "-" name_slash ${name_slash})
 933         string(REPLACE "\\" "-" name_dashes ${name_slash})
 934         string(TOLOWER "${project}${name_dashes}" name_var)
 935         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
 936           ${dir}
 937           PARAMS ${ARG_PARAMS}
 938           DEPENDS ${ARG_DEPENDS}
 939           ARGS ${ARG_ARGS}
 940         )
 941       endif()
 942     endforeach()
 943   endif()
 944 endfunction()