cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckIncludeFileCXX)
   8 include(CheckLibraryExists)
   9 include(CheckSymbolExists)
  10 include(CheckFunctionExists)
  11 include(CheckCXXSourceCompiles)
  12 include(TestBigEndian)
  13
  14 include(HandleLLVMStdlib)
  15
  16 if( UNIX AND NOT BEOS )
  17   # Used by check_symbol_exists:
  18   set(CMAKE_REQUIRED_LIBRARIES m)
  19 endif()
  20
  21 # Helper macros and functions
  22 macro(add_cxx_include result files)
  23   set(${result} "")
  24   foreach (file_name ${files})
  25      set(${result} "${${result}}#include<${file_name}>\n")
  26   endforeach()
  27 endmacro(add_cxx_include files result)
  28
  29 function(check_type_exists type files variable)
  30   add_cxx_include(includes "${files}")
  31   CHECK_CXX_SOURCE_COMPILES("
  32     ${includes} ${type} typeVar;
  33     int main() {
  34         return 0;
  35     }
  36     " ${variable})
  37 endfunction()
  38
  39 # include checks
  40 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
  41 check_include_file(dirent.h HAVE_DIRENT_H)
  42 check_include_file(dlfcn.h HAVE_DLFCN_H)
  43 check_include_file(errno.h HAVE_ERRNO_H)
  44 check_include_file(execinfo.h HAVE_EXECINFO_H)
  45 check_include_file(fcntl.h HAVE_FCNTL_H)
  46 check_include_file(inttypes.h HAVE_INTTYPES_H)
  47 check_include_file(limits.h HAVE_LIMITS_H)
  48 check_include_file(malloc.h HAVE_MALLOC_H)
  49 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  50 check_include_file(ndir.h HAVE_NDIR_H)
  51 if( NOT PURE_WINDOWS )
  52   check_include_file(pthread.h HAVE_PTHREAD_H)
  53 endif()
  54 check_include_file(signal.h HAVE_SIGNAL_H)
  55 check_include_file(stdint.h HAVE_STDINT_H)
  56 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  57 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  58 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  59 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  60 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  61 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  62 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  63 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  64 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  65 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  66 check_include_file(termios.h HAVE_TERMIOS_H)
  67 check_include_file(unistd.h HAVE_UNISTD_H)
  68 check_include_file(utime.h HAVE_UTIME_H)
  69 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  70 check_include_file(zlib.h HAVE_ZLIB_H)
  71 check_include_file(fenv.h HAVE_FENV_H)
  72 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  73 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  74
  75 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  76 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  77
  78 # library checks
  79 if( NOT PURE_WINDOWS )
  80   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  81   if (HAVE_LIBPTHREAD)
  82     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  83     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  84     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  85   else()
  86     # this could be Android
  87     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  88     if (PTHREAD_IN_LIBC)
  89       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  90       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  91       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  92     endif()
  93   endif()
  94   check_library_exists(dl dlopen "" HAVE_LIBDL)
  95   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
  96   if (LLVM_ENABLE_ZLIB)
  97     check_library_exists(z compress2 "" HAVE_LIBZ)
  98   else()
  99     set(HAVE_LIBZ 0)
 100   endif()
 101   check_library_exists(edit el_init "" HAVE_LIBEDIT)
 102   if(LLVM_ENABLE_TERMINFO)
 103     set(HAVE_TERMINFO 0)
 104     foreach(library tinfo terminfo curses ncurses ncursesw)
 105       string(TOUPPER ${library} library_suffix)
 106       check_library_exists(${library} setupterm "" HAVE_TERMINFO_${library_suffix})
 107       if(HAVE_TERMINFO_${library_suffix})
 108         set(HAVE_TERMINFO 1)
 109         set(TERMINFO_LIBS "${library}")
 110         break()
 111       endif()
 112     endforeach()
 113   else()
 114     set(HAVE_TERMINFO 0)
 115   endif()
 116 endif()
 117
 118 # function checks
 119 check_symbol_exists(arc4random "stdlib.h" HAVE_DECL_ARC4RANDOM)
 120 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 121 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 122 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 123 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 124 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 125 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 126 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 127 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 128 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 129 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 130 check_symbol_exists(ceilf math.h HAVE_CEILF)
 131 check_symbol_exists(floorf math.h HAVE_FLOORF)
 132 check_symbol_exists(fmodf math.h HAVE_FMODF)
 133 check_symbol_exists(log math.h HAVE_LOG)
 134 check_symbol_exists(log2 math.h HAVE_LOG2)
 135 check_symbol_exists(log10 math.h HAVE_LOG10)
 136 check_symbol_exists(exp math.h HAVE_EXP)
 137 check_symbol_exists(exp2 math.h HAVE_EXP2)
 138 check_symbol_exists(exp10 math.h HAVE_EXP10)
 139 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 140 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 141 if( HAVE_SETJMP_H )
 142   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 143   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 144   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 145   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 146 endif()
 147 if( HAVE_SYS_UIO_H )
 148   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 149 endif()
 150 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 151 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 152 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 153                     HAVE_MALLOC_ZONE_STATISTICS)
 154 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 155 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 156 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 157 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 158 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 159 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 160 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 161 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 162 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 163 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 164 check_symbol_exists(pread unistd.h HAVE_PREAD)
 165 check_symbol_exists(realpath stdlib.h HAVE_REALPATH)
 166 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 167 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 168 if( HAVE_RAND48_SRAND48 )
 169   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 170   if( HAVE_RAND48_LRAND48 )
 171     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 172     if( HAVE_RAND48_DRAND48 )
 173       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 174     endif()
 175   endif()
 176 endif()
 177 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 178 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 179 check_symbol_exists(strerror string.h HAVE_STRERROR)
 180 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 181 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 182 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 183 if( PURE_WINDOWS )
 184   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 185
 186   check_function_exists(_alloca HAVE__ALLOCA)
 187   check_function_exists(__alloca HAVE___ALLOCA)
 188   check_function_exists(__chkstk HAVE___CHKSTK)
 189   check_function_exists(___chkstk HAVE____CHKSTK)
 190
 191   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 192   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 193   check_function_exists(__divdi3 HAVE___DIVDI3)
 194   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 195   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 196   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 197   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 198   check_function_exists(__moddi3 HAVE___MODDI3)
 199   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 200   check_function_exists(__umoddi3 HAVE___UMODDI3)
 201
 202   check_function_exists(__main HAVE___MAIN)
 203   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 204 endif()
 205 if( HAVE_DLFCN_H )
 206   if( HAVE_LIBDL )
 207     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 208   endif()
 209   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 210   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 211   if( HAVE_LIBDL )
 212     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 213   endif()
 214 endif()
 215
 216 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 217 if( LLVM_USING_GLIBC )
 218   add_llvm_definitions( -D_GNU_SOURCE )
 219 endif()
 220
 221 set(headers "sys/types.h")
 222
 223 if (HAVE_INTTYPES_H)
 224   set(headers ${headers} "inttypes.h")
 225 endif()
 226
 227 if (HAVE_STDINT_H)
 228   set(headers ${headers} "stdint.h")
 229 endif()
 230
 231 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 232 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 233 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 234
 235 # available programs checks
 236 function(llvm_find_program name)
 237   string(TOUPPER ${name} NAME)
 238   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 239
 240   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 241   mark_as_advanced(LLVM_PATH_${NAME})
 242   if(LLVM_PATH_${NAME})
 243     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 244     mark_as_advanced(HAVE_${NAME})
 245   else(LLVM_PATH_${NAME})
 246     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 247   endif(LLVM_PATH_${NAME})
 248 endfunction()
 249
 250 llvm_find_program(gv)
 251 llvm_find_program(circo)
 252 llvm_find_program(twopi)
 253 llvm_find_program(neato)
 254 llvm_find_program(fdp)
 255 llvm_find_program(dot)
 256 llvm_find_program(dotty)
 257 llvm_find_program(xdot xdot.py)
 258 llvm_find_program(Graphviz)
 259
 260 if( LLVM_ENABLE_FFI )
 261   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 262   if( FFI_INCLUDE_PATH )
 263     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 264     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 265   else()
 266     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 267     if( FFI_INCLUDE_PATH )
 268       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 269       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 270     endif()
 271   endif()
 272
 273   if( NOT FFI_HEADER )
 274     message(FATAL_ERROR "libffi includes are not found.")
 275   endif()
 276
 277   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 278   if( NOT FFI_LIBRARY_PATH )
 279     message(FATAL_ERROR "libffi is not found.")
 280   endif()
 281
 282   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 283   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 284   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 285   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 286   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 287 else()
 288   unset(HAVE_FFI_FFI_H CACHE)
 289   unset(HAVE_FFI_H CACHE)
 290   unset(HAVE_FFI_CALL CACHE)
 291 endif( LLVM_ENABLE_FFI )
 292
 293 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 294 include(CheckAtomic)
 295
 296 if( LLVM_ENABLE_PIC )
 297   set(ENABLE_PIC 1)
 298 else()
 299   set(ENABLE_PIC 0)
 300 endif()
 301
 302 find_package(LibXml2)
 303 if (LIBXML2_FOUND)
 304   set(CLANG_HAVE_LIBXML 1)
 305   # When cross-compiling, liblzma is not detected as a dependency for libxml2,
 306   # which makes linking c-index-test fail. But for native builds, all libraries
 307   # are installed and checked by CMake before Makefiles are generated and everything
 308   # works according to the plan. However, if a -llzma is added to native builds,
 309   # an additional requirement on the static liblzma.a is required, but will not
 310   # be checked by CMake, breaking native compilation.
 311   # Since this is only pertinent to cross-compilations, and there's no way CMake
 312   # can check for every foreign library on every OS, we add the dep and warn the dev.
 313   if ( CMAKE_CROSSCOMPILING )
 314     if (NOT PC_LIBXML_VERSION VERSION_LESS "2.8.0")
 315       message(STATUS "Adding LZMA as a dep to XML2 for cross-compilation, make sure liblzma.a is available.")
 316       set(LIBXML2_LIBRARIES ${LIBXML2_LIBRARIES} "-llzma")
 317     endif ()
 318   endif ()
 319 endif ()
 320
 321 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 322
 323 set(USE_NO_MAYBE_UNINITIALIZED 0)
 324 set(USE_NO_UNINITIALIZED 0)
 325
 326 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 327 # false positives.
 328 if (CMAKE_COMPILER_IS_GNUCXX)
 329   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 330   if (HAS_MAYBE_UNINITIALIZED)
 331     set(USE_NO_MAYBE_UNINITIALIZED 1)
 332   else()
 333     # Only recent versions of gcc make the distinction between -Wuninitialized
 334     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 335     # turn off all uninitialized use warnings.
 336     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 337     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 338   endif()
 339 endif()
 340
 341 # By default, we target the host, but this can be overridden at CMake
 342 # invocation time.
 343 include(GetHostTriple)
 344 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 345
 346 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 347     "Host on which LLVM binaries will run")
 348
 349 # Determine the native architecture.
 350 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 351 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 352   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 353 endif ()
 354
 355 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 356   set(LLVM_NATIVE_ARCH X86)
 357 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 358   set(LLVM_NATIVE_ARCH X86)
 359 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 360   set(LLVM_NATIVE_ARCH X86)
 361 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 362   set(LLVM_NATIVE_ARCH X86)
 363 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 364   set(LLVM_NATIVE_ARCH Sparc)
 365 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 366   set(LLVM_NATIVE_ARCH PowerPC)
 367 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 368   set(LLVM_NATIVE_ARCH AArch64)
 369 elseif (LLVM_NATIVE_ARCH MATCHES "arm64")
 370   set(LLVM_NATIVE_ARCH ARM64)
 371 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 372   set(LLVM_NATIVE_ARCH ARM)
 373 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 374   set(LLVM_NATIVE_ARCH Mips)
 375 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 376   set(LLVM_NATIVE_ARCH XCore)
 377 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 378   set(LLVM_NATIVE_ARCH MSP430)
 379 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 380   set(LLVM_NATIVE_ARCH Hexagon)
 381 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 382   set(LLVM_NATIVE_ARCH SystemZ)
 383 else ()
 384   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 385 endif ()
 386
 387 # If build targets includes "host", then replace with native architecture.
 388 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
 389 if( NOT idx LESS 0 )
 390   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 391   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 392   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 393 endif()
 394
 395 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 396 if (NATIVE_ARCH_IDX EQUAL -1)
 397   message(STATUS
 398     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 399 else ()
 400   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 401   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 402   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 403   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 404   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 405
 406   # We don't have an ASM parser for all architectures yet.
 407   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 408     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 409   endif ()
 410
 411   # We don't have an disassembler for all architectures yet.
 412   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 413     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 414   endif ()
 415 endif ()
 416
 417 if( MINGW )
 418   set(HAVE_LIBIMAGEHLP 1)
 419   set(HAVE_LIBPSAPI 1)
 420   set(HAVE_LIBSHELL32 1)
 421   # TODO: Check existence of libraries.
 422   #   include(CheckLibraryExists)
 423   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 424 endif( MINGW )
 425
 426 if (NOT HAVE_STRTOLL)
 427   # Use _strtoi64 if strtoll is not available.
 428   check_symbol_exists(_strtoi64 stdlib.h have_strtoi64)
 429   if (have_strtoi64)
 430     set(HAVE_STRTOLL 1)
 431     set(strtoll "_strtoi64")
 432     set(strtoull "_strtoui64")
 433   endif ()
 434 endif ()
 435
 436 if( MSVC )
 437   set(SHLIBEXT ".lib")
 438   set(stricmp "_stricmp")
 439   set(strdup "_strdup")
 440 endif( MSVC )
 441
 442 if( PURE_WINDOWS )
 443   CHECK_CXX_SOURCE_COMPILES("
 444     #include <windows.h>
 445     #include <imagehlp.h>
 446     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 447     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 448     int main(){return 0;}"
 449     HAVE_ELMCB_PCSTR)
 450   if( HAVE_ELMCB_PCSTR )
 451     set(WIN32_ELMCB_PCSTR "PCSTR")
 452   else()
 453     set(WIN32_ELMCB_PCSTR "PSTR")
 454   endif()
 455 endif( PURE_WINDOWS )
 456
 457 # FIXME: Signal handler return type, currently hardcoded to 'void'
 458 set(RETSIGTYPE void)
 459
 460 if( LLVM_ENABLE_THREADS )
 461   # Check if threading primitives aren't supported on this platform
 462   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 463     set(LLVM_ENABLE_THREADS 0)
 464   endif()
 465 endif()
 466
 467 if( LLVM_ENABLE_THREADS )
 468   message(STATUS "Threads enabled.")
 469 else( LLVM_ENABLE_THREADS )
 470   message(STATUS "Threads disabled.")
 471 endif()
 472
 473 if (LLVM_ENABLE_ZLIB )
 474   # Check if zlib is available in the system.
 475   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 476     set(LLVM_ENABLE_ZLIB 0)
 477   endif()
 478 endif()
 479
 480 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})
 481
 482 if (LLVM_ENABLE_DOXYGEN)
 483   message(STATUS "Doxygen enabled.")
 484   find_package(Doxygen)
 485
 486   if (DOXYGEN_FOUND)
 487     # If we find doxygen and we want to enable doxygen by default create a
 488     # global aggregate doxygen target for generating llvm and any/all
 489     # subprojects doxygen documentation.
 490     if (LLVM_BUILD_DOCS)
 491       add_custom_target(doxygen ALL)
 492     endif()
 493
 494     option(LLVM_DOXYGEN_EXTERNAL_SEARCH "Enable doxygen external search." OFF)
 495     if (LLVM_DOXYGEN_EXTERNAL_SEARCH)
 496       set(LLVM_DOXYGEN_SEARCHENGINE_URL "" CACHE STRING "URL to use for external searhc.")
 497       set(LLVM_DOXYGEN_SEARCH_MAPPINGS "" CACHE STRING "Doxygen Search Mappings")
 498     endif()
 499   endif()
 500 else()
 501   message(STATUS "Doxygen disabled.")
 502 endif()