cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckIncludeFileCXX)
   8 include(CheckLibraryExists)
   9 include(CheckSymbolExists)
  10 include(CheckFunctionExists)
  11 include(CheckCXXSourceCompiles)
  12 include(TestBigEndian)
  13
  14 include(HandleLLVMStdlib)
  15
  16 if( UNIX AND NOT BEOS )
  17   # Used by check_symbol_exists:
  18   set(CMAKE_REQUIRED_LIBRARIES m)
  19 endif()
  20 # x86_64 FreeBSD 9.2 requires libcxxrt to be specified explicitly.
  21 if( CMAKE_SYSTEM MATCHES "FreeBSD-9.2-RELEASE" AND
  22     CMAKE_SIZEOF_VOID_P EQUAL 8 )
  23   list(APPEND CMAKE_REQUIRED_LIBRARIES "cxxrt")
  24 endif()
  25
  26 # Helper macros and functions
  27 macro(add_cxx_include result files)
  28   set(${result} "")
  29   foreach (file_name ${files})
  30      set(${result} "${${result}}#include<${file_name}>\n")
  31   endforeach()
  32 endmacro(add_cxx_include files result)
  33
  34 function(check_type_exists type files variable)
  35   add_cxx_include(includes "${files}")
  36   CHECK_CXX_SOURCE_COMPILES("
  37     ${includes} ${type} typeVar;
  38     int main() {
  39         return 0;
  40     }
  41     " ${variable})
  42 endfunction()
  43
  44 # include checks
  45 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
  46 check_include_file(dirent.h HAVE_DIRENT_H)
  47 check_include_file(dlfcn.h HAVE_DLFCN_H)
  48 check_include_file(errno.h HAVE_ERRNO_H)
  49 check_include_file(execinfo.h HAVE_EXECINFO_H)
  50 check_include_file(fcntl.h HAVE_FCNTL_H)
  51 check_include_file(inttypes.h HAVE_INTTYPES_H)
  52 check_include_file(limits.h HAVE_LIMITS_H)
  53 check_include_file(link.h HAVE_LINK_H)
  54 check_include_file(malloc.h HAVE_MALLOC_H)
  55 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  56 check_include_file(ndir.h HAVE_NDIR_H)
  57 if( NOT PURE_WINDOWS )
  58   check_include_file(pthread.h HAVE_PTHREAD_H)
  59 endif()
  60 check_include_file(signal.h HAVE_SIGNAL_H)
  61 check_include_file(stdint.h HAVE_STDINT_H)
  62 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  63 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  64 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  65 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  66 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  67 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  68 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  69 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  70 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  71 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  72 check_include_file(termios.h HAVE_TERMIOS_H)
  73 check_include_file(unistd.h HAVE_UNISTD_H)
  74 check_include_file(utime.h HAVE_UTIME_H)
  75 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  76 check_include_file(zlib.h HAVE_ZLIB_H)
  77 check_include_file(fenv.h HAVE_FENV_H)
  78 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  79 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  80
  81 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  82 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  83
  84 # library checks
  85 if( NOT PURE_WINDOWS )
  86   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  87   if (HAVE_LIBPTHREAD)
  88     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  89     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  90     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  91   else()
  92     # this could be Android
  93     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  94     if (PTHREAD_IN_LIBC)
  95       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  96       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  97       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  98     endif()
  99   endif()
 100   check_library_exists(dl dlopen "" HAVE_LIBDL)
 101   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 102   if (LLVM_ENABLE_ZLIB)
 103     check_library_exists(z compress2 "" HAVE_LIBZ)
 104   else()
 105     set(HAVE_LIBZ 0)
 106   endif()
 107   check_library_exists(edit el_init "" HAVE_LIBEDIT)
 108   if(LLVM_ENABLE_TERMINFO)
 109     set(HAVE_TERMINFO 0)
 110     foreach(library tinfo terminfo curses ncurses ncursesw)
 111       string(TOUPPER ${library} library_suffix)
 112       check_library_exists(${library} setupterm "" HAVE_TERMINFO_${library_suffix})
 113       if(HAVE_TERMINFO_${library_suffix})
 114         set(HAVE_TERMINFO 1)
 115         set(TERMINFO_LIBS "${library}")
 116         break()
 117       endif()
 118     endforeach()
 119   else()
 120     set(HAVE_TERMINFO 0)
 121   endif()
 122 endif()
 123
 124 # function checks
 125 check_symbol_exists(arc4random "stdlib.h" HAVE_DECL_ARC4RANDOM)
 126 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 127 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 128 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 129 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 130 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 131 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 132 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 133 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 134 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 135 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 136 check_symbol_exists(ceilf math.h HAVE_CEILF)
 137 check_symbol_exists(floorf math.h HAVE_FLOORF)
 138 check_symbol_exists(fmodf math.h HAVE_FMODF)
 139 check_symbol_exists(log math.h HAVE_LOG)
 140 check_symbol_exists(log2 math.h HAVE_LOG2)
 141 check_symbol_exists(log10 math.h HAVE_LOG10)
 142 check_symbol_exists(exp math.h HAVE_EXP)
 143 check_symbol_exists(exp2 math.h HAVE_EXP2)
 144 check_symbol_exists(exp10 math.h HAVE_EXP10)
 145 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 146 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 147 if( HAVE_SETJMP_H )
 148   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 149   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 150   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 151   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 152 endif()
 153 if( HAVE_SYS_UIO_H )
 154   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 155 endif()
 156 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 157 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 158 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 159                     HAVE_MALLOC_ZONE_STATISTICS)
 160 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 161 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 162 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 163 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 164 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 165 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 166 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 167 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 168 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 169 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 170 check_symbol_exists(pread unistd.h HAVE_PREAD)
 171 check_symbol_exists(realpath stdlib.h HAVE_REALPATH)
 172 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 173 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 174 if( HAVE_RAND48_SRAND48 )
 175   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 176   if( HAVE_RAND48_LRAND48 )
 177     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 178     if( HAVE_RAND48_DRAND48 )
 179       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 180     endif()
 181   endif()
 182 endif()
 183 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 184 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 185 check_symbol_exists(strerror string.h HAVE_STRERROR)
 186 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 187 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 188 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 189 if( PURE_WINDOWS )
 190   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 191
 192   check_function_exists(_alloca HAVE__ALLOCA)
 193   check_function_exists(__alloca HAVE___ALLOCA)
 194   check_function_exists(__chkstk HAVE___CHKSTK)
 195   check_function_exists(___chkstk HAVE____CHKSTK)
 196
 197   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 198   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 199   check_function_exists(__divdi3 HAVE___DIVDI3)
 200   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 201   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 202   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 203   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 204   check_function_exists(__moddi3 HAVE___MODDI3)
 205   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 206   check_function_exists(__umoddi3 HAVE___UMODDI3)
 207
 208   check_function_exists(__main HAVE___MAIN)
 209   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 210 endif()
 211 if( HAVE_DLFCN_H )
 212   if( HAVE_LIBDL )
 213     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 214   endif()
 215   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 216   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 217   if( HAVE_LIBDL )
 218     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 219   endif()
 220 endif()
 221
 222 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 223 if( LLVM_USING_GLIBC )
 224   add_llvm_definitions( -D_GNU_SOURCE )
 225 endif()
 226
 227 set(headers "sys/types.h")
 228
 229 if (HAVE_INTTYPES_H)
 230   set(headers ${headers} "inttypes.h")
 231 endif()
 232
 233 if (HAVE_STDINT_H)
 234   set(headers ${headers} "stdint.h")
 235 endif()
 236
 237 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 238 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 239 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 240
 241 # available programs checks
 242 function(llvm_find_program name)
 243   string(TOUPPER ${name} NAME)
 244   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 245
 246   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 247   mark_as_advanced(LLVM_PATH_${NAME})
 248   if(LLVM_PATH_${NAME})
 249     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 250     mark_as_advanced(HAVE_${NAME})
 251   else(LLVM_PATH_${NAME})
 252     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 253   endif(LLVM_PATH_${NAME})
 254 endfunction()
 255
 256 if (LLVM_ENABLE_DOXYGEN)
 257   llvm_find_program(dot)
 258 endif ()
 259
 260 if( LLVM_ENABLE_FFI )
 261   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 262   if( EXISTS "${FFI_INCLUDE_PATH}/ffi.h" )
 263     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 264     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 265   else()
 266     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 267     if( EXISTS "${FFI_INCLUDE_PATH}/ffi/ffi.h" )
 268       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 269       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 270     endif()
 271   endif()
 272
 273   if( NOT FFI_HEADER )
 274     message(FATAL_ERROR "libffi includes are not found.")
 275   endif()
 276
 277   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 278   if( NOT FFI_LIBRARY_PATH )
 279     message(FATAL_ERROR "libffi is not found.")
 280   endif()
 281
 282   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 283   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 284   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 285   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 286   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 287 else()
 288   unset(HAVE_FFI_FFI_H CACHE)
 289   unset(HAVE_FFI_H CACHE)
 290   unset(HAVE_FFI_CALL CACHE)
 291 endif( LLVM_ENABLE_FFI )
 292
 293 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 294 include(CheckAtomic)
 295
 296 if( LLVM_ENABLE_PIC )
 297   set(ENABLE_PIC 1)
 298 else()
 299   set(ENABLE_PIC 0)
 300 endif()
 301
 302 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 303
 304 set(USE_NO_MAYBE_UNINITIALIZED 0)
 305 set(USE_NO_UNINITIALIZED 0)
 306
 307 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 308 # false positives.
 309 if (CMAKE_COMPILER_IS_GNUCXX)
 310   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 311   if (HAS_MAYBE_UNINITIALIZED)
 312     set(USE_NO_MAYBE_UNINITIALIZED 1)
 313   else()
 314     # Only recent versions of gcc make the distinction between -Wuninitialized
 315     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 316     # turn off all uninitialized use warnings.
 317     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 318     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 319   endif()
 320 endif()
 321
 322 # By default, we target the host, but this can be overridden at CMake
 323 # invocation time.
 324 include(GetHostTriple)
 325 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 326
 327 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 328     "Host on which LLVM binaries will run")
 329
 330 # Determine the native architecture.
 331 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 332 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 333   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 334 endif ()
 335
 336 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 337   set(LLVM_NATIVE_ARCH X86)
 338 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 339   set(LLVM_NATIVE_ARCH X86)
 340 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 341   set(LLVM_NATIVE_ARCH X86)
 342 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 343   set(LLVM_NATIVE_ARCH X86)
 344 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 345   set(LLVM_NATIVE_ARCH Sparc)
 346 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 347   set(LLVM_NATIVE_ARCH PowerPC)
 348 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 349   set(LLVM_NATIVE_ARCH AArch64)
 350 elseif (LLVM_NATIVE_ARCH MATCHES "arm64")
 351   set(LLVM_NATIVE_ARCH AArch64)
 352 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 353   set(LLVM_NATIVE_ARCH ARM)
 354 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 355   set(LLVM_NATIVE_ARCH Mips)
 356 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 357   set(LLVM_NATIVE_ARCH XCore)
 358 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 359   set(LLVM_NATIVE_ARCH MSP430)
 360 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 361   set(LLVM_NATIVE_ARCH Hexagon)
 362 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 363   set(LLVM_NATIVE_ARCH SystemZ)
 364 else ()
 365   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 366 endif ()
 367
 368 # If build targets includes "host", then replace with native architecture.
 369 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
 370 if( NOT idx LESS 0 )
 371   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 372   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 373   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 374 endif()
 375
 376 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 377 if (NATIVE_ARCH_IDX EQUAL -1)
 378   message(STATUS
 379     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 380 else ()
 381   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 382   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 383   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 384   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 385   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 386
 387   # We don't have an ASM parser for all architectures yet.
 388   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 389     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 390   endif ()
 391
 392   # We don't have an disassembler for all architectures yet.
 393   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 394     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 395   endif ()
 396 endif ()
 397
 398 if( MINGW )
 399   set(HAVE_LIBIMAGEHLP 1)
 400   set(HAVE_LIBPSAPI 1)
 401   set(HAVE_LIBSHELL32 1)
 402   # TODO: Check existence of libraries.
 403   #   include(CheckLibraryExists)
 404   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 405 endif( MINGW )
 406
 407 if (NOT HAVE_STRTOLL)
 408   # Use _strtoi64 if strtoll is not available.
 409   check_symbol_exists(_strtoi64 stdlib.h have_strtoi64)
 410   if (have_strtoi64)
 411     set(HAVE_STRTOLL 1)
 412     set(strtoll "_strtoi64")
 413     set(strtoull "_strtoui64")
 414   endif ()
 415 endif ()
 416
 417 if( MSVC )
 418   set(SHLIBEXT ".lib")
 419   set(stricmp "_stricmp")
 420   set(strdup "_strdup")
 421 endif( MSVC )
 422
 423 if( PURE_WINDOWS )
 424   CHECK_CXX_SOURCE_COMPILES("
 425     #include <windows.h>
 426     #include <imagehlp.h>
 427     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 428     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 429     int main(){return 0;}"
 430     HAVE_ELMCB_PCSTR)
 431   if( HAVE_ELMCB_PCSTR )
 432     set(WIN32_ELMCB_PCSTR "PCSTR")
 433   else()
 434     set(WIN32_ELMCB_PCSTR "PSTR")
 435   endif()
 436 endif( PURE_WINDOWS )
 437
 438 # FIXME: Signal handler return type, currently hardcoded to 'void'
 439 set(RETSIGTYPE void)
 440
 441 if( LLVM_ENABLE_THREADS )
 442   # Check if threading primitives aren't supported on this platform
 443   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 444     set(LLVM_ENABLE_THREADS 0)
 445   endif()
 446 endif()
 447
 448 if( LLVM_ENABLE_THREADS )
 449   message(STATUS "Threads enabled.")
 450 else( LLVM_ENABLE_THREADS )
 451   message(STATUS "Threads disabled.")
 452 endif()
 453
 454 if (LLVM_ENABLE_ZLIB )
 455   # Check if zlib is available in the system.
 456   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 457     set(LLVM_ENABLE_ZLIB 0)
 458   endif()
 459 endif()
 460
 461 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})
 462
 463 if (LLVM_ENABLE_DOXYGEN)
 464   message(STATUS "Doxygen enabled.")
 465   find_package(Doxygen REQUIRED)
 466
 467   if (DOXYGEN_FOUND)
 468     # If we find doxygen and we want to enable doxygen by default create a
 469     # global aggregate doxygen target for generating llvm and any/all
 470     # subprojects doxygen documentation.
 471     if (LLVM_BUILD_DOCS)
 472       add_custom_target(doxygen ALL)
 473     endif()
 474
 475     option(LLVM_DOXYGEN_EXTERNAL_SEARCH "Enable doxygen external search." OFF)
 476     if (LLVM_DOXYGEN_EXTERNAL_SEARCH)
 477       set(LLVM_DOXYGEN_SEARCHENGINE_URL "" CACHE STRING "URL to use for external searhc.")
 478       set(LLVM_DOXYGEN_SEARCH_MAPPINGS "" CACHE STRING "Doxygen Search Mappings")
 479     endif()
 480   endif()
 481 else()
 482   message(STATUS "Doxygen disabled.")
 483 endif()
 484
 485 if (LLVM_ENABLE_SPHINX)
 486   message(STATUS "Sphinx enabled.")
 487   find_package(Sphinx REQUIRED)
 488   if (LLVM_BUILD_DOCS)
 489     add_custom_target(sphinx ALL)
 490   endif()
 491 else()
 492   message(STATUS "Sphinx disabled.")
 493 endif()
 494
 495 set(LLVM_BINDINGS "")
 496 if(WIN32)
 497   message(STATUS "Go bindings disabled.")
 498 else()
 499   find_program(GO_EXECUTABLE NAMES go DOC "go executable")
 500   if(GO_EXECUTABLE STREQUAL "GO_EXECUTABLE-NOTFOUND")
 501     message(STATUS "Go bindings disabled.")
 502   else()
 503     execute_process(COMMAND ${GO_EXECUTABLE} run ${CMAKE_SOURCE_DIR}/bindings/go/conftest.go
 504                     RESULT_VARIABLE GO_CONFTEST)
 505     if(GO_CONFTEST STREQUAL "0")
 506       set(LLVM_BINDINGS "${LLVM_BINDINGS} go")
 507       message(STATUS "Go bindings enabled.")
 508     else()
 509       message(STATUS "Go bindings disabled, need at least Go 1.2.")
 510     endif()
 511   endif()
 512 endif()