autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.7svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2009 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2009 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-auroraux*)
 169     llvm_cv_link_all_option="-Wl,-z,allextract"
 170     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 171     llvm_cv_os_type="AuroraUX"
 172     llvm_cv_platform_type="Unix" ;;
 173   *-*-win32*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="Win32"
 177     llvm_cv_platform_type="Win32" ;;
 178   *-*-mingw*)
 179     llvm_cv_link_all_option="-Wl,--whole-archive"
 180     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 181     llvm_cv_os_type="MingW"
 182     llvm_cv_platform_type="Win32" ;;
 183   *-*-haiku*)
 184     llvm_cv_link_all_option="-Wl,--whole-archive"
 185     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 186     llvm_cv_os_type="Haiku"
 187     llvm_cv_platform_type="Unix" ;;
 188   *-unknown-eabi*)
 189     llvm_cv_link_all_option="-Wl,--whole-archive"
 190     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 191     llvm_cv_os_type="Freestanding"
 192     llvm_cv_platform_type="Unix" ;;
 193   *-unknown-elf*)
 194     llvm_cv_link_all_option="-Wl,--whole-archive"
 195     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 196     llvm_cv_os_type="Freestanding"
 197     llvm_cv_platform_type="Unix" ;;
 198   *)
 199     llvm_cv_link_all_option=""
 200     llvm_cv_no_link_all_option=""
 201     llvm_cv_os_type="Unknown"
 202     llvm_cv_platform_type="Unknown" ;;
 203 esac])
 204
 205 AC_CACHE_CHECK([type of operating system we're going to target],
 206                [llvm_cv_target_os_type],
 207 [case $target in
 208   *-*-aix*)
 209     llvm_cv_target_os_type="AIX" ;;
 210   *-*-irix*)
 211     llvm_cv_target_os_type="IRIX" ;;
 212   *-*-cygwin*)
 213     llvm_cv_target_os_type="Cygwin" ;;
 214   *-*-darwin*)
 215     llvm_cv_target_os_type="Darwin" ;;
 216   *-*-freebsd*)
 217     llvm_cv_target_os_type="FreeBSD" ;;
 218   *-*-openbsd*)
 219     llvm_cv_target_os_type="OpenBSD" ;;
 220   *-*-netbsd*)
 221     llvm_cv_target_os_type="NetBSD" ;;
 222   *-*-dragonfly*)
 223     llvm_cv_target_os_type="DragonFly" ;;
 224   *-*-hpux*)
 225     llvm_cv_target_os_type="HP-UX" ;;
 226   *-*-interix*)
 227     llvm_cv_target_os_type="Interix" ;;
 228   *-*-linux*)
 229     llvm_cv_target_os_type="Linux" ;;
 230   *-*-solaris*)
 231     llvm_cv_target_os_type="SunOS" ;;
 232   *-*-auroraux*)
 233     llvm_cv_target_os_type="AuroraUX" ;;
 234   *-*-win32*)
 235     llvm_cv_target_os_type="Win32" ;;
 236   *-*-mingw*)
 237     llvm_cv_target_os_type="MingW" ;;
 238   *-*-haiku*)
 239     llvm_cv_target_os_type="Haiku" ;;
 240   *-unknown-eabi*)
 241     llvm_cv_target_os_type="Freestanding" ;;
 242   *)
 243     llvm_cv_target_os_type="Unknown" ;;
 244 esac])
 245
 246 dnl Make sure we aren't attempting to configure for an unknown system
 247 if test "$llvm_cv_os_type" = "Unknown" ; then
 248   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 249 fi
 250
 251 dnl Set the "OS" Makefile variable based on the platform type so the
 252 dnl makefile can configure itself to specific build hosts
 253 AC_SUBST(OS,$llvm_cv_os_type)
 254 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 255 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 256
 257 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 258 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 259 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 260
 261 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 262 dnl This is used by lib/System to determine the basic kind of implementation
 263 dnl to use.
 264 case $llvm_cv_platform_type in
 265   Unix)
 266     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 267     AC_SUBST(LLVM_ON_UNIX,[1])
 268     AC_SUBST(LLVM_ON_WIN32,[0])
 269     ;;
 270   Win32)
 271     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 272     AC_SUBST(LLVM_ON_UNIX,[0])
 273     AC_SUBST(LLVM_ON_WIN32,[1])
 274     ;;
 275 esac
 276
 277 dnl Determine what our target architecture is and configure accordingly.
 278 dnl This will allow Makefiles to make a distinction between the hardware and
 279 dnl the OS.
 280 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 281 [case $target in
 282   i?86-*)                 llvm_cv_target_arch="x86" ;;
 283   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 284   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 285   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 286   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 287   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 288   mips-*)                 llvm_cv_target_arch="Mips" ;;
 289   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 290   xcore-*)                llvm_cv_target_arch="XCore" ;;
 291   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 292   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 293   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 294   *)                      llvm_cv_target_arch="Unknown" ;;
 295 esac])
 296
 297 if test "$llvm_cv_target_arch" = "Unknown" ; then
 298   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 299 fi
 300
 301 # Determine the LLVM native architecture for the target
 302 case "$llvm_cv_target_arch" in
 303     x86)     LLVM_NATIVE_ARCH="X86" ;;
 304     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 305     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 306 esac
 307
 308 dnl Define a substitution, ARCH, for the target architecture
 309 AC_SUBST(ARCH,$llvm_cv_target_arch)
 310
 311 dnl Check for the endianness of the target
 312 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 313
 314 dnl Check for build platform executable suffix if we're crosscompiling
 315 if test "$cross_compiling" = yes; then
 316   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 317   AC_BUILD_EXEEXT
 318   ac_build_prefix=${build_alias}-
 319   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 320   if test -z "$BUILD_CXX"; then
 321      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 322      if test -z "$BUILD_CXX"; then
 323        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 324      fi
 325   fi
 326 else
 327   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 328 fi
 329
 330 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 331 dnl that this build is being done from a checkout. This sets up several
 332 dnl defaults for the command line switches. When we build with a CVS directory,
 333 dnl we get a debug with assertions turned on. Without, we assume a source
 334 dnl release and we get an optimized build without assertions.
 335 dnl See --enable-optimized and --enable-assertions below
 336 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 337   cvsbuild="yes"
 338   optimize="no"
 339   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 340 else
 341   cvsbuild="no"
 342   optimize="yes"
 343 fi
 344
 345 dnl===-----------------------------------------------------------------------===
 346 dnl===
 347 dnl=== SECTION 3: Command line arguments for the configure script.
 348 dnl===
 349 dnl===-----------------------------------------------------------------------===
 350
 351 dnl --enable-optimized : check whether they want to do an optimized build:
 352 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 353  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 354 if test ${enableval} = "no" ; then
 355   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 356 else
 357   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 358 fi
 359
 360 dnl --enable-profiling : check whether they want to do a profile build:
 361 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 362  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 363 if test ${enableval} = "no" ; then
 364   AC_SUBST(ENABLE_PROFILING,[[]])
 365 else
 366   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 367 fi
 368
 369 dnl --enable-assertions : check whether they want to turn on assertions or not:
 370 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 371   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 372 if test ${enableval} = "yes" ; then
 373   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 374 else
 375   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 376 fi
 377
 378 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 379 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 380   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 381 if test ${enableval} = "yes" ; then
 382   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 383   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 384 else
 385   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 386   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 387 fi
 388
 389 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 390 AC_ARG_ENABLE(debug-runtime,
 391    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 392 if test ${enableval} = "no" ; then
 393   AC_SUBST(DEBUG_RUNTIME,[[]])
 394 else
 395   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 396 fi
 397
 398 dnl --enable-debug-symbols : should even optimized compiler libraries
 399 dnl have debug symbols?
 400 AC_ARG_ENABLE(debug-symbols,
 401    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 402 if test ${enableval} = "no" ; then
 403   AC_SUBST(DEBUG_SYMBOLS,[[]])
 404 else
 405   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 406 fi
 407
 408 dnl --enable-jit: check whether they want to enable the jit
 409 AC_ARG_ENABLE(jit,
 410   AS_HELP_STRING(--enable-jit,
 411                  [Enable Just In Time Compiling (default is YES)]),,
 412   enableval=default)
 413 if test ${enableval} = "no"
 414 then
 415   AC_SUBST(JIT,[[]])
 416 else
 417   case "$llvm_cv_target_arch" in
 418     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 419     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 420     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 421     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 422     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 423     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 424     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 425     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 426     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 427     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 428     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 429     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 430     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 431   esac
 432 fi
 433
 434 dnl Allow enablement of doxygen generated documentation
 435 AC_ARG_ENABLE(doxygen,
 436               AS_HELP_STRING([--enable-doxygen],
 437                              [Build doxygen documentation (default is NO)]),,
 438                              enableval=default)
 439 case "$enableval" in
 440   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 441   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 442   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 443   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 444 esac
 445
 446 dnl Allow disablement of threads
 447 AC_ARG_ENABLE(threads,
 448               AS_HELP_STRING([--enable-threads],
 449                              [Use threads if available (default is YES)]),,
 450                              enableval=default)
 451 case "$enableval" in
 452   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 453   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 454   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 455   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 456 esac
 457 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 458
 459 dnl Allow building without position independent code
 460 AC_ARG_ENABLE(pic,
 461   AS_HELP_STRING([--enable-pic],
 462                  [Build LLVM with Position Independent Code (default is YES)]),,
 463                  enableval=default)
 464 case "$enableval" in
 465   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 466   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 467   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 468   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 469 esac
 470 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 471                    [Define if position independent code is enabled])
 472
 473 dnl Allow specific targets to be specified for building (or not)
 474 TARGETS_TO_BUILD=""
 475 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 476     [Build specific host targets: all or target1,target2,... Valid targets are:
 477      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu, pic16,
 478      xcore, msp430, systemz, blackfin, cbe, msil, and cpp (default=all)]),,
 479     enableval=all)
 480 if test "$enableval" = host-only ; then
 481   enableval=host
 482 fi
 483 case "$enableval" in
 484   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend MSIL CppBackend" ;;
 485   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 486       case "$a_target" in
 487         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 488         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 489         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 490         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 491         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 492         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 493         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 494         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 495         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 496         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 497         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 498         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 499         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 500         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 501         msil)     TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 502         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 503         host) case "$llvm_cv_target_arch" in
 504             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 505             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 506             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 507             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 508             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 509             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 510             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 511             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 512             PIC16)       TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 513             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 514             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 515             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 516             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 517             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 518           esac ;;
 519         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 520       esac
 521   done
 522   ;;
 523 esac
 524 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 525
 526 # Determine whether we are building LLVM support for the native architecture.
 527 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 528 for a_target in $TARGETS_TO_BUILD; do
 529   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 530     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 531     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 532       [LLVM architecture name for the native architecture, if available])
 533   fi
 534 done
 535
 536 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 537 # target feature def files.
 538 LLVM_ENUM_TARGETS=""
 539 LLVM_ENUM_ASM_PRINTERS=""
 540 LLVM_ENUM_ASM_PARSERS=""
 541 LLVM_ENUM_DISASSEMBLERS=""
 542 for target_to_build in $TARGETS_TO_BUILD; do
 543   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 544   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 545     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 546   fi
 547   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 548     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 549   fi
 550   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 551     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 552   fi
 553 done
 554 AC_SUBST(LLVM_ENUM_TARGETS)
 555 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 556 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 557 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 558
 559 dnl Prevent the CBackend from using printf("%a") for floating point so older
 560 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 561 dnl can still compile the CBE's output
 562 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 563   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 564   enableval=default)
 565 case "$enableval" in
 566   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 567   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 568   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 569   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 570 esac
 571 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 572                    [Define if CBE is enabled for printf %a output])
 573
 574 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 575 AC_ARG_WITH(llvmgccdir,
 576   AS_HELP_STRING([--with-llvmgccdir],
 577     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 578     withval=default)
 579 case "$withval" in
 580   default) WITH_LLVMGCCDIR=default ;;
 581   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 582   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 583 esac
 584
 585 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 586 AC_ARG_WITH(llvmgcc,
 587   AS_HELP_STRING([--with-llvmgcc],
 588     [Specify location of llvm-gcc driver (default searches PATH)]),
 589     LLVMGCC=$with_llvmgcc
 590       WITH_LLVMGCCDIR="",)
 591
 592 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 593 AC_ARG_WITH(llvmgxx,
 594   AS_HELP_STRING([--with-llvmgxx],
 595     [Specify location of llvm-g++ driver (default searches PATH)]),
 596     LLVMGXX=$with_llvmgxx
 597     WITH_LLVMGCCDIR="",)
 598
 599 if test -n "$LLVMGCC"; then
 600    LLVMGCCCOMMAND="$LLVMGCC"
 601 fi
 602
 603 if test -n "$LLVMGXX"; then
 604    LLVMGXXCOMMAND="$LLVMGXX"
 605 fi
 606
 607 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 608    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 609 fi
 610
 611 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 612    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 613 fi
 614
 615 dnl Override the option to use for optimized builds.
 616 AC_ARG_WITH(optimize-option,
 617   AS_HELP_STRING([--with-optimize-option],
 618                  [Select the compiler options to use for optimized builds]),,
 619                  withval=default)
 620 AC_MSG_CHECKING([optimization flags])
 621 case "$withval" in
 622   default)
 623     case "$llvm_cv_os_type" in
 624     MingW) optimize_option=-O3 ;;
 625     *)     optimize_option=-O2 ;;
 626     esac ;;
 627   *) optimize_option="$withval" ;;
 628 esac
 629 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 630 AC_MSG_RESULT([$optimize_option])
 631
 632 dnl Specify extra build options
 633 AC_ARG_WITH(extra-options,
 634   AS_HELP_STRING([--with-extra-options],
 635                  [Specify additional options to compile LLVM with]),,
 636                  withval=default)
 637 case "$withval" in
 638   default) EXTRA_OPTIONS= ;;
 639   *) EXTRA_OPTIONS=$withval ;;
 640 esac
 641 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 642
 643 dnl Allow specific bindings to be specified for building (or not)
 644 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 645     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 646     enableval=default)
 647 BINDINGS_TO_BUILD=""
 648 case "$enableval" in
 649   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 650   all ) BINDINGS_TO_BUILD="ocaml" ;;
 651   none | no) BINDINGS_TO_BUILD="" ;;
 652   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 653       case "$a_binding" in
 654         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 655         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 656       esac
 657   done
 658   ;;
 659 esac
 660
 661 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 662 dnl script for bindings/ocaml/configure, except that its auto value depends on
 663 dnl OCAMLC, which is found here to support tests.
 664 AC_ARG_WITH([ocaml-libdir],
 665   [AS_HELP_STRING([--with-ocaml-libdir],
 666     [Specify install location for ocaml bindings (default is stdlib)])],
 667   [],
 668   [withval=auto])
 669 case "$withval" in
 670   auto) with_ocaml_libdir="$withval" ;;
 671   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 672   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 673 esac
 674
 675 AC_ARG_WITH(c-include-dir,
 676   AS_HELP_STRING([--with-c-include-dirs],
 677     [Colon separated list of directories clang will search for headers]),,
 678     withval="")
 679 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 680                    [Directories clang will search for headers])
 681
 682 AC_ARG_WITH(cxx-include-root,
 683   AS_HELP_STRING([--with-cxx-include-root],
 684     [Directory with the libstdc++ headers.]),,
 685     withval="")
 686 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 687                    [Directory with the libstdc++ headers.])
 688
 689 AC_ARG_WITH(cxx-include-arch,
 690   AS_HELP_STRING([--with-cxx-include-arch],
 691     [Architecture of the libstdc++ headers.]),,
 692     withval="")
 693 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 694                    [Arch the libstdc++ headers.])
 695
 696 AC_ARG_WITH(cxx-include-32bit-dir,
 697   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 698     [32 bit multilib dir.]),,
 699     withval="")
 700 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 701                    [32 bit multilib directory.])
 702
 703 AC_ARG_WITH(cxx-include-64bit-dir,
 704   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 705     [64 bit multilib directory.]),,
 706     withval="")
 707 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 708                    [64 bit multilib directory.])
 709
 710 dnl Allow linking of LLVM with GPLv3 binutils code.
 711 AC_ARG_WITH(binutils-include,
 712   AS_HELP_STRING([--with-binutils-include],
 713     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 714   withval=default)
 715 case "$withval" in
 716   default) WITH_BINUTILS_INCDIR=default ;;
 717   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 718   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 719 esac
 720 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 721   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 722   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 723      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 724      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 725   fi
 726 fi
 727
 728 dnl --enable-libffi : check whether the user wants to turn off libffi:
 729 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 730   --enable-libffi,[Check for the presence of libffi (default is YES)]),,
 731   enableval=yes)
 732 case "$enableval" in
 733   yes) llvm_cv_enable_libffi="yes" ;;
 734   no)  llvm_cv_enable_libffi="no"  ;;
 735   *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 736 esac
 737
 738 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 739 if test "$llvm_cv_os_type" = "Win32" ; then
 740    llvmc_dynamic="yes"
 741 else
 742    llvmc_dynamic="no"
 743 fi
 744
 745 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 746 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 747 --enable-llvmc-dynamic,
 748 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 749 enableval=$llvmc_dynamic)
 750 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 751    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 752 else
 753    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 754 fi
 755
 756 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 757 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 758 --enable-llvmc-dynamic-plugins,
 759 [Enable dynamic LLVMC plugins (default is YES)]),,
 760 enableval=yes)
 761 if test ${enableval} = "yes" ; then
 762    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 763 else
 764    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 765 fi
 766
 767 dnl===-----------------------------------------------------------------------===
 768 dnl===
 769 dnl=== SECTION 4: Check for programs we need and that they are the right version
 770 dnl===
 771 dnl===-----------------------------------------------------------------------===
 772
 773 dnl Check for compilation tools
 774 AC_PROG_CPP
 775 AC_PROG_CC(gcc)
 776 AC_PROG_CXX(g++)
 777
 778 AC_PROG_NM
 779 AC_SUBST(NM)
 780
 781 dnl Check for the tools that the makefiles require
 782 AC_CHECK_GNU_MAKE
 783 AC_PROG_LN_S
 784 AC_PATH_PROG(CMP, [cmp], [cmp])
 785 AC_PATH_PROG(CP, [cp], [cp])
 786 AC_PATH_PROG(DATE, [date], [date])
 787 AC_PATH_PROG(FIND, [find], [find])
 788 AC_PATH_PROG(GREP, [grep], [grep])
 789 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 790 AC_PATH_PROG(MV,   [mv],   [mv])
 791 AC_PROG_RANLIB
 792 AC_PATH_PROG(RM,   [rm],   [rm])
 793 AC_PATH_PROG(SED,  [sed],  [sed])
 794 AC_PATH_PROG(TAR,  [tar],  [gtar])
 795 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 796
 797 dnl Looking for misc. graph plotting software
 798 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 799 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 800   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 801   dnl If we're targeting for mingw we should emit windows paths, not msys
 802   if test "$llvm_cv_os_type" = "MingW" ; then
 803     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 804   fi
 805   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 806    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 807 fi
 808 AC_PATH_PROG(DOT, [dot], [echo dot])
 809 if test "$DOT" != "echo dot" ; then
 810   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 811   dnl If we're targeting for mingw we should emit windows paths, not msys
 812   if test "$llvm_cv_os_type" = "MingW" ; then
 813     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 814   fi
 815   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 816    [Define to path to dot program if found or 'echo dot' otherwise])
 817 fi
 818 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 819 if test "$FDP" != "echo fdp" ; then
 820   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 821   dnl If we're targeting for mingw we should emit windows paths, not msys
 822   if test "$llvm_cv_os_type" = "MingW" ; then
 823     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 824   fi
 825   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 826    [Define to path to fdp program if found or 'echo fdp' otherwise])
 827 fi
 828 AC_PATH_PROG(NEATO, [neato], [echo neato])
 829 if test "$NEATO" != "echo neato" ; then
 830   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 831   dnl If we're targeting for mingw we should emit windows paths, not msys
 832   if test "$llvm_cv_os_type" = "MingW" ; then
 833     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 834   fi
 835   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 836    [Define to path to neato program if found or 'echo neato' otherwise])
 837 fi
 838 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 839 if test "$TWOPI" != "echo twopi" ; then
 840   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 841   dnl If we're targeting for mingw we should emit windows paths, not msys
 842   if test "$llvm_cv_os_type" = "MingW" ; then
 843     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 844   fi
 845   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 846    [Define to path to twopi program if found or 'echo twopi' otherwise])
 847 fi
 848 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 849 if test "$CIRCO" != "echo circo" ; then
 850   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 851   dnl If we're targeting for mingw we should emit windows paths, not msys
 852   if test "$llvm_cv_os_type" = "MingW" ; then
 853     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 854   fi
 855   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 856    [Define to path to circo program if found or 'echo circo' otherwise])
 857 fi
 858 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 859 if test "$GV" != "echo gv" ; then
 860   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 861   dnl If we're targeting for mingw we should emit windows paths, not msys
 862   if test "$llvm_cv_os_type" = "MingW" ; then
 863     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 864   fi
 865   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 866    [Define to path to gv program if found or 'echo gv' otherwise])
 867 fi
 868 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 869 if test "$DOTTY" != "echo dotty" ; then
 870   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 871   dnl If we're targeting for mingw we should emit windows paths, not msys
 872   if test "$llvm_cv_os_type" = "MingW" ; then
 873     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 874   fi
 875   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 876    [Define to path to dotty program if found or 'echo dotty' otherwise])
 877 fi
 878
 879 dnl Look for a sufficiently recent version of Perl.
 880 LLVM_PROG_PERL([5.006])
 881 AC_SUBST(PERL)
 882 if test x"$PERL" = xnone; then
 883    AC_SUBST(HAVE_PERL,0)
 884    AC_MSG_ERROR([perl is required but was not found, please install it])
 885 else
 886    AC_SUBST(HAVE_PERL,1)
 887 fi
 888
 889 dnl Find the install program
 890 AC_PROG_INSTALL
 891
 892 dnl Checks for documentation and testing tools that we can do without. If these
 893 dnl are not found then they are set to "true" which always succeeds but does
 894 dnl nothing. This just lets the build output show that we could have done
 895 dnl something if the tool was available.
 896 AC_PATH_PROG(BZIP2, [bzip2])
 897 AC_PATH_PROG(DOXYGEN, [doxygen])
 898 AC_PATH_PROG(GROFF, [groff])
 899 AC_PATH_PROG(GZIP, [gzip])
 900 AC_PATH_PROG(POD2HTML, [pod2html])
 901 AC_PATH_PROG(POD2MAN, [pod2man])
 902 AC_PATH_PROG(RUNTEST, [runtest])
 903 DJ_AC_PATH_TCLSH
 904 AC_PATH_PROG(ZIP, [zip])
 905 AC_PATH_PROGS(OCAMLC, [ocamlc])
 906 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 907 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 908 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 909 AC_PATH_PROGS(GAS, [gas as])
 910
 911 dnl Determine whether the linker supports the -R option.
 912 AC_LINK_USE_R
 913
 914 dnl Determine whether the linker supports the -export-dynamic option.
 915 AC_LINK_EXPORT_DYNAMIC
 916
 917 dnl Check for libtool and the library that has dlopen function (which must come
 918 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 919 dnl libtool).
 920 AC_LIBTOOL_DLOPEN
 921 AC_LIB_LTDL
 922 AC_PROG_LIBTOOL
 923
 924 if test "$lt_cv_dlopen_self" = "yes" ; then
 925   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 926               [Define if dlopen(0) will open the symbols of the program])
 927 fi
 928
 929
 930 if test "$WITH_LLVMGCCDIR" = "default" ; then
 931   LLVMGCC="llvm-gcc${EXEEXT}"
 932   LLVMGXX="llvm-g++${EXEEXT}"
 933   LLVMGCCCOMMAND="$LLVMGCC"
 934   LLVMGXXCOMMAND="$LLVMGXX"
 935   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 936   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 937   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 938   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 939 else
 940   if test -z "$LLVMGCC"; then
 941     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 942     LLVMGCCCOMMAND="$LLVMGCC"
 943   fi
 944   if test -z "$LLVMGXX"; then
 945     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 946     LLVMGXXCOMMAND="$LLVMGXX"
 947   fi
 948
 949   AC_SUBST(LLVMGCC,$LLVMGCC)
 950   AC_SUBST(LLVMGXX,$LLVMGXX)
 951   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 952   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 953 fi
 954
 955
 956 AC_MSG_CHECKING([tool compatibility])
 957
 958 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 959 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 960 dnl to support those options.
 961 dnl "icc" emits gcc signatures
 962 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 963 ICC=no
 964 IXX=no
 965 case $CC in
 966   icc*|icpc*)
 967     ICC=yes
 968     IXX=yes
 969     ;;
 970    *)
 971     ;;
 972 esac
 973
 974 if test "$GCC" != "yes" && test "$ICC" != "yes"
 975 then
 976   AC_MSG_ERROR([gcc|icc required but not found])
 977 fi
 978
 979 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 980 if test "$GXX" != "yes" && test "$IXX" != "yes"
 981 then
 982   AC_MSG_ERROR([g++|icc required but not found])
 983 fi
 984
 985 dnl Verify that GCC is version 3.0 or higher
 986 if test "$GCC" = "yes"
 987 then
 988   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 989 #error Unsupported GCC version
 990 #endif
 991 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 992 fi
 993
 994 dnl Check for GNU Make.  We use its extensions, so don't build without it
 995 if test -z "$llvm_cv_gnu_make_command"
 996 then
 997   AC_MSG_ERROR([GNU Make required but not found])
 998 fi
 999
