autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.9svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65
  66 dnl
  67 dnl One tricky part of doing this is that some projects depend upon other
  68 dnl projects.  For example, several projects rely upon the LLVM test suite.
  69 dnl We want to configure those projects first so that their object trees are
  70 dnl created before running the configure scripts of projects that depend upon
  71 dnl them.
  72 dnl
  73
  74 dnl Several projects use llvm-gcc, so configure that first
  75 if test -d ${srcdir}/projects/llvm-gcc ; then
  76   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  77 fi
  78
  79 dnl Several projects use the LLVM test suite, so configure it next.
  80 if test -d ${srcdir}/projects/test-suite ; then
  81   AC_CONFIG_SUBDIRS([projects/test-suite])
  82 fi
  83
  84 dnl llvm-test is the old name of the test-suite, kept here for backwards
  85 dnl compatibility
  86 if test -d ${srcdir}/projects/llvm-test ; then
  87   AC_CONFIG_SUBDIRS([projects/llvm-test])
  88 fi
  89
  90 dnl Some projects use poolalloc; configure that next
  91 if test -d ${srcdir}/projects/poolalloc ; then
  92   AC_CONFIG_SUBDIRS([projects/poolalloc])
  93 fi
  94
  95 if test -d ${srcdir}/projects/llvm-poolalloc ; then
  96   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
  97 fi
  98
  99 dnl Check for all other projects
 100 for i in `ls ${srcdir}/projects`
 101 do
 102   if test -d ${srcdir}/projects/${i} ; then
 103     case ${i} in
 104       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 105       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 106       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 107       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 108       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 109       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 110       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 111       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 112       llvm-gcc)       ;;
 113       test-suite)     ;;
 114       llvm-test)      ;;
 115       poolalloc)      ;;
 116       llvm-poolalloc) ;;
 117       *)
 118         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 119         ;;
 120     esac
 121   fi
 122 done
 123
 124 dnl Disable the build of polly, even if it is checked out into tools/polly.
 125 AC_ARG_ENABLE(polly,
 126               AS_HELP_STRING([--enable-polly],
 127                              [Use polly if available (default is YES)]),,
 128                              enableval=default)
 129 case "$enableval" in
 130   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 131   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 132   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 133   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 134 esac
 135
 136
 137 dnl Check if polly is checked out into tools/polly and configure it if
 138 dnl available.
 139 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 140   AC_SUBST(LLVM_HAS_POLLY,1)
 141   AC_CONFIG_SUBDIRS([tools/polly])
 142 fi
 143
 144 dnl===-----------------------------------------------------------------------===
 145 dnl===
 146 dnl=== SECTION 2: Architecture, target, and host checks
 147 dnl===
 148 dnl===-----------------------------------------------------------------------===
 149
 150 dnl Check the target for which we're compiling and the host that will do the
 151 dnl compilations. This will tell us which LLVM compiler will be used for
 152 dnl compiling SSA into object code. This needs to be done early because
 153 dnl following tests depend on it.
 154 AC_CANONICAL_TARGET
 155
 156 dnl Determine the platform type and cache its value. This helps us configure
 157 dnl the System library to the correct build platform.
 158 AC_CACHE_CHECK([type of operating system we're going to host on],
 159                [llvm_cv_os_type],
 160 [case $host in
 161   *-*-aix*)
 162     llvm_cv_link_all_option="-Wl,--whole-archive"
 163     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 164     llvm_cv_os_type="AIX"
 165     llvm_cv_platform_type="Unix" ;;
 166   *-*-irix*)
 167     llvm_cv_link_all_option="-Wl,--whole-archive"
 168     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 169     llvm_cv_os_type="IRIX"
 170     llvm_cv_platform_type="Unix" ;;
 171   *-*-cygwin*)
 172     llvm_cv_link_all_option="-Wl,--whole-archive"
 173     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 174     llvm_cv_os_type="Cygwin"
 175     llvm_cv_platform_type="Unix" ;;
 176   *-*-darwin*)
 177     llvm_cv_link_all_option="-Wl,-all_load"
 178     llvm_cv_no_link_all_option="-Wl,-noall_load"
 179     llvm_cv_os_type="Darwin"
 180     llvm_cv_platform_type="Unix" ;;
 181   *-*-minix*)
 182     llvm_cv_link_all_option="-Wl,-all_load"
 183     llvm_cv_no_link_all_option="-Wl,-noall_load"
 184     llvm_cv_os_type="Minix"
 185     llvm_cv_platform_type="Unix" ;;
 186   *-*-freebsd*)
 187     llvm_cv_link_all_option="-Wl,--whole-archive"
 188     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 189     llvm_cv_os_type="FreeBSD"
 190     llvm_cv_platform_type="Unix" ;;
 191   *-*-openbsd*)
 192     llvm_cv_link_all_option="-Wl,--whole-archive"
 193     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 194     llvm_cv_os_type="OpenBSD"
 195     llvm_cv_platform_type="Unix" ;;
 196   *-*-netbsd*)
 197     llvm_cv_link_all_option="-Wl,--whole-archive"
 198     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 199     llvm_cv_os_type="NetBSD"
 200     llvm_cv_platform_type="Unix" ;;
 201   *-*-dragonfly*)
 202     llvm_cv_link_all_option="-Wl,--whole-archive"
 203     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 204     llvm_cv_os_type="DragonFly"
 205     llvm_cv_platform_type="Unix" ;;
 206   *-*-hpux*)
 207     llvm_cv_link_all_option="-Wl,--whole-archive"
 208     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 209     llvm_cv_os_type="HP-UX"
 210     llvm_cv_platform_type="Unix" ;;
 211   *-*-interix*)
 212     llvm_cv_link_all_option="-Wl,--whole-archive"
 213     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 214     llvm_cv_os_type="Interix"
 215     llvm_cv_platform_type="Unix" ;;
 216   *-*-linux*)
 217     llvm_cv_link_all_option="-Wl,--whole-archive"
 218     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 219     llvm_cv_os_type="Linux"
 220     llvm_cv_platform_type="Unix" ;;
 221   *-*-solaris*)
 222     llvm_cv_link_all_option="-Wl,-z,allextract"
 223     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 224     llvm_cv_os_type="SunOS"
 225     llvm_cv_platform_type="Unix" ;;
 226   *-*-auroraux*)
 227     llvm_cv_link_all_option="-Wl,-z,allextract"
 228     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 229     llvm_cv_os_type="AuroraUX"
 230     llvm_cv_platform_type="Unix" ;;
 231   *-*-win32*)
 232     llvm_cv_link_all_option="-Wl,--whole-archive"
 233     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 234     llvm_cv_os_type="Win32"
 235     llvm_cv_platform_type="Win32" ;;
 236   *-*-mingw*)
 237     llvm_cv_link_all_option="-Wl,--whole-archive"
 238     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 239     llvm_cv_os_type="MingW"
 240     llvm_cv_platform_type="Win32" ;;
 241   *-*-haiku*)
 242     llvm_cv_link_all_option="-Wl,--whole-archive"
 243     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 244     llvm_cv_os_type="Haiku"
 245     llvm_cv_platform_type="Unix" ;;
 246   *-unknown-eabi*)
 247     llvm_cv_link_all_option="-Wl,--whole-archive"
 248     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 249     llvm_cv_os_type="Freestanding"
 250     llvm_cv_platform_type="Unix" ;;
 251   *-unknown-elf*)
 252     llvm_cv_link_all_option="-Wl,--whole-archive"
 253     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 254     llvm_cv_os_type="Freestanding"
 255     llvm_cv_platform_type="Unix" ;;
 256   *)
 257     llvm_cv_link_all_option=""
 258     llvm_cv_no_link_all_option=""
 259     llvm_cv_os_type="Unknown"
 260     llvm_cv_platform_type="Unknown" ;;
 261 esac])
 262
 263 AC_CACHE_CHECK([type of operating system we're going to target],
 264                [llvm_cv_target_os_type],
 265 [case $target in
 266   *-*-aix*)
 267     llvm_cv_target_os_type="AIX" ;;
 268   *-*-irix*)
 269     llvm_cv_target_os_type="IRIX" ;;
 270   *-*-cygwin*)
 271     llvm_cv_target_os_type="Cygwin" ;;
 272   *-*-darwin*)
 273     llvm_cv_target_os_type="Darwin" ;;
 274   *-*-minix*)
 275     llvm_cv_target_os_type="Minix" ;;
 276   *-*-freebsd*)
 277     llvm_cv_target_os_type="FreeBSD" ;;
 278   *-*-openbsd*)
 279     llvm_cv_target_os_type="OpenBSD" ;;
 280   *-*-netbsd*)
 281     llvm_cv_target_os_type="NetBSD" ;;
 282   *-*-dragonfly*)
 283     llvm_cv_target_os_type="DragonFly" ;;
 284   *-*-hpux*)
 285     llvm_cv_target_os_type="HP-UX" ;;
 286   *-*-interix*)
 287     llvm_cv_target_os_type="Interix" ;;
 288   *-*-linux*)
 289     llvm_cv_target_os_type="Linux" ;;
 290   *-*-solaris*)
 291     llvm_cv_target_os_type="SunOS" ;;
 292   *-*-auroraux*)
 293     llvm_cv_target_os_type="AuroraUX" ;;
 294   *-*-win32*)
 295     llvm_cv_target_os_type="Win32" ;;
 296   *-*-mingw*)
 297     llvm_cv_target_os_type="MingW" ;;
 298   *-*-haiku*)
 299     llvm_cv_target_os_type="Haiku" ;;
 300   *-unknown-eabi*)
 301     llvm_cv_target_os_type="Freestanding" ;;
 302   *)
 303     llvm_cv_target_os_type="Unknown" ;;
 304 esac])
 305
 306 dnl Make sure we aren't attempting to configure for an unknown system
 307 if test "$llvm_cv_os_type" = "Unknown" ; then
 308   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 309 fi
 310
 311 dnl Set the "OS" Makefile variable based on the platform type so the
 312 dnl makefile can configure itself to specific build hosts
 313 AC_SUBST(OS,$llvm_cv_os_type)
 314 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 315 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 316
 317 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 318 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 319 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 320
 321 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 322 dnl This is used by lib/System to determine the basic kind of implementation
 323 dnl to use.
 324 case $llvm_cv_platform_type in
 325   Unix)
 326     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 327     AC_SUBST(LLVM_ON_UNIX,[1])
 328     AC_SUBST(LLVM_ON_WIN32,[0])
 329     ;;
 330   Win32)
 331     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 332     AC_SUBST(LLVM_ON_UNIX,[0])
 333     AC_SUBST(LLVM_ON_WIN32,[1])
 334     ;;
 335 esac
 336
 337 dnl Determine what our target architecture is and configure accordingly.
 338 dnl This will allow Makefiles to make a distinction between the hardware and
 339 dnl the OS.
 340 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 341 [case $target in
 342   i?86-*)                 llvm_cv_target_arch="x86" ;;
 343   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 344   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 345   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 346   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 347   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 348   mips-*)                 llvm_cv_target_arch="Mips" ;;
 349   xcore-*)                llvm_cv_target_arch="XCore" ;;
 350   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 351   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 352   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 353   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 354   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 355   *)                      llvm_cv_target_arch="Unknown" ;;
 356 esac])
 357
 358 if test "$llvm_cv_target_arch" = "Unknown" ; then
 359   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 360 fi
 361
 362 # Determine the LLVM native architecture for the target
 363 case "$llvm_cv_target_arch" in
 364     x86)     LLVM_NATIVE_ARCH="X86" ;;
 365     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 366     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 367 esac
 368
 369 dnl Define a substitution, ARCH, for the target architecture
 370 AC_SUBST(ARCH,$llvm_cv_target_arch)
 371
 372 dnl Check for the endianness of the target
 373 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 374
 375 dnl Check for build platform executable suffix if we're crosscompiling
 376 if test "$cross_compiling" = yes; then
 377   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 378   AC_BUILD_EXEEXT
 379   ac_build_prefix=${build_alias}-
 380   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 381   if test -z "$BUILD_CXX"; then
 382      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 383      if test -z "$BUILD_CXX"; then
 384        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 385      fi
 386   fi
 387 else
 388   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 389 fi
 390
 391 dnl Check to see if there's a .svn or .git directory indicating that this
 392 dnl build is being done from a checkout. This sets up several defaults for
 393 dnl the command line switches. When we build with a checkout directory,
 394 dnl we get a debug with assertions turned on. Without, we assume a source
 395 dnl release and we get an optimized build without assertions.
 396 dnl See --enable-optimized and --enable-assertions below
 397 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 398   cvsbuild="yes"
 399   optimize="no"
 400   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 401 else
 402   cvsbuild="no"
 403   optimize="yes"
 404 fi
 405
 406 dnl===-----------------------------------------------------------------------===
 407 dnl===
 408 dnl=== SECTION 3: Command line arguments for the configure script.
 409 dnl===
 410 dnl===-----------------------------------------------------------------------===
 411
 412 dnl --enable-optimized : check whether they want to do an optimized build:
 413 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 414  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 415 if test ${enableval} = "no" ; then
 416   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 417 else
 418   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 419 fi
 420
 421 dnl --enable-profiling : check whether they want to do a profile build:
 422 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 423  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 424 if test ${enableval} = "no" ; then
 425   AC_SUBST(ENABLE_PROFILING,[[]])
 426 else
 427   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 428 fi
 429
 430 dnl --enable-assertions : check whether they want to turn on assertions or not:
 431 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 432   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 433 if test ${enableval} = "yes" ; then
 434   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 435 else
 436   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 437 fi
 438
 439 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 440 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 441   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 442 if test ${enableval} = "yes" ; then
 443   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 444   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 445 else
 446   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 447   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 448 fi
 449
 450 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 451 AC_ARG_ENABLE(debug-runtime,
 452    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 453 if test ${enableval} = "no" ; then
 454   AC_SUBST(DEBUG_RUNTIME,[[]])
 455 else
 456   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 457 fi
 458
 459 dnl --enable-debug-symbols : should even optimized compiler libraries
 460 dnl have debug symbols?
 461 AC_ARG_ENABLE(debug-symbols,
 462    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 463 if test ${enableval} = "no" ; then
 464   AC_SUBST(DEBUG_SYMBOLS,[[]])
 465 else
 466   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 467 fi
 468
 469 dnl --enable-jit: check whether they want to enable the jit
 470 AC_ARG_ENABLE(jit,
 471   AS_HELP_STRING(--enable-jit,
 472                  [Enable Just In Time Compiling (default is YES)]),,
 473   enableval=default)
 474 if test ${enableval} = "no"
 475 then
 476   AC_SUBST(JIT,[[]])
 477 else
 478   case "$llvm_cv_target_arch" in
 479     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 480     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 481     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 482     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 483     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 484     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 485     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 486     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 487     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 488     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 489     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 490     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 491     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 492     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 493   esac
 494 fi
 495
 496 dnl Allow enablement of doxygen generated documentation
 497 AC_ARG_ENABLE(doxygen,
 498               AS_HELP_STRING([--enable-doxygen],
 499                              [Build doxygen documentation (default is NO)]),,
 500                              enableval=default)
 501 case "$enableval" in
 502   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 503   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 504   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 505   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 506 esac
 507
 508 dnl Allow disablement of threads
 509 AC_ARG_ENABLE(threads,
 510               AS_HELP_STRING([--enable-threads],
 511                              [Use threads if available (default is YES)]),,
 512                              enableval=default)
 513 case "$enableval" in
 514   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 515   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 516   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 517   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 518 esac
 519 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 520
 521 dnl Allow building without position independent code
 522 AC_ARG_ENABLE(pic,
 523   AS_HELP_STRING([--enable-pic],
 524                  [Build LLVM with Position Independent Code (default is YES)]),,
 525                  enableval=default)
 526 case "$enableval" in
 527   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 528   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 529   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 530   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 531 esac
 532 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 533                    [Define if position independent code is enabled])
 534
 535 dnl Allow building a shared library and linking tools against it.
 536 AC_ARG_ENABLE(shared,
 537   AS_HELP_STRING([--enable-shared],
 538                  [Build a shared library and link tools against it (default is NO)]),,
 539                  enableval=default)
 540 case "$enableval" in
 541   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 542   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 543   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 544   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 545 esac
 546
 547 dnl Enable embedding timestamp information into build.
 548 AC_ARG_ENABLE(timestamps,
 549   AS_HELP_STRING([--enable-timestamps],
 550                  [Enable embedding timestamp information in build (default is YES)]),,
 551                  enableval=default)
 552 case "$enableval" in
 553   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 554   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 555   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 556   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 557 esac
 558 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 559                    [Define if timestamp information (e.g., __DATE___) is allowed])
 560
 561 dnl Allow specific targets to be specified for building (or not)
 562 TARGETS_TO_BUILD=""
 563 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 564     [Build specific host targets: all or target1,target2,... Valid targets are:
 565      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu,
 566      xcore, msp430, systemz, blackfin, ptx, cbe, and cpp (default=all)]),,
 567     enableval=all)
 568 if test "$enableval" = host-only ; then
 569   enableval=host
 570 fi
 571 case "$enableval" in
 572   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU XCore MSP430 SystemZ Blackfin CBackend CppBackend MBlaze PTX" ;;
 573   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 574       case "$a_target" in
 575         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 576         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 577         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 578         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 579         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 580         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 581         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 582         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 583         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 584         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 585         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 586         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 587         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 588         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 589         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 590         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 591         host) case "$llvm_cv_target_arch" in
 592             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 593             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 594             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 595             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 596             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 597             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 598             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 599             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 600             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 601             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 602             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 603             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 604             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 605             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 606             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 607           esac ;;
 608         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 609       esac
 610   done
 611   ;;
 612 esac
 613 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 614
 615 # Determine whether we are building LLVM support for the native architecture.
 616 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 617 for a_target in $TARGETS_TO_BUILD; do
 618   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 619     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 620       [LLVM architecture name for the native architecture, if available])
 621     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 622     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 623     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 624     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 625       [LLVM name for the native Target init function, if available])
 626     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 627       [LLVM name for the native TargetInfo init function, if available])
 628     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 629       [LLVM name for the native AsmPrinter init function, if available])
 630   fi
 631 done
 632
 633 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 634 # target feature def files.
 635 LLVM_ENUM_TARGETS=""
 636 LLVM_ENUM_ASM_PRINTERS=""
 637 LLVM_ENUM_ASM_PARSERS=""
 638 LLVM_ENUM_DISASSEMBLERS=""
 639 for target_to_build in $TARGETS_TO_BUILD; do
 640   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 641   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 642     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 643   fi
 644   # MC-ized AsmPrinters live in TARGET/InstPrinter, not AsmPrinter
 645   if test -f ${srcdir}/lib/Target/${target_to_build}/InstPrinter/Makefile ; then
 646     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 647   fi
 648   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 649     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 650   fi
 651   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 652     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 653   fi
 654 done
 655 AC_SUBST(LLVM_ENUM_TARGETS)
 656 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 657 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 658 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 659
 660 dnl Prevent the CBackend from using printf("%a") for floating point so older
 661 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 662 dnl can still compile the CBE's output
 663 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 664   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 665   enableval=default)
 666 case "$enableval" in
 667   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 668   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 669   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 670   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 671 esac
 672 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 673                    [Define if CBE is enabled for printf %a output])
 674
 675 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 676 AC_ARG_WITH(llvmgccdir,
 677   AS_HELP_STRING([--with-llvmgccdir],
 678     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 679     withval=default)
 680 case "$withval" in
 681   default) WITH_LLVMGCCDIR=default ;;
 682   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 683   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 684 esac
 685
 686 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 687 AC_ARG_WITH(llvmgcc,
 688   AS_HELP_STRING([--with-llvmgcc],
 689     [Specify location of llvm-gcc driver (default searches PATH)]),
 690     LLVMGCC=$with_llvmgcc
 691       WITH_LLVMGCCDIR="",)
 692
 693 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 694 AC_ARG_WITH(llvmgxx,
 695   AS_HELP_STRING([--with-llvmgxx],
 696     [Specify location of llvm-g++ driver (default searches PATH)]),
 697     LLVMGXX=$with_llvmgxx
 698     WITH_LLVMGCCDIR="",)
 699
 700 if test -n "$LLVMGCC"; then
 701    LLVMGCCCOMMAND="$LLVMGCC"
 702 fi
 703
 704 if test -n "$LLVMGXX"; then
 705    LLVMGXXCOMMAND="$LLVMGXX"
 706 fi
 707
 708 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 709    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 710 fi
 711
 712 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 713    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 714 fi
 715
 716 dnl Allow a specific Clang compiler to be used with this LLVM config.
 717 AC_ARG_WITH(clang,
 718   AS_HELP_STRING([--with-clang],
 719     [Specify location of clang compiler (default is --with-built-clang)]),
 720     [],[with_clang=default])
 721
 722 dnl Enable use of the built Clang.
 723 AC_ARG_WITH(built-clang,
 724   AS_HELP_STRING([--with-built-clang],
 725     [Use the compiled Clang as the LLVM compiler (default=check)]),
 726     [],[with_built_clang=check])
 727
 728 dnl Select the Clang compiler option.
 729 dnl
 730 dnl If --with-clang is given, always honor that; otherwise honor
 731 dnl --with-built-clang, or check if we have the clang sources.
 732 AC_MSG_CHECKING([clang compiler])
 733 WITH_CLANGPATH=""
 734 WITH_BUILT_CLANG=0
 735 if test "$with_clang" != "default"; then
 736    WITH_CLANGPATH="$with_clang"
 737    if ! test -x "$WITH_CLANGPATH"; then
 738      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 739    fi
 740 elif test "$with_built_clang" = "yes"; then
 741    WITH_BUILT_CLANG=1
 742 elif test "$with_built_clang" = "no"; then
 743    WITH_BUILT_CLANG=0
 744 else
 745    if test "$with_built_clang" != "check"; then
 746       AC_MSG_ERROR([invalid value for --with-built-clang.])
 747    fi
 748
 749    if test -f ${srcdir}/tools/clang/README.txt; then
 750      WITH_BUILT_CLANG=1
 751    fi
 752 fi
 753
 754 if ! test -z "$WITH_CLANGPATH"; then
 755    AC_MSG_RESULT([$WITH_CLANGPATH])
 756    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 757 elif test "$WITH_BUILT_CLANG" = "1"; then
 758    AC_MSG_RESULT([built])
 759 else
 760    AC_MSG_RESULT([none])
 761 fi
 762 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 763 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 764 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 765
 766 dnl Override the option to use for optimized builds.
 767 AC_ARG_WITH(optimize-option,
 768   AS_HELP_STRING([--with-optimize-option],
 769                  [Select the compiler options to use for optimized builds]),,
 770                  withval=default)
 771 AC_MSG_CHECKING([optimization flags])
 772 case "$withval" in
 773   default)
 774     case "$llvm_cv_os_type" in
 775     FreeBSD) optimize_option=-O2 ;;
 776     MingW) optimize_option=-O2 ;;
 777     *)     optimize_option=-O3 ;;
 778     esac ;;
 779   *) optimize_option="$withval" ;;
 780 esac
 781 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 782 AC_MSG_RESULT([$optimize_option])
 783
 784 dnl Specify extra build options
 785 AC_ARG_WITH(extra-options,
 786   AS_HELP_STRING([--with-extra-options],
 787                  [Specify additional options to compile LLVM with]),,
 788                  withval=default)
 789 case "$withval" in
 790   default) EXTRA_OPTIONS= ;;
 791   *) EXTRA_OPTIONS=$withval ;;
 792 esac
 793 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 794
 795 dnl Allow specific bindings to be specified for building (or not)
 796 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 797     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 798     enableval=default)
 799 BINDINGS_TO_BUILD=""
 800 case "$enableval" in
 801   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 802   all ) BINDINGS_TO_BUILD="ocaml" ;;
 803   none | no) BINDINGS_TO_BUILD="" ;;
 804   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 805       case "$a_binding" in
 806         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 807         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 808       esac
 809   done
 810   ;;
 811 esac
 812
 813 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 814 dnl script for bindings/ocaml/configure, except that its auto value depends on
 815 dnl OCAMLC, which is found here to support tests.
 816 AC_ARG_WITH([ocaml-libdir],
 817   [AS_HELP_STRING([--with-ocaml-libdir],
 818     [Specify install location for ocaml bindings (default is stdlib)])],
 819   [],
 820   [withval=auto])
 821 case "$withval" in
 822   auto) with_ocaml_libdir="$withval" ;;
 823   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 824   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 825 esac
 826
 827 AC_ARG_WITH(clang-resource-dir,
 828   AS_HELP_STRING([--with-clang-resource-dir],
 829     [Relative directory from the Clang binary for resource files]),,
 830     withval="")
 831 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 832                    [Relative directory for resource files])
 833
 834 AC_ARG_WITH(c-include-dirs,
 835   AS_HELP_STRING([--with-c-include-dirs],
 836     [Colon separated list of directories clang will search for headers]),,
 837     withval="")
 838 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 839                    [Directories clang will search for headers])
 840
 841 AC_ARG_WITH(cxx-include-root,
 842   AS_HELP_STRING([--with-cxx-include-root],
 843     [Directory with the libstdc++ headers.]),,
 844     withval="")
 845 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 846                    [Directory with the libstdc++ headers.])
 847
 848 AC_ARG_WITH(cxx-include-arch,
 849   AS_HELP_STRING([--with-cxx-include-arch],
 850     [Architecture of the libstdc++ headers.]),,
 851     withval="")
 852 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 853                    [Arch the libstdc++ headers.])
 854
 855 AC_ARG_WITH(cxx-include-32bit-dir,
 856   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 857     [32 bit multilib dir.]),,
 858     withval="")
 859 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 860                    [32 bit multilib directory.])
 861
 862 AC_ARG_WITH(cxx-include-64bit-dir,
 863   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 864     [64 bit multilib directory.]),,
 865     withval="")
 866 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 867                    [64 bit multilib directory.])
 868
 869 dnl Allow linking of LLVM with GPLv3 binutils code.
 870 AC_ARG_WITH(binutils-include,
 871   AS_HELP_STRING([--with-binutils-include],
 872     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 873   withval=default)
 874 case "$withval" in
 875   default) WITH_BINUTILS_INCDIR=default ;;
 876   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 877   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 878 esac
 879 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 880   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 881   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 882      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 883      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 884   fi
 885 fi
 886
 887 dnl --enable-libffi : check whether the user wants to turn off libffi:
 888 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 889   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 890   [case "$enableval" in
 891     yes) llvm_cv_enable_libffi="yes" ;;
 892     no)  llvm_cv_enable_libffi="no"  ;;
 893     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 894   esac],
 895   llvm_cv_enable_libffi=no)
 896
 897 dnl===-----------------------------------------------------------------------===
 898 dnl===
 899 dnl=== SECTION 4: Check for programs we need and that they are the right version
 900 dnl===
 901 dnl===-----------------------------------------------------------------------===
 902
 903 dnl Check for compilation tools
 904 AC_PROG_CPP
 905 AC_PROG_CC(gcc)
 906 AC_PROG_CXX(g++)
 907
 908 AC_PROG_NM
 909 AC_SUBST(NM)
 910
 911 dnl Check for the tools that the makefiles require
 912 AC_CHECK_GNU_MAKE
 913 AC_PROG_LN_S
 914 AC_PATH_PROG(CMP, [cmp], [cmp])
 915 AC_PATH_PROG(CP, [cp], [cp])
 916 AC_PATH_PROG(DATE, [date], [date])
 917 AC_PATH_PROG(FIND, [find], [find])
 918 AC_PATH_PROG(GREP, [grep], [grep])
 919 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 920 AC_PATH_PROG(MV,   [mv],   [mv])
 921 AC_PROG_RANLIB
 922 AC_CHECK_TOOL(AR, ar, false)
 923 AC_PATH_PROG(RM,   [rm],   [rm])
 924 AC_PATH_PROG(SED,  [sed],  [sed])
 925 AC_PATH_PROG(TAR,  [tar],  [gtar])
 926 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 927
 928 dnl Looking for misc. graph plotting software
 929 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 930 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 931   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 932   dnl If we're targeting for mingw we should emit windows paths, not msys
 933   if test "$llvm_cv_os_type" = "MingW" ; then
 934     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 935   fi
 936   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 937    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 938 fi
 939 AC_PATH_PROG(DOT, [dot], [echo dot])
 940 if test "$DOT" != "echo dot" ; then
 941   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 942   dnl If we're targeting for mingw we should emit windows paths, not msys
 943   if test "$llvm_cv_os_type" = "MingW" ; then
 944     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 945   fi
 946   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 947    [Define to path to dot program if found or 'echo dot' otherwise])
 948 fi
 949 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 950 if test "$FDP" != "echo fdp" ; then
 951   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 952   dnl If we're targeting for mingw we should emit windows paths, not msys
 953   if test "$llvm_cv_os_type" = "MingW" ; then
 954     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 955   fi
 956   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 957    [Define to path to fdp program if found or 'echo fdp' otherwise])
 958 fi
 959 AC_PATH_PROG(NEATO, [neato], [echo neato])
 960 if test "$NEATO" != "echo neato" ; then
 961   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 962   dnl If we're targeting for mingw we should emit windows paths, not msys
 963   if test "$llvm_cv_os_type" = "MingW" ; then
 964     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 965   fi
 966   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 967    [Define to path to neato program if found or 'echo neato' otherwise])
 968 fi
 969 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 970 if test "$TWOPI" != "echo twopi" ; then
 971   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 972   dnl If we're targeting for mingw we should emit windows paths, not msys
 973   if test "$llvm_cv_os_type" = "MingW" ; then
 974     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 975   fi
 976   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 977    [Define to path to twopi program if found or 'echo twopi' otherwise])
 978 fi
 979 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 980 if test "$CIRCO" != "echo circo" ; then
 981   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 982   dnl If we're targeting for mingw we should emit windows paths, not msys
 983   if test "$llvm_cv_os_type" = "MingW" ; then
 984     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 985   fi
 986   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 987    [Define to path to circo program if found or 'echo circo' otherwise])
 988 fi
 989 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 990 if test "$GV" != "echo gv" ; then
 991   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 992   dnl If we're targeting for mingw we should emit windows paths, not msys
 993   if test "$llvm_cv_os_type" = "MingW" ; then
 994     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 995   fi
 996   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 997    [Define to path to gv program if found or 'echo gv' otherwise])
 998 fi
 999 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1000 if test "$DOTTY" != "echo dotty" ; then
1001   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1002   dnl If we're targeting for mingw we should emit windows paths, not msys
1003   if test "$llvm_cv_os_type" = "MingW" ; then
1004     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1005   fi
1006   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1007    [Define to path to dotty program if found or 'echo dotty' otherwise])
1008 fi
1009 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1010 if test "$XDOT_PY" != "echo xdot.py" ; then
1011   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1012   dnl If we're targeting for mingw we should emit windows paths, not msys
1013   if test "$llvm_cv_os_type" = "MingW" ; then
1014     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1015   fi
1016   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1017    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1018 fi
1019
1020 dnl Look for a sufficiently recent version of Perl.
1021 LLVM_PROG_PERL([5.006])
1022 AC_SUBST(PERL)
1023 if test x"$PERL" = xnone; then
1024    AC_SUBST(HAVE_PERL,0)
1025    AC_MSG_ERROR([perl is required but was not found, please install it])
1026 else
1027    AC_SUBST(HAVE_PERL,1)
1028 fi
1029
1030 dnl Find the install program
1031 AC_PROG_INSTALL
1032 dnl Prepend src dir to install path dir if it's a relative path
1033 dnl This is a hack for installs that take place in something other
1034 dnl than the top level.
1035 case "$INSTALL" in
1036  [[\\/$]]* | ?:[[\\/]]* ) ;;
1037  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1038 esac
1039
1040 dnl Checks for documentation and testing tools that we can do without. If these
1041 dnl are not found then they are set to "true" which always succeeds but does
1042 dnl nothing. This just lets the build output show that we could have done
1043 dnl something if the tool was available.
1044 AC_PATH_PROG(BZIP2, [bzip2])
1045 AC_PATH_PROG(CAT, [cat])
1046 AC_PATH_PROG(DOXYGEN, [doxygen])
1047 AC_PATH_PROG(GROFF, [groff])
1048 AC_PATH_PROG(GZIP, [gzip])
1049 AC_PATH_PROG(POD2HTML, [pod2html])
1050 AC_PATH_PROG(POD2MAN, [pod2man])
1051 AC_PATH_PROG(PDFROFF, [pdfroff])
1052 AC_PATH_PROG(RUNTEST, [runtest])
1053 DJ_AC_PATH_TCLSH
1054 AC_PATH_PROG(ZIP, [zip])
1055 AC_PATH_PROGS(OCAMLC, [ocamlc])
1056 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1057 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1058 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1059 AC_PATH_PROGS(GAS, [gas as])
1060
1061 dnl Get the version of the linker in use.
1062 AC_LINK_GET_VERSION
1063
1064 dnl Determine whether the linker supports the -R option.
1065 AC_LINK_USE_R
1066
1067 dnl Determine whether the linker supports the -export-dynamic option.
1068 AC_LINK_EXPORT_DYNAMIC
1069
1070 dnl Determine whether the linker supports the --version-script option.
1071 AC_LINK_VERSION_SCRIPT
1072
1073 dnl Check for libtool and the library that has dlopen function (which must come
1074 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1075 dnl libtool).
1076 AC_LIBTOOL_DLOPEN
1077 AC_LIB_LTDL
1078
1079 if test "$WITH_LLVMGCCDIR" = "default" ; then
1080   LLVMGCC="llvm-gcc${EXEEXT}"
1081   LLVMGXX="llvm-g++${EXEEXT}"
1082   LLVMGCCCOMMAND="$LLVMGCC"
1083   LLVMGXXCOMMAND="$LLVMGXX"
1084   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1085   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1086   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
1087   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
1088 else
1089   if test -z "$LLVMGCC"; then
1090     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
1091     LLVMGCCCOMMAND="$LLVMGCC"
1092   fi
1093   if test -z "$LLVMGXX"; then
1094     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1095     LLVMGXXCOMMAND="$LLVMGXX"
1096   fi
1097
1098   AC_SUBST(LLVMGCC,$LLVMGCC)
1099   AC_SUBST(LLVMGXX,$LLVMGXX)
1100   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1101   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1102 fi
1103
1104 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1105 dnl found, otherwise clang if available.
1106 AC_ARG_WITH(llvmcc,
1107   AS_HELP_STRING([--with-llvmcc=<name>],
1108     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1109     [],[with_llvmcc=check])
1110 AC_MSG_CHECKING([LLVM capable compiler])
1111 if test "$with_llvmcc" != "check"; then
1112    if (test "$with_llvmcc" != "llvm-gcc" &&
1113        test "$with_llvmcc" != "clang" &&
1114        test "$with_llvmcc" != "none"); then
1115       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1116    fi
1117    WITH_LLVMCC="$with_llvmcc"
1118 elif test -n "$LLVMGCC"; then
1119    WITH_LLVMCC=llvm-gcc
1120 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1121    WITH_LLVMCC=clang
1122 else
1123    WITH_LLVMCC=none
1124 fi
1125 AC_MSG_RESULT([$WITH_LLVMCC])
1126 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1127
1128 AC_MSG_CHECKING([tool compatibility])
1129
1130 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1131 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1132 dnl to support those options.
1133 dnl "icc" emits gcc signatures
1134 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1135 ICC=no
1136 IXX=no
1137 case $CC in
1138   icc*|icpc*)
1139     ICC=yes
1140     IXX=yes
1141     ;;
1142    *)
1143     ;;
1144 esac
1145
1146 if test "$GCC" != "yes" && test "$ICC" != "yes"
1147 then
1148   AC_MSG_ERROR([gcc|icc required but not found])
1149 fi
1150
1151 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
1152 if test "$GXX" != "yes" && test "$IXX" != "yes"
1153 then
1154   AC_MSG_ERROR([g++|icc required but not found])
1155 fi
1156
1157 dnl Verify that GCC is version 3.0 or higher
1158 if test "$GCC" = "yes"
1159 then
1160   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1161 #error Unsupported GCC version
1162 #endif
1163 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1164 fi
1165
1166 dnl Check for GNU Make.  We use its extensions, so don't build without it
1167 if test -z "$llvm_cv_gnu_make_command"
1168 then
1169   AC_MSG_ERROR([GNU Make required but not found])
1170 fi
1171
1172 dnl Tool compatibility is okay if we make it here.
1173 AC_MSG_RESULT([ok])
1174
1175 dnl Check optional compiler flags.
1176 AC_MSG_CHECKING([optional compiler flags])
1177 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1178 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1179 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1180
1181 dnl===-----------------------------------------------------------------------===
1182 dnl===
1183 dnl=== SECTION 5: Check for libraries
1184 dnl===
1185 dnl===-----------------------------------------------------------------------===
1186
1187 AC_CHECK_LIB(m,sin)
1188 if test "$llvm_cv_os_type" = "MingW" ; then
1189   AC_CHECK_LIB(imagehlp, main)
1190   AC_CHECK_LIB(psapi, main)
1191 fi
1192
1193 dnl dlopen() is required for plugin support.
1194 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1195                [Define if dlopen() is available on this platform.]),
1196                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1197
1198 dnl libffi is optional; used to call external functions from the interpreter
1199 if test "$llvm_cv_enable_libffi" = "yes" ; then
1200   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1201                  [Define if libffi is available on this platform.]),
1202                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1203 fi
1204
1205 dnl mallinfo is optional; the code can compile (minus features) without it
1206 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1207                [Define if mallinfo() is available on this platform.]))
1208
1209 dnl pthread locking functions are optional - but llvm will not be thread-safe
1210 dnl without locks.
1211 if test "$ENABLE_THREADS" -eq 1 ; then
1212   AC_CHECK_LIB(pthread, pthread_mutex_init)
1213   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1214                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1215                            [Have pthread_mutex_lock]))
1216   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1217                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1218                  [Have pthread_rwlock_init]))
1219   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1220                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1221                  [Have pthread_getspecific]))
1222 fi
1223
1224 dnl Allow extra x86-disassembler library
1225 AC_ARG_WITH(udis86,
1226   AS_HELP_STRING([--with-udis86=<path>],
1227     [Use udis86 external x86 disassembler library]),
1228     [
1229       AC_SUBST(USE_UDIS86, [1])
1230       case "$withval" in
1231         /usr/lib|yes) ;;
1232         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1233       esac
1234       AC_CHECK_LIB(udis86, ud_init, [], [
1235         echo "Error! You need to have libudis86 around."
1236         exit -1
1237       ])
1238     ],
1239     AC_SUBST(USE_UDIS86, [0]))
1240 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1241                    [Define if use udis86 library])
1242
1243 dnl Allow OProfile support for JIT output.
1244 AC_ARG_WITH(oprofile,
1245   AS_HELP_STRING([--with-oprofile=<prefix>],
1246     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1247     [
1248       AC_SUBST(USE_OPROFILE, [1])
1249       case "$withval" in
1250         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1251         no) llvm_cv_oppath=
1252             AC_SUBST(USE_OPROFILE, [0]) ;;
1253         *) llvm_cv_oppath="${withval}/lib/oprofile"
1254            CPPFLAGS="-I${withval}/include";;
1255       esac
1256       if test -n "$llvm_cv_oppath" ; then
1257         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1258         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1259         dnl libbfd is not included properly in libopagent in some Debian
1260         dnl versions.  If libbfd isn't found at all, we assume opagent works
1261         dnl anyway.
1262         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1263         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1264           echo "Error! You need to have libopagent around."
1265           exit -1
1266         ])
1267         AC_CHECK_HEADER([opagent.h], [], [
1268           echo "Error! You need to have opagent.h around."
1269           exit -1
1270           ])
1271       fi
1272     ],
1273     [
1274       AC_SUBST(USE_OPROFILE, [0])
1275     ])
1276 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1277                    [Define if we have the oprofile JIT-support library])
1278
1279 dnl===-----------------------------------------------------------------------===
1280 dnl===
1281 dnl=== SECTION 6: Check for header files
1282 dnl===
1283 dnl===-----------------------------------------------------------------------===
1284
1285 dnl First, use autoconf provided macros for specific headers that we need
1286 dnl We don't check for ancient stuff or things that are guaranteed to be there
1287 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1288 dnl Generally we're looking for POSIX headers.
1289 AC_HEADER_DIRENT
1290 AC_HEADER_MMAP_ANONYMOUS
1291 AC_HEADER_STAT
1292 AC_HEADER_STDC
1293 AC_HEADER_SYS_WAIT
1294 AC_HEADER_TIME
1295
1296 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1297 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1298 AC_CHECK_HEADERS([utime.h windows.h])
1299 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1300 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1301 AC_CHECK_HEADERS([valgrind/valgrind.h])
1302 AC_CHECK_HEADERS([fenv.h])
1303 if test "$ENABLE_THREADS" -eq 1 ; then
1304   AC_CHECK_HEADERS(pthread.h,
1305                    AC_SUBST(HAVE_PTHREAD, 1),
1306                    AC_SUBST(HAVE_PTHREAD, 0))
1307 else
1308   AC_SUBST(HAVE_PTHREAD, 0)
1309 fi
1310
1311 dnl Try to find ffi.h.
1312 if test "$llvm_cv_enable_libffi" = "yes" ; then
1313   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1314 fi
1315
1316 dnl Try to find Darwin specific crash reporting library.
1317 AC_CHECK_HEADERS([CrashReporterClient.h])
1318
1319 dnl===-----------------------------------------------------------------------===
1320 dnl===
1321 dnl=== SECTION 7: Check for types and structures
1322 dnl===
1323 dnl===-----------------------------------------------------------------------===
1324
1325 AC_HUGE_VAL_CHECK
1326 AC_TYPE_PID_T
1327 AC_TYPE_SIZE_T
1328 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1329 AC_STRUCT_TM
1330 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1331 AC_CHECK_TYPES([uint64_t],,
1332          AC_CHECK_TYPES([u_int64_t],,
1333          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1334
1335 dnl===-----------------------------------------------------------------------===
1336 dnl===
1337 dnl=== SECTION 8: Check for specific functions needed
1338 dnl===
1339 dnl===-----------------------------------------------------------------------===
1340
1341 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1342 AC_CHECK_FUNCS([powf fmodf strtof round ])
1343 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1344 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1345 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1346 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1347 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1348 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1349 AC_C_PRINTF_A
1350 AC_FUNC_RAND48
1351
1352 dnl Check for variations in the Standard C++ library and STL. These macros are
1353 dnl provided by LLVM in the autoconf/m4 directory.
1354 AC_FUNC_ISNAN
1355 AC_FUNC_ISINF
1356
1357 dnl Check for mmap support.We also need to know if /dev/zero is required to
1358 dnl be opened for allocating RWX memory.
1359 dnl Make sure we aren't attempting to configure for an unknown system
1360 if test "$llvm_cv_platform_type" = "Unix" ; then
1361   AC_FUNC_MMAP
1362   AC_FUNC_MMAP_FILE
1363   AC_NEED_DEV_ZERO_FOR_MMAP
1364
1365   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1366   then
1367     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1368   fi
1369   if test "$ac_cv_func_mmap_file" = "no"
1370   then
1371     AC_MSG_WARN([mmap() of files required but not found])
1372   fi
1373 fi
1374
1375 dnl atomic builtins are required for threading support.
1376 AC_MSG_CHECKING(for GCC atomic builtins)
1377 dnl Since we'll be using these atomic builtins in C++ files we should test
1378 dnl the C++ compiler.
1379 AC_LANG_PUSH([C++])
1380 AC_LINK_IFELSE(
1381   AC_LANG_SOURCE(
1382     [[int main() {
1383         volatile unsigned long val = 1;
1384         __sync_synchronize();
1385         __sync_val_compare_and_swap(&val, 1, 0);
1386         __sync_add_and_fetch(&val, 1);
1387         __sync_sub_and_fetch(&val, 1);
1388         return 0;
1389       }
1390     ]]),
1391   AC_LANG_POP([C++])
1392   AC_MSG_RESULT(yes)
1393   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1394   AC_MSG_RESULT(no)
1395   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1396   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1397
1398 dnl===-----------------------------------------------------------------------===
1399 dnl===
1400 dnl=== SECTION 9: Additional checks, variables, etc.
1401 dnl===
1402 dnl===-----------------------------------------------------------------------===
1403
1404 dnl Handle 32-bit linux systems running a 64-bit kernel.
1405 dnl This has to come after section 4 because it invokes the compiler.
1406 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1407   AC_IS_LINUX_MIXED
1408   if test "$llvm_cv_linux_mixed" = "yes"; then
1409     llvm_cv_target_arch="x86"
1410     ARCH="x86"
1411   fi
1412 fi
1413
1414 dnl Check, whether __dso_handle is present
1415 AC_CHECK_FUNCS([__dso_handle])
1416
1417 dnl See if the llvm-gcc executable can compile to LLVM assembly
1418 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1419 [llvm_cv_llvmgcc_sanity="no"
1420 if test -x "$LLVMGCC" ; then
1421   cp /dev/null conftest.c
1422   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1423       grep 'target datalayout =' > /dev/null 2>&1
1424   if test $? -eq 0 ; then
1425     llvm_cv_llvmgcc_sanity="yes"
1426   fi
1427   rm conftest.c
1428 fi])
1429
1430 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1431 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1432   AC_MSG_CHECKING([llvm-gcc component support])
1433   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1434   AC_SUBST(LLVMCC1,$llvmcc1path)
1435   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1436   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1437   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1438   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1439   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1440   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1441   AC_MSG_RESULT([ok])
1442 fi
1443
1444 dnl Propagate the shared library extension that the libltdl checks did to
1445 dnl the Makefiles so we can use it there too
1446 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1447
1448 dnl Propagate the run-time library path variable that the libltdl
1449 dnl checks found to the Makefiles so we can use it there too
1450 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1451
1452 # Translate the various configuration directories and other basic
1453 # information into substitutions that will end up in Makefile.config.in
1454 # that these configured values can be used by the makefiles
1455 if test "${prefix}" = "NONE" ; then
1456   prefix="/usr/local"
1457 fi
1458 eval LLVM_PREFIX="${prefix}";
1459 eval LLVM_BINDIR="${prefix}/bin";
1460 eval LLVM_LIBDIR="${prefix}/lib";
1461 eval LLVM_DATADIR="${prefix}/share/llvm";
1462 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1463 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1464 eval LLVM_INCLUDEDIR="${prefix}/include";
1465 eval LLVM_INFODIR="${prefix}/info";
1466 eval LLVM_MANDIR="${prefix}/man";
1467 LLVM_CONFIGTIME=`date`
1468 AC_SUBST(LLVM_PREFIX)
1469 AC_SUBST(LLVM_BINDIR)
1470 AC_SUBST(LLVM_LIBDIR)
1471 AC_SUBST(LLVM_DATADIR)
1472 AC_SUBST(LLVM_DOCSDIR)
1473 AC_SUBST(LLVM_ETCDIR)
1474 AC_SUBST(LLVM_INCLUDEDIR)
1475 AC_SUBST(LLVM_INFODIR)
1476 AC_SUBST(LLVM_MANDIR)
1477 AC_SUBST(LLVM_CONFIGTIME)
1478
1479 # Place the various directores into the config.h file as #defines so that we
1480 # can know about the installation paths within LLVM.
1481 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1482                    [Installation prefix directory])
1483 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1484                    [Installation directory for binary executables])
1485 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1486                    [Installation directory for libraries])
1487 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1488                    [Installation directory for data files])
1489 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1490                    [Installation directory for documentation])
1491 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1492                    [Installation directory for config files])
1493 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1494                    [Installation directory for include files])
1495 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1496                    [Installation directory for .info files])
1497 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1498                    [Installation directory for man pages])
1499 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1500                    [Time at which LLVM was configured])
1501 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1502                    [Host triple we were built on])
1503
1504 # Determine which bindings to build.
1505 if test "$BINDINGS_TO_BUILD" = auto ; then
1506   BINDINGS_TO_BUILD=""
1507   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1508     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1509   fi
1510 fi
1511 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1512
1513 # This isn't really configurey, but it avoids having to repeat the list in
1514 # other files.
1515 AC_SUBST(ALL_BINDINGS,ocaml)
1516
1517 # Do any work necessary to ensure that bindings have what they need.
1518 binding_prereqs_failed=0
1519 for a_binding in $BINDINGS_TO_BUILD ; do
1520   case "$a_binding" in
1521   ocaml)
1522     if test "x$OCAMLC" = x ; then
1523       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1524       binding_prereqs_failed=1
1525     fi
1526     if test "x$OCAMLDEP" = x ; then
1527       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1528       binding_prereqs_failed=1
1529     fi
1530     if test "x$OCAMLOPT" = x ; then
1531       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1532       dnl ocamlopt is optional!
1533     fi
1534     if test "x$with_ocaml_libdir" != xauto ; then
1535       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1536     else
1537       ocaml_stdlib="`"$OCAMLC" -where`"
1538       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1539       then
1540         # ocaml stdlib is beneath our prefix; use stdlib
1541         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1542       else
1543         # ocaml stdlib is outside our prefix; use libdir/ocaml
1544         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1545       fi
1546     fi
1547     ;;
1548   esac
1549 done
1550 if test "$binding_prereqs_failed" = 1 ; then
1551   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1552 fi
1553
1554 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1555 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1556
1557 dnl Determine linker rpath flag
1558 if test "$llvm_cv_link_use_r" = "yes" ; then
1559   RPATH="-Wl,-R"
1560 else
1561   RPATH="-Wl,-rpath"
1562 fi
1563 AC_SUBST(RPATH)
1564
1565 dnl Determine linker rdynamic flag
1566 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1567   RDYNAMIC="-Wl,-export-dynamic"
1568 else
1569   RDYNAMIC=""
1570 fi
1571 AC_SUBST(RDYNAMIC)
1572
1573 dnl===-----------------------------------------------------------------------===
1574 dnl===
1575 dnl=== SECTION 10: Specify the output files and generate it
1576 dnl===
1577 dnl===-----------------------------------------------------------------------===
1578
1579 dnl Configure header files
1580 dnl WARNING: dnl If you add or remove any of the following config headers, then
1581 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1582 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1583 dnl files can be updated automatically when their *.in sources change.
1584 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1585 AH_TOP([#ifndef CONFIG_H
1586 #define CONFIG_H])
1587 AH_BOTTOM([#endif])
1588
1589 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1590 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1591 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1592 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1593 AC_CONFIG_HEADERS([include/llvm/System/DataTypes.h])
1594
1595 dnl Configure the makefile's configuration data
1596 AC_CONFIG_FILES([Makefile.config])
1597
1598 dnl Configure the RPM spec file for LLVM
1599 AC_CONFIG_FILES([llvm.spec])
1600
1601 dnl Configure llvmc's Base plugin
1602 AC_CONFIG_FILES([tools/llvmc/src/Base.td])
1603
1604 dnl Do the first stage of configuration for llvm-config.in.
1605 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1606
1607 dnl Do special configuration of Makefiles
1608 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1609 AC_CONFIG_MAKEFILE(Makefile)
1610 AC_CONFIG_MAKEFILE(Makefile.common)
1611 AC_CONFIG_MAKEFILE(examples/Makefile)
1612 AC_CONFIG_MAKEFILE(lib/Makefile)
1613 AC_CONFIG_MAKEFILE(runtime/Makefile)
1614 AC_CONFIG_MAKEFILE(test/Makefile)
1615 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1616 AC_CONFIG_MAKEFILE(unittests/Makefile)
1617 AC_CONFIG_MAKEFILE(tools/Makefile)
1618 AC_CONFIG_MAKEFILE(utils/Makefile)
1619 AC_CONFIG_MAKEFILE(projects/Makefile)
1620 AC_CONFIG_MAKEFILE(bindings/Makefile)
1621 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1622
1623 dnl Finally, crank out the output
1624 AC_OUTPUT