autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.1svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  80       *)
  81         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  82         ;;
  83     esac
  84   fi
  85 done
  86
  87 dnl===-----------------------------------------------------------------------===
  88 dnl===
  89 dnl=== SECTION 2: Architecture, target, and host checks
  90 dnl===
  91 dnl===-----------------------------------------------------------------------===
  92
  93 dnl Check the target for which we're compiling and the host that will do the
  94 dnl compilations. This will tell us which LLVM compiler will be used for
  95 dnl compiling SSA into object code. This needs to be done early because
  96 dnl following tests depend on it.
  97 AC_CANONICAL_TARGET
  98
  99 dnl Determine the platform type and cache its value. This helps us configure
 100 dnl the System library to the correct build platform.
 101 AC_CACHE_CHECK([type of operating system we're going to host on],
 102                [llvm_cv_os_type],
 103 [case $host in
 104   *-*-aix*)
 105     llvm_cv_link_all_option="-Wl,--whole-archive"
 106     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 107     llvm_cv_os_type="AIX"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-irix*)
 110     llvm_cv_link_all_option="-Wl,--whole-archive"
 111     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 112     llvm_cv_os_type="IRIX"
 113     llvm_cv_platform_type="Unix" ;;
 114   *-*-cygwin*)
 115     llvm_cv_link_all_option="-Wl,--whole-archive"
 116     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 117     llvm_cv_os_type="Cygwin"
 118     llvm_cv_platform_type="Unix" ;;
 119   *-*-darwin*)
 120     llvm_cv_link_all_option="-Wl,-all_load"
 121     llvm_cv_link_all_option="-Wl,-noall_load"
 122     llvm_cv_os_type="Darwin"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-freebsd*)
 125     llvm_cv_link_all_option="-Wl,--whole-archive"
 126     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 127     llvm_cv_os_type="FreeBSD"
 128     llvm_cv_platform_type="Unix" ;;
 129   *-*-openbsd*)
 130     llvm_cv_link_all_option="-Wl,--whole-archive"
 131     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 132     llvm_cv_os_type="OpenBSD"
 133     llvm_cv_platform_type="Unix" ;;
 134   *-*-netbsd*)
 135     llvm_cv_link_all_option="-Wl,--whole-archive"
 136     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 137     llvm_cv_os_type="NetBSD"
 138     llvm_cv_platform_type="Unix" ;;
 139   *-*-hpux*)
 140     llvm_cv_link_all_option="-Wl,--whole-archive"
 141     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 142     llvm_cv_os_type="HP-UX"
 143     llvm_cv_platform_type="Unix" ;;
 144   *-*-interix*)
 145     llvm_cv_link_all_option="-Wl,--whole-archive"
 146     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 147     llvm_cv_os_type="Interix"
 148     llvm_cv_platform_type="Unix" ;;
 149   *-*-linux*)
 150     llvm_cv_link_all_option="-Wl,--whole-archive"
 151     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 152     llvm_cv_os_type="Linux"
 153     llvm_cv_platform_type="Unix" ;;
 154   *-*-solaris*)
 155     llvm_cv_link_all_option="-Wl,-z,allextract"
 156     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 157     llvm_cv_os_type="SunOS"
 158     llvm_cv_platform_type="Unix" ;;
 159   *-*-win32*)
 160     llvm_cv_link_all_option="-Wl,--whole-archive"
 161     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 162     llvm_cv_os_type="Win32"
 163     llvm_cv_platform_type="Win32" ;;
 164   *-*-mingw*)
 165     llvm_cv_link_all_option="-Wl,--whole-archive"
 166     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 167     llvm_cv_os_type="MingW"
 168     llvm_cv_platform_type="Win32" ;;
 169   *)
 170     llvm_cv_link_all_option=""
 171     llvm_cv_no_link_all_option=""
 172     llvm_cv_os_type="Unknown"
 173     llvm_cv_platform_type="Unknown" ;;
 174 esac])
 175
 176 dnl Make sure we aren't attempting to configure for an unknown system
 177 if test "$llvm_cv_os_type" = "Unknown" ; then
 178   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 179 fi
 180
 181 dnl Set the "OS" Makefile variable based on the platform type so the
 182 dnl makefile can configure itself to specific build hosts
 183 AC_SUBST(OS,$llvm_cv_os_type)
 184
 185 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 186 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 187 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 188
 189 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 190 dnl This is used by lib/System to determine the basic kind of implementation
 191 dnl to use.
 192 case $llvm_cv_platform_type in
 193   Unix)
 194     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 195     AC_SUBST(LLVM_ON_UNIX,[1])
 196     AC_SUBST(LLVM_ON_WIN32,[0])
 197     ;;
 198   Win32)
 199     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 200     AC_SUBST(LLVM_ON_UNIX,[0])
 201     AC_SUBST(LLVM_ON_WIN32,[1])
 202     ;;
 203 esac
 204
 205 dnl Determine what our target architecture is and configure accordingly.
 206 dnl This will allow Makefiles to make a distinction between the hardware and
 207 dnl the OS.
 208 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 209 [case $target in
 210   i?86-*)                 llvm_cv_target_arch="x86" ;;
 211   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 212   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 213   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 214   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 215   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 216   arm-*)                  llvm_cv_target_arch="ARM" ;;
 217   *)                      llvm_cv_target_arch="Unknown" ;;
 218 esac])
 219
 220 if test "$llvm_cv_target_arch" = "Unknown" ; then
 221   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 222 fi
 223
 224 dnl Define a substitution, ARCH, for the target architecture
 225 AC_SUBST(ARCH,$llvm_cv_target_arch)
 226
 227 dnl Check for the endianness of the target
 228 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 229
 230 dnl Check for build platform executable suffix if we're crosscompiling
 231 if test "$cross_compiling" = yes; then
 232   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 233   AC_BUILD_EXEEXT
 234 else
 235   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 236 fi
 237
 238 dnl Check to see if there's a "CVS" (or .svn) directory indicating that this
 239 dnl build is being done from a checkout. This sets up several defaults for the
 240 dnl command line switches. When we build with a CVS directory, we get a
 241 dnl debug with assertions turned on. Without, we assume a source release and we
 242 dnl get an optimized build without assertions. See --enable-optimized and
 243 dnl --enable-assertions below
 244 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn"; then
 245   cvsbuild="yes"
 246   optimize="no"
 247   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 248 else
 249   cvsbuild="no"
 250   optimize="yes"
 251 fi
 252
 253 dnl===-----------------------------------------------------------------------===
 254 dnl===
 255 dnl=== SECTION 3: Command line arguments for the configure script.
 256 dnl===
 257 dnl===-----------------------------------------------------------------------===
 258
 259 dnl --enable-optimized : check whether they want to do an optimized build:
 260 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 261  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 262 if test ${enableval} = "no" ; then
 263   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 264 else
 265   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 266 fi
 267
 268 dnl --enable-assertions : check whether they want to turn on assertions or not:
 269 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 270   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 271 if test ${enableval} = "yes" ; then
 272   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 273 else
 274   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 275 fi
 276
 277 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 278 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 279   [--enable-expensive-checks,Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 280 if test ${enableval} = "yes" ; then
 281   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 282   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 283 else
 284   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 285   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 286 fi
 287
 288 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 289 AC_ARG_ENABLE(debug-runtime,
 290    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 291 if test ${enableval} = "no" ; then
 292   AC_SUBST(DEBUG_RUNTIME,[[]])
 293 else
 294   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 295 fi
 296
 297 dnl --enable-jit: check whether they want to enable the jit
 298 AC_ARG_ENABLE(jit,
 299   AS_HELP_STRING(--enable-jit,
 300                  [Enable Just In Time Compiling (default is YES)]),,
 301   enableval=default)
 302 if test ${enableval} = "no"
 303 then
 304   AC_SUBST(JIT,[[]])
 305 else
 306   case "$llvm_cv_target_arch" in
 307     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 308     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 309     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 310     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 311     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 312     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 313     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 314     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 315   esac
 316 fi
 317
 318 dnl Allow enablement of doxygen generated documentation
 319 AC_ARG_ENABLE(doxygen,
 320               AS_HELP_STRING([--enable-doxygen],
 321                              [Build doxygen documentation (default is NO)]),,
 322                              enableval=default)
 323 case "$enableval" in
 324   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 325   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 326   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 327   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 328 esac
 329
 330 dnl Allow disablement of threads
 331 AC_ARG_ENABLE(threads,
 332               AS_HELP_STRING([--enable-threads],
 333                              [Use threads if available (default is YES)]),,
 334                              enableval=default)
 335 case "$enableval" in
 336   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 337   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 338   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 339   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 340 esac
 341 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 342
 343 dnl Allow building with position independent code
 344 AC_ARG_ENABLE(pic,
 345   AS_HELP_STRING([--enable-pic],
 346                  [Build LLVM with Position Independent Code (default is NO)]),,
 347                  enableval=default)
 348 case "$enableval" in
 349   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 350   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 351   default) AC_SUBST(ENABLE_PIC,[0]) ;;
 352   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 353 esac
 354 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 355                    [Define if position independent code is enabled])
 356
 357 dnl Allow specific targets to be specified for building (or not)
 358 TARGETS_TO_BUILD=""
 359 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 360     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 361     enableval=all)
 362 case "$enableval" in
 363   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM" ;;
 364   host-only)
 365     case "$llvm_cv_target_arch" in
 366       x86)     TARGETS_TO_BUILD="X86" ;;
 367       x86_64)  TARGETS_TO_BUILD="X86" ;;
 368       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 369       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 370       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 371       IA64)    TARGETS_TO_BUILD="IA64" ;;
 372       ARM)     TARGETS_TO_BUILD="ARM" ;;
 373       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 374     esac
 375     ;;
 376   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 377       case "$a_target" in
 378         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 379         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 380         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 381         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 382         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 383         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 384         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 385         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 386       esac
 387   done
 388   ;;
 389 esac
 390 TARGETS_TO_BUILD="CBackend MSIL $TARGETS_TO_BUILD"
 391 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 392
 393 dnl Prevent the CBackend from using printf("%a") for floating point so older
 394 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 395 dnl can still compile the CBE's output
 396 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 397   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 398   enableval=default)
 399 case "$enableval" in
 400   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 401   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 402   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 403   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 404 esac
 405 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 406                    [Define if CBE is enabled for printf %a output])
 407
 408 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 409 AC_ARG_WITH(llvmgccdir,
 410   AS_HELP_STRING([--with-llvmgccdir],
 411     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 412     withval=default)
 413 case "$withval" in
 414   default) WITH_LLVMGCCDIR=default ;;
 415   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 416   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 417 esac
 418
 419 dnl Specify extra build options
 420 AC_ARG_WITH(extra-options,
 421   AS_HELP_STRING([--with-extra-options],
 422                  [Specify addtional options to compile LLVM with]),,
 423                  withval=default)
 424 case "$withval" in
 425   default) EXTRA_OPTIONS= ;;
 426   *) EXTRA_OPTIONS=$withval ;;
 427 esac
 428 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 429
 430 dnl===-----------------------------------------------------------------------===
 431 dnl===
 432 dnl=== SECTION 4: Check for programs we need and that they are the right version
 433 dnl===
 434 dnl===-----------------------------------------------------------------------===
 435
 436 dnl Check for compilation tools
 437 AC_PROG_CPP
 438 AC_PROG_CC(gcc)
 439 AC_PROG_CXX(g++)
 440 AC_PROG_FLEX
 441 AC_PROG_BISON
 442
 443 AC_PROG_NM
 444 AC_SUBST(NM)
 445
 446 dnl Check for the tools that the makefiles require
 447 AC_CHECK_GNU_MAKE
 448 AC_PROG_LN_S
 449 AC_PATH_PROG(CMP, [cmp], [cmp])
 450 AC_PATH_PROG(CP, [cp], [cp])
 451 AC_PATH_PROG(DATE, [date], [date])
 452 AC_PATH_PROG(FIND, [find], [find])
 453 AC_PATH_PROG(GREP, [grep], [grep])
 454 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 455 AC_PATH_PROG(MV,   [mv],   [mv])
 456 AC_PROG_RANLIB
 457 AC_PATH_PROG(RM,   [rm],   [rm])
 458 AC_PATH_PROG(SED,  [sed],  [sed])
 459 AC_PATH_PROG(TAR,  [tar],  [gtar])
 460 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 461
 462 dnl Looking for misc. graph plotting software
 463 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 464 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 465   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 466   dnl If we're targeting for mingw we should emit windows paths, not msys
 467   if test "$llvm_cv_os_type" = "MingW" ; then
 468     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 469   fi
 470   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 471    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 472 fi
 473 AC_PATH_PROG(DOT, [dot], [echo dot])
 474 if test "$DOT" != "echo dot" ; then
 475   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 476   dnl If we're targeting for mingw we should emit windows paths, not msys
 477   if test "$llvm_cv_os_type" = "MingW" ; then
 478     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 479   fi
 480   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 481    [Define to path to dot program if found or 'echo dot' otherwise])
 482 fi
 483 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 484 if test "$GV" != "echo gv" ; then
 485   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 486   dnl If we're targeting for mingw we should emit windows paths, not msys
 487   if test "$llvm_cv_os_type" = "MingW" ; then
 488     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 489   fi
 490   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 491    [Define to path to gv program if found or 'echo gv' otherwise])
 492 fi
 493 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 494 if test "$DOTTY" != "echo dotty" ; then
 495   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 496   dnl If we're targeting for mingw we should emit windows paths, not msys
 497   if test "$llvm_cv_os_type" = "MingW" ; then
 498     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 499   fi
 500   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 501    [Define to path to dotty program if found or 'echo dotty' otherwise])
 502 fi
 503
 504 dnl Look for a sufficiently recent version of Perl.
 505 LLVM_PROG_PERL([5.006])
 506 AC_SUBST(PERL)
 507 if test x"$PERL" = xnone; then
 508    AC_SUBST(HAVE_PERL,0)
 509    AC_MSG_ERROR([perl is required but was not found, please install it])
 510 else
 511    AC_SUBST(HAVE_PERL,1)
 512 fi
 513
 514 dnl Find the install program
 515 AC_PROG_INSTALL
 516
 517 dnl Checks for documentation and testing tools that we can do without. If these
 518 dnl are not found then they are set to "true" which always succeeds but does
 519 dnl nothing. This just lets the build output show that we could have done
 520 dnl something if the tool was available.
 521 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 522 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 523 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 524 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 525 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 526 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 527 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 528 DJ_AC_PATH_TCLSH
 529 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 530
 531 dnl Determine if the linker supports the -R option.
 532 AC_LINK_USE_R
 533
 534 dnl Check for libtool and the library that has dlopen function (which must come
 535 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 536 dnl libtool).
 537 AC_LIBTOOL_DLOPEN
 538 AC_LIB_LTDL
 539 AC_PROG_LIBTOOL
 540
 541 if test "$lt_cv_dlopen_self" = "yes" ; then
 542   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 543               [Define if dlopen(0) will open the symbols of the program])
 544 fi
 545
 546 dnl Check if we know how to tell etags we are using C++:
 547 etags_version=`$ETAGS --version 2>&1`
 548 case "$etags_version" in
 549         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 550         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 551         *) ETAGSFLAGS="" ;;
 552 esac
 553 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 554
 555 if test "$WITH_LLVMGCCDIR" = "default" ; then
 556   LLVMGCC="llvm-gcc${EXEEXT}"
 557   LLVMGXX="llvm-g++${EXEEXT}"
 558   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 559   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 560 else
 561   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 562   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 563   AC_SUBST(LLVMGCC,$LLVMGCC)
 564   AC_SUBST(LLVMGXX,$LLVMGXX)
 565 fi
 566
 567 AC_MSG_CHECKING([tool compatibility])
 568
 569 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 570 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 571 dnl to support those options.
 572 dnl "icc" emits gcc signatures
 573 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 574 ICC=no
 575 IXX=no
 576 case $CC in
 577   icc*|icpc*)
 578     ICC=yes
 579     IXX=yes
 580     ;;
 581    *)
 582     ;;
 583 esac
 584
 585 if test "$GCC" != "yes" && test "$ICC" != "yes"
 586 then
 587   AC_MSG_ERROR([gcc|icc required but not found])
 588 fi
 589
 590 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 591 if test "$GXX" != "yes" && test "$IXX" != "yes"
 592 then
 593   AC_MSG_ERROR([g++|icc required but not found])
 594 fi
 595
 596 dnl Verify that GCC is version 3.0 or higher
 597 if test "$GCC" = "yes"
 598 then
 599   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 600   if test "$gccmajor" -lt "3"
 601   then
 602     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 603   fi
 604 fi
 605
 606 dnl Check for GNU Make.  We use its extensions, so don't build without it
 607 if test -z "$llvm_cv_gnu_make_command"
 608 then
 609   AC_MSG_ERROR([GNU Make required but not found])
 610 fi
 611
 612 dnl Tool compatibility is okay if we make it here.
 613 AC_MSG_RESULT([ok])
 614
 615 dnl===-----------------------------------------------------------------------===
 616 dnl===
 617 dnl=== SECTION 5: Check for libraries
 618 dnl===
 619 dnl===-----------------------------------------------------------------------===
 620
 621 dnl libelf is for sparc only; we can ignore it if we don't have it
 622 AC_CHECK_LIB(elf, elf_begin)
 623 AC_CHECK_LIB(m,sin)
 624 if test "$llvm_cv_os_type" = "MingW" ; then
 625   AC_CHECK_LIB(imagehlp, main)
 626   AC_CHECK_LIB(psapi, main)
 627 fi
 628
 629 dnl lt_dlopen may be required for plugin support.
 630 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 631               [Define if lt_dlopen() is available on this platform]),
 632               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 633                            not be available]))
 634
 635 dnl dlopen() is required for plugin support.
 636 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 637                [Define if dlopen() is available on this platform.]),
 638                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 639
 640 dnl mallinfo is optional; the code can compile (minus features) without it
 641 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 642                [Define if mallinfo() is available on this platform.]))
 643
 644 dnl pthread locking functions are optional - but llvm will not be thread-safe
 645 dnl without locks.
 646 if test "$ENABLE_THREADS" -eq 1 ; then
 647   AC_CHECK_LIB(pthread,pthread_mutex_init)
 648   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 649                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 650                            [Have pthread_mutex_lock]))
 651 fi
 652
 653 dnl Allow extra x86-disassembler library
 654 AC_ARG_WITH(udis86,
 655   AS_HELP_STRING([--with-udis86=<path>],
 656     [Use udis86 external x86 disassembler library]),
 657     [
 658       AC_SUBST(USE_UDIS86, [1])
 659       case "$withval" in
 660         /usr/lib|yes) ;;
 661         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 662       esac
 663       AC_CHECK_LIB(udis86, ud_init, [], [
 664         echo "Error! You need to have libudis86 around."
 665         exit -1
 666       ])
 667     ],
 668     AC_SUBST(USE_UDIS86, [0]))
 669 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 670                    [Define if use udis86 library])
 671
 672 dnl===-----------------------------------------------------------------------===
 673 dnl===
 674 dnl=== SECTION 6: Check for header files
 675 dnl===
 676 dnl===-----------------------------------------------------------------------===
 677
 678 dnl First, use autoconf provided macros for specific headers that we need
 679 dnl We don't check for ancient stuff or things that are guaranteed to be there
 680 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 681 dnl Generally we're looking for POSIX headers.
 682 AC_HEADER_DIRENT
 683 AC_HEADER_MMAP_ANONYMOUS
 684 AC_HEADER_STAT
 685 AC_HEADER_STDC
 686 AC_HEADER_SYS_WAIT
 687 AC_HEADER_TIME
 688
 689 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 690 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 691 AC_CHECK_HEADERS([windows.h sys/mman.h sys/param.h sys/resource.h sys/time.h])
 692 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 693 if test "$ENABLE_THREADS" -eq 1 ; then
 694   AC_CHECK_HEADER(pthread.h,
 695                   AC_SUBST(HAVE_PTHREAD, 1),
 696                    AC_SUBST(HAVE_PTHREAD, 0))
 697 else
 698   AC_SUBST(HAVE_PTHREAD, 0)
 699 fi
 700
 701 dnl===-----------------------------------------------------------------------===
 702 dnl===
 703 dnl=== SECTION 7: Check for types and structures
 704 dnl===
 705 dnl===-----------------------------------------------------------------------===
 706
 707 AC_HUGE_VAL_CHECK
 708 AC_TYPE_PID_T
 709 AC_TYPE_SIZE_T
 710 AC_TYPE_SIGNAL
 711 AC_STRUCT_TM
 712 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 713 AC_CHECK_TYPES([uint64_t],,
 714          AC_CHECK_TYPES([u_int64_t],,
 715          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 716
 717 dnl===-----------------------------------------------------------------------===
 718 dnl===
 719 dnl=== SECTION 8: Check for specific functions needed
 720 dnl===
 721 dnl===-----------------------------------------------------------------------===
 722
 723 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 724 AC_CHECK_FUNCS([powf fmodf strtof round ])
 725 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 726 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 727 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 728 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 729 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 730 AC_C_PRINTF_A
 731 AC_FUNC_ALLOCA
 732 AC_FUNC_RAND48
 733
 734 dnl Check for variations in the Standard C++ library and STL. These macros are
 735 dnl provided by LLVM in the autoconf/m4 directory.
 736 AC_CXX_HAVE_HASH_MAP
 737 AC_CXX_HAVE_HASH_SET
 738 AC_CXX_HAVE_STD_ITERATOR
 739 AC_CXX_HAVE_BI_ITERATOR
 740 AC_CXX_HAVE_FWD_ITERATOR
 741 AC_FUNC_ISNAN
 742 AC_FUNC_ISINF
 743
 744 dnl Check for mmap support.We also need to know if /dev/zero is required to
 745 dnl be opened for allocating RWX memory.
 746 dnl Make sure we aren't attempting to configure for an unknown system
 747 if test "$llvm_cv_platform_type" = "Unix" ; then
 748   AC_FUNC_MMAP
 749   AC_FUNC_MMAP_FILE
 750   AC_NEED_DEV_ZERO_FOR_MMAP
 751
 752   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 753   then
 754     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 755   fi
 756   if test "$ac_cv_func_mmap_file" = "no"
 757   then
 758     AC_MSG_WARN([mmap() of files required but not found])
 759   fi
 760 fi
 761
 762 dnl===-----------------------------------------------------------------------===
 763 dnl===
 764 dnl=== SECTION 9: Additional checks, variables, etc.
 765 dnl===
 766 dnl===-----------------------------------------------------------------------===
 767
 768 dnl See if the llvm-gcc executable can compile to LLVM assembly
 769 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 770 [llvm_cv_llvmgcc_sanity="no"
 771 if test -x "$LLVMGCC" ; then
 772   cp /dev/null conftest.c
 773   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 774       grep 'target datalayout =' > /dev/null 2>&1
 775   if test $? -eq 0 ; then
 776     llvm_cv_llvmgcc_sanity="yes"
 777   fi
 778   rm conftest.c
 779 fi])
 780
 781 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 782 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 783   AC_MSG_CHECKING([llvm-gcc component support])
 784   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 785   AC_SUBST(LLVMCC1,$llvmcc1path)
 786   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 787   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 788   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 789   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 790   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 791   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 792   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 793   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 794   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 795   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 796   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ -]*\).*/\1/'`]
 797   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
 798   AC_MSG_RESULT([ok])
 799 fi
 800
 801 dnl Propagate the shared library extension that the libltdl checks did to
 802 dnl the Makefiles so we can use it there too
 803 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 804
 805 # Translate the various configuration directories and other basic
 806 # information into substitutions that will end up in Makefile.config.in
 807 # that these configured values can be used by the makefiles
 808 if test "${prefix}" = "NONE" ; then
 809   prefix="/usr/local"
 810 fi
 811 eval LLVM_PREFIX="${prefix}";
 812 eval LLVM_BINDIR="${prefix}/bin";
 813 eval LLVM_LIBDIR="${prefix}/lib";
 814 eval LLVM_DATADIR="${prefix}/share/llvm";
 815 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 816 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 817 eval LLVM_INCLUDEDIR="${prefix}/include";
 818 eval LLVM_INFODIR="${prefix}/info";
 819 eval LLVM_MANDIR="${prefix}/man";
 820 LLVM_CONFIGTIME=`date`
 821 AC_SUBST(LLVM_PREFIX)
 822 AC_SUBST(LLVM_BINDIR)
 823 AC_SUBST(LLVM_LIBDIR)
 824 AC_SUBST(LLVM_DATADIR)
 825 AC_SUBST(LLVM_DOCSDIR)
 826 AC_SUBST(LLVM_ETCDIR)
 827 AC_SUBST(LLVM_INCLUDEDIR)
 828 AC_SUBST(LLVM_INFODIR)
 829 AC_SUBST(LLVM_MANDIR)
 830 AC_SUBST(LLVM_CONFIGTIME)
 831
 832 # Place the various directores into the config.h file as #defines so that we
 833 # can know about the installation paths within LLVM.
 834 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 835                    [Installation prefix directory])
 836 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 837                    [Installation directory for binary executables])
 838 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 839                    [Installation directory for libraries])
 840 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 841                    [Installation directory for data files])
 842 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 843                    [Installation directory for documentation])
 844 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 845                    [Installation directory for config files])
 846 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 847                    [Installation directory for include files])
 848 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 849                    [Installation directory for .info files])
 850 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 851                    [Installation directory for man pages])
 852 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 853                    [Time at which LLVM was configured])
 854
 855 dnl===-----------------------------------------------------------------------===
 856 dnl===
 857 dnl=== SECTION 10: Specify the output files and generate it
 858 dnl===
 859 dnl===-----------------------------------------------------------------------===
 860
 861 dnl Configure header files
 862 dnl WARNING: dnl If you add or remove any of the following config headers, then
 863 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 864 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 865 dnl files can be updated automatically when their *.in sources change.
 866 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 867 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 868 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 869 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 870 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 871
 872 dnl Configure the makefile's configuration data
 873 AC_CONFIG_FILES([Makefile.config])
 874
 875 dnl Configure the RPM spec file for LLVM
 876 AC_CONFIG_FILES([llvm.spec])
 877
 878 dnl Configure doxygen's configuration file
 879 AC_CONFIG_FILES([docs/doxygen.cfg])
 880
 881 dnl Do the first stage of configuration for llvm-config.in.
 882 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 883
 884 dnl Do special configuration of Makefiles
 885 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 886 AC_CONFIG_MAKEFILE(Makefile)
 887 AC_CONFIG_MAKEFILE(Makefile.common)
 888 AC_CONFIG_MAKEFILE(examples/Makefile)
 889 AC_CONFIG_MAKEFILE(lib/Makefile)
 890 AC_CONFIG_MAKEFILE(runtime/Makefile)
 891 AC_CONFIG_MAKEFILE(test/Makefile)
 892 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 893 AC_CONFIG_MAKEFILE(tools/Makefile)
 894 AC_CONFIG_MAKEFILE(utils/Makefile)
 895 AC_CONFIG_MAKEFILE(projects/Makefile)
 896
 897 dnl Finally, crank out the output
 898 AC_OUTPUT
 899