autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[3.0svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2011 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2011 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65
  66 dnl
  67 dnl One tricky part of doing this is that some projects depend upon other
  68 dnl projects.  For example, several projects rely upon the LLVM test suite.
  69 dnl We want to configure those projects first so that their object trees are
  70 dnl created before running the configure scripts of projects that depend upon
  71 dnl them.
  72 dnl
  73
  74 dnl Several projects use llvm-gcc, so configure that first
  75 if test -d ${srcdir}/projects/llvm-gcc ; then
  76   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  77 fi
  78
  79 dnl Several projects use the LLVM test suite, so configure it next.
  80 if test -d ${srcdir}/projects/test-suite ; then
  81   AC_CONFIG_SUBDIRS([projects/test-suite])
  82 fi
  83
  84 dnl llvm-test is the old name of the test-suite, kept here for backwards
  85 dnl compatibility
  86 if test -d ${srcdir}/projects/llvm-test ; then
  87   AC_CONFIG_SUBDIRS([projects/llvm-test])
  88 fi
  89
  90 dnl Some projects use poolalloc; configure that next
  91 if test -d ${srcdir}/projects/poolalloc ; then
  92   AC_CONFIG_SUBDIRS([projects/poolalloc])
  93 fi
  94
  95 if test -d ${srcdir}/projects/llvm-poolalloc ; then
  96   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
  97 fi
  98
  99 dnl Check for all other projects
 100 for i in `ls ${srcdir}/projects`
 101 do
 102   if test -d ${srcdir}/projects/${i} ; then
 103     case ${i} in
 104       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 105       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 106       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 107       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 108       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 109       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 110       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 111       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 112       llvm-gcc)       ;;
 113       test-suite)     ;;
 114       llvm-test)      ;;
 115       poolalloc)      ;;
 116       llvm-poolalloc) ;;
 117       *)
 118         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 119         ;;
 120     esac
 121   fi
 122 done
 123
 124 dnl Disable the build of polly, even if it is checked out into tools/polly.
 125 AC_ARG_ENABLE(polly,
 126               AS_HELP_STRING([--enable-polly],
 127                              [Use polly if available (default is YES)]),,
 128                              enableval=default)
 129 case "$enableval" in
 130   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 131   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 132   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 133   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 134 esac
 135
 136
 137 dnl Check if polly is checked out into tools/polly and configure it if
 138 dnl available.
 139 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 140   AC_SUBST(LLVM_HAS_POLLY,1)
 141   AC_CONFIG_SUBDIRS([tools/polly])
 142 fi
 143
 144 dnl===-----------------------------------------------------------------------===
 145 dnl===
 146 dnl=== SECTION 2: Architecture, target, and host checks
 147 dnl===
 148 dnl===-----------------------------------------------------------------------===
 149
 150 dnl Check the target for which we're compiling and the host that will do the
 151 dnl compilations. This will tell us which LLVM compiler will be used for
 152 dnl compiling SSA into object code. This needs to be done early because
 153 dnl following tests depend on it.
 154 AC_CANONICAL_TARGET
 155
 156 dnl Determine the platform type and cache its value. This helps us configure
 157 dnl the System library to the correct build platform.
 158 AC_CACHE_CHECK([type of operating system we're going to host on],
 159                [llvm_cv_os_type],
 160 [case $host in
 161   *-*-aix*)
 162     llvm_cv_link_all_option="-Wl,--whole-archive"
 163     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 164     llvm_cv_os_type="AIX"
 165     llvm_cv_platform_type="Unix" ;;
 166   *-*-irix*)
 167     llvm_cv_link_all_option="-Wl,--whole-archive"
 168     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 169     llvm_cv_os_type="IRIX"
 170     llvm_cv_platform_type="Unix" ;;
 171   *-*-cygwin*)
 172     llvm_cv_link_all_option="-Wl,--whole-archive"
 173     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 174     llvm_cv_os_type="Cygwin"
 175     llvm_cv_platform_type="Unix" ;;
 176   *-*-darwin*)
 177     llvm_cv_link_all_option="-Wl,-all_load"
 178     llvm_cv_no_link_all_option="-Wl,-noall_load"
 179     llvm_cv_os_type="Darwin"
 180     llvm_cv_platform_type="Unix" ;;
 181   *-*-minix*)
 182     llvm_cv_link_all_option="-Wl,-all_load"
 183     llvm_cv_no_link_all_option="-Wl,-noall_load"
 184     llvm_cv_os_type="Minix"
 185     llvm_cv_platform_type="Unix" ;;
 186   *-*-freebsd*)
 187     llvm_cv_link_all_option="-Wl,--whole-archive"
 188     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 189     llvm_cv_os_type="FreeBSD"
 190     llvm_cv_platform_type="Unix" ;;
 191   *-*-openbsd*)
 192     llvm_cv_link_all_option="-Wl,--whole-archive"
 193     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 194     llvm_cv_os_type="OpenBSD"
 195     llvm_cv_platform_type="Unix" ;;
 196   *-*-netbsd*)
 197     llvm_cv_link_all_option="-Wl,--whole-archive"
 198     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 199     llvm_cv_os_type="NetBSD"
 200     llvm_cv_platform_type="Unix" ;;
 201   *-*-dragonfly*)
 202     llvm_cv_link_all_option="-Wl,--whole-archive"
 203     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 204     llvm_cv_os_type="DragonFly"
 205     llvm_cv_platform_type="Unix" ;;
 206   *-*-hpux*)
 207     llvm_cv_link_all_option="-Wl,--whole-archive"
 208     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 209     llvm_cv_os_type="HP-UX"
 210     llvm_cv_platform_type="Unix" ;;
 211   *-*-interix*)
 212     llvm_cv_link_all_option="-Wl,--whole-archive"
 213     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 214     llvm_cv_os_type="Interix"
 215     llvm_cv_platform_type="Unix" ;;
 216   *-*-linux*)
 217     llvm_cv_link_all_option="-Wl,--whole-archive"
 218     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 219     llvm_cv_os_type="Linux"
 220     llvm_cv_platform_type="Unix" ;;
 221   *-*-solaris*)
 222     llvm_cv_link_all_option="-Wl,-z,allextract"
 223     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 224     llvm_cv_os_type="SunOS"
 225     llvm_cv_platform_type="Unix" ;;
 226   *-*-auroraux*)
 227     llvm_cv_link_all_option="-Wl,-z,allextract"
 228     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 229     llvm_cv_os_type="AuroraUX"
 230     llvm_cv_platform_type="Unix" ;;
 231   *-*-win32*)
 232     llvm_cv_link_all_option="-Wl,--whole-archive"
 233     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 234     llvm_cv_os_type="Win32"
 235     llvm_cv_platform_type="Win32" ;;
 236   *-*-mingw*)
 237     llvm_cv_link_all_option="-Wl,--whole-archive"
 238     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 239     llvm_cv_os_type="MingW"
 240     llvm_cv_platform_type="Win32" ;;
 241   *-*-haiku*)
 242     llvm_cv_link_all_option="-Wl,--whole-archive"
 243     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 244     llvm_cv_os_type="Haiku"
 245     llvm_cv_platform_type="Unix" ;;
 246   *-unknown-eabi*)
 247     llvm_cv_link_all_option="-Wl,--whole-archive"
 248     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 249     llvm_cv_os_type="Freestanding"
 250     llvm_cv_platform_type="Unix" ;;
 251   *-unknown-elf*)
 252     llvm_cv_link_all_option="-Wl,--whole-archive"
 253     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 254     llvm_cv_os_type="Freestanding"
 255     llvm_cv_platform_type="Unix" ;;
 256   *)
 257     llvm_cv_link_all_option=""
 258     llvm_cv_no_link_all_option=""
 259     llvm_cv_os_type="Unknown"
 260     llvm_cv_platform_type="Unknown" ;;
 261 esac])
 262
 263 AC_CACHE_CHECK([type of operating system we're going to target],
 264                [llvm_cv_target_os_type],
 265 [case $target in
 266   *-*-aix*)
 267     llvm_cv_target_os_type="AIX" ;;
 268   *-*-irix*)
 269     llvm_cv_target_os_type="IRIX" ;;
 270   *-*-cygwin*)
 271     llvm_cv_target_os_type="Cygwin" ;;
 272   *-*-darwin*)
 273     llvm_cv_target_os_type="Darwin" ;;
 274   *-*-minix*)
 275     llvm_cv_target_os_type="Minix" ;;
 276   *-*-freebsd*)
 277     llvm_cv_target_os_type="FreeBSD" ;;
 278   *-*-openbsd*)
 279     llvm_cv_target_os_type="OpenBSD" ;;
 280   *-*-netbsd*)
 281     llvm_cv_target_os_type="NetBSD" ;;
 282   *-*-dragonfly*)
 283     llvm_cv_target_os_type="DragonFly" ;;
 284   *-*-hpux*)
 285     llvm_cv_target_os_type="HP-UX" ;;
 286   *-*-interix*)
 287     llvm_cv_target_os_type="Interix" ;;
 288   *-*-linux*)
 289     llvm_cv_target_os_type="Linux" ;;
 290   *-*-solaris*)
 291     llvm_cv_target_os_type="SunOS" ;;
 292   *-*-auroraux*)
 293     llvm_cv_target_os_type="AuroraUX" ;;
 294   *-*-win32*)
 295     llvm_cv_target_os_type="Win32" ;;
 296   *-*-mingw*)
 297     llvm_cv_target_os_type="MingW" ;;
 298   *-*-haiku*)
 299     llvm_cv_target_os_type="Haiku" ;;
 300   *-*-rtems*)
 301     llvm_cv_target_os_type="RTEMS" ;;
 302   *-unknown-eabi*)
 303     llvm_cv_target_os_type="Freestanding" ;;
 304   *)
 305     llvm_cv_target_os_type="Unknown" ;;
 306 esac])
 307
 308 dnl Make sure we aren't attempting to configure for an unknown system
 309 if test "$llvm_cv_os_type" = "Unknown" ; then
 310   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 311 fi
 312
 313 dnl Set the "OS" Makefile variable based on the platform type so the
 314 dnl makefile can configure itself to specific build hosts
 315 AC_SUBST(OS,$llvm_cv_os_type)
 316 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 317 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 318
 319 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 320 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 321 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 322
 323 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 324 dnl This is used by lib/Support to determine the basic kind of implementation
 325 dnl to use.
 326 case $llvm_cv_platform_type in
 327   Unix)
 328     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 329     AC_SUBST(LLVM_ON_UNIX,[1])
 330     AC_SUBST(LLVM_ON_WIN32,[0])
 331     ;;
 332   Win32)
 333     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 334     AC_SUBST(LLVM_ON_UNIX,[0])
 335     AC_SUBST(LLVM_ON_WIN32,[1])
 336     ;;
 337 esac
 338
 339 dnl Determine what our target architecture is and configure accordingly.
 340 dnl This will allow Makefiles to make a distinction between the hardware and
 341 dnl the OS.
 342 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 343 [case $target in
 344   i?86-*)                 llvm_cv_target_arch="x86" ;;
 345   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 346   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 347   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 348   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 349   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 350   mips-*)                 llvm_cv_target_arch="Mips" ;;
 351   xcore-*)                llvm_cv_target_arch="XCore" ;;
 352   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 353   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 354   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 355   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 356   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 357   *)                      llvm_cv_target_arch="Unknown" ;;
 358 esac])
 359
 360 if test "$llvm_cv_target_arch" = "Unknown" ; then
 361   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 362 fi
 363
 364 # Determine the LLVM native architecture for the target
 365 case "$llvm_cv_target_arch" in
 366     x86)     LLVM_NATIVE_ARCH="X86" ;;
 367     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 368     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 369 esac
 370
 371 dnl Define a substitution, ARCH, for the target architecture
 372 AC_SUBST(ARCH,$llvm_cv_target_arch)
 373
 374 dnl Check for the endianness of the target
 375 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 376
 377 dnl Check for build platform executable suffix if we're crosscompiling
 378 if test "$cross_compiling" = yes; then
 379   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 380   AC_BUILD_EXEEXT
 381   ac_build_prefix=${build_alias}-
 382   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 383   if test -z "$BUILD_CXX"; then
 384      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 385      if test -z "$BUILD_CXX"; then
 386        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 387      fi
 388   fi
 389 else
 390   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 391 fi
 392
 393 dnl Check to see if there's a .svn or .git directory indicating that this
 394 dnl build is being done from a checkout. This sets up several defaults for
 395 dnl the command line switches. When we build with a checkout directory,
 396 dnl we get a debug with assertions turned on. Without, we assume a source
 397 dnl release and we get an optimized build without assertions.
 398 dnl See --enable-optimized and --enable-assertions below
 399 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 400   cvsbuild="yes"
 401   optimize="no"
 402   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 403 else
 404   cvsbuild="no"
 405   optimize="yes"
 406 fi
 407
 408 dnl===-----------------------------------------------------------------------===
 409 dnl===
 410 dnl=== SECTION 3: Command line arguments for the configure script.
 411 dnl===
 412 dnl===-----------------------------------------------------------------------===
 413
 414 dnl --enable-optimized : check whether they want to do an optimized build:
 415 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 416  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 417 if test ${enableval} = "no" ; then
 418   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 419 else
 420   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 421 fi
 422
 423 dnl --enable-profiling : check whether they want to do a profile build:
 424 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 425  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 426 if test ${enableval} = "no" ; then
 427   AC_SUBST(ENABLE_PROFILING,[[]])
 428 else
 429   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 430 fi
 431
 432 dnl --enable-assertions : check whether they want to turn on assertions or not:
 433 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 434   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 435 if test ${enableval} = "yes" ; then
 436   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 437 else
 438   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 439 fi
 440
 441 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 442 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 443   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 444 if test ${enableval} = "yes" ; then
 445   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 446   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 447 else
 448   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 449   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 450 fi
 451
 452 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 453 AC_ARG_ENABLE(debug-runtime,
 454    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 455 if test ${enableval} = "no" ; then
 456   AC_SUBST(DEBUG_RUNTIME,[[]])
 457 else
 458   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 459 fi
 460
 461 dnl --enable-debug-symbols : should even optimized compiler libraries
 462 dnl have debug symbols?
 463 AC_ARG_ENABLE(debug-symbols,
 464    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 465 if test ${enableval} = "no" ; then
 466   AC_SUBST(DEBUG_SYMBOLS,[[]])
 467 else
 468   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 469 fi
 470
 471 dnl --enable-jit: check whether they want to enable the jit
 472 AC_ARG_ENABLE(jit,
 473   AS_HELP_STRING(--enable-jit,
 474                  [Enable Just In Time Compiling (default is YES)]),,
 475   enableval=default)
 476 if test ${enableval} = "no"
 477 then
 478   AC_SUBST(JIT,[[]])
 479 else
 480   case "$llvm_cv_target_arch" in
 481     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 482     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 483     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 484     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 485     Alpha)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 486     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 487     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 488     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 489     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 490     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 491     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 492     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 493     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 494     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 495   esac
 496 fi
 497
 498 dnl Allow enablement of building and installing docs
 499 AC_ARG_ENABLE(docs,
 500               AS_HELP_STRING([--enable-docs],
 501                              [Build documents (default is YES)]),,
 502                              enableval=default)
 503 case "$enableval" in
 504   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 505   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 506   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 507   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 508 esac
 509
 510 dnl Allow enablement of doxygen generated documentation
 511 AC_ARG_ENABLE(doxygen,
 512               AS_HELP_STRING([--enable-doxygen],
 513                              [Build doxygen documentation (default is NO)]),,
 514                              enableval=default)
 515 case "$enableval" in
 516   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 517   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 518   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 519   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 520 esac
 521
 522 dnl Allow disablement of threads
 523 AC_ARG_ENABLE(threads,
 524               AS_HELP_STRING([--enable-threads],
 525                              [Use threads if available (default is YES)]),,
 526                              enableval=default)
 527 case "$enableval" in
 528   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 529   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 530   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 531   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 532 esac
 533 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 534
 535 dnl Allow disablement of pthread.h
 536 AC_ARG_ENABLE(pthreads,
 537               AS_HELP_STRING([--enable-pthreads],
 538                              [Use pthreads if available (default is YES)]),,
 539                              enableval=default)
 540 case "$enableval" in
 541   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 542   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 543   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 544   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 545 esac
 546
 547 dnl Allow building without position independent code
 548 AC_ARG_ENABLE(pic,
 549   AS_HELP_STRING([--enable-pic],
 550                  [Build LLVM with Position Independent Code (default is YES)]),,
 551                  enableval=default)
 552 case "$enableval" in
 553   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 554   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 555   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 556   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 557 esac
 558 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 559                    [Define if position independent code is enabled])
 560
 561 dnl Allow building a shared library and linking tools against it.
 562 AC_ARG_ENABLE(shared,
 563   AS_HELP_STRING([--enable-shared],
 564                  [Build a shared library and link tools against it (default is NO)]),,
 565                  enableval=default)
 566 case "$enableval" in
 567   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 568   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 569   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 570   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 571 esac
 572
 573 dnl Allow libstdc++ is embedded in LLVM.dll.
 574 AC_ARG_ENABLE(embed-stdcxx,
 575   AS_HELP_STRING([--enable-embed-stdcxx],
 576                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is YES)]),,
 577                  enableval=default)
 578 case "$enableval" in
 579   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 580   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 581   default) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 582   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 583 esac
 584
 585 dnl Enable embedding timestamp information into build.
 586 AC_ARG_ENABLE(timestamps,
 587   AS_HELP_STRING([--enable-timestamps],
 588                  [Enable embedding timestamp information in build (default is YES)]),,
 589                  enableval=default)
 590 case "$enableval" in
 591   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 592   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 593   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 594   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 595 esac
 596 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 597                    [Define if timestamp information (e.g., __DATE___) is allowed])
 598
 599 dnl Allow specific targets to be specified for building (or not)
 600 TARGETS_TO_BUILD=""
 601 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 602     [Build specific host targets: all or target1,target2,... Valid targets are:
 603      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu,
 604      xcore, msp430, systemz, blackfin, ptx, cbe, and cpp (default=all)]),,
 605     enableval=all)
 606 if test "$enableval" = host-only ; then
 607   enableval=host
 608 fi
 609 case "$enableval" in
 610   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU XCore MSP430 SystemZ Blackfin CBackend CppBackend MBlaze PTX" ;;
 611   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 612       case "$a_target" in
 613         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 614         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 615         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 616         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 617         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 618         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 619         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 620         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 621         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 622         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 623         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 624         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 625         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 626         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 627         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 628         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 629         host) case "$llvm_cv_target_arch" in
 630             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 631             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 632             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 633             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 634             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 635             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 636             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 637             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 638             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 639             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 640             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 641             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 642             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 643             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 644             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 645           esac ;;
 646         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 647       esac
 648   done
 649   ;;
 650 esac
 651 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 652
 653 # Determine whether we are building LLVM support for the native architecture.
 654 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 655 for a_target in $TARGETS_TO_BUILD; do
 656   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 657     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 658       [LLVM architecture name for the native architecture, if available])
 659     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 660     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 661     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 662     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 663     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 664       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 665     fi
 666     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 667       [LLVM name for the native Target init function, if available])
 668     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 669       [LLVM name for the native TargetInfo init function, if available])
 670     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 671       [LLVM name for the native target MC init function, if available])
 672     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 673       [LLVM name for the native AsmPrinter init function, if available])
 674     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 675       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 676        [LLVM name for the native AsmParser init function, if available])
 677     fi
 678   fi
 679 done
 680
 681 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 682 # target feature def files.
 683 LLVM_ENUM_TARGETS=""
 684 LLVM_ENUM_ASM_PRINTERS=""
 685 LLVM_ENUM_ASM_PARSERS=""
 686 LLVM_ENUM_DISASSEMBLERS=""
 687 for target_to_build in $TARGETS_TO_BUILD; do
 688   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 689   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 690     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 691   fi
 692   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 693     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 694   fi
 695   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 696     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 697   fi
 698 done
 699 AC_SUBST(LLVM_ENUM_TARGETS)
 700 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 701 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 702 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 703
 704 dnl Prevent the CBackend from using printf("%a") for floating point so older
 705 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 706 dnl can still compile the CBE's output
 707 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 708   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 709   enableval=default)
 710 case "$enableval" in
 711   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 712   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 713   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 714   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 715 esac
 716 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 717                    [Define if CBE is enabled for printf %a output])
 718
 719 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 720 AC_ARG_WITH(llvmgccdir,
 721   AS_HELP_STRING([--with-llvmgccdir],
 722     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 723     withval=default)
 724 case "$withval" in
 725   default) WITH_LLVMGCCDIR=default ;;
 726   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 727   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 728 esac
 729
 730 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 731 AC_ARG_WITH(llvmgcc,
 732   AS_HELP_STRING([--with-llvmgcc],
 733     [Specify location of llvm-gcc driver (default searches PATH)]),
 734     LLVMGCC=$with_llvmgcc
 735       WITH_LLVMGCCDIR="",)
 736
 737 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 738 AC_ARG_WITH(llvmgxx,
 739   AS_HELP_STRING([--with-llvmgxx],
 740     [Specify location of llvm-g++ driver (default searches PATH)]),
 741     LLVMGXX=$with_llvmgxx
 742     WITH_LLVMGCCDIR="",)
 743
 744 if test -n "$LLVMGCC"; then
 745    LLVMGCCCOMMAND="$LLVMGCC"
 746 fi
 747
 748 if test -n "$LLVMGXX"; then
 749    LLVMGXXCOMMAND="$LLVMGXX"
 750 fi
 751
 752 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 753    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 754 fi
 755
 756 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 757    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 758 fi
 759
 760 dnl Allow a specific Clang compiler to be used with this LLVM config.
 761 AC_ARG_WITH(clang,
 762   AS_HELP_STRING([--with-clang],
 763     [Specify location of clang compiler (default is --with-built-clang)]),
 764     [],[with_clang=default])
 765
 766 dnl Enable use of the built Clang.
 767 AC_ARG_WITH(built-clang,
 768   AS_HELP_STRING([--with-built-clang],
 769     [Use the compiled Clang as the LLVM compiler (default=check)]),
 770     [],[with_built_clang=check])
 771
 772 dnl Select the Clang compiler option.
 773 dnl
 774 dnl If --with-clang is given, always honor that; otherwise honor
 775 dnl --with-built-clang, or check if we have the clang sources.
 776 AC_MSG_CHECKING([clang compiler])
 777 WITH_CLANGPATH=""
 778 WITH_BUILT_CLANG=0
 779 if test "$with_clang" != "default"; then
 780    WITH_CLANGPATH="$with_clang"
 781    if ! test -x "$WITH_CLANGPATH"; then
 782      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 783    fi
 784 elif test "$with_built_clang" = "yes"; then
 785    WITH_BUILT_CLANG=1
 786 elif test "$with_built_clang" = "no"; then
 787    WITH_BUILT_CLANG=0
 788 else
 789    if test "$with_built_clang" != "check"; then
 790       AC_MSG_ERROR([invalid value for --with-built-clang.])
 791    fi
 792
 793    if test -f ${srcdir}/tools/clang/README.txt; then
 794      WITH_BUILT_CLANG=1
 795    fi
 796 fi
 797
 798 if ! test -z "$WITH_CLANGPATH"; then
 799    AC_MSG_RESULT([$WITH_CLANGPATH])
 800    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 801 elif test "$WITH_BUILT_CLANG" = "1"; then
 802    AC_MSG_RESULT([built])
 803 else
 804    AC_MSG_RESULT([none])
 805 fi
 806 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 807 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 808 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 809
 810 dnl Override the option to use for optimized builds.
 811 AC_ARG_WITH(optimize-option,
 812   AS_HELP_STRING([--with-optimize-option],
 813                  [Select the compiler options to use for optimized builds]),,
 814                  withval=default)
 815 AC_MSG_CHECKING([optimization flags])
 816 case "$withval" in
 817   default)
 818     case "$llvm_cv_os_type" in
 819     FreeBSD) optimize_option=-O2 ;;
 820     MingW) optimize_option=-O2 ;;
 821     *)     optimize_option=-O3 ;;
 822     esac ;;
 823   *) optimize_option="$withval" ;;
 824 esac
 825 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 826 AC_MSG_RESULT([$optimize_option])
 827
 828 dnl Specify extra build options
 829 AC_ARG_WITH(extra-options,
 830   AS_HELP_STRING([--with-extra-options],
 831                  [Specify additional options to compile LLVM with]),,
 832                  withval=default)
 833 case "$withval" in
 834   default) EXTRA_OPTIONS= ;;
 835   *) EXTRA_OPTIONS=$withval ;;
 836 esac
 837 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 838
 839 dnl Specify extra linker build options
 840 AC_ARG_WITH(extra-ld-options,
 841   AS_HELP_STRING([--with-extra-ld-options],
 842                  [Specify additional options to link LLVM with]),,
 843                  withval=default)
 844 case "$withval" in
 845   default) EXTRA_LD_OPTIONS= ;;
 846   *) EXTRA_LD_OPTIONS=$withval ;;
 847 esac
 848 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 849
 850 dnl Allow specific bindings to be specified for building (or not)
 851 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 852     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 853     enableval=default)
 854 BINDINGS_TO_BUILD=""
 855 case "$enableval" in
 856   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 857   all ) BINDINGS_TO_BUILD="ocaml" ;;
 858   none | no) BINDINGS_TO_BUILD="" ;;
 859   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 860       case "$a_binding" in
 861         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 862         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 863       esac
 864   done
 865   ;;
 866 esac
 867
 868 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 869 dnl script for bindings/ocaml/configure, except that its auto value depends on
 870 dnl OCAMLC, which is found here to support tests.
 871 AC_ARG_WITH([ocaml-libdir],
 872   [AS_HELP_STRING([--with-ocaml-libdir],
 873     [Specify install location for ocaml bindings (default is stdlib)])],
 874   [],
 875   [withval=auto])
 876 case "$withval" in
 877   auto) with_ocaml_libdir="$withval" ;;
 878   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 879   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 880 esac
 881
 882 AC_ARG_WITH(clang-resource-dir,
 883   AS_HELP_STRING([--with-clang-resource-dir],
 884     [Relative directory from the Clang binary for resource files]),,
 885     withval="")
 886 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 887                    [Relative directory for resource files])
 888
 889 AC_ARG_WITH(c-include-dirs,
 890   AS_HELP_STRING([--with-c-include-dirs],
 891     [Colon separated list of directories clang will search for headers]),,
 892     withval="")
 893 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 894                    [Directories clang will search for headers])
 895
 896 AC_ARG_WITH(cxx-include-root,
 897   AS_HELP_STRING([--with-cxx-include-root],
 898     [Directory with the libstdc++ headers.]),,
 899     withval="")
 900 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 901                    [Directory with the libstdc++ headers.])
 902
 903 AC_ARG_WITH(cxx-include-arch,
 904   AS_HELP_STRING([--with-cxx-include-arch],
 905     [Architecture of the libstdc++ headers.]),,
 906     withval="")
 907 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 908                    [Arch the libstdc++ headers.])
 909
 910 AC_ARG_WITH(cxx-include-32bit-dir,
 911   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 912     [32 bit multilib dir.]),,
 913     withval="")
 914 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 915                    [32 bit multilib directory.])
 916
 917 AC_ARG_WITH(cxx-include-64bit-dir,
 918   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 919     [64 bit multilib directory.]),,
 920     withval="")
 921 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 922                    [64 bit multilib directory.])
 923
 924 dnl Allow linking of LLVM with GPLv3 binutils code.
 925 AC_ARG_WITH(binutils-include,
 926   AS_HELP_STRING([--with-binutils-include],
 927     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 928   withval=default)
 929 case "$withval" in
 930   default) WITH_BINUTILS_INCDIR=default ;;
 931   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 932   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 933 esac
 934 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 935   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 936   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 937      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 938      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 939   fi
 940 fi
 941
 942 dnl Specify the URL where bug reports should be submitted.
 943 AC_ARG_WITH(bug-report-url,
 944   AS_HELP_STRING([--with-bug-report-url],
 945     [Specify the URL where bug reports should be submitted (default=http://llvm.org)]),,
 946     withval="http://llvm.org")
 947 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 948                    [Bug report URL.])
 949
 950 dnl --enable-libffi : check whether the user wants to turn off libffi:
 951 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 952   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 953   [case "$enableval" in
 954     yes) llvm_cv_enable_libffi="yes" ;;
 955     no)  llvm_cv_enable_libffi="no"  ;;
 956     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 957   esac],
 958   llvm_cv_enable_libffi=no)
 959
 960 dnl===-----------------------------------------------------------------------===
 961 dnl===
 962 dnl=== SECTION 4: Check for programs we need and that they are the right version
 963 dnl===
 964 dnl===-----------------------------------------------------------------------===
 965
 966 dnl Check for compilation tools
 967 AC_PROG_CPP
 968 AC_PROG_CC(gcc)
 969 AC_PROG_CXX(g++)
 970
 971 AC_PROG_NM
 972 AC_SUBST(NM)
 973
 974 dnl Check for the tools that the makefiles require
 975 AC_CHECK_GNU_MAKE
 976 AC_PROG_LN_S
 977 AC_PATH_PROG(CMP, [cmp], [cmp])
 978 AC_PATH_PROG(CP, [cp], [cp])
 979 AC_PATH_PROG(DATE, [date], [date])
 980 AC_PATH_PROG(FIND, [find], [find])
 981 AC_PATH_PROG(GREP, [grep], [grep])
 982 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 983 AC_PATH_PROG(MV,   [mv],   [mv])
 984 AC_PROG_RANLIB
 985 AC_CHECK_TOOL(AR, ar, false)
 986 AC_PATH_PROG(RM,   [rm],   [rm])
 987 AC_PATH_PROG(SED,  [sed],  [sed])
 988 AC_PATH_PROG(TAR,  [tar],  [gtar])
 989 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 990
 991 dnl Looking for misc. graph plotting software
 992 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 993 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 994   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 995   dnl If we're targeting for mingw we should emit windows paths, not msys
 996   if test "$llvm_cv_os_type" = "MingW" ; then
 997     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 998   fi
 999   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1000    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1001 fi
