autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.6cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT($LLVM_COPYRIGHT)
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  78       *)
  79         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  80         ;;
  81     esac
  82   fi
  83 done
  84
  85 dnl===-----------------------------------------------------------------------===
  86 dnl===
  87 dnl=== SECTION 2: Architecture, target, and host checks
  88 dnl===
  89 dnl===-----------------------------------------------------------------------===
  90
  91 dnl Check the target for which we're compiling and the host that will do the
  92 dnl compilations. This will tell us which LLVM compiler will be used for
  93 dnl compiling SSA into object code. This needs to be done early because
  94 dnl following tests depend on it.
  95 AC_CANONICAL_TARGET
  96
  97 dnl Determine the platform type and cache its value. This helps us configure
  98 dnl the System library to the correct build platform.
  99 AC_CACHE_CHECK([type of operating system we're on],
 100                [llvm_cv_os_type],
 101 [case $build in
 102   *-*-aix*)
 103     llvm_cv_os_type="AIX"
 104     llvm_cv_platform_type="Unix" ;;
 105   *-*-cygwin*)
 106     llvm_cv_os_type="Cygwin"
 107     llvm_cv_platform_type="Unix" ;;
 108   *-*-darwin*)
 109     llvm_cv_os_type="Darwin"
 110     llvm_cv_platform_type="Unix" ;;
 111   *-*-freebsd*)
 112     llvm_cv_os_type="FreeBSD"
 113     llvm_cv_platform_type="Unix" ;;
 114   *-*-hpux*)
 115     llvm_cv_os_type="HP-UX"
 116     llvm_cv_platform_type="Unix" ;;
 117   *-*-interix*)
 118     llvm_cv_os_type="Interix"
 119     llvm_cv_platform_type="Unix" ;;
 120   *-*-linux*)
 121     llvm_cv_os_type="Linux"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-solaris*)
 124     llvm_cv_os_type="SunOS"
 125     llvm_cv_platform_type="Unix" ;;
 126   *-*-win32*)
 127     llvm_cv_os_type="Win32"
 128     llvm_cv_platform_type="Win32" ;;
 129   *-*-mingw*)
 130     llvm_cv_os_type="MingW"
 131     llvm_cv_platform_type="Win32" ;;
 132   *)
 133     llvm_cv_os_type="Unknown"
 134     llvm_cv_platform_type="Unknown" ;;
 135 esac])
 136
 137 dnl Make sure we aren't attempting to configure for an unknown system
 138 if test "$llvm_cv_os_type" = "Unknown" ; then
 139   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 140 fi
 141
 142 dnl Set the "OS" Makefile variable based on the platform type so the
 143 dnl makefile can configure itself to specific build hosts
 144 AC_SUBST(OS,$llvm_cv_os_type)
 145
 146 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 147 dnl This is used by lib/System to determine the basic kind of implementation
 148 dnl to use.
 149 case $llvm_cv_platform_type in
 150   Unix)
 151     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 152     AC_SUBST(LLVM_ON_UNIX,[1])
 153     AC_SUBST(LLVM_ON_WIN32,[0])
 154     ;;
 155   Win32)
 156     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 157     AC_SUBST(LLVM_ON_UNIX,[0])
 158     AC_SUBST(LLVM_ON_WIN32,[1])
 159     ;;
 160 esac
 161
 162 dnl Determine what our target architecture is and configure accordingly.
 163 dnl This will allow Makefiles to make a distinction between the hardware and
 164 dnl the OS.
 165 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 166 [case $target in
 167   i?86-*)                 llvm_cv_target_arch="x86" ;;
 168   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 169   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 170   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 171   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 172   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 173   *)                      llvm_cv_target_arch="Unknown" ;;
 174 esac])
 175
 176 if test "$llvm_cv_target_arch" = "Unknown" ; then
 177   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 178 fi
 179
 180 dnl Define a substitution, ARCH, for the target architecture
 181 AC_SUBST(ARCH,$llvm_cv_target_arch)
 182
 183 dnl Check for the endianness of the target
 184 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 185
 186 dnl===-----------------------------------------------------------------------===
 187 dnl===
 188 dnl=== SECTION 3: Command line arguments for the configure script.
 189 dnl===
 190 dnl===-----------------------------------------------------------------------===
 191
 192 dnl --enable-optimized : check whether they want to do an optimized build:
 193 AC_ARG_ENABLE(optimized,
 194               AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
 195 if test ${enableval} = "no" ; then
 196   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 197 else
 198   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 199 fi
 200
 201 dnl --enable-jit: check whether they want to enable the jit
 202 AC_ARG_ENABLE(jit,
 203   AS_HELP_STRING(--enable-jit,
 204                  [Enable Just In Time Compiling (default is YES)]),,
 205   enableval=default)
 206 if test ${enableval} = "no"
 207 then
 208   AC_SUBST(JIT,[[]])
 209 else
 210   case "$llvm_cv_target_arch" in
 211     x86)     AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 212     Sparc)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 213     PowerPC) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 214     x86_64)  AC_SUBST(JIT,[[]]) ;;
 215     Alpha)   AC_SUBST(JIT,[[]]) ;;
 216     IA64)    AC_SUBST(JIT,[[]]) ;;
 217     *)       AC_SUBST(JIT,[[]]) ;;
 218   esac
 219 fi
 220
 221 dnl Allow enablement of doxygen generated documentation
 222 AC_ARG_ENABLE(doxygen,
 223               AS_HELP_STRING([--enable-doxygen],
 224                              [Build doxygen documentation (default is NO)]),,
 225                              enableval=default)
 226 case "$enableval" in
 227   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 228   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 229   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 230   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 231 esac
 232
 233 dnl Allow specific targets to be specified for building (or not)
 234 TARGETS_TO_BUILD=""
 235 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-target],
 236     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 237     enableval=all)
 238 case "$enableval" in
 239   all) TARGETS_TO_BUILD="X86 SparcV8 SparcV9 PowerPC Alpha IA64 Skeleton" ;;
 240   host-only)
 241     case "$llvm_cv_target_arch" in
 242       x86)     TARGETS_TO_BUILD="X86" ;;
 243       x86_64)  TARGETS_TO_BUILD="X86" ;;
 244       Sparc)   TARGETS_TO_BUILD="SparcV8 SparcV9" ;;
 245       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 246       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 247       IA64)    TARGETS_TO_BUILD="IA64" ;;
 248       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 249     esac
 250     ;;
 251   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 252       case "$a_target" in
 253         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 254         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 255         sparc)   TARGETS_TO_BUILD="SparcV8 SparcV9 $TARGETS_TO_BUILD" ;;
 256         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 257         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 258         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 259         skeleton)TARGETS_TO_BUILD="Skeleton $TARGETS_TO_BUILD";;
 260         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 261       esac
 262   done
 263   ;;
 264 esac
 265 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 266 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 267
 268 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 269 AC_ARG_WITH(llvmgccdir,
 270   AS_HELP_STRING([--with-llvmgccdir],
 271     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 272     withval=default)
 273 case "$withval" in
 274   default) WITH_LLVMGCCDIR=default ;;
 275   /*)      WITH_LLVMGCCDIR=$withval ;;
 276   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 277 esac
 278
 279
 280 dnl===-----------------------------------------------------------------------===
 281 dnl===
 282 dnl=== SECTION 4: Check for programs we need and that they are the right version
 283 dnl===
 284 dnl===-----------------------------------------------------------------------===
 285
 286 dnl Check for compilation tools
 287 AC_PROG_CPP
 288 AC_PROG_CC(gcc)
 289 AC_PROG_CXX(g++)
 290 AC_PROG_FLEX
 291 AC_PROG_BISON
 292
 293 dnl Check for the tools that the makefiles require
 294 AC_CHECK_GNU_MAKE
 295 AC_PROG_LN_S
 296 AC_PATH_PROG(CMP, [cmp], [cmp])
 297 AC_PATH_PROG(CP, [cp], [cp])
 298 AC_PATH_PROG(DATE, [date], [date])
 299 AC_PATH_PROG(FIND, [find], [find])
 300 AC_PATH_PROG(GREP, [grep], [grep])
 301 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 302 AC_PATH_PROG(MV,   [mv],   [mv])
 303 AC_PROG_RANLIB
 304 AC_PATH_PROG(RM,   [rm],   [rm])
 305 AC_PATH_PROG(SED,  [sed],  [sed])
 306 AC_PATH_PROG(TAR,  [tar],  [gtar])
 307
 308 dnl Find the install program
 309 AC_PROG_INSTALL
 310
 311 dnl Checks for documentation and testing tools that we can do without. If these
 312 dnl are not found then they are set to "true" which always succeeds but does
 313 dnl nothing. This just lets the build output show that we could have done
 314 dnl something if the tool was available.
 315 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 316 AC_PATH_PROG(DOT,[dot],[true dot])
 317 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 318 AC_PATH_PROG(ETAGS,[etags],[true etags])
 319 AC_PATH_PROG(GROFF,[groff],[true groff])
 320 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 321 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 322 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 323 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 324 DJ_AC_PATH_TCLSH
 325 AC_PATH_PROG(ZIP,[zip],[true zip])
 326
 327 dnl Determine if the linker supports the -R option.
 328 AC_LINK_USE_R
 329
 330 dnl Check for libtool and the library that has dlopen function (which must come
 331 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 332 dnl libtool).
 333 AC_LIBTOOL_DLOPEN
 334 AC_LIB_LTDL
 335 AC_PROG_LIBTOOL
 336
 337 if test "$lt_cv_dlopen_self" = "yes" ; then
 338   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 339               [Define if dlopen(0) will open the symbols of the program])
 340 fi
 341
 342 dnl Check if we know how to tell etags we are using C++:
 343 etags_version=`$ETAGS --version 2>&1`
 344 case "$etags_version" in
 345         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 346         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 347         *) ETAGSFLAGS="" ;;
 348 esac
 349 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 350
 351 if test "$WITH_LLVMGCCDIR" = "default" ; then
 352   LLVMGCC="llvm-gcc${EXEEXT}"
 353   LLVMGXX="llvm-g++${EXEEXT}"
 354   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 355   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 356 else
 357   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 358   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 359   AC_SUBST(LLVMGCC,$LLVMGCC)
 360   AC_SUBST(LLVMGXX,$LLVMGXX)
 361 fi
 362
 363 AC_MSG_CHECKING([tool compatibility])
 364
 365 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 366 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 367 dnl to support those options.
 368 dnl "icc" emits gcc signatures
 369 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 370 ICC=no
 371 IXX=no
 372 case $CC in
 373   icc*|icpc*)
 374     ICC=yes
 375     IXX=yes
 376     ;;
 377    *)
 378     ;;
 379 esac
 380
 381 if test "$GCC" != "yes" && test "$ICC" != "yes"
 382 then
 383   AC_MSG_ERROR([gcc|icc required but not found])
 384 fi
 385
 386 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 387 if test "$GXX" != "yes" && test "$IXX" != "yes"
 388 then
 389   AC_MSG_ERROR([g++|icc required but not found])
 390 fi
 391
 392 dnl Verify that GCC is version 3.0 or higher
 393 if test "$GCC" = "yes"
 394 then
 395   gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 396   if test "$gccmajor" -lt "3"
 397   then
 398     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 399   fi
 400 fi
 401
 402 dnl Check for GNU Make.  We use its extensions, so don't build without it
 403 if test -z "$llvm_cv_gnu_make_command"
 404 then
 405   AC_MSG_ERROR([GNU Make required but not found])
 406 fi
 407
 408 dnl Tool compatibility is okay if we make it here.
 409 AC_MSG_RESULT([ok])
 410
 411 dnl===-----------------------------------------------------------------------===
 412 dnl===
 413 dnl=== SECTION 5: Check for libraries
 414 dnl===
 415 dnl===-----------------------------------------------------------------------===
 416
 417 dnl libelf is for sparc only; we can ignore it if we don't have it
 418 AC_CHECK_LIB(elf, elf_begin)
 419
 420
 421 dnl lt_dlopen may be required for plugin support.
 422 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 423               [Define if lt_dlopen() is available on this platform]),
 424               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 425                            not be available]))
 426
 427 dnl dlopen() is required for plugin support.
 428 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 429                [Define if dlopen() is available on this platform.]),
 430                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 431
 432 dnl mallinfo is optional; the code can compile (minus features) without it
 433 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 434                [Define if mallinfo() is available on this platform.]))
 435
 436 dnl pthread locking functions are optional - but llvm will not be thread-safe
 437 dnl without locks.
 438 AC_CHECK_LIB(pthread,pthread_mutex_init)
 439 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 440                AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 441                          [Have pthread_mutex_lock]))
 442
 443 dnl===-----------------------------------------------------------------------===
 444 dnl===
 445 dnl=== SECTION 6: Check for header files
 446 dnl===
 447 dnl===-----------------------------------------------------------------------===
 448
 449 dnl First, use autoconf provided macros for specific headers that we need
 450 dnl We don't check for ancient stuff or things that are guaranteed to be there
 451 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 452 dnl Generally we're looking for POSIX headers.
 453 AC_HEADER_DIRENT
 454 AC_HEADER_MMAP_ANONYMOUS
 455 AC_HEADER_STAT
 456 AC_HEADER_STDC
 457 AC_HEADER_SYS_WAIT
 458 AC_HEADER_TIME
 459
 460 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 461 AC_CHECK_HEADERS([malloc.h pthread.h signal.h stdint.h unistd.h utime.h])
 462 AC_CHECK_HEADERS([windows.h])
 463 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/types.h])
 464 AC_CHECK_HEADERS([rw/stdex/hash_map.h rw/stdex/hash_set.h])
 465
 466 dnl===-----------------------------------------------------------------------===
 467 dnl===
 468 dnl=== SECTION 7: Check for types and structures
 469 dnl===
 470 dnl===-----------------------------------------------------------------------===
 471
 472 AC_TYPE_PID_T
 473 AC_TYPE_SIZE_T
 474 AC_TYPE_SIGNAL
 475 AC_STRUCT_TM
 476 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 477 AC_CHECK_TYPES([uint64_t],,
 478          AC_CHECK_TYPES([u_int64_t],,
 479          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 480
 481 dnl===-----------------------------------------------------------------------===
 482 dnl===
 483 dnl=== SECTION 8: Check for specific functions needed
 484 dnl===
 485 dnl===-----------------------------------------------------------------------===
 486
 487 AC_CHECK_FUNCS([backtrace getcwd getpagesize getrusage gettimeofday ])
 488 AC_CHECK_FUNCS([isatty mkdtemp mkstemp mktemp ])
 489 AC_CHECK_FUNCS([realpath sbrk setrlimit strdup strerror strerror_r ])
 490 AC_CHECK_FUNCS([strtoll strtoq sysconf])
 491 AC_C_PRINTF_A
 492 AC_FUNC_ALLOCA
 493 AC_FUNC_RAND48
 494
 495 dnl Check for variations in the Standard C++ library and STL. These macros are
 496 dnl provided by LLVM in the autoconf/m4 directory.
 497 AC_CXX_HAVE_HASH_MAP
 498 AC_CXX_HAVE_HASH_SET
 499 AC_CXX_HAVE_STD_ITERATOR
 500 AC_CXX_HAVE_BI_ITERATOR
 501 AC_CXX_HAVE_FWD_ITERATOR
 502 AC_FUNC_ISNAN
 503 AC_FUNC_ISINF
 504
 505 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 506 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 507 dnl be opened for allocating RWX memory.
 508 AC_FUNC_MMAP
 509 AC_FUNC_MMAP_FILE
 510 AC_NEED_DEV_ZERO_FOR_MMAP
 511 AC_CHECK_FUNC(mprotect,,
 512               AC_MSG_ERROR([Function mprotect() required but not found]))
 513
 514 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 515 then
 516   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 517 fi
 518 if test "$ac_cv_func_mmap_file" = "no"
 519 then
 520   AC_MSG_WARN([mmap() of files required but not found])
 521 fi
 522
 523 dnl===-----------------------------------------------------------------------===
 524 dnl===
 525 dnl=== SECTION 9: Additional checks, variables, etc.
 526 dnl===
 527 dnl===-----------------------------------------------------------------------===
 528
 529 dnl See if the llvm-gcc executable can compile to LLVM assembly
 530 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 531 [llvm_cv_llvmgcc_sanity="no"
 532 if test -x "$LLVMGCC" ; then
 533   cp /dev/null conftest.c
 534   "$LLVMGCC" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 535   if test $? -eq 0 ; then
 536     llvm_cv_llvmgcc_sanity="yes"
 537   fi
 538   rm conftest.c
 539 fi])
 540
 541 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 542 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 543   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 544   AC_SUBST(LLVMCC1,$llvmcc1path)
 545   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 546   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 547   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 548   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 549 fi
 550
 551 dnl Propagate the shared library extension that the libltdl checks did to
 552 dnl the Makefiles so we can use it there too
 553 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 554
 555 # Translate the various configuration directories and other basic
 556 # information into substitutions that will end up in Makefile.config.in
 557 # that these configured values can be used by the makefiles
 558 eval LLVM_PREFIX="${prefix}";
 559 eval LLVM_BINDIR="${prefix}/bin";
 560 eval LLVM_LIBDIR="${prefix}/lib";
 561 eval LLVM_DATADIR="${prefix}/share/llvm";
 562 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 563 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 564 eval LLVM_INCLUDEDIR="${prefix}/include";
 565 eval LLVM_INFODIR="${prefix}/info";
 566 eval LLVM_MANDIR="${prefix}/man";
 567 LLVM_CONFIGTIME=`date`
 568 AC_SUBST(LLVM_PREFIX)
 569 AC_SUBST(LLVM_BINDIR)
 570 AC_SUBST(LLVM_LIBDIR)
 571 AC_SUBST(LLVM_DATADIR)
 572 AC_SUBST(LLVM_DOCSDIR)
 573 AC_SUBST(LLVM_ETCDIR)
 574 AC_SUBST(LLVM_INCLUDEDIR)
 575 AC_SUBST(LLVM_INFODIR)
 576 AC_SUBST(LLVM_MANDIR)
 577 AC_SUBST(LLVM_CONFIGTIME)
 578
 579 # Place the various directores into the config.h file as #defines so that we
 580 # can know about the installation paths within LLVM.
 581 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 582                    [Installation prefix directory])
 583 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 584                    [Installation directory for binary executables])
 585 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 586                    [Installation directory for libraries])
 587 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 588                    [Installation directory for data files])
 589 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 590                    [Installation directory for documentation])
 591 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 592                    [Installation directory for config files])
 593 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 594                    [Installation directory for include files])
 595 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 596                    [Installation directory for .info files])
 597 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 598                    [Installation directory for man pages])
 599 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 600                    [Time at which LLVM was configured])
 601
 602 dnl===-----------------------------------------------------------------------===
 603 dnl===
 604 dnl=== SECTION 10: Specify the output files and generate it
 605 dnl===
 606 dnl===-----------------------------------------------------------------------===
 607
 608 dnl Configure header files
 609 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 610 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 611 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 612 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 613 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 614
 615 dnl Configure the makefile's configuration data
 616 AC_CONFIG_FILES([Makefile.config])
 617
 618 dnl Configure doxygen's configuration file
 619 AC_CONFIG_FILES([docs/doxygen.cfg])
 620
 621 dnl Do special configuration of Makefiles
 622 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 623 AC_CONFIG_MAKEFILE(Makefile)
 624 AC_CONFIG_MAKEFILE(Makefile.common)
 625 AC_CONFIG_MAKEFILE(examples/Makefile)
 626 AC_CONFIG_MAKEFILE(lib/Makefile)
 627 AC_CONFIG_MAKEFILE(runtime/Makefile)
 628 AC_CONFIG_MAKEFILE(test/Makefile)
 629 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 630 AC_CONFIG_MAKEFILE(tools/Makefile)
 631 AC_CONFIG_MAKEFILE(utils/Makefile)
 632 AC_CONFIG_MAKEFILE(projects/Makefile)
 633
 634 dnl Finally, crank out the output
 635 AC_OUTPUT
 636
 637 dnl Warn loudly if llvm-gcc was not obviously working
 638 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 639  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 640  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 641  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 642  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 643  AC_MSG_WARN([***** build the llvm tools.])
 644 fi