cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckIncludeFileCXX)
   8 include(CheckLibraryExists)
   9 include(CheckSymbolExists)
  10 include(CheckFunctionExists)
  11 include(CheckCXXSourceCompiles)
  12 include(TestBigEndian)
  13
  14 include(HandleLLVMStdlib)
  15
  16 if( UNIX AND NOT BEOS )
  17   # Used by check_symbol_exists:
  18   set(CMAKE_REQUIRED_LIBRARIES m)
  19 endif()
  20 # x86_64 FreeBSD 9.2 requires libcxxrt to be specified explicitly.
  21 if( CMAKE_SYSTEM MATCHES "FreeBSD-9.2-RELEASE" AND
  22     CMAKE_SIZEOF_VOID_P EQUAL 8 )
  23   list(APPEND CMAKE_REQUIRED_LIBRARIES "cxxrt")
  24 endif()
  25
  26 # Helper macros and functions
  27 macro(add_cxx_include result files)
  28   set(${result} "")
  29   foreach (file_name ${files})
  30      set(${result} "${${result}}#include<${file_name}>\n")
  31   endforeach()
  32 endmacro(add_cxx_include files result)
  33
  34 function(check_type_exists type files variable)
  35   add_cxx_include(includes "${files}")
  36   CHECK_CXX_SOURCE_COMPILES("
  37     ${includes} ${type} typeVar;
  38     int main() {
  39         return 0;
  40     }
  41     " ${variable})
  42 endfunction()
  43
  44 # include checks
  45 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
  46 check_include_file(dirent.h HAVE_DIRENT_H)
  47 check_include_file(dlfcn.h HAVE_DLFCN_H)
  48 check_include_file(errno.h HAVE_ERRNO_H)
  49 check_include_file(execinfo.h HAVE_EXECINFO_H)
  50 check_include_file(fcntl.h HAVE_FCNTL_H)
  51 check_include_file(inttypes.h HAVE_INTTYPES_H)
  52 check_include_file(limits.h HAVE_LIMITS_H)
  53 check_include_file(malloc.h HAVE_MALLOC_H)
  54 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  55 check_include_file(ndir.h HAVE_NDIR_H)
  56 if( NOT PURE_WINDOWS )
  57   check_include_file(pthread.h HAVE_PTHREAD_H)
  58 endif()
  59 check_include_file(signal.h HAVE_SIGNAL_H)
  60 check_include_file(stdint.h HAVE_STDINT_H)
  61 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  62 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  63 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  64 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  65 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  66 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  67 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  68 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  69 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  70 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  71 check_include_file(termios.h HAVE_TERMIOS_H)
  72 check_include_file(unistd.h HAVE_UNISTD_H)
  73 check_include_file(utime.h HAVE_UTIME_H)
  74 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  75 check_include_file(zlib.h HAVE_ZLIB_H)
  76 check_include_file(fenv.h HAVE_FENV_H)
  77 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  78 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  79
  80 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  81 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  82
  83 # library checks
  84 if( NOT PURE_WINDOWS )
  85   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  86   if (HAVE_LIBPTHREAD)
  87     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  88     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  89     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  90   else()
  91     # this could be Android
  92     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  93     if (PTHREAD_IN_LIBC)
  94       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  95       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  96       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  97     endif()
  98   endif()
  99   check_library_exists(dl dlopen "" HAVE_LIBDL)
 100   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 101   if (LLVM_ENABLE_ZLIB)
 102     check_library_exists(z compress2 "" HAVE_LIBZ)
 103   else()
 104     set(HAVE_LIBZ 0)
 105   endif()
 106   check_library_exists(edit el_init "" HAVE_LIBEDIT)
 107   if(LLVM_ENABLE_TERMINFO)
 108     set(HAVE_TERMINFO 0)
 109     foreach(library tinfo terminfo curses ncurses ncursesw)
 110       string(TOUPPER ${library} library_suffix)
 111       check_library_exists(${library} setupterm "" HAVE_TERMINFO_${library_suffix})
 112       if(HAVE_TERMINFO_${library_suffix})
 113         set(HAVE_TERMINFO 1)
 114         set(TERMINFO_LIBS "${library}")
 115         break()
 116       endif()
 117     endforeach()
 118   else()
 119     set(HAVE_TERMINFO 0)
 120   endif()
 121 endif()
 122
 123 # function checks
 124 check_symbol_exists(arc4random "stdlib.h" HAVE_DECL_ARC4RANDOM)
 125 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 126 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 127 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 128 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 129 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 130 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 131 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 132 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 133 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 134 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 135 check_symbol_exists(ceilf math.h HAVE_CEILF)
 136 check_symbol_exists(floorf math.h HAVE_FLOORF)
 137 check_symbol_exists(fmodf math.h HAVE_FMODF)
 138 check_symbol_exists(log math.h HAVE_LOG)
 139 check_symbol_exists(log2 math.h HAVE_LOG2)
 140 check_symbol_exists(log10 math.h HAVE_LOG10)
 141 check_symbol_exists(exp math.h HAVE_EXP)
 142 check_symbol_exists(exp2 math.h HAVE_EXP2)
 143 check_symbol_exists(exp10 math.h HAVE_EXP10)
 144 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 145 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 146 if( HAVE_SETJMP_H )
 147   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 148   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 149   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 150   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 151 endif()
 152 if( HAVE_SYS_UIO_H )
 153   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 154 endif()
 155 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 156 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 157 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 158                     HAVE_MALLOC_ZONE_STATISTICS)
 159 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 160 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 161 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 162 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 163 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 164 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 165 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 166 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 167 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 168 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 169 check_symbol_exists(pread unistd.h HAVE_PREAD)
 170 check_symbol_exists(realpath stdlib.h HAVE_REALPATH)
 171 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 172 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 173 if( HAVE_RAND48_SRAND48 )
 174   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 175   if( HAVE_RAND48_LRAND48 )
 176     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 177     if( HAVE_RAND48_DRAND48 )
 178       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 179     endif()
 180   endif()
 181 endif()
 182 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 183 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 184 check_symbol_exists(strerror string.h HAVE_STRERROR)
 185 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 186 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 187 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 188 if( PURE_WINDOWS )
 189   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 190
 191   check_function_exists(_alloca HAVE__ALLOCA)
 192   check_function_exists(__alloca HAVE___ALLOCA)
 193   check_function_exists(__chkstk HAVE___CHKSTK)
 194   check_function_exists(___chkstk HAVE____CHKSTK)
 195
 196   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 197   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 198   check_function_exists(__divdi3 HAVE___DIVDI3)
 199   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 200   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 201   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 202   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 203   check_function_exists(__moddi3 HAVE___MODDI3)
 204   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 205   check_function_exists(__umoddi3 HAVE___UMODDI3)
 206
 207   check_function_exists(__main HAVE___MAIN)
 208   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 209 endif()
 210 if( HAVE_DLFCN_H )
 211   if( HAVE_LIBDL )
 212     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 213   endif()
 214   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 215   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 216   if( HAVE_LIBDL )
 217     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 218   endif()
 219 endif()
 220
 221 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 222 if( LLVM_USING_GLIBC )
 223   add_llvm_definitions( -D_GNU_SOURCE )
 224 endif()
 225
 226 set(headers "sys/types.h")
 227
 228 if (HAVE_INTTYPES_H)
 229   set(headers ${headers} "inttypes.h")
 230 endif()
 231
 232 if (HAVE_STDINT_H)
 233   set(headers ${headers} "stdint.h")
 234 endif()
 235
 236 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 237 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 238 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 239
 240 # available programs checks
 241 function(llvm_find_program name)
 242   string(TOUPPER ${name} NAME)
 243   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 244
 245   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 246   mark_as_advanced(LLVM_PATH_${NAME})
 247   if(LLVM_PATH_${NAME})
 248     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 249     mark_as_advanced(HAVE_${NAME})
 250   else(LLVM_PATH_${NAME})
 251     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 252   endif(LLVM_PATH_${NAME})
 253 endfunction()
 254
 255 llvm_find_program(gv)
 256 llvm_find_program(circo)
 257 llvm_find_program(twopi)
 258 llvm_find_program(neato)
 259 llvm_find_program(fdp)
 260 llvm_find_program(dot)
 261 llvm_find_program(dotty)
 262 llvm_find_program(xdot xdot.py)
 263 llvm_find_program(Graphviz)
 264
 265 if( LLVM_ENABLE_FFI )
 266   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 267   if( FFI_INCLUDE_PATH )
 268     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 269     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 270   else()
 271     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 272     if( FFI_INCLUDE_PATH )
 273       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 274       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 275     endif()
 276   endif()
 277
 278   if( NOT FFI_HEADER )
 279     message(FATAL_ERROR "libffi includes are not found.")
 280   endif()
 281
 282   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 283   if( NOT FFI_LIBRARY_PATH )
 284     message(FATAL_ERROR "libffi is not found.")
 285   endif()
 286
 287   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 288   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 289   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 290   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 291   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 292 else()
 293   unset(HAVE_FFI_FFI_H CACHE)
 294   unset(HAVE_FFI_H CACHE)
 295   unset(HAVE_FFI_CALL CACHE)
 296 endif( LLVM_ENABLE_FFI )
 297
 298 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 299 include(CheckAtomic)
 300
 301 if( LLVM_ENABLE_PIC )
 302   set(ENABLE_PIC 1)
 303 else()
 304   set(ENABLE_PIC 0)
 305 endif()
 306
 307 find_package(LibXml2)
 308 if (LIBXML2_FOUND)
 309   set(CLANG_HAVE_LIBXML 1)
 310   # When cross-compiling, liblzma is not detected as a dependency for libxml2,
 311   # which makes linking c-index-test fail. But for native builds, all libraries
 312   # are installed and checked by CMake before Makefiles are generated and everything
 313   # works according to the plan. However, if a -llzma is added to native builds,
 314   # an additional requirement on the static liblzma.a is required, but will not
 315   # be checked by CMake, breaking native compilation.
 316   # Since this is only pertinent to cross-compilations, and there's no way CMake
 317   # can check for every foreign library on every OS, we add the dep and warn the dev.
 318   if ( CMAKE_CROSSCOMPILING )
 319     if (NOT PC_LIBXML_VERSION VERSION_LESS "2.8.0")
 320       message(STATUS "Adding LZMA as a dep to XML2 for cross-compilation, make sure liblzma.a is available.")
 321       set(LIBXML2_LIBRARIES ${LIBXML2_LIBRARIES} "-llzma")
 322     endif ()
 323   endif ()
 324 endif ()
 325
 326 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 327
 328 set(USE_NO_MAYBE_UNINITIALIZED 0)
 329 set(USE_NO_UNINITIALIZED 0)
 330
 331 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 332 # false positives.
 333 if (CMAKE_COMPILER_IS_GNUCXX)
 334   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 335   if (HAS_MAYBE_UNINITIALIZED)
 336     set(USE_NO_MAYBE_UNINITIALIZED 1)
 337   else()
 338     # Only recent versions of gcc make the distinction between -Wuninitialized
 339     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 340     # turn off all uninitialized use warnings.
 341     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 342     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 343   endif()
 344 endif()
 345
 346 # By default, we target the host, but this can be overridden at CMake
 347 # invocation time.
 348 include(GetHostTriple)
 349 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 350
 351 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 352     "Host on which LLVM binaries will run")
 353
 354 # Determine the native architecture.
 355 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 356 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 357   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 358 endif ()
 359
 360 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 361   set(LLVM_NATIVE_ARCH X86)
 362 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 363   set(LLVM_NATIVE_ARCH X86)
 364 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 365   set(LLVM_NATIVE_ARCH X86)
 366 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 367   set(LLVM_NATIVE_ARCH X86)
 368 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 369   set(LLVM_NATIVE_ARCH Sparc)
 370 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 371   set(LLVM_NATIVE_ARCH PowerPC)
 372 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 373   set(LLVM_NATIVE_ARCH AArch64)
 374 elseif (LLVM_NATIVE_ARCH MATCHES "arm64")
 375   set(LLVM_NATIVE_ARCH ARM64)
 376 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 377   set(LLVM_NATIVE_ARCH ARM)
 378 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 379   set(LLVM_NATIVE_ARCH Mips)
 380 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 381   set(LLVM_NATIVE_ARCH XCore)
 382 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 383   set(LLVM_NATIVE_ARCH MSP430)
 384 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 385   set(LLVM_NATIVE_ARCH Hexagon)
 386 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 387   set(LLVM_NATIVE_ARCH SystemZ)
 388 else ()
 389   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 390 endif ()
 391
 392 # If build targets includes "host", then replace with native architecture.
 393 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
 394 if( NOT idx LESS 0 )
 395   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 396   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 397   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 398 endif()
 399
 400 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 401 if (NATIVE_ARCH_IDX EQUAL -1)
 402   message(STATUS
 403     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 404 else ()
 405   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 406   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 407   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 408   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 409   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 410
 411   # We don't have an ASM parser for all architectures yet.
 412   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 413     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 414   endif ()
 415
 416   # We don't have an disassembler for all architectures yet.
 417   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 418     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 419   endif ()
 420 endif ()
 421
 422 if( MINGW )
 423   set(HAVE_LIBIMAGEHLP 1)
 424   set(HAVE_LIBPSAPI 1)
 425   set(HAVE_LIBSHELL32 1)
 426   # TODO: Check existence of libraries.
 427   #   include(CheckLibraryExists)
 428   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 429 endif( MINGW )
 430
 431 if (NOT HAVE_STRTOLL)
 432   # Use _strtoi64 if strtoll is not available.
 433   check_symbol_exists(_strtoi64 stdlib.h have_strtoi64)
 434   if (have_strtoi64)
 435     set(HAVE_STRTOLL 1)
 436     set(strtoll "_strtoi64")
 437     set(strtoull "_strtoui64")
 438   endif ()
 439 endif ()
 440
 441 if( MSVC )
 442   set(SHLIBEXT ".lib")
 443   set(stricmp "_stricmp")
 444   set(strdup "_strdup")
 445 endif( MSVC )
 446
 447 if( PURE_WINDOWS )
 448   CHECK_CXX_SOURCE_COMPILES("
 449     #include <windows.h>
 450     #include <imagehlp.h>
 451     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 452     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 453     int main(){return 0;}"
 454     HAVE_ELMCB_PCSTR)
 455   if( HAVE_ELMCB_PCSTR )
 456     set(WIN32_ELMCB_PCSTR "PCSTR")
 457   else()
 458     set(WIN32_ELMCB_PCSTR "PSTR")
 459   endif()
 460 endif( PURE_WINDOWS )
 461
 462 # FIXME: Signal handler return type, currently hardcoded to 'void'
 463 set(RETSIGTYPE void)
 464
 465 if( LLVM_ENABLE_THREADS )
 466   # Check if threading primitives aren't supported on this platform
 467   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 468     set(LLVM_ENABLE_THREADS 0)
 469   endif()
 470 endif()
 471
 472 if( LLVM_ENABLE_THREADS )
 473   message(STATUS "Threads enabled.")
 474 else( LLVM_ENABLE_THREADS )
 475   message(STATUS "Threads disabled.")
 476 endif()
 477
 478 if (LLVM_ENABLE_ZLIB )
 479   # Check if zlib is available in the system.
 480   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 481     set(LLVM_ENABLE_ZLIB 0)
 482   endif()
 483 endif()
 484
 485 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})
 486
 487 if (LLVM_ENABLE_DOXYGEN)
 488   message(STATUS "Doxygen enabled.")
 489   find_package(Doxygen REQUIRED)
 490
 491   if (DOXYGEN_FOUND)
 492     # If we find doxygen and we want to enable doxygen by default create a
 493     # global aggregate doxygen target for generating llvm and any/all
 494     # subprojects doxygen documentation.
 495     if (LLVM_BUILD_DOCS)
 496       add_custom_target(doxygen ALL)
 497     endif()
 498
 499     option(LLVM_DOXYGEN_EXTERNAL_SEARCH "Enable doxygen external search." OFF)
 500     if (LLVM_DOXYGEN_EXTERNAL_SEARCH)
 501       set(LLVM_DOXYGEN_SEARCHENGINE_URL "" CACHE STRING "URL to use for external searhc.")
 502       set(LLVM_DOXYGEN_SEARCH_MAPPINGS "" CACHE STRING "Doxygen Search Mappings")
 503     endif()
 504   endif()
 505 else()
 506   message(STATUS "Doxygen disabled.")
 507 endif()
 508
 509 if (LLVM_ENABLE_SPHINX)
 510   message(STATUS "Sphinx enabled.")
 511   find_package(Sphinx REQUIRED)
 512   if (LLVM_BUILD_DOCS)
 513     add_custom_target(sphinx ALL)
 514   endif()
 515 else()
 516   message(STATUS "Sphinx disabled.")
 517 endif()