cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckLibraryExists)
   8 include(CheckSymbolExists)
   9 include(CheckFunctionExists)
  10 include(CheckCXXSourceCompiles)
  11 include(TestBigEndian)
  12
  13 if( UNIX AND NOT BEOS )
  14   # Used by check_symbol_exists:
  15   set(CMAKE_REQUIRED_LIBRARIES m)
  16 endif()
  17
  18 # Helper macros and functions
  19 macro(add_cxx_include result files)
  20   set(${result} "")
  21   foreach (file_name ${files})
  22      set(${result} "${${result}}#include<${file_name}>\n")
  23   endforeach()
  24 endmacro(add_cxx_include files result)
  25
  26 function(check_type_exists type files variable)
  27   add_cxx_include(includes "${files}")
  28   CHECK_CXX_SOURCE_COMPILES("
  29     ${includes} ${type} typeVar;
  30     int main() {
  31         return 0;
  32     }
  33     " ${variable})
  34 endfunction()
  35
  36 # include checks
  37 check_include_file(argz.h HAVE_ARGZ_H)
  38 check_include_file(assert.h HAVE_ASSERT_H)
  39 check_include_file(ctype.h HAVE_CTYPE_H)
  40 check_include_file(dirent.h HAVE_DIRENT_H)
  41 check_include_file(dl.h HAVE_DL_H)
  42 check_include_file(dld.h HAVE_DLD_H)
  43 check_include_file(dlfcn.h HAVE_DLFCN_H)
  44 check_include_file(errno.h HAVE_ERRNO_H)
  45 check_include_file(execinfo.h HAVE_EXECINFO_H)
  46 check_include_file(fcntl.h HAVE_FCNTL_H)
  47 check_include_file(inttypes.h HAVE_INTTYPES_H)
  48 check_include_file(limits.h HAVE_LIMITS_H)
  49 check_include_file(link.h HAVE_LINK_H)
  50 check_include_file(malloc.h HAVE_MALLOC_H)
  51 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  52 check_include_file(memory.h HAVE_MEMORY_H)
  53 check_include_file(ndir.h HAVE_NDIR_H)
  54 if( NOT PURE_WINDOWS )
  55   check_include_file(pthread.h HAVE_PTHREAD_H)
  56 endif()
  57 check_include_file(sanitizer/msan_interface.h HAVE_SANITIZER_MSAN_INTERFACE_H)
  58 check_include_file(setjmp.h HAVE_SETJMP_H)
  59 check_include_file(signal.h HAVE_SIGNAL_H)
  60 check_include_file(stdint.h HAVE_STDINT_H)
  61 check_include_file(stdio.h HAVE_STDIO_H)
  62 check_include_file(stdlib.h HAVE_STDLIB_H)
  63 check_include_file(string.h HAVE_STRING_H)
  64 check_include_file(strings.h HAVE_STRINGS_H)
  65 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  66 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  67 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  68 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  69 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  70 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  71 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  72 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  73 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  74 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  75 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  76 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  77 check_include_file(termios.h HAVE_TERMIOS_H)
  78 check_include_file(unistd.h HAVE_UNISTD_H)
  79 check_include_file(utime.h HAVE_UTIME_H)
  80 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  81 check_include_file(windows.h HAVE_WINDOWS_H)
  82 check_include_file(fenv.h HAVE_FENV_H)
  83 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  84 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  85
  86 # library checks
  87 if( NOT PURE_WINDOWS )
  88   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  89   if (HAVE_LIBPTHREAD)
  90     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  91     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  92     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  93   else()
  94     # this could be Android
  95     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  96     if (PTHREAD_IN_LIBC)
  97       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  98       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  99       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
 100     endif()
 101   endif()
 102   check_library_exists(dl dlopen "" HAVE_LIBDL)
 103   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 104 endif()
 105
 106 # function checks
 107 check_symbol_exists(arc4random "stdlib.h" HAVE_ARC4RANDOM)
 108 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 109 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 110 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 111 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 112 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 113 check_symbol_exists(index strings.h HAVE_INDEX)
 114 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 115 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 116 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 117 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 118 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 119 check_symbol_exists(ceilf math.h HAVE_CEILF)
 120 check_symbol_exists(floorf math.h HAVE_FLOORF)
 121 check_symbol_exists(fmodf math.h HAVE_FMODF)
 122 check_symbol_exists(log math.h HAVE_LOG)
 123 check_symbol_exists(log2 math.h HAVE_LOG2)
 124 check_symbol_exists(log10 math.h HAVE_LOG10)
 125 check_symbol_exists(exp math.h HAVE_EXP)
 126 check_symbol_exists(exp2 math.h HAVE_EXP2)
 127 check_symbol_exists(exp10 math.h HAVE_EXP10)
 128 if( HAVE_SETJMP_H )
 129   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 130   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 131   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 132   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 133 endif()
 134 if( HAVE_SYS_UIO_H )
 135   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 136 endif()
 137 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 138 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 139 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 140                     HAVE_MALLOC_ZONE_STATISTICS)
 141 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 142 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 143 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 144 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 145 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 146 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 147 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 148 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 149 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 150 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 151 check_symbol_exists(pread unistd.h HAVE_PREAD)
 152 check_symbol_exists(rindex strings.h HAVE_RINDEX)
 153 check_symbol_exists(strchr string.h HAVE_STRCHR)
 154 check_symbol_exists(strcmp string.h HAVE_STRCMP)
 155 check_symbol_exists(strdup string.h HAVE_STRDUP)
 156 check_symbol_exists(strrchr string.h HAVE_STRRCHR)
 157 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 158 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 159 if( HAVE_RAND48_SRAND48 )
 160   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 161   if( HAVE_RAND48_LRAND48 )
 162     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 163     if( HAVE_RAND48_DRAND48 )
 164       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 165     endif()
 166   endif()
 167 endif()
 168 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 169 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 170 check_symbol_exists(strerror string.h HAVE_STRERROR)
 171 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 172 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 173 check_symbol_exists(memcpy string.h HAVE_MEMCPY)
 174 check_symbol_exists(memmove string.h HAVE_MEMMOVE)
 175 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 176 if( PURE_WINDOWS )
 177   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 178
 179   check_function_exists(_alloca HAVE__ALLOCA)
 180   check_function_exists(__alloca HAVE___ALLOCA)
 181   check_function_exists(__chkstk HAVE___CHKSTK)
 182   check_function_exists(___chkstk HAVE____CHKSTK)
 183
 184   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 185   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 186   check_function_exists(__divdi3 HAVE___DIVDI3)
 187   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 188   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 189   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 190   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 191   check_function_exists(__moddi3 HAVE___MODDI3)
 192   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 193   check_function_exists(__umoddi3 HAVE___UMODDI3)
 194
 195   check_function_exists(__main HAVE___MAIN)
 196   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 197 endif()
 198 if( HAVE_ARGZ_H )
 199   check_symbol_exists(argz_append argz.h HAVE_ARGZ_APPEND)
 200   check_symbol_exists(argz_create_sep argz.h HAVE_ARGZ_CREATE_SEP)
 201   check_symbol_exists(argz_insert argz.h HAVE_ARGZ_INSERT)
 202   check_symbol_exists(argz_next argz.h HAVE_ARGZ_NEXT)
 203   check_symbol_exists(argz_stringify argz.h HAVE_ARGZ_STRINGIFY)
 204 endif()
 205 if( HAVE_DLFCN_H )
 206   if( HAVE_LIBDL )
 207     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 208   endif()
 209   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 210   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 211   if( HAVE_LIBDL )
 212     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 213   endif()
 214 endif()
 215
 216 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 217 if( LLVM_USING_GLIBC )
 218   add_llvm_definitions( -D_GNU_SOURCE )
 219 endif()
 220
 221 set(headers "")
 222 if (HAVE_SYS_TYPES_H)
 223   set(headers ${headers} "sys/types.h")
 224 endif()
 225
 226 if (HAVE_INTTYPES_H)
 227   set(headers ${headers} "inttypes.h")
 228 endif()
 229
 230 if (HAVE_STDINT_H)
 231   set(headers ${headers} "stdint.h")
 232 endif()
 233
 234 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 235 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 236 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 237 check_type_exists(error_t errno.h HAVE_ERROR_T)
 238
 239 # available programs checks
 240 function(llvm_find_program name)
 241   string(TOUPPER ${name} NAME)
 242   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 243   find_program(LLVM_PATH_${NAME} ${name})
 244   mark_as_advanced(LLVM_PATH_${NAME})
 245   if(LLVM_PATH_${NAME})
 246     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 247     mark_as_advanced(HAVE_${NAME})
 248   else(LLVM_PATH_${NAME})
 249     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 250   endif(LLVM_PATH_${NAME})
 251 endfunction()
 252
 253 llvm_find_program(gv)
 254 llvm_find_program(circo)
 255 llvm_find_program(twopi)
 256 llvm_find_program(neato)
 257 llvm_find_program(fdp)
 258 llvm_find_program(dot)
 259 llvm_find_program(dotty)
 260 llvm_find_program(xdot.py)
 261 llvm_find_program(Graphviz)
 262
 263 if( LLVM_ENABLE_FFI )
 264   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 265   if( FFI_INCLUDE_PATH )
 266     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 267     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 268   else()
 269     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 270     if( FFI_INCLUDE_PATH )
 271       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 272       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 273     endif()
 274   endif()
 275
 276   if( NOT FFI_HEADER )
 277     message(FATAL_ERROR "libffi includes are not found.")
 278   endif()
 279
 280   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 281   if( NOT FFI_LIBRARY_PATH )
 282     message(FATAL_ERROR "libffi is not found.")
 283   endif()
 284
 285   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 286   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 287   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 288   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 289   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 290 else()
 291   unset(HAVE_FFI_FFI_H CACHE)
 292   unset(HAVE_FFI_H CACHE)
 293   unset(HAVE_FFI_CALL CACHE)
 294 endif( LLVM_ENABLE_FFI )
 295
 296 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 297 include(CheckAtomic)
 298
 299 if( LLVM_ENABLE_PIC )
 300   set(ENABLE_PIC 1)
 301 else()
 302   set(ENABLE_PIC 0)
 303 endif()
 304
 305 find_package(LibXml2)
 306 if (LIBXML2_FOUND)
 307   set(CLANG_HAVE_LIBXML 1)
 308 endif ()
 309
 310 include(CheckCXXCompilerFlag)
 311
 312 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 313
 314 set(USE_NO_MAYBE_UNINITIALIZED 0)
 315 set(USE_NO_UNINITIALIZED 0)
 316
 317 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 318 # false positives.
 319 if (CMAKE_COMPILER_IS_GNUCXX)
 320   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 321   if (HAS_MAYBE_UNINITIALIZED)
 322     set(USE_NO_MAYBE_UNINITIALIZED 1)
 323   else()
 324     # Only recent versions of gcc make the distinction between -Wuninitialized
 325     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 326     # turn off all uninitialized use warnings.
 327     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 328     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 329   endif()
 330 endif()
 331
 332 include(GetHostTriple)
 333 get_host_triple(LLVM_HOST_TRIPLE)
 334
 335 # By default, we target the host, but this can be overridden at CMake
 336 # invocation time.
 337 set(LLVM_HOSTTRIPLE "${LLVM_HOST_TRIPLE}")
 338
 339 # Determine the native architecture.
 340 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 341 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 342   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 343 endif ()
 344
 345 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 346   set(LLVM_NATIVE_ARCH X86)
 347 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 348   set(LLVM_NATIVE_ARCH X86)
 349 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 350   set(LLVM_NATIVE_ARCH X86)
 351 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 352   set(LLVM_NATIVE_ARCH X86)
 353 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 354   set(LLVM_NATIVE_ARCH Sparc)
 355 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 356   set(LLVM_NATIVE_ARCH PowerPC)
 357 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 358   set(LLVM_NATIVE_ARCH ARM)
 359 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 360   set(LLVM_NATIVE_ARCH Mips)
 361 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 362   set(LLVM_NATIVE_ARCH XCore)
 363 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 364   set(LLVM_NATIVE_ARCH MSP430)
 365 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 366   set(LLVM_NATIVE_ARCH Hexagon)
 367 else ()
 368   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 369 endif ()
 370
 371 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 372 if (NATIVE_ARCH_IDX EQUAL -1)
 373   message(STATUS
 374     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 375 else ()
 376   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 377   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 378   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 379   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 380   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 381
 382   # We don't have an ASM parser for all architectures yet.
 383   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 384     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 385   endif ()
 386
 387   # We don't have an disassembler for all architectures yet.
 388   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 389     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 390   endif ()
 391 endif ()
 392
 393 if( MINGW )
 394   set(HAVE_LIBIMAGEHLP 1)
 395   set(HAVE_LIBPSAPI 1)
 396   # TODO: Check existence of libraries.
 397   #   include(CheckLibraryExists)
 398   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 399 endif( MINGW )
 400
 401 if( MSVC )
 402   set(error_t int)
 403   set(LTDL_SHLIBPATH_VAR "PATH")
 404   set(LTDL_SYSSEARCHPATH "")
 405   set(LTDL_DLOPEN_DEPLIBS 1)
 406   set(SHLIBEXT ".lib")
 407   set(LTDL_OBJDIR "_libs")
 408   set(HAVE_STRTOLL 1)
 409   set(strtoll "_strtoi64")
 410   set(strtoull "_strtoui64")
 411   set(stricmp "_stricmp")
 412   set(strdup "_strdup")
 413 else( MSVC )
 414   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 415   set(LTDL_SYSSEARCHPATH "") # TODO
 416   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 417 endif( MSVC )
 418
 419 if( PURE_WINDOWS )
 420   CHECK_CXX_SOURCE_COMPILES("
 421     #include <windows.h>
 422     #include <imagehlp.h>
 423     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 424     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 425     int main(){return 0;}"
 426     HAVE_ELMCB_PCSTR)
 427   if( HAVE_ELMCB_PCSTR )
 428     set(WIN32_ELMCB_PCSTR "PCSTR")
 429   else()
 430     set(WIN32_ELMCB_PCSTR "PSTR")
 431   endif()
 432 endif( PURE_WINDOWS )
 433
 434 # FIXME: Signal handler return type, currently hardcoded to 'void'
 435 set(RETSIGTYPE void)
 436
 437 if( LLVM_ENABLE_THREADS )
 438   # Check if threading primitives aren't supported on this platform
 439   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 440     set(LLVM_ENABLE_THREADS 0)
 441   endif()
 442 endif()
 443
 444 if( LLVM_ENABLE_THREADS )
 445   message(STATUS "Threads enabled.")
 446 else( LLVM_ENABLE_THREADS )
 447   message(STATUS "Threads disabled.")
 448 endif()
 449
 450 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})