autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.1svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [1], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2012 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2012 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl We need to check for the compiler up here to avoid anything else
  63 dnl starting with a different one.
  64 AC_PROG_CC(clang llvm-gcc gcc)
  65 AC_PROG_CXX(clang++ llvm-g++ g++)
  66 AC_PROG_CPP
  67
  68 dnl Configure all of the projects present in our source tree. While we could
  69 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  70 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  71 dnl Instead we match on the known projects.
  72
  73 dnl
  74 dnl One tricky part of doing this is that some projects depend upon other
  75 dnl projects.  For example, several projects rely upon the LLVM test suite.
  76 dnl We want to configure those projects first so that their object trees are
  77 dnl created before running the configure scripts of projects that depend upon
  78 dnl them.
  79 dnl
  80
  81 dnl Several projects use llvm-gcc, so configure that first
  82 if test -d ${srcdir}/projects/llvm-gcc ; then
  83   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  84 fi
  85
  86 dnl Several projects use the LLVM test suite, so configure it next.
  87 if test -d ${srcdir}/projects/test-suite ; then
  88   AC_CONFIG_SUBDIRS([projects/test-suite])
  89 fi
  90
  91 dnl llvm-test is the old name of the test-suite, kept here for backwards
  92 dnl compatibility
  93 if test -d ${srcdir}/projects/llvm-test ; then
  94   AC_CONFIG_SUBDIRS([projects/llvm-test])
  95 fi
  96
  97 dnl Some projects use poolalloc; configure that next
  98 if test -d ${srcdir}/projects/poolalloc ; then
  99   AC_CONFIG_SUBDIRS([projects/poolalloc])
 100 fi
 101
 102 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 103   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 104 fi
 105
 106 dnl Check for all other projects
 107 for i in `ls ${srcdir}/projects`
 108 do
 109   if test -d ${srcdir}/projects/${i} ; then
 110     case ${i} in
 111       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 112       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 113       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 114       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 115       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 116       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 117       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 118       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 119       compiler-rt)       ;;
 120       llvm-gcc)       ;;
 121       test-suite)     ;;
 122       llvm-test)      ;;
 123       poolalloc)      ;;
 124       llvm-poolalloc) ;;
 125       *)
 126         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 127         ;;
 128     esac
 129   fi
 130 done
 131
 132 dnl Disable the build of polly, even if it is checked out into tools/polly.
 133 AC_ARG_ENABLE(polly,
 134               AS_HELP_STRING([--enable-polly],
 135                              [Use polly if available (default is YES)]),,
 136                              enableval=default)
 137 case "$enableval" in
 138   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 139   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 140   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 141   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 142 esac
 143
 144
 145 dnl Check if polly is checked out into tools/polly and configure it if
 146 dnl available.
 147 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 148   AC_SUBST(LLVM_HAS_POLLY,1)
 149   AC_CONFIG_SUBDIRS([tools/polly])
 150 fi
 151
 152 dnl===-----------------------------------------------------------------------===
 153 dnl===
 154 dnl=== SECTION 2: Architecture, target, and host checks
 155 dnl===
 156 dnl===-----------------------------------------------------------------------===
 157
 158 dnl Check the target for which we're compiling and the host that will do the
 159 dnl compilations. This will tell us which LLVM compiler will be used for
 160 dnl compiling SSA into object code. This needs to be done early because
 161 dnl following tests depend on it.
 162 AC_CANONICAL_TARGET
 163
 164 dnl Determine the platform type and cache its value. This helps us configure
 165 dnl the System library to the correct build platform.
 166 AC_CACHE_CHECK([type of operating system we're going to host on],
 167                [llvm_cv_os_type],
 168 [case $host in
 169   *-*-aix*)
 170     llvm_cv_link_all_option="-Wl,--whole-archive"
 171     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 172     llvm_cv_os_type="AIX"
 173     llvm_cv_platform_type="Unix" ;;
 174   *-*-irix*)
 175     llvm_cv_link_all_option="-Wl,--whole-archive"
 176     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 177     llvm_cv_os_type="IRIX"
 178     llvm_cv_platform_type="Unix" ;;
 179   *-*-cygwin*)
 180     llvm_cv_link_all_option="-Wl,--whole-archive"
 181     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 182     llvm_cv_os_type="Cygwin"
 183     llvm_cv_platform_type="Unix" ;;
 184   *-*-darwin*)
 185     llvm_cv_link_all_option="-Wl,-all_load"
 186     llvm_cv_no_link_all_option="-Wl,-noall_load"
 187     llvm_cv_os_type="Darwin"
 188     llvm_cv_platform_type="Unix" ;;
 189   *-*-minix*)
 190     llvm_cv_link_all_option="-Wl,-all_load"
 191     llvm_cv_no_link_all_option="-Wl,-noall_load"
 192     llvm_cv_os_type="Minix"
 193     llvm_cv_platform_type="Unix" ;;
 194   *-*-freebsd* | *-*-kfreebsd-gnu)
 195     llvm_cv_link_all_option="-Wl,--whole-archive"
 196     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 197     llvm_cv_os_type="FreeBSD"
 198     llvm_cv_platform_type="Unix" ;;
 199   *-*-openbsd*)
 200     llvm_cv_link_all_option="-Wl,--whole-archive"
 201     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 202     llvm_cv_os_type="OpenBSD"
 203     llvm_cv_platform_type="Unix" ;;
 204   *-*-netbsd*)
 205     llvm_cv_link_all_option="-Wl,--whole-archive"
 206     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 207     llvm_cv_os_type="NetBSD"
 208     llvm_cv_platform_type="Unix" ;;
 209   *-*-dragonfly*)
 210     llvm_cv_link_all_option="-Wl,--whole-archive"
 211     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 212     llvm_cv_os_type="DragonFly"
 213     llvm_cv_platform_type="Unix" ;;
 214   *-*-hpux*)
 215     llvm_cv_link_all_option="-Wl,--whole-archive"
 216     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 217     llvm_cv_os_type="HP-UX"
 218     llvm_cv_platform_type="Unix" ;;
 219   *-*-interix*)
 220     llvm_cv_link_all_option="-Wl,--whole-archive"
 221     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 222     llvm_cv_os_type="Interix"
 223     llvm_cv_platform_type="Unix" ;;
 224   *-*-linux*)
 225     llvm_cv_link_all_option="-Wl,--whole-archive"
 226     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 227     llvm_cv_os_type="Linux"
 228     llvm_cv_platform_type="Unix" ;;
 229   *-*-gnu*)
 230     llvm_cv_link_all_option="-Wl,--whole-archive"
 231     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 232     llvm_cv_os_type="GNU"
 233     llvm_cv_platform_type="Unix" ;;
 234   *-*-solaris*)
 235     llvm_cv_link_all_option="-Wl,-z,allextract"
 236     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 237     llvm_cv_os_type="SunOS"
 238     llvm_cv_platform_type="Unix" ;;
 239   *-*-auroraux*)
 240     llvm_cv_link_all_option="-Wl,-z,allextract"
 241     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 242     llvm_cv_os_type="AuroraUX"
 243     llvm_cv_platform_type="Unix" ;;
 244   *-*-win32*)
 245     llvm_cv_link_all_option="-Wl,--whole-archive"
 246     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 247     llvm_cv_os_type="Win32"
 248     llvm_cv_platform_type="Win32" ;;
 249   *-*-mingw*)
 250     llvm_cv_link_all_option="-Wl,--whole-archive"
 251     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 252     llvm_cv_os_type="MingW"
 253     llvm_cv_platform_type="Win32" ;;
 254   *-*-haiku*)
 255     llvm_cv_link_all_option="-Wl,--whole-archive"
 256     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 257     llvm_cv_os_type="Haiku"
 258     llvm_cv_platform_type="Unix" ;;
 259   *-unknown-eabi*)
 260     llvm_cv_link_all_option="-Wl,--whole-archive"
 261     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 262     llvm_cv_os_type="Freestanding"
 263     llvm_cv_platform_type="Unix" ;;
 264   *-unknown-elf*)
 265     llvm_cv_link_all_option="-Wl,--whole-archive"
 266     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 267     llvm_cv_os_type="Freestanding"
 268     llvm_cv_platform_type="Unix" ;;
 269   *)
 270     llvm_cv_link_all_option=""
 271     llvm_cv_no_link_all_option=""
 272     llvm_cv_os_type="Unknown"
 273     llvm_cv_platform_type="Unknown" ;;
 274 esac])
 275
 276 AC_CACHE_CHECK([type of operating system we're going to target],
 277                [llvm_cv_target_os_type],
 278 [case $target in
 279   *-*-aix*)
 280     llvm_cv_target_os_type="AIX" ;;
 281   *-*-irix*)
 282     llvm_cv_target_os_type="IRIX" ;;
 283   *-*-cygwin*)
 284     llvm_cv_target_os_type="Cygwin" ;;
 285   *-*-darwin*)
 286     llvm_cv_target_os_type="Darwin" ;;
 287   *-*-minix*)
 288     llvm_cv_target_os_type="Minix" ;;
 289   *-*-freebsd*)
 290     llvm_cv_target_os_type="FreeBSD" ;;
 291   *-*-openbsd*)
 292     llvm_cv_target_os_type="OpenBSD" ;;
 293   *-*-netbsd*)
 294     llvm_cv_target_os_type="NetBSD" ;;
 295   *-*-dragonfly*)
 296     llvm_cv_target_os_type="DragonFly" ;;
 297   *-*-hpux*)
 298     llvm_cv_target_os_type="HP-UX" ;;
 299   *-*-interix*)
 300     llvm_cv_target_os_type="Interix" ;;
 301   *-*-linux*)
 302     llvm_cv_target_os_type="Linux" ;;
 303   *-*-solaris*)
 304     llvm_cv_target_os_type="SunOS" ;;
 305   *-*-auroraux*)
 306     llvm_cv_target_os_type="AuroraUX" ;;
 307   *-*-win32*)
 308     llvm_cv_target_os_type="Win32" ;;
 309   *-*-mingw*)
 310     llvm_cv_target_os_type="MingW" ;;
 311   *-*-haiku*)
 312     llvm_cv_target_os_type="Haiku" ;;
 313   *-*-rtems*)
 314     llvm_cv_target_os_type="RTEMS" ;;
 315   *-*-nacl*)
 316     llvm_cv_target_os_type="NativeClient" ;;
 317   *-unknown-eabi*)
 318     llvm_cv_target_os_type="Freestanding" ;;
 319   *)
 320     llvm_cv_target_os_type="Unknown" ;;
 321 esac])
 322
 323 dnl Make sure we aren't attempting to configure for an unknown system
 324 if test "$llvm_cv_os_type" = "Unknown" ; then
 325   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 326 fi
 327
 328 dnl Set the "OS" Makefile variable based on the platform type so the
 329 dnl makefile can configure itself to specific build hosts
 330 AC_SUBST(OS,$llvm_cv_os_type)
 331 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 332 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 333
 334 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 335 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 336 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 337
 338 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 339 dnl This is used by lib/Support to determine the basic kind of implementation
 340 dnl to use.
 341 case $llvm_cv_platform_type in
 342   Unix)
 343     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 344     AC_SUBST(LLVM_ON_UNIX,[1])
 345     AC_SUBST(LLVM_ON_WIN32,[0])
 346     ;;
 347   Win32)
 348     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 349     AC_SUBST(LLVM_ON_UNIX,[0])
 350     AC_SUBST(LLVM_ON_WIN32,[1])
 351     ;;
 352 esac
 353
 354 dnl Determine what our target architecture is and configure accordingly.
 355 dnl This will allow Makefiles to make a distinction between the hardware and
 356 dnl the OS.
 357 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 358 [case $target in
 359   i?86-*)                 llvm_cv_target_arch="x86" ;;
 360   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 361   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 362   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 363   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 364   mips-*)                 llvm_cv_target_arch="Mips" ;;
 365   mipsel-*)               llvm_cv_target_arch="Mips" ;;
 366   xcore-*)                llvm_cv_target_arch="XCore" ;;
 367   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 368   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 369   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 370   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 371   *)                      llvm_cv_target_arch="Unknown" ;;
 372 esac])
 373
 374 if test "$llvm_cv_target_arch" = "Unknown" ; then
 375   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 376 fi
 377
 378 dnl Determine the LLVM native architecture for the target
 379 case "$llvm_cv_target_arch" in
 380     x86)     LLVM_NATIVE_ARCH="X86" ;;
 381     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 382     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 383 esac
 384
 385 dnl Define a substitution, ARCH, for the target architecture
 386 AC_SUBST(ARCH,$llvm_cv_target_arch)
 387
 388 dnl Check for the endianness of the target
 389 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 390
 391 dnl Check for build platform executable suffix if we're cross-compiling
 392 if test "$cross_compiling" = yes; then
 393   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 394   AC_BUILD_EXEEXT
 395   ac_build_prefix=${build_alias}-
 396   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 397   if test -z "$BUILD_CXX"; then
 398      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 399      if test -z "$BUILD_CXX"; then
 400        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 401      fi
 402   fi
 403 else
 404   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 405 fi
 406
 407 dnl Check to see if there's a .svn or .git directory indicating that this
 408 dnl build is being done from a checkout. This sets up several defaults for
 409 dnl the command line switches. When we build with a checkout directory,
 410 dnl we get a debug with assertions turned on. Without, we assume a source
 411 dnl release and we get an optimized build without assertions.
 412 dnl See --enable-optimized and --enable-assertions below
 413 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 414   cvsbuild="yes"
 415   optimize="no"
 416   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 417 else
 418   cvsbuild="no"
 419   optimize="yes"
 420 fi
 421
 422 dnl===-----------------------------------------------------------------------===
 423 dnl===
 424 dnl=== SECTION 3: Command line arguments for the configure script.
 425 dnl===
 426 dnl===-----------------------------------------------------------------------===
 427
 428 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 429 AC_ARG_ENABLE(libcpp,
 430               AS_HELP_STRING([--enable-libcpp],
 431                              [Use libc++ if available (default is NO)]),,
 432                              enableval=default)
 433 case "$enableval" in
 434   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 435   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 436   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 437   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 438 esac
 439
 440 dnl --enable-optimized : check whether they want to do an optimized build:
 441 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 442  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 443 if test ${enableval} = "no" ; then
 444   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 445 else
 446   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 447 fi
 448
 449 dnl --enable-profiling : check whether they want to do a profile build:
 450 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 451  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 452 if test ${enableval} = "no" ; then
 453   AC_SUBST(ENABLE_PROFILING,[[]])
 454 else
 455   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 456 fi
 457
 458 dnl --enable-assertions : check whether they want to turn on assertions or not:
 459 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 460   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 461 if test ${enableval} = "yes" ; then
 462   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 463 else
 464   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 465 fi
 466
 467 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 468 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 469   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 470 if test ${enableval} = "yes" ; then
 471   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 472   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 473 else
 474   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 475   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 476 fi
 477
 478 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 479 AC_ARG_ENABLE(debug-runtime,
 480    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 481 if test ${enableval} = "no" ; then
 482   AC_SUBST(DEBUG_RUNTIME,[[]])
 483 else
 484   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 485 fi
 486
 487 dnl --enable-debug-symbols : should even optimized compiler libraries
 488 dnl have debug symbols?
 489 AC_ARG_ENABLE(debug-symbols,
 490    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 491 if test ${enableval} = "no" ; then
 492   AC_SUBST(DEBUG_SYMBOLS,[[]])
 493 else
 494   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 495 fi
 496
 497 dnl --enable-jit: check whether they want to enable the jit
 498 AC_ARG_ENABLE(jit,
 499   AS_HELP_STRING(--enable-jit,
 500                  [Enable Just In Time Compiling (default is YES)]),,
 501   enableval=default)
 502 if test ${enableval} = "no"
 503 then
 504   AC_SUBST(JIT,[[]])
 505 else
 506   case "$llvm_cv_target_arch" in
 507     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 508     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 509     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 510     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 511     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 512     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 513     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 514     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 515     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 516     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 517     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 518     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 519   esac
 520 fi
 521
 522 dnl Allow enablement of building and installing docs
 523 AC_ARG_ENABLE(docs,
 524               AS_HELP_STRING([--enable-docs],
 525                              [Build documents (default is YES)]),,
 526                              enableval=default)
 527 case "$enableval" in
 528   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 529   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 530   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 531   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 532 esac
 533
 534 dnl Allow enablement of doxygen generated documentation
 535 AC_ARG_ENABLE(doxygen,
 536               AS_HELP_STRING([--enable-doxygen],
 537                              [Build doxygen documentation (default is NO)]),,
 538                              enableval=default)
 539 case "$enableval" in
 540   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 541   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 542   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 543   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 544 esac
 545
 546 dnl Allow disablement of threads
 547 AC_ARG_ENABLE(threads,
 548               AS_HELP_STRING([--enable-threads],
 549                              [Use threads if available (default is YES)]),,
 550                              enableval=default)
 551 case "$enableval" in
 552   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 553   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 554   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 555   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 556 esac
 557 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 558                    [Define if threads enabled])
 559
 560 dnl Allow disablement of pthread.h
 561 AC_ARG_ENABLE(pthreads,
 562               AS_HELP_STRING([--enable-pthreads],
 563                              [Use pthreads if available (default is YES)]),,
 564                              enableval=default)
 565 case "$enableval" in
 566   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 567   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 568   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 569   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 570 esac
 571
 572 dnl Allow building without position independent code
 573 AC_ARG_ENABLE(pic,
 574   AS_HELP_STRING([--enable-pic],
 575                  [Build LLVM with Position Independent Code (default is YES)]),,
 576                  enableval=default)
 577 case "$enableval" in
 578   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 579   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 580   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 581   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 582 esac
 583 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 584                    [Define if position independent code is enabled])
 585
 586 dnl Allow building a shared library and linking tools against it.
 587 AC_ARG_ENABLE(shared,
 588   AS_HELP_STRING([--enable-shared],
 589                  [Build a shared library and link tools against it (default is NO)]),,
 590                  enableval=default)
 591 case "$enableval" in
 592   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 593   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 594   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 595   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 596 esac
 597
 598 dnl Allow libstdc++ is embedded in LLVM.dll.
 599 AC_ARG_ENABLE(embed-stdcxx,
 600   AS_HELP_STRING([--enable-embed-stdcxx],
 601                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 602                  enableval=default)
 603 case "$enableval" in
 604   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 605   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 606   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 607   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 608 esac
 609
 610 dnl Enable embedding timestamp information into build.
 611 AC_ARG_ENABLE(timestamps,
 612   AS_HELP_STRING([--enable-timestamps],
 613                  [Enable embedding timestamp information in build (default is YES)]),,
 614                  enableval=default)
 615 case "$enableval" in
 616   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 617   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 618   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 619   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 620 esac
 621 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 622                    [Define if timestamp information (e.g., __DATE___) is allowed])
 623
 624 dnl Allow specific targets to be specified for building (or not)
 625 TARGETS_TO_BUILD=""
 626 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 627     [Build specific host targets: all or target1,target2,... Valid targets are:
 628      host, x86, x86_64, sparc, powerpc, arm, mips, spu, hexagon,
 629      xcore, msp430, ptx, cbe, and cpp (default=all)]),,
 630     enableval=all)
 631 if test "$enableval" = host-only ; then
 632   enableval=host
 633 fi
 634 case "$enableval" in
 635   all) TARGETS_TO_BUILD="X86 Sparc PowerPC ARM Mips CellSPU XCore MSP430 CppBackend MBlaze PTX Hexagon" ;;
 636   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 637       case "$a_target" in
 638         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 639         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 640         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 641         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 642         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 643         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 644         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 645         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 646         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 647         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 648         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 649         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 650         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 651         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 652         host) case "$llvm_cv_target_arch" in
 653             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 654             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 655             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 656             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 657             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 658             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 659             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 660             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 661             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 662             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 663             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 664             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 665             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 666           esac ;;
 667         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 668       esac
 669   done
 670   ;;
 671 esac
 672 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 673
 674 dnl Determine whether we are building LLVM support for the native architecture.
 675 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 676 for a_target in $TARGETS_TO_BUILD; do
 677   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 678     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 679       [LLVM architecture name for the native architecture, if available])
 680     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 681     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 682     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 683     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 684     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 685       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 686     fi
 687     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 688       [LLVM name for the native Target init function, if available])
 689     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 690       [LLVM name for the native TargetInfo init function, if available])
 691     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 692       [LLVM name for the native target MC init function, if available])
 693     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 694       [LLVM name for the native AsmPrinter init function, if available])
 695     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 696       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 697        [LLVM name for the native AsmParser init function, if available])
 698     fi
 699   fi
 700 done
 701
 702 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 703 dnl target feature def files.
 704 LLVM_ENUM_TARGETS=""
 705 LLVM_ENUM_ASM_PRINTERS=""
 706 LLVM_ENUM_ASM_PARSERS=""
 707 LLVM_ENUM_DISASSEMBLERS=""
 708 for target_to_build in $TARGETS_TO_BUILD; do
 709   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 710   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 711     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 712   fi
 713   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 714     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 715   fi
 716   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 717     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 718   fi
 719 done
 720 AC_SUBST(LLVM_ENUM_TARGETS)
 721 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 722 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 723 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 724
 725 dnl Override the option to use for optimized builds.
 726 AC_ARG_WITH(optimize-option,
 727   AS_HELP_STRING([--with-optimize-option],
 728                  [Select the compiler options to use for optimized builds]),,
 729                  withval=default)
 730 AC_MSG_CHECKING([optimization flags])
 731 case "$withval" in
 732   default)
 733     case "$llvm_cv_os_type" in
 734     FreeBSD) optimize_option=-O2 ;;
 735     MingW) optimize_option=-O2 ;;
 736     *)     optimize_option=-O3 ;;
 737     esac ;;
 738   *) optimize_option="$withval" ;;
 739 esac
 740 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 741 AC_MSG_RESULT([$optimize_option])
 742
 743 dnl Specify extra build options
 744 AC_ARG_WITH(extra-options,
 745   AS_HELP_STRING([--with-extra-options],
 746                  [Specify additional options to compile LLVM with]),,
 747                  withval=default)
 748 case "$withval" in
 749   default) EXTRA_OPTIONS= ;;
 750   *) EXTRA_OPTIONS=$withval ;;
 751 esac
 752 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 753
 754 dnl Specify extra linker build options
 755 AC_ARG_WITH(extra-ld-options,
 756   AS_HELP_STRING([--with-extra-ld-options],
 757                  [Specify additional options to link LLVM with]),,
 758                  withval=default)
 759 case "$withval" in
 760   default) EXTRA_LD_OPTIONS= ;;
 761   *) EXTRA_LD_OPTIONS=$withval ;;
 762 esac
 763 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 764
 765 dnl Allow specific bindings to be specified for building (or not)
 766 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 767     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 768     enableval=default)
 769 BINDINGS_TO_BUILD=""
 770 case "$enableval" in
 771   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 772   all ) BINDINGS_TO_BUILD="ocaml" ;;
 773   none | no) BINDINGS_TO_BUILD="" ;;
 774   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 775       case "$a_binding" in
 776         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 777         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 778       esac
 779   done
 780   ;;
 781 esac
 782
 783 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 784 dnl script for bindings/ocaml/configure, except that its auto value depends on
 785 dnl OCAMLC, which is found here to support tests.
 786 AC_ARG_WITH([ocaml-libdir],
 787   [AS_HELP_STRING([--with-ocaml-libdir],
 788     [Specify install location for ocaml bindings (default is stdlib)])],
 789   [],
 790   [withval=auto])
 791 case "$withval" in
 792   auto) with_ocaml_libdir="$withval" ;;
 793   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 794   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 795 esac
 796
 797 AC_ARG_WITH(clang-srcdir,
 798   AS_HELP_STRING([--with-clang-srcdir],
 799     [Directory to the out-of-tree Clang source]),,
 800     withval="-")
 801 case "$withval" in
 802   -) clang_src_root="" ;;
 803   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 804   *) clang_src_root="$ac_pwd/$withval" ;;
 805 esac
 806 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
 807
 808 AC_ARG_WITH(clang-resource-dir,
 809   AS_HELP_STRING([--with-clang-resource-dir],
 810     [Relative directory from the Clang binary for resource files]),,
 811     withval="")
 812 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 813                    [Relative directory for resource files])
 814
 815 AC_ARG_WITH(c-include-dirs,
 816   AS_HELP_STRING([--with-c-include-dirs],
 817     [Colon separated list of directories clang will search for headers]),,
 818     withval="")
 819 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 820                    [Directories clang will search for headers])
 821
 822 # Clang normally uses the system c++ headers and libraries. With this option,
 823 # clang will use the ones provided by a gcc installation instead. This option should
 824 # be passed the same value that was used with --prefix when configuring gcc.
 825 AC_ARG_WITH(gcc-toolchain,
 826   AS_HELP_STRING([--with-gcc-toolchain],
 827     [Directory where gcc is installed.]),,
 828     withval="")
 829 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
 830                    [Directory where gcc is installed.])
 831
 832 dnl Allow linking of LLVM with GPLv3 binutils code.
 833 AC_ARG_WITH(binutils-include,
 834   AS_HELP_STRING([--with-binutils-include],
 835     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 836   withval=default)
 837 case "$withval" in
 838   default) WITH_BINUTILS_INCDIR=default ;;
 839   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 840   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 841 esac
 842 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 843   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 844   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 845      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 846      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 847   fi
 848 fi
 849
 850 dnl Specify the URL where bug reports should be submitted.
 851 AC_ARG_WITH(bug-report-url,
 852   AS_HELP_STRING([--with-bug-report-url],
 853     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 854     withval="http://llvm.org/bugs/")
 855 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 856                    [Bug report URL.])
 857
 858 dnl --enable-libffi : check whether the user wants to turn off libffi:
 859 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 860   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 861   [case "$enableval" in
 862     yes) llvm_cv_enable_libffi="yes" ;;
 863     no)  llvm_cv_enable_libffi="no"  ;;
 864     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 865   esac],
 866   llvm_cv_enable_libffi=no)
 867
 868 AC_ARG_WITH(internal-prefix,
 869   AS_HELP_STRING([--with-internal-prefix],
 870     [Installation directory for internal files]),,
 871     withval="")
 872 AC_SUBST(INTERNAL_PREFIX,[$withval])
 873
 874 dnl===-----------------------------------------------------------------------===
 875 dnl===
 876 dnl=== SECTION 4: Check for programs we need and that they are the right version
 877 dnl===
 878 dnl===-----------------------------------------------------------------------===
 879
 880 AC_PROG_NM
 881 AC_SUBST(NM)
 882
 883 dnl Check for the tools that the makefiles require
 884 AC_CHECK_GNU_MAKE
 885 AC_PROG_LN_S
 886 AC_PATH_PROG(CMP, [cmp], [cmp])
 887 AC_PATH_PROG(CP, [cp], [cp])
 888 AC_PATH_PROG(DATE, [date], [date])
 889 AC_PATH_PROG(FIND, [find], [find])
 890 AC_PATH_PROG(GREP, [grep], [grep])
 891 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 892 AC_PATH_PROG(MV,   [mv],   [mv])
 893 AC_PROG_RANLIB
 894 AC_CHECK_TOOL(AR, ar, false)
 895 AC_PATH_PROG(RM,   [rm],   [rm])
 896 AC_PATH_PROG(SED,  [sed],  [sed])
 897 AC_PATH_PROG(TAR,  [tar],  [gtar])
 898 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 899
 900 dnl Looking for misc. graph plotting software
 901 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 902 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 903   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 904   dnl If we're targeting for mingw we should emit windows paths, not msys
 905   if test "$llvm_cv_os_type" = "MingW" ; then
 906     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 907   fi
 908   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 909    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 910 fi
 911 AC_PATH_PROG(DOT, [dot], [echo dot])
 912 if test "$DOT" != "echo dot" ; then
 913   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 914   dnl If we're targeting for mingw we should emit windows paths, not msys
 915   if test "$llvm_cv_os_type" = "MingW" ; then
 916     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 917   fi
 918   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 919    [Define to path to dot program if found or 'echo dot' otherwise])
 920 fi
 921 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 922 if test "$FDP" != "echo fdp" ; then
 923   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 924   dnl If we're targeting for mingw we should emit windows paths, not msys
 925   if test "$llvm_cv_os_type" = "MingW" ; then
 926     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 927   fi
 928   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 929    [Define to path to fdp program if found or 'echo fdp' otherwise])
 930 fi
 931 AC_PATH_PROG(NEATO, [neato], [echo neato])
 932 if test "$NEATO" != "echo neato" ; then
 933   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 934   dnl If we're targeting for mingw we should emit windows paths, not msys
 935   if test "$llvm_cv_os_type" = "MingW" ; then
 936     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 937   fi
 938   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 939    [Define to path to neato program if found or 'echo neato' otherwise])
 940 fi
 941 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 942 if test "$TWOPI" != "echo twopi" ; then
 943   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 944   dnl If we're targeting for mingw we should emit windows paths, not msys
 945   if test "$llvm_cv_os_type" = "MingW" ; then
 946     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 947   fi
 948   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 949    [Define to path to twopi program if found or 'echo twopi' otherwise])
 950 fi
 951 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 952 if test "$CIRCO" != "echo circo" ; then
 953   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 954   dnl If we're targeting for mingw we should emit windows paths, not msys
 955   if test "$llvm_cv_os_type" = "MingW" ; then
 956     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 957   fi
 958   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 959    [Define to path to circo program if found or 'echo circo' otherwise])
 960 fi
 961 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 962 if test "$GV" != "echo gv" ; then
 963   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 964   dnl If we're targeting for mingw we should emit windows paths, not msys
 965   if test "$llvm_cv_os_type" = "MingW" ; then
 966     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 967   fi
 968   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 969    [Define to path to gv program if found or 'echo gv' otherwise])
 970 fi
 971 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 972 if test "$DOTTY" != "echo dotty" ; then
 973   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 974   dnl If we're targeting for mingw we should emit windows paths, not msys
 975   if test "$llvm_cv_os_type" = "MingW" ; then
 976     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 977   fi
 978   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 979    [Define to path to dotty program if found or 'echo dotty' otherwise])
 980 fi
 981 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
 982 if test "$XDOT_PY" != "echo xdot.py" ; then
 983   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
 984   dnl If we're targeting for mingw we should emit windows paths, not msys
 985   if test "$llvm_cv_os_type" = "MingW" ; then
 986     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 987   fi
 988   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
 989    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
 990 fi
 991
 992 dnl Find the install program
 993 AC_PROG_INSTALL
 994 dnl Prepend src dir to install path dir if it's a relative path
 995 dnl This is a hack for installs that take place in something other
 996 dnl than the top level.
 997 case "$INSTALL" in
 998  [[\\/$]]* | ?:[[\\/]]* ) ;;
 999  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1000 esac
1001
1002 dnl Checks for documentation and testing tools that we can do without. If these
1003 dnl are not found then they are set to "true" which always succeeds but does
1004 dnl nothing. This just lets the build output show that we could have done
1005 dnl something if the tool was available.
1006 AC_PATH_PROG(BZIP2, [bzip2])
1007 AC_PATH_PROG(CAT, [cat])
1008 AC_PATH_PROG(DOXYGEN, [doxygen])
1009 AC_PATH_PROG(GROFF, [groff])
1010 AC_PATH_PROG(GZIPBIN, [gzip])
1011 AC_PATH_PROG(POD2HTML, [pod2html])
1012 AC_PATH_PROG(POD2MAN, [pod2man])
1013 AC_PATH_PROG(PDFROFF, [pdfroff])
1014 AC_PATH_PROG(RUNTEST, [runtest])
1015 DJ_AC_PATH_TCLSH
1016 AC_PATH_PROG(ZIP, [zip])
1017 AC_PATH_PROGS(OCAMLC, [ocamlc])
1018 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1019 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1020 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1021 AC_PATH_PROGS(GAS, [gas as])
1022
1023 dnl Get the version of the linker in use.
1024 AC_LINK_GET_VERSION
1025
1026 dnl Determine whether the linker supports the -R option.
1027 AC_LINK_USE_R
1028
1029 dnl Determine whether the linker supports the -export-dynamic option.
1030 AC_LINK_EXPORT_DYNAMIC
1031
1032 dnl Determine whether the linker supports the --version-script option.
1033 AC_LINK_VERSION_SCRIPT
1034
1035 dnl Check for libtool and the library that has dlopen function (which must come
1036 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1037 dnl libtool).
1038 AC_LIBTOOL_DLOPEN
1039 AC_LIB_LTDL
1040
1041 AC_MSG_CHECKING([tool compatibility])
1042
1043 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1044 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1045 dnl to support those options.
1046 dnl "icc" emits gcc signatures
1047 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1048 ICC=no
1049 IXX=no
1050 case $CC in
1051   icc*|icpc*)
1052     ICC=yes
1053     IXX=yes
1054     ;;
1055    *)
1056     ;;
1057 esac
1058
1059 if test "$GCC" != "yes" && test "$ICC" != "yes"
1060 then
1061   AC_MSG_ERROR([gcc|icc required but not found])
1062 fi
1063
1064 dnl Ensure that compilation tools are compatible with GCC extensions
1065 if test "$GXX" != "yes" && test "$IXX" != "yes"
1066 then
1067   AC_MSG_ERROR([g++|clang++|icc required but not found])
1068 fi
1069
1070 dnl Verify that GCC is version 3.0 or higher
1071 if test "$GCC" = "yes"
1072 then
1073   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1074 #error Unsupported GCC version
1075 #endif
1076 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1077 fi
1078
1079 dnl Check for GNU Make.  We use its extensions, so don't build without it
1080 if test -z "$llvm_cv_gnu_make_command"
1081 then
1082   AC_MSG_ERROR([GNU Make required but not found])
1083 fi
1084
1085 dnl Tool compatibility is okay if we make it here.
1086 AC_MSG_RESULT([ok])
1087
1088 dnl Check optional compiler flags.
1089 AC_MSG_CHECKING([optional compiler flags])
1090 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1091 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1092 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1093 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT])
1094
1095 dnl===-----------------------------------------------------------------------===
1096 dnl===
1097 dnl=== SECTION 5: Check for libraries
1098 dnl===
1099 dnl===-----------------------------------------------------------------------===
1100
1101 AC_CHECK_LIB(m,sin)
1102 if test "$llvm_cv_os_type" = "MingW" ; then
1103   AC_CHECK_LIB(imagehlp, main)
1104   AC_CHECK_LIB(psapi, main)
1105 fi
1106
1107 dnl dlopen() is required for plugin support.
1108 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1109                [Define if dlopen() is available on this platform.]),
1110                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1111
1112 dnl libffi is optional; used to call external functions from the interpreter
1113 if test "$llvm_cv_enable_libffi" = "yes" ; then
1114   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1115                  [Define if libffi is available on this platform.]),
1116                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1117 fi
1118
1119 dnl mallinfo is optional; the code can compile (minus features) without it
1120 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1121                [Define if mallinfo() is available on this platform.]))
1122
1123 dnl pthread locking functions are optional - but llvm will not be thread-safe
1124 dnl without locks.
1125 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1126   AC_CHECK_LIB(pthread, pthread_mutex_init)
1127   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1128                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1129                            [Have pthread_mutex_lock]))
1130   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1131                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1132                  [Have pthread_rwlock_init]))
1133   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1134                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1135                  [Have pthread_getspecific]))
1136 fi
1137
1138 dnl Allow extra x86-disassembler library
1139 AC_ARG_WITH(udis86,
1140   AS_HELP_STRING([--with-udis86=<path>],
1141     [Use udis86 external x86 disassembler library]),
1142     [
1143       AC_SUBST(USE_UDIS86, [1])
1144       case "$withval" in
1145         /usr/lib|yes) ;;
1146         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1147       esac
1148       AC_CHECK_LIB(udis86, ud_init, [], [
1149         echo "Error! You need to have libudis86 around."
1150         exit -1
1151       ])
1152     ],
1153     AC_SUBST(USE_UDIS86, [0]))
1154 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1155                    [Define if use udis86 library])
1156
1157 dnl Allow OProfile support for JIT output.
1158 AC_ARG_WITH(oprofile,
1159   AS_HELP_STRING([--with-oprofile=<prefix>],
1160     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1161     [
1162       AC_SUBST(USE_OPROFILE, [1])
1163       case "$withval" in
1164         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1165         no) llvm_cv_oppath=
1166             AC_SUBST(USE_OPROFILE, [0]) ;;
1167         *) llvm_cv_oppath="${withval}/lib/oprofile"
1168            CPPFLAGS="-I${withval}/include";;
1169       esac
1170       case $llvm_cv_os_type in
1171         Linux)
1172           if test -n "$llvm_cv_oppath" ; then
1173             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1174             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1175             dnl libbfd is not included properly in libopagent in some Debian
1176             dnl versions.  If libbfd isn't found at all, we assume opagent works
1177             dnl anyway.
1178             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1179             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1180               echo "Error! You need to have libopagent around."
1181               exit -1
1182             ])
1183             AC_CHECK_HEADER([opagent.h], [], [
1184               echo "Error! You need to have opagent.h around."
1185               exit -1
1186               ])
1187           fi ;;
1188         *)
1189           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1190       esac
1191     ],
1192     [
1193       AC_SUBST(USE_OPROFILE, [0])
1194     ])
1195 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1196                    [Define if we have the oprofile JIT-support library])
1197
1198 dnl Enable support for Intel JIT Events API.
1199 AC_ARG_WITH(intel-jitevents,
1200   AS_HELP_STRING([--with-intel-jitevents=<vtune-amplifier-dir>],
1201     [Specify location of run-time support library for Intel JIT API (default=/opt/intel/vtune_amplifier_xe_2011)]),
1202     [
1203       case $llvm_cv_os_type in
1204         Linux|Win32|Cygwin|MingW) ;;
1205         *)
1206           AC_MSG_ERROR([
1207             Intel JIT API support is available on Linux and Windows only."]) ;;
1208       esac
1209
1210       AC_SUBST(USE_INTEL_JITEVENTS, [1])
1211       case "$llvm_cv_target_arch" in
1212         x86)    llvm_intel_jitevents_archdir="lib32";;
1213         x86_64) llvm_intel_jitevents_archdir="lib64";;
1214         *)      echo "Target architecture $llvm_cv_target_arch does not support Intel JIT Events API"
1215                 exit -1;;
1216       esac
1217       INTEL_JITEVENTS_INCDIR="/opt/intel/vtune_amplifier_xe_2011/include"
1218       INTEL_JITEVENTS_LIBDIR="/opt/intel/vtune_amplifier_xe_2011/$llvm_intel_jitevents_archdir"
1219       case "$withval" in
1220         /* | [[A-Za-z]]:[[\\/]]*) INTEL_JITEVENTS_INCDIR=$withval/include
1221                                   INTEL_JITEVENTS_LIBDIR=$withval/$llvm_intel_jitevents_archdir ;;
1222         *) ;;
1223       esac
1224
1225       AC_SUBST(INTEL_JITEVENTS_INCDIR)
1226       AC_SUBST(INTEL_JITEVENTS_LIBDIR)
1227
1228       LIBS="$LIBS -L${INTEL_JITEVENTS_LIBDIR}"
1229       CPPFLAGS="$CPPFLAGS -I$INTEL_JITEVENTS_INCDIR"
1230
1231       AC_SEARCH_LIBS(iJIT_IsProfilingActive, jitprofiling, [], [
1232         echo "Error! Cannot find libjitprofiling.a. Please check path specified in flag --with-intel-jitevents"
1233         exit -1
1234       ])
1235       AC_CHECK_HEADER([jitprofiling.h], [], [
1236         echo "Error! Cannot find jitprofiling.h. Please check path specified in flag --with-intel-jitevents"
1237         exit -1
1238       ])
1239
1240     ],
1241     [
1242       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1243     ])
1244 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1245                    [Define if we have the Intel JIT API runtime support library])
1246
1247 dnl===-----------------------------------------------------------------------===
1248 dnl===
1249 dnl=== SECTION 6: Check for header files
1250 dnl===
1251 dnl===-----------------------------------------------------------------------===
1252
1253 dnl First, use autoconf provided macros for specific headers that we need
1254 dnl We don't check for ancient stuff or things that are guaranteed to be there
1255 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1256 dnl Generally we're looking for POSIX headers.
1257 AC_HEADER_DIRENT
1258 AC_HEADER_MMAP_ANONYMOUS
1259 AC_HEADER_STAT
1260 AC_HEADER_SYS_WAIT
1261 AC_HEADER_TIME
1262
1263 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1264 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1265 AC_CHECK_HEADERS([utime.h windows.h])
1266 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1267 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1268 AC_CHECK_HEADERS([valgrind/valgrind.h])
1269 AC_CHECK_HEADERS([fenv.h])
1270 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1271   AC_CHECK_HEADERS(pthread.h,
1272                    AC_SUBST(HAVE_PTHREAD, 1),
1273                    AC_SUBST(HAVE_PTHREAD, 0))
1274 else
1275   AC_SUBST(HAVE_PTHREAD, 0)
1276 fi
1277
1278 dnl Try to find ffi.h.
1279 if test "$llvm_cv_enable_libffi" = "yes" ; then
1280   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1281 fi
1282
1283 dnl Try to find Darwin specific crash reporting libraries.
1284 AC_CHECK_HEADERS([CrashReporterClient.h])
1285
1286 dnl Try to find Darwin specific crash reporting global.
1287 AC_MSG_CHECKING([__crashreporter_info__])
1288 AC_LINK_IFELSE(
1289   AC_LANG_SOURCE(
1290     [[extern const char *__crashreporter_info__;
1291       int main() {
1292         __crashreporter_info__ = "test";
1293         return 0;
1294       }
1295     ]]),
1296   AC_MSG_RESULT(yes)
1297   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1298   AC_MSG_RESULT(no)
1299   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1300             Define if __crashreporter_info__ exists.))
1301
1302 dnl===-----------------------------------------------------------------------===
1303 dnl===
1304 dnl=== SECTION 7: Check for types and structures
1305 dnl===
1306 dnl===-----------------------------------------------------------------------===
1307
1308 AC_HUGE_VAL_CHECK
1309 AC_TYPE_PID_T
1310 AC_TYPE_SIZE_T
1311 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1312 AC_STRUCT_TM
1313 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1314 AC_CHECK_TYPES([uint64_t],,
1315          AC_CHECK_TYPES([u_int64_t],,
1316          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1317
1318 dnl===-----------------------------------------------------------------------===
1319 dnl===
1320 dnl=== SECTION 8: Check for specific functions needed
1321 dnl===
1322 dnl===-----------------------------------------------------------------------===
1323
1324 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1325 AC_CHECK_FUNCS([powf fmodf strtof round ])
1326 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1327 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1328 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit strdup ])
1329 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1330 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1331 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1332 AC_C_PRINTF_A
1333 AC_FUNC_RAND48
1334
1335 dnl Check the declaration "Secure API" on Windows environments.
1336 AC_CHECK_DECLS([strerror_s])
1337
1338 dnl Check symbols in libgcc.a for JIT on Mingw.
1339 if test "$llvm_cv_os_type" = "MingW" ; then
1340   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1341   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1342   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1343   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1344
1345   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1346   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1347   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1348   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1349   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1350   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1351   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1352   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1353   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1354   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1355
1356   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1357   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1358 fi
1359
1360 dnl Check Win32 API EnumerateLoadedModules.
1361 if test "$llvm_cv_os_type" = "MingW" ; then
1362   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1363   AC_COMPILE_IFELSE([[#include <windows.h>
1364 #include <imagehlp.h>
1365 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1366 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1367 [
1368   AC_MSG_RESULT([yes])
1369   llvm_cv_win32_elmcb_pcstr="PCSTR"
1370 ],
1371 [
1372   AC_MSG_RESULT([no])
1373   llvm_cv_win32_elmcb_pcstr="PSTR"
1374 ])
1375   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1376 fi
1377
1378 dnl Check for variations in the Standard C++ library and STL. These macros are
1379 dnl provided by LLVM in the autoconf/m4 directory.
1380 AC_FUNC_ISNAN
1381 AC_FUNC_ISINF
1382
1383 dnl Check for mmap support.We also need to know if /dev/zero is required to
1384 dnl be opened for allocating RWX memory.
1385 dnl Make sure we aren't attempting to configure for an unknown system
1386 if test "$llvm_cv_platform_type" = "Unix" ; then
1387   AC_FUNC_MMAP
1388   AC_FUNC_MMAP_FILE
1389   AC_NEED_DEV_ZERO_FOR_MMAP
1390
1391   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1392   then
1393     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1394   fi
1395   if test "$ac_cv_func_mmap_file" = "no"
1396   then
1397     AC_MSG_WARN([mmap() of files required but not found])
1398   fi
1399 fi
1400
1401 dnl atomic builtins are required for threading support.
1402 AC_MSG_CHECKING(for GCC atomic builtins)
1403 dnl Since we'll be using these atomic builtins in C++ files we should test
1404 dnl the C++ compiler.
1405 AC_LANG_PUSH([C++])
1406 AC_LINK_IFELSE(
1407   AC_LANG_SOURCE(
1408     [[int main() {
1409         volatile unsigned long val = 1;
1410         __sync_synchronize();
1411         __sync_val_compare_and_swap(&val, 1, 0);
1412         __sync_add_and_fetch(&val, 1);
1413         __sync_sub_and_fetch(&val, 1);
1414         return 0;
1415       }
1416     ]]),
1417   AC_LANG_POP([C++])
1418   AC_MSG_RESULT(yes)
1419   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1420   AC_MSG_RESULT(no)
1421   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1422   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1423
1424 dnl===-----------------------------------------------------------------------===
1425 dnl===
1426 dnl=== SECTION 9: Additional checks, variables, etc.
1427 dnl===
1428 dnl===-----------------------------------------------------------------------===
1429
1430 dnl Handle 32-bit linux systems running a 64-bit kernel.
1431 dnl This has to come after section 4 because it invokes the compiler.
1432 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1433   AC_IS_LINUX_MIXED
1434   if test "$llvm_cv_linux_mixed" = "yes"; then
1435     llvm_cv_target_arch="x86"
1436     ARCH="x86"
1437   fi
1438 fi
1439
1440 dnl Check whether __dso_handle is present
1441 AC_CHECK_FUNCS([__dso_handle])
1442
1443 dnl Propagate the shared library extension that the libltdl checks did to
1444 dnl the Makefiles so we can use it there too
1445 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1446
1447 dnl Propagate the run-time library path variable that the libltdl
1448 dnl checks found to the Makefiles so we can use it there too
1449 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1450
1451 dnl Translate the various configuration directories and other basic
1452 dnl information into substitutions that will end up in Makefile.config.in
1453 dnl that these configured values can be used by the makefiles
1454 if test "${prefix}" = "NONE" ; then
1455   prefix="/usr/local"
1456 fi
1457 eval LLVM_PREFIX="${prefix}";
1458 eval LLVM_BINDIR="${prefix}/bin";
1459 eval LLVM_LIBDIR="${prefix}/lib";
1460 eval LLVM_DATADIR="${prefix}/share/llvm";
1461 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1462 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1463 eval LLVM_INCLUDEDIR="${prefix}/include";
1464 eval LLVM_INFODIR="${prefix}/info";
1465 eval LLVM_MANDIR="${prefix}/man";
1466 LLVM_CONFIGTIME=`date`
1467 AC_SUBST(LLVM_PREFIX)
1468 AC_SUBST(LLVM_BINDIR)
1469 AC_SUBST(LLVM_LIBDIR)
1470 AC_SUBST(LLVM_DATADIR)
1471 AC_SUBST(LLVM_DOCSDIR)
1472 AC_SUBST(LLVM_ETCDIR)
1473 AC_SUBST(LLVM_INCLUDEDIR)
1474 AC_SUBST(LLVM_INFODIR)
1475 AC_SUBST(LLVM_MANDIR)
1476 AC_SUBST(LLVM_CONFIGTIME)
1477
1478 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1479 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1480   LLVM_CONFIGTIME="(timestamp not enabled)"
1481 fi
1482
1483 dnl Place the various directories into the config.h file as #defines so that we
1484 dnl can know about the installation paths within LLVM.
1485 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1486                    [Installation prefix directory])
1487 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1488                    [Installation directory for binary executables])
1489 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1490                    [Installation directory for libraries])
1491 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1492                    [Installation directory for data files])
1493 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1494                    [Installation directory for documentation])
1495 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1496                    [Installation directory for config files])
1497 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1498                    [Installation directory for include files])
1499 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1500                    [Installation directory for .info files])
1501 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1502                    [Installation directory for man pages])
1503 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1504                    [Time at which LLVM was configured])
1505 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1506                    [Target triple LLVM will generate code for by default])
1507
1508 dnl Determine which bindings to build.
1509 if test "$BINDINGS_TO_BUILD" = auto ; then
1510   BINDINGS_TO_BUILD=""
1511   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1512     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1513   fi
1514 fi
1515 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1516
1517 dnl This isn't really configurey, but it avoids having to repeat the list in
1518 dnl other files.
1519 AC_SUBST(ALL_BINDINGS,ocaml)
1520
1521 dnl Do any work necessary to ensure that bindings have what they need.
1522 binding_prereqs_failed=0
1523 for a_binding in $BINDINGS_TO_BUILD ; do
1524   case "$a_binding" in
1525   ocaml)
1526     if test "x$OCAMLC" = x ; then
1527       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1528       binding_prereqs_failed=1
1529     fi
1530     if test "x$OCAMLDEP" = x ; then
1531       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1532       binding_prereqs_failed=1
1533     fi
1534     if test "x$OCAMLOPT" = x ; then
1535       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1536       dnl ocamlopt is optional!
1537     fi
1538     if test "x$with_ocaml_libdir" != xauto ; then
1539       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1540     else
1541       ocaml_stdlib="`"$OCAMLC" -where`"
1542       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1543       then
1544         # ocaml stdlib is beneath our prefix; use stdlib
1545         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1546       else
1547         # ocaml stdlib is outside our prefix; use libdir/ocaml
1548         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1549       fi
1550     fi
1551     ;;
1552   esac
1553 done
1554 if test "$binding_prereqs_failed" = 1 ; then
1555   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1556 fi
1557
1558 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1559 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1560
1561 dnl Determine linker rpath flag
1562 if test "$llvm_cv_link_use_r" = "yes" ; then
1563   RPATH="-Wl,-R"
1564 else
1565   RPATH="-Wl,-rpath"
1566 fi
1567 AC_SUBST(RPATH)
1568
1569 dnl Determine linker rdynamic flag
1570 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1571   RDYNAMIC="-Wl,-export-dynamic"
1572 else
1573   RDYNAMIC=""
1574 fi
1575 AC_SUBST(RDYNAMIC)
1576
1577 dnl===-----------------------------------------------------------------------===
1578 dnl===
1579 dnl=== SECTION 10: Specify the output files and generate it
1580 dnl===
1581 dnl===-----------------------------------------------------------------------===
1582
1583 dnl Configure header files
1584 dnl WARNING: dnl If you add or remove any of the following config headers, then
1585 dnl you MUST also update Makefile so that the variable FilesToConfig
1586 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1587 dnl files can be updated automatically when their *.in sources change.
1588 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1589 AH_TOP([#ifndef CONFIG_H
1590 #define CONFIG_H])
1591 AH_BOTTOM([#endif])
1592
1593 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1594 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1595 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1596 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1597 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1598
1599 dnl Configure the makefile's configuration data
1600 AC_CONFIG_FILES([Makefile.config])
1601
1602 dnl Configure the RPM spec file for LLVM
1603 AC_CONFIG_FILES([llvm.spec])
1604
1605 dnl Configure doxygen's configuration file
1606 AC_CONFIG_FILES([docs/doxygen.cfg])
1607
1608 dnl Configure clang, if present
1609 if test "${clang_src_root}" = ""; then
1610   clang_src_root="$srcdir/tools/clang"
1611 fi
1612 if test -f ${clang_src_root}/README.txt; then
1613   dnl Use variables to stay under 80 columns.
1614   configh="include/clang/Config/config.h"
1615   doxy="docs/doxygen.cfg"
1616   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
1617   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
1618 fi
1619
1620 dnl OCaml findlib META file
1621 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1622
1623 dnl Do special configuration of Makefiles
1624 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1625 AC_CONFIG_MAKEFILE(Makefile)
1626 AC_CONFIG_MAKEFILE(Makefile.common)
1627 AC_CONFIG_MAKEFILE(examples/Makefile)
1628 AC_CONFIG_MAKEFILE(lib/Makefile)
1629 AC_CONFIG_MAKEFILE(runtime/Makefile)
1630 AC_CONFIG_MAKEFILE(test/Makefile)
1631 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1632 AC_CONFIG_MAKEFILE(unittests/Makefile)
1633 AC_CONFIG_MAKEFILE(tools/Makefile)
1634 AC_CONFIG_MAKEFILE(utils/Makefile)
1635 AC_CONFIG_MAKEFILE(projects/Makefile)
1636 AC_CONFIG_MAKEFILE(bindings/Makefile)
1637 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1638
1639 dnl Finally, crank out the output
1640 AC_OUTPUT