1000 dnl Tool compatibility is okay if we make it here.
1001 AC_MSG_RESULT([ok])
1002
1003 dnl Check optional compiler flags.
1004 AC_MSG_CHECKING([optional compiler flags])
1005 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1006 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1007 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1008
1009 dnl===-----------------------------------------------------------------------===
1010 dnl===
1011 dnl=== SECTION 5: Check for libraries
1012 dnl===
1013 dnl===-----------------------------------------------------------------------===
1014
1015 AC_CHECK_LIB(m,sin)
1016 if test "$llvm_cv_os_type" = "MingW" ; then
1017   AC_CHECK_LIB(imagehlp, main)
1018   AC_CHECK_LIB(psapi, main)
1019 fi
1020
1021 dnl dlopen() is required for plugin support.
1022 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1023                [Define if dlopen() is available on this platform.]),
1024                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1025
1026 dnl libffi is optional; used to call external functions from the interpreter
1027 if test "$llvm_cv_enable_libffi" = "yes" ; then
1028   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1029                  [Define if libffi is available on this platform.]),
1030                  AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
1031 fi
1032
1033 dnl mallinfo is optional; the code can compile (minus features) without it
1034 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1035                [Define if mallinfo() is available on this platform.]))
1036
1037 dnl pthread locking functions are optional - but llvm will not be thread-safe
1038 dnl without locks.
1039 if test "$ENABLE_THREADS" -eq 1 ; then
1040   AC_CHECK_LIB(pthread, pthread_mutex_init)
1041   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1042                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1043                            [Have pthread_mutex_lock]))
1044   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1045                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1046                  [Have pthread_rwlock_init]))
1047   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1048                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1049                  [Have pthread_getspecific]))
1050 fi
1051
1052 dnl Allow extra x86-disassembler library
1053 AC_ARG_WITH(udis86,
1054   AS_HELP_STRING([--with-udis86=<path>],
1055     [Use udis86 external x86 disassembler library]),
1056     [
1057       AC_SUBST(USE_UDIS86, [1])
1058       case "$withval" in
1059         /usr/lib|yes) ;;
1060         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1061       esac
1062       AC_CHECK_LIB(udis86, ud_init, [], [
1063         echo "Error! You need to have libudis86 around."
1064         exit -1
1065       ])
1066     ],
1067     AC_SUBST(USE_UDIS86, [0]))
1068 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1069                    [Define if use udis86 library])
1070
1071 dnl Allow OProfile support for JIT output.
1072 AC_ARG_WITH(oprofile,
1073   AS_HELP_STRING([--with-oprofile=<prefix>],
1074     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1075     [
1076       AC_SUBST(USE_OPROFILE, [1])
1077       case "$withval" in
1078         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1079         no) llvm_cv_oppath=
1080             AC_SUBST(USE_OPROFILE, [0]) ;;
1081         *) llvm_cv_oppath="${withval}/lib/oprofile"
1082            CPPFLAGS="-I${withval}/include";;
1083       esac
1084       if test -n "$llvm_cv_oppath" ; then
1085         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1086         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1087         dnl libbfd is not included properly in libopagent in some Debian
1088         dnl versions.  If libbfd isn't found at all, we assume opagent works
1089         dnl anyway.
1090         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1091         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1092           echo "Error! You need to have libopagent around."
1093           exit -1
1094         ])
1095         AC_CHECK_HEADER([opagent.h], [], [
1096           echo "Error! You need to have opagent.h around."
1097           exit -1
1098           ])
1099       fi
1100     ],
1101     [
1102       AC_SUBST(USE_OPROFILE, [0])
1103     ])
1104 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1105                    [Define if we have the oprofile JIT-support library])
1106
1107 dnl===-----------------------------------------------------------------------===
1108 dnl===
1109 dnl=== SECTION 6: Check for header files
1110 dnl===
1111 dnl===-----------------------------------------------------------------------===
1112
1113 dnl First, use autoconf provided macros for specific headers that we need
1114 dnl We don't check for ancient stuff or things that are guaranteed to be there
1115 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1116 dnl Generally we're looking for POSIX headers.
1117 AC_HEADER_DIRENT
1118 AC_HEADER_MMAP_ANONYMOUS
1119 AC_HEADER_STAT
1120 AC_HEADER_STDC
1121 AC_HEADER_SYS_WAIT
1122 AC_HEADER_TIME
1123
1124 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1125 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1126 AC_CHECK_HEADERS([utime.h windows.h])
1127 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1128 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1129 if test "$ENABLE_THREADS" -eq 1 ; then
1130   AC_CHECK_HEADERS(pthread.h,
1131                    AC_SUBST(HAVE_PTHREAD, 1),
1132                    AC_SUBST(HAVE_PTHREAD, 0))
1133 else
1134   AC_SUBST(HAVE_PTHREAD, 0)
1135 fi
1136
1137 dnl Try to find ffi.h.
1138 if test "$llvm_cv_enable_libffi" = "yes" ; then
1139   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1140 fi
1141
1142 dnl===-----------------------------------------------------------------------===
1143 dnl===
1144 dnl=== SECTION 7: Check for types and structures
1145 dnl===
1146 dnl===-----------------------------------------------------------------------===
1147
1148 AC_HUGE_VAL_CHECK
1149 AC_TYPE_PID_T
1150 AC_TYPE_SIZE_T
1151 AC_TYPE_SIGNAL
1152 AC_STRUCT_TM
1153 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1154 AC_CHECK_TYPES([uint64_t],,
1155          AC_CHECK_TYPES([u_int64_t],,
1156          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1157
1158 dnl===-----------------------------------------------------------------------===
1159 dnl===
1160 dnl=== SECTION 8: Check for specific functions needed
1161 dnl===
1162 dnl===-----------------------------------------------------------------------===
1163
1164 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1165 AC_CHECK_FUNCS([powf fmodf strtof round ])
1166 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1167 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1168 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup ])
1169 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1170 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1171 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1172 AC_C_PRINTF_A
1173 dnl FIXME: This is no longer used, please remove (but test)!!!
1174 AC_FUNC_ALLOCA
1175 AC_FUNC_RAND48
1176
1177 dnl Check for variations in the Standard C++ library and STL. These macros are
1178 dnl provided by LLVM in the autoconf/m4 directory.
1179 AC_CXX_HAVE_STD_ITERATOR
1180 AC_CXX_HAVE_BI_ITERATOR
1181 AC_CXX_HAVE_FWD_ITERATOR
1182 AC_FUNC_ISNAN
1183 AC_FUNC_ISINF
1184
1185 dnl Check for mmap support.We also need to know if /dev/zero is required to
1186 dnl be opened for allocating RWX memory.
1187 dnl Make sure we aren't attempting to configure for an unknown system
1188 if test "$llvm_cv_platform_type" = "Unix" ; then
1189   AC_FUNC_MMAP
1190   AC_FUNC_MMAP_FILE
1191   AC_NEED_DEV_ZERO_FOR_MMAP
1192
1193   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1194   then
1195     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1196   fi
1197   if test "$ac_cv_func_mmap_file" = "no"
1198   then
1199     AC_MSG_WARN([mmap() of files required but not found])
1200   fi
1201 fi
1202
1203 dnl atomic builtins are required for threading support.
1204 AC_MSG_CHECKING(for GCC atomic builtins)
1205 AC_LINK_IFELSE(
1206   AC_LANG_SOURCE(
1207     [[int main() {
1208         volatile unsigned long val = 1;
1209         __sync_synchronize();
1210         __sync_val_compare_and_swap(&val, 1, 0);
1211         __sync_add_and_fetch(&val, 1);
1212         __sync_sub_and_fetch(&val, 1);
1213         return 0;
1214       }
1215     ]]),
1216   AC_MSG_RESULT(yes)
1217   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1218   AC_MSG_RESULT(no)
1219   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1220   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1221
1222
1223 dnl===-----------------------------------------------------------------------===
1224 dnl===
1225 dnl=== SECTION 9: Additional checks, variables, etc.
1226 dnl===
1227 dnl===-----------------------------------------------------------------------===
1228
1229 dnl Handle 32-bit linux systems running a 64-bit kernel.
1230 dnl This has to come after section 4 because it invokes the compiler.
1231 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1232   AC_IS_LINUX_MIXED
1233   if test "$llvm_cv_linux_mixed" = "yes"; then
1234     llvm_cv_target_arch="x86"
1235     ARCH="x86"
1236   fi
1237 fi
1238
1239 dnl Check, whether __dso_handle is present
1240 AC_CHECK_FUNCS([__dso_handle])
1241
1242 dnl See if the llvm-gcc executable can compile to LLVM assembly
1243 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1244 [llvm_cv_llvmgcc_sanity="no"
1245 if test -x "$LLVMGCC" ; then
1246   cp /dev/null conftest.c
1247   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1248       grep 'target datalayout =' > /dev/null 2>&1
1249   if test $? -eq 0 ; then
1250     llvm_cv_llvmgcc_sanity="yes"
1251   fi
1252   rm conftest.c
1253 fi])
1254
1255 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1256 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1257   AC_MSG_CHECKING([llvm-gcc component support])
1258   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1259   AC_SUBST(LLVMCC1,$llvmcc1path)
1260   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1261   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1262   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1263   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1264   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
1265   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
1266   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
1267   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
1268   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
1269   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
1270   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1271   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1272   AC_MSG_RESULT([ok])
1273 fi
1274
1275 dnl Propagate the shared library extension that the libltdl checks did to
1276 dnl the Makefiles so we can use it there too
1277 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1278
1279 # Translate the various configuration directories and other basic
1280 # information into substitutions that will end up in Makefile.config.in
1281 # that these configured values can be used by the makefiles
1282 if test "${prefix}" = "NONE" ; then
1283   prefix="/usr/local"
1284 fi
1285 eval LLVM_PREFIX="${prefix}";
1286 eval LLVM_BINDIR="${prefix}/bin";
1287 eval LLVM_LIBDIR="${prefix}/lib";
1288 eval LLVM_DATADIR="${prefix}/share/llvm";
1289 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
1290 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1291 eval LLVM_INCLUDEDIR="${prefix}/include";
1292 eval LLVM_INFODIR="${prefix}/info";
1293 eval LLVM_MANDIR="${prefix}/man";
1294 LLVM_CONFIGTIME=`date`
1295 AC_SUBST(LLVM_PREFIX)
1296 AC_SUBST(LLVM_BINDIR)
1297 AC_SUBST(LLVM_LIBDIR)
1298 AC_SUBST(LLVM_DATADIR)
1299 AC_SUBST(LLVM_DOCSDIR)
1300 AC_SUBST(LLVM_ETCDIR)
1301 AC_SUBST(LLVM_INCLUDEDIR)
1302 AC_SUBST(LLVM_INFODIR)
1303 AC_SUBST(LLVM_MANDIR)
1304 AC_SUBST(LLVM_CONFIGTIME)
1305
1306 # Place the various directores into the config.h file as #defines so that we
1307 # can know about the installation paths within LLVM.
1308 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1309                    [Installation prefix directory])
1310 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1311                    [Installation directory for binary executables])
1312 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1313                    [Installation directory for libraries])
1314 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1315                    [Installation directory for data files])
1316 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1317                    [Installation directory for documentation])
1318 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1319                    [Installation directory for config files])
1320 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1321                    [Installation directory for include files])
1322 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1323                    [Installation directory for .info files])
1324 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1325                    [Installation directory for man pages])
1326 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1327                    [Time at which LLVM was configured])
1328 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1329                    [Host triple we were built on])
1330
1331 # Determine which bindings to build.
1332 if test "$BINDINGS_TO_BUILD" = auto ; then
1333   BINDINGS_TO_BUILD=""
1334   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1335     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1336   fi
1337 fi
1338 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1339
1340 # This isn't really configurey, but it avoids having to repeat the list in
1341 # other files.
1342 AC_SUBST(ALL_BINDINGS,ocaml)
1343
1344 # Do any work necessary to ensure that bindings have what they need.
1345 binding_prereqs_failed=0
1346 for a_binding in $BINDINGS_TO_BUILD ; do
1347   case "$a_binding" in
1348   ocaml)
1349     if test "x$OCAMLC" = x ; then
1350       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1351       binding_prereqs_failed=1
1352     fi
1353     if test "x$OCAMLDEP" = x ; then
1354       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1355       binding_prereqs_failed=1
1356     fi
1357     if test "x$OCAMLOPT" = x ; then
1358       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1359       dnl ocamlopt is optional!
1360     fi
1361     if test "x$with_ocaml_libdir" != xauto ; then
1362       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1363     else
1364       ocaml_stdlib="`"$OCAMLC" -where`"
1365       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1366       then
1367         # ocaml stdlib is beneath our prefix; use stdlib
1368         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1369       else
1370         # ocaml stdlib is outside our prefix; use libdir/ocaml
1371         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1372       fi
1373     fi
1374     ;;
1375   esac
1376 done
1377 if test "$binding_prereqs_failed" = 1 ; then
1378   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1379 fi
1380
1381 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1382 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1383
1384 dnl Determine linker rpath flag
1385 if test "$llvm_cv_link_use_r" = "yes" ; then
1386   RPATH="-Wl,-R"
1387 else
1388   RPATH="-Wl,-rpath"
1389 fi
1390 AC_SUBST(RPATH)
1391
1392 dnl Determine linker rdynamic flag
1393 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1394   RDYNAMIC="-Wl,-export-dynamic"
1395 else
1396   RDYNAMIC=""
1397 fi
1398 AC_SUBST(RDYNAMIC)
1399
1400 dnl===-----------------------------------------------------------------------===
1401 dnl===
1402 dnl=== SECTION 10: Specify the output files and generate it
1403 dnl===
1404 dnl===-----------------------------------------------------------------------===
1405
1406 dnl Configure header files
1407 dnl WARNING: dnl If you add or remove any of the following config headers, then
1408 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1409 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1410 dnl files can be updated automatically when their *.in sources change.
1411 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1412 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1413 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1414 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1415 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1416 AC_CONFIG_HEADERS([include/llvm/System/DataTypes.h])
1417
1418 dnl Configure the makefile's configuration data
1419 AC_CONFIG_FILES([Makefile.config])
1420
1421 dnl Configure the RPM spec file for LLVM
1422 AC_CONFIG_FILES([llvm.spec])
1423
1424 dnl Configure doxygen's configuration file
1425 AC_CONFIG_FILES([docs/doxygen.cfg])
1426
1427 dnl Configure llvmc's Base plugin
1428 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1429
1430 dnl Do the first stage of configuration for llvm-config.in.
1431 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1432
1433 dnl Do special configuration of Makefiles
1434 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1435 AC_CONFIG_MAKEFILE(Makefile)
1436 AC_CONFIG_MAKEFILE(Makefile.common)
1437 AC_CONFIG_MAKEFILE(examples/Makefile)
1438 AC_CONFIG_MAKEFILE(lib/Makefile)
1439 AC_CONFIG_MAKEFILE(runtime/Makefile)
1440 AC_CONFIG_MAKEFILE(test/Makefile)
1441 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1442 AC_CONFIG_MAKEFILE(unittests/Makefile)
1443 AC_CONFIG_MAKEFILE(tools/Makefile)
1444 AC_CONFIG_MAKEFILE(utils/Makefile)
1445 AC_CONFIG_MAKEFILE(projects/Makefile)
1446 AC_CONFIG_MAKEFILE(bindings/Makefile)
1447 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1448
1449 dnl Finally, crank out the output
1450 AC_OUTPUT