1002 AC_PATH_PROG(DOT, [dot], [echo dot])
1003 if test "$DOT" != "echo dot" ; then
1004   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1005   dnl If we're targeting for mingw we should emit windows paths, not msys
1006   if test "$llvm_cv_os_type" = "MingW" ; then
1007     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1008   fi
1009   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1010    [Define to path to dot program if found or 'echo dot' otherwise])
1011 fi
1012 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1013 if test "$FDP" != "echo fdp" ; then
1014   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1015   dnl If we're targeting for mingw we should emit windows paths, not msys
1016   if test "$llvm_cv_os_type" = "MingW" ; then
1017     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1018   fi
1019   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1020    [Define to path to fdp program if found or 'echo fdp' otherwise])
1021 fi
1022 AC_PATH_PROG(NEATO, [neato], [echo neato])
1023 if test "$NEATO" != "echo neato" ; then
1024   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1025   dnl If we're targeting for mingw we should emit windows paths, not msys
1026   if test "$llvm_cv_os_type" = "MingW" ; then
1027     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1028   fi
1029   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1030    [Define to path to neato program if found or 'echo neato' otherwise])
1031 fi
1032 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1033 if test "$TWOPI" != "echo twopi" ; then
1034   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1035   dnl If we're targeting for mingw we should emit windows paths, not msys
1036   if test "$llvm_cv_os_type" = "MingW" ; then
1037     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1038   fi
1039   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1040    [Define to path to twopi program if found or 'echo twopi' otherwise])
1041 fi
1042 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1043 if test "$CIRCO" != "echo circo" ; then
1044   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1045   dnl If we're targeting for mingw we should emit windows paths, not msys
1046   if test "$llvm_cv_os_type" = "MingW" ; then
1047     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1048   fi
1049   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1050    [Define to path to circo program if found or 'echo circo' otherwise])
1051 fi
1052 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1053 if test "$GV" != "echo gv" ; then
1054   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1055   dnl If we're targeting for mingw we should emit windows paths, not msys
1056   if test "$llvm_cv_os_type" = "MingW" ; then
1057     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1058   fi
1059   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1060    [Define to path to gv program if found or 'echo gv' otherwise])
1061 fi
1062 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1063 if test "$DOTTY" != "echo dotty" ; then
1064   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1065   dnl If we're targeting for mingw we should emit windows paths, not msys
1066   if test "$llvm_cv_os_type" = "MingW" ; then
1067     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1068   fi
1069   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1070    [Define to path to dotty program if found or 'echo dotty' otherwise])
1071 fi
1072 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1073 if test "$XDOT_PY" != "echo xdot.py" ; then
1074   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1075   dnl If we're targeting for mingw we should emit windows paths, not msys
1076   if test "$llvm_cv_os_type" = "MingW" ; then
1077     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1078   fi
1079   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1080    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1081 fi
1082
1083 dnl Look for a sufficiently recent version of Perl.
1084 LLVM_PROG_PERL([5.006])
1085 AC_SUBST(PERL)
1086 if test x"$PERL" = xnone; then
1087    AC_SUBST(HAVE_PERL,0)
1088    AC_MSG_ERROR([perl is required but was not found, please install it])
1089 else
1090    AC_SUBST(HAVE_PERL,1)
1091 fi
1092
1093 dnl Find the install program
1094 AC_PROG_INSTALL
1095 dnl Prepend src dir to install path dir if it's a relative path
1096 dnl This is a hack for installs that take place in something other
1097 dnl than the top level.
1098 case "$INSTALL" in
1099  [[\\/$]]* | ?:[[\\/]]* ) ;;
1100  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1101 esac
1102
1103 dnl Checks for documentation and testing tools that we can do without. If these
1104 dnl are not found then they are set to "true" which always succeeds but does
1105 dnl nothing. This just lets the build output show that we could have done
1106 dnl something if the tool was available.
1107 AC_PATH_PROG(BZIP2, [bzip2])
1108 AC_PATH_PROG(CAT, [cat])
1109 AC_PATH_PROG(DOXYGEN, [doxygen])
1110 AC_PATH_PROG(GROFF, [groff])
1111 AC_PATH_PROG(GZIPBIN, [gzip])
1112 AC_PATH_PROG(POD2HTML, [pod2html])
1113 AC_PATH_PROG(POD2MAN, [pod2man])
1114 AC_PATH_PROG(PDFROFF, [pdfroff])
1115 AC_PATH_PROG(RUNTEST, [runtest])
1116 DJ_AC_PATH_TCLSH
1117 AC_PATH_PROG(ZIP, [zip])
1118 AC_PATH_PROGS(OCAMLC, [ocamlc])
1119 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1120 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1121 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1122 AC_PATH_PROGS(GAS, [gas as])
1123
1124 dnl Get the version of the linker in use.
1125 AC_LINK_GET_VERSION
1126
1127 dnl Determine whether the linker supports the -R option.
1128 AC_LINK_USE_R
1129
1130 dnl Determine whether the linker supports the -export-dynamic option.
1131 AC_LINK_EXPORT_DYNAMIC
1132
1133 dnl Determine whether the linker supports the --version-script option.
1134 AC_LINK_VERSION_SCRIPT
1135
1136 dnl Check for libtool and the library that has dlopen function (which must come
1137 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1138 dnl libtool).
1139 AC_LIBTOOL_DLOPEN
1140 AC_LIB_LTDL
1141
1142 if test "$WITH_LLVMGCCDIR" = "default" ; then
1143   LLVMGCC="llvm-gcc${EXEEXT}"
1144   LLVMGXX="llvm-g++${EXEEXT}"
1145   LLVMGCCCOMMAND="$LLVMGCC"
1146   LLVMGXXCOMMAND="$LLVMGXX"
1147   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1148   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1149   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
1150   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
1151 else
1152   if test -z "$LLVMGCC"; then
1153     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
1154     LLVMGCCCOMMAND="$LLVMGCC"
1155   fi
1156   if test -z "$LLVMGXX"; then
1157     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1158     LLVMGXXCOMMAND="$LLVMGXX"
1159   fi
1160
1161   AC_SUBST(LLVMGCC,$LLVMGCC)
1162   AC_SUBST(LLVMGXX,$LLVMGXX)
1163   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1164   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1165 fi
1166
1167 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1168 dnl found, otherwise clang if available.
1169 AC_ARG_WITH(llvmcc,
1170   AS_HELP_STRING([--with-llvmcc=<name>],
1171     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1172     [],[with_llvmcc=check])
1173 AC_MSG_CHECKING([LLVM capable compiler])
1174 if test "$with_llvmcc" != "check"; then
1175    if (test "$with_llvmcc" != "llvm-gcc" &&
1176        test "$with_llvmcc" != "clang" &&
1177        test "$with_llvmcc" != "none"); then
1178       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1179    fi
1180    WITH_LLVMCC="$with_llvmcc"
1181 elif test -n "$LLVMGCC"; then
1182    WITH_LLVMCC=llvm-gcc
1183 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1184    WITH_LLVMCC=clang
1185 else
1186    WITH_LLVMCC=none
1187 fi
1188 AC_MSG_RESULT([$WITH_LLVMCC])
1189 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1190
1191 AC_MSG_CHECKING([tool compatibility])
1192
1193 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1194 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1195 dnl to support those options.
1196 dnl "icc" emits gcc signatures
1197 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1198 ICC=no
1199 IXX=no
1200 case $CC in
1201   icc*|icpc*)
1202     ICC=yes
1203     IXX=yes
1204     ;;
1205    *)
1206     ;;
1207 esac
1208
1209 if test "$GCC" != "yes" && test "$ICC" != "yes"
1210 then
1211   AC_MSG_ERROR([gcc|icc required but not found])
1212 fi
1213
1214 dnl Ensure that compilation tools are compatible with GCC extensions
1215 if test "$GXX" != "yes" && test "$IXX" != "yes"
1216 then
1217   AC_MSG_ERROR([g++|clang++|icc required but not found])
1218 fi
1219
1220 dnl Verify that GCC is version 3.0 or higher
1221 if test "$GCC" = "yes"
1222 then
1223   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1224 #error Unsupported GCC version
1225 #endif
1226 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1227 fi
1228
1229 dnl Check for GNU Make.  We use its extensions, so don't build without it
1230 if test -z "$llvm_cv_gnu_make_command"
1231 then
1232   AC_MSG_ERROR([GNU Make required but not found])
1233 fi
1234
1235 dnl Tool compatibility is okay if we make it here.
1236 AC_MSG_RESULT([ok])
1237
1238 dnl Check optional compiler flags.
1239 AC_MSG_CHECKING([optional compiler flags])
1240 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1241 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1242 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1243
1244 dnl===-----------------------------------------------------------------------===
1245 dnl===
1246 dnl=== SECTION 5: Check for libraries
1247 dnl===
1248 dnl===-----------------------------------------------------------------------===
1249
1250 AC_CHECK_LIB(m,sin)
1251 if test "$llvm_cv_os_type" = "MingW" ; then
1252   AC_CHECK_LIB(imagehlp, main)
1253   AC_CHECK_LIB(psapi, main)
1254 fi
1255
1256 dnl dlopen() is required for plugin support.
1257 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1258                [Define if dlopen() is available on this platform.]),
1259                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1260
1261 dnl libffi is optional; used to call external functions from the interpreter
1262 if test "$llvm_cv_enable_libffi" = "yes" ; then
1263   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1264                  [Define if libffi is available on this platform.]),
1265                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1266 fi
1267
1268 dnl mallinfo is optional; the code can compile (minus features) without it
1269 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1270                [Define if mallinfo() is available on this platform.]))
1271
1272 dnl pthread locking functions are optional - but llvm will not be thread-safe
1273 dnl without locks.
1274 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1275   AC_CHECK_LIB(pthread, pthread_mutex_init)
1276   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1277                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1278                            [Have pthread_mutex_lock]))
1279   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1280                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1281                  [Have pthread_rwlock_init]))
1282   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1283                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1284                  [Have pthread_getspecific]))
1285 fi
1286
1287 dnl Allow extra x86-disassembler library
1288 AC_ARG_WITH(udis86,
1289   AS_HELP_STRING([--with-udis86=<path>],
1290     [Use udis86 external x86 disassembler library]),
1291     [
1292       AC_SUBST(USE_UDIS86, [1])
1293       case "$withval" in
1294         /usr/lib|yes) ;;
1295         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1296       esac
1297       AC_CHECK_LIB(udis86, ud_init, [], [
1298         echo "Error! You need to have libudis86 around."
1299         exit -1
1300       ])
1301     ],
1302     AC_SUBST(USE_UDIS86, [0]))
1303 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1304                    [Define if use udis86 library])
1305
1306 dnl Allow OProfile support for JIT output.
1307 AC_ARG_WITH(oprofile,
1308   AS_HELP_STRING([--with-oprofile=<prefix>],
1309     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1310     [
1311       AC_SUBST(USE_OPROFILE, [1])
1312       case "$withval" in
1313         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1314         no) llvm_cv_oppath=
1315             AC_SUBST(USE_OPROFILE, [0]) ;;
1316         *) llvm_cv_oppath="${withval}/lib/oprofile"
1317            CPPFLAGS="-I${withval}/include";;
1318       esac
1319       if test -n "$llvm_cv_oppath" ; then
1320         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1321         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1322         dnl libbfd is not included properly in libopagent in some Debian
1323         dnl versions.  If libbfd isn't found at all, we assume opagent works
1324         dnl anyway.
1325         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1326         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1327           echo "Error! You need to have libopagent around."
1328           exit -1
1329         ])
1330         AC_CHECK_HEADER([opagent.h], [], [
1331           echo "Error! You need to have opagent.h around."
1332           exit -1
1333           ])
1334       fi
1335     ],
1336     [
1337       AC_SUBST(USE_OPROFILE, [0])
1338     ])
1339 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1340                    [Define if we have the oprofile JIT-support library])
1341
1342 dnl===-----------------------------------------------------------------------===
1343 dnl===
1344 dnl=== SECTION 6: Check for header files
1345 dnl===
1346 dnl===-----------------------------------------------------------------------===
1347
1348 dnl First, use autoconf provided macros for specific headers that we need
1349 dnl We don't check for ancient stuff or things that are guaranteed to be there
1350 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1351 dnl Generally we're looking for POSIX headers.
1352 AC_HEADER_DIRENT
1353 AC_HEADER_MMAP_ANONYMOUS
1354 AC_HEADER_STAT
1355 AC_HEADER_STDC
1356 AC_HEADER_SYS_WAIT
1357 AC_HEADER_TIME
1358
1359 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1360 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1361 AC_CHECK_HEADERS([utime.h windows.h])
1362 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1363 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1364 AC_CHECK_HEADERS([valgrind/valgrind.h])
1365 AC_CHECK_HEADERS([fenv.h])
1366 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1367   AC_CHECK_HEADERS(pthread.h,
1368                    AC_SUBST(HAVE_PTHREAD, 1),
1369                    AC_SUBST(HAVE_PTHREAD, 0))
1370 else
1371   AC_SUBST(HAVE_PTHREAD, 0)
1372 fi
1373
1374 dnl Try to find ffi.h.
1375 if test "$llvm_cv_enable_libffi" = "yes" ; then
1376   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1377 fi
1378
1379 dnl Try to find Darwin specific crash reporting libraries.
1380 AC_CHECK_HEADERS([CrashReporterClient.h])
1381
1382 dnl Try to find Darwin specific crash reporting global.
1383 AC_MSG_CHECKING([__crashreporter_info__])
1384 AC_LINK_IFELSE(
1385   AC_LANG_SOURCE(
1386     [[extern const char *__crashreporter_info__;
1387       int main() {
1388         __crashreporter_info__ = "test";
1389         return 0;
1390       }
1391     ]]),
1392   AC_MSG_RESULT(yes)
1393   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1394   AC_MSG_RESULT(no)
1395   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1396             Define if __crashreporter_info__ exists.))
1397
1398 dnl===-----------------------------------------------------------------------===
1399 dnl===
1400 dnl=== SECTION 7: Check for types and structures
1401 dnl===
1402 dnl===-----------------------------------------------------------------------===
1403
1404 AC_HUGE_VAL_CHECK
1405 AC_TYPE_PID_T
1406 AC_TYPE_SIZE_T
1407 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1408 AC_STRUCT_TM
1409 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1410 AC_CHECK_TYPES([uint64_t],,
1411          AC_CHECK_TYPES([u_int64_t],,
1412          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1413
1414 dnl===-----------------------------------------------------------------------===
1415 dnl===
1416 dnl=== SECTION 8: Check for specific functions needed
1417 dnl===
1418 dnl===-----------------------------------------------------------------------===
1419
1420 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1421 AC_CHECK_FUNCS([powf fmodf strtof round ])
1422 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1423 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1424 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1425 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1426 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1427 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1428 AC_C_PRINTF_A
1429 AC_FUNC_RAND48
1430
1431 dnl Check the declaration "Secure API" on Windows environments.
1432 AC_CHECK_DECLS([strerror_s])
1433
1434 dnl Check symbols in libgcc.a for JIT on Mingw.
1435 if test "$llvm_cv_os_type" = "MingW" ; then
1436   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1437   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1438   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1439   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1440
1441   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1442   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1443   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1444   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1445   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1446   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1447   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1448   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1449   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1450   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1451
1452   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1453   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1454 fi
1455
1456 dnl Check Win32 API EnumerateLoadedModules.
1457 if test "$llvm_cv_os_type" = "MingW" ; then
1458   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1459   AC_COMPILE_IFELSE([[#include <windows.h>
1460 #include <imagehlp.h>
1461 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1462 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1463 [
1464   AC_MSG_RESULT([yes])
1465   llvm_cv_win32_elmcb_pcstr="PCSTR"
1466 ],
1467 [
1468   AC_MSG_RESULT([no])
1469   llvm_cv_win32_elmcb_pcstr="PSTR"
1470 ])
1471   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1472 fi
1473
1474 dnl Check for variations in the Standard C++ library and STL. These macros are
1475 dnl provided by LLVM in the autoconf/m4 directory.
1476 AC_FUNC_ISNAN
1477 AC_FUNC_ISINF
1478
1479 dnl Check for mmap support.We also need to know if /dev/zero is required to
1480 dnl be opened for allocating RWX memory.
1481 dnl Make sure we aren't attempting to configure for an unknown system
1482 if test "$llvm_cv_platform_type" = "Unix" ; then
1483   AC_FUNC_MMAP
1484   AC_FUNC_MMAP_FILE
1485   AC_NEED_DEV_ZERO_FOR_MMAP
1486
1487   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1488   then
1489     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1490   fi
1491   if test "$ac_cv_func_mmap_file" = "no"
1492   then
1493     AC_MSG_WARN([mmap() of files required but not found])
1494   fi
1495 fi
1496
1497 dnl atomic builtins are required for threading support.
1498 AC_MSG_CHECKING(for GCC atomic builtins)
1499 dnl Since we'll be using these atomic builtins in C++ files we should test
1500 dnl the C++ compiler.
1501 AC_LANG_PUSH([C++])
1502 AC_LINK_IFELSE(
1503   AC_LANG_SOURCE(
1504     [[int main() {
1505         volatile unsigned long val = 1;
1506         __sync_synchronize();
1507         __sync_val_compare_and_swap(&val, 1, 0);
1508         __sync_add_and_fetch(&val, 1);
1509         __sync_sub_and_fetch(&val, 1);
1510         return 0;
1511       }
1512     ]]),
1513   AC_LANG_POP([C++])
1514   AC_MSG_RESULT(yes)
1515   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1516   AC_MSG_RESULT(no)
1517   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1518   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1519
1520 dnl===-----------------------------------------------------------------------===
1521 dnl===
1522 dnl=== SECTION 9: Additional checks, variables, etc.
1523 dnl===
1524 dnl===-----------------------------------------------------------------------===
1525
1526 dnl Handle 32-bit linux systems running a 64-bit kernel.
1527 dnl This has to come after section 4 because it invokes the compiler.
1528 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1529   AC_IS_LINUX_MIXED
1530   if test "$llvm_cv_linux_mixed" = "yes"; then
1531     llvm_cv_target_arch="x86"
1532     ARCH="x86"
1533   fi
1534 fi
1535
1536 dnl Check, whether __dso_handle is present
1537 AC_CHECK_FUNCS([__dso_handle])
1538
1539 dnl Check wether llvm-gcc is based on dragonegg
1540 AC_CACHE_CHECK([whether llvm-gcc is dragonegg],[llvm_cv_llvmgcc_dragonegg],
1541 [llvm_cv_llvmgcc_dragonegg="no"
1542 if test -n "$LLVMGCC" ; then
1543   cp /dev/null conftest.c
1544   $LLVMGCC -fplugin-arg-dragonegg-emit-ir -S -o - conftest.c > /dev/null 2>&1
1545   if test $? -eq 0 ; then
1546     llvm_cv_llvmgcc_dragonegg="yes"
1547   fi
1548   rm conftest.c
1549 fi])
1550
1551 dnl Set the flags needed to emit LLVM IR and to disable optimizations
1552 dnl in llvmgcc
1553 if test "$llvm_cv_llvmgcc_dragonegg" = "yes" ; then
1554   LLVMCC_EMITIR_FLAG="-fplugin-arg-dragonegg-emit-ir"
1555   LLVMCC_DISABLEOPT_FLAGS="-fplugin-arg-dragonegg-llvm-ir-optimize=0"
1556 else
1557   LLVMCC_EMITIR_FLAG="-emit-llvm"
1558   LLVMCC_DISABLEOPT_FLAGS="-mllvm -disable-llvm-optzns"
1559 fi
1560
1561 AC_SUBST(LLVMCC_EMITIR_FLAG)
1562
1563 dnl See if the llvm-gcc executable can compile to LLVM assembly
1564 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1565 [llvm_cv_llvmgcc_sanity="no"
1566 if test -n "$LLVMGCC" ; then
1567   cp /dev/null conftest.c
1568   $LLVMGCC "$LLVMCC_EMITIR_FLAG" -S -o - conftest.c | \
1569       grep 'target datalayout =' > /dev/null 2>&1
1570   if test $? -eq 0 ; then
1571     llvm_cv_llvmgcc_sanity="yes"
1572   fi
1573   rm conftest.c
1574 fi])
1575
1576 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1577 dnl Furthermore, add some information about the tools
1578 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1579   AC_MSG_CHECKING([llvm-gcc component support])
1580   llvmcc1path=`$LLVMGCC --print-prog-name=cc1`
1581   AC_SUBST(LLVMCC1,$llvmcc1path)
1582   llvmcc1pluspath=`$LLVMGCC --print-prog-name=cc1plus`
1583   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1584   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1585   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1586   llvmgcclangs=[`$LLVMGCC -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1587   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1588   AC_SUBST(LLVMGCC_DRAGONEGG,$llvm_cv_llvmgcc_dragonegg)
1589   AC_SUBST(LLVMCC_DISABLEOPT_FLAGS)
1590   AC_MSG_RESULT([ok])
1591 fi
1592
1593 dnl Propagate the shared library extension that the libltdl checks did to
1594 dnl the Makefiles so we can use it there too
1595 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1596
1597 dnl Propagate the run-time library path variable that the libltdl
1598 dnl checks found to the Makefiles so we can use it there too
1599 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1600
1601 # Translate the various configuration directories and other basic
1602 # information into substitutions that will end up in Makefile.config.in
1603 # that these configured values can be used by the makefiles
1604 if test "${prefix}" = "NONE" ; then
1605   prefix="/usr/local"
1606 fi
1607 eval LLVM_PREFIX="${prefix}";
1608 eval LLVM_BINDIR="${prefix}/bin";
1609 eval LLVM_LIBDIR="${prefix}/lib";
1610 eval LLVM_DATADIR="${prefix}/share/llvm";
1611 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1612 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1613 eval LLVM_INCLUDEDIR="${prefix}/include";
1614 eval LLVM_INFODIR="${prefix}/info";
1615 eval LLVM_MANDIR="${prefix}/man";
1616 LLVM_CONFIGTIME=`date`
1617 AC_SUBST(LLVM_PREFIX)
1618 AC_SUBST(LLVM_BINDIR)
1619 AC_SUBST(LLVM_LIBDIR)
1620 AC_SUBST(LLVM_DATADIR)
1621 AC_SUBST(LLVM_DOCSDIR)
1622 AC_SUBST(LLVM_ETCDIR)
1623 AC_SUBST(LLVM_INCLUDEDIR)
1624 AC_SUBST(LLVM_INFODIR)
1625 AC_SUBST(LLVM_MANDIR)
1626 AC_SUBST(LLVM_CONFIGTIME)
1627
1628 # Place the various directores into the config.h file as #defines so that we
1629 # can know about the installation paths within LLVM.
1630 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1631                    [Installation prefix directory])
1632 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1633                    [Installation directory for binary executables])
1634 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1635                    [Installation directory for libraries])
1636 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1637                    [Installation directory for data files])
1638 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1639                    [Installation directory for documentation])
1640 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1641                    [Installation directory for config files])
1642 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1643                    [Installation directory for include files])
1644 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1645                    [Installation directory for .info files])
1646 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1647                    [Installation directory for man pages])
1648 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1649                    [Time at which LLVM was configured])
1650 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1651                    [Host triple we were built on])
1652
1653 # Determine which bindings to build.
1654 if test "$BINDINGS_TO_BUILD" = auto ; then
1655   BINDINGS_TO_BUILD=""
1656   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1657     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1658   fi
1659 fi
1660 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1661
1662 # This isn't really configurey, but it avoids having to repeat the list in
1663 # other files.
1664 AC_SUBST(ALL_BINDINGS,ocaml)
1665
1666 # Do any work necessary to ensure that bindings have what they need.
1667 binding_prereqs_failed=0
1668 for a_binding in $BINDINGS_TO_BUILD ; do
1669   case "$a_binding" in
1670   ocaml)
1671     if test "x$OCAMLC" = x ; then
1672       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1673       binding_prereqs_failed=1
1674     fi
1675     if test "x$OCAMLDEP" = x ; then
1676       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1677       binding_prereqs_failed=1
1678     fi
1679     if test "x$OCAMLOPT" = x ; then
1680       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1681       dnl ocamlopt is optional!
1682     fi
1683     if test "x$with_ocaml_libdir" != xauto ; then
1684       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1685     else
1686       ocaml_stdlib="`"$OCAMLC" -where`"
1687       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1688       then
1689         # ocaml stdlib is beneath our prefix; use stdlib
1690         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1691       else
1692         # ocaml stdlib is outside our prefix; use libdir/ocaml
1693         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1694       fi
1695     fi
1696     ;;
1697   esac
1698 done
1699 if test "$binding_prereqs_failed" = 1 ; then
1700   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1701 fi
1702
1703 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1704 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1705
1706 dnl Determine linker rpath flag
1707 if test "$llvm_cv_link_use_r" = "yes" ; then
1708   RPATH="-Wl,-R"
1709 else
1710   RPATH="-Wl,-rpath"
1711 fi
1712 AC_SUBST(RPATH)
1713
1714 dnl Determine linker rdynamic flag
1715 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1716   RDYNAMIC="-Wl,-export-dynamic"
1717 else
1718   RDYNAMIC=""
1719 fi
1720 AC_SUBST(RDYNAMIC)
1721
1722 dnl===-----------------------------------------------------------------------===
1723 dnl===
1724 dnl=== SECTION 10: Specify the output files and generate it
1725 dnl===
1726 dnl===-----------------------------------------------------------------------===
1727
1728 dnl Configure header files
1729 dnl WARNING: dnl If you add or remove any of the following config headers, then
1730 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1731 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1732 dnl files can be updated automatically when their *.in sources change.
1733 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1734 AH_TOP([#ifndef CONFIG_H
1735 #define CONFIG_H])
1736 AH_BOTTOM([#endif])
1737
1738 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1739 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1740 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1741 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1742 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1743
1744 dnl Configure the makefile's configuration data
1745 AC_CONFIG_FILES([Makefile.config])
1746
1747 dnl Configure the RPM spec file for LLVM
1748 AC_CONFIG_FILES([llvm.spec])
1749
1750 dnl Configure doxygen's configuration file
1751 AC_CONFIG_FILES([docs/doxygen.cfg])
1752 if test -f ${srcdir}/tools/clang/README.txt; then
1753   AC_CONFIG_FILES([tools/clang/docs/doxygen.cfg])
1754 fi
1755
1756 dnl Configure llvmc's Base plugin
1757 AC_CONFIG_FILES([tools/llvmc/src/Base.td])
1758
1759 dnl Do the first stage of configuration for llvm-config.in.
1760 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1761
1762 dnl Do special configuration of Makefiles
1763 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1764 AC_CONFIG_MAKEFILE(Makefile)
1765 AC_CONFIG_MAKEFILE(Makefile.common)
1766 AC_CONFIG_MAKEFILE(examples/Makefile)
1767 AC_CONFIG_MAKEFILE(lib/Makefile)
1768 AC_CONFIG_MAKEFILE(runtime/Makefile)
1769 AC_CONFIG_MAKEFILE(test/Makefile)
1770 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1771 AC_CONFIG_MAKEFILE(unittests/Makefile)
1772 AC_CONFIG_MAKEFILE(tools/Makefile)
1773 AC_CONFIG_MAKEFILE(utils/Makefile)
1774 AC_CONFIG_MAKEFILE(projects/Makefile)
1775 AC_CONFIG_MAKEFILE(bindings/Makefile)
1776 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1777
1778 dnl Finally, crank out the output
1779 AC_OUTPUT