cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckLibraryExists)
   8 include(CheckSymbolExists)
   9 include(CheckFunctionExists)
  10 include(CheckCXXSourceCompiles)
  11 include(TestBigEndian)
  12
  13 if( UNIX AND NOT BEOS )
  14   # Used by check_symbol_exists:
  15   set(CMAKE_REQUIRED_LIBRARIES m)
  16 endif()
  17
  18 # Helper macros and functions
  19 macro(add_cxx_include result files)
  20   set(${result} "")
  21   foreach (file_name ${files})
  22      set(${result} "${${result}}#include<${file_name}>\n")
  23   endforeach()
  24 endmacro(add_cxx_include files result)
  25
  26 function(check_type_exists type files variable)
  27   add_cxx_include(includes "${files}")
  28   CHECK_CXX_SOURCE_COMPILES("
  29     ${includes} ${type} typeVar;
  30     int main() {
  31         return 0;
  32     }
  33     " ${variable})
  34 endfunction()
  35
  36 # include checks
  37 check_include_file(argz.h HAVE_ARGZ_H)
  38 check_include_file(assert.h HAVE_ASSERT_H)
  39 check_include_file(ctype.h HAVE_CTYPE_H)
  40 check_include_file(dirent.h HAVE_DIRENT_H)
  41 check_include_file(dl.h HAVE_DL_H)
  42 check_include_file(dld.h HAVE_DLD_H)
  43 check_include_file(dlfcn.h HAVE_DLFCN_H)
  44 check_include_file(errno.h HAVE_ERRNO_H)
  45 check_include_file(execinfo.h HAVE_EXECINFO_H)
  46 check_include_file(fcntl.h HAVE_FCNTL_H)
  47 check_include_file(inttypes.h HAVE_INTTYPES_H)
  48 check_include_file(limits.h HAVE_LIMITS_H)
  49 check_include_file(link.h HAVE_LINK_H)
  50 check_include_file(malloc.h HAVE_MALLOC_H)
  51 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  52 check_include_file(memory.h HAVE_MEMORY_H)
  53 check_include_file(ndir.h HAVE_NDIR_H)
  54 if( NOT PURE_WINDOWS )
  55   check_include_file(pthread.h HAVE_PTHREAD_H)
  56 endif()
  57 check_include_file(sanitizer/msan_interface.h HAVE_SANITIZER_MSAN_INTERFACE_H)
  58 check_include_file(setjmp.h HAVE_SETJMP_H)
  59 check_include_file(signal.h HAVE_SIGNAL_H)
  60 check_include_file(stdint.h HAVE_STDINT_H)
  61 check_include_file(stdio.h HAVE_STDIO_H)
  62 check_include_file(stdlib.h HAVE_STDLIB_H)
  63 check_include_file(string.h HAVE_STRING_H)
  64 check_include_file(strings.h HAVE_STRINGS_H)
  65 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  66 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  67 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  68 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  69 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  70 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  71 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  72 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  73 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  74 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  75 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  76 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  77 check_include_file(termios.h HAVE_TERMIOS_H)
  78 check_include_file(unistd.h HAVE_UNISTD_H)
  79 check_include_file(utime.h HAVE_UTIME_H)
  80 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  81 check_include_file(windows.h HAVE_WINDOWS_H)
  82 check_include_file(zlib.h HAVE_ZLIB_H)
  83 check_include_file(fenv.h HAVE_FENV_H)
  84 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  85 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  86
  87 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  88 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  89
  90 # library checks
  91 if( NOT PURE_WINDOWS )
  92   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  93   if (HAVE_LIBPTHREAD)
  94     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  95     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  96     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  97   else()
  98     # this could be Android
  99     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
 100     if (PTHREAD_IN_LIBC)
 101       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
 102       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
 103       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
 104     endif()
 105   endif()
 106   check_library_exists(dl dlopen "" HAVE_LIBDL)
 107   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 108   check_library_exists(z compress2 "" HAVE_LIBZ)
 109 endif()
 110
 111 # function checks
 112 check_symbol_exists(arc4random "stdlib.h" HAVE_ARC4RANDOM)
 113 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 114 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 115 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 116 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 117 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 118 check_symbol_exists(index strings.h HAVE_INDEX)
 119 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 120 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 121 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 122 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 123 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 124 check_symbol_exists(ceilf math.h HAVE_CEILF)
 125 check_symbol_exists(floorf math.h HAVE_FLOORF)
 126 check_symbol_exists(fmodf math.h HAVE_FMODF)
 127 check_symbol_exists(log math.h HAVE_LOG)
 128 check_symbol_exists(log2 math.h HAVE_LOG2)
 129 check_symbol_exists(log10 math.h HAVE_LOG10)
 130 check_symbol_exists(exp math.h HAVE_EXP)
 131 check_symbol_exists(exp2 math.h HAVE_EXP2)
 132 check_symbol_exists(exp10 math.h HAVE_EXP10)
 133 if( HAVE_SETJMP_H )
 134   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 135   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 136   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 137   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 138 endif()
 139 if( HAVE_SYS_UIO_H )
 140   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 141 endif()
 142 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 143 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 144 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 145                     HAVE_MALLOC_ZONE_STATISTICS)
 146 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 147 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 148 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 149 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 150 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 151 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 152 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 153 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 154 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 155 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 156 check_symbol_exists(pread unistd.h HAVE_PREAD)
 157 check_symbol_exists(rindex strings.h HAVE_RINDEX)
 158 check_symbol_exists(strchr string.h HAVE_STRCHR)
 159 check_symbol_exists(strcmp string.h HAVE_STRCMP)
 160 check_symbol_exists(strdup string.h HAVE_STRDUP)
 161 check_symbol_exists(strrchr string.h HAVE_STRRCHR)
 162 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 163 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 164 if( HAVE_RAND48_SRAND48 )
 165   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 166   if( HAVE_RAND48_LRAND48 )
 167     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 168     if( HAVE_RAND48_DRAND48 )
 169       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 170     endif()
 171   endif()
 172 endif()
 173 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 174 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 175 check_symbol_exists(strerror string.h HAVE_STRERROR)
 176 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 177 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 178 check_symbol_exists(memcpy string.h HAVE_MEMCPY)
 179 check_symbol_exists(memmove string.h HAVE_MEMMOVE)
 180 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 181 if( PURE_WINDOWS )
 182   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 183
 184   check_function_exists(_alloca HAVE__ALLOCA)
 185   check_function_exists(__alloca HAVE___ALLOCA)
 186   check_function_exists(__chkstk HAVE___CHKSTK)
 187   check_function_exists(___chkstk HAVE____CHKSTK)
 188
 189   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 190   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 191   check_function_exists(__divdi3 HAVE___DIVDI3)
 192   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 193   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 194   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 195   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 196   check_function_exists(__moddi3 HAVE___MODDI3)
 197   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 198   check_function_exists(__umoddi3 HAVE___UMODDI3)
 199
 200   check_function_exists(__main HAVE___MAIN)
 201   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 202 endif()
 203 if( HAVE_ARGZ_H )
 204   check_symbol_exists(argz_append argz.h HAVE_ARGZ_APPEND)
 205   check_symbol_exists(argz_create_sep argz.h HAVE_ARGZ_CREATE_SEP)
 206   check_symbol_exists(argz_insert argz.h HAVE_ARGZ_INSERT)
 207   check_symbol_exists(argz_next argz.h HAVE_ARGZ_NEXT)
 208   check_symbol_exists(argz_stringify argz.h HAVE_ARGZ_STRINGIFY)
 209 endif()
 210 if( HAVE_DLFCN_H )
 211   if( HAVE_LIBDL )
 212     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 213   endif()
 214   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 215   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 216   if( HAVE_LIBDL )
 217     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 218   endif()
 219 endif()
 220
 221 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 222 if( LLVM_USING_GLIBC )
 223   add_llvm_definitions( -D_GNU_SOURCE )
 224 endif()
 225
 226 set(headers "")
 227 if (HAVE_SYS_TYPES_H)
 228   set(headers ${headers} "sys/types.h")
 229 endif()
 230
 231 if (HAVE_INTTYPES_H)
 232   set(headers ${headers} "inttypes.h")
 233 endif()
 234
 235 if (HAVE_STDINT_H)
 236   set(headers ${headers} "stdint.h")
 237 endif()
 238
 239 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 240 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 241 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 242 check_type_exists(error_t errno.h HAVE_ERROR_T)
 243
 244 # available programs checks
 245 function(llvm_find_program name)
 246   string(TOUPPER ${name} NAME)
 247   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 248   find_program(LLVM_PATH_${NAME} ${name})
 249   mark_as_advanced(LLVM_PATH_${NAME})
 250   if(LLVM_PATH_${NAME})
 251     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 252     mark_as_advanced(HAVE_${NAME})
 253   else(LLVM_PATH_${NAME})
 254     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 255   endif(LLVM_PATH_${NAME})
 256 endfunction()
 257
 258 llvm_find_program(gv)
 259 llvm_find_program(circo)
 260 llvm_find_program(twopi)
 261 llvm_find_program(neato)
 262 llvm_find_program(fdp)
 263 llvm_find_program(dot)
 264 llvm_find_program(dotty)
 265 llvm_find_program(xdot.py)
 266 llvm_find_program(Graphviz)
 267
 268 if( LLVM_ENABLE_FFI )
 269   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 270   if( FFI_INCLUDE_PATH )
 271     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 272     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 273   else()
 274     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 275     if( FFI_INCLUDE_PATH )
 276       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 277       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 278     endif()
 279   endif()
 280
 281   if( NOT FFI_HEADER )
 282     message(FATAL_ERROR "libffi includes are not found.")
 283   endif()
 284
 285   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 286   if( NOT FFI_LIBRARY_PATH )
 287     message(FATAL_ERROR "libffi is not found.")
 288   endif()
 289
 290   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 291   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 292   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 293   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 294   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 295 else()
 296   unset(HAVE_FFI_FFI_H CACHE)
 297   unset(HAVE_FFI_H CACHE)
 298   unset(HAVE_FFI_CALL CACHE)
 299 endif( LLVM_ENABLE_FFI )
 300
 301 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 302 include(CheckAtomic)
 303
 304 if( LLVM_ENABLE_PIC )
 305   set(ENABLE_PIC 1)
 306 else()
 307   set(ENABLE_PIC 0)
 308 endif()
 309
 310 find_package(LibXml2)
 311 if (LIBXML2_FOUND)
 312   set(CLANG_HAVE_LIBXML 1)
 313 endif ()
 314
 315 include(CheckCXXCompilerFlag)
 316
 317 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 318
 319 set(USE_NO_MAYBE_UNINITIALIZED 0)
 320 set(USE_NO_UNINITIALIZED 0)
 321
 322 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 323 # false positives.
 324 if (CMAKE_COMPILER_IS_GNUCXX)
 325   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 326   if (HAS_MAYBE_UNINITIALIZED)
 327     set(USE_NO_MAYBE_UNINITIALIZED 1)
 328   else()
 329     # Only recent versions of gcc make the distinction between -Wuninitialized
 330     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 331     # turn off all uninitialized use warnings.
 332     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 333     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 334   endif()
 335 endif()
 336
 337 include(GetHostTriple)
 338 get_host_triple(LLVM_HOST_TRIPLE)
 339
 340 # By default, we target the host, but this can be overridden at CMake
 341 # invocation time.
 342 set(LLVM_HOSTTRIPLE "${LLVM_HOST_TRIPLE}")
 343
 344 # Determine the native architecture.
 345 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 346 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 347   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 348 endif ()
 349
 350 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 351   set(LLVM_NATIVE_ARCH X86)
 352 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 353   set(LLVM_NATIVE_ARCH X86)
 354 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 355   set(LLVM_NATIVE_ARCH X86)
 356 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 357   set(LLVM_NATIVE_ARCH X86)
 358 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 359   set(LLVM_NATIVE_ARCH Sparc)
 360 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 361   set(LLVM_NATIVE_ARCH PowerPC)
 362 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 363   set(LLVM_NATIVE_ARCH ARM)
 364 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 365   set(LLVM_NATIVE_ARCH Mips)
 366 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 367   set(LLVM_NATIVE_ARCH XCore)
 368 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 369   set(LLVM_NATIVE_ARCH MSP430)
 370 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 371   set(LLVM_NATIVE_ARCH Hexagon)
 372 else ()
 373   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 374 endif ()
 375
 376 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 377 if (NATIVE_ARCH_IDX EQUAL -1)
 378   message(STATUS
 379     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 380 else ()
 381   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 382   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 383   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 384   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 385   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 386
 387   # We don't have an ASM parser for all architectures yet.
 388   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 389     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 390   endif ()
 391
 392   # We don't have an disassembler for all architectures yet.
 393   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 394     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 395   endif ()
 396 endif ()
 397
 398 if( MINGW )
 399   set(HAVE_LIBIMAGEHLP 1)
 400   set(HAVE_LIBPSAPI 1)
 401   # TODO: Check existence of libraries.
 402   #   include(CheckLibraryExists)
 403   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 404 endif( MINGW )
 405
 406 if( MSVC )
 407   set(error_t int)
 408   set(LTDL_SHLIBPATH_VAR "PATH")
 409   set(LTDL_SYSSEARCHPATH "")
 410   set(LTDL_DLOPEN_DEPLIBS 1)
 411   set(SHLIBEXT ".lib")
 412   set(LTDL_OBJDIR "_libs")
 413   set(HAVE_STRTOLL 1)
 414   set(strtoll "_strtoi64")
 415   set(strtoull "_strtoui64")
 416   set(stricmp "_stricmp")
 417   set(strdup "_strdup")
 418 else( MSVC )
 419   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 420   set(LTDL_SYSSEARCHPATH "") # TODO
 421   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 422 endif( MSVC )
 423
 424 if( PURE_WINDOWS )
 425   CHECK_CXX_SOURCE_COMPILES("
 426     #include <windows.h>
 427     #include <imagehlp.h>
 428     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 429     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 430     int main(){return 0;}"
 431     HAVE_ELMCB_PCSTR)
 432   if( HAVE_ELMCB_PCSTR )
 433     set(WIN32_ELMCB_PCSTR "PCSTR")
 434   else()
 435     set(WIN32_ELMCB_PCSTR "PSTR")
 436   endif()
 437 endif( PURE_WINDOWS )
 438
 439 # FIXME: Signal handler return type, currently hardcoded to 'void'
 440 set(RETSIGTYPE void)
 441
 442 if( LLVM_ENABLE_THREADS )
 443   # Check if threading primitives aren't supported on this platform
 444   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 445     set(LLVM_ENABLE_THREADS 0)
 446   endif()
 447 endif()
 448
 449 if( LLVM_ENABLE_THREADS )
 450   message(STATUS "Threads enabled.")
 451 else( LLVM_ENABLE_THREADS )
 452   message(STATUS "Threads disabled.")
 453 endif()
 454
 455 if (LLVM_ENABLE_ZLIB )
 456   # Check if zlib is available in the system.
 457   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 458     set(LLVM_ENABLE_ZLIB 0)
 459   endif()
 460 endif()
 461
 462 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})