autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.1svn],[http://llvm.org/bugs/])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2012 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2012 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.60 or later.
  42 AC_PREREQ(2.60)
  43
  44 dnl Verify that the source directory is valid. This makes sure that we are
  45 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  46 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  47
  48 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  49 dnl various tools where the m4 autoconf macros are.
  50 AC_CONFIG_AUX_DIR([autoconf])
  51
  52 dnl Quit if the source directory has already been configured.
  53 dnl NOTE: This relies upon undocumented autoconf behavior.
  54 if test ${srcdir} != "." ; then
  55   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  56     AC_MSG_ERROR([Already configured in ${srcdir}])
  57   fi
  58 fi
  59
  60 dnl We need to check for the compiler up here to avoid anything else
  61 dnl starting with a different one.
  62 AC_PROG_CC(clang llvm-gcc gcc)
  63 AC_PROG_CXX(clang++ llvm-g++ g++)
  64 AC_PROG_CPP
  65
  66 dnl Configure all of the projects present in our source tree. While we could
  67 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  68 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  69 dnl Instead we match on the known projects.
  70
  71 dnl
  72 dnl One tricky part of doing this is that some projects depend upon other
  73 dnl projects.  For example, several projects rely upon the LLVM test suite.
  74 dnl We want to configure those projects first so that their object trees are
  75 dnl created before running the configure scripts of projects that depend upon
  76 dnl them.
  77 dnl
  78
  79 dnl Several projects use llvm-gcc, so configure that first
  80 if test -d ${srcdir}/projects/llvm-gcc ; then
  81   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  82 fi
  83
  84 dnl Several projects use the LLVM test suite, so configure it next.
  85 if test -d ${srcdir}/projects/test-suite ; then
  86   AC_CONFIG_SUBDIRS([projects/test-suite])
  87 fi
  88
  89 dnl llvm-test is the old name of the test-suite, kept here for backwards
  90 dnl compatibility
  91 if test -d ${srcdir}/projects/llvm-test ; then
  92   AC_CONFIG_SUBDIRS([projects/llvm-test])
  93 fi
  94
  95 dnl Some projects use poolalloc; configure that next
  96 if test -d ${srcdir}/projects/poolalloc ; then
  97   AC_CONFIG_SUBDIRS([projects/poolalloc])
  98 fi
  99
 100 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 101   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 102 fi
 103
 104 dnl Check for all other projects
 105 for i in `ls ${srcdir}/projects`
 106 do
 107   if test -d ${srcdir}/projects/${i} ; then
 108     case ${i} in
 109       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 110       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 111       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 112       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 113       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 114       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 115       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 116       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 117       compiler-rt)       ;;
 118       llvm-gcc)       ;;
 119       test-suite)     ;;
 120       llvm-test)      ;;
 121       poolalloc)      ;;
 122       llvm-poolalloc) ;;
 123       *)
 124         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 125         ;;
 126     esac
 127   fi
 128 done
 129
 130 dnl Disable the build of polly, even if it is checked out into tools/polly.
 131 AC_ARG_ENABLE(polly,
 132               AS_HELP_STRING([--enable-polly],
 133                              [Use polly if available (default is YES)]),,
 134                              enableval=default)
 135 case "$enableval" in
 136   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 137   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 138   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 139   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 140 esac
 141
 142
 143 dnl Check if polly is checked out into tools/polly and configure it if
 144 dnl available.
 145 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 146   AC_SUBST(LLVM_HAS_POLLY,1)
 147   AC_CONFIG_SUBDIRS([tools/polly])
 148 fi
 149
 150 dnl===-----------------------------------------------------------------------===
 151 dnl===
 152 dnl=== SECTION 2: Architecture, target, and host checks
 153 dnl===
 154 dnl===-----------------------------------------------------------------------===
 155
 156 dnl Check the target for which we're compiling and the host that will do the
 157 dnl compilations. This will tell us which LLVM compiler will be used for
 158 dnl compiling SSA into object code. This needs to be done early because
 159 dnl following tests depend on it.
 160 AC_CANONICAL_TARGET
 161
 162 dnl Determine the platform type and cache its value. This helps us configure
 163 dnl the System library to the correct build platform.
 164 AC_CACHE_CHECK([type of operating system we're going to host on],
 165                [llvm_cv_os_type],
 166 [case $host in
 167   *-*-aix*)
 168     llvm_cv_link_all_option="-Wl,--whole-archive"
 169     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 170     llvm_cv_os_type="AIX"
 171     llvm_cv_platform_type="Unix" ;;
 172   *-*-irix*)
 173     llvm_cv_link_all_option="-Wl,--whole-archive"
 174     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 175     llvm_cv_os_type="IRIX"
 176     llvm_cv_platform_type="Unix" ;;
 177   *-*-cygwin*)
 178     llvm_cv_link_all_option="-Wl,--whole-archive"
 179     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 180     llvm_cv_os_type="Cygwin"
 181     llvm_cv_platform_type="Unix" ;;
 182   *-*-darwin*)
 183     llvm_cv_link_all_option="-Wl,-all_load"
 184     llvm_cv_no_link_all_option="-Wl,-noall_load"
 185     llvm_cv_os_type="Darwin"
 186     llvm_cv_platform_type="Unix" ;;
 187   *-*-minix*)
 188     llvm_cv_link_all_option="-Wl,-all_load"
 189     llvm_cv_no_link_all_option="-Wl,-noall_load"
 190     llvm_cv_os_type="Minix"
 191     llvm_cv_platform_type="Unix" ;;
 192   *-*-freebsd* | *-*-kfreebsd-gnu)
 193     llvm_cv_link_all_option="-Wl,--whole-archive"
 194     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 195     llvm_cv_os_type="FreeBSD"
 196     llvm_cv_platform_type="Unix" ;;
 197   *-*-openbsd*)
 198     llvm_cv_link_all_option="-Wl,--whole-archive"
 199     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 200     llvm_cv_os_type="OpenBSD"
 201     llvm_cv_platform_type="Unix" ;;
 202   *-*-netbsd*)
 203     llvm_cv_link_all_option="-Wl,--whole-archive"
 204     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 205     llvm_cv_os_type="NetBSD"
 206     llvm_cv_platform_type="Unix" ;;
 207   *-*-dragonfly*)
 208     llvm_cv_link_all_option="-Wl,--whole-archive"
 209     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 210     llvm_cv_os_type="DragonFly"
 211     llvm_cv_platform_type="Unix" ;;
 212   *-*-hpux*)
 213     llvm_cv_link_all_option="-Wl,--whole-archive"
 214     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 215     llvm_cv_os_type="HP-UX"
 216     llvm_cv_platform_type="Unix" ;;
 217   *-*-interix*)
 218     llvm_cv_link_all_option="-Wl,--whole-archive"
 219     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 220     llvm_cv_os_type="Interix"
 221     llvm_cv_platform_type="Unix" ;;
 222   *-*-linux*)
 223     llvm_cv_link_all_option="-Wl,--whole-archive"
 224     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 225     llvm_cv_os_type="Linux"
 226     llvm_cv_platform_type="Unix" ;;
 227   *-*-gnu*)
 228     llvm_cv_link_all_option="-Wl,--whole-archive"
 229     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 230     llvm_cv_os_type="GNU"
 231     llvm_cv_platform_type="Unix" ;;
 232   *-*-solaris*)
 233     llvm_cv_link_all_option="-Wl,-z,allextract"
 234     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 235     llvm_cv_os_type="SunOS"
 236     llvm_cv_platform_type="Unix" ;;
 237   *-*-auroraux*)
 238     llvm_cv_link_all_option="-Wl,-z,allextract"
 239     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 240     llvm_cv_os_type="AuroraUX"
 241     llvm_cv_platform_type="Unix" ;;
 242   *-*-win32*)
 243     llvm_cv_link_all_option="-Wl,--whole-archive"
 244     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 245     llvm_cv_os_type="Win32"
 246     llvm_cv_platform_type="Win32" ;;
 247   *-*-mingw*)
 248     llvm_cv_link_all_option="-Wl,--whole-archive"
 249     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 250     llvm_cv_os_type="MingW"
 251     llvm_cv_platform_type="Win32" ;;
 252   *-*-haiku*)
 253     llvm_cv_link_all_option="-Wl,--whole-archive"
 254     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 255     llvm_cv_os_type="Haiku"
 256     llvm_cv_platform_type="Unix" ;;
 257   *-unknown-eabi*)
 258     llvm_cv_link_all_option="-Wl,--whole-archive"
 259     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 260     llvm_cv_os_type="Freestanding"
 261     llvm_cv_platform_type="Unix" ;;
 262   *-unknown-elf*)
 263     llvm_cv_link_all_option="-Wl,--whole-archive"
 264     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 265     llvm_cv_os_type="Freestanding"
 266     llvm_cv_platform_type="Unix" ;;
 267   *)
 268     llvm_cv_link_all_option=""
 269     llvm_cv_no_link_all_option=""
 270     llvm_cv_os_type="Unknown"
 271     llvm_cv_platform_type="Unknown" ;;
 272 esac])
 273
 274 AC_CACHE_CHECK([type of operating system we're going to target],
 275                [llvm_cv_target_os_type],
 276 [case $target in
 277   *-*-aix*)
 278     llvm_cv_target_os_type="AIX" ;;
 279   *-*-irix*)
 280     llvm_cv_target_os_type="IRIX" ;;
 281   *-*-cygwin*)
 282     llvm_cv_target_os_type="Cygwin" ;;
 283   *-*-darwin*)
 284     llvm_cv_target_os_type="Darwin" ;;
 285   *-*-minix*)
 286     llvm_cv_target_os_type="Minix" ;;
 287   *-*-freebsd*)
 288     llvm_cv_target_os_type="FreeBSD" ;;
 289   *-*-openbsd*)
 290     llvm_cv_target_os_type="OpenBSD" ;;
 291   *-*-netbsd*)
 292     llvm_cv_target_os_type="NetBSD" ;;
 293   *-*-dragonfly*)
 294     llvm_cv_target_os_type="DragonFly" ;;
 295   *-*-hpux*)
 296     llvm_cv_target_os_type="HP-UX" ;;
 297   *-*-interix*)
 298     llvm_cv_target_os_type="Interix" ;;
 299   *-*-linux*)
 300     llvm_cv_target_os_type="Linux" ;;
 301   *-*-solaris*)
 302     llvm_cv_target_os_type="SunOS" ;;
 303   *-*-auroraux*)
 304     llvm_cv_target_os_type="AuroraUX" ;;
 305   *-*-win32*)
 306     llvm_cv_target_os_type="Win32" ;;
 307   *-*-mingw*)
 308     llvm_cv_target_os_type="MingW" ;;
 309   *-*-haiku*)
 310     llvm_cv_target_os_type="Haiku" ;;
 311   *-*-rtems*)
 312     llvm_cv_target_os_type="RTEMS" ;;
 313   *-*-nacl*)
 314     llvm_cv_target_os_type="NativeClient" ;;
 315   *-unknown-eabi*)
 316     llvm_cv_target_os_type="Freestanding" ;;
 317   *)
 318     llvm_cv_target_os_type="Unknown" ;;
 319 esac])
 320
 321 dnl Make sure we aren't attempting to configure for an unknown system
 322 if test "$llvm_cv_os_type" = "Unknown" ; then
 323   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 324 fi
 325
 326 dnl Set the "OS" Makefile variable based on the platform type so the
 327 dnl makefile can configure itself to specific build hosts
 328 AC_SUBST(OS,$llvm_cv_os_type)
 329 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 330 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 331
 332 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 333 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 334 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 335
 336 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 337 dnl This is used by lib/Support to determine the basic kind of implementation
 338 dnl to use.
 339 case $llvm_cv_platform_type in
 340   Unix)
 341     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 342     AC_SUBST(LLVM_ON_UNIX,[1])
 343     AC_SUBST(LLVM_ON_WIN32,[0])
 344     ;;
 345   Win32)
 346     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 347     AC_SUBST(LLVM_ON_UNIX,[0])
 348     AC_SUBST(LLVM_ON_WIN32,[1])
 349     ;;
 350 esac
 351
 352 dnl Determine what our target architecture is and configure accordingly.
 353 dnl This will allow Makefiles to make a distinction between the hardware and
 354 dnl the OS.
 355 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 356 [case $target in
 357   i?86-*)                 llvm_cv_target_arch="x86" ;;
 358   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 359   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 360   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 361   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 362   mips-*)                 llvm_cv_target_arch="Mips" ;;
 363   mipsel-*)               llvm_cv_target_arch="Mips" ;;
 364   xcore-*)                llvm_cv_target_arch="XCore" ;;
 365   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 366   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 367   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 368   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 369   *)                      llvm_cv_target_arch="Unknown" ;;
 370 esac])
 371
 372 if test "$llvm_cv_target_arch" = "Unknown" ; then
 373   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 374 fi
 375
 376 dnl Determine the LLVM native architecture for the target
 377 case "$llvm_cv_target_arch" in
 378     x86)     LLVM_NATIVE_ARCH="X86" ;;
 379     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 380     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 381 esac
 382
 383 dnl Define a substitution, ARCH, for the target architecture
 384 AC_SUBST(ARCH,$llvm_cv_target_arch)
 385
 386 dnl Check for the endianness of the target
 387 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 388
 389 dnl Check for build platform executable suffix if we're cross-compiling
 390 if test "$cross_compiling" = yes; then
 391   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 392   AC_BUILD_EXEEXT
 393   ac_build_prefix=${build_alias}-
 394   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 395   if test -z "$BUILD_CXX"; then
 396      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 397      if test -z "$BUILD_CXX"; then
 398        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 399      fi
 400   fi
 401 else
 402   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 403 fi
 404
 405 dnl Check to see if there's a .svn or .git directory indicating that this
 406 dnl build is being done from a checkout. This sets up several defaults for
 407 dnl the command line switches. When we build with a checkout directory,
 408 dnl we get a debug with assertions turned on. Without, we assume a source
 409 dnl release and we get an optimized build without assertions.
 410 dnl See --enable-optimized and --enable-assertions below
 411 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 412   cvsbuild="yes"
 413   optimize="no"
 414   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 415 else
 416   cvsbuild="no"
 417   optimize="yes"
 418 fi
 419
 420 dnl===-----------------------------------------------------------------------===
 421 dnl===
 422 dnl=== SECTION 3: Command line arguments for the configure script.
 423 dnl===
 424 dnl===-----------------------------------------------------------------------===
 425
 426 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 427 AC_ARG_ENABLE(libcpp,
 428               AS_HELP_STRING([--enable-libcpp],
 429                              [Use libc++ if available (default is NO)]),,
 430                              enableval=default)
 431 case "$enableval" in
 432   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 433   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 434   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 435   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 436 esac
 437
 438 dnl --enable-optimized : check whether they want to do an optimized build:
 439 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 440  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 441 if test ${enableval} = "no" ; then
 442   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 443 else
 444   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 445 fi
 446
 447 dnl --enable-profiling : check whether they want to do a profile build:
 448 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 449  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 450 if test ${enableval} = "no" ; then
 451   AC_SUBST(ENABLE_PROFILING,[[]])
 452 else
 453   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 454 fi
 455
 456 dnl --enable-assertions : check whether they want to turn on assertions or not:
 457 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 458   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 459 if test ${enableval} = "yes" ; then
 460   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 461 else
 462   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 463 fi
 464
 465 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 466 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 467   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 468 if test ${enableval} = "yes" ; then
 469   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 470   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 471 else
 472   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 473   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 474 fi
 475
 476 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 477 AC_ARG_ENABLE(debug-runtime,
 478    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 479 if test ${enableval} = "no" ; then
 480   AC_SUBST(DEBUG_RUNTIME,[[]])
 481 else
 482   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 483 fi
 484
 485 dnl --enable-debug-symbols : should even optimized compiler libraries
 486 dnl have debug symbols?
 487 AC_ARG_ENABLE(debug-symbols,
 488    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 489 if test ${enableval} = "no" ; then
 490   AC_SUBST(DEBUG_SYMBOLS,[[]])
 491 else
 492   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 493 fi
 494
 495 dnl --enable-jit: check whether they want to enable the jit
 496 AC_ARG_ENABLE(jit,
 497   AS_HELP_STRING(--enable-jit,
 498                  [Enable Just In Time Compiling (default is YES)]),,
 499   enableval=default)
 500 if test ${enableval} = "no"
 501 then
 502   AC_SUBST(JIT,[[]])
 503 else
 504   case "$llvm_cv_target_arch" in
 505     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 506     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 507     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 508     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 509     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 510     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 511     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 512     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 513     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 514     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 515     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 516     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 517   esac
 518 fi
 519
 520 dnl Allow enablement of building and installing docs
 521 AC_ARG_ENABLE(docs,
 522               AS_HELP_STRING([--enable-docs],
 523                              [Build documents (default is YES)]),,
 524                              enableval=default)
 525 case "$enableval" in
 526   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 527   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 528   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 529   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 530 esac
 531
 532 dnl Allow enablement of doxygen generated documentation
 533 AC_ARG_ENABLE(doxygen,
 534               AS_HELP_STRING([--enable-doxygen],
 535                              [Build doxygen documentation (default is NO)]),,
 536                              enableval=default)
 537 case "$enableval" in
 538   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 539   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 540   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 541   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 542 esac
 543
 544 dnl Allow disablement of threads
 545 AC_ARG_ENABLE(threads,
 546               AS_HELP_STRING([--enable-threads],
 547                              [Use threads if available (default is YES)]),,
 548                              enableval=default)
 549 case "$enableval" in
 550   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 551   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 552   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 553   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 554 esac
 555 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 556                    [Define if threads enabled])
 557
 558 dnl Allow disablement of pthread.h
 559 AC_ARG_ENABLE(pthreads,
 560               AS_HELP_STRING([--enable-pthreads],
 561                              [Use pthreads if available (default is YES)]),,
 562                              enableval=default)
 563 case "$enableval" in
 564   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 565   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 566   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 567   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 568 esac
 569
 570 dnl Allow building without position independent code
 571 AC_ARG_ENABLE(pic,
 572   AS_HELP_STRING([--enable-pic],
 573                  [Build LLVM with Position Independent Code (default is YES)]),,
 574                  enableval=default)
 575 case "$enableval" in
 576   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 577   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 578   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 579   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 580 esac
 581 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 582                    [Define if position independent code is enabled])
 583
 584 dnl Allow building a shared library and linking tools against it.
 585 AC_ARG_ENABLE(shared,
 586   AS_HELP_STRING([--enable-shared],
 587                  [Build a shared library and link tools against it (default is NO)]),,
 588                  enableval=default)
 589 case "$enableval" in
 590   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 591   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 592   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 593   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 594 esac
 595
 596 dnl Allow libstdc++ is embedded in LLVM.dll.
 597 AC_ARG_ENABLE(embed-stdcxx,
 598   AS_HELP_STRING([--enable-embed-stdcxx],
 599                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 600                  enableval=default)
 601 case "$enableval" in
 602   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 603   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 604   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 605   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 606 esac
 607
 608 dnl Enable embedding timestamp information into build.
 609 AC_ARG_ENABLE(timestamps,
 610   AS_HELP_STRING([--enable-timestamps],
 611                  [Enable embedding timestamp information in build (default is YES)]),,
 612                  enableval=default)
 613 case "$enableval" in
 614   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 615   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 616   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 617   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 618 esac
 619 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 620                    [Define if timestamp information (e.g., __DATE___) is allowed])
 621
 622 dnl Allow specific targets to be specified for building (or not)
 623 TARGETS_TO_BUILD=""
 624 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 625     [Build specific host targets: all or target1,target2,... Valid targets are:
 626      host, x86, x86_64, sparc, powerpc, arm, mips, spu, hexagon,
 627      xcore, msp430, ptx, cbe, and cpp (default=all)]),,
 628     enableval=all)
 629 if test "$enableval" = host-only ; then
 630   enableval=host
 631 fi
 632 case "$enableval" in
 633   all) TARGETS_TO_BUILD="X86 Sparc PowerPC ARM Mips CellSPU XCore MSP430 CBackend CppBackend MBlaze PTX Hexagon" ;;
 634   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 635       case "$a_target" in
 636         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 637         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 638         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 639         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 640         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 641         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 642         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 643         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 644         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 645         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 646         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 647         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 648         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 649         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 650         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 651         host) case "$llvm_cv_target_arch" in
 652             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 653             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 654             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 655             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 656             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 657             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 658             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 659             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 660             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 661             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 662             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 663             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 664             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 665           esac ;;
 666         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 667       esac
 668   done
 669   ;;
 670 esac
 671 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 672
 673 dnl Determine whether we are building LLVM support for the native architecture.
 674 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 675 for a_target in $TARGETS_TO_BUILD; do
 676   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 677     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 678       [LLVM architecture name for the native architecture, if available])
 679     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 680     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 681     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 682     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 683     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 684       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 685     fi
 686     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 687       [LLVM name for the native Target init function, if available])
 688     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 689       [LLVM name for the native TargetInfo init function, if available])
 690     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 691       [LLVM name for the native target MC init function, if available])
 692     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 693       [LLVM name for the native AsmPrinter init function, if available])
 694     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 695       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 696        [LLVM name for the native AsmParser init function, if available])
 697     fi
 698   fi
 699 done
 700
 701 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 702 dnl target feature def files.
 703 LLVM_ENUM_TARGETS=""
 704 LLVM_ENUM_ASM_PRINTERS=""
 705 LLVM_ENUM_ASM_PARSERS=""
 706 LLVM_ENUM_DISASSEMBLERS=""
 707 for target_to_build in $TARGETS_TO_BUILD; do
 708   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 709   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 710     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 711   fi
 712   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 713     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 714   fi
 715   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 716     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 717   fi
 718 done
 719 AC_SUBST(LLVM_ENUM_TARGETS)
 720 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 721 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 722 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 723
 724 dnl Prevent the CBackend from using printf("%a") for floating point so older
 725 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 726 dnl can still compile the CBE's output
 727 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 728   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 729   enableval=default)
 730 case "$enableval" in
 731   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 732   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 733   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 734   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 735 esac
 736 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 737                    [Define if CBE is enabled for printf %a output])
 738
 739 dnl Override the option to use for optimized builds.
 740 AC_ARG_WITH(optimize-option,
 741   AS_HELP_STRING([--with-optimize-option],
 742                  [Select the compiler options to use for optimized builds]),,
 743                  withval=default)
 744 AC_MSG_CHECKING([optimization flags])
 745 case "$withval" in
 746   default)
 747     case "$llvm_cv_os_type" in
 748     FreeBSD) optimize_option=-O2 ;;
 749     MingW) optimize_option=-O2 ;;
 750     *)     optimize_option=-O3 ;;
 751     esac ;;
 752   *) optimize_option="$withval" ;;
 753 esac
 754 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 755 AC_MSG_RESULT([$optimize_option])
 756
 757 dnl Specify extra build options
 758 AC_ARG_WITH(extra-options,
 759   AS_HELP_STRING([--with-extra-options],
 760                  [Specify additional options to compile LLVM with]),,
 761                  withval=default)
 762 case "$withval" in
 763   default) EXTRA_OPTIONS= ;;
 764   *) EXTRA_OPTIONS=$withval ;;
 765 esac
 766 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 767
 768 dnl Specify extra linker build options
 769 AC_ARG_WITH(extra-ld-options,
 770   AS_HELP_STRING([--with-extra-ld-options],
 771                  [Specify additional options to link LLVM with]),,
 772                  withval=default)
 773 case "$withval" in
 774   default) EXTRA_LD_OPTIONS= ;;
 775   *) EXTRA_LD_OPTIONS=$withval ;;
 776 esac
 777 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 778
 779 dnl Allow specific bindings to be specified for building (or not)
 780 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 781     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 782     enableval=default)
 783 BINDINGS_TO_BUILD=""
 784 case "$enableval" in
 785   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 786   all ) BINDINGS_TO_BUILD="ocaml" ;;
 787   none | no) BINDINGS_TO_BUILD="" ;;
 788   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 789       case "$a_binding" in
 790         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 791         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 792       esac
 793   done
 794   ;;
 795 esac
 796
 797 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 798 dnl script for bindings/ocaml/configure, except that its auto value depends on
 799 dnl OCAMLC, which is found here to support tests.
 800 AC_ARG_WITH([ocaml-libdir],
 801   [AS_HELP_STRING([--with-ocaml-libdir],
 802     [Specify install location for ocaml bindings (default is stdlib)])],
 803   [],
 804   [withval=auto])
 805 case "$withval" in
 806   auto) with_ocaml_libdir="$withval" ;;
 807   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 808   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 809 esac
 810
 811 AC_ARG_WITH(clang-srcdir,
 812   AS_HELP_STRING([--with-clang-srcdir],
 813     [Directory to the out-of-tree Clang source]),,
 814     withval="-")
 815 case "$withval" in
 816   -) clang_src_root="" ;;
 817   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 818   *) clang_src_root="$ac_pwd/$withval" ;;
 819 esac
 820 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
 821
 822 AC_ARG_WITH(clang-resource-dir,
 823   AS_HELP_STRING([--with-clang-resource-dir],
 824     [Relative directory from the Clang binary for resource files]),,
 825     withval="")
 826 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 827                    [Relative directory for resource files])
 828
 829 AC_ARG_WITH(c-include-dirs,
 830   AS_HELP_STRING([--with-c-include-dirs],
 831     [Colon separated list of directories clang will search for headers]),,
 832     withval="")
 833 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 834                    [Directories clang will search for headers])
 835
 836 AC_ARG_WITH(cxx-include-root,
 837   AS_HELP_STRING([--with-cxx-include-root],
 838     [Directory with the libstdc++ headers.]),,
 839     withval="")
 840 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 841                    [Directory with the libstdc++ headers.])
 842
 843 AC_ARG_WITH(cxx-include-arch,
 844   AS_HELP_STRING([--with-cxx-include-arch],
 845     [Architecture of the libstdc++ headers.]),,
 846     withval="")
 847 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 848                    [Arch the libstdc++ headers.])
 849
 850 AC_ARG_WITH(cxx-include-32bit-dir,
 851   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 852     [32 bit multilib dir.]),,
 853     withval="")
 854 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 855                    [32 bit multilib directory.])
 856
 857 AC_ARG_WITH(cxx-include-64bit-dir,
 858   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 859     [64 bit multilib directory.]),,
 860     withval="")
 861 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 862                    [64 bit multilib directory.])
 863
 864 dnl Allow linking of LLVM with GPLv3 binutils code.
 865 AC_ARG_WITH(binutils-include,
 866   AS_HELP_STRING([--with-binutils-include],
 867     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 868   withval=default)
 869 case "$withval" in
 870   default) WITH_BINUTILS_INCDIR=default ;;
 871   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 872   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 873 esac
 874 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 875   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 876   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 877      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 878      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 879   fi
 880 fi
 881
 882 dnl Specify the URL where bug reports should be submitted.
 883 AC_ARG_WITH(bug-report-url,
 884   AS_HELP_STRING([--with-bug-report-url],
 885     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 886     withval="http://llvm.org/bugs/")
 887 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 888                    [Bug report URL.])
 889
 890 dnl --enable-libffi : check whether the user wants to turn off libffi:
 891 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 892   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 893   [case "$enableval" in
 894     yes) llvm_cv_enable_libffi="yes" ;;
 895     no)  llvm_cv_enable_libffi="no"  ;;
 896     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 897   esac],
 898   llvm_cv_enable_libffi=no)
 899
 900 AC_ARG_WITH(internal-prefix,
 901   AS_HELP_STRING([--with-internal-prefix],
 902     [Installation directory for internal files]),,
 903     withval="")
 904 AC_SUBST(INTERNAL_PREFIX,[$withval])
 905
 906 dnl===-----------------------------------------------------------------------===
 907 dnl===
 908 dnl=== SECTION 4: Check for programs we need and that they are the right version
 909 dnl===
 910 dnl===-----------------------------------------------------------------------===
 911
 912 AC_PROG_NM
 913 AC_SUBST(NM)
 914
 915 dnl Check for the tools that the makefiles require
 916 AC_CHECK_GNU_MAKE
 917 AC_PROG_LN_S
 918 AC_PATH_PROG(CMP, [cmp], [cmp])
 919 AC_PATH_PROG(CP, [cp], [cp])
 920 AC_PATH_PROG(DATE, [date], [date])
 921 AC_PATH_PROG(FIND, [find], [find])
 922 AC_PATH_PROG(GREP, [grep], [grep])
 923 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 924 AC_PATH_PROG(MV,   [mv],   [mv])
 925 AC_PROG_RANLIB
 926 AC_CHECK_TOOL(AR, ar, false)
 927 AC_PATH_PROG(RM,   [rm],   [rm])
 928 AC_PATH_PROG(SED,  [sed],  [sed])
 929 AC_PATH_PROG(TAR,  [tar],  [gtar])
 930 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 931
 932 dnl Looking for misc. graph plotting software
 933 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 934 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 935   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 936   dnl If we're targeting for mingw we should emit windows paths, not msys
 937   if test "$llvm_cv_os_type" = "MingW" ; then
 938     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 939   fi
 940   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 941    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 942 fi
 943 AC_PATH_PROG(DOT, [dot], [echo dot])
 944 if test "$DOT" != "echo dot" ; then
 945   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 946   dnl If we're targeting for mingw we should emit windows paths, not msys
 947   if test "$llvm_cv_os_type" = "MingW" ; then
 948     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 949   fi
 950   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 951    [Define to path to dot program if found or 'echo dot' otherwise])
 952 fi
 953 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 954 if test "$FDP" != "echo fdp" ; then
 955   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 956   dnl If we're targeting for mingw we should emit windows paths, not msys
 957   if test "$llvm_cv_os_type" = "MingW" ; then
 958     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 959   fi
 960   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 961    [Define to path to fdp program if found or 'echo fdp' otherwise])
 962 fi
 963 AC_PATH_PROG(NEATO, [neato], [echo neato])
 964 if test "$NEATO" != "echo neato" ; then
 965   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 966   dnl If we're targeting for mingw we should emit windows paths, not msys
 967   if test "$llvm_cv_os_type" = "MingW" ; then
 968     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 969   fi
 970   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 971    [Define to path to neato program if found or 'echo neato' otherwise])
 972 fi
 973 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 974 if test "$TWOPI" != "echo twopi" ; then
 975   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 976   dnl If we're targeting for mingw we should emit windows paths, not msys
 977   if test "$llvm_cv_os_type" = "MingW" ; then
 978     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 979   fi
 980   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 981    [Define to path to twopi program if found or 'echo twopi' otherwise])
 982 fi
 983 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 984 if test "$CIRCO" != "echo circo" ; then
 985   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 986   dnl If we're targeting for mingw we should emit windows paths, not msys
 987   if test "$llvm_cv_os_type" = "MingW" ; then
 988     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 989   fi
 990   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 991    [Define to path to circo program if found or 'echo circo' otherwise])
 992 fi
 993 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 994 if test "$GV" != "echo gv" ; then
 995   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 996   dnl If we're targeting for mingw we should emit windows paths, not msys
 997   if test "$llvm_cv_os_type" = "MingW" ; then
 998     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 999   fi
