cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckIncludeFileCXX)
   8 include(CheckLibraryExists)
   9 include(CheckSymbolExists)
  10 include(CheckFunctionExists)
  11 include(CheckCXXSourceCompiles)
  12 include(TestBigEndian)
  13
  14 include(HandleLLVMStdlib)
  15
  16 if( UNIX AND NOT BEOS )
  17   # Used by check_symbol_exists:
  18   set(CMAKE_REQUIRED_LIBRARIES m)
  19 endif()
  20 # x86_64 FreeBSD 9.2 requires libcxxrt to be specified explicitly.
  21 if( CMAKE_SYSTEM MATCHES "FreeBSD-9.2-RELEASE" AND
  22     CMAKE_SIZEOF_VOID_P EQUAL 8 )
  23   list(APPEND CMAKE_REQUIRED_LIBRARIES "cxxrt")
  24 endif()
  25
  26 # Helper macros and functions
  27 macro(add_cxx_include result files)
  28   set(${result} "")
  29   foreach (file_name ${files})
  30      set(${result} "${${result}}#include<${file_name}>\n")
  31   endforeach()
  32 endmacro(add_cxx_include files result)
  33
  34 function(check_type_exists type files variable)
  35   add_cxx_include(includes "${files}")
  36   CHECK_CXX_SOURCE_COMPILES("
  37     ${includes} ${type} typeVar;
  38     int main() {
  39         return 0;
  40     }
  41     " ${variable})
  42 endfunction()
  43
  44 # include checks
  45 check_include_file(dirent.h HAVE_DIRENT_H)
  46 check_include_file(dlfcn.h HAVE_DLFCN_H)
  47 check_include_file(errno.h HAVE_ERRNO_H)
  48 check_include_file(execinfo.h HAVE_EXECINFO_H)
  49 check_include_file(fcntl.h HAVE_FCNTL_H)
  50 check_include_file(inttypes.h HAVE_INTTYPES_H)
  51 check_include_file(limits.h HAVE_LIMITS_H)
  52 check_include_file(link.h HAVE_LINK_H)
  53 check_include_file(malloc.h HAVE_MALLOC_H)
  54 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  55 check_include_file(ndir.h HAVE_NDIR_H)
  56 if( NOT PURE_WINDOWS )
  57   check_include_file(pthread.h HAVE_PTHREAD_H)
  58 endif()
  59 check_include_file(signal.h HAVE_SIGNAL_H)
  60 check_include_file(stdint.h HAVE_STDINT_H)
  61 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  62 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  63 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  64 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  65 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  66 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  67 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  68 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  69 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  70 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  71 check_include_file(termios.h HAVE_TERMIOS_H)
  72 check_include_file(unistd.h HAVE_UNISTD_H)
  73 check_include_file(utime.h HAVE_UTIME_H)
  74 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  75 check_include_file(zlib.h HAVE_ZLIB_H)
  76 check_include_file(fenv.h HAVE_FENV_H)
  77 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  78 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  79
  80 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  81 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  82 check_include_file(histedit.h HAVE_HISTEDIT_H)
  83
  84 # size_t must be defined before including cxxabi.h on FreeBSD 10.0.
  85 check_cxx_source_compiles("
  86 #include <stddef.h>
  87 #include <cxxabi.h>
  88 int main() { return 0; }
  89 " HAVE_CXXABI_H)
  90
  91 # library checks
  92 if( NOT PURE_WINDOWS )
  93   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  94   if (HAVE_LIBPTHREAD)
  95     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  96     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  97     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  98   else()
  99     # this could be Android
 100     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
 101     if (PTHREAD_IN_LIBC)
 102       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
 103       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
 104       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
 105     endif()
 106   endif()
 107   check_library_exists(dl dlopen "" HAVE_LIBDL)
 108   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 109   if (LLVM_ENABLE_ZLIB)
 110     check_library_exists(z compress2 "" HAVE_LIBZ)
 111   else()
 112     set(HAVE_LIBZ 0)
 113   endif()
 114   if (HAVE_HISTEDIT_H)
 115     check_library_exists(edit el_init "" HAVE_LIBEDIT)
 116   endif()
 117   if(LLVM_ENABLE_TERMINFO)
 118     set(HAVE_TERMINFO 0)
 119     foreach(library tinfo terminfo curses ncurses ncursesw)
 120       string(TOUPPER ${library} library_suffix)
 121       check_library_exists(${library} setupterm "" HAVE_TERMINFO_${library_suffix})
 122       if(HAVE_TERMINFO_${library_suffix})
 123         set(HAVE_TERMINFO 1)
 124         set(TERMINFO_LIBS "${library}")
 125         break()
 126       endif()
 127     endforeach()
 128   else()
 129     set(HAVE_TERMINFO 0)
 130   endif()
 131 endif()
 132
 133 # function checks
 134 check_symbol_exists(arc4random "stdlib.h" HAVE_DECL_ARC4RANDOM)
 135 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 136 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 137 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 138 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 139 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 140 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 141 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 142 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 143 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 144 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 145 check_symbol_exists(ceilf math.h HAVE_CEILF)
 146 check_symbol_exists(floorf math.h HAVE_FLOORF)
 147 check_symbol_exists(fmodf math.h HAVE_FMODF)
 148 check_symbol_exists(log math.h HAVE_LOG)
 149 check_symbol_exists(log2 math.h HAVE_LOG2)
 150 check_symbol_exists(log10 math.h HAVE_LOG10)
 151 check_symbol_exists(exp math.h HAVE_EXP)
 152 check_symbol_exists(exp2 math.h HAVE_EXP2)
 153 check_symbol_exists(exp10 math.h HAVE_EXP10)
 154 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 155 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 156 if( HAVE_SETJMP_H )
 157   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 158   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 159   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 160   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 161 endif()
 162 if( HAVE_SYS_UIO_H )
 163   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 164 endif()
 165 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 166 check_symbol_exists(mallctl malloc_np.h HAVE_MALLCTL)
 167 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 168 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 169                     HAVE_MALLOC_ZONE_STATISTICS)
 170 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 171 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 172 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 173 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 174 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 175 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 176 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 177 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 178 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 179 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 180 check_symbol_exists(pread unistd.h HAVE_PREAD)
 181 check_symbol_exists(realpath stdlib.h HAVE_REALPATH)
 182 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 183 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 184 if( HAVE_RAND48_SRAND48 )
 185   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 186   if( HAVE_RAND48_LRAND48 )
 187     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 188     if( HAVE_RAND48_DRAND48 )
 189       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 190     endif()
 191   endif()
 192 endif()
 193 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 194 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 195 check_symbol_exists(strerror string.h HAVE_STRERROR)
 196 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 197 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 198 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 199 if( PURE_WINDOWS )
 200   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 201
 202   check_function_exists(_alloca HAVE__ALLOCA)
 203   check_function_exists(__alloca HAVE___ALLOCA)
 204   check_function_exists(__chkstk HAVE___CHKSTK)
 205   check_function_exists(__chkstk_ms HAVE___CHKSTK_MS)
 206   check_function_exists(___chkstk HAVE____CHKSTK)
 207   check_function_exists(___chkstk_ms HAVE____CHKSTK_MS)
 208
 209   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 210   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 211   check_function_exists(__divdi3 HAVE___DIVDI3)
 212   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 213   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 214   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 215   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 216   check_function_exists(__moddi3 HAVE___MODDI3)
 217   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 218   check_function_exists(__umoddi3 HAVE___UMODDI3)
 219
 220   check_function_exists(__main HAVE___MAIN)
 221   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 222 endif()
 223 if( HAVE_DLFCN_H )
 224   if( HAVE_LIBDL )
 225     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 226   endif()
 227   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 228   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 229   if( HAVE_LIBDL )
 230     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 231   endif()
 232 endif()
 233
 234 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 235 if( LLVM_USING_GLIBC )
 236   add_llvm_definitions( -D_GNU_SOURCE )
 237 endif()
 238
 239 set(headers "sys/types.h")
 240
 241 if (HAVE_INTTYPES_H)
 242   set(headers ${headers} "inttypes.h")
 243 endif()
 244
 245 if (HAVE_STDINT_H)
 246   set(headers ${headers} "stdint.h")
 247 endif()
 248
 249 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 250 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 251 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 252
 253 # available programs checks
 254 function(llvm_find_program name)
 255   string(TOUPPER ${name} NAME)
 256   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 257
 258   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 259   mark_as_advanced(LLVM_PATH_${NAME})
 260   if(LLVM_PATH_${NAME})
 261     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 262     mark_as_advanced(HAVE_${NAME})
 263   else(LLVM_PATH_${NAME})
 264     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 265   endif(LLVM_PATH_${NAME})
 266 endfunction()
 267
 268 if (LLVM_ENABLE_DOXYGEN)
 269   llvm_find_program(dot)
 270 endif ()
 271
 272 if( LLVM_ENABLE_FFI )
 273   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 274   if( EXISTS "${FFI_INCLUDE_PATH}/ffi.h" )
 275     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 276     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 277   else()
 278     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 279     if( EXISTS "${FFI_INCLUDE_PATH}/ffi/ffi.h" )
 280       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 281       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 282     endif()
 283   endif()
 284
 285   if( NOT FFI_HEADER )
 286     message(FATAL_ERROR "libffi includes are not found.")
 287   endif()
 288
 289   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 290   if( NOT FFI_LIBRARY_PATH )
 291     message(FATAL_ERROR "libffi is not found.")
 292   endif()
 293
 294   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 295   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 296   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 297   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 298   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 299 else()
 300   unset(HAVE_FFI_FFI_H CACHE)
 301   unset(HAVE_FFI_H CACHE)
 302   unset(HAVE_FFI_CALL CACHE)
 303 endif( LLVM_ENABLE_FFI )
 304
 305 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 306 include(CheckAtomic)
 307
 308 if( LLVM_ENABLE_PIC )
 309   set(ENABLE_PIC 1)
 310 else()
 311   set(ENABLE_PIC 0)
 312 endif()
 313
 314 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 315
 316 set(USE_NO_MAYBE_UNINITIALIZED 0)
 317 set(USE_NO_UNINITIALIZED 0)
 318
 319 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 320 # false positives.
 321 if (CMAKE_COMPILER_IS_GNUCXX)
 322   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 323   if (HAS_MAYBE_UNINITIALIZED)
 324     set(USE_NO_MAYBE_UNINITIALIZED 1)
 325   else()
 326     # Only recent versions of gcc make the distinction between -Wuninitialized
 327     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 328     # turn off all uninitialized use warnings.
 329     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 330     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 331   endif()
 332 endif()
 333
 334 # By default, we target the host, but this can be overridden at CMake
 335 # invocation time.
 336 include(GetHostTriple)
 337 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 338
 339 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 340     "Host on which LLVM binaries will run")
 341
 342 # Determine the native architecture.
 343 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 344 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 345   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 346 endif ()
 347
 348 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 349   set(LLVM_NATIVE_ARCH X86)
 350 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 351   set(LLVM_NATIVE_ARCH X86)
 352 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 353   set(LLVM_NATIVE_ARCH X86)
 354 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 355   set(LLVM_NATIVE_ARCH X86)
 356 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 357   set(LLVM_NATIVE_ARCH Sparc)
 358 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 359   set(LLVM_NATIVE_ARCH PowerPC)
 360 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 361   set(LLVM_NATIVE_ARCH AArch64)
 362 elseif (LLVM_NATIVE_ARCH MATCHES "arm64")
 363   set(LLVM_NATIVE_ARCH AArch64)
 364 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 365   set(LLVM_NATIVE_ARCH ARM)
 366 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 367   set(LLVM_NATIVE_ARCH Mips)
 368 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 369   set(LLVM_NATIVE_ARCH XCore)
 370 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 371   set(LLVM_NATIVE_ARCH MSP430)
 372 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 373   set(LLVM_NATIVE_ARCH Hexagon)
 374 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 375   set(LLVM_NATIVE_ARCH SystemZ)
 376 else ()
 377   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 378 endif ()
 379
 380 # If build targets includes "host", then replace with native architecture.
 381 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
 382 if( NOT idx LESS 0 )
 383   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 384   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 385   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 386 endif()
 387
 388 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 389 if (NATIVE_ARCH_IDX EQUAL -1)
 390   message(STATUS
 391     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 392 else ()
 393   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 394   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 395   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 396   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 397   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 398
 399   # We don't have an ASM parser for all architectures yet.
 400   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 401     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 402   endif ()
 403
 404   # We don't have an disassembler for all architectures yet.
 405   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 406     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 407   endif ()
 408 endif ()
 409
 410 if( MINGW )
 411   set(HAVE_LIBIMAGEHLP 1)
 412   set(HAVE_LIBPSAPI 1)
 413   set(HAVE_LIBSHELL32 1)
 414   # TODO: Check existence of libraries.
 415   #   include(CheckLibraryExists)
 416   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 417 endif( MINGW )
 418
 419 if (NOT HAVE_STRTOLL)
 420   # Use _strtoi64 if strtoll is not available.
 421   check_symbol_exists(_strtoi64 stdlib.h have_strtoi64)
 422   if (have_strtoi64)
 423     set(HAVE_STRTOLL 1)
 424     set(strtoll "_strtoi64")
 425     set(strtoull "_strtoui64")
 426   endif ()
 427 endif ()
 428
 429 if( MSVC )
 430   set(SHLIBEXT ".lib")
 431   set(stricmp "_stricmp")
 432   set(strdup "_strdup")
 433
 434   # See if the DIA SDK is available and usable.
 435   set(MSVC_DIA_SDK_DIR "$ENV{VSINSTALLDIR}DIA SDK")
 436
 437   # Due to a bug in MSVC 2013's installation software, it is possible
 438   # for MSVC 2013 to write the DIA SDK into the Visual Studio 2012
 439   # install directory.  If this happens, the installation is corrupt
 440   # and there's nothing we can do.  It happens with enough frequency
 441   # though that we should handle it.  We do so by simply checking that
 442   # the DIA SDK folder exists.  Should this happen you will need to
 443   # uninstall VS 2012 and then re-install VS 2013.
 444   if (IS_DIRECTORY ${MSVC_DIA_SDK_DIR})
 445     set(HAVE_DIA_SDK 1)
 446   else()
 447     set(HAVE_DIA_SDK 0)
 448   endif()
 449 endif( MSVC )
 450
 451 if( PURE_WINDOWS )
 452   CHECK_CXX_SOURCE_COMPILES("
 453     #include <windows.h>
 454     #include <imagehlp.h>
 455     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 456     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 457     int main(){return 0;}"
 458     HAVE_ELMCB_PCSTR)
 459   if( HAVE_ELMCB_PCSTR )
 460     set(WIN32_ELMCB_PCSTR "PCSTR")
 461   else()
 462     set(WIN32_ELMCB_PCSTR "PSTR")
 463   endif()
 464 endif( PURE_WINDOWS )
 465
 466 # FIXME: Signal handler return type, currently hardcoded to 'void'
 467 set(RETSIGTYPE void)
 468
 469 if( LLVM_ENABLE_THREADS )
 470   # Check if threading primitives aren't supported on this platform
 471   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 472     set(LLVM_ENABLE_THREADS 0)
 473   endif()
 474 endif()
 475
 476 if( LLVM_ENABLE_THREADS )
 477   message(STATUS "Threads enabled.")
 478 else( LLVM_ENABLE_THREADS )
 479   message(STATUS "Threads disabled.")
 480 endif()
 481
 482 if (LLVM_ENABLE_ZLIB )
 483   # Check if zlib is available in the system.
 484   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 485     set(LLVM_ENABLE_ZLIB 0)
 486   endif()
 487 endif()
 488
 489 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})
 490
 491 if (LLVM_ENABLE_DOXYGEN)
 492   message(STATUS "Doxygen enabled.")
 493   find_package(Doxygen REQUIRED)
 494
 495   if (DOXYGEN_FOUND)
 496     # If we find doxygen and we want to enable doxygen by default create a
 497     # global aggregate doxygen target for generating llvm and any/all
 498     # subprojects doxygen documentation.
 499     if (LLVM_BUILD_DOCS)
 500       add_custom_target(doxygen ALL)
 501     endif()
 502
 503     option(LLVM_DOXYGEN_EXTERNAL_SEARCH "Enable doxygen external search." OFF)
 504     if (LLVM_DOXYGEN_EXTERNAL_SEARCH)
 505       set(LLVM_DOXYGEN_SEARCHENGINE_URL "" CACHE STRING "URL to use for external searhc.")
 506       set(LLVM_DOXYGEN_SEARCH_MAPPINGS "" CACHE STRING "Doxygen Search Mappings")
 507     endif()
 508   endif()
 509 else()
 510   message(STATUS "Doxygen disabled.")
 511 endif()
 512
 513 if (LLVM_ENABLE_SPHINX)
 514   message(STATUS "Sphinx enabled.")
 515   find_package(Sphinx REQUIRED)
 516   if (LLVM_BUILD_DOCS)
 517     add_custom_target(sphinx ALL)
 518   endif()
 519 else()
 520   message(STATUS "Sphinx disabled.")
 521 endif()
 522
 523 set(LLVM_BINDINGS "")
 524 if(WIN32)
 525   message(STATUS "Go bindings disabled.")
 526 else()
 527   find_program(GO_EXECUTABLE NAMES go DOC "go executable")
 528   if(GO_EXECUTABLE STREQUAL "GO_EXECUTABLE-NOTFOUND")
 529     message(STATUS "Go bindings disabled.")
 530   else()
 531     execute_process(COMMAND ${GO_EXECUTABLE} run ${CMAKE_SOURCE_DIR}/bindings/go/conftest.go
 532                     RESULT_VARIABLE GO_CONFTEST)
 533     if(GO_CONFTEST STREQUAL "0")
 534       set(LLVM_BINDINGS "${LLVM_BINDINGS} go")
 535       message(STATUS "Go bindings enabled.")
 536     else()
 537       message(STATUS "Go bindings disabled, need at least Go 1.2.")
 538     endif()
 539   endif()
 540 endif()
 541
 542 find_program(GOLD_EXECUTABLE NAMES ld.gold ld DOC "The gold linker")
 543 if(GOLD_EXECUTABLE)
 544         set(LLVM_BINUTILS_INCDIR "" CACHE PATH
 545                 "PATH to binutils/include containing plugin-api.h for gold plugin.")
 546 endif()
 547
 548 include(FindOCaml)
 549 include(AddOCaml)
 550 if(WIN32)
 551   message(STATUS "OCaml bindings disabled.")
 552 else()
 553   find_package(OCaml)
 554   if( NOT OCAML_FOUND )
 555     message(STATUS "OCaml bindings disabled.")
 556   else()
 557     if( OCAML_VERSION VERSION_LESS "4.00.0" )
 558       message(STATUS "OCaml bindings disabled, need OCaml >=4.00.0.")
 559     else()
 560       find_ocamlfind_package(ctypes VERSION 0.3 OPTIONAL)
 561       if( HAVE_OCAML_CTYPES )
 562         message(STATUS "OCaml bindings enabled.")
 563         find_ocamlfind_package(oUnit VERSION 2 OPTIONAL)
 564         set(LLVM_BINDINGS "${LLVM_BINDINGS} ocaml")
 565       else()
 566         message(STATUS "OCaml bindings disabled, need ctypes >=0.3.")
 567       endif()
 568     endif()
 569   endif()
 570 endif()
 571
 572 string(REPLACE " " ";" LLVM_BINDINGS_LIST "${LLVM_BINDINGS}")