autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.7cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  78       "llvm-kernel")  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  79       *)
  80         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  81         ;;
  82     esac
  83   fi
  84 done
  85
  86 dnl===-----------------------------------------------------------------------===
  87 dnl===
  88 dnl=== SECTION 2: Architecture, target, and host checks
  89 dnl===
  90 dnl===-----------------------------------------------------------------------===
  91
  92 dnl Check the target for which we're compiling and the host that will do the
  93 dnl compilations. This will tell us which LLVM compiler will be used for
  94 dnl compiling SSA into object code. This needs to be done early because
  95 dnl following tests depend on it.
  96 AC_CANONICAL_TARGET
  97
  98 dnl Determine the platform type and cache its value. This helps us configure
  99 dnl the System library to the correct build platform.
 100 AC_CACHE_CHECK([type of operating system we're on],
 101                [llvm_cv_os_type],
 102 [case $build in
 103   *-*-aix*)
 104     llvm_cv_os_type="AIX"
 105     llvm_cv_platform_type="Unix" ;;
 106   *-*-cygwin*)
 107     llvm_cv_os_type="Cygwin"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-darwin*)
 110     llvm_cv_os_type="Darwin"
 111     llvm_cv_platform_type="Unix" ;;
 112   *-*-freebsd*)
 113     llvm_cv_os_type="FreeBSD"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-hpux*)
 116     llvm_cv_os_type="HP-UX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-interix*)
 119     llvm_cv_os_type="Interix"
 120     llvm_cv_platform_type="Unix" ;;
 121   *-*-linux*)
 122     llvm_cv_os_type="Linux"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-solaris*)
 125     llvm_cv_os_type="SunOS"
 126     llvm_cv_platform_type="Unix" ;;
 127   *-*-win32*)
 128     llvm_cv_os_type="Win32"
 129     llvm_cv_platform_type="Win32" ;;
 130   *-*-mingw*)
 131     llvm_cv_os_type="MingW"
 132     llvm_cv_platform_type="Win32" ;;
 133   *)
 134     llvm_cv_os_type="Unknown"
 135     llvm_cv_platform_type="Unknown" ;;
 136 esac])
 137
 138 dnl Make sure we aren't attempting to configure for an unknown system
 139 if test "$llvm_cv_os_type" = "Unknown" ; then
 140   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 141 fi
 142
 143 dnl Set the "OS" Makefile variable based on the platform type so the
 144 dnl makefile can configure itself to specific build hosts
 145 AC_SUBST(OS,$llvm_cv_os_type)
 146
 147 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 148 dnl This is used by lib/System to determine the basic kind of implementation
 149 dnl to use.
 150 case $llvm_cv_platform_type in
 151   Unix)
 152     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 153     AC_SUBST(LLVM_ON_UNIX,[1])
 154     AC_SUBST(LLVM_ON_WIN32,[0])
 155     ;;
 156   Win32)
 157     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 158     AC_SUBST(LLVM_ON_UNIX,[0])
 159     AC_SUBST(LLVM_ON_WIN32,[1])
 160     ;;
 161 esac
 162
 163 dnl Determine what our target architecture is and configure accordingly.
 164 dnl This will allow Makefiles to make a distinction between the hardware and
 165 dnl the OS.
 166 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 167 [case $target in
 168   i?86-*)                 llvm_cv_target_arch="x86" ;;
 169   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 170   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 171   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 172   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 173   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 174   *)                      llvm_cv_target_arch="Unknown" ;;
 175 esac])
 176
 177 if test "$llvm_cv_target_arch" = "Unknown" ; then
 178   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 179 fi
 180
 181 dnl Define a substitution, ARCH, for the target architecture
 182 AC_SUBST(ARCH,$llvm_cv_target_arch)
 183
 184 dnl Check for the endianness of the target
 185 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 186
 187 dnl===-----------------------------------------------------------------------===
 188 dnl===
 189 dnl=== SECTION 3: Command line arguments for the configure script.
 190 dnl===
 191 dnl===-----------------------------------------------------------------------===
 192
 193 dnl --enable-optimized : check whether they want to do an optimized build:
 194 AC_ARG_ENABLE(optimized,
 195               AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
 196 if test ${enableval} = "no" ; then
 197   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 198 else
 199   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 200 fi
 201
 202 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 203 AC_ARG_ENABLE(debug-runtime,
 204    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 205 if test ${enableval} = "no" ; then
 206   AC_SUBST(DEBUG_RUNTIME,[[]])
 207 else
 208   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 209 fi
 210
 211 dnl --enable-jit: check whether they want to enable the jit
 212 AC_ARG_ENABLE(jit,
 213   AS_HELP_STRING(--enable-jit,
 214                  [Enable Just In Time Compiling (default is YES)]),,
 215   enableval=default)
 216 if test ${enableval} = "no"
 217 then
 218   AC_SUBST(JIT,[[]])
 219 else
 220   case "$llvm_cv_target_arch" in
 221     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 222     Sparc)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 223     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 224     x86_64)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 225     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 226     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 227     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 228   esac
 229 fi
 230
 231 dnl Allow enablement of doxygen generated documentation
 232 AC_ARG_ENABLE(doxygen,
 233               AS_HELP_STRING([--enable-doxygen],
 234                              [Build doxygen documentation (default is NO)]),,
 235                              enableval=default)
 236 case "$enableval" in
 237   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 238   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 239   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 240   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 241 esac
 242
 243 dnl Allow disablement of threads
 244 AC_ARG_ENABLE(threads,
 245               AS_HELP_STRING([--enable-threads],
 246                              [Use threads if available (default is YES)]),,
 247                              enableval=yes)
 248 case "$enableval" in
 249   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 250   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 251   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 252 esac
 253 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 254
 255 dnl Allow specific targets to be specified for building (or not)
 256 TARGETS_TO_BUILD=""
 257 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-target],
 258     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 259     enableval=all)
 260 case "$enableval" in
 261   all) TARGETS_TO_BUILD="X86 Sparc SparcV9 PowerPC Alpha IA64" ;;
 262   host-only)
 263     case "$llvm_cv_target_arch" in
 264       x86)     TARGETS_TO_BUILD="X86" ;;
 265       x86_64)  TARGETS_TO_BUILD="X86" ;;
 266       Sparc)   TARGETS_TO_BUILD="Sparc SparcV9" ;;
 267       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 268       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 269       IA64)    TARGETS_TO_BUILD="IA64" ;;
 270       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 271     esac
 272     ;;
 273   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 274       case "$a_target" in
 275         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 276         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 277         sparc)   TARGETS_TO_BUILD="Sparc SparcV9 $TARGETS_TO_BUILD" ;;
 278         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 279         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 280         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 281         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 282       esac
 283   done
 284   ;;
 285 esac
 286 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 287 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 288
 289 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 290 AC_ARG_WITH(llvmgccdir,
 291   AS_HELP_STRING([--with-llvmgccdir],
 292     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 293     withval=default)
 294 case "$withval" in
 295   default) WITH_LLVMGCCDIR=default ;;
 296   /*)      WITH_LLVMGCCDIR=$withval ;;
 297   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 298 esac
 299
 300
 301 dnl===-----------------------------------------------------------------------===
 302 dnl===
 303 dnl=== SECTION 4: Check for programs we need and that they are the right version
 304 dnl===
 305 dnl===-----------------------------------------------------------------------===
 306
 307 dnl Check for compilation tools
 308 AC_PROG_CPP
 309 AC_PROG_CC(gcc)
 310 AC_PROG_CXX(g++)
 311 AC_PROG_FLEX
 312 AC_PROG_BISON
 313
 314 dnl Check for the tools that the makefiles require
 315 AC_CHECK_GNU_MAKE
 316 AC_PROG_LN_S
 317 AC_PATH_PROG(CMP, [cmp], [cmp])
 318 AC_PATH_PROG(CP, [cp], [cp])
 319 AC_PATH_PROG(DATE, [date], [date])
 320 AC_PATH_PROG(FIND, [find], [find])
 321 AC_PATH_PROG(GREP, [grep], [grep])
 322 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 323 AC_PATH_PROG(MV,   [mv],   [mv])
 324 AC_PROG_RANLIB
 325 AC_PATH_PROG(RM,   [rm],   [rm])
 326 AC_PATH_PROG(SED,  [sed],  [sed])
 327 AC_PATH_PROG(TAR,  [tar],  [gtar])
 328 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 329 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 330   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 331   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ",
 332    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 333 fi
 334 AC_PATH_PROG(GV, [gv], [echo gv])
 335 if test "$GV" != "echo gv" ; then
 336   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 337   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV",
 338    [Define to path to gv program if found or 'echo gv' otherwise])
 339 fi
 340
 341 dnl Look for a sufficiently recent version of Perl.
 342 LLVM_PROG_PERL([5.006])
 343 AC_SUBST(PERL)
 344 if test x"$PERL" = xnone; then
 345    AC_SUBST(HAVE_PERL,0)
 346 else
 347    AC_SUBST(HAVE_PERL,1)
 348 fi
 349
 350 dnl Find the install program
 351 AC_PROG_INSTALL
 352
 353 dnl Checks for documentation and testing tools that we can do without. If these
 354 dnl are not found then they are set to "true" which always succeeds but does
 355 dnl nothing. This just lets the build output show that we could have done
 356 dnl something if the tool was available.
 357 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 358 AC_PATH_PROG(DOT,[dot],[true dot])
 359 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 360 AC_PATH_PROG(ETAGS,[etags],[true etags])
 361 AC_PATH_PROG(GROFF,[groff],[true groff])
 362 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 363 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 364 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 365 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 366 DJ_AC_PATH_TCLSH
 367 AC_PATH_PROG(ZIP,[zip],[true zip])
 368
 369 dnl Determine if the linker supports the -R option.
 370 AC_LINK_USE_R
 371
 372 dnl Check for libtool and the library that has dlopen function (which must come
 373 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 374 dnl libtool).
 375 AC_LIBTOOL_DLOPEN
 376 AC_LIB_LTDL
 377 AC_PROG_LIBTOOL
 378
 379 if test "$lt_cv_dlopen_self" = "yes" ; then
 380   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 381               [Define if dlopen(0) will open the symbols of the program])
 382 fi
 383
 384 dnl Check if we know how to tell etags we are using C++:
 385 etags_version=`$ETAGS --version 2>&1`
 386 case "$etags_version" in
 387         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 388         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 389         *) ETAGSFLAGS="" ;;
 390 esac
 391 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 392
 393 if test "$WITH_LLVMGCCDIR" = "default" ; then
 394   LLVMGCC="llvm-gcc${EXEEXT}"
 395   LLVMGXX="llvm-g++${EXEEXT}"
 396   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 397   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 398 else
 399   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 400   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 401   AC_SUBST(LLVMGCC,$LLVMGCC)
 402   AC_SUBST(LLVMGXX,$LLVMGXX)
 403 fi
 404
 405 AC_MSG_CHECKING([tool compatibility])
 406
 407 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 408 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 409 dnl to support those options.
 410 dnl "icc" emits gcc signatures
 411 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 412 ICC=no
 413 IXX=no
 414 case $CC in
 415   icc*|icpc*)
 416     ICC=yes
 417     IXX=yes
 418     ;;
 419    *)
 420     ;;
 421 esac
 422
 423 if test "$GCC" != "yes" && test "$ICC" != "yes"
 424 then
 425   AC_MSG_ERROR([gcc|icc required but not found])
 426 fi
 427
 428 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 429 if test "$GXX" != "yes" && test "$IXX" != "yes"
 430 then
 431   AC_MSG_ERROR([g++|icc required but not found])
 432 fi
 433
 434 dnl Verify that GCC is version 3.0 or higher
 435 if test "$GCC" = "yes"
 436 then
 437   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 438   if test "$gccmajor" -lt "3"
 439   then
 440     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 441   fi
 442 fi
 443
 444 dnl Check for GNU Make.  We use its extensions, so don't build without it
 445 if test -z "$llvm_cv_gnu_make_command"
 446 then
 447   AC_MSG_ERROR([GNU Make required but not found])
 448 fi
 449
 450 dnl Tool compatibility is okay if we make it here.
 451 AC_MSG_RESULT([ok])
 452
 453 dnl===-----------------------------------------------------------------------===
 454 dnl===
 455 dnl=== SECTION 5: Check for libraries
 456 dnl===
 457 dnl===-----------------------------------------------------------------------===
 458
 459 dnl libelf is for sparc only; we can ignore it if we don't have it
 460 AC_CHECK_LIB(elf, elf_begin)
 461 AC_CHECK_LIB(m,sin)
 462
 463 dnl lt_dlopen may be required for plugin support.
 464 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 465               [Define if lt_dlopen() is available on this platform]),
 466               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 467                            not be available]))
 468
 469 dnl dlopen() is required for plugin support.
 470 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 471                [Define if dlopen() is available on this platform.]),
 472                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 473
 474 dnl mallinfo is optional; the code can compile (minus features) without it
 475 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 476                [Define if mallinfo() is available on this platform.]))
 477
 478 dnl pthread locking functions are optional - but llvm will not be thread-safe
 479 dnl without locks.
 480 if test "$ENABLE_THREADS" -eq 1 ; then
 481   AC_CHECK_LIB(pthread,pthread_mutex_init)
 482   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 483                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 484                            [Have pthread_mutex_lock]))
 485 fi
 486
 487 dnl===-----------------------------------------------------------------------===
 488 dnl===
 489 dnl=== SECTION 6: Check for header files
 490 dnl===
 491 dnl===-----------------------------------------------------------------------===
 492
 493 dnl First, use autoconf provided macros for specific headers that we need
 494 dnl We don't check for ancient stuff or things that are guaranteed to be there
 495 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 496 dnl Generally we're looking for POSIX headers.
 497 AC_HEADER_DIRENT
 498 AC_HEADER_MMAP_ANONYMOUS
 499 AC_HEADER_STAT
 500 AC_HEADER_STDC
 501 AC_HEADER_SYS_WAIT
 502 AC_HEADER_TIME
 503
 504 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 505 AC_CHECK_HEADERS([malloc.h signal.h stdint.h unistd.h utime.h windows.h])
 506 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/types.h])
 507 AC_CHECK_HEADERS([malloc/malloc.h])
 508 if test "$ENABLE_THREADS" -eq 1 ; then
 509   AC_CHECK_HEADERS(pthread.h)
 510 fi
 511
 512 dnl===-----------------------------------------------------------------------===
 513 dnl===
 514 dnl=== SECTION 7: Check for types and structures
 515 dnl===
 516 dnl===-----------------------------------------------------------------------===
 517
 518 AC_TYPE_PID_T
 519 AC_TYPE_SIZE_T
 520 AC_TYPE_SIGNAL
 521 AC_STRUCT_TM
 522 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 523 AC_CHECK_TYPES([uint64_t],,
 524          AC_CHECK_TYPES([u_int64_t],,
 525          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 526
 527 dnl===-----------------------------------------------------------------------===
 528 dnl===
 529 dnl=== SECTION 8: Check for specific functions needed
 530 dnl===
 531 dnl===-----------------------------------------------------------------------===
 532
 533 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 534 AC_CHECK_FUNCS([getpagesize getrusage gettimeofday isatty mkdtemp mkstemp ])
 535 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 536 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 537 AC_C_PRINTF_A
 538 AC_FUNC_ALLOCA
 539 AC_FUNC_RAND48
 540
 541 dnl Check for variations in the Standard C++ library and STL. These macros are
 542 dnl provided by LLVM in the autoconf/m4 directory.
 543 AC_CXX_HAVE_HASH_MAP
 544 AC_CXX_HAVE_HASH_SET
 545 AC_CXX_HAVE_STD_ITERATOR
 546 AC_CXX_HAVE_BI_ITERATOR
 547 AC_CXX_HAVE_FWD_ITERATOR
 548 AC_FUNC_ISNAN
 549 AC_FUNC_ISINF
 550
 551 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 552 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 553 dnl be opened for allocating RWX memory.
 554 AC_FUNC_MMAP
 555 AC_FUNC_MMAP_FILE
 556 AC_NEED_DEV_ZERO_FOR_MMAP
 557 AC_CHECK_FUNC(mprotect,,
 558               AC_MSG_ERROR([Function mprotect() required but not found]))
 559
 560 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 561 then
 562   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 563 fi
 564 if test "$ac_cv_func_mmap_file" = "no"
 565 then
 566   AC_MSG_WARN([mmap() of files required but not found])
 567 fi
 568
 569 dnl===-----------------------------------------------------------------------===
 570 dnl===
 571 dnl=== SECTION 9: Additional checks, variables, etc.
 572 dnl===
 573 dnl===-----------------------------------------------------------------------===
 574
 575 dnl See if the llvm-gcc executable can compile to LLVM assembly
 576 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 577 [llvm_cv_llvmgcc_sanity="no"
 578 if test -x "$LLVMGCC" ; then
 579   cp /dev/null conftest.c
 580   "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
 581   if test $? -eq 0 ; then
 582     llvm_cv_llvmgcc_sanity="yes"
 583   fi
 584   rm conftest.c
 585 fi])
 586
 587 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 588 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 589   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 590   AC_SUBST(LLVMCC1,$llvmcc1path)
 591   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 592   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 593   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 594   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 595 fi
 596
 597 dnl Propagate the shared library extension that the libltdl checks did to
 598 dnl the Makefiles so we can use it there too
 599 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 600
 601 # Translate the various configuration directories and other basic
 602 # information into substitutions that will end up in Makefile.config.in
 603 # that these configured values can be used by the makefiles
 604 eval LLVM_PREFIX="${prefix}";
 605 eval LLVM_BINDIR="${prefix}/bin";
 606 eval LLVM_LIBDIR="${prefix}/lib";
 607 eval LLVM_DATADIR="${prefix}/share/llvm";
 608 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 609 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 610 eval LLVM_INCLUDEDIR="${prefix}/include";
 611 eval LLVM_INFODIR="${prefix}/info";
 612 eval LLVM_MANDIR="${prefix}/man";
 613 LLVM_CONFIGTIME=`date`
 614 AC_SUBST(LLVM_PREFIX)
 615 AC_SUBST(LLVM_BINDIR)
 616 AC_SUBST(LLVM_LIBDIR)
 617 AC_SUBST(LLVM_DATADIR)
 618 AC_SUBST(LLVM_DOCSDIR)
 619 AC_SUBST(LLVM_ETCDIR)
 620 AC_SUBST(LLVM_INCLUDEDIR)
 621 AC_SUBST(LLVM_INFODIR)
 622 AC_SUBST(LLVM_MANDIR)
 623 AC_SUBST(LLVM_CONFIGTIME)
 624
 625 # Place the various directores into the config.h file as #defines so that we
 626 # can know about the installation paths within LLVM.
 627 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 628                    [Installation prefix directory])
 629 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 630                    [Installation directory for binary executables])
 631 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 632                    [Installation directory for libraries])
 633 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 634                    [Installation directory for data files])
 635 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 636                    [Installation directory for documentation])
 637 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 638                    [Installation directory for config files])
 639 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 640                    [Installation directory for include files])
 641 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 642                    [Installation directory for .info files])
 643 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 644                    [Installation directory for man pages])
 645 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 646                    [Time at which LLVM was configured])
 647
 648 dnl===-----------------------------------------------------------------------===
 649 dnl===
 650 dnl=== SECTION 10: Specify the output files and generate it
 651 dnl===
 652 dnl===-----------------------------------------------------------------------===
 653
 654 dnl Configure header files
 655 dnl WARNING: dnl If you add or remove any of the following config headers, then
 656 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 657 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 658 dnl files can be updated automatically when their *.in sources change.
 659 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 660 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 661 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 662 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 663 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 664
 665 dnl Configure the makefile's configuration data
 666 AC_CONFIG_FILES([Makefile.config])
 667
 668 dnl Configure doxygen's configuration file
 669 AC_CONFIG_FILES([docs/doxygen.cfg])
 670
 671 dnl Do the first stage of configuration for llvm-config.in.
 672 AC_CONFIG_FILES([utils/llvm-config/llvm-config.in])
 673
 674 dnl Do special configuration of Makefiles
 675 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 676 AC_CONFIG_MAKEFILE(Makefile)
 677 AC_CONFIG_MAKEFILE(Makefile.common)
 678 AC_CONFIG_MAKEFILE(examples/Makefile)
 679 AC_CONFIG_MAKEFILE(lib/Makefile)
 680 AC_CONFIG_MAKEFILE(runtime/Makefile)
 681 AC_CONFIG_MAKEFILE(test/Makefile)
 682 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 683 AC_CONFIG_MAKEFILE(tools/Makefile)
 684 AC_CONFIG_MAKEFILE(utils/Makefile)
 685 AC_CONFIG_MAKEFILE(projects/Makefile)
 686
 687 dnl Finally, crank out the output
 688 AC_OUTPUT
 689
 690 dnl Warn loudly if llvm-gcc was not obviously working
 691 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 692  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 693  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 694  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 695  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 696  AC_MSG_WARN([***** build the llvm tools.])
 697 fi