1000   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1001    [Define to path to gv program if found or 'echo gv' otherwise])
1002 fi
1003 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1004 if test "$DOTTY" != "echo dotty" ; then
1005   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1006   dnl If we're targeting for mingw we should emit windows paths, not msys
1007   if test "$llvm_cv_os_type" = "MingW" ; then
1008     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1009   fi
1010   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1011    [Define to path to dotty program if found or 'echo dotty' otherwise])
1012 fi
1013 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1014 if test "$XDOT_PY" != "echo xdot.py" ; then
1015   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1016   dnl If we're targeting for mingw we should emit windows paths, not msys
1017   if test "$llvm_cv_os_type" = "MingW" ; then
1018     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1019   fi
1020   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1021    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1022 fi
1023
1024 dnl Look for a sufficiently recent version of Perl.
1025 LLVM_PROG_PERL([5.006])
1026 AC_SUBST(PERL)
1027 if test x"$PERL" = xnone; then
1028    AC_SUBST(HAVE_PERL,0)
1029    AC_MSG_ERROR([perl is required but was not found, please install it])
1030 else
1031    AC_SUBST(HAVE_PERL,1)
1032 fi
1033
1034 dnl Find the install program
1035 AC_PROG_INSTALL
1036 dnl Prepend src dir to install path dir if it's a relative path
1037 dnl This is a hack for installs that take place in something other
1038 dnl than the top level.
1039 case "$INSTALL" in
1040  [[\\/$]]* | ?:[[\\/]]* ) ;;
1041  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1042 esac
1043
1044 dnl Checks for documentation and testing tools that we can do without. If these
1045 dnl are not found then they are set to "true" which always succeeds but does
1046 dnl nothing. This just lets the build output show that we could have done
1047 dnl something if the tool was available.
1048 AC_PATH_PROG(BZIP2, [bzip2])
1049 AC_PATH_PROG(CAT, [cat])
1050 AC_PATH_PROG(DOXYGEN, [doxygen])
1051 AC_PATH_PROG(GROFF, [groff])
1052 AC_PATH_PROG(GZIPBIN, [gzip])
1053 AC_PATH_PROG(POD2HTML, [pod2html])
1054 AC_PATH_PROG(POD2MAN, [pod2man])
1055 AC_PATH_PROG(PDFROFF, [pdfroff])
1056 AC_PATH_PROG(RUNTEST, [runtest])
1057 DJ_AC_PATH_TCLSH
1058 AC_PATH_PROG(ZIP, [zip])
1059 AC_PATH_PROGS(OCAMLC, [ocamlc])
1060 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1061 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1062 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1063 AC_PATH_PROGS(GAS, [gas as])
1064
1065 dnl Get the version of the linker in use.
1066 AC_LINK_GET_VERSION
1067
1068 dnl Determine whether the linker supports the -R option.
1069 AC_LINK_USE_R
1070
1071 dnl Determine whether the linker supports the -export-dynamic option.
1072 AC_LINK_EXPORT_DYNAMIC
1073
1074 dnl Determine whether the linker supports the --version-script option.
1075 AC_LINK_VERSION_SCRIPT
1076
1077 dnl Check for libtool and the library that has dlopen function (which must come
1078 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1079 dnl libtool).
1080 AC_LIBTOOL_DLOPEN
1081 AC_LIB_LTDL
1082
1083 AC_MSG_CHECKING([tool compatibility])
1084
1085 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1086 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1087 dnl to support those options.
1088 dnl "icc" emits gcc signatures
1089 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1090 ICC=no
1091 IXX=no
1092 case $CC in
1093   icc*|icpc*)
1094     ICC=yes
1095     IXX=yes
1096     ;;
1097    *)
1098     ;;
1099 esac
1100
1101 if test "$GCC" != "yes" && test "$ICC" != "yes"
1102 then
1103   AC_MSG_ERROR([gcc|icc required but not found])
1104 fi
1105
1106 dnl Ensure that compilation tools are compatible with GCC extensions
1107 if test "$GXX" != "yes" && test "$IXX" != "yes"
1108 then
1109   AC_MSG_ERROR([g++|clang++|icc required but not found])
1110 fi
1111
1112 dnl Verify that GCC is version 3.0 or higher
1113 if test "$GCC" = "yes"
1114 then
1115   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1116 #error Unsupported GCC version
1117 #endif
1118 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1119 fi
1120
1121 dnl Check for GNU Make.  We use its extensions, so don't build without it
1122 if test -z "$llvm_cv_gnu_make_command"
1123 then
1124   AC_MSG_ERROR([GNU Make required but not found])
1125 fi
1126
1127 dnl Tool compatibility is okay if we make it here.
1128 AC_MSG_RESULT([ok])
1129
1130 dnl Check optional compiler flags.
1131 AC_MSG_CHECKING([optional compiler flags])
1132 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1133 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1134 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1135
1136 dnl===-----------------------------------------------------------------------===
1137 dnl===
1138 dnl=== SECTION 5: Check for libraries
1139 dnl===
1140 dnl===-----------------------------------------------------------------------===
1141
1142 AC_CHECK_LIB(m,sin)
1143 if test "$llvm_cv_os_type" = "MingW" ; then
1144   AC_CHECK_LIB(imagehlp, main)
1145   AC_CHECK_LIB(psapi, main)
1146 fi
1147
1148 dnl dlopen() is required for plugin support.
1149 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1150                [Define if dlopen() is available on this platform.]),
1151                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1152
1153 dnl libffi is optional; used to call external functions from the interpreter
1154 if test "$llvm_cv_enable_libffi" = "yes" ; then
1155   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1156                  [Define if libffi is available on this platform.]),
1157                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1158 fi
1159
1160 dnl mallinfo is optional; the code can compile (minus features) without it
1161 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1162                [Define if mallinfo() is available on this platform.]))
1163
1164 dnl pthread locking functions are optional - but llvm will not be thread-safe
1165 dnl without locks.
1166 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1167   AC_CHECK_LIB(pthread, pthread_mutex_init)
1168   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1169                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1170                            [Have pthread_mutex_lock]))
1171   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1172                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1173                  [Have pthread_rwlock_init]))
1174   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1175                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1176                  [Have pthread_getspecific]))
1177 fi
1178
1179 dnl Allow extra x86-disassembler library
1180 AC_ARG_WITH(udis86,
1181   AS_HELP_STRING([--with-udis86=<path>],
1182     [Use udis86 external x86 disassembler library]),
1183     [
1184       AC_SUBST(USE_UDIS86, [1])
1185       case "$withval" in
1186         /usr/lib|yes) ;;
1187         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1188       esac
1189       AC_CHECK_LIB(udis86, ud_init, [], [
1190         echo "Error! You need to have libudis86 around."
1191         exit -1
1192       ])
1193     ],
1194     AC_SUBST(USE_UDIS86, [0]))
1195 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1196                    [Define if use udis86 library])
1197
1198 dnl Allow OProfile support for JIT output.
1199 AC_ARG_WITH(oprofile,
1200   AS_HELP_STRING([--with-oprofile=<prefix>],
1201     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1202     [
1203       AC_SUBST(USE_OPROFILE, [1])
1204       case "$withval" in
1205         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1206         no) llvm_cv_oppath=
1207             AC_SUBST(USE_OPROFILE, [0]) ;;
1208         *) llvm_cv_oppath="${withval}/lib/oprofile"
1209            CPPFLAGS="-I${withval}/include";;
1210       esac
1211       if test -n "$llvm_cv_oppath" ; then
1212         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1213         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1214         dnl libbfd is not included properly in libopagent in some Debian
1215         dnl versions.  If libbfd isn't found at all, we assume opagent works
1216         dnl anyway.
1217         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1218         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1219           echo "Error! You need to have libopagent around."
1220           exit -1
1221         ])
1222         AC_CHECK_HEADER([opagent.h], [], [
1223           echo "Error! You need to have opagent.h around."
1224           exit -1
1225           ])
1226       fi
1227     ],
1228     [
1229       AC_SUBST(USE_OPROFILE, [0])
1230     ])
1231 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1232                    [Define if we have the oprofile JIT-support library])
1233
1234 dnl===-----------------------------------------------------------------------===
1235 dnl===
1236 dnl=== SECTION 6: Check for header files
1237 dnl===
1238 dnl===-----------------------------------------------------------------------===
1239
1240 dnl First, use autoconf provided macros for specific headers that we need
1241 dnl We don't check for ancient stuff or things that are guaranteed to be there
1242 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1243 dnl Generally we're looking for POSIX headers.
1244 AC_HEADER_DIRENT
1245 AC_HEADER_MMAP_ANONYMOUS
1246 AC_HEADER_STAT
1247 AC_HEADER_SYS_WAIT
1248 AC_HEADER_TIME
1249
1250 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1251 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1252 AC_CHECK_HEADERS([utime.h windows.h])
1253 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1254 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1255 AC_CHECK_HEADERS([valgrind/valgrind.h])
1256 AC_CHECK_HEADERS([fenv.h])
1257 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1258   AC_CHECK_HEADERS(pthread.h,
1259                    AC_SUBST(HAVE_PTHREAD, 1),
1260                    AC_SUBST(HAVE_PTHREAD, 0))
1261 else
1262   AC_SUBST(HAVE_PTHREAD, 0)
1263 fi
1264
1265 dnl Try to find ffi.h.
1266 if test "$llvm_cv_enable_libffi" = "yes" ; then
1267   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1268 fi
1269
1270 dnl Try to find Darwin specific crash reporting libraries.
1271 AC_CHECK_HEADERS([CrashReporterClient.h])
1272
1273 dnl Try to find Darwin specific crash reporting global.
1274 AC_MSG_CHECKING([__crashreporter_info__])
1275 AC_LINK_IFELSE(
1276   AC_LANG_SOURCE(
1277     [[extern const char *__crashreporter_info__;
1278       int main() {
1279         __crashreporter_info__ = "test";
1280         return 0;
1281       }
1282     ]]),
1283   AC_MSG_RESULT(yes)
1284   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1285   AC_MSG_RESULT(no)
1286   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1287             Define if __crashreporter_info__ exists.))
1288
1289 dnl===-----------------------------------------------------------------------===
1290 dnl===
1291 dnl=== SECTION 7: Check for types and structures
1292 dnl===
1293 dnl===-----------------------------------------------------------------------===
1294
1295 AC_HUGE_VAL_CHECK
1296 AC_TYPE_PID_T
1297 AC_TYPE_SIZE_T
1298 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1299 AC_STRUCT_TM
1300 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1301 AC_CHECK_TYPES([uint64_t],,
1302          AC_CHECK_TYPES([u_int64_t],,
1303          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1304
1305 dnl===-----------------------------------------------------------------------===
1306 dnl===
1307 dnl=== SECTION 8: Check for specific functions needed
1308 dnl===
1309 dnl===-----------------------------------------------------------------------===
1310
1311 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1312 AC_CHECK_FUNCS([powf fmodf strtof round ])
1313 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1314 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1315 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit strdup ])
1316 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1317 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1318 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1319 AC_C_PRINTF_A
1320 AC_FUNC_RAND48
1321
1322 dnl Check the declaration "Secure API" on Windows environments.
1323 AC_CHECK_DECLS([strerror_s])
1324
1325 dnl Check symbols in libgcc.a for JIT on Mingw.
1326 if test "$llvm_cv_os_type" = "MingW" ; then
1327   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1328   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1329   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1330   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1331
1332   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1333   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1334   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1335   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1336   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1337   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1338   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1339   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1340   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1341   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1342
1343   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1344   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1345 fi
1346
1347 dnl Check Win32 API EnumerateLoadedModules.
1348 if test "$llvm_cv_os_type" = "MingW" ; then
1349   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1350   AC_COMPILE_IFELSE([[#include <windows.h>
1351 #include <imagehlp.h>
1352 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1353 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1354 [
1355   AC_MSG_RESULT([yes])
1356   llvm_cv_win32_elmcb_pcstr="PCSTR"
1357 ],
1358 [
1359   AC_MSG_RESULT([no])
1360   llvm_cv_win32_elmcb_pcstr="PSTR"
1361 ])
1362   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1363 fi
1364
1365 dnl Check for variations in the Standard C++ library and STL. These macros are
1366 dnl provided by LLVM in the autoconf/m4 directory.
1367 AC_FUNC_ISNAN
1368 AC_FUNC_ISINF
1369
1370 dnl Check for mmap support.We also need to know if /dev/zero is required to
1371 dnl be opened for allocating RWX memory.
1372 dnl Make sure we aren't attempting to configure for an unknown system
1373 if test "$llvm_cv_platform_type" = "Unix" ; then
1374   AC_FUNC_MMAP
1375   AC_FUNC_MMAP_FILE
1376   AC_NEED_DEV_ZERO_FOR_MMAP
1377
1378   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1379   then
1380     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1381   fi
1382   if test "$ac_cv_func_mmap_file" = "no"
1383   then
1384     AC_MSG_WARN([mmap() of files required but not found])
1385   fi
1386 fi
1387
1388 dnl atomic builtins are required for threading support.
1389 AC_MSG_CHECKING(for GCC atomic builtins)
1390 dnl Since we'll be using these atomic builtins in C++ files we should test
1391 dnl the C++ compiler.
1392 AC_LANG_PUSH([C++])
1393 AC_LINK_IFELSE(
1394   AC_LANG_SOURCE(
1395     [[int main() {
1396         volatile unsigned long val = 1;
1397         __sync_synchronize();
1398         __sync_val_compare_and_swap(&val, 1, 0);
1399         __sync_add_and_fetch(&val, 1);
1400         __sync_sub_and_fetch(&val, 1);
1401         return 0;
1402       }
1403     ]]),
1404   AC_LANG_POP([C++])
1405   AC_MSG_RESULT(yes)
1406   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1407   AC_MSG_RESULT(no)
1408   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1409   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1410
1411 dnl===-----------------------------------------------------------------------===
1412 dnl===
1413 dnl=== SECTION 9: Additional checks, variables, etc.
1414 dnl===
1415 dnl===-----------------------------------------------------------------------===
1416
1417 dnl Handle 32-bit linux systems running a 64-bit kernel.
1418 dnl This has to come after section 4 because it invokes the compiler.
1419 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1420   AC_IS_LINUX_MIXED
1421   if test "$llvm_cv_linux_mixed" = "yes"; then
1422     llvm_cv_target_arch="x86"
1423     ARCH="x86"
1424   fi
1425 fi
1426
1427 dnl Check whether __dso_handle is present
1428 AC_CHECK_FUNCS([__dso_handle])
1429
1430 dnl Propagate the shared library extension that the libltdl checks did to
1431 dnl the Makefiles so we can use it there too
1432 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1433
1434 dnl Propagate the run-time library path variable that the libltdl
1435 dnl checks found to the Makefiles so we can use it there too
1436 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1437
1438 dnl Translate the various configuration directories and other basic
1439 dnl information into substitutions that will end up in Makefile.config.in
1440 dnl that these configured values can be used by the makefiles
1441 if test "${prefix}" = "NONE" ; then
1442   prefix="/usr/local"
1443 fi
1444 eval LLVM_PREFIX="${prefix}";
1445 eval LLVM_BINDIR="${prefix}/bin";
1446 eval LLVM_LIBDIR="${prefix}/lib";
1447 eval LLVM_DATADIR="${prefix}/share/llvm";
1448 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1449 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1450 eval LLVM_INCLUDEDIR="${prefix}/include";
1451 eval LLVM_INFODIR="${prefix}/info";
1452 eval LLVM_MANDIR="${prefix}/man";
1453 LLVM_CONFIGTIME=`date`
1454 AC_SUBST(LLVM_PREFIX)
1455 AC_SUBST(LLVM_BINDIR)
1456 AC_SUBST(LLVM_LIBDIR)
1457 AC_SUBST(LLVM_DATADIR)
1458 AC_SUBST(LLVM_DOCSDIR)
1459 AC_SUBST(LLVM_ETCDIR)
1460 AC_SUBST(LLVM_INCLUDEDIR)
1461 AC_SUBST(LLVM_INFODIR)
1462 AC_SUBST(LLVM_MANDIR)
1463 AC_SUBST(LLVM_CONFIGTIME)
1464
1465 dnl Place the various directories into the config.h file as #defines so that we
1466 dnl can know about the installation paths within LLVM.
1467 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1468                    [Installation prefix directory])
1469 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1470                    [Installation directory for binary executables])
1471 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1472                    [Installation directory for libraries])
1473 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1474                    [Installation directory for data files])
1475 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1476                    [Installation directory for documentation])
1477 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1478                    [Installation directory for config files])
1479 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1480                    [Installation directory for include files])
1481 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1482                    [Installation directory for .info files])
1483 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1484                    [Installation directory for man pages])
1485 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1486                    [Time at which LLVM was configured])
1487 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1488                    [Target triple LLVM will generate code for by default])
1489
1490 dnl Determine which bindings to build.
1491 if test "$BINDINGS_TO_BUILD" = auto ; then
1492   BINDINGS_TO_BUILD=""
1493   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1494     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1495   fi
1496 fi
1497 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1498
1499 dnl This isn't really configurey, but it avoids having to repeat the list in
1500 dnl other files.
1501 AC_SUBST(ALL_BINDINGS,ocaml)
1502
1503 dnl Do any work necessary to ensure that bindings have what they need.
1504 binding_prereqs_failed=0
1505 for a_binding in $BINDINGS_TO_BUILD ; do
1506   case "$a_binding" in
1507   ocaml)
1508     if test "x$OCAMLC" = x ; then
1509       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1510       binding_prereqs_failed=1
1511     fi
1512     if test "x$OCAMLDEP" = x ; then
1513       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1514       binding_prereqs_failed=1
1515     fi
1516     if test "x$OCAMLOPT" = x ; then
1517       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1518       dnl ocamlopt is optional!
1519     fi
1520     if test "x$with_ocaml_libdir" != xauto ; then
1521       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1522     else
1523       ocaml_stdlib="`"$OCAMLC" -where`"
1524       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1525       then
1526         # ocaml stdlib is beneath our prefix; use stdlib
1527         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1528       else
1529         # ocaml stdlib is outside our prefix; use libdir/ocaml
1530         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1531       fi
1532     fi
1533     ;;
1534   esac
1535 done
1536 if test "$binding_prereqs_failed" = 1 ; then
1537   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1538 fi
1539
1540 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1541 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1542
1543 dnl Determine linker rpath flag
1544 if test "$llvm_cv_link_use_r" = "yes" ; then
1545   RPATH="-Wl,-R"
1546 else
1547   RPATH="-Wl,-rpath"
1548 fi
1549 AC_SUBST(RPATH)
1550
1551 dnl Determine linker rdynamic flag
1552 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1553   RDYNAMIC="-Wl,-export-dynamic"
1554 else
1555   RDYNAMIC=""
1556 fi
1557 AC_SUBST(RDYNAMIC)
1558
1559 dnl===-----------------------------------------------------------------------===
1560 dnl===
1561 dnl=== SECTION 10: Specify the output files and generate it
1562 dnl===
1563 dnl===-----------------------------------------------------------------------===
1564
1565 dnl Configure header files
1566 dnl WARNING: dnl If you add or remove any of the following config headers, then
1567 dnl you MUST also update Makefile so that the variable FilesToConfig
1568 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1569 dnl files can be updated automatically when their *.in sources change.
1570 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1571 AH_TOP([#ifndef CONFIG_H
1572 #define CONFIG_H])
1573 AH_BOTTOM([#endif])
1574
1575 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1576 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1577 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1578 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1579 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1580
1581 dnl Configure the makefile's configuration data
1582 AC_CONFIG_FILES([Makefile.config])
1583
1584 dnl Configure the RPM spec file for LLVM
1585 AC_CONFIG_FILES([llvm.spec])
1586
1587 dnl Configure doxygen's configuration file
1588 AC_CONFIG_FILES([docs/doxygen.cfg])
1589
1590 dnl Configure clang, if present
1591 if test ${clang_src_root} = ""; then
1592   clang_src_root="$ac_pwd/tools/clang"
1593 fi
1594 if test -f ${clang_src_root}/README.txt; then
1595   AC_CONFIG_HEADERS([${clang_src_root}/include/clang/Config/config.h])
1596   AC_CONFIG_FILES([${clang_src_root}/docs/doxygen.cfg])
1597 fi
1598
1599 dnl OCaml findlib META file
1600 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1601
1602 dnl Do special configuration of Makefiles
1603 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1604 AC_CONFIG_MAKEFILE(Makefile)
1605 AC_CONFIG_MAKEFILE(Makefile.common)
1606 AC_CONFIG_MAKEFILE(examples/Makefile)
1607 AC_CONFIG_MAKEFILE(lib/Makefile)
1608 AC_CONFIG_MAKEFILE(runtime/Makefile)
1609 AC_CONFIG_MAKEFILE(test/Makefile)
1610 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1611 AC_CONFIG_MAKEFILE(unittests/Makefile)
1612 AC_CONFIG_MAKEFILE(tools/Makefile)
1613 AC_CONFIG_MAKEFILE(utils/Makefile)
1614 AC_CONFIG_MAKEFILE(projects/Makefile)
1615 AC_CONFIG_MAKEFILE(bindings/Makefile)
1616 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1617
1618 dnl Finally, crank out the output
1619 AC_OUTPUT