autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.7svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2009 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2009 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-auroraux*)
 169     llvm_cv_link_all_option="-Wl,-z,allextract"
 170     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 171     llvm_cv_os_type="AuroraUX"
 172     llvm_cv_platform_type="Unix" ;;
 173   *-*-win32*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="Win32"
 177     llvm_cv_platform_type="Win32" ;;
 178   *-*-mingw*)
 179     llvm_cv_link_all_option="-Wl,--whole-archive"
 180     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 181     llvm_cv_os_type="MingW"
 182     llvm_cv_platform_type="Win32" ;;
 183   *-*-haiku*)
 184     llvm_cv_link_all_option="-Wl,--whole-archive"
 185     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 186     llvm_cv_os_type="Haiku"
 187     llvm_cv_platform_type="Unix" ;;
 188   *-unknown-eabi*)
 189     llvm_cv_link_all_option="-Wl,--whole-archive"
 190     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 191     llvm_cv_os_type="Freestanding"
 192     llvm_cv_platform_type="Unix" ;;
 193   *-unknown-elf*)
 194     llvm_cv_link_all_option="-Wl,--whole-archive"
 195     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 196     llvm_cv_os_type="Freestanding"
 197     llvm_cv_platform_type="Unix" ;;
 198   *)
 199     llvm_cv_link_all_option=""
 200     llvm_cv_no_link_all_option=""
 201     llvm_cv_os_type="Unknown"
 202     llvm_cv_platform_type="Unknown" ;;
 203 esac])
 204
 205 AC_CACHE_CHECK([type of operating system we're going to target],
 206                [llvm_cv_target_os_type],
 207 [case $target in
 208   *-*-aix*)
 209     llvm_cv_target_os_type="AIX" ;;
 210   *-*-irix*)
 211     llvm_cv_target_os_type="IRIX" ;;
 212   *-*-cygwin*)
 213     llvm_cv_target_os_type="Cygwin" ;;
 214   *-*-darwin*)
 215     llvm_cv_target_os_type="Darwin" ;;
 216   *-*-freebsd*)
 217     llvm_cv_target_os_type="FreeBSD" ;;
 218   *-*-openbsd*)
 219     llvm_cv_target_os_type="OpenBSD" ;;
 220   *-*-netbsd*)
 221     llvm_cv_target_os_type="NetBSD" ;;
 222   *-*-dragonfly*)
 223     llvm_cv_target_os_type="DragonFly" ;;
 224   *-*-hpux*)
 225     llvm_cv_target_os_type="HP-UX" ;;
 226   *-*-interix*)
 227     llvm_cv_target_os_type="Interix" ;;
 228   *-*-linux*)
 229     llvm_cv_target_os_type="Linux" ;;
 230   *-*-solaris*)
 231     llvm_cv_target_os_type="SunOS" ;;
 232   *-*-auroraux*)
 233     llvm_cv_target_os_type="AuroraUX" ;;
 234   *-*-win32*)
 235     llvm_cv_target_os_type="Win32" ;;
 236   *-*-mingw*)
 237     llvm_cv_target_os_type="MingW" ;;
 238   *-*-haiku*)
 239     llvm_cv_target_os_type="Haiku" ;;
 240   *-unknown-eabi*)
 241     llvm_cv_target_os_type="Freestanding" ;;
 242   *)
 243     llvm_cv_target_os_type="Unknown" ;;
 244 esac])
 245
 246 dnl Make sure we aren't attempting to configure for an unknown system
 247 if test "$llvm_cv_os_type" = "Unknown" ; then
 248   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 249 fi
 250
 251 dnl Set the "OS" Makefile variable based on the platform type so the
 252 dnl makefile can configure itself to specific build hosts
 253 AC_SUBST(OS,$llvm_cv_os_type)
 254 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 255 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 256
 257 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 258 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 259 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 260
 261 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 262 dnl This is used by lib/System to determine the basic kind of implementation
 263 dnl to use.
 264 case $llvm_cv_platform_type in
 265   Unix)
 266     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 267     AC_SUBST(LLVM_ON_UNIX,[1])
 268     AC_SUBST(LLVM_ON_WIN32,[0])
 269     ;;
 270   Win32)
 271     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 272     AC_SUBST(LLVM_ON_UNIX,[0])
 273     AC_SUBST(LLVM_ON_WIN32,[1])
 274     ;;
 275 esac
 276
 277 dnl Determine what our target architecture is and configure accordingly.
 278 dnl This will allow Makefiles to make a distinction between the hardware and
 279 dnl the OS.
 280 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 281 [case $target in
 282   i?86-*)                 llvm_cv_target_arch="x86" ;;
 283   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 284   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 285   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 286   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 287   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 288   mips-*)                 llvm_cv_target_arch="Mips" ;;
 289   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 290   xcore-*)                llvm_cv_target_arch="XCore" ;;
 291   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 292   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 293   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 294   *)                      llvm_cv_target_arch="Unknown" ;;
 295 esac])
 296
 297 if test "$llvm_cv_target_arch" = "Unknown" ; then
 298   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 299 fi
 300
 301 # Determine the LLVM native architecture for the target
 302 case "$llvm_cv_target_arch" in
 303     x86)     LLVM_NATIVE_ARCH="X86" ;;
 304     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 305     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 306 esac
 307
 308 dnl Define a substitution, ARCH, for the target architecture
 309 AC_SUBST(ARCH,$llvm_cv_target_arch)
 310
 311 dnl Check for the endianness of the target
 312 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 313
 314 dnl Check for build platform executable suffix if we're crosscompiling
 315 if test "$cross_compiling" = yes; then
 316   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 317   AC_BUILD_EXEEXT
 318   ac_build_prefix=${build_alias}-
 319   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 320   if test -z "$BUILD_CXX"; then
 321      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 322      if test -z "$BUILD_CXX"; then
 323        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 324      fi
 325   fi
 326 else
 327   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 328 fi
 329
 330 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 331 dnl that this build is being done from a checkout. This sets up several
 332 dnl defaults for the command line switches. When we build with a CVS directory,
 333 dnl we get a debug with assertions turned on. Without, we assume a source
 334 dnl release and we get an optimized build without assertions.
 335 dnl See --enable-optimized and --enable-assertions below
 336 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 337   cvsbuild="yes"
 338   optimize="no"
 339   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 340 else
 341   cvsbuild="no"
 342   optimize="yes"
 343 fi
 344
 345 dnl===-----------------------------------------------------------------------===
 346 dnl===
 347 dnl=== SECTION 3: Command line arguments for the configure script.
 348 dnl===
 349 dnl===-----------------------------------------------------------------------===
 350
 351 dnl --enable-optimized : check whether they want to do an optimized build:
 352 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 353  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 354 if test ${enableval} = "no" ; then
 355   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 356 else
 357   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 358 fi
 359
 360 dnl --enable-profiling : check whether they want to do a profile build:
 361 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 362  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 363 if test ${enableval} = "no" ; then
 364   AC_SUBST(ENABLE_PROFILING,[[]])
 365 else
 366   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 367 fi
 368
 369 dnl --enable-assertions : check whether they want to turn on assertions or not:
 370 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 371   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 372 if test ${enableval} = "yes" ; then
 373   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 374 else
 375   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 376 fi
 377
 378 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 379 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 380   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 381 if test ${enableval} = "yes" ; then
 382   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 383   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 384 else
 385   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 386   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 387 fi
 388
 389 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 390 AC_ARG_ENABLE(debug-runtime,
 391    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 392 if test ${enableval} = "no" ; then
 393   AC_SUBST(DEBUG_RUNTIME,[[]])
 394 else
 395   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 396 fi
 397
 398 dnl --enable-debug-symbols : should even optimized compiler libraries
 399 dnl have debug symbols?
 400 AC_ARG_ENABLE(debug-symbols,
 401    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 402 if test ${enableval} = "no" ; then
 403   AC_SUBST(DEBUG_SYMBOLS,[[]])
 404 else
 405   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 406 fi
 407
 408 dnl --enable-jit: check whether they want to enable the jit
 409 AC_ARG_ENABLE(jit,
 410   AS_HELP_STRING(--enable-jit,
 411                  [Enable Just In Time Compiling (default is YES)]),,
 412   enableval=default)
 413 if test ${enableval} = "no"
 414 then
 415   AC_SUBST(JIT,[[]])
 416 else
 417   case "$llvm_cv_target_arch" in
 418     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 419     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 420     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 421     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 422     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 423     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 424     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 425     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 426     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 427     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 428     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 429     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 430     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 431   esac
 432 fi
 433
 434 dnl Allow enablement of doxygen generated documentation
 435 AC_ARG_ENABLE(doxygen,
 436               AS_HELP_STRING([--enable-doxygen],
 437                              [Build doxygen documentation (default is NO)]),,
 438                              enableval=default)
 439 case "$enableval" in
 440   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 441   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 442   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 443   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 444 esac
 445
 446 dnl Allow disablement of threads
 447 AC_ARG_ENABLE(threads,
 448               AS_HELP_STRING([--enable-threads],
 449                              [Use threads if available (default is YES)]),,
 450                              enableval=default)
 451 case "$enableval" in
 452   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 453   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 454   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 455   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 456 esac
 457 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 458
 459 dnl Allow building without position independent code
 460 AC_ARG_ENABLE(pic,
 461   AS_HELP_STRING([--enable-pic],
 462                  [Build LLVM with Position Independent Code (default is YES)]),,
 463                  enableval=default)
 464 case "$enableval" in
 465   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 466   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 467   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 468   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 469 esac
 470 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 471                    [Define if position independent code is enabled])
 472
 473 dnl Allow specific targets to be specified for building (or not)
 474 TARGETS_TO_BUILD=""
 475 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 476     [Build specific host targets: all or target1,target2,... Valid targets are:
 477      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu, pic16,
 478      xcore, msp430, systemz, blackfin, cbe, msil, and cpp (default=all)]),,
 479     enableval=all)
 480 if test "$enableval" = host-only ; then
 481   enableval=host
 482 fi
 483 case "$enableval" in
 484   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend MSIL CppBackend" ;;
 485   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 486       case "$a_target" in
 487         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 488         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 489         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 490         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 491         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 492         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 493         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 494         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 495         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 496         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 497         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 498         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 499         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 500         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 501         msil)     TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 502         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 503         host) case "$llvm_cv_target_arch" in
 504             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 505             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 506             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 507             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 508             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 509             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 510             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 511             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 512             PIC16)       TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 513             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 514             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 515             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 516             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 517             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 518           esac ;;
 519         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 520       esac
 521   done
 522   ;;
 523 esac
 524 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 525
 526 # Determine whether we are building LLVM support for the native architecture.
 527 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 528 for a_target in $TARGETS_TO_BUILD; do
 529   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 530     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 531     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 532       [LLVM architecture name for the native architecture, if available])
 533   fi
 534 done
 535
 536 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 537 # target feature def files.
 538 LLVM_ENUM_TARGETS=""
 539 LLVM_ENUM_ASM_PRINTERS=""
 540 LLVM_ENUM_ASM_PARSERS=""
 541 LLVM_ENUM_DISASSEMBLERS=""
 542 for target_to_build in $TARGETS_TO_BUILD; do
 543   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 544   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 545     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 546   fi
 547   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 548     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 549   fi
 550   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 551     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 552   fi
 553 done
 554 AC_SUBST(LLVM_ENUM_TARGETS)
 555 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 556 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 557 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 558
 559 dnl Prevent the CBackend from using printf("%a") for floating point so older
 560 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 561 dnl can still compile the CBE's output
 562 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 563   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 564   enableval=default)
 565 case "$enableval" in
 566   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 567   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 568   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 569   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 570 esac
 571 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 572                    [Define if CBE is enabled for printf %a output])
 573
 574 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 575 AC_ARG_WITH(llvmgccdir,
 576   AS_HELP_STRING([--with-llvmgccdir],
 577     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 578     withval=default)
 579 case "$withval" in
 580   default) WITH_LLVMGCCDIR=default ;;
 581   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 582   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 583 esac
 584
 585 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 586 AC_ARG_WITH(llvmgcc,
 587   AS_HELP_STRING([--with-llvmgcc],
 588     [Specify location of llvm-gcc driver (default searches PATH)]),
 589     LLVMGCC=$with_llvmgcc
 590       WITH_LLVMGCCDIR="",)
 591
 592 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 593 AC_ARG_WITH(llvmgxx,
 594   AS_HELP_STRING([--with-llvmgxx],
 595     [Specify location of llvm-g++ driver (default searches PATH)]),
 596     LLVMGXX=$with_llvmgxx
 597     WITH_LLVMGCCDIR="",)
 598
 599 if test -n "$LLVMGCC"; then
 600    LLVMGCCCOMMAND="$LLVMGCC"
 601 fi
 602
 603 if test -n "$LLVMGXX"; then
 604    LLVMGXXCOMMAND="$LLVMGXX"
 605 fi
 606
 607 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 608    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 609 fi
 610
 611 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 612    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 613 fi
 614
 615 dnl Allow a specific Clang compiler to be used with this LLVM config.
 616 AC_ARG_WITH(clang,
 617   AS_HELP_STRING([--with-clang],
 618     [Specify location of clang compiler (default is --with-built-clang)]),
 619     [],[with_clang=default])
 620
 621 dnl Enable use of the built Clang.
 622 AC_ARG_WITH(built-clang,
 623   AS_HELP_STRING([--with-built-clang],
 624     [Use the compiled Clang as the LLVM compiler (default=check)]),
 625     [],[with_built_clang=check])
 626
 627 dnl Select the Clang compiler option.
 628 dnl
 629 dnl If --with-clang is given, always honor that; otherwise honor
 630 dnl --with-built-clang, or check if we have the clang sources.
 631 AC_MSG_CHECKING([clang compiler])
 632 WITH_CLANGPATH=""
 633 WITH_BUILT_CLANG=0
 634 if test "$with_clang" != "default"; then
 635    WITH_CLANGPATH="$with_clang"
 636    if ! test -x "$WITH_CLANGPATH"; then
 637      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 638    fi
 639 elif test "$with_built_clang" = "yes"; then
 640    WITH_BUILT_CLANG=1
 641 elif test "$with_built_clang" = "no"; then
 642    WITH_BUILT_CLANG=0
 643 else
 644    if test "$with_built_clang" != "check"; then
 645       AC_MSG_ERROR([invalid value for --with-built-clang.])
 646    fi
 647
 648    if test -f ${srcdir}/tools/clang/README.txt; then
 649      WITH_BUILT_CLANG=1
 650    fi
 651 fi
 652
 653 if ! test -z "$WITH_CLANGPATH"; then
 654    AC_MSG_RESULT([$WITH_CLANGPATH])
 655    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 656 elif test "$WITH_BUILT_CLANG" = "1"; then
 657    AC_MSG_RESULT([built])
 658 else
 659    AC_MSG_RESULT([none])
 660 fi
 661 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 662 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 663 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 664
 665 dnl Override the option to use for optimized builds.
 666 AC_ARG_WITH(optimize-option,
 667   AS_HELP_STRING([--with-optimize-option],
 668                  [Select the compiler options to use for optimized builds]),,
 669                  withval=default)
 670 AC_MSG_CHECKING([optimization flags])
 671 case "$withval" in
 672   default)
 673     case "$llvm_cv_os_type" in
 674     MingW) optimize_option=-O3 ;;
 675     *)     optimize_option=-O2 ;;
 676     esac ;;
 677   *) optimize_option="$withval" ;;
 678 esac
 679 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 680 AC_MSG_RESULT([$optimize_option])
 681
 682 dnl Specify extra build options
 683 AC_ARG_WITH(extra-options,
 684   AS_HELP_STRING([--with-extra-options],
 685                  [Specify additional options to compile LLVM with]),,
 686                  withval=default)
 687 case "$withval" in
 688   default) EXTRA_OPTIONS= ;;
 689   *) EXTRA_OPTIONS=$withval ;;
 690 esac
 691 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 692
 693 dnl Allow specific bindings to be specified for building (or not)
 694 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 695     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 696     enableval=default)
 697 BINDINGS_TO_BUILD=""
 698 case "$enableval" in
 699   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 700   all ) BINDINGS_TO_BUILD="ocaml" ;;
 701   none | no) BINDINGS_TO_BUILD="" ;;
 702   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 703       case "$a_binding" in
 704         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 705         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 706       esac
 707   done
 708   ;;
 709 esac
 710
 711 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 712 dnl script for bindings/ocaml/configure, except that its auto value depends on
 713 dnl OCAMLC, which is found here to support tests.
 714 AC_ARG_WITH([ocaml-libdir],
 715   [AS_HELP_STRING([--with-ocaml-libdir],
 716     [Specify install location for ocaml bindings (default is stdlib)])],
 717   [],
 718   [withval=auto])
 719 case "$withval" in
 720   auto) with_ocaml_libdir="$withval" ;;
 721   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 722   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 723 esac
 724
 725 AC_ARG_WITH(c-include-dirs,
 726   AS_HELP_STRING([--with-c-include-dirs],
 727     [Colon separated list of directories clang will search for headers]),,
 728     withval="")
 729 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 730                    [Directories clang will search for headers])
 731
 732 AC_ARG_WITH(cxx-include-root,
 733   AS_HELP_STRING([--with-cxx-include-root],
 734     [Directory with the libstdc++ headers.]),,
 735     withval="")
 736 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 737                    [Directory with the libstdc++ headers.])
 738
 739 AC_ARG_WITH(cxx-include-arch,
 740   AS_HELP_STRING([--with-cxx-include-arch],
 741     [Architecture of the libstdc++ headers.]),,
 742     withval="")
 743 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 744                    [Arch the libstdc++ headers.])
 745
 746 AC_ARG_WITH(cxx-include-32bit-dir,
 747   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 748     [32 bit multilib dir.]),,
 749     withval="")
 750 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 751                    [32 bit multilib directory.])
 752
 753 AC_ARG_WITH(cxx-include-64bit-dir,
 754   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 755     [64 bit multilib directory.]),,
 756     withval="")
 757 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 758                    [64 bit multilib directory.])
 759
 760 dnl Allow linking of LLVM with GPLv3 binutils code.
 761 AC_ARG_WITH(binutils-include,
 762   AS_HELP_STRING([--with-binutils-include],
 763     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 764   withval=default)
 765 case "$withval" in
 766   default) WITH_BINUTILS_INCDIR=default ;;
 767   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 768   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 769 esac
 770 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 771   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 772   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 773      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 774      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 775   fi
 776 fi
 777
 778 dnl --enable-libffi : check whether the user wants to turn off libffi:
 779 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 780   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 781   [case "$enableval" in
 782     yes) llvm_cv_enable_libffi="yes" ;;
 783     no)  llvm_cv_enable_libffi="no"  ;;
 784     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 785   esac],
 786   llvm_cv_enable_libffi=no)
 787
 788 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 789 if test "$llvm_cv_os_type" = "Win32" ; then
 790    llvmc_dynamic="yes"
 791 else
 792    llvmc_dynamic="no"
 793 fi
 794
 795 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 796 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 797 --enable-llvmc-dynamic,
 798 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 799 enableval=$llvmc_dynamic)
 800 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 801    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 802 else
 803    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 804 fi
 805
 806 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 807 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 808 --enable-llvmc-dynamic-plugins,
 809 [Enable dynamic LLVMC plugins (default is YES)]),,
 810 enableval=yes)
 811 if test ${enableval} = "yes" ; then
 812    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 813 else
 814    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 815 fi
 816
 817 dnl===-----------------------------------------------------------------------===
 818 dnl===
 819 dnl=== SECTION 4: Check for programs we need and that they are the right version
 820 dnl===
 821 dnl===-----------------------------------------------------------------------===
 822
 823 dnl Check for compilation tools
 824 AC_PROG_CPP
 825 AC_PROG_CC(gcc)
 826 AC_PROG_CXX(g++)
 827
 828 AC_PROG_NM
 829 AC_SUBST(NM)
 830
 831 dnl Check for the tools that the makefiles require
 832 AC_CHECK_GNU_MAKE
 833 AC_PROG_LN_S
 834 AC_PATH_PROG(CMP, [cmp], [cmp])
 835 AC_PATH_PROG(CP, [cp], [cp])
 836 AC_PATH_PROG(DATE, [date], [date])
 837 AC_PATH_PROG(FIND, [find], [find])
 838 AC_PATH_PROG(GREP, [grep], [grep])
 839 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 840 AC_PATH_PROG(MV,   [mv],   [mv])
 841 AC_PROG_RANLIB
 842 AC_CHECK_TOOL(AR, ar, false)
 843 AC_PATH_PROG(RM,   [rm],   [rm])
 844 AC_PATH_PROG(SED,  [sed],  [sed])
 845 AC_PATH_PROG(TAR,  [tar],  [gtar])
 846 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 847
 848 dnl Looking for misc. graph plotting software
 849 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 850 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 851   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 852   dnl If we're targeting for mingw we should emit windows paths, not msys
 853   if test "$llvm_cv_os_type" = "MingW" ; then
 854     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 855   fi
 856   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 857    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 858 fi
 859 AC_PATH_PROG(DOT, [dot], [echo dot])
 860 if test "$DOT" != "echo dot" ; then
 861   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 862   dnl If we're targeting for mingw we should emit windows paths, not msys
 863   if test "$llvm_cv_os_type" = "MingW" ; then
 864     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 865   fi
 866   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 867    [Define to path to dot program if found or 'echo dot' otherwise])
 868 fi
 869 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 870 if test "$FDP" != "echo fdp" ; then
 871   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 872   dnl If we're targeting for mingw we should emit windows paths, not msys
 873   if test "$llvm_cv_os_type" = "MingW" ; then
 874     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 875   fi
 876   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 877    [Define to path to fdp program if found or 'echo fdp' otherwise])
 878 fi
 879 AC_PATH_PROG(NEATO, [neato], [echo neato])
 880 if test "$NEATO" != "echo neato" ; then
 881   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 882   dnl If we're targeting for mingw we should emit windows paths, not msys
 883   if test "$llvm_cv_os_type" = "MingW" ; then
 884     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 885   fi
 886   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 887    [Define to path to neato program if found or 'echo neato' otherwise])
 888 fi
 889 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 890 if test "$TWOPI" != "echo twopi" ; then
 891   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 892   dnl If we're targeting for mingw we should emit windows paths, not msys
 893   if test "$llvm_cv_os_type" = "MingW" ; then
 894     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 895   fi
 896   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 897    [Define to path to twopi program if found or 'echo twopi' otherwise])
 898 fi
 899 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 900 if test "$CIRCO" != "echo circo" ; then
 901   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 902   dnl If we're targeting for mingw we should emit windows paths, not msys
 903   if test "$llvm_cv_os_type" = "MingW" ; then
 904     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 905   fi
 906   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 907    [Define to path to circo program if found or 'echo circo' otherwise])
 908 fi
 909 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 910 if test "$GV" != "echo gv" ; then
 911   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 912   dnl If we're targeting for mingw we should emit windows paths, not msys
 913   if test "$llvm_cv_os_type" = "MingW" ; then
 914     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 915   fi
 916   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 917    [Define to path to gv program if found or 'echo gv' otherwise])
 918 fi
 919 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 920 if test "$DOTTY" != "echo dotty" ; then
 921   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 922   dnl If we're targeting for mingw we should emit windows paths, not msys
 923   if test "$llvm_cv_os_type" = "MingW" ; then
 924     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 925   fi
 926   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 927    [Define to path to dotty program if found or 'echo dotty' otherwise])
 928 fi
 929
 930 dnl Look for a sufficiently recent version of Perl.
 931 LLVM_PROG_PERL([5.006])
 932 AC_SUBST(PERL)
 933 if test x"$PERL" = xnone; then
 934    AC_SUBST(HAVE_PERL,0)
 935    AC_MSG_ERROR([perl is required but was not found, please install it])
 936 else
 937    AC_SUBST(HAVE_PERL,1)
 938 fi
 939
 940 dnl Find the install program
 941 AC_PROG_INSTALL
 942
 943 dnl Checks for documentation and testing tools that we can do without. If these
 944 dnl are not found then they are set to "true" which always succeeds but does
 945 dnl nothing. This just lets the build output show that we could have done
 946 dnl something if the tool was available.
 947 AC_PATH_PROG(BZIP2, [bzip2])
 948 AC_PATH_PROG(DOXYGEN, [doxygen])
 949 AC_PATH_PROG(GROFF, [groff])
 950 AC_PATH_PROG(GZIP, [gzip])
 951 AC_PATH_PROG(POD2HTML, [pod2html])
 952 AC_PATH_PROG(POD2MAN, [pod2man])
 953 AC_PATH_PROG(RUNTEST, [runtest])
 954 DJ_AC_PATH_TCLSH
 955 AC_PATH_PROG(ZIP, [zip])
 956 AC_PATH_PROGS(OCAMLC, [ocamlc])
 957 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 958 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 959 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 960 AC_PATH_PROGS(GAS, [gas as])
 961
 962 dnl Determine whether the linker supports the -R option.
 963 AC_LINK_USE_R
 964
 965 dnl Determine whether the linker supports the -export-dynamic option.
 966 AC_LINK_EXPORT_DYNAMIC
 967
 968 dnl Check for libtool and the library that has dlopen function (which must come
 969 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 970 dnl libtool).
 971 AC_LIBTOOL_DLOPEN
 972 AC_LIB_LTDL
 973
 974 if test "$WITH_LLVMGCCDIR" = "default" ; then
 975   LLVMGCC="llvm-gcc${EXEEXT}"
 976   LLVMGXX="llvm-g++${EXEEXT}"
 977   LLVMGCCCOMMAND="$LLVMGCC"
 978   LLVMGXXCOMMAND="$LLVMGXX"
 979   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 980   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 981   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 982   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 983 else
 984   if test -z "$LLVMGCC"; then
 985     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 986     LLVMGCCCOMMAND="$LLVMGCC"
 987   fi
 988   if test -z "$LLVMGXX"; then
 989     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 990     LLVMGXXCOMMAND="$LLVMGXX"
 991   fi
 992
 993   AC_SUBST(LLVMGCC,$LLVMGCC)
 994   AC_SUBST(LLVMGXX,$LLVMGXX)
 995   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 996   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 997 fi
 998
 999 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1000 dnl found, otherwise clang if available.
1001 AC_ARG_WITH(llvmcc,
1002   AS_HELP_STRING([--with-llvmcc=<name>],
1003     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1004     [],[with_llvmcc=check])
1005 AC_MSG_CHECKING([LLVM capable compiler])
1006 if test "$with_llvmcc" != "check"; then
1007    if (test "$with_llvmcc" != "llvm-gcc" &&
1008        test "$with_llvmcc" != "clang" &&
1009        test "$with_llvmcc" != "none"); then
1010       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1011    fi
1012    WITH_LLVMCC="$with_llvmcc"
1013 elif test -n "$LLVMGCC"; then
1014    WITH_LLVMCC=llvm-gcc
1015 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1016    WITH_LLVMCC=clang
1017 else
1018    WITH_LLVMCC=none
1019 fi
1020 AC_MSG_RESULT([$WITH_LLVMCC])
1021 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1022
1023 AC_MSG_CHECKING([tool compatibility])
1024
1025 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1026 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1027 dnl to support those options.
1028 dnl "icc" emits gcc signatures
1029 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1030 ICC=no
1031 IXX=no
1032 case $CC in
1033   icc*|icpc*)
1034     ICC=yes
1035     IXX=yes
1036     ;;
1037    *)
1038     ;;
1039 esac
1040
1041 if test "$GCC" != "yes" && test "$ICC" != "yes"
1042 then
1043   AC_MSG_ERROR([gcc|icc required but not found])
1044 fi
1045
1046 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
1047 if test "$GXX" != "yes" && test "$IXX" != "yes"
1048 then
1049   AC_MSG_ERROR([g++|icc required but not found])
1050 fi
1051
1052 dnl Verify that GCC is version 3.0 or higher
1053 if test "$GCC" = "yes"
1054 then
1055   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1056 #error Unsupported GCC version
1057 #endif
1058 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1059 fi
1060
1061 dnl Check for GNU Make.  We use its extensions, so don't build without it
1062 if test -z "$llvm_cv_gnu_make_command"
1063 then
1064   AC_MSG_ERROR([GNU Make required but not found])
1065 fi
1066
1067 dnl Tool compatibility is okay if we make it here.
1068 AC_MSG_RESULT([ok])
1069
1070 dnl Check optional compiler flags.
1071 AC_MSG_CHECKING([optional compiler flags])
1072 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1073 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1074 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1075
1076 dnl===-----------------------------------------------------------------------===
1077 dnl===
1078 dnl=== SECTION 5: Check for libraries
1079 dnl===
1080 dnl===-----------------------------------------------------------------------===
1081
1082 AC_CHECK_LIB(m,sin)
1083 if test "$llvm_cv_os_type" = "MingW" ; then
1084   AC_CHECK_LIB(imagehlp, main)
1085   AC_CHECK_LIB(psapi, main)
1086 fi
1087
1088 dnl dlopen() is required for plugin support.
1089 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1090                [Define if dlopen() is available on this platform.]),
1091                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1092
1093 dnl libffi is optional; used to call external functions from the interpreter
1094 if test "$llvm_cv_enable_libffi" = "yes" ; then
1095   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1096                  [Define if libffi is available on this platform.]),
1097                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1098 fi
1099
1100 dnl mallinfo is optional; the code can compile (minus features) without it
1101 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1102                [Define if mallinfo() is available on this platform.]))
1103
1104 dnl pthread locking functions are optional - but llvm will not be thread-safe
1105 dnl without locks.
1106 if test "$ENABLE_THREADS" -eq 1 ; then
1107   AC_CHECK_LIB(pthread, pthread_mutex_init)
1108   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1109                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1110                            [Have pthread_mutex_lock]))
1111   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1112                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1113                  [Have pthread_rwlock_init]))
1114   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1115                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1116                  [Have pthread_getspecific]))
1117 fi
1118
1119 dnl Allow extra x86-disassembler library
1120 AC_ARG_WITH(udis86,
1121   AS_HELP_STRING([--with-udis86=<path>],
1122     [Use udis86 external x86 disassembler library]),
1123     [
1124       AC_SUBST(USE_UDIS86, [1])
1125       case "$withval" in
1126         /usr/lib|yes) ;;
1127         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1128       esac
1129       AC_CHECK_LIB(udis86, ud_init, [], [
1130         echo "Error! You need to have libudis86 around."
1131         exit -1
1132       ])
1133     ],
1134     AC_SUBST(USE_UDIS86, [0]))
1135 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1136                    [Define if use udis86 library])
1137
1138 dnl Allow OProfile support for JIT output.
1139 AC_ARG_WITH(oprofile,
1140   AS_HELP_STRING([--with-oprofile=<prefix>],
1141     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1142     [
1143       AC_SUBST(USE_OPROFILE, [1])
1144       case "$withval" in
1145         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1146         no) llvm_cv_oppath=
1147             AC_SUBST(USE_OPROFILE, [0]) ;;
1148         *) llvm_cv_oppath="${withval}/lib/oprofile"
1149            CPPFLAGS="-I${withval}/include";;
1150       esac
1151       if test -n "$llvm_cv_oppath" ; then
1152         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1153         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1154         dnl libbfd is not included properly in libopagent in some Debian
1155         dnl versions.  If libbfd isn't found at all, we assume opagent works
1156         dnl anyway.
1157         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1158         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1159           echo "Error! You need to have libopagent around."
1160           exit -1
1161         ])
1162         AC_CHECK_HEADER([opagent.h], [], [
1163           echo "Error! You need to have opagent.h around."
1164           exit -1
1165           ])
1166       fi
1167     ],
1168     [
1169       AC_SUBST(USE_OPROFILE, [0])
1170     ])
1171 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1172                    [Define if we have the oprofile JIT-support library])
1173
1174 dnl===-----------------------------------------------------------------------===
1175 dnl===
1176 dnl=== SECTION 6: Check for header files
1177 dnl===
1178 dnl===-----------------------------------------------------------------------===
1179
1180 dnl First, use autoconf provided macros for specific headers that we need
1181 dnl We don't check for ancient stuff or things that are guaranteed to be there
1182 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1183 dnl Generally we're looking for POSIX headers.
1184 AC_HEADER_DIRENT
1185 AC_HEADER_MMAP_ANONYMOUS
1186 AC_HEADER_STAT
1187 AC_HEADER_STDC
1188 AC_HEADER_SYS_WAIT
1189 AC_HEADER_TIME
1190
1191 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1192 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1193 AC_CHECK_HEADERS([utime.h windows.h])
1194 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1195 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1196 if test "$ENABLE_THREADS" -eq 1 ; then
1197   AC_CHECK_HEADERS(pthread.h,
1198                    AC_SUBST(HAVE_PTHREAD, 1),
1199                    AC_SUBST(HAVE_PTHREAD, 0))
1200 else
1201   AC_SUBST(HAVE_PTHREAD, 0)
1202 fi
1203
1204 dnl Try to find ffi.h.
1205 if test "$llvm_cv_enable_libffi" = "yes" ; then
1206   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1207 fi
1208
1209 dnl===-----------------------------------------------------------------------===
1210 dnl===
1211 dnl=== SECTION 7: Check for types and structures
1212 dnl===
1213 dnl===-----------------------------------------------------------------------===
1214
1215 AC_HUGE_VAL_CHECK
1216 AC_TYPE_PID_T
1217 AC_TYPE_SIZE_T
1218 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1219 AC_STRUCT_TM
1220 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1221 AC_CHECK_TYPES([uint64_t],,
1222          AC_CHECK_TYPES([u_int64_t],,
1223          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1224
1225 dnl===-----------------------------------------------------------------------===
1226 dnl===
1227 dnl=== SECTION 8: Check for specific functions needed
1228 dnl===
1229 dnl===-----------------------------------------------------------------------===
1230
1231 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1232 AC_CHECK_FUNCS([powf fmodf strtof round ])
1233 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1234 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1235 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup ])
1236 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1237 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1238 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1239 AC_C_PRINTF_A
1240 AC_FUNC_RAND48
1241
1242 dnl Check for variations in the Standard C++ library and STL. These macros are
1243 dnl provided by LLVM in the autoconf/m4 directory.
1244 AC_FUNC_ISNAN
1245 AC_FUNC_ISINF
1246
1247 dnl Check for mmap support.We also need to know if /dev/zero is required to
1248 dnl be opened for allocating RWX memory.
1249 dnl Make sure we aren't attempting to configure for an unknown system
1250 if test "$llvm_cv_platform_type" = "Unix" ; then
1251   AC_FUNC_MMAP
1252   AC_FUNC_MMAP_FILE
1253   AC_NEED_DEV_ZERO_FOR_MMAP
1254
1255   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1256   then
1257     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1258   fi
1259   if test "$ac_cv_func_mmap_file" = "no"
1260   then
1261     AC_MSG_WARN([mmap() of files required but not found])
1262   fi
1263 fi
1264
1265 dnl atomic builtins are required for threading support.
1266 AC_MSG_CHECKING(for GCC atomic builtins)
1267 AC_LINK_IFELSE(
1268   AC_LANG_SOURCE(
1269     [[int main() {
1270         volatile unsigned long val = 1;
1271         __sync_synchronize();
1272         __sync_val_compare_and_swap(&val, 1, 0);
1273         __sync_add_and_fetch(&val, 1);
1274         __sync_sub_and_fetch(&val, 1);
1275         return 0;
1276       }
1277     ]]),
1278   AC_MSG_RESULT(yes)
1279   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1280   AC_MSG_RESULT(no)
1281   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1282   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1283
1284
1285 dnl===-----------------------------------------------------------------------===
1286 dnl===
1287 dnl=== SECTION 9: Additional checks, variables, etc.
1288 dnl===
1289 dnl===-----------------------------------------------------------------------===
1290
1291 dnl Handle 32-bit linux systems running a 64-bit kernel.
1292 dnl This has to come after section 4 because it invokes the compiler.
1293 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1294   AC_IS_LINUX_MIXED
1295   if test "$llvm_cv_linux_mixed" = "yes"; then
1296     llvm_cv_target_arch="x86"
1297     ARCH="x86"
1298   fi
1299 fi
1300
1301 dnl Check, whether __dso_handle is present
1302 AC_CHECK_FUNCS([__dso_handle])
1303
1304 dnl See if the llvm-gcc executable can compile to LLVM assembly
1305 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1306 [llvm_cv_llvmgcc_sanity="no"
1307 if test -x "$LLVMGCC" ; then
1308   cp /dev/null conftest.c
1309   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1310       grep 'target datalayout =' > /dev/null 2>&1
1311   if test $? -eq 0 ; then
1312     llvm_cv_llvmgcc_sanity="yes"
1313   fi
1314   rm conftest.c
1315 fi])
1316
1317 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1318 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1319   AC_MSG_CHECKING([llvm-gcc component support])
1320   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1321   AC_SUBST(LLVMCC1,$llvmcc1path)
1322   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1323   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1324   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1325   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1326   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1327   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1328   AC_MSG_RESULT([ok])
1329 fi
1330
1331 dnl Propagate the shared library extension that the libltdl checks did to
1332 dnl the Makefiles so we can use it there too
1333 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1334
1335 # Translate the various configuration directories and other basic
1336 # information into substitutions that will end up in Makefile.config.in
1337 # that these configured values can be used by the makefiles
1338 if test "${prefix}" = "NONE" ; then
1339   prefix="/usr/local"
1340 fi
1341 eval LLVM_PREFIX="${prefix}";
1342 eval LLVM_BINDIR="${prefix}/bin";
1343 eval LLVM_LIBDIR="${prefix}/lib";
1344 eval LLVM_DATADIR="${prefix}/share/llvm";
1345 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
1346 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1347 eval LLVM_INCLUDEDIR="${prefix}/include";
1348 eval LLVM_INFODIR="${prefix}/info";
1349 eval LLVM_MANDIR="${prefix}/man";
1350 LLVM_CONFIGTIME=`date`
1351 AC_SUBST(LLVM_PREFIX)
1352 AC_SUBST(LLVM_BINDIR)
1353 AC_SUBST(LLVM_LIBDIR)
1354 AC_SUBST(LLVM_DATADIR)
1355 AC_SUBST(LLVM_DOCSDIR)
1356 AC_SUBST(LLVM_ETCDIR)
1357 AC_SUBST(LLVM_INCLUDEDIR)
1358 AC_SUBST(LLVM_INFODIR)
1359 AC_SUBST(LLVM_MANDIR)
1360 AC_SUBST(LLVM_CONFIGTIME)
1361
1362 # Place the various directores into the config.h file as #defines so that we
1363 # can know about the installation paths within LLVM.
1364 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1365                    [Installation prefix directory])
1366 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1367                    [Installation directory for binary executables])
1368 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1369                    [Installation directory for libraries])
1370 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1371                    [Installation directory for data files])
1372 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1373                    [Installation directory for documentation])
1374 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1375                    [Installation directory for config files])
1376 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1377                    [Installation directory for include files])
1378 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1379                    [Installation directory for .info files])
1380 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1381                    [Installation directory for man pages])
1382 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1383                    [Time at which LLVM was configured])
1384 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1385                    [Host triple we were built on])
1386
1387 # Determine which bindings to build.
1388 if test "$BINDINGS_TO_BUILD" = auto ; then
1389   BINDINGS_TO_BUILD=""
1390   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1391     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1392   fi
1393 fi
1394 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1395
1396 # This isn't really configurey, but it avoids having to repeat the list in
1397 # other files.
1398 AC_SUBST(ALL_BINDINGS,ocaml)
1399
1400 # Do any work necessary to ensure that bindings have what they need.
1401 binding_prereqs_failed=0
1402 for a_binding in $BINDINGS_TO_BUILD ; do
1403   case "$a_binding" in
1404   ocaml)
1405     if test "x$OCAMLC" = x ; then
1406       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1407       binding_prereqs_failed=1
1408     fi
1409     if test "x$OCAMLDEP" = x ; then
1410       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1411       binding_prereqs_failed=1
1412     fi
1413     if test "x$OCAMLOPT" = x ; then
1414       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1415       dnl ocamlopt is optional!
1416     fi
1417     if test "x$with_ocaml_libdir" != xauto ; then
1418       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1419     else
1420       ocaml_stdlib="`"$OCAMLC" -where`"
1421       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1422       then
1423         # ocaml stdlib is beneath our prefix; use stdlib
1424         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1425       else
1426         # ocaml stdlib is outside our prefix; use libdir/ocaml
1427         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1428       fi
1429     fi
1430     ;;
1431   esac
1432 done
1433 if test "$binding_prereqs_failed" = 1 ; then
1434   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1435 fi
1436
1437 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1438 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1439
1440 dnl Determine linker rpath flag
1441 if test "$llvm_cv_link_use_r" = "yes" ; then
1442   RPATH="-Wl,-R"
1443 else
1444   RPATH="-Wl,-rpath"
1445 fi
1446 AC_SUBST(RPATH)
1447
1448 dnl Determine linker rdynamic flag
1449 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1450   RDYNAMIC="-Wl,-export-dynamic"
1451 else
1452   RDYNAMIC=""
1453 fi
1454 AC_SUBST(RDYNAMIC)
1455
1456 dnl===-----------------------------------------------------------------------===
1457 dnl===
1458 dnl=== SECTION 10: Specify the output files and generate it
1459 dnl===
1460 dnl===-----------------------------------------------------------------------===
1461
1462 dnl Configure header files
1463 dnl WARNING: dnl If you add or remove any of the following config headers, then
1464 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1465 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1466 dnl files can be updated automatically when their *.in sources change.
1467 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1468 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1469 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1470 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1471 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1472 AC_CONFIG_HEADERS([include/llvm/System/DataTypes.h])
1473
1474 dnl Configure the makefile's configuration data
1475 AC_CONFIG_FILES([Makefile.config])
1476
1477 dnl Configure the RPM spec file for LLVM
1478 AC_CONFIG_FILES([llvm.spec])
1479
1480 dnl Configure doxygen's configuration file
1481 AC_CONFIG_FILES([docs/doxygen.cfg])
1482
1483 dnl Configure llvmc's Base plugin
1484 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1485
1486 dnl Do the first stage of configuration for llvm-config.in.
1487 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1488
1489 dnl Do special configuration of Makefiles
1490 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1491 AC_CONFIG_MAKEFILE(Makefile)
1492 AC_CONFIG_MAKEFILE(Makefile.common)
1493 AC_CONFIG_MAKEFILE(examples/Makefile)
1494 AC_CONFIG_MAKEFILE(lib/Makefile)
1495 AC_CONFIG_MAKEFILE(runtime/Makefile)
1496 AC_CONFIG_MAKEFILE(test/Makefile)
1497 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1498 AC_CONFIG_MAKEFILE(unittests/Makefile)
1499 AC_CONFIG_MAKEFILE(tools/Makefile)
1500 AC_CONFIG_MAKEFILE(utils/Makefile)
1501 AC_CONFIG_MAKEFILE(projects/Makefile)
1502 AC_CONFIG_MAKEFILE(bindings/Makefile)
1503 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1504
1505 dnl Finally, crank out the output
1506 AC_OUTPUT