autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.8svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65
  66 dnl
  67 dnl One tricky part of doing this is that some projects depend upon other
  68 dnl projects.  For example, several projects rely upon the LLVM test suite.
  69 dnl We want to configure those projects first so that their object trees are
  70 dnl created before running the configure scripts of projects that depend upon
  71 dnl them.
  72 dnl
  73
  74 dnl Several projects use llvm-gcc, so configure that first
  75 if test -d ${srcdir}/projects/llvm-gcc ; then
  76   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  77 fi
  78
  79 dnl Several projects use the LLVM test suite, so configure it next.
  80 if test -d ${srcdir}/projects/test-suite ; then
  81   AC_CONFIG_SUBDIRS([projects/test-suite])
  82 fi
  83
  84 dnl llvm-test is the old name of the test-suite, kept here for backwards
  85 dnl compatibility
  86 if test -d ${srcdir}/projects/llvm-test ; then
  87   AC_CONFIG_SUBDIRS([projects/llvm-test])
  88 fi
  89
  90 dnl Some projects use poolalloc; configure that next
  91 if test -d ${srcdir}/projects/poolalloc ; then
  92   AC_CONFIG_SUBDIRS([projects/poolalloc])
  93 fi
  94
  95 if test -d ${srcdir}/projects/llvm-poolalloc ; then
  96   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
  97 fi
  98
  99 dnl Check for all other projects
 100 for i in `ls ${srcdir}/projects`
 101 do
 102   if test -d ${srcdir}/projects/${i} ; then
 103     case ${i} in
 104       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 105       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 106       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 107       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 108       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 109       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 110       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 111       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 112       llvm-gcc)       ;;
 113       test-suite)     ;;
 114       llvm-test)      ;;
 115       poolalloc)      ;;
 116       llvm-poolalloc) ;;
 117       *)
 118         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 119         ;;
 120     esac
 121   fi
 122 done
 123
 124 dnl===-----------------------------------------------------------------------===
 125 dnl===
 126 dnl=== SECTION 2: Architecture, target, and host checks
 127 dnl===
 128 dnl===-----------------------------------------------------------------------===
 129
 130 dnl Check the target for which we're compiling and the host that will do the
 131 dnl compilations. This will tell us which LLVM compiler will be used for
 132 dnl compiling SSA into object code. This needs to be done early because
 133 dnl following tests depend on it.
 134 AC_CANONICAL_TARGET
 135
 136 dnl Determine the platform type and cache its value. This helps us configure
 137 dnl the System library to the correct build platform.
 138 AC_CACHE_CHECK([type of operating system we're going to host on],
 139                [llvm_cv_os_type],
 140 [case $host in
 141   *-*-aix*)
 142     llvm_cv_link_all_option="-Wl,--whole-archive"
 143     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 144     llvm_cv_os_type="AIX"
 145     llvm_cv_platform_type="Unix" ;;
 146   *-*-irix*)
 147     llvm_cv_link_all_option="-Wl,--whole-archive"
 148     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 149     llvm_cv_os_type="IRIX"
 150     llvm_cv_platform_type="Unix" ;;
 151   *-*-cygwin*)
 152     llvm_cv_link_all_option="-Wl,--whole-archive"
 153     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 154     llvm_cv_os_type="Cygwin"
 155     llvm_cv_platform_type="Unix" ;;
 156   *-*-darwin*)
 157     llvm_cv_link_all_option="-Wl,-all_load"
 158     llvm_cv_no_link_all_option="-Wl,-noall_load"
 159     llvm_cv_os_type="Darwin"
 160     llvm_cv_platform_type="Unix" ;;
 161   *-*-minix*)
 162     llvm_cv_link_all_option="-Wl,-all_load"
 163     llvm_cv_no_link_all_option="-Wl,-noall_load"
 164     llvm_cv_os_type="Minix"
 165     llvm_cv_platform_type="Unix" ;;
 166   *-*-freebsd*)
 167     llvm_cv_link_all_option="-Wl,--whole-archive"
 168     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 169     llvm_cv_os_type="FreeBSD"
 170     llvm_cv_platform_type="Unix" ;;
 171   *-*-openbsd*)
 172     llvm_cv_link_all_option="-Wl,--whole-archive"
 173     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 174     llvm_cv_os_type="OpenBSD"
 175     llvm_cv_platform_type="Unix" ;;
 176   *-*-netbsd*)
 177     llvm_cv_link_all_option="-Wl,--whole-archive"
 178     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 179     llvm_cv_os_type="NetBSD"
 180     llvm_cv_platform_type="Unix" ;;
 181   *-*-dragonfly*)
 182     llvm_cv_link_all_option="-Wl,--whole-archive"
 183     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 184     llvm_cv_os_type="DragonFly"
 185     llvm_cv_platform_type="Unix" ;;
 186   *-*-hpux*)
 187     llvm_cv_link_all_option="-Wl,--whole-archive"
 188     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 189     llvm_cv_os_type="HP-UX"
 190     llvm_cv_platform_type="Unix" ;;
 191   *-*-interix*)
 192     llvm_cv_link_all_option="-Wl,--whole-archive"
 193     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 194     llvm_cv_os_type="Interix"
 195     llvm_cv_platform_type="Unix" ;;
 196   *-*-linux*)
 197     llvm_cv_link_all_option="-Wl,--whole-archive"
 198     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 199     llvm_cv_os_type="Linux"
 200     llvm_cv_platform_type="Unix" ;;
 201   *-*-solaris*)
 202     llvm_cv_link_all_option="-Wl,-z,allextract"
 203     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 204     llvm_cv_os_type="SunOS"
 205     llvm_cv_platform_type="Unix" ;;
 206   *-*-auroraux*)
 207     llvm_cv_link_all_option="-Wl,-z,allextract"
 208     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 209     llvm_cv_os_type="AuroraUX"
 210     llvm_cv_platform_type="Unix" ;;
 211   *-*-win32*)
 212     llvm_cv_link_all_option="-Wl,--whole-archive"
 213     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 214     llvm_cv_os_type="Win32"
 215     llvm_cv_platform_type="Win32" ;;
 216   *-*-mingw*)
 217     llvm_cv_link_all_option="-Wl,--whole-archive"
 218     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 219     llvm_cv_os_type="MingW"
 220     llvm_cv_platform_type="Win32" ;;
 221   *-*-haiku*)
 222     llvm_cv_link_all_option="-Wl,--whole-archive"
 223     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 224     llvm_cv_os_type="Haiku"
 225     llvm_cv_platform_type="Unix" ;;
 226   *-unknown-eabi*)
 227     llvm_cv_link_all_option="-Wl,--whole-archive"
 228     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 229     llvm_cv_os_type="Freestanding"
 230     llvm_cv_platform_type="Unix" ;;
 231   *-unknown-elf*)
 232     llvm_cv_link_all_option="-Wl,--whole-archive"
 233     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 234     llvm_cv_os_type="Freestanding"
 235     llvm_cv_platform_type="Unix" ;;
 236   *)
 237     llvm_cv_link_all_option=""
 238     llvm_cv_no_link_all_option=""
 239     llvm_cv_os_type="Unknown"
 240     llvm_cv_platform_type="Unknown" ;;
 241 esac])
 242
 243 AC_CACHE_CHECK([type of operating system we're going to target],
 244                [llvm_cv_target_os_type],
 245 [case $target in
 246   *-*-aix*)
 247     llvm_cv_target_os_type="AIX" ;;
 248   *-*-irix*)
 249     llvm_cv_target_os_type="IRIX" ;;
 250   *-*-cygwin*)
 251     llvm_cv_target_os_type="Cygwin" ;;
 252   *-*-darwin*)
 253     llvm_cv_target_os_type="Darwin" ;;
 254   *-*-minix*)
 255     llvm_cv_target_os_type="Minix" ;;
 256   *-*-freebsd*)
 257     llvm_cv_target_os_type="FreeBSD" ;;
 258   *-*-openbsd*)
 259     llvm_cv_target_os_type="OpenBSD" ;;
 260   *-*-netbsd*)
 261     llvm_cv_target_os_type="NetBSD" ;;
 262   *-*-dragonfly*)
 263     llvm_cv_target_os_type="DragonFly" ;;
 264   *-*-hpux*)
 265     llvm_cv_target_os_type="HP-UX" ;;
 266   *-*-interix*)
 267     llvm_cv_target_os_type="Interix" ;;
 268   *-*-linux*)
 269     llvm_cv_target_os_type="Linux" ;;
 270   *-*-solaris*)
 271     llvm_cv_target_os_type="SunOS" ;;
 272   *-*-auroraux*)
 273     llvm_cv_target_os_type="AuroraUX" ;;
 274   *-*-win32*)
 275     llvm_cv_target_os_type="Win32" ;;
 276   *-*-mingw*)
 277     llvm_cv_target_os_type="MingW" ;;
 278   *-*-haiku*)
 279     llvm_cv_target_os_type="Haiku" ;;
 280   *-unknown-eabi*)
 281     llvm_cv_target_os_type="Freestanding" ;;
 282   *)
 283     llvm_cv_target_os_type="Unknown" ;;
 284 esac])
 285
 286 dnl Make sure we aren't attempting to configure for an unknown system
 287 if test "$llvm_cv_os_type" = "Unknown" ; then
 288   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 289 fi
 290
 291 dnl Set the "OS" Makefile variable based on the platform type so the
 292 dnl makefile can configure itself to specific build hosts
 293 AC_SUBST(OS,$llvm_cv_os_type)
 294 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 295 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 296
 297 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 298 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 299 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 300
 301 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 302 dnl This is used by lib/System to determine the basic kind of implementation
 303 dnl to use.
 304 case $llvm_cv_platform_type in
 305   Unix)
 306     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 307     AC_SUBST(LLVM_ON_UNIX,[1])
 308     AC_SUBST(LLVM_ON_WIN32,[0])
 309     ;;
 310   Win32)
 311     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 312     AC_SUBST(LLVM_ON_UNIX,[0])
 313     AC_SUBST(LLVM_ON_WIN32,[1])
 314     ;;
 315 esac
 316
 317 dnl Determine what our target architecture is and configure accordingly.
 318 dnl This will allow Makefiles to make a distinction between the hardware and
 319 dnl the OS.
 320 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 321 [case $target in
 322   i?86-*)                 llvm_cv_target_arch="x86" ;;
 323   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 324   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 325   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 326   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 327   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 328   mips-*)                 llvm_cv_target_arch="Mips" ;;
 329   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 330   xcore-*)                llvm_cv_target_arch="XCore" ;;
 331   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 332   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 333   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 334   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 335   *)                      llvm_cv_target_arch="Unknown" ;;
 336 esac])
 337
 338 if test "$llvm_cv_target_arch" = "Unknown" ; then
 339   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 340 fi
 341
 342 # Determine the LLVM native architecture for the target
 343 case "$llvm_cv_target_arch" in
 344     x86)     LLVM_NATIVE_ARCH="X86" ;;
 345     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 346     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 347 esac
 348
 349 dnl Define a substitution, ARCH, for the target architecture
 350 AC_SUBST(ARCH,$llvm_cv_target_arch)
 351
 352 dnl Check for the endianness of the target
 353 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 354
 355 dnl Check for build platform executable suffix if we're crosscompiling
 356 if test "$cross_compiling" = yes; then
 357   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 358   AC_BUILD_EXEEXT
 359   ac_build_prefix=${build_alias}-
 360   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 361   if test -z "$BUILD_CXX"; then
 362      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 363      if test -z "$BUILD_CXX"; then
 364        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 365      fi
 366   fi
 367 else
 368   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 369 fi
 370
 371 dnl Check to see if there's a .svn or .git directory indicating that this
 372 dnl build is being done from a checkout. This sets up several defaults for
 373 dnl the command line switches. When we build with a checkout directory,
 374 dnl we get a debug with assertions turned on. Without, we assume a source
 375 dnl release and we get an optimized build without assertions.
 376 dnl See --enable-optimized and --enable-assertions below
 377 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 378   cvsbuild="yes"
 379   optimize="no"
 380   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 381 else
 382   cvsbuild="no"
 383   optimize="yes"
 384 fi
 385
 386 dnl===-----------------------------------------------------------------------===
 387 dnl===
 388 dnl=== SECTION 3: Command line arguments for the configure script.
 389 dnl===
 390 dnl===-----------------------------------------------------------------------===
 391
 392 dnl --enable-optimized : check whether they want to do an optimized build:
 393 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 394  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 395 if test ${enableval} = "no" ; then
 396   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 397 else
 398   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 399 fi
 400
 401 dnl --enable-profiling : check whether they want to do a profile build:
 402 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 403  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 404 if test ${enableval} = "no" ; then
 405   AC_SUBST(ENABLE_PROFILING,[[]])
 406 else
 407   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 408 fi
 409
 410 dnl --enable-assertions : check whether they want to turn on assertions or not:
 411 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 412   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 413 if test ${enableval} = "yes" ; then
 414   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 415 else
 416   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 417 fi
 418
 419 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 420 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 421   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 422 if test ${enableval} = "yes" ; then
 423   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 424   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 425 else
 426   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 427   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 428 fi
 429
 430 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 431 AC_ARG_ENABLE(debug-runtime,
 432    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 433 if test ${enableval} = "no" ; then
 434   AC_SUBST(DEBUG_RUNTIME,[[]])
 435 else
 436   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 437 fi
 438
 439 dnl --enable-debug-symbols : should even optimized compiler libraries
 440 dnl have debug symbols?
 441 AC_ARG_ENABLE(debug-symbols,
 442    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 443 if test ${enableval} = "no" ; then
 444   AC_SUBST(DEBUG_SYMBOLS,[[]])
 445 else
 446   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 447 fi
 448
 449 dnl --enable-jit: check whether they want to enable the jit
 450 AC_ARG_ENABLE(jit,
 451   AS_HELP_STRING(--enable-jit,
 452                  [Enable Just In Time Compiling (default is YES)]),,
 453   enableval=default)
 454 if test ${enableval} = "no"
 455 then
 456   AC_SUBST(JIT,[[]])
 457 else
 458   case "$llvm_cv_target_arch" in
 459     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 460     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 461     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 462     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 463     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 464     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 465     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 466     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 467     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 468     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 469     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 470     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 471     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 472     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 473   esac
 474 fi
 475
 476 dnl Allow enablement of doxygen generated documentation
 477 AC_ARG_ENABLE(doxygen,
 478               AS_HELP_STRING([--enable-doxygen],
 479                              [Build doxygen documentation (default is NO)]),,
 480                              enableval=default)
 481 case "$enableval" in
 482   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 483   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 484   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 485   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 486 esac
 487
 488 dnl Allow disablement of threads
 489 AC_ARG_ENABLE(threads,
 490               AS_HELP_STRING([--enable-threads],
 491                              [Use threads if available (default is YES)]),,
 492                              enableval=default)
 493 case "$enableval" in
 494   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 495   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 496   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 497   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 498 esac
 499 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 500
 501 dnl Allow building without position independent code
 502 AC_ARG_ENABLE(pic,
 503   AS_HELP_STRING([--enable-pic],
 504                  [Build LLVM with Position Independent Code (default is YES)]),,
 505                  enableval=default)
 506 case "$enableval" in
 507   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 508   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 509   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 510   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 511 esac
 512 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 513                    [Define if position independent code is enabled])
 514
 515 dnl Allow building a shared library and linking tools against it.
 516 AC_ARG_ENABLE(shared,
 517   AS_HELP_STRING([--enable-shared],
 518                  [Build a shared library and link tools against it (default is NO)]),,
 519                  enableval=default)
 520 case "$enableval" in
 521   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 522   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 523   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 524   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 525 esac
 526
 527 dnl Enable embedding timestamp information into build.
 528 AC_ARG_ENABLE(timestamps,
 529   AS_HELP_STRING([--enable-timestamps],
 530                  [Enable embedding timestamp information in build (default is YES)]),,
 531                  enableval=default)
 532 case "$enableval" in
 533   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 534   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 535   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 536   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 537 esac
 538 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 539                    [Define if timestamp information (e.g., __DATE___) is allowed])
 540
 541 dnl Allow specific targets to be specified for building (or not)
 542 TARGETS_TO_BUILD=""
 543 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 544     [Build specific host targets: all or target1,target2,... Valid targets are:
 545      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu, pic16,
 546      xcore, msp430, systemz, blackfin, cbe, msil, and cpp (default=all)]),,
 547     enableval=all)
 548 if test "$enableval" = host-only ; then
 549   enableval=host
 550 fi
 551 case "$enableval" in
 552   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend MSIL CppBackend MBlaze" ;;
 553   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 554       case "$a_target" in
 555         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 556         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 557         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 558         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 559         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 560         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 561         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 562         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 563         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 564         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 565         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 566         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 567         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 568         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 569         msil)     TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 570         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 571         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 572         host) case "$llvm_cv_target_arch" in
 573             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 574             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 575             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 576             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 577             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 578             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 579             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 580             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 581             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 582             PIC16)       TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 583             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 584             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 585             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 586             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 587             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 588           esac ;;
 589         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 590       esac
 591   done
 592   ;;
 593 esac
 594 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 595
 596 # Determine whether we are building LLVM support for the native architecture.
 597 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 598 for a_target in $TARGETS_TO_BUILD; do
 599   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 600     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 601     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCHNAME,$LLVM_NATIVE_ARCH,
 602       [Short LLVM architecture name for the native architecture, if available])
 603     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 604       [LLVM architecture name for the native architecture, if available])
 605   fi
 606 done
 607
 608 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 609 # target feature def files.
 610 LLVM_ENUM_TARGETS=""
 611 LLVM_ENUM_ASM_PRINTERS=""
 612 LLVM_ENUM_ASM_PARSERS=""
 613 LLVM_ENUM_DISASSEMBLERS=""
 614 for target_to_build in $TARGETS_TO_BUILD; do
 615   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 616   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 617     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 618   fi
 619   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 620     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 621   fi
 622   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 623     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 624   fi
 625 done
 626 AC_SUBST(LLVM_ENUM_TARGETS)
 627 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 628 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 629 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 630
 631 dnl Prevent the CBackend from using printf("%a") for floating point so older
 632 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 633 dnl can still compile the CBE's output
 634 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 635   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 636   enableval=default)
 637 case "$enableval" in
 638   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 639   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 640   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 641   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 642 esac
 643 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 644                    [Define if CBE is enabled for printf %a output])
 645
 646 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 647 AC_ARG_WITH(llvmgccdir,
 648   AS_HELP_STRING([--with-llvmgccdir],
 649     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 650     withval=default)
 651 case "$withval" in
 652   default) WITH_LLVMGCCDIR=default ;;
 653   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 654   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 655 esac
 656
 657 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 658 AC_ARG_WITH(llvmgcc,
 659   AS_HELP_STRING([--with-llvmgcc],
 660     [Specify location of llvm-gcc driver (default searches PATH)]),
 661     LLVMGCC=$with_llvmgcc
 662       WITH_LLVMGCCDIR="",)
 663
 664 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 665 AC_ARG_WITH(llvmgxx,
 666   AS_HELP_STRING([--with-llvmgxx],
 667     [Specify location of llvm-g++ driver (default searches PATH)]),
 668     LLVMGXX=$with_llvmgxx
 669     WITH_LLVMGCCDIR="",)
 670
 671 if test -n "$LLVMGCC"; then
 672    LLVMGCCCOMMAND="$LLVMGCC"
 673 fi
 674
 675 if test -n "$LLVMGXX"; then
 676    LLVMGXXCOMMAND="$LLVMGXX"
 677 fi
 678
 679 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 680    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 681 fi
 682
 683 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 684    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 685 fi
 686
 687 dnl Allow a specific Clang compiler to be used with this LLVM config.
 688 AC_ARG_WITH(clang,
 689   AS_HELP_STRING([--with-clang],
 690     [Specify location of clang compiler (default is --with-built-clang)]),
 691     [],[with_clang=default])
 692
 693 dnl Enable use of the built Clang.
 694 AC_ARG_WITH(built-clang,
 695   AS_HELP_STRING([--with-built-clang],
 696     [Use the compiled Clang as the LLVM compiler (default=check)]),
 697     [],[with_built_clang=check])
 698
 699 dnl Select the Clang compiler option.
 700 dnl
 701 dnl If --with-clang is given, always honor that; otherwise honor
 702 dnl --with-built-clang, or check if we have the clang sources.
 703 AC_MSG_CHECKING([clang compiler])
 704 WITH_CLANGPATH=""
 705 WITH_BUILT_CLANG=0
 706 if test "$with_clang" != "default"; then
 707    WITH_CLANGPATH="$with_clang"
 708    if ! test -x "$WITH_CLANGPATH"; then
 709      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 710    fi
 711 elif test "$with_built_clang" = "yes"; then
 712    WITH_BUILT_CLANG=1
 713 elif test "$with_built_clang" = "no"; then
 714    WITH_BUILT_CLANG=0
 715 else
 716    if test "$with_built_clang" != "check"; then
 717       AC_MSG_ERROR([invalid value for --with-built-clang.])
 718    fi
 719
 720    if test -f ${srcdir}/tools/clang/README.txt; then
 721      WITH_BUILT_CLANG=1
 722    fi
 723 fi
 724
 725 if ! test -z "$WITH_CLANGPATH"; then
 726    AC_MSG_RESULT([$WITH_CLANGPATH])
 727    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 728 elif test "$WITH_BUILT_CLANG" = "1"; then
 729    AC_MSG_RESULT([built])
 730 else
 731    AC_MSG_RESULT([none])
 732 fi
 733 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 734 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 735 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 736
 737 dnl Override the option to use for optimized builds.
 738 AC_ARG_WITH(optimize-option,
 739   AS_HELP_STRING([--with-optimize-option],
 740                  [Select the compiler options to use for optimized builds]),,
 741                  withval=default)
 742 AC_MSG_CHECKING([optimization flags])
 743 case "$withval" in
 744   default)
 745     case "$llvm_cv_os_type" in
 746     FreeBSD) optimize_option=-O2 ;;
 747     MingW) optimize_option=-O2 ;;
 748     *)     optimize_option=-O3 ;;
 749     esac ;;
 750   *) optimize_option="$withval" ;;
 751 esac
 752 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 753 AC_MSG_RESULT([$optimize_option])
 754
 755 dnl Specify extra build options
 756 AC_ARG_WITH(extra-options,
 757   AS_HELP_STRING([--with-extra-options],
 758                  [Specify additional options to compile LLVM with]),,
 759                  withval=default)
 760 case "$withval" in
 761   default) EXTRA_OPTIONS= ;;
 762   *) EXTRA_OPTIONS=$withval ;;
 763 esac
 764 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 765
 766 dnl Allow specific bindings to be specified for building (or not)
 767 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 768     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 769     enableval=default)
 770 BINDINGS_TO_BUILD=""
 771 case "$enableval" in
 772   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 773   all ) BINDINGS_TO_BUILD="ocaml" ;;
 774   none | no) BINDINGS_TO_BUILD="" ;;
 775   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 776       case "$a_binding" in
 777         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 778         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 779       esac
 780   done
 781   ;;
 782 esac
 783
 784 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 785 dnl script for bindings/ocaml/configure, except that its auto value depends on
 786 dnl OCAMLC, which is found here to support tests.
 787 AC_ARG_WITH([ocaml-libdir],
 788   [AS_HELP_STRING([--with-ocaml-libdir],
 789     [Specify install location for ocaml bindings (default is stdlib)])],
 790   [],
 791   [withval=auto])
 792 case "$withval" in
 793   auto) with_ocaml_libdir="$withval" ;;
 794   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 795   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 796 esac
 797
 798 AC_ARG_WITH(c-include-dirs,
 799   AS_HELP_STRING([--with-c-include-dirs],
 800     [Colon separated list of directories clang will search for headers]),,
 801     withval="")
 802 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 803                    [Directories clang will search for headers])
 804
 805 AC_ARG_WITH(cxx-include-root,
 806   AS_HELP_STRING([--with-cxx-include-root],
 807     [Directory with the libstdc++ headers.]),,
 808     withval="")
 809 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 810                    [Directory with the libstdc++ headers.])
 811
 812 AC_ARG_WITH(cxx-include-arch,
 813   AS_HELP_STRING([--with-cxx-include-arch],
 814     [Architecture of the libstdc++ headers.]),,
 815     withval="")
 816 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 817                    [Arch the libstdc++ headers.])
 818
 819 AC_ARG_WITH(cxx-include-32bit-dir,
 820   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 821     [32 bit multilib dir.]),,
 822     withval="")
 823 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 824                    [32 bit multilib directory.])
 825
 826 AC_ARG_WITH(cxx-include-64bit-dir,
 827   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 828     [64 bit multilib directory.]),,
 829     withval="")
 830 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 831                    [64 bit multilib directory.])
 832
 833 dnl Allow linking of LLVM with GPLv3 binutils code.
 834 AC_ARG_WITH(binutils-include,
 835   AS_HELP_STRING([--with-binutils-include],
 836     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 837   withval=default)
 838 case "$withval" in
 839   default) WITH_BINUTILS_INCDIR=default ;;
 840   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 841   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 842 esac
 843 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 844   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 845   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 846      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 847      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 848   fi
 849 fi
 850
 851 dnl --enable-libffi : check whether the user wants to turn off libffi:
 852 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 853   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 854   [case "$enableval" in
 855     yes) llvm_cv_enable_libffi="yes" ;;
 856     no)  llvm_cv_enable_libffi="no"  ;;
 857     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 858   esac],
 859   llvm_cv_enable_libffi=no)
 860
 861 dnl===-----------------------------------------------------------------------===
 862 dnl===
 863 dnl=== SECTION 4: Check for programs we need and that they are the right version
 864 dnl===
 865 dnl===-----------------------------------------------------------------------===
 866
 867 dnl Check for compilation tools
 868 AC_PROG_CPP
 869 AC_PROG_CC(gcc)
 870 AC_PROG_CXX(g++)
 871
 872 AC_PROG_NM
 873 AC_SUBST(NM)
 874
 875 dnl Check for the tools that the makefiles require
 876 AC_CHECK_GNU_MAKE
 877 AC_PROG_LN_S
 878 AC_PATH_PROG(CMP, [cmp], [cmp])
 879 AC_PATH_PROG(CP, [cp], [cp])
 880 AC_PATH_PROG(DATE, [date], [date])
 881 AC_PATH_PROG(FIND, [find], [find])
 882 AC_PATH_PROG(GREP, [grep], [grep])
 883 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 884 AC_PATH_PROG(MV,   [mv],   [mv])
 885 AC_PROG_RANLIB
 886 AC_CHECK_TOOL(AR, ar, false)
 887 AC_PATH_PROG(RM,   [rm],   [rm])
 888 AC_PATH_PROG(SED,  [sed],  [sed])
 889 AC_PATH_PROG(TAR,  [tar],  [gtar])
 890 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 891
 892 dnl Looking for misc. graph plotting software
 893 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 894 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 895   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 896   dnl If we're targeting for mingw we should emit windows paths, not msys
 897   if test "$llvm_cv_os_type" = "MingW" ; then
 898     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 899   fi
 900   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 901    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 902 fi
 903 AC_PATH_PROG(DOT, [dot], [echo dot])
 904 if test "$DOT" != "echo dot" ; then
 905   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 906   dnl If we're targeting for mingw we should emit windows paths, not msys
 907   if test "$llvm_cv_os_type" = "MingW" ; then
 908     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 909   fi
 910   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 911    [Define to path to dot program if found or 'echo dot' otherwise])
 912 fi
 913 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 914 if test "$FDP" != "echo fdp" ; then
 915   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 916   dnl If we're targeting for mingw we should emit windows paths, not msys
 917   if test "$llvm_cv_os_type" = "MingW" ; then
 918     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 919   fi
 920   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 921    [Define to path to fdp program if found or 'echo fdp' otherwise])
 922 fi
 923 AC_PATH_PROG(NEATO, [neato], [echo neato])
 924 if test "$NEATO" != "echo neato" ; then
 925   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 926   dnl If we're targeting for mingw we should emit windows paths, not msys
 927   if test "$llvm_cv_os_type" = "MingW" ; then
 928     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 929   fi
 930   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 931    [Define to path to neato program if found or 'echo neato' otherwise])
 932 fi
 933 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 934 if test "$TWOPI" != "echo twopi" ; then
 935   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 936   dnl If we're targeting for mingw we should emit windows paths, not msys
 937   if test "$llvm_cv_os_type" = "MingW" ; then
 938     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 939   fi
 940   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 941    [Define to path to twopi program if found or 'echo twopi' otherwise])
 942 fi
 943 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 944 if test "$CIRCO" != "echo circo" ; then
 945   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 946   dnl If we're targeting for mingw we should emit windows paths, not msys
 947   if test "$llvm_cv_os_type" = "MingW" ; then
 948     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 949   fi
 950   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 951    [Define to path to circo program if found or 'echo circo' otherwise])
 952 fi
 953 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 954 if test "$GV" != "echo gv" ; then
 955   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 956   dnl If we're targeting for mingw we should emit windows paths, not msys
 957   if test "$llvm_cv_os_type" = "MingW" ; then
 958     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 959   fi
 960   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 961    [Define to path to gv program if found or 'echo gv' otherwise])
 962 fi
 963 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 964 if test "$DOTTY" != "echo dotty" ; then
 965   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 966   dnl If we're targeting for mingw we should emit windows paths, not msys
 967   if test "$llvm_cv_os_type" = "MingW" ; then
 968     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 969   fi
 970   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 971    [Define to path to dotty program if found or 'echo dotty' otherwise])
 972 fi
 973
 974 dnl Look for a sufficiently recent version of Perl.
 975 LLVM_PROG_PERL([5.006])
 976 AC_SUBST(PERL)
 977 if test x"$PERL" = xnone; then
 978    AC_SUBST(HAVE_PERL,0)
 979    AC_MSG_ERROR([perl is required but was not found, please install it])
 980 else
 981    AC_SUBST(HAVE_PERL,1)
 982 fi
 983
 984 dnl Find the install program
 985 AC_PROG_INSTALL
 986 dnl Prepend src dir to install path dir if it's a relative path
 987 dnl This is a hack for installs that take place in something other
 988 dnl than the top level.
 989 case "$INSTALL" in
 990  [[\\/$]]* | ?:[[\\/]]* ) ;;
 991  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 992 esac
 993
 994 dnl Checks for documentation and testing tools that we can do without. If these
 995 dnl are not found then they are set to "true" which always succeeds but does
 996 dnl nothing. This just lets the build output show that we could have done
 997 dnl something if the tool was available.
 998 AC_PATH_PROG(BZIP2, [bzip2])
 999 AC_PATH_PROG(CAT, [cat])
1000 AC_PATH_PROG(DOXYGEN, [doxygen])
1001 AC_PATH_PROG(GROFF, [groff])
1002 AC_PATH_PROG(GZIP, [gzip])
1003 AC_PATH_PROG(POD2HTML, [pod2html])
1004 AC_PATH_PROG(POD2MAN, [pod2man])
1005 AC_PATH_PROG(PDFROFF, [pdfroff])
1006 AC_PATH_PROG(RUNTEST, [runtest])
1007 DJ_AC_PATH_TCLSH
1008 AC_PATH_PROG(ZIP, [zip])
1009 AC_PATH_PROGS(OCAMLC, [ocamlc])
1010 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1011 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1012 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1013 AC_PATH_PROGS(GAS, [gas as])
1014
1015 dnl Get the version of the linker in use.
1016 AC_LINK_GET_VERSION
1017
1018 dnl Determine whether the linker supports the -R option.
1019 AC_LINK_USE_R
1020
1021 dnl Determine whether the linker supports the -export-dynamic option.
1022 AC_LINK_EXPORT_DYNAMIC
1023
1024 dnl Determine whether the linker supports the --version-script option.
1025 AC_LINK_VERSION_SCRIPT
1026
1027 dnl Check for libtool and the library that has dlopen function (which must come
1028 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1029 dnl libtool).
1030 AC_LIBTOOL_DLOPEN
1031 AC_LIB_LTDL
1032
1033 if test "$WITH_LLVMGCCDIR" = "default" ; then
1034   LLVMGCC="llvm-gcc${EXEEXT}"
1035   LLVMGXX="llvm-g++${EXEEXT}"
1036   LLVMGCCCOMMAND="$LLVMGCC"
1037   LLVMGXXCOMMAND="$LLVMGXX"
1038   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1039   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1040   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
1041   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
1042 else
1043   if test -z "$LLVMGCC"; then
1044     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
1045     LLVMGCCCOMMAND="$LLVMGCC"
1046   fi
1047   if test -z "$LLVMGXX"; then
1048     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1049     LLVMGXXCOMMAND="$LLVMGXX"
1050   fi
1051
1052   AC_SUBST(LLVMGCC,$LLVMGCC)
1053   AC_SUBST(LLVMGXX,$LLVMGXX)
1054   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1055   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1056 fi
1057
1058 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1059 dnl found, otherwise clang if available.
1060 AC_ARG_WITH(llvmcc,
1061   AS_HELP_STRING([--with-llvmcc=<name>],
1062     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1063     [],[with_llvmcc=check])
1064 AC_MSG_CHECKING([LLVM capable compiler])
1065 if test "$with_llvmcc" != "check"; then
1066    if (test "$with_llvmcc" != "llvm-gcc" &&
1067        test "$with_llvmcc" != "clang" &&
1068        test "$with_llvmcc" != "none"); then
1069       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1070    fi
1071    WITH_LLVMCC="$with_llvmcc"
1072 elif test -n "$LLVMGCC"; then
1073    WITH_LLVMCC=llvm-gcc
1074 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1075    WITH_LLVMCC=clang
1076 else
1077    WITH_LLVMCC=none
1078 fi
1079 AC_MSG_RESULT([$WITH_LLVMCC])
1080 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1081
1082 AC_MSG_CHECKING([tool compatibility])
1083
1084 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1085 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1086 dnl to support those options.
1087 dnl "icc" emits gcc signatures
1088 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1089 ICC=no
1090 IXX=no
1091 case $CC in
1092   icc*|icpc*)
1093     ICC=yes
1094     IXX=yes
1095     ;;
1096    *)
1097     ;;
1098 esac
1099
1100 if test "$GCC" != "yes" && test "$ICC" != "yes"
1101 then
1102   AC_MSG_ERROR([gcc|icc required but not found])
1103 fi
1104
1105 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
1106 if test "$GXX" != "yes" && test "$IXX" != "yes"
1107 then
1108   AC_MSG_ERROR([g++|icc required but not found])
1109 fi
1110
1111 dnl Verify that GCC is version 3.0 or higher
1112 if test "$GCC" = "yes"
1113 then
1114   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1115 #error Unsupported GCC version
1116 #endif
1117 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1118 fi
1119
1120 dnl Check for GNU Make.  We use its extensions, so don't build without it
1121 if test -z "$llvm_cv_gnu_make_command"
1122 then
1123   AC_MSG_ERROR([GNU Make required but not found])
1124 fi
1125
1126 dnl Tool compatibility is okay if we make it here.
1127 AC_MSG_RESULT([ok])
1128
1129 dnl Check optional compiler flags.
1130 AC_MSG_CHECKING([optional compiler flags])
1131 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1132 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1133 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1134
1135 dnl===-----------------------------------------------------------------------===
1136 dnl===
1137 dnl=== SECTION 5: Check for libraries
1138 dnl===
1139 dnl===-----------------------------------------------------------------------===
1140
1141 AC_CHECK_LIB(m,sin)
1142 if test "$llvm_cv_os_type" = "MingW" ; then
1143   AC_CHECK_LIB(imagehlp, main)
1144   AC_CHECK_LIB(psapi, main)
1145 fi
1146
1147 dnl dlopen() is required for plugin support.
1148 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1149                [Define if dlopen() is available on this platform.]),
1150                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1151
1152 dnl libffi is optional; used to call external functions from the interpreter
1153 if test "$llvm_cv_enable_libffi" = "yes" ; then
1154   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1155                  [Define if libffi is available on this platform.]),
1156                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1157 fi
1158
1159 dnl mallinfo is optional; the code can compile (minus features) without it
1160 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1161                [Define if mallinfo() is available on this platform.]))
1162
1163 dnl pthread locking functions are optional - but llvm will not be thread-safe
1164 dnl without locks.
1165 if test "$ENABLE_THREADS" -eq 1 ; then
1166   AC_CHECK_LIB(pthread, pthread_mutex_init)
1167   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1168                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1169                            [Have pthread_mutex_lock]))
1170   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1171                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1172                  [Have pthread_rwlock_init]))
1173   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1174                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1175                  [Have pthread_getspecific]))
1176 fi
1177
1178 dnl Allow extra x86-disassembler library
1179 AC_ARG_WITH(udis86,
1180   AS_HELP_STRING([--with-udis86=<path>],
1181     [Use udis86 external x86 disassembler library]),
1182     [
1183       AC_SUBST(USE_UDIS86, [1])
1184       case "$withval" in
1185         /usr/lib|yes) ;;
1186         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1187       esac
1188       AC_CHECK_LIB(udis86, ud_init, [], [
1189         echo "Error! You need to have libudis86 around."
1190         exit -1
1191       ])
1192     ],
1193     AC_SUBST(USE_UDIS86, [0]))
1194 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1195                    [Define if use udis86 library])
1196
1197 dnl Allow OProfile support for JIT output.
1198 AC_ARG_WITH(oprofile,
1199   AS_HELP_STRING([--with-oprofile=<prefix>],
1200     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1201     [
1202       AC_SUBST(USE_OPROFILE, [1])
1203       case "$withval" in
1204         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1205         no) llvm_cv_oppath=
1206             AC_SUBST(USE_OPROFILE, [0]) ;;
1207         *) llvm_cv_oppath="${withval}/lib/oprofile"
1208            CPPFLAGS="-I${withval}/include";;
1209       esac
1210       if test -n "$llvm_cv_oppath" ; then
1211         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1212         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1213         dnl libbfd is not included properly in libopagent in some Debian
1214         dnl versions.  If libbfd isn't found at all, we assume opagent works
1215         dnl anyway.
1216         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1217         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1218           echo "Error! You need to have libopagent around."
1219           exit -1
1220         ])
1221         AC_CHECK_HEADER([opagent.h], [], [
1222           echo "Error! You need to have opagent.h around."
1223           exit -1
1224           ])
1225       fi
1226     ],
1227     [
1228       AC_SUBST(USE_OPROFILE, [0])
1229     ])
1230 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1231                    [Define if we have the oprofile JIT-support library])
1232
1233 dnl===-----------------------------------------------------------------------===
1234 dnl===
1235 dnl=== SECTION 6: Check for header files
1236 dnl===
1237 dnl===-----------------------------------------------------------------------===
1238
1239 dnl First, use autoconf provided macros for specific headers that we need
1240 dnl We don't check for ancient stuff or things that are guaranteed to be there
1241 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1242 dnl Generally we're looking for POSIX headers.
1243 AC_HEADER_DIRENT
1244 AC_HEADER_MMAP_ANONYMOUS
1245 AC_HEADER_STAT
1246 AC_HEADER_STDC
1247 AC_HEADER_SYS_WAIT
1248 AC_HEADER_TIME
1249
1250 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1251 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1252 AC_CHECK_HEADERS([utime.h windows.h])
1253 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1254 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1255 AC_CHECK_HEADERS([valgrind/valgrind.h])
1256 if test "$ENABLE_THREADS" -eq 1 ; then
1257   AC_CHECK_HEADERS(pthread.h,
1258                    AC_SUBST(HAVE_PTHREAD, 1),
1259                    AC_SUBST(HAVE_PTHREAD, 0))
1260 else
1261   AC_SUBST(HAVE_PTHREAD, 0)
1262 fi
1263
1264 dnl Try to find ffi.h.
1265 if test "$llvm_cv_enable_libffi" = "yes" ; then
1266   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1267 fi
1268
1269 dnl Try to find Darwin specific crash reporting library.
1270 AC_CHECK_HEADERS([CrashReporterClient.h])
1271
1272 dnl Try to find Darwin specific linker-section library.
1273 AC_CHECK_HEADERS([mach-o/getsect.h])
1274
1275 dnl===-----------------------------------------------------------------------===
1276 dnl===
1277 dnl=== SECTION 7: Check for types and structures
1278 dnl===
1279 dnl===-----------------------------------------------------------------------===
1280
1281 AC_HUGE_VAL_CHECK
1282 AC_TYPE_PID_T
1283 AC_TYPE_SIZE_T
1284 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1285 AC_STRUCT_TM
1286 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1287 AC_CHECK_TYPES([uint64_t],,
1288          AC_CHECK_TYPES([u_int64_t],,
1289          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1290
1291 dnl===-----------------------------------------------------------------------===
1292 dnl===
1293 dnl=== SECTION 8: Check for specific functions needed
1294 dnl===
1295 dnl===-----------------------------------------------------------------------===
1296
1297 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1298 AC_CHECK_FUNCS([powf fmodf strtof round ])
1299 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1300 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1301 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1302 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1303 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1304 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1305 AC_C_PRINTF_A
1306 AC_FUNC_RAND48
1307
1308 dnl Check for variations in the Standard C++ library and STL. These macros are
1309 dnl provided by LLVM in the autoconf/m4 directory.
1310 AC_FUNC_ISNAN
1311 AC_FUNC_ISINF
1312
1313 dnl Check for mmap support.We also need to know if /dev/zero is required to
1314 dnl be opened for allocating RWX memory.
1315 dnl Make sure we aren't attempting to configure for an unknown system
1316 if test "$llvm_cv_platform_type" = "Unix" ; then
1317   AC_FUNC_MMAP
1318   AC_FUNC_MMAP_FILE
1319   AC_NEED_DEV_ZERO_FOR_MMAP
1320
1321   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1322   then
1323     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1324   fi
1325   if test "$ac_cv_func_mmap_file" = "no"
1326   then
1327     AC_MSG_WARN([mmap() of files required but not found])
1328   fi
1329 fi
1330
1331 dnl atomic builtins are required for threading support.
1332 AC_MSG_CHECKING(for GCC atomic builtins)
1333 dnl Since we'll be using these atomic builtins in C++ files we should test
1334 dnl the C++ compiler.
1335 AC_LANG_PUSH([C++])
1336 AC_LINK_IFELSE(
1337   AC_LANG_SOURCE(
1338     [[int main() {
1339         volatile unsigned long val = 1;
1340         __sync_synchronize();
1341         __sync_val_compare_and_swap(&val, 1, 0);
1342         __sync_add_and_fetch(&val, 1);
1343         __sync_sub_and_fetch(&val, 1);
1344         return 0;
1345       }
1346     ]]),
1347   AC_LANG_POP([C++])
1348   AC_MSG_RESULT(yes)
1349   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1350   AC_MSG_RESULT(no)
1351   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1352   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1353
1354 dnl Check for Darwin-specific getsect().
1355 AC_MSG_CHECKING(for getsect())
1356 AC_COMPILE_IFELSE(
1357   AC_LANG_SOURCE(
1358     [[#include <mach-o/getsect.h>
1359       int main() {
1360         unsigned long p;
1361         return (int)getsect("__DATA","__pass_info", &p);
1362       }
1363     ]]),
1364   AC_MSG_RESULT(yes)
1365     AC_DEFINE(HAVE_GETSECT, 1, Have Darwin getsect() support),
1366   AC_MSG_RESULT(no)
1367     AC_DEFINE(HAVE_GETSECT, 1, Have Darwin getsect() support)
1368 )
1369
1370
1371 dnl===-----------------------------------------------------------------------===
1372 dnl===
1373 dnl=== SECTION 9: Additional checks, variables, etc.
1374 dnl===
1375 dnl===-----------------------------------------------------------------------===
1376
1377 dnl Handle 32-bit linux systems running a 64-bit kernel.
1378 dnl This has to come after section 4 because it invokes the compiler.
1379 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1380   AC_IS_LINUX_MIXED
1381   if test "$llvm_cv_linux_mixed" = "yes"; then
1382     llvm_cv_target_arch="x86"
1383     ARCH="x86"
1384   fi
1385 fi
1386
1387 dnl Check, whether __dso_handle is present
1388 AC_CHECK_FUNCS([__dso_handle])
1389
1390 dnl See if the llvm-gcc executable can compile to LLVM assembly
1391 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1392 [llvm_cv_llvmgcc_sanity="no"
1393 if test -x "$LLVMGCC" ; then
1394   cp /dev/null conftest.c
1395   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1396       grep 'target datalayout =' > /dev/null 2>&1
1397   if test $? -eq 0 ; then
1398     llvm_cv_llvmgcc_sanity="yes"
1399   fi
1400   rm conftest.c
1401 fi])
1402
1403 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1404 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1405   AC_MSG_CHECKING([llvm-gcc component support])
1406   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1407   AC_SUBST(LLVMCC1,$llvmcc1path)
1408   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1409   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1410   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1411   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1412   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1413   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1414   AC_MSG_RESULT([ok])
1415 fi
1416
1417 dnl Propagate the shared library extension that the libltdl checks did to
1418 dnl the Makefiles so we can use it there too
1419 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1420
1421 dnl Propagate the run-time library path variable that the libltdl
1422 dnl checks found to the Makefiles so we can use it there too
1423 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1424
1425 # Translate the various configuration directories and other basic
1426 # information into substitutions that will end up in Makefile.config.in
1427 # that these configured values can be used by the makefiles
1428 if test "${prefix}" = "NONE" ; then
1429   prefix="/usr/local"
1430 fi
1431 eval LLVM_PREFIX="${prefix}";
1432 eval LLVM_BINDIR="${prefix}/bin";
1433 eval LLVM_LIBDIR="${prefix}/lib";
1434 eval LLVM_DATADIR="${prefix}/share/llvm";
1435 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1436 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1437 eval LLVM_INCLUDEDIR="${prefix}/include";
1438 eval LLVM_INFODIR="${prefix}/info";
1439 eval LLVM_MANDIR="${prefix}/man";
1440 LLVM_CONFIGTIME=`date`
1441 AC_SUBST(LLVM_PREFIX)
1442 AC_SUBST(LLVM_BINDIR)
1443 AC_SUBST(LLVM_LIBDIR)
1444 AC_SUBST(LLVM_DATADIR)
1445 AC_SUBST(LLVM_DOCSDIR)
1446 AC_SUBST(LLVM_ETCDIR)
1447 AC_SUBST(LLVM_INCLUDEDIR)
1448 AC_SUBST(LLVM_INFODIR)
1449 AC_SUBST(LLVM_MANDIR)
1450 AC_SUBST(LLVM_CONFIGTIME)
1451
1452 # Place the various directores into the config.h file as #defines so that we
1453 # can know about the installation paths within LLVM.
1454 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1455                    [Installation prefix directory])
1456 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1457                    [Installation directory for binary executables])
1458 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1459                    [Installation directory for libraries])
1460 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1461                    [Installation directory for data files])
1462 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1463                    [Installation directory for documentation])
1464 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1465                    [Installation directory for config files])
1466 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1467                    [Installation directory for include files])
1468 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1469                    [Installation directory for .info files])
1470 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1471                    [Installation directory for man pages])
1472 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1473                    [Time at which LLVM was configured])
1474 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1475                    [Host triple we were built on])
1476
1477 # Determine which bindings to build.
1478 if test "$BINDINGS_TO_BUILD" = auto ; then
1479   BINDINGS_TO_BUILD=""
1480   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1481     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1482   fi
1483 fi
1484 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1485
1486 # This isn't really configurey, but it avoids having to repeat the list in
1487 # other files.
1488 AC_SUBST(ALL_BINDINGS,ocaml)
1489
1490 # Do any work necessary to ensure that bindings have what they need.
1491 binding_prereqs_failed=0
1492 for a_binding in $BINDINGS_TO_BUILD ; do
1493   case "$a_binding" in
1494   ocaml)
1495     if test "x$OCAMLC" = x ; then
1496       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1497       binding_prereqs_failed=1
1498     fi
1499     if test "x$OCAMLDEP" = x ; then
1500       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1501       binding_prereqs_failed=1
1502     fi
1503     if test "x$OCAMLOPT" = x ; then
1504       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1505       dnl ocamlopt is optional!
1506     fi
1507     if test "x$with_ocaml_libdir" != xauto ; then
1508       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1509     else
1510       ocaml_stdlib="`"$OCAMLC" -where`"
1511       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1512       then
1513         # ocaml stdlib is beneath our prefix; use stdlib
1514         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1515       else
1516         # ocaml stdlib is outside our prefix; use libdir/ocaml
1517         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1518       fi
1519     fi
1520     ;;
1521   esac
1522 done
1523 if test "$binding_prereqs_failed" = 1 ; then
1524   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1525 fi
1526
1527 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1528 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1529
1530 dnl Determine linker rpath flag
1531 if test "$llvm_cv_link_use_r" = "yes" ; then
1532   RPATH="-Wl,-R"
1533 else
1534   RPATH="-Wl,-rpath"
1535 fi
1536 AC_SUBST(RPATH)
1537
1538 dnl Determine linker rdynamic flag
1539 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1540   RDYNAMIC="-Wl,-export-dynamic"
1541 else
1542   RDYNAMIC=""
1543 fi
1544 AC_SUBST(RDYNAMIC)
1545
1546 dnl===-----------------------------------------------------------------------===
1547 dnl===
1548 dnl=== SECTION 10: Specify the output files and generate it
1549 dnl===
1550 dnl===-----------------------------------------------------------------------===
1551
1552 dnl Configure header files
1553 dnl WARNING: dnl If you add or remove any of the following config headers, then
1554 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1555 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1556 dnl files can be updated automatically when their *.in sources change.
1557 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1558 AH_TOP([#ifndef CONFIG_H
1559 #define CONFIG_H])
1560 AH_BOTTOM([#endif])
1561
1562 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1563 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1564 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1565 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1566 AC_CONFIG_HEADERS([include/llvm/System/DataTypes.h])
1567
1568 dnl Configure the makefile's configuration data
1569 AC_CONFIG_FILES([Makefile.config])
1570
1571 dnl Configure the RPM spec file for LLVM
1572 AC_CONFIG_FILES([llvm.spec])
1573
1574 dnl Configure llvmc's Base plugin
1575 AC_CONFIG_FILES([tools/llvmc/src/Base.td])
1576
1577 dnl Do the first stage of configuration for llvm-config.in.
1578 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1579
1580 dnl Do special configuration of Makefiles
1581 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1582 AC_CONFIG_MAKEFILE(Makefile)
1583 AC_CONFIG_MAKEFILE(Makefile.common)
1584 AC_CONFIG_MAKEFILE(examples/Makefile)
1585 AC_CONFIG_MAKEFILE(lib/Makefile)
1586 AC_CONFIG_MAKEFILE(runtime/Makefile)
1587 AC_CONFIG_MAKEFILE(test/Makefile)
1588 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1589 AC_CONFIG_MAKEFILE(unittests/Makefile)
1590 AC_CONFIG_MAKEFILE(tools/Makefile)
1591 AC_CONFIG_MAKEFILE(utils/Makefile)
1592 AC_CONFIG_MAKEFILE(projects/Makefile)
1593 AC_CONFIG_MAKEFILE(bindings/Makefile)
1594 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1595
1596 dnl Finally, crank out the output
1597 AC_OUTPUT