cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckIncludeFileCXX)
   8 include(CheckLibraryExists)
   9 include(CheckSymbolExists)
  10 include(CheckFunctionExists)
  11 include(CheckCXXSourceCompiles)
  12 include(TestBigEndian)
  13
  14 if( UNIX AND NOT BEOS )
  15   # Used by check_symbol_exists:
  16   set(CMAKE_REQUIRED_LIBRARIES m)
  17 endif()
  18
  19 # Helper macros and functions
  20 macro(add_cxx_include result files)
  21   set(${result} "")
  22   foreach (file_name ${files})
  23      set(${result} "${${result}}#include<${file_name}>\n")
  24   endforeach()
  25 endmacro(add_cxx_include files result)
  26
  27 function(check_type_exists type files variable)
  28   add_cxx_include(includes "${files}")
  29   CHECK_CXX_SOURCE_COMPILES("
  30     ${includes} ${type} typeVar;
  31     int main() {
  32         return 0;
  33     }
  34     " ${variable})
  35 endfunction()
  36
  37 # include checks
  38 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
  39 check_include_file(dirent.h HAVE_DIRENT_H)
  40 check_include_file(dlfcn.h HAVE_DLFCN_H)
  41 check_include_file(errno.h HAVE_ERRNO_H)
  42 check_include_file(execinfo.h HAVE_EXECINFO_H)
  43 check_include_file(fcntl.h HAVE_FCNTL_H)
  44 check_include_file(inttypes.h HAVE_INTTYPES_H)
  45 check_include_file(limits.h HAVE_LIMITS_H)
  46 check_include_file(malloc.h HAVE_MALLOC_H)
  47 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  48 check_include_file(ndir.h HAVE_NDIR_H)
  49 if( NOT PURE_WINDOWS )
  50   check_include_file(pthread.h HAVE_PTHREAD_H)
  51 endif()
  52 check_include_file(sanitizer/msan_interface.h HAVE_SANITIZER_MSAN_INTERFACE_H)
  53 check_include_file(signal.h HAVE_SIGNAL_H)
  54 check_include_file(stdint.h HAVE_STDINT_H)
  55 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  56 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  57 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  58 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  59 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  60 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  61 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  62 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  63 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  64 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  65 check_include_file(termios.h HAVE_TERMIOS_H)
  66 check_include_file(unistd.h HAVE_UNISTD_H)
  67 check_include_file(utime.h HAVE_UTIME_H)
  68 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  69 check_include_file(zlib.h HAVE_ZLIB_H)
  70 check_include_file(fenv.h HAVE_FENV_H)
  71 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  72 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  73
  74 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  75 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  76
  77 # library checks
  78 if( NOT PURE_WINDOWS )
  79   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  80   if (HAVE_LIBPTHREAD)
  81     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  82     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  83     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  84   else()
  85     # this could be Android
  86     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  87     if (PTHREAD_IN_LIBC)
  88       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  89       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  90       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  91     endif()
  92   endif()
  93   check_library_exists(dl dlopen "" HAVE_LIBDL)
  94   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
  95   if (LLVM_ENABLE_ZLIB)
  96     check_library_exists(z compress2 "" HAVE_LIBZ)
  97   else()
  98     set(HAVE_LIBZ 0)
  99   endif()
 100   if(LLVM_ENABLE_TERMINFO)
 101     set(HAVE_TERMINFO 0)
 102     foreach(library tinfo curses ncurses ncursesw)
 103       string(TOUPPER ${library} library_suffix)
 104       check_library_exists(${library} setupterm "" HAVE_TERMINFO_${library_suffix})
 105       if(HAVE_TERMINFO_${library_suffix})
 106         set(HAVE_TERMINFO 1)
 107         set(TERMINFO_LIBS "${library}")
 108         break()
 109       endif()
 110     endforeach()
 111   else()
 112     set(HAVE_TERMINFO 0)
 113   endif()
 114 endif()
 115
 116 # function checks
 117 check_symbol_exists(arc4random "stdlib.h" HAVE_ARC4RANDOM)
 118 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 119 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 120 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 121 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 122 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 123 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 124 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 125 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 126 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 127 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 128 check_symbol_exists(ceilf math.h HAVE_CEILF)
 129 check_symbol_exists(floorf math.h HAVE_FLOORF)
 130 check_symbol_exists(fmodf math.h HAVE_FMODF)
 131 check_symbol_exists(log math.h HAVE_LOG)
 132 check_symbol_exists(log2 math.h HAVE_LOG2)
 133 check_symbol_exists(log10 math.h HAVE_LOG10)
 134 check_symbol_exists(exp math.h HAVE_EXP)
 135 check_symbol_exists(exp2 math.h HAVE_EXP2)
 136 check_symbol_exists(exp10 math.h HAVE_EXP10)
 137 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 138 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 139 if( HAVE_SETJMP_H )
 140   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 141   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 142   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 143   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 144 endif()
 145 if( HAVE_SYS_UIO_H )
 146   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 147 endif()
 148 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 149 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 150 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 151                     HAVE_MALLOC_ZONE_STATISTICS)
 152 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 153 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 154 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 155 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 156 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 157 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 158 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 159 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 160 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 161 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 162 check_symbol_exists(pread unistd.h HAVE_PREAD)
 163 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 164 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 165 if( HAVE_RAND48_SRAND48 )
 166   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 167   if( HAVE_RAND48_LRAND48 )
 168     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 169     if( HAVE_RAND48_DRAND48 )
 170       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 171     endif()
 172   endif()
 173 endif()
 174 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 175 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 176 check_symbol_exists(strerror string.h HAVE_STRERROR)
 177 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 178 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 179 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 180 if( PURE_WINDOWS )
 181   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 182
 183   check_function_exists(_alloca HAVE__ALLOCA)
 184   check_function_exists(__alloca HAVE___ALLOCA)
 185   check_function_exists(__chkstk HAVE___CHKSTK)
 186   check_function_exists(___chkstk HAVE____CHKSTK)
 187
 188   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 189   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 190   check_function_exists(__divdi3 HAVE___DIVDI3)
 191   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 192   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 193   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 194   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 195   check_function_exists(__moddi3 HAVE___MODDI3)
 196   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 197   check_function_exists(__umoddi3 HAVE___UMODDI3)
 198
 199   check_function_exists(__main HAVE___MAIN)
 200   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 201 endif()
 202 if( HAVE_DLFCN_H )
 203   if( HAVE_LIBDL )
 204     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 205   endif()
 206   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 207   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 208   if( HAVE_LIBDL )
 209     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 210   endif()
 211 endif()
 212
 213 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 214 if( LLVM_USING_GLIBC )
 215   add_llvm_definitions( -D_GNU_SOURCE )
 216 endif()
 217
 218 set(headers "sys/types.h")
 219
 220 if (HAVE_INTTYPES_H)
 221   set(headers ${headers} "inttypes.h")
 222 endif()
 223
 224 if (HAVE_STDINT_H)
 225   set(headers ${headers} "stdint.h")
 226 endif()
 227
 228 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 229 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 230 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 231
 232 # available programs checks
 233 function(llvm_find_program name)
 234   string(TOUPPER ${name} NAME)
 235   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 236
 237   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 238   mark_as_advanced(LLVM_PATH_${NAME})
 239   if(LLVM_PATH_${NAME})
 240     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 241     mark_as_advanced(HAVE_${NAME})
 242   else(LLVM_PATH_${NAME})
 243     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 244   endif(LLVM_PATH_${NAME})
 245 endfunction()
 246
 247 llvm_find_program(gv)
 248 llvm_find_program(circo)
 249 llvm_find_program(twopi)
 250 llvm_find_program(neato)
 251 llvm_find_program(fdp)
 252 llvm_find_program(dot)
 253 llvm_find_program(dotty)
 254 llvm_find_program(xdot xdot.py)
 255 llvm_find_program(Graphviz)
 256
 257 if( LLVM_ENABLE_FFI )
 258   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 259   if( FFI_INCLUDE_PATH )
 260     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 261     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 262   else()
 263     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 264     if( FFI_INCLUDE_PATH )
 265       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 266       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 267     endif()
 268   endif()
 269
 270   if( NOT FFI_HEADER )
 271     message(FATAL_ERROR "libffi includes are not found.")
 272   endif()
 273
 274   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 275   if( NOT FFI_LIBRARY_PATH )
 276     message(FATAL_ERROR "libffi is not found.")
 277   endif()
 278
 279   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 280   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 281   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 282   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 283   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 284 else()
 285   unset(HAVE_FFI_FFI_H CACHE)
 286   unset(HAVE_FFI_H CACHE)
 287   unset(HAVE_FFI_CALL CACHE)
 288 endif( LLVM_ENABLE_FFI )
 289
 290 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 291 include(CheckAtomic)
 292
 293 if( LLVM_ENABLE_PIC )
 294   set(ENABLE_PIC 1)
 295 else()
 296   set(ENABLE_PIC 0)
 297 endif()
 298
 299 find_package(LibXml2)
 300 if (LIBXML2_FOUND)
 301   set(CLANG_HAVE_LIBXML 1)
 302 endif ()
 303
 304 include(CheckCXXCompilerFlag)
 305
 306 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 307
 308 set(USE_NO_MAYBE_UNINITIALIZED 0)
 309 set(USE_NO_UNINITIALIZED 0)
 310
 311 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 312 # false positives.
 313 if (CMAKE_COMPILER_IS_GNUCXX)
 314   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 315   if (HAS_MAYBE_UNINITIALIZED)
 316     set(USE_NO_MAYBE_UNINITIALIZED 1)
 317   else()
 318     # Only recent versions of gcc make the distinction between -Wuninitialized
 319     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 320     # turn off all uninitialized use warnings.
 321     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 322     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 323   endif()
 324 endif()
 325
 326 # By default, we target the host, but this can be overridden at CMake
 327 # invocation time.
 328 include(GetHostTriple)
 329 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 330
 331 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 332     "Host on which LLVM binaries will run")
 333
 334 # Determine the native architecture.
 335 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 336 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 337   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 338 endif ()
 339
 340 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 341   set(LLVM_NATIVE_ARCH X86)
 342 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 343   set(LLVM_NATIVE_ARCH X86)
 344 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 345   set(LLVM_NATIVE_ARCH X86)
 346 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 347   set(LLVM_NATIVE_ARCH X86)
 348 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 349   set(LLVM_NATIVE_ARCH Sparc)
 350 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 351   set(LLVM_NATIVE_ARCH PowerPC)
 352 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 353   set(LLVM_NATIVE_ARCH AArch64)
 354 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 355   set(LLVM_NATIVE_ARCH ARM)
 356 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 357   set(LLVM_NATIVE_ARCH Mips)
 358 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 359   set(LLVM_NATIVE_ARCH XCore)
 360 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 361   set(LLVM_NATIVE_ARCH MSP430)
 362 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 363   set(LLVM_NATIVE_ARCH Hexagon)
 364 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 365   set(LLVM_NATIVE_ARCH SystemZ)
 366 else ()
 367   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 368 endif ()
 369
 370 # If build targets includes "host", then replace with native architecture.
 371 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
 372 if( NOT idx LESS 0 )
 373   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 374   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 375   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 376 endif()
 377
 378 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 379 if (NATIVE_ARCH_IDX EQUAL -1)
 380   message(STATUS
 381     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 382 else ()
 383   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 384   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 385   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 386   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 387   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 388
 389   # We don't have an ASM parser for all architectures yet.
 390   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 391     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 392   endif ()
 393
 394   # We don't have an disassembler for all architectures yet.
 395   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 396     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 397   endif ()
 398 endif ()
 399
 400 if( MINGW )
 401   set(HAVE_LIBIMAGEHLP 1)
 402   set(HAVE_LIBPSAPI 1)
 403   # TODO: Check existence of libraries.
 404   #   include(CheckLibraryExists)
 405   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 406 endif( MINGW )
 407
 408 if (NOT HAVE_STRTOLL)
 409   # Use _strtoi64 if strtoll is not available.
 410   check_symbol_exists(_strtoi64 stdlib.h have_strtoi64)
 411   if (have_strtoi64)
 412     set(HAVE_STRTOLL 1)
 413     set(strtoll "_strtoi64")
 414     set(strtoull "_strtoui64")
 415   endif ()
 416 endif ()
 417
 418 if( MSVC )
 419   set(SHLIBEXT ".lib")
 420   set(stricmp "_stricmp")
 421   set(strdup "_strdup")
 422 endif( MSVC )
 423
 424 if( PURE_WINDOWS )
 425   CHECK_CXX_SOURCE_COMPILES("
 426     #include <windows.h>
 427     #include <imagehlp.h>
 428     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 429     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 430     int main(){return 0;}"
 431     HAVE_ELMCB_PCSTR)
 432   if( HAVE_ELMCB_PCSTR )
 433     set(WIN32_ELMCB_PCSTR "PCSTR")
 434   else()
 435     set(WIN32_ELMCB_PCSTR "PSTR")
 436   endif()
 437 endif( PURE_WINDOWS )
 438
 439 # FIXME: Signal handler return type, currently hardcoded to 'void'
 440 set(RETSIGTYPE void)
 441
 442 if( LLVM_ENABLE_THREADS )
 443   # Check if threading primitives aren't supported on this platform
 444   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 445     set(LLVM_ENABLE_THREADS 0)
 446   endif()
 447 endif()
 448
 449 if( LLVM_ENABLE_THREADS )
 450   message(STATUS "Threads enabled.")
 451 else( LLVM_ENABLE_THREADS )
 452   message(STATUS "Threads disabled.")
 453 endif()
 454
 455 if (LLVM_ENABLE_ZLIB )
 456   # Check if zlib is available in the system.
 457   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 458     set(LLVM_ENABLE_ZLIB 0)
 459   endif()
 460 endif()
 461
 462 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})