autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.7cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  78       "llvm-kernel")  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  79       *)
  80         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  81         ;;
  82     esac
  83   fi
  84 done
  85
  86 dnl===-----------------------------------------------------------------------===
  87 dnl===
  88 dnl=== SECTION 2: Architecture, target, and host checks
  89 dnl===
  90 dnl===-----------------------------------------------------------------------===
  91
  92 dnl Check the target for which we're compiling and the host that will do the
  93 dnl compilations. This will tell us which LLVM compiler will be used for
  94 dnl compiling SSA into object code. This needs to be done early because
  95 dnl following tests depend on it.
  96 AC_CANONICAL_TARGET
  97
  98 dnl Determine the platform type and cache its value. This helps us configure
  99 dnl the System library to the correct build platform.
 100 AC_CACHE_CHECK([type of operating system we're on],
 101                [llvm_cv_os_type],
 102 [case $build in
 103   *-*-aix*)
 104     llvm_cv_os_type="AIX"
 105     llvm_cv_platform_type="Unix" ;;
 106   *-*-cygwin*)
 107     llvm_cv_os_type="Cygwin"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-darwin*)
 110     llvm_cv_os_type="Darwin"
 111     llvm_cv_platform_type="Unix" ;;
 112   *-*-freebsd*)
 113     llvm_cv_os_type="FreeBSD"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-hpux*)
 116     llvm_cv_os_type="HP-UX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-interix*)
 119     llvm_cv_os_type="Interix"
 120     llvm_cv_platform_type="Unix" ;;
 121   *-*-linux*)
 122     llvm_cv_os_type="Linux"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-solaris*)
 125     llvm_cv_os_type="SunOS"
 126     llvm_cv_platform_type="Unix" ;;
 127   *-*-win32*)
 128     llvm_cv_os_type="Win32"
 129     llvm_cv_platform_type="Win32" ;;
 130   *-*-mingw*)
 131     llvm_cv_os_type="MingW"
 132     llvm_cv_platform_type="Win32" ;;
 133   *)
 134     llvm_cv_os_type="Unknown"
 135     llvm_cv_platform_type="Unknown" ;;
 136 esac])
 137
 138 dnl Make sure we aren't attempting to configure for an unknown system
 139 if test "$llvm_cv_os_type" = "Unknown" ; then
 140   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 141 fi
 142
 143 dnl Set the "OS" Makefile variable based on the platform type so the
 144 dnl makefile can configure itself to specific build hosts
 145 AC_SUBST(OS,$llvm_cv_os_type)
 146
 147 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 148 dnl This is used by lib/System to determine the basic kind of implementation
 149 dnl to use.
 150 case $llvm_cv_platform_type in
 151   Unix)
 152     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 153     AC_SUBST(LLVM_ON_UNIX,[1])
 154     AC_SUBST(LLVM_ON_WIN32,[0])
 155     ;;
 156   Win32)
 157     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 158     AC_SUBST(LLVM_ON_UNIX,[0])
 159     AC_SUBST(LLVM_ON_WIN32,[1])
 160     ;;
 161 esac
 162
 163 dnl Determine what our target architecture is and configure accordingly.
 164 dnl This will allow Makefiles to make a distinction between the hardware and
 165 dnl the OS.
 166 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 167 [case $target in
 168   i?86-*)                 llvm_cv_target_arch="x86" ;;
 169   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 170   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 171   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 172   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 173   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 174   *)                      llvm_cv_target_arch="Unknown" ;;
 175 esac])
 176
 177 if test "$llvm_cv_target_arch" = "Unknown" ; then
 178   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 179 fi
 180
 181 dnl Define a substitution, ARCH, for the target architecture
 182 AC_SUBST(ARCH,$llvm_cv_target_arch)
 183
 184 dnl Check for the endianness of the target
 185 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 186
 187 dnl===-----------------------------------------------------------------------===
 188 dnl===
 189 dnl=== SECTION 3: Command line arguments for the configure script.
 190 dnl===
 191 dnl===-----------------------------------------------------------------------===
 192
 193 dnl --enable-optimized : check whether they want to do an optimized build:
 194 AC_ARG_ENABLE(optimized,
 195               AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
 196 if test ${enableval} = "no" ; then
 197   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 198 else
 199   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 200 fi
 201
 202 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 203 AC_ARG_ENABLE(debug-runtime,
 204    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 205 if test ${enableval} = "no" ; then
 206   AC_SUBST(DEBUG_RUNTIME,[[]])
 207 else
 208   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 209 fi
 210
 211 dnl --enable-jit: check whether they want to enable the jit
 212 AC_ARG_ENABLE(jit,
 213   AS_HELP_STRING(--enable-jit,
 214                  [Enable Just In Time Compiling (default is YES)]),,
 215   enableval=default)
 216 if test ${enableval} = "no"
 217 then
 218   AC_SUBST(JIT,[[]])
 219 else
 220   case "$llvm_cv_target_arch" in
 221     x86)     AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 222     Sparc)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 223     PowerPC) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 224     x86_64)  AC_SUBST(JIT,[[]]) ;;
 225     Alpha)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 226     IA64)    AC_SUBST(JIT,[[]]) ;;
 227     *)       AC_SUBST(JIT,[[]]) ;;
 228   esac
 229 fi
 230
 231 dnl Allow enablement of doxygen generated documentation
 232 AC_ARG_ENABLE(doxygen,
 233               AS_HELP_STRING([--enable-doxygen],
 234                              [Build doxygen documentation (default is NO)]),,
 235                              enableval=default)
 236 case "$enableval" in
 237   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 238   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 239   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 240   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 241 esac
 242
 243 dnl Allow disablement of threads
 244 AC_ARG_ENABLE(threads,
 245               AS_HELP_STRING([--enable-threads],
 246                              [Use threads if available (default is YES)]),,
 247                              enableval=yes)
 248 case "$enableval" in
 249   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 250   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 251   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 252 esac
 253 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 254
 255 dnl Allow specific targets to be specified for building (or not)
 256 TARGETS_TO_BUILD=""
 257 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-target],
 258     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 259     enableval=all)
 260 case "$enableval" in
 261   all) TARGETS_TO_BUILD="X86 Sparc SparcV9 PowerPC Alpha IA64" ;;
 262   host-only)
 263     case "$llvm_cv_target_arch" in
 264       x86)     TARGETS_TO_BUILD="X86" ;;
 265       x86_64)  TARGETS_TO_BUILD="X86" ;;
 266       Sparc)   TARGETS_TO_BUILD="Sparc SparcV9" ;;
 267       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 268       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 269       IA64)    TARGETS_TO_BUILD="IA64" ;;
 270       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 271     esac
 272     ;;
 273   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 274       case "$a_target" in
 275         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 276         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 277         sparc)   TARGETS_TO_BUILD="Sparc SparcV9 $TARGETS_TO_BUILD" ;;
 278         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 279         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 280         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 281         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 282       esac
 283   done
 284   ;;
 285 esac
 286 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 287 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 288
 289 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 290 AC_ARG_WITH(llvmgccdir,
 291   AS_HELP_STRING([--with-llvmgccdir],
 292     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 293     withval=default)
 294 case "$withval" in
 295   default) WITH_LLVMGCCDIR=default ;;
 296   /*)      WITH_LLVMGCCDIR=$withval ;;
 297   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 298 esac
 299
 300
 301 dnl===-----------------------------------------------------------------------===
 302 dnl===
 303 dnl=== SECTION 4: Check for programs we need and that they are the right version
 304 dnl===
 305 dnl===-----------------------------------------------------------------------===
 306
 307 dnl Check for compilation tools
 308 AC_PROG_CPP
 309 AC_PROG_CC(gcc)
 310 AC_PROG_CXX(g++)
 311 AC_PROG_FLEX
 312 AC_PROG_BISON
 313
 314 dnl Check for the tools that the makefiles require
 315 AC_CHECK_GNU_MAKE
 316 AC_PROG_LN_S
 317 AC_PATH_PROG(CMP, [cmp], [cmp])
 318 AC_PATH_PROG(CP, [cp], [cp])
 319 AC_PATH_PROG(DATE, [date], [date])
 320 AC_PATH_PROG(FIND, [find], [find])
 321 AC_PATH_PROG(GREP, [grep], [grep])
 322 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 323 AC_PATH_PROG(MV,   [mv],   [mv])
 324 AC_PROG_RANLIB
 325 AC_PATH_PROG(RM,   [rm],   [rm])
 326 AC_PATH_PROG(SED,  [sed],  [sed])
 327 AC_PATH_PROG(TAR,  [tar],  [gtar])
 328 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 329 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 330   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 331   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ",
 332    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 333 fi
 334 AC_PATH_PROG(GV, [gv], [echo gv])
 335 if test "$GV" != "echo gv" ; then
 336   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 337   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV",
 338    [Define to path to gv program if found or 'echo gv' otherwise])
 339 fi
 340
 341 dnl Find the install program
 342 AC_PROG_INSTALL
 343
 344 dnl Checks for documentation and testing tools that we can do without. If these
 345 dnl are not found then they are set to "true" which always succeeds but does
 346 dnl nothing. This just lets the build output show that we could have done
 347 dnl something if the tool was available.
 348 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 349 AC_PATH_PROG(DOT,[dot],[true dot])
 350 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 351 AC_PATH_PROG(ETAGS,[etags],[true etags])
 352 AC_PATH_PROG(GROFF,[groff],[true groff])
 353 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 354 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 355 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 356 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 357 DJ_AC_PATH_TCLSH
 358 AC_PATH_PROG(ZIP,[zip],[true zip])
 359
 360 dnl Determine if the linker supports the -R option.
 361 AC_LINK_USE_R
 362
 363 dnl Check for libtool and the library that has dlopen function (which must come
 364 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 365 dnl libtool).
 366 AC_LIBTOOL_DLOPEN
 367 AC_LIB_LTDL
 368 AC_PROG_LIBTOOL
 369
 370 if test "$lt_cv_dlopen_self" = "yes" ; then
 371   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 372               [Define if dlopen(0) will open the symbols of the program])
 373 fi
 374
 375 dnl Check if we know how to tell etags we are using C++:
 376 etags_version=`$ETAGS --version 2>&1`
 377 case "$etags_version" in
 378         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 379         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 380         *) ETAGSFLAGS="" ;;
 381 esac
 382 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 383
 384 if test "$WITH_LLVMGCCDIR" = "default" ; then
 385   LLVMGCC="llvm-gcc${EXEEXT}"
 386   LLVMGXX="llvm-g++${EXEEXT}"
 387   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 388   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 389 else
 390   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 391   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 392   AC_SUBST(LLVMGCC,$LLVMGCC)
 393   AC_SUBST(LLVMGXX,$LLVMGXX)
 394 fi
 395
 396 AC_MSG_CHECKING([tool compatibility])
 397
 398 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 399 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 400 dnl to support those options.
 401 dnl "icc" emits gcc signatures
 402 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 403 ICC=no
 404 IXX=no
 405 case $CC in
 406   icc*|icpc*)
 407     ICC=yes
 408     IXX=yes
 409     ;;
 410    *)
 411     ;;
 412 esac
 413
 414 if test "$GCC" != "yes" && test "$ICC" != "yes"
 415 then
 416   AC_MSG_ERROR([gcc|icc required but not found])
 417 fi
 418
 419 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 420 if test "$GXX" != "yes" && test "$IXX" != "yes"
 421 then
 422   AC_MSG_ERROR([g++|icc required but not found])
 423 fi
 424
 425 dnl Verify that GCC is version 3.0 or higher
 426 if test "$GCC" = "yes"
 427 then
 428   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 429   if test "$gccmajor" -lt "3"
 430   then
 431     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 432   fi
 433 fi
 434
 435 dnl Check for GNU Make.  We use its extensions, so don't build without it
 436 if test -z "$llvm_cv_gnu_make_command"
 437 then
 438   AC_MSG_ERROR([GNU Make required but not found])
 439 fi
 440
 441 dnl Tool compatibility is okay if we make it here.
 442 AC_MSG_RESULT([ok])
 443
 444 dnl===-----------------------------------------------------------------------===
 445 dnl===
 446 dnl=== SECTION 5: Check for libraries
 447 dnl===
 448 dnl===-----------------------------------------------------------------------===
 449
 450 dnl libelf is for sparc only; we can ignore it if we don't have it
 451 AC_CHECK_LIB(elf, elf_begin)
 452 AC_CHECK_LIB(m,sin)
 453
 454 dnl lt_dlopen may be required for plugin support.
 455 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 456               [Define if lt_dlopen() is available on this platform]),
 457               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 458                            not be available]))
 459
 460 dnl dlopen() is required for plugin support.
 461 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 462                [Define if dlopen() is available on this platform.]),
 463                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 464
 465 dnl mallinfo is optional; the code can compile (minus features) without it
 466 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 467                [Define if mallinfo() is available on this platform.]))
 468
 469 dnl pthread locking functions are optional - but llvm will not be thread-safe
 470 dnl without locks.
 471 if test "$ENABLE_THREADS" -eq 1 ; then
 472   AC_CHECK_LIB(pthread,pthread_mutex_init)
 473   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 474                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 475                            [Have pthread_mutex_lock]))
 476 fi
 477
 478 dnl===-----------------------------------------------------------------------===
 479 dnl===
 480 dnl=== SECTION 6: Check for header files
 481 dnl===
 482 dnl===-----------------------------------------------------------------------===
 483
 484 dnl First, use autoconf provided macros for specific headers that we need
 485 dnl We don't check for ancient stuff or things that are guaranteed to be there
 486 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 487 dnl Generally we're looking for POSIX headers.
 488 AC_HEADER_DIRENT
 489 AC_HEADER_MMAP_ANONYMOUS
 490 AC_HEADER_STAT
 491 AC_HEADER_STDC
 492 AC_HEADER_SYS_WAIT
 493 AC_HEADER_TIME
 494
 495 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 496 AC_CHECK_HEADERS([malloc.h signal.h stdint.h unistd.h utime.h windows.h])
 497 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/types.h])
 498 AC_CHECK_HEADERS([malloc/malloc.h])
 499 if test "$ENABLE_THREADS" -eq 1 ; then
 500   AC_CHECK_HEADERS(pthread.h)
 501 fi
 502
 503 dnl===-----------------------------------------------------------------------===
 504 dnl===
 505 dnl=== SECTION 7: Check for types and structures
 506 dnl===
 507 dnl===-----------------------------------------------------------------------===
 508
 509 AC_TYPE_PID_T
 510 AC_TYPE_SIZE_T
 511 AC_TYPE_SIGNAL
 512 AC_STRUCT_TM
 513 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 514 AC_CHECK_TYPES([uint64_t],,
 515          AC_CHECK_TYPES([u_int64_t],,
 516          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 517
 518 dnl===-----------------------------------------------------------------------===
 519 dnl===
 520 dnl=== SECTION 8: Check for specific functions needed
 521 dnl===
 522 dnl===-----------------------------------------------------------------------===
 523
 524 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 525 AC_CHECK_FUNCS([getpagesize getrusage gettimeofday isatty mkdtemp mkstemp ])
 526 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 527 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 528 AC_C_PRINTF_A
 529 AC_FUNC_ALLOCA
 530 AC_FUNC_RAND48
 531
 532 dnl Check for variations in the Standard C++ library and STL. These macros are
 533 dnl provided by LLVM in the autoconf/m4 directory.
 534 AC_CXX_HAVE_HASH_MAP
 535 AC_CXX_HAVE_HASH_SET
 536 AC_CXX_HAVE_STD_ITERATOR
 537 AC_CXX_HAVE_BI_ITERATOR
 538 AC_CXX_HAVE_FWD_ITERATOR
 539 AC_FUNC_ISNAN
 540 AC_FUNC_ISINF
 541
 542 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 543 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 544 dnl be opened for allocating RWX memory.
 545 AC_FUNC_MMAP
 546 AC_FUNC_MMAP_FILE
 547 AC_NEED_DEV_ZERO_FOR_MMAP
 548 AC_CHECK_FUNC(mprotect,,
 549               AC_MSG_ERROR([Function mprotect() required but not found]))
 550
 551 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 552 then
 553   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 554 fi
 555 if test "$ac_cv_func_mmap_file" = "no"
 556 then
 557   AC_MSG_WARN([mmap() of files required but not found])
 558 fi
 559
 560 dnl===-----------------------------------------------------------------------===
 561 dnl===
 562 dnl=== SECTION 9: Additional checks, variables, etc.
 563 dnl===
 564 dnl===-----------------------------------------------------------------------===
 565
 566 dnl See if the llvm-gcc executable can compile to LLVM assembly
 567 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 568 [llvm_cv_llvmgcc_sanity="no"
 569 if test -x "$LLVMGCC" ; then
 570   cp /dev/null conftest.c
 571   "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
 572   if test $? -eq 0 ; then
 573     llvm_cv_llvmgcc_sanity="yes"
 574   fi
 575   rm conftest.c
 576 fi])
 577
 578 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 579 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 580   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 581   AC_SUBST(LLVMCC1,$llvmcc1path)
 582   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 583   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 584   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 585   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 586 fi
 587
 588 dnl Propagate the shared library extension that the libltdl checks did to
 589 dnl the Makefiles so we can use it there too
 590 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 591
 592 # Translate the various configuration directories and other basic
 593 # information into substitutions that will end up in Makefile.config.in
 594 # that these configured values can be used by the makefiles
 595 eval LLVM_PREFIX="${prefix}";
 596 eval LLVM_BINDIR="${prefix}/bin";
 597 eval LLVM_LIBDIR="${prefix}/lib";
 598 eval LLVM_DATADIR="${prefix}/share/llvm";
 599 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 600 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 601 eval LLVM_INCLUDEDIR="${prefix}/include";
 602 eval LLVM_INFODIR="${prefix}/info";
 603 eval LLVM_MANDIR="${prefix}/man";
 604 LLVM_CONFIGTIME=`date`
 605 AC_SUBST(LLVM_PREFIX)
 606 AC_SUBST(LLVM_BINDIR)
 607 AC_SUBST(LLVM_LIBDIR)
 608 AC_SUBST(LLVM_DATADIR)
 609 AC_SUBST(LLVM_DOCSDIR)
 610 AC_SUBST(LLVM_ETCDIR)
 611 AC_SUBST(LLVM_INCLUDEDIR)
 612 AC_SUBST(LLVM_INFODIR)
 613 AC_SUBST(LLVM_MANDIR)
 614 AC_SUBST(LLVM_CONFIGTIME)
 615
 616 # Place the various directores into the config.h file as #defines so that we
 617 # can know about the installation paths within LLVM.
 618 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 619                    [Installation prefix directory])
 620 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 621                    [Installation directory for binary executables])
 622 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 623                    [Installation directory for libraries])
 624 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 625                    [Installation directory for data files])
 626 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 627                    [Installation directory for documentation])
 628 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 629                    [Installation directory for config files])
 630 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 631                    [Installation directory for include files])
 632 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 633                    [Installation directory for .info files])
 634 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 635                    [Installation directory for man pages])
 636 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 637                    [Time at which LLVM was configured])
 638
 639 dnl===-----------------------------------------------------------------------===
 640 dnl===
 641 dnl=== SECTION 10: Specify the output files and generate it
 642 dnl===
 643 dnl===-----------------------------------------------------------------------===
 644
 645 dnl Configure header files
 646 dnl WARNING: dnl If you add or remove any of the following config headers, then
 647 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 648 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 649 dnl files can be updated automatically when their *.in sources change.
 650 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 651 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 652 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 653 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 654 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 655
 656 dnl Configure the makefile's configuration data
 657 AC_CONFIG_FILES([Makefile.config])
 658
 659 dnl Configure doxygen's configuration file
 660 AC_CONFIG_FILES([docs/doxygen.cfg])
 661
 662 dnl Do the first stage of configuration for llvm-config.in.
 663 AC_CONFIG_FILES([utils/llvm-config/llvm-config.in])
 664
 665 dnl Do special configuration of Makefiles
 666 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 667 AC_CONFIG_MAKEFILE(Makefile)
 668 AC_CONFIG_MAKEFILE(Makefile.common)
 669 AC_CONFIG_MAKEFILE(examples/Makefile)
 670 AC_CONFIG_MAKEFILE(lib/Makefile)
 671 AC_CONFIG_MAKEFILE(runtime/Makefile)
 672 AC_CONFIG_MAKEFILE(test/Makefile)
 673 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 674 AC_CONFIG_MAKEFILE(tools/Makefile)
 675 AC_CONFIG_MAKEFILE(utils/Makefile)
 676 AC_CONFIG_MAKEFILE(projects/Makefile)
 677
 678 dnl Finally, crank out the output
 679 AC_OUTPUT
 680
 681 dnl Warn loudly if llvm-gcc was not obviously working
 682 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 683  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 684  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 685  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 686  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 687  AC_MSG_WARN([***** build the llvm tools.])
 688 fi