autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[3.0svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2011 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2011 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl We need to check for the compiler up here to avoid anything else
  62 dnl starting with a different one.
  63 AC_PROG_CC(clang llvm-gcc gcc)
  64 AC_PROG_CXX(clang++ llvm-g++ g++)
  65 AC_PROG_CPP
  66
  67 dnl Configure all of the projects present in our source tree. While we could
  68 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  69 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  70 dnl Instead we match on the known projects.
  71
  72 dnl
  73 dnl One tricky part of doing this is that some projects depend upon other
  74 dnl projects.  For example, several projects rely upon the LLVM test suite.
  75 dnl We want to configure those projects first so that their object trees are
  76 dnl created before running the configure scripts of projects that depend upon
  77 dnl them.
  78 dnl
  79
  80 dnl Several projects use llvm-gcc, so configure that first
  81 if test -d ${srcdir}/projects/llvm-gcc ; then
  82   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  83 fi
  84
  85 dnl Several projects use the LLVM test suite, so configure it next.
  86 if test -d ${srcdir}/projects/test-suite ; then
  87   AC_CONFIG_SUBDIRS([projects/test-suite])
  88 fi
  89
  90 dnl llvm-test is the old name of the test-suite, kept here for backwards
  91 dnl compatibility
  92 if test -d ${srcdir}/projects/llvm-test ; then
  93   AC_CONFIG_SUBDIRS([projects/llvm-test])
  94 fi
  95
  96 dnl Some projects use poolalloc; configure that next
  97 if test -d ${srcdir}/projects/poolalloc ; then
  98   AC_CONFIG_SUBDIRS([projects/poolalloc])
  99 fi
 100
 101 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 102   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 103 fi
 104
 105 dnl Check for all other projects
 106 for i in `ls ${srcdir}/projects`
 107 do
 108   if test -d ${srcdir}/projects/${i} ; then
 109     case ${i} in
 110       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 111       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 112       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 113       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 114       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 115       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 116       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 117       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 118       llvm-gcc)       ;;
 119       test-suite)     ;;
 120       llvm-test)      ;;
 121       poolalloc)      ;;
 122       llvm-poolalloc) ;;
 123       *)
 124         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 125         ;;
 126     esac
 127   fi
 128 done
 129
 130 dnl Disable the build of polly, even if it is checked out into tools/polly.
 131 AC_ARG_ENABLE(polly,
 132               AS_HELP_STRING([--enable-polly],
 133                              [Use polly if available (default is YES)]),,
 134                              enableval=default)
 135 case "$enableval" in
 136   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 137   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 138   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 139   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 140 esac
 141
 142
 143 dnl Check if polly is checked out into tools/polly and configure it if
 144 dnl available.
 145 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 146   AC_SUBST(LLVM_HAS_POLLY,1)
 147   AC_CONFIG_SUBDIRS([tools/polly])
 148 fi
 149
 150 dnl===-----------------------------------------------------------------------===
 151 dnl===
 152 dnl=== SECTION 2: Architecture, target, and host checks
 153 dnl===
 154 dnl===-----------------------------------------------------------------------===
 155
 156 dnl Check the target for which we're compiling and the host that will do the
 157 dnl compilations. This will tell us which LLVM compiler will be used for
 158 dnl compiling SSA into object code. This needs to be done early because
 159 dnl following tests depend on it.
 160 AC_CANONICAL_TARGET
 161
 162 dnl Determine the platform type and cache its value. This helps us configure
 163 dnl the System library to the correct build platform.
 164 AC_CACHE_CHECK([type of operating system we're going to host on],
 165                [llvm_cv_os_type],
 166 [case $host in
 167   *-*-aix*)
 168     llvm_cv_link_all_option="-Wl,--whole-archive"
 169     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 170     llvm_cv_os_type="AIX"
 171     llvm_cv_platform_type="Unix" ;;
 172   *-*-irix*)
 173     llvm_cv_link_all_option="-Wl,--whole-archive"
 174     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 175     llvm_cv_os_type="IRIX"
 176     llvm_cv_platform_type="Unix" ;;
 177   *-*-cygwin*)
 178     llvm_cv_link_all_option="-Wl,--whole-archive"
 179     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 180     llvm_cv_os_type="Cygwin"
 181     llvm_cv_platform_type="Unix" ;;
 182   *-*-darwin*)
 183     llvm_cv_link_all_option="-Wl,-all_load"
 184     llvm_cv_no_link_all_option="-Wl,-noall_load"
 185     llvm_cv_os_type="Darwin"
 186     llvm_cv_platform_type="Unix" ;;
 187   *-*-minix*)
 188     llvm_cv_link_all_option="-Wl,-all_load"
 189     llvm_cv_no_link_all_option="-Wl,-noall_load"
 190     llvm_cv_os_type="Minix"
 191     llvm_cv_platform_type="Unix" ;;
 192   *-*-freebsd*)
 193     llvm_cv_link_all_option="-Wl,--whole-archive"
 194     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 195     llvm_cv_os_type="FreeBSD"
 196     llvm_cv_platform_type="Unix" ;;
 197   *-*-openbsd*)
 198     llvm_cv_link_all_option="-Wl,--whole-archive"
 199     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 200     llvm_cv_os_type="OpenBSD"
 201     llvm_cv_platform_type="Unix" ;;
 202   *-*-netbsd*)
 203     llvm_cv_link_all_option="-Wl,--whole-archive"
 204     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 205     llvm_cv_os_type="NetBSD"
 206     llvm_cv_platform_type="Unix" ;;
 207   *-*-dragonfly*)
 208     llvm_cv_link_all_option="-Wl,--whole-archive"
 209     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 210     llvm_cv_os_type="DragonFly"
 211     llvm_cv_platform_type="Unix" ;;
 212   *-*-hpux*)
 213     llvm_cv_link_all_option="-Wl,--whole-archive"
 214     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 215     llvm_cv_os_type="HP-UX"
 216     llvm_cv_platform_type="Unix" ;;
 217   *-*-interix*)
 218     llvm_cv_link_all_option="-Wl,--whole-archive"
 219     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 220     llvm_cv_os_type="Interix"
 221     llvm_cv_platform_type="Unix" ;;
 222   *-*-linux*)
 223     llvm_cv_link_all_option="-Wl,--whole-archive"
 224     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 225     llvm_cv_os_type="Linux"
 226     llvm_cv_platform_type="Unix" ;;
 227   *-*-solaris*)
 228     llvm_cv_link_all_option="-Wl,-z,allextract"
 229     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 230     llvm_cv_os_type="SunOS"
 231     llvm_cv_platform_type="Unix" ;;
 232   *-*-auroraux*)
 233     llvm_cv_link_all_option="-Wl,-z,allextract"
 234     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 235     llvm_cv_os_type="AuroraUX"
 236     llvm_cv_platform_type="Unix" ;;
 237   *-*-win32*)
 238     llvm_cv_link_all_option="-Wl,--whole-archive"
 239     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 240     llvm_cv_os_type="Win32"
 241     llvm_cv_platform_type="Win32" ;;
 242   *-*-mingw*)
 243     llvm_cv_link_all_option="-Wl,--whole-archive"
 244     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 245     llvm_cv_os_type="MingW"
 246     llvm_cv_platform_type="Win32" ;;
 247   *-*-haiku*)
 248     llvm_cv_link_all_option="-Wl,--whole-archive"
 249     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 250     llvm_cv_os_type="Haiku"
 251     llvm_cv_platform_type="Unix" ;;
 252   *-unknown-eabi*)
 253     llvm_cv_link_all_option="-Wl,--whole-archive"
 254     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 255     llvm_cv_os_type="Freestanding"
 256     llvm_cv_platform_type="Unix" ;;
 257   *-unknown-elf*)
 258     llvm_cv_link_all_option="-Wl,--whole-archive"
 259     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 260     llvm_cv_os_type="Freestanding"
 261     llvm_cv_platform_type="Unix" ;;
 262   *)
 263     llvm_cv_link_all_option=""
 264     llvm_cv_no_link_all_option=""
 265     llvm_cv_os_type="Unknown"
 266     llvm_cv_platform_type="Unknown" ;;
 267 esac])
 268
 269 AC_CACHE_CHECK([type of operating system we're going to target],
 270                [llvm_cv_target_os_type],
 271 [case $target in
 272   *-*-aix*)
 273     llvm_cv_target_os_type="AIX" ;;
 274   *-*-irix*)
 275     llvm_cv_target_os_type="IRIX" ;;
 276   *-*-cygwin*)
 277     llvm_cv_target_os_type="Cygwin" ;;
 278   *-*-darwin*)
 279     llvm_cv_target_os_type="Darwin" ;;
 280   *-*-minix*)
 281     llvm_cv_target_os_type="Minix" ;;
 282   *-*-freebsd*)
 283     llvm_cv_target_os_type="FreeBSD" ;;
 284   *-*-openbsd*)
 285     llvm_cv_target_os_type="OpenBSD" ;;
 286   *-*-netbsd*)
 287     llvm_cv_target_os_type="NetBSD" ;;
 288   *-*-dragonfly*)
 289     llvm_cv_target_os_type="DragonFly" ;;
 290   *-*-hpux*)
 291     llvm_cv_target_os_type="HP-UX" ;;
 292   *-*-interix*)
 293     llvm_cv_target_os_type="Interix" ;;
 294   *-*-linux*)
 295     llvm_cv_target_os_type="Linux" ;;
 296   *-*-solaris*)
 297     llvm_cv_target_os_type="SunOS" ;;
 298   *-*-auroraux*)
 299     llvm_cv_target_os_type="AuroraUX" ;;
 300   *-*-win32*)
 301     llvm_cv_target_os_type="Win32" ;;
 302   *-*-mingw*)
 303     llvm_cv_target_os_type="MingW" ;;
 304   *-*-haiku*)
 305     llvm_cv_target_os_type="Haiku" ;;
 306   *-*-rtems*)
 307     llvm_cv_target_os_type="RTEMS" ;;
 308   *-*-nacl*)
 309     llvm_cv_target_os_type="NativeClient" ;;
 310   *-unknown-eabi*)
 311     llvm_cv_target_os_type="Freestanding" ;;
 312   *)
 313     llvm_cv_target_os_type="Unknown" ;;
 314 esac])
 315
 316 dnl Make sure we aren't attempting to configure for an unknown system
 317 if test "$llvm_cv_os_type" = "Unknown" ; then
 318   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 319 fi
 320
 321 dnl Set the "OS" Makefile variable based on the platform type so the
 322 dnl makefile can configure itself to specific build hosts
 323 AC_SUBST(OS,$llvm_cv_os_type)
 324 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 325 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 326
 327 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 328 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 329 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 330
 331 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 332 dnl This is used by lib/Support to determine the basic kind of implementation
 333 dnl to use.
 334 case $llvm_cv_platform_type in
 335   Unix)
 336     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 337     AC_SUBST(LLVM_ON_UNIX,[1])
 338     AC_SUBST(LLVM_ON_WIN32,[0])
 339     ;;
 340   Win32)
 341     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 342     AC_SUBST(LLVM_ON_UNIX,[0])
 343     AC_SUBST(LLVM_ON_WIN32,[1])
 344     ;;
 345 esac
 346
 347 dnl Determine what our target architecture is and configure accordingly.
 348 dnl This will allow Makefiles to make a distinction between the hardware and
 349 dnl the OS.
 350 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 351 [case $target in
 352   i?86-*)                 llvm_cv_target_arch="x86" ;;
 353   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 354   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 355   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 356   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 357   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 358   mips-*)                 llvm_cv_target_arch="Mips" ;;
 359   xcore-*)                llvm_cv_target_arch="XCore" ;;
 360   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 361   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 362   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 363   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 364   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 365   *)                      llvm_cv_target_arch="Unknown" ;;
 366 esac])
 367
 368 if test "$llvm_cv_target_arch" = "Unknown" ; then
 369   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 370 fi
 371
 372 # Determine the LLVM native architecture for the target
 373 case "$llvm_cv_target_arch" in
 374     x86)     LLVM_NATIVE_ARCH="X86" ;;
 375     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 376     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 377 esac
 378
 379 dnl Define a substitution, ARCH, for the target architecture
 380 AC_SUBST(ARCH,$llvm_cv_target_arch)
 381
 382 dnl Check for the endianness of the target
 383 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 384
 385 dnl Check for build platform executable suffix if we're crosscompiling
 386 if test "$cross_compiling" = yes; then
 387   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 388   AC_BUILD_EXEEXT
 389   ac_build_prefix=${build_alias}-
 390   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 391   if test -z "$BUILD_CXX"; then
 392      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 393      if test -z "$BUILD_CXX"; then
 394        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 395      fi
 396   fi
 397 else
 398   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 399 fi
 400
 401 dnl Check to see if there's a .svn or .git directory indicating that this
 402 dnl build is being done from a checkout. This sets up several defaults for
 403 dnl the command line switches. When we build with a checkout directory,
 404 dnl we get a debug with assertions turned on. Without, we assume a source
 405 dnl release and we get an optimized build without assertions.
 406 dnl See --enable-optimized and --enable-assertions below
 407 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 408   cvsbuild="yes"
 409   optimize="no"
 410   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 411 else
 412   cvsbuild="no"
 413   optimize="yes"
 414 fi
 415
 416 dnl===-----------------------------------------------------------------------===
 417 dnl===
 418 dnl=== SECTION 3: Command line arguments for the configure script.
 419 dnl===
 420 dnl===-----------------------------------------------------------------------===
 421
 422 dnl --enable-optimized : check whether they want to do an optimized build:
 423 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 424  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 425 if test ${enableval} = "no" ; then
 426   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 427 else
 428   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 429 fi
 430
 431 dnl --enable-profiling : check whether they want to do a profile build:
 432 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 433  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 434 if test ${enableval} = "no" ; then
 435   AC_SUBST(ENABLE_PROFILING,[[]])
 436 else
 437   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 438 fi
 439
 440 dnl --enable-assertions : check whether they want to turn on assertions or not:
 441 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 442   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 443 if test ${enableval} = "yes" ; then
 444   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 445 else
 446   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 447 fi
 448
 449 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 450 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 451   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 452 if test ${enableval} = "yes" ; then
 453   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 454   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 455 else
 456   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 457   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 458 fi
 459
 460 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 461 AC_ARG_ENABLE(debug-runtime,
 462    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 463 if test ${enableval} = "no" ; then
 464   AC_SUBST(DEBUG_RUNTIME,[[]])
 465 else
 466   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 467 fi
 468
 469 dnl --enable-debug-symbols : should even optimized compiler libraries
 470 dnl have debug symbols?
 471 AC_ARG_ENABLE(debug-symbols,
 472    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 473 if test ${enableval} = "no" ; then
 474   AC_SUBST(DEBUG_SYMBOLS,[[]])
 475 else
 476   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 477 fi
 478
 479 dnl --enable-jit: check whether they want to enable the jit
 480 AC_ARG_ENABLE(jit,
 481   AS_HELP_STRING(--enable-jit,
 482                  [Enable Just In Time Compiling (default is YES)]),,
 483   enableval=default)
 484 if test ${enableval} = "no"
 485 then
 486   AC_SUBST(JIT,[[]])
 487 else
 488   case "$llvm_cv_target_arch" in
 489     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 490     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 491     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 492     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 493     Alpha)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 494     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 495     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 496     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 497     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 498     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 499     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 500     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 501     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 502     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 503   esac
 504 fi
 505
 506 dnl Allow enablement of building and installing docs
 507 AC_ARG_ENABLE(docs,
 508               AS_HELP_STRING([--enable-docs],
 509                              [Build documents (default is YES)]),,
 510                              enableval=default)
 511 case "$enableval" in
 512   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 513   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 514   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 515   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 516 esac
 517
 518 dnl Allow enablement of doxygen generated documentation
 519 AC_ARG_ENABLE(doxygen,
 520               AS_HELP_STRING([--enable-doxygen],
 521                              [Build doxygen documentation (default is NO)]),,
 522                              enableval=default)
 523 case "$enableval" in
 524   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 525   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 526   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 527   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 528 esac
 529
 530 dnl Allow disablement of threads
 531 AC_ARG_ENABLE(threads,
 532               AS_HELP_STRING([--enable-threads],
 533                              [Use threads if available (default is YES)]),,
 534                              enableval=default)
 535 case "$enableval" in
 536   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 537   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 538   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 539   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 540 esac
 541 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 542
 543 dnl Allow disablement of pthread.h
 544 AC_ARG_ENABLE(pthreads,
 545               AS_HELP_STRING([--enable-pthreads],
 546                              [Use pthreads if available (default is YES)]),,
 547                              enableval=default)
 548 case "$enableval" in
 549   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 550   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 551   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 552   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 553 esac
 554
 555 dnl Allow building without position independent code
 556 AC_ARG_ENABLE(pic,
 557   AS_HELP_STRING([--enable-pic],
 558                  [Build LLVM with Position Independent Code (default is YES)]),,
 559                  enableval=default)
 560 case "$enableval" in
 561   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 562   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 563   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 564   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 565 esac
 566 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 567                    [Define if position independent code is enabled])
 568
 569 dnl Allow building a shared library and linking tools against it.
 570 AC_ARG_ENABLE(shared,
 571   AS_HELP_STRING([--enable-shared],
 572                  [Build a shared library and link tools against it (default is NO)]),,
 573                  enableval=default)
 574 case "$enableval" in
 575   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 576   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 577   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 578   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 579 esac
 580
 581 dnl Allow libstdc++ is embedded in LLVM.dll.
 582 AC_ARG_ENABLE(embed-stdcxx,
 583   AS_HELP_STRING([--enable-embed-stdcxx],
 584                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is YES)]),,
 585                  enableval=default)
 586 case "$enableval" in
 587   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 588   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 589   default) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 590   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 591 esac
 592
 593 dnl Enable embedding timestamp information into build.
 594 AC_ARG_ENABLE(timestamps,
 595   AS_HELP_STRING([--enable-timestamps],
 596                  [Enable embedding timestamp information in build (default is YES)]),,
 597                  enableval=default)
 598 case "$enableval" in
 599   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 600   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 601   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 602   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 603 esac
 604 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 605                    [Define if timestamp information (e.g., __DATE___) is allowed])
 606
 607 dnl Allow specific targets to be specified for building (or not)
 608 TARGETS_TO_BUILD=""
 609 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 610     [Build specific host targets: all or target1,target2,... Valid targets are:
 611      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu,
 612      xcore, msp430, systemz, blackfin, ptx, cbe, and cpp (default=all)]),,
 613     enableval=all)
 614 if test "$enableval" = host-only ; then
 615   enableval=host
 616 fi
 617 case "$enableval" in
 618   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU XCore MSP430 SystemZ Blackfin CBackend CppBackend MBlaze PTX" ;;
 619   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 620       case "$a_target" in
 621         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 622         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 623         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 624         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 625         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 626         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 627         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 628         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 629         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 630         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 631         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 632         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 633         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 634         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 635         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 636         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 637         host) case "$llvm_cv_target_arch" in
 638             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 639             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 640             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 641             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 642             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 643             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 644             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 645             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 646             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 647             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 648             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 649             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 650             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 651             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 652             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 653           esac ;;
 654         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 655       esac
 656   done
 657   ;;
 658 esac
 659 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 660
 661 # Determine whether we are building LLVM support for the native architecture.
 662 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 663 for a_target in $TARGETS_TO_BUILD; do
 664   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 665     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 666       [LLVM architecture name for the native architecture, if available])
 667     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 668     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 669     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 670     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 671     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 672       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 673     fi
 674     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 675       [LLVM name for the native Target init function, if available])
 676     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 677       [LLVM name for the native TargetInfo init function, if available])
 678     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 679       [LLVM name for the native target MC init function, if available])
 680     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 681       [LLVM name for the native AsmPrinter init function, if available])
 682     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 683       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 684        [LLVM name for the native AsmParser init function, if available])
 685     fi
 686   fi
 687 done
 688
 689 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 690 # target feature def files.
 691 LLVM_ENUM_TARGETS=""
 692 LLVM_ENUM_ASM_PRINTERS=""
 693 LLVM_ENUM_ASM_PARSERS=""
 694 LLVM_ENUM_DISASSEMBLERS=""
 695 for target_to_build in $TARGETS_TO_BUILD; do
 696   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 697   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 698     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 699   fi
 700   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 701     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 702   fi
 703   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 704     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 705   fi
 706 done
 707 AC_SUBST(LLVM_ENUM_TARGETS)
 708 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 709 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 710 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 711
 712 dnl Prevent the CBackend from using printf("%a") for floating point so older
 713 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 714 dnl can still compile the CBE's output
 715 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 716   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 717   enableval=default)
 718 case "$enableval" in
 719   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 720   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 721   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 722   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 723 esac
 724 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 725                    [Define if CBE is enabled for printf %a output])
 726
 727 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 728 AC_ARG_WITH(llvmgccdir,
 729   AS_HELP_STRING([--with-llvmgccdir],
 730     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 731     withval=default)
 732 case "$withval" in
 733   default) WITH_LLVMGCCDIR=default ;;
 734   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 735   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 736 esac
 737
 738 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 739 AC_ARG_WITH(llvmgcc,
 740   AS_HELP_STRING([--with-llvmgcc],
 741     [Specify location of llvm-gcc driver (default searches PATH)]),
 742     LLVMGCC=$with_llvmgcc
 743       WITH_LLVMGCCDIR="",)
 744
 745 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 746 AC_ARG_WITH(llvmgxx,
 747   AS_HELP_STRING([--with-llvmgxx],
 748     [Specify location of llvm-g++ driver (default searches PATH)]),
 749     LLVMGXX=$with_llvmgxx
 750     WITH_LLVMGCCDIR="",)
 751
 752 if test -n "$LLVMGCC"; then
 753    LLVMGCCCOMMAND="$LLVMGCC"
 754 fi
 755
 756 if test -n "$LLVMGXX"; then
 757    LLVMGXXCOMMAND="$LLVMGXX"
 758 fi
 759
 760 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 761    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 762 fi
 763
 764 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 765    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 766 fi
 767
 768 dnl Allow a specific Clang compiler to be used with this LLVM config.
 769 AC_ARG_WITH(clang,
 770   AS_HELP_STRING([--with-clang],
 771     [Specify location of clang compiler (default is --with-built-clang)]),
 772     [],[with_clang=default])
 773
 774 dnl Enable use of the built Clang.
 775 AC_ARG_WITH(built-clang,
 776   AS_HELP_STRING([--with-built-clang],
 777     [Use the compiled Clang as the LLVM compiler (default=check)]),
 778     [],[with_built_clang=check])
 779
 780 dnl Select the Clang compiler option.
 781 dnl
 782 dnl If --with-clang is given, always honor that; otherwise honor
 783 dnl --with-built-clang, or check if we have the clang sources.
 784 AC_MSG_CHECKING([clang compiler])
 785 WITH_CLANGPATH=""
 786 WITH_BUILT_CLANG=0
 787 if test "$with_clang" != "default"; then
 788    WITH_CLANGPATH="$with_clang"
 789    if ! test -x "$WITH_CLANGPATH"; then
 790      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 791    fi
 792 elif test "$with_built_clang" = "yes"; then
 793    WITH_BUILT_CLANG=1
 794 elif test "$with_built_clang" = "no"; then
 795    WITH_BUILT_CLANG=0
 796 else
 797    if test "$with_built_clang" != "check"; then
 798       AC_MSG_ERROR([invalid value for --with-built-clang.])
 799    fi
 800
 801    if test -f ${srcdir}/tools/clang/README.txt; then
 802      WITH_BUILT_CLANG=1
 803    fi
 804 fi
 805
 806 if ! test -z "$WITH_CLANGPATH"; then
 807    AC_MSG_RESULT([$WITH_CLANGPATH])
 808    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 809 elif test "$WITH_BUILT_CLANG" = "1"; then
 810    AC_MSG_RESULT([built])
 811 else
 812    AC_MSG_RESULT([none])
 813 fi
 814 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 815 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 816 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 817
 818 dnl Override the option to use for optimized builds.
 819 AC_ARG_WITH(optimize-option,
 820   AS_HELP_STRING([--with-optimize-option],
 821                  [Select the compiler options to use for optimized builds]),,
 822                  withval=default)
 823 AC_MSG_CHECKING([optimization flags])
 824 case "$withval" in
 825   default)
 826     case "$llvm_cv_os_type" in
 827     FreeBSD) optimize_option=-O2 ;;
 828     MingW) optimize_option=-O2 ;;
 829     *)     optimize_option=-O3 ;;
 830     esac ;;
 831   *) optimize_option="$withval" ;;
 832 esac
 833 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 834 AC_MSG_RESULT([$optimize_option])
 835
 836 dnl Specify extra build options
 837 AC_ARG_WITH(extra-options,
 838   AS_HELP_STRING([--with-extra-options],
 839                  [Specify additional options to compile LLVM with]),,
 840                  withval=default)
 841 case "$withval" in
 842   default) EXTRA_OPTIONS= ;;
 843   *) EXTRA_OPTIONS=$withval ;;
 844 esac
 845 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 846
 847 dnl Specify extra linker build options
 848 AC_ARG_WITH(extra-ld-options,
 849   AS_HELP_STRING([--with-extra-ld-options],
 850                  [Specify additional options to link LLVM with]),,
 851                  withval=default)
 852 case "$withval" in
 853   default) EXTRA_LD_OPTIONS= ;;
 854   *) EXTRA_LD_OPTIONS=$withval ;;
 855 esac
 856 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 857
 858 dnl Allow specific bindings to be specified for building (or not)
 859 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 860     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 861     enableval=default)
 862 BINDINGS_TO_BUILD=""
 863 case "$enableval" in
 864   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 865   all ) BINDINGS_TO_BUILD="ocaml" ;;
 866   none | no) BINDINGS_TO_BUILD="" ;;
 867   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 868       case "$a_binding" in
 869         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 870         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 871       esac
 872   done
 873   ;;
 874 esac
 875
 876 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 877 dnl script for bindings/ocaml/configure, except that its auto value depends on
 878 dnl OCAMLC, which is found here to support tests.
 879 AC_ARG_WITH([ocaml-libdir],
 880   [AS_HELP_STRING([--with-ocaml-libdir],
 881     [Specify install location for ocaml bindings (default is stdlib)])],
 882   [],
 883   [withval=auto])
 884 case "$withval" in
 885   auto) with_ocaml_libdir="$withval" ;;
 886   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 887   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 888 esac
 889
 890 AC_ARG_WITH(clang-resource-dir,
 891   AS_HELP_STRING([--with-clang-resource-dir],
 892     [Relative directory from the Clang binary for resource files]),,
 893     withval="")
 894 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 895                    [Relative directory for resource files])
 896
 897 AC_ARG_WITH(c-include-dirs,
 898   AS_HELP_STRING([--with-c-include-dirs],
 899     [Colon separated list of directories clang will search for headers]),,
 900     withval="")
 901 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 902                    [Directories clang will search for headers])
 903
 904 AC_ARG_WITH(cxx-include-root,
 905   AS_HELP_STRING([--with-cxx-include-root],
 906     [Directory with the libstdc++ headers.]),,
 907     withval="")
 908 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 909                    [Directory with the libstdc++ headers.])
 910
 911 AC_ARG_WITH(cxx-include-arch,
 912   AS_HELP_STRING([--with-cxx-include-arch],
 913     [Architecture of the libstdc++ headers.]),,
 914     withval="")
 915 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 916                    [Arch the libstdc++ headers.])
 917
 918 AC_ARG_WITH(cxx-include-32bit-dir,
 919   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 920     [32 bit multilib dir.]),,
 921     withval="")
 922 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 923                    [32 bit multilib directory.])
 924
 925 AC_ARG_WITH(cxx-include-64bit-dir,
 926   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 927     [64 bit multilib directory.]),,
 928     withval="")
 929 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 930                    [64 bit multilib directory.])
 931
 932 dnl Allow linking of LLVM with GPLv3 binutils code.
 933 AC_ARG_WITH(binutils-include,
 934   AS_HELP_STRING([--with-binutils-include],
 935     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 936   withval=default)
 937 case "$withval" in
 938   default) WITH_BINUTILS_INCDIR=default ;;
 939   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 940   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 941 esac
 942 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 943   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 944   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 945      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 946      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 947   fi
 948 fi
 949
 950 dnl Specify the URL where bug reports should be submitted.
 951 AC_ARG_WITH(bug-report-url,
 952   AS_HELP_STRING([--with-bug-report-url],
 953     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 954     withval="http://llvm.org/bugs/")
 955 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 956                    [Bug report URL.])
 957
 958 dnl --enable-libffi : check whether the user wants to turn off libffi:
 959 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 960   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 961   [case "$enableval" in
 962     yes) llvm_cv_enable_libffi="yes" ;;
 963     no)  llvm_cv_enable_libffi="no"  ;;
 964     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 965   esac],
 966   llvm_cv_enable_libffi=no)
 967
 968 dnl===-----------------------------------------------------------------------===
 969 dnl===
 970 dnl=== SECTION 4: Check for programs we need and that they are the right version
 971 dnl===
 972 dnl===-----------------------------------------------------------------------===
 973
 974 AC_PROG_NM
 975 AC_SUBST(NM)
 976
 977 dnl Check for the tools that the makefiles require
 978 AC_CHECK_GNU_MAKE
 979 AC_PROG_LN_S
 980 AC_PATH_PROG(CMP, [cmp], [cmp])
 981 AC_PATH_PROG(CP, [cp], [cp])
 982 AC_PATH_PROG(DATE, [date], [date])
 983 AC_PATH_PROG(FIND, [find], [find])
 984 AC_PATH_PROG(GREP, [grep], [grep])
 985 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 986 AC_PATH_PROG(MV,   [mv],   [mv])
 987 AC_PROG_RANLIB
 988 AC_CHECK_TOOL(AR, ar, false)
 989 AC_PATH_PROG(RM,   [rm],   [rm])
 990 AC_PATH_PROG(SED,  [sed],  [sed])
 991 AC_PATH_PROG(TAR,  [tar],  [gtar])
 992 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 993
 994 dnl Looking for misc. graph plotting software
 995 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 996 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 997   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 998   dnl If we're targeting for mingw we should emit windows paths, not msys
 999   if test "$llvm_cv_os_type" = "MingW" ; then
1000     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1001   fi
1002   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1003    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1004 fi
1005 AC_PATH_PROG(DOT, [dot], [echo dot])
1006 if test "$DOT" != "echo dot" ; then
1007   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1008   dnl If we're targeting for mingw we should emit windows paths, not msys
1009   if test "$llvm_cv_os_type" = "MingW" ; then
1010     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1011   fi
1012   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1013    [Define to path to dot program if found or 'echo dot' otherwise])
1014 fi
1015 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1016 if test "$FDP" != "echo fdp" ; then
1017   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1018   dnl If we're targeting for mingw we should emit windows paths, not msys
1019   if test "$llvm_cv_os_type" = "MingW" ; then
1020     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1021   fi
1022   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1023    [Define to path to fdp program if found or 'echo fdp' otherwise])
1024 fi
1025 AC_PATH_PROG(NEATO, [neato], [echo neato])
1026 if test "$NEATO" != "echo neato" ; then
1027   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1028   dnl If we're targeting for mingw we should emit windows paths, not msys
1029   if test "$llvm_cv_os_type" = "MingW" ; then
1030     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1031   fi
1032   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1033    [Define to path to neato program if found or 'echo neato' otherwise])
1034 fi
1035 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1036 if test "$TWOPI" != "echo twopi" ; then
1037   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1038   dnl If we're targeting for mingw we should emit windows paths, not msys
1039   if test "$llvm_cv_os_type" = "MingW" ; then
1040     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1041   fi
1042   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1043    [Define to path to twopi program if found or 'echo twopi' otherwise])
1044 fi
1045 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1046 if test "$CIRCO" != "echo circo" ; then
1047   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1048   dnl If we're targeting for mingw we should emit windows paths, not msys
1049   if test "$llvm_cv_os_type" = "MingW" ; then
1050     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1051   fi
1052   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1053    [Define to path to circo program if found or 'echo circo' otherwise])
1054 fi
1055 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1056 if test "$GV" != "echo gv" ; then
1057   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1058   dnl If we're targeting for mingw we should emit windows paths, not msys
1059   if test "$llvm_cv_os_type" = "MingW" ; then
1060     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1061   fi
1062   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1063    [Define to path to gv program if found or 'echo gv' otherwise])
1064 fi
1065 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1066 if test "$DOTTY" != "echo dotty" ; then
1067   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1068   dnl If we're targeting for mingw we should emit windows paths, not msys
1069   if test "$llvm_cv_os_type" = "MingW" ; then
1070     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1071   fi
1072   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1073    [Define to path to dotty program if found or 'echo dotty' otherwise])
1074 fi
1075 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1076 if test "$XDOT_PY" != "echo xdot.py" ; then
1077   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1078   dnl If we're targeting for mingw we should emit windows paths, not msys
1079   if test "$llvm_cv_os_type" = "MingW" ; then
1080     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1081   fi
1082   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1083    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1084 fi
1085
1086 dnl Look for a sufficiently recent version of Perl.
1087 LLVM_PROG_PERL([5.006])
1088 AC_SUBST(PERL)
1089 if test x"$PERL" = xnone; then
1090    AC_SUBST(HAVE_PERL,0)
1091    AC_MSG_ERROR([perl is required but was not found, please install it])
1092 else
1093    AC_SUBST(HAVE_PERL,1)
1094 fi
1095
1096 dnl Find the install program
1097 AC_PROG_INSTALL
1098 dnl Prepend src dir to install path dir if it's a relative path
1099 dnl This is a hack for installs that take place in something other
1100 dnl than the top level.
1101 case "$INSTALL" in
1102  [[\\/$]]* | ?:[[\\/]]* ) ;;
1103  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1104 esac
1105
1106 dnl Checks for documentation and testing tools that we can do without. If these
1107 dnl are not found then they are set to "true" which always succeeds but does
1108 dnl nothing. This just lets the build output show that we could have done
1109 dnl something if the tool was available.
1110 AC_PATH_PROG(BZIP2, [bzip2])
1111 AC_PATH_PROG(CAT, [cat])
1112 AC_PATH_PROG(DOXYGEN, [doxygen])
1113 AC_PATH_PROG(GROFF, [groff])
1114 AC_PATH_PROG(GZIPBIN, [gzip])
1115 AC_PATH_PROG(POD2HTML, [pod2html])
1116 AC_PATH_PROG(POD2MAN, [pod2man])
1117 AC_PATH_PROG(PDFROFF, [pdfroff])
1118 AC_PATH_PROG(RUNTEST, [runtest])
1119 DJ_AC_PATH_TCLSH
1120 AC_PATH_PROG(ZIP, [zip])
1121 AC_PATH_PROGS(OCAMLC, [ocamlc])
1122 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1123 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1124 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1125 AC_PATH_PROGS(GAS, [gas as])
1126
1127 dnl Get the version of the linker in use.
1128 AC_LINK_GET_VERSION
1129
1130 dnl Determine whether the linker supports the -R option.
1131 AC_LINK_USE_R
1132
1133 dnl Determine whether the linker supports the -export-dynamic option.
1134 AC_LINK_EXPORT_DYNAMIC
1135
1136 dnl Determine whether the linker supports the --version-script option.
1137 AC_LINK_VERSION_SCRIPT
1138
1139 dnl Check for libtool and the library that has dlopen function (which must come
1140 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1141 dnl libtool).
1142 AC_LIBTOOL_DLOPEN
1143 AC_LIB_LTDL
1144
1145 if test "$WITH_LLVMGCCDIR" = "default" ; then
1146   LLVMGCC="llvm-gcc${EXEEXT}"
1147   LLVMGXX="llvm-g++${EXEEXT}"
1148   LLVMGCCCOMMAND="$LLVMGCC"
1149   LLVMGXXCOMMAND="$LLVMGXX"
1150   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1151   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1152   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
1153   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
1154 else
1155   if test -z "$LLVMGCC"; then
1156     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
1157     LLVMGCCCOMMAND="$LLVMGCC"
1158   fi
1159   if test -z "$LLVMGXX"; then
1160     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1161     LLVMGXXCOMMAND="$LLVMGXX"
1162   fi
1163
1164   AC_SUBST(LLVMGCC,$LLVMGCC)
1165   AC_SUBST(LLVMGXX,$LLVMGXX)
1166   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1167   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1168 fi
1169
1170 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1171 dnl found, otherwise clang if available.
1172 AC_ARG_WITH(llvmcc,
1173   AS_HELP_STRING([--with-llvmcc=<name>],
1174     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1175     [],[with_llvmcc=check])
1176 AC_MSG_CHECKING([LLVM capable compiler])
1177 if test "$with_llvmcc" != "check"; then
1178    if (test "$with_llvmcc" != "llvm-gcc" &&
1179        test "$with_llvmcc" != "clang" &&
1180        test "$with_llvmcc" != "none"); then
1181       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1182    fi
1183    WITH_LLVMCC="$with_llvmcc"
1184 elif test -n "$LLVMGCC"; then
1185    WITH_LLVMCC=llvm-gcc
1186 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1187    WITH_LLVMCC=clang
1188 else
1189    WITH_LLVMCC=none
1190 fi
1191 AC_MSG_RESULT([$WITH_LLVMCC])
1192 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1193
1194 AC_MSG_CHECKING([tool compatibility])
1195
1196 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1197 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1198 dnl to support those options.
1199 dnl "icc" emits gcc signatures
1200 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1201 ICC=no
1202 IXX=no
1203 case $CC in
1204   icc*|icpc*)
1205     ICC=yes
1206     IXX=yes
1207     ;;
1208    *)
1209     ;;
1210 esac
1211
1212 if test "$GCC" != "yes" && test "$ICC" != "yes"
1213 then
1214   AC_MSG_ERROR([gcc|icc required but not found])
1215 fi
1216
1217 dnl Ensure that compilation tools are compatible with GCC extensions
1218 if test "$GXX" != "yes" && test "$IXX" != "yes"
1219 then
1220   AC_MSG_ERROR([g++|clang++|icc required but not found])
1221 fi
1222
1223 dnl Verify that GCC is version 3.0 or higher
1224 if test "$GCC" = "yes"
1225 then
1226   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1227 #error Unsupported GCC version
1228 #endif
1229 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1230 fi
1231
1232 dnl Check for GNU Make.  We use its extensions, so don't build without it
1233 if test -z "$llvm_cv_gnu_make_command"
1234 then
1235   AC_MSG_ERROR([GNU Make required but not found])
1236 fi
1237
1238 dnl Tool compatibility is okay if we make it here.
1239 AC_MSG_RESULT([ok])
1240
1241 dnl Check optional compiler flags.
1242 AC_MSG_CHECKING([optional compiler flags])
1243 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1244 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1245 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1246
1247 dnl===-----------------------------------------------------------------------===
1248 dnl===
1249 dnl=== SECTION 5: Check for libraries
1250 dnl===
1251 dnl===-----------------------------------------------------------------------===
1252
1253 AC_CHECK_LIB(m,sin)
1254 if test "$llvm_cv_os_type" = "MingW" ; then
1255   AC_CHECK_LIB(imagehlp, main)
1256   AC_CHECK_LIB(psapi, main)
1257 fi
1258
1259 dnl dlopen() is required for plugin support.
1260 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1261                [Define if dlopen() is available on this platform.]),
1262                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1263
1264 dnl libffi is optional; used to call external functions from the interpreter
1265 if test "$llvm_cv_enable_libffi" = "yes" ; then
1266   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1267                  [Define if libffi is available on this platform.]),
1268                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1269 fi
1270
1271 dnl mallinfo is optional; the code can compile (minus features) without it
1272 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1273                [Define if mallinfo() is available on this platform.]))
1274
1275 dnl pthread locking functions are optional - but llvm will not be thread-safe
1276 dnl without locks.
1277 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1278   AC_CHECK_LIB(pthread, pthread_mutex_init)
1279   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1280                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1281                            [Have pthread_mutex_lock]))
1282   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1283                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1284                  [Have pthread_rwlock_init]))
1285   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1286                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1287                  [Have pthread_getspecific]))
1288 fi
1289
1290 dnl Allow extra x86-disassembler library
1291 AC_ARG_WITH(udis86,
1292   AS_HELP_STRING([--with-udis86=<path>],
1293     [Use udis86 external x86 disassembler library]),
1294     [
1295       AC_SUBST(USE_UDIS86, [1])
1296       case "$withval" in
1297         /usr/lib|yes) ;;
1298         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1299       esac
1300       AC_CHECK_LIB(udis86, ud_init, [], [
1301         echo "Error! You need to have libudis86 around."
1302         exit -1
1303       ])
1304     ],
1305     AC_SUBST(USE_UDIS86, [0]))
1306 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1307                    [Define if use udis86 library])
1308
1309 dnl Allow OProfile support for JIT output.
1310 AC_ARG_WITH(oprofile,
1311   AS_HELP_STRING([--with-oprofile=<prefix>],
1312     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1313     [
1314       AC_SUBST(USE_OPROFILE, [1])
1315       case "$withval" in
1316         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1317         no) llvm_cv_oppath=
1318             AC_SUBST(USE_OPROFILE, [0]) ;;
1319         *) llvm_cv_oppath="${withval}/lib/oprofile"
1320            CPPFLAGS="-I${withval}/include";;
1321       esac
1322       if test -n "$llvm_cv_oppath" ; then
1323         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1324         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1325         dnl libbfd is not included properly in libopagent in some Debian
1326         dnl versions.  If libbfd isn't found at all, we assume opagent works
1327         dnl anyway.
1328         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1329         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1330           echo "Error! You need to have libopagent around."
1331           exit -1
1332         ])
1333         AC_CHECK_HEADER([opagent.h], [], [
1334           echo "Error! You need to have opagent.h around."
1335           exit -1
1336           ])
1337       fi
1338     ],
1339     [
1340       AC_SUBST(USE_OPROFILE, [0])
1341     ])
1342 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1343                    [Define if we have the oprofile JIT-support library])
1344
1345 dnl===-----------------------------------------------------------------------===
1346 dnl===
1347 dnl=== SECTION 6: Check for header files
1348 dnl===
1349 dnl===-----------------------------------------------------------------------===
1350
1351 dnl First, use autoconf provided macros for specific headers that we need
1352 dnl We don't check for ancient stuff or things that are guaranteed to be there
1353 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1354 dnl Generally we're looking for POSIX headers.
1355 AC_HEADER_DIRENT
1356 AC_HEADER_MMAP_ANONYMOUS
1357 AC_HEADER_STAT
1358 AC_HEADER_STDC
1359 AC_HEADER_SYS_WAIT
1360 AC_HEADER_TIME
1361
1362 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1363 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1364 AC_CHECK_HEADERS([utime.h windows.h])
1365 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1366 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1367 AC_CHECK_HEADERS([valgrind/valgrind.h])
1368 AC_CHECK_HEADERS([fenv.h])
1369 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1370   AC_CHECK_HEADERS(pthread.h,
1371                    AC_SUBST(HAVE_PTHREAD, 1),
1372                    AC_SUBST(HAVE_PTHREAD, 0))
1373 else
1374   AC_SUBST(HAVE_PTHREAD, 0)
1375 fi
1376
1377 dnl Try to find ffi.h.
1378 if test "$llvm_cv_enable_libffi" = "yes" ; then
1379   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1380 fi
1381
1382 dnl Try to find Darwin specific crash reporting libraries.
1383 AC_CHECK_HEADERS([CrashReporterClient.h])
1384
1385 dnl Try to find Darwin specific crash reporting global.
1386 AC_MSG_CHECKING([__crashreporter_info__])
1387 AC_LINK_IFELSE(
1388   AC_LANG_SOURCE(
1389     [[extern const char *__crashreporter_info__;
1390       int main() {
1391         __crashreporter_info__ = "test";
1392         return 0;
1393       }
1394     ]]),
1395   AC_MSG_RESULT(yes)
1396   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1397   AC_MSG_RESULT(no)
1398   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1399             Define if __crashreporter_info__ exists.))
1400
1401 dnl===-----------------------------------------------------------------------===
1402 dnl===
1403 dnl=== SECTION 7: Check for types and structures
1404 dnl===
1405 dnl===-----------------------------------------------------------------------===
1406
1407 AC_HUGE_VAL_CHECK
1408 AC_TYPE_PID_T
1409 AC_TYPE_SIZE_T
1410 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1411 AC_STRUCT_TM
1412 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1413 AC_CHECK_TYPES([uint64_t],,
1414          AC_CHECK_TYPES([u_int64_t],,
1415          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1416
1417 dnl===-----------------------------------------------------------------------===
1418 dnl===
1419 dnl=== SECTION 8: Check for specific functions needed
1420 dnl===
1421 dnl===-----------------------------------------------------------------------===
1422
1423 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1424 AC_CHECK_FUNCS([powf fmodf strtof round ])
1425 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1426 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1427 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1428 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1429 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1430 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1431 AC_C_PRINTF_A
1432 AC_FUNC_RAND48
1433
1434 dnl Check the declaration "Secure API" on Windows environments.
1435 AC_CHECK_DECLS([strerror_s])
1436
1437 dnl Check symbols in libgcc.a for JIT on Mingw.
1438 if test "$llvm_cv_os_type" = "MingW" ; then
1439   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1440   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1441   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1442   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1443
1444   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1445   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1446   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1447   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1448   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1449   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1450   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1451   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1452   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1453   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1454
1455   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1456   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1457 fi
1458
1459 dnl Check Win32 API EnumerateLoadedModules.
1460 if test "$llvm_cv_os_type" = "MingW" ; then
1461   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1462   AC_COMPILE_IFELSE([[#include <windows.h>
1463 #include <imagehlp.h>
1464 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1465 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1466 [
1467   AC_MSG_RESULT([yes])
1468   llvm_cv_win32_elmcb_pcstr="PCSTR"
1469 ],
1470 [
1471   AC_MSG_RESULT([no])
1472   llvm_cv_win32_elmcb_pcstr="PSTR"
1473 ])
1474   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1475 fi
1476
1477 dnl Check for variations in the Standard C++ library and STL. These macros are
1478 dnl provided by LLVM in the autoconf/m4 directory.
1479 AC_FUNC_ISNAN
1480 AC_FUNC_ISINF
1481
1482 dnl Check for mmap support.We also need to know if /dev/zero is required to
1483 dnl be opened for allocating RWX memory.
1484 dnl Make sure we aren't attempting to configure for an unknown system
1485 if test "$llvm_cv_platform_type" = "Unix" ; then
1486   AC_FUNC_MMAP
1487   AC_FUNC_MMAP_FILE
1488   AC_NEED_DEV_ZERO_FOR_MMAP
1489
1490   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1491   then
1492     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1493   fi
1494   if test "$ac_cv_func_mmap_file" = "no"
1495   then
1496     AC_MSG_WARN([mmap() of files required but not found])
1497   fi
1498 fi
1499
1500 dnl atomic builtins are required for threading support.
1501 AC_MSG_CHECKING(for GCC atomic builtins)
1502 dnl Since we'll be using these atomic builtins in C++ files we should test
1503 dnl the C++ compiler.
1504 AC_LANG_PUSH([C++])
1505 AC_LINK_IFELSE(
1506   AC_LANG_SOURCE(
1507     [[int main() {
1508         volatile unsigned long val = 1;
1509         __sync_synchronize();
1510         __sync_val_compare_and_swap(&val, 1, 0);
1511         __sync_add_and_fetch(&val, 1);
1512         __sync_sub_and_fetch(&val, 1);
1513         return 0;
1514       }
1515     ]]),
1516   AC_LANG_POP([C++])
1517   AC_MSG_RESULT(yes)
1518   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1519   AC_MSG_RESULT(no)
1520   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1521   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1522
1523 dnl===-----------------------------------------------------------------------===
1524 dnl===
1525 dnl=== SECTION 9: Additional checks, variables, etc.
1526 dnl===
1527 dnl===-----------------------------------------------------------------------===
1528
1529 dnl Handle 32-bit linux systems running a 64-bit kernel.
1530 dnl This has to come after section 4 because it invokes the compiler.
1531 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1532   AC_IS_LINUX_MIXED
1533   if test "$llvm_cv_linux_mixed" = "yes"; then
1534     llvm_cv_target_arch="x86"
1535     ARCH="x86"
1536   fi
1537 fi
1538
1539 dnl Check, whether __dso_handle is present
1540 AC_CHECK_FUNCS([__dso_handle])
1541
1542 dnl Check wether llvm-gcc is based on dragonegg
1543 AC_CACHE_CHECK([whether llvm-gcc is dragonegg],[llvm_cv_llvmgcc_dragonegg],
1544 [llvm_cv_llvmgcc_dragonegg="no"
1545 if test -n "$LLVMGCC" ; then
1546   cp /dev/null conftest.c
1547   $LLVMGCC -fplugin-arg-dragonegg-emit-ir -S -o - conftest.c > /dev/null 2>&1
1548   if test $? -eq 0 ; then
1549     llvm_cv_llvmgcc_dragonegg="yes"
1550   fi
1551   rm conftest.c
1552 fi])
1553
1554 dnl Set the flags needed to emit LLVM IR and to disable optimizations
1555 dnl in llvmgcc
1556 if test "$llvm_cv_llvmgcc_dragonegg" = "yes" ; then
1557   LLVMCC_EMITIR_FLAG="-fplugin-arg-dragonegg-emit-ir"
1558   LLVMCC_DISABLEOPT_FLAGS="-fplugin-arg-dragonegg-llvm-ir-optimize=0"
1559 else
1560   LLVMCC_EMITIR_FLAG="-emit-llvm"
1561   LLVMCC_DISABLEOPT_FLAGS="-mllvm -disable-llvm-optzns"
1562 fi
1563
1564 AC_SUBST(LLVMCC_EMITIR_FLAG)
1565
1566 dnl See if the llvm-gcc executable can compile to LLVM assembly
1567 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1568 [llvm_cv_llvmgcc_sanity="no"
1569 if test -n "$LLVMGCC" ; then
1570   cp /dev/null conftest.c
1571   $LLVMGCC "$LLVMCC_EMITIR_FLAG" -S -o - conftest.c | \
1572       grep 'target datalayout =' > /dev/null 2>&1
1573   if test $? -eq 0 ; then
1574     llvm_cv_llvmgcc_sanity="yes"
1575   fi
1576   rm conftest.c
1577 fi])
1578
1579 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1580 dnl Furthermore, add some information about the tools
1581 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1582   AC_MSG_CHECKING([llvm-gcc component support])
1583   llvmcc1path=`$LLVMGCC --print-prog-name=cc1`
1584   AC_SUBST(LLVMCC1,$llvmcc1path)
1585   llvmcc1pluspath=`$LLVMGCC --print-prog-name=cc1plus`
1586   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1587   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1588   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1589   llvmgcclangs=[`$LLVMGCC -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1590   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1591   AC_SUBST(LLVMGCC_DRAGONEGG,$llvm_cv_llvmgcc_dragonegg)
1592   AC_SUBST(LLVMCC_DISABLEOPT_FLAGS)
1593   AC_MSG_RESULT([ok])
1594 fi
1595
1596 dnl Propagate the shared library extension that the libltdl checks did to
1597 dnl the Makefiles so we can use it there too
1598 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1599
1600 dnl Propagate the run-time library path variable that the libltdl
1601 dnl checks found to the Makefiles so we can use it there too
1602 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1603
1604 # Translate the various configuration directories and other basic
1605 # information into substitutions that will end up in Makefile.config.in
1606 # that these configured values can be used by the makefiles
1607 if test "${prefix}" = "NONE" ; then
1608   prefix="/usr/local"
1609 fi
1610 eval LLVM_PREFIX="${prefix}";
1611 eval LLVM_BINDIR="${prefix}/bin";
1612 eval LLVM_LIBDIR="${prefix}/lib";
1613 eval LLVM_DATADIR="${prefix}/share/llvm";
1614 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1615 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1616 eval LLVM_INCLUDEDIR="${prefix}/include";
1617 eval LLVM_INFODIR="${prefix}/info";
1618 eval LLVM_MANDIR="${prefix}/man";
1619 LLVM_CONFIGTIME=`date`
1620 AC_SUBST(LLVM_PREFIX)
1621 AC_SUBST(LLVM_BINDIR)
1622 AC_SUBST(LLVM_LIBDIR)
1623 AC_SUBST(LLVM_DATADIR)
1624 AC_SUBST(LLVM_DOCSDIR)
1625 AC_SUBST(LLVM_ETCDIR)
1626 AC_SUBST(LLVM_INCLUDEDIR)
1627 AC_SUBST(LLVM_INFODIR)
1628 AC_SUBST(LLVM_MANDIR)
1629 AC_SUBST(LLVM_CONFIGTIME)
1630
1631 # Place the various directores into the config.h file as #defines so that we
1632 # can know about the installation paths within LLVM.
1633 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1634                    [Installation prefix directory])
1635 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1636                    [Installation directory for binary executables])
1637 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1638                    [Installation directory for libraries])
1639 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1640                    [Installation directory for data files])
1641 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1642                    [Installation directory for documentation])
1643 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1644                    [Installation directory for config files])
1645 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1646                    [Installation directory for include files])
1647 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1648                    [Installation directory for .info files])
1649 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1650                    [Installation directory for man pages])
1651 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1652                    [Time at which LLVM was configured])
1653 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1654                    [Host triple we were built on])
1655
1656 # Determine which bindings to build.
1657 if test "$BINDINGS_TO_BUILD" = auto ; then
1658   BINDINGS_TO_BUILD=""
1659   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1660     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1661   fi
1662 fi
1663 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1664
1665 # This isn't really configurey, but it avoids having to repeat the list in
1666 # other files.
1667 AC_SUBST(ALL_BINDINGS,ocaml)
1668
1669 # Do any work necessary to ensure that bindings have what they need.
1670 binding_prereqs_failed=0
1671 for a_binding in $BINDINGS_TO_BUILD ; do
1672   case "$a_binding" in
1673   ocaml)
1674     if test "x$OCAMLC" = x ; then
1675       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1676       binding_prereqs_failed=1
1677     fi
1678     if test "x$OCAMLDEP" = x ; then
1679       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1680       binding_prereqs_failed=1
1681     fi
1682     if test "x$OCAMLOPT" = x ; then
1683       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1684       dnl ocamlopt is optional!
1685     fi
1686     if test "x$with_ocaml_libdir" != xauto ; then
1687       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1688     else
1689       ocaml_stdlib="`"$OCAMLC" -where`"
1690       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1691       then
1692         # ocaml stdlib is beneath our prefix; use stdlib
1693         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1694       else
1695         # ocaml stdlib is outside our prefix; use libdir/ocaml
1696         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1697       fi
1698     fi
1699     ;;
1700   esac
1701 done
1702 if test "$binding_prereqs_failed" = 1 ; then
1703   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1704 fi
1705
1706 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1707 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1708
1709 dnl Determine linker rpath flag
1710 if test "$llvm_cv_link_use_r" = "yes" ; then
1711   RPATH="-Wl,-R"
1712 else
1713   RPATH="-Wl,-rpath"
1714 fi
1715 AC_SUBST(RPATH)
1716
1717 dnl Determine linker rdynamic flag
1718 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1719   RDYNAMIC="-Wl,-export-dynamic"
1720 else
1721   RDYNAMIC=""
1722 fi
1723 AC_SUBST(RDYNAMIC)
1724
1725 dnl===-----------------------------------------------------------------------===
1726 dnl===
1727 dnl=== SECTION 10: Specify the output files and generate it
1728 dnl===
1729 dnl===-----------------------------------------------------------------------===
1730
1731 dnl Configure header files
1732 dnl WARNING: dnl If you add or remove any of the following config headers, then
1733 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1734 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1735 dnl files can be updated automatically when their *.in sources change.
1736 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1737 AH_TOP([#ifndef CONFIG_H
1738 #define CONFIG_H])
1739 AH_BOTTOM([#endif])
1740
1741 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1742 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1743 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1744 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1745 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1746
1747 dnl Configure the makefile's configuration data
1748 AC_CONFIG_FILES([Makefile.config])
1749
1750 dnl Configure the RPM spec file for LLVM
1751 AC_CONFIG_FILES([llvm.spec])
1752
1753 dnl Configure doxygen's configuration file
1754 AC_CONFIG_FILES([docs/doxygen.cfg])
1755 if test -f ${srcdir}/tools/clang/README.txt; then
1756   AC_CONFIG_FILES([tools/clang/docs/doxygen.cfg])
1757 fi
1758
1759 dnl Configure llvmc's Base plugin
1760 AC_CONFIG_FILES([tools/llvmc/src/Base.td])
1761
1762 dnl Do the first stage of configuration for llvm-config.in.
1763 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1764
1765 dnl Do special configuration of Makefiles
1766 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1767 AC_CONFIG_MAKEFILE(Makefile)
1768 AC_CONFIG_MAKEFILE(Makefile.common)
1769 AC_CONFIG_MAKEFILE(examples/Makefile)
1770 AC_CONFIG_MAKEFILE(lib/Makefile)
1771 AC_CONFIG_MAKEFILE(runtime/Makefile)
1772 AC_CONFIG_MAKEFILE(test/Makefile)
1773 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1774 AC_CONFIG_MAKEFILE(unittests/Makefile)
1775 AC_CONFIG_MAKEFILE(tools/Makefile)
1776 AC_CONFIG_MAKEFILE(utils/Makefile)
1777 AC_CONFIG_MAKEFILE(projects/Makefile)
1778 AC_CONFIG_MAKEFILE(bindings/Makefile)
1779 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1780
1781 dnl Finally, crank out the output
1782 AC_OUTPUT