autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.7svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2009 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2009 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-auroraux*)
 169     llvm_cv_link_all_option="-Wl,-z,allextract"
 170     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 171     llvm_cv_os_type="AuroraUX"
 172     llvm_cv_platform_type="Unix" ;;
 173   *-*-win32*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="Win32"
 177     llvm_cv_platform_type="Win32" ;;
 178   *-*-mingw*)
 179     llvm_cv_link_all_option="-Wl,--whole-archive"
 180     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 181     llvm_cv_os_type="MingW"
 182     llvm_cv_platform_type="Win32" ;;
 183   *-*-haiku*)
 184     llvm_cv_link_all_option="-Wl,--whole-archive"
 185     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 186     llvm_cv_os_type="Haiku"
 187     llvm_cv_platform_type="Unix" ;;
 188   *-unknown-eabi*)
 189     llvm_cv_link_all_option="-Wl,--whole-archive"
 190     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 191     llvm_cv_os_type="Freestanding"
 192     llvm_cv_platform_type="Unix" ;;
 193   *-unknown-elf*)
 194     llvm_cv_link_all_option="-Wl,--whole-archive"
 195     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 196     llvm_cv_os_type="Freestanding"
 197     llvm_cv_platform_type="Unix" ;;
 198   *)
 199     llvm_cv_link_all_option=""
 200     llvm_cv_no_link_all_option=""
 201     llvm_cv_os_type="Unknown"
 202     llvm_cv_platform_type="Unknown" ;;
 203 esac])
 204
 205 AC_CACHE_CHECK([type of operating system we're going to target],
 206                [llvm_cv_target_os_type],
 207 [case $target in
 208   *-*-aix*)
 209     llvm_cv_target_os_type="AIX" ;;
 210   *-*-irix*)
 211     llvm_cv_target_os_type="IRIX" ;;
 212   *-*-cygwin*)
 213     llvm_cv_target_os_type="Cygwin" ;;
 214   *-*-darwin*)
 215     llvm_cv_target_os_type="Darwin" ;;
 216   *-*-freebsd*)
 217     llvm_cv_target_os_type="FreeBSD" ;;
 218   *-*-openbsd*)
 219     llvm_cv_target_os_type="OpenBSD" ;;
 220   *-*-netbsd*)
 221     llvm_cv_target_os_type="NetBSD" ;;
 222   *-*-dragonfly*)
 223     llvm_cv_target_os_type="DragonFly" ;;
 224   *-*-hpux*)
 225     llvm_cv_target_os_type="HP-UX" ;;
 226   *-*-interix*)
 227     llvm_cv_target_os_type="Interix" ;;
 228   *-*-linux*)
 229     llvm_cv_target_os_type="Linux" ;;
 230   *-*-solaris*)
 231     llvm_cv_target_os_type="SunOS" ;;
 232   *-*-auroraux*)
 233     llvm_cv_target_os_type="AuroraUX" ;;
 234   *-*-win32*)
 235     llvm_cv_target_os_type="Win32" ;;
 236   *-*-mingw*)
 237     llvm_cv_target_os_type="MingW" ;;
 238   *-*-haiku*)
 239     llvm_cv_target_os_type="Haiku" ;;
 240   *-unknown-eabi*)
 241     llvm_cv_target_os_type="Freestanding" ;;
 242   *)
 243     llvm_cv_target_os_type="Unknown" ;;
 244 esac])
 245
 246 dnl Make sure we aren't attempting to configure for an unknown system
 247 if test "$llvm_cv_os_type" = "Unknown" ; then
 248   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 249 fi
 250
 251 dnl Set the "OS" Makefile variable based on the platform type so the
 252 dnl makefile can configure itself to specific build hosts
 253 AC_SUBST(OS,$llvm_cv_os_type)
 254 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 255 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 256
 257 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 258 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 259 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 260
 261 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 262 dnl This is used by lib/System to determine the basic kind of implementation
 263 dnl to use.
 264 case $llvm_cv_platform_type in
 265   Unix)
 266     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 267     AC_SUBST(LLVM_ON_UNIX,[1])
 268     AC_SUBST(LLVM_ON_WIN32,[0])
 269     ;;
 270   Win32)
 271     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 272     AC_SUBST(LLVM_ON_UNIX,[0])
 273     AC_SUBST(LLVM_ON_WIN32,[1])
 274     ;;
 275 esac
 276
 277 dnl Determine what our target architecture is and configure accordingly.
 278 dnl This will allow Makefiles to make a distinction between the hardware and
 279 dnl the OS.
 280 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 281 [case $target in
 282   i?86-*)                 llvm_cv_target_arch="x86" ;;
 283   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 284   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 285   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 286   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 287   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 288   mips-*)                 llvm_cv_target_arch="Mips" ;;
 289   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 290   xcore-*)                llvm_cv_target_arch="XCore" ;;
 291   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 292   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 293   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 294   *)                      llvm_cv_target_arch="Unknown" ;;
 295 esac])
 296
 297 if test "$llvm_cv_target_arch" = "Unknown" ; then
 298   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 299 fi
 300
 301 # Determine the LLVM native architecture for the target
 302 case "$llvm_cv_target_arch" in
 303     x86)     LLVM_NATIVE_ARCH="X86" ;;
 304     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 305     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 306 esac
 307
 308 dnl Define a substitution, ARCH, for the target architecture
 309 AC_SUBST(ARCH,$llvm_cv_target_arch)
 310
 311 dnl Check for the endianness of the target
 312 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 313
 314 dnl Check for build platform executable suffix if we're crosscompiling
 315 if test "$cross_compiling" = yes; then
 316   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 317   AC_BUILD_EXEEXT
 318   ac_build_prefix=${build_alias}-
 319   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 320   if test -z "$BUILD_CXX"; then
 321      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 322      if test -z "$BUILD_CXX"; then
 323        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 324      fi
 325   fi
 326 else
 327   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 328 fi
 329
 330 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 331 dnl that this build is being done from a checkout. This sets up several
 332 dnl defaults for the command line switches. When we build with a CVS directory,
 333 dnl we get a debug with assertions turned on. Without, we assume a source
 334 dnl release and we get an optimized build without assertions.
 335 dnl See --enable-optimized and --enable-assertions below
 336 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 337   cvsbuild="yes"
 338   optimize="no"
 339   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 340 else
 341   cvsbuild="no"
 342   optimize="yes"
 343 fi
 344
 345 dnl===-----------------------------------------------------------------------===
 346 dnl===
 347 dnl=== SECTION 3: Command line arguments for the configure script.
 348 dnl===
 349 dnl===-----------------------------------------------------------------------===
 350
 351 dnl --enable-optimized : check whether they want to do an optimized build:
 352 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 353  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 354 if test ${enableval} = "no" ; then
 355   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 356 else
 357   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 358 fi
 359
 360 dnl --enable-profiling : check whether they want to do a profile build:
 361 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 362  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 363 if test ${enableval} = "no" ; then
 364   AC_SUBST(ENABLE_PROFILING,[[]])
 365 else
 366   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 367 fi
 368
 369 dnl --enable-assertions : check whether they want to turn on assertions or not:
 370 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 371   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 372 if test ${enableval} = "yes" ; then
 373   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 374 else
 375   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 376 fi
 377
 378 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 379 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 380   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 381 if test ${enableval} = "yes" ; then
 382   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 383   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 384 else
 385   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 386   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 387 fi
 388
 389 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 390 AC_ARG_ENABLE(debug-runtime,
 391    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 392 if test ${enableval} = "no" ; then
 393   AC_SUBST(DEBUG_RUNTIME,[[]])
 394 else
 395   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 396 fi
 397
 398 dnl --enable-debug-symbols : should even optimized compiler libraries
 399 dnl have debug symbols?
 400 AC_ARG_ENABLE(debug-symbols,
 401    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 402 if test ${enableval} = "no" ; then
 403   AC_SUBST(DEBUG_SYMBOLS,[[]])
 404 else
 405   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 406 fi
 407
 408 dnl --enable-jit: check whether they want to enable the jit
 409 AC_ARG_ENABLE(jit,
 410   AS_HELP_STRING(--enable-jit,
 411                  [Enable Just In Time Compiling (default is YES)]),,
 412   enableval=default)
 413 if test ${enableval} = "no"
 414 then
 415   AC_SUBST(JIT,[[]])
 416 else
 417   case "$llvm_cv_target_arch" in
 418     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 419     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 420     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 421     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 422     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 423     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 424     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 425     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 426     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 427     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 428     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 429     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 430     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 431   esac
 432 fi
 433
 434 dnl Allow enablement of doxygen generated documentation
 435 AC_ARG_ENABLE(doxygen,
 436               AS_HELP_STRING([--enable-doxygen],
 437                              [Build doxygen documentation (default is NO)]),,
 438                              enableval=default)
 439 case "$enableval" in
 440   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 441   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 442   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 443   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 444 esac
 445
 446 dnl Allow disablement of threads
 447 AC_ARG_ENABLE(threads,
 448               AS_HELP_STRING([--enable-threads],
 449                              [Use threads if available (default is YES)]),,
 450                              enableval=default)
 451 case "$enableval" in
 452   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 453   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 454   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 455   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 456 esac
 457 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 458
 459 dnl Allow building without position independent code
 460 AC_ARG_ENABLE(pic,
 461   AS_HELP_STRING([--enable-pic],
 462                  [Build LLVM with Position Independent Code (default is YES)]),,
 463                  enableval=default)
 464 case "$enableval" in
 465   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 466   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 467   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 468   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 469 esac
 470 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 471                    [Define if position independent code is enabled])
 472
 473 dnl Allow specific targets to be specified for building (or not)
 474 TARGETS_TO_BUILD=""
 475 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 476     [Build specific host targets: all or target1,target2,... Valid targets are:
 477      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu, pic16,
 478      xcore, msp430, systemz, blackfin, cbe, msil, and cpp (default=all)]),,
 479     enableval=all)
 480 if test "$enableval" = host-only ; then
 481   enableval=host
 482 fi
 483 case "$enableval" in
 484   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend MSIL CppBackend" ;;
 485   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 486       case "$a_target" in
 487         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 488         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 489         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 490         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 491         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 492         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 493         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 494         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 495         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 496         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 497         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 498         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 499         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 500         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 501         msil)     TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 502         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 503         host) case "$llvm_cv_target_arch" in
 504             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 505             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 506             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 507             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 508             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 509             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 510             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 511             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 512             PIC16)       TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 513             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 514             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 515             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 516             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 517             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 518           esac ;;
 519         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 520       esac
 521   done
 522   ;;
 523 esac
 524 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 525
 526 # Determine whether we are building LLVM support for the native architecture.
 527 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 528 for a_target in $TARGETS_TO_BUILD; do
 529   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 530     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 531     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 532       [LLVM architecture name for the native architecture, if available])
 533   fi
 534 done
 535
 536 # Build the LLVM_TARGET and LLVM_ASM_PRINTER macro uses for
 537 # Targets.def, AsmPrinters.def, and AsmParsers.def.
 538 LLVM_ENUM_TARGETS=""
 539 LLVM_ENUM_ASM_PRINTERS=""
 540 LLVM_ENUM_ASM_PARSERS=""
 541 for target_to_build in $TARGETS_TO_BUILD; do
 542   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 543   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 544     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 545   fi
 546   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 547     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 548   fi
 549 done
 550 AC_SUBST(LLVM_ENUM_TARGETS)
 551 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 552 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 553
 554 dnl Prevent the CBackend from using printf("%a") for floating point so older
 555 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 556 dnl can still compile the CBE's output
 557 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 558   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 559   enableval=default)
 560 case "$enableval" in
 561   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 562   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 563   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 564   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 565 esac
 566 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 567                    [Define if CBE is enabled for printf %a output])
 568
 569 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 570 AC_ARG_WITH(llvmgccdir,
 571   AS_HELP_STRING([--with-llvmgccdir],
 572     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 573     withval=default)
 574 case "$withval" in
 575   default) WITH_LLVMGCCDIR=default ;;
 576   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 577   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 578 esac
 579
 580 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 581 AC_ARG_WITH(llvmgcc,
 582   AS_HELP_STRING([--with-llvmgcc],
 583     [Specify location of llvm-gcc driver (default searches PATH)]),
 584     LLVMGCC=$with_llvmgcc
 585       WITH_LLVMGCCDIR="",)
 586
 587 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 588 AC_ARG_WITH(llvmgxx,
 589   AS_HELP_STRING([--with-llvmgxx],
 590     [Specify location of llvm-g++ driver (default searches PATH)]),
 591     LLVMGXX=$with_llvmgxx
 592     WITH_LLVMGCCDIR="",)
 593
 594 if test -n "$LLVMGCC"; then
 595    LLVMGCCCOMMAND="$LLVMGCC"
 596 fi
 597
 598 if test -n "$LLVMGXX"; then
 599    LLVMGXXCOMMAND="$LLVMGXX"
 600 fi
 601
 602 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 603    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 604 fi
 605
 606 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 607    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 608 fi
 609
 610 dnl Override the option to use for optimized builds.
 611 AC_ARG_WITH(optimize-option,
 612   AS_HELP_STRING([--with-optimize-option],
 613                  [Select the compiler options to use for optimized builds]),,
 614                  withval=default)
 615 AC_MSG_CHECKING([optimization flags])
 616 case "$withval" in
 617   default)
 618     case "$llvm_cv_os_type" in
 619     MingW) optimize_option=-O3 ;;
 620     *)     optimize_option=-O2 ;;
 621     esac ;;
 622   *) optimize_option="$withval" ;;
 623 esac
 624 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 625 AC_MSG_RESULT([$optimize_option])
 626
 627 dnl Specify extra build options
 628 AC_ARG_WITH(extra-options,
 629   AS_HELP_STRING([--with-extra-options],
 630                  [Specify additional options to compile LLVM with]),,
 631                  withval=default)
 632 case "$withval" in
 633   default) EXTRA_OPTIONS= ;;
 634   *) EXTRA_OPTIONS=$withval ;;
 635 esac
 636 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 637
 638 dnl Allow specific bindings to be specified for building (or not)
 639 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 640     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 641     enableval=default)
 642 BINDINGS_TO_BUILD=""
 643 case "$enableval" in
 644   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 645   all ) BINDINGS_TO_BUILD="ocaml" ;;
 646   none | no) BINDINGS_TO_BUILD="" ;;
 647   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 648       case "$a_binding" in
 649         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 650         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 651       esac
 652   done
 653   ;;
 654 esac
 655
 656 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 657 dnl script for bindings/ocaml/configure, except that its auto value depends on
 658 dnl OCAMLC, which is found here to support tests.
 659 AC_ARG_WITH([ocaml-libdir],
 660   [AS_HELP_STRING([--with-ocaml-libdir],
 661     [Specify install location for ocaml bindings (default is stdlib)])],
 662   [],
 663   [withval=auto])
 664 case "$withval" in
 665   auto) with_ocaml_libdir="$withval" ;;
 666   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 667   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 668 esac
 669
 670 AC_ARG_WITH(c-include-dir,
 671   AS_HELP_STRING([--with-c-include-dirs],
 672     [Colon separated list of directories clang will search for headers]),,
 673     withval="")
 674 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 675                    [Directories clang will search for headers])
 676
 677 dnl Allow linking of LLVM with GPLv3 binutils code.
 678 AC_ARG_WITH(binutils-include,
 679   AS_HELP_STRING([--with-binutils-include],
 680     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 681   withval=default)
 682 case "$withval" in
 683   default) WITH_BINUTILS_INCDIR=default ;;
 684   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 685   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 686 esac
 687 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 688   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 689   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 690      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 691      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 692   fi
 693 fi
 694
 695 dnl --enable-libffi : check whether the user wants to turn off libffi:
 696 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 697   --enable-libffi,[Check for the presence of libffi (default is YES)]),,
 698   enableval=yes)
 699 case "$enableval" in
 700   yes) llvm_cv_enable_libffi="yes" ;;
 701   no)  llvm_cv_enable_libffi="no"  ;;
 702   *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 703 esac
 704
 705 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 706 if test "$llvm_cv_os_type" = "Win32" ; then
 707    llvmc_dynamic="yes"
 708 else
 709    llvmc_dynamic="no"
 710 fi
 711
 712 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 713 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 714 --enable-llvmc-dynamic,
 715 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 716 enableval=$llvmc_dynamic)
 717 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 718    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 719 else
 720    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 721 fi
 722
 723 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 724 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 725 --enable-llvmc-dynamic-plugins,
 726 [Enable dynamic LLVMC plugins (default is YES)]),,
 727 enableval=yes)
 728 if test ${enableval} = "yes" ; then
 729    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 730 else
 731    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 732 fi
 733
 734 dnl===-----------------------------------------------------------------------===
 735 dnl===
 736 dnl=== SECTION 4: Check for programs we need and that they are the right version
 737 dnl===
 738 dnl===-----------------------------------------------------------------------===
 739
 740 dnl Check for compilation tools
 741 AC_PROG_CPP
 742 AC_PROG_CC(gcc)
 743 AC_PROG_CXX(g++)
 744
 745 AC_PROG_NM
 746 AC_SUBST(NM)
 747
 748 dnl Check for the tools that the makefiles require
 749 AC_CHECK_GNU_MAKE
 750 AC_PROG_LN_S
 751 AC_PATH_PROG(CMP, [cmp], [cmp])
 752 AC_PATH_PROG(CP, [cp], [cp])
 753 AC_PATH_PROG(DATE, [date], [date])
 754 AC_PATH_PROG(FIND, [find], [find])
 755 AC_PATH_PROG(GREP, [grep], [grep])
 756 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 757 AC_PATH_PROG(MV,   [mv],   [mv])
 758 AC_PROG_RANLIB
 759 AC_PATH_PROG(RM,   [rm],   [rm])
 760 AC_PATH_PROG(SED,  [sed],  [sed])
 761 AC_PATH_PROG(TAR,  [tar],  [gtar])
 762 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 763
 764 dnl Looking for misc. graph plotting software
 765 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 766 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 767   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 768   dnl If we're targeting for mingw we should emit windows paths, not msys
 769   if test "$llvm_cv_os_type" = "MingW" ; then
 770     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 771   fi
 772   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 773    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 774 fi
 775 AC_PATH_PROG(DOT, [dot], [echo dot])
 776 if test "$DOT" != "echo dot" ; then
 777   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 778   dnl If we're targeting for mingw we should emit windows paths, not msys
 779   if test "$llvm_cv_os_type" = "MingW" ; then
 780     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 781   fi
 782   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 783    [Define to path to dot program if found or 'echo dot' otherwise])
 784 fi
 785 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 786 if test "$FDP" != "echo fdp" ; then
 787   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 788   dnl If we're targeting for mingw we should emit windows paths, not msys
 789   if test "$llvm_cv_os_type" = "MingW" ; then
 790     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 791   fi
 792   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 793    [Define to path to fdp program if found or 'echo fdp' otherwise])
 794 fi
 795 AC_PATH_PROG(NEATO, [neato], [echo neato])
 796 if test "$NEATO" != "echo neato" ; then
 797   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 798   dnl If we're targeting for mingw we should emit windows paths, not msys
 799   if test "$llvm_cv_os_type" = "MingW" ; then
 800     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 801   fi
 802   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 803    [Define to path to neato program if found or 'echo neato' otherwise])
 804 fi
 805 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 806 if test "$TWOPI" != "echo twopi" ; then
 807   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 808   dnl If we're targeting for mingw we should emit windows paths, not msys
 809   if test "$llvm_cv_os_type" = "MingW" ; then
 810     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 811   fi
 812   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 813    [Define to path to twopi program if found or 'echo twopi' otherwise])
 814 fi
 815 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 816 if test "$CIRCO" != "echo circo" ; then
 817   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 818   dnl If we're targeting for mingw we should emit windows paths, not msys
 819   if test "$llvm_cv_os_type" = "MingW" ; then
 820     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 821   fi
 822   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 823    [Define to path to circo program if found or 'echo circo' otherwise])
 824 fi
 825 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 826 if test "$GV" != "echo gv" ; then
 827   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 828   dnl If we're targeting for mingw we should emit windows paths, not msys
 829   if test "$llvm_cv_os_type" = "MingW" ; then
 830     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 831   fi
 832   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 833    [Define to path to gv program if found or 'echo gv' otherwise])
 834 fi
 835 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 836 if test "$DOTTY" != "echo dotty" ; then
 837   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 838   dnl If we're targeting for mingw we should emit windows paths, not msys
 839   if test "$llvm_cv_os_type" = "MingW" ; then
 840     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 841   fi
 842   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 843    [Define to path to dotty program if found or 'echo dotty' otherwise])
 844 fi
 845
 846 dnl Look for a sufficiently recent version of Perl.
 847 LLVM_PROG_PERL([5.006])
 848 AC_SUBST(PERL)
 849 if test x"$PERL" = xnone; then
 850    AC_SUBST(HAVE_PERL,0)
 851    AC_MSG_ERROR([perl is required but was not found, please install it])
 852 else
 853    AC_SUBST(HAVE_PERL,1)
 854 fi
 855
 856 dnl Find the install program
 857 AC_PROG_INSTALL
 858
 859 dnl Checks for documentation and testing tools that we can do without. If these
 860 dnl are not found then they are set to "true" which always succeeds but does
 861 dnl nothing. This just lets the build output show that we could have done
 862 dnl something if the tool was available.
 863 AC_PATH_PROG(BZIP2, [bzip2])
 864 AC_PATH_PROG(DOXYGEN, [doxygen])
 865 AC_PATH_PROG(GROFF, [groff])
 866 AC_PATH_PROG(GZIP, [gzip])
 867 AC_PATH_PROG(POD2HTML, [pod2html])
 868 AC_PATH_PROG(POD2MAN, [pod2man])
 869 AC_PATH_PROG(RUNTEST, [runtest])
 870 DJ_AC_PATH_TCLSH
 871 AC_PATH_PROG(ZIP, [zip])
 872 AC_PATH_PROGS(OCAMLC, [ocamlc])
 873 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 874 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 875 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 876 AC_PATH_PROGS(GAS, [gas as])
 877
 878 dnl Determine whether the linker supports the -R option.
 879 AC_LINK_USE_R
 880
 881 dnl Determine whether the linker supports the -export-dynamic option.
 882 AC_LINK_EXPORT_DYNAMIC
 883
 884 dnl Check for libtool and the library that has dlopen function (which must come
 885 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 886 dnl libtool).
 887 AC_LIBTOOL_DLOPEN
 888 AC_LIB_LTDL
 889 AC_PROG_LIBTOOL
 890
 891 if test "$lt_cv_dlopen_self" = "yes" ; then
 892   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 893               [Define if dlopen(0) will open the symbols of the program])
 894 fi
 895
 896
 897 if test "$WITH_LLVMGCCDIR" = "default" ; then
 898   LLVMGCC="llvm-gcc${EXEEXT}"
 899   LLVMGXX="llvm-g++${EXEEXT}"
 900   LLVMGCCCOMMAND="$LLVMGCC"
 901   LLVMGXXCOMMAND="$LLVMGXX"
 902   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 903   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 904   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 905   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 906 else
 907   if test -z "$LLVMGCC"; then
 908     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 909     LLVMGCCCOMMAND="$LLVMGCC"
 910   fi
 911   if test -z "$LLVMGXX"; then
 912     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 913     LLVMGXXCOMMAND="$LLVMGXX"
 914   fi
 915
 916   AC_SUBST(LLVMGCC,$LLVMGCC)
 917   AC_SUBST(LLVMGXX,$LLVMGXX)
 918   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 919   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 920 fi
 921
 922
 923 AC_MSG_CHECKING([tool compatibility])
 924
 925 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 926 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 927 dnl to support those options.
 928 dnl "icc" emits gcc signatures
 929 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 930 ICC=no
 931 IXX=no
 932 case $CC in
 933   icc*|icpc*)
 934     ICC=yes
 935     IXX=yes
 936     ;;
 937    *)
 938     ;;
 939 esac
 940
 941 if test "$GCC" != "yes" && test "$ICC" != "yes"
 942 then
 943   AC_MSG_ERROR([gcc|icc required but not found])
 944 fi
 945
 946 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 947 if test "$GXX" != "yes" && test "$IXX" != "yes"
 948 then
 949   AC_MSG_ERROR([g++|icc required but not found])
 950 fi
 951
 952 dnl Verify that GCC is version 3.0 or higher
 953 if test "$GCC" = "yes"
 954 then
 955   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 956 #error Unsupported GCC version
 957 #endif
 958 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 959 fi
 960
 961 dnl Check for GNU Make.  We use its extensions, so don't build without it
 962 if test -z "$llvm_cv_gnu_make_command"
 963 then
 964   AC_MSG_ERROR([GNU Make required but not found])
 965 fi
 966
 967 dnl Tool compatibility is okay if we make it here.
 968 AC_MSG_RESULT([ok])
 969
 970 dnl Check optional compiler flags.
 971 AC_MSG_CHECKING([optional compiler flags])
 972 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
 973 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
 974 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
 975
 976 dnl===-----------------------------------------------------------------------===
 977 dnl===
 978 dnl=== SECTION 5: Check for libraries
 979 dnl===
 980 dnl===-----------------------------------------------------------------------===
 981
 982 AC_CHECK_LIB(m,sin)
 983 if test "$llvm_cv_os_type" = "MingW" ; then
 984   AC_CHECK_LIB(imagehlp, main)
 985   AC_CHECK_LIB(psapi, main)
 986 fi
 987
 988 dnl dlopen() is required for plugin support.
 989 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 990                [Define if dlopen() is available on this platform.]),
 991                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 992
 993 dnl libffi is optional; used to call external functions from the interpreter
 994 if test "$llvm_cv_enable_libffi" = "yes" ; then
 995   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
 996                  [Define if libffi is available on this platform.]),
 997                  AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
 998 fi
 999
1000 dnl mallinfo is optional; the code can compile (minus features) without it
1001 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1002                [Define if mallinfo() is available on this platform.]))
1003
1004 dnl pthread locking functions are optional - but llvm will not be thread-safe
1005 dnl without locks.
1006 if test "$ENABLE_THREADS" -eq 1 ; then
1007   AC_CHECK_LIB(pthread, pthread_mutex_init)
1008   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1009                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1010                            [Have pthread_mutex_lock]))
1011   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1012                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1013                  [Have pthread_rwlock_init]))
1014   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1015                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1016                  [Have pthread_getspecific]))
1017 fi
1018
1019 dnl Allow extra x86-disassembler library
1020 AC_ARG_WITH(udis86,
1021   AS_HELP_STRING([--with-udis86=<path>],
1022     [Use udis86 external x86 disassembler library]),
1023     [
1024       AC_SUBST(USE_UDIS86, [1])
1025       case "$withval" in
1026         /usr/lib|yes) ;;
1027         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1028       esac
1029       AC_CHECK_LIB(udis86, ud_init, [], [
1030         echo "Error! You need to have libudis86 around."
1031         exit -1
1032       ])
1033     ],
1034     AC_SUBST(USE_UDIS86, [0]))
1035 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1036                    [Define if use udis86 library])
1037
1038 dnl Allow OProfile support for JIT output.
1039 AC_ARG_WITH(oprofile,
1040   AS_HELP_STRING([--with-oprofile=<prefix>],
1041     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1042     [
1043       AC_SUBST(USE_OPROFILE, [1])
1044       case "$withval" in
1045         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1046         no) llvm_cv_oppath=
1047             AC_SUBST(USE_OPROFILE, [0]) ;;
1048         *) llvm_cv_oppath="${withval}/lib/oprofile"
1049            CPPFLAGS="-I${withval}/include";;
1050       esac
1051       if test -n "$llvm_cv_oppath" ; then
1052         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1053         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1054         dnl libbfd is not included properly in libopagent in some Debian
1055         dnl versions.  If libbfd isn't found at all, we assume opagent works
1056         dnl anyway.
1057         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1058         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1059           echo "Error! You need to have libopagent around."
1060           exit -1
1061         ])
1062         AC_CHECK_HEADER([opagent.h], [], [
1063           echo "Error! You need to have opagent.h around."
1064           exit -1
1065           ])
1066       fi
1067     ],
1068     [
1069       AC_SUBST(USE_OPROFILE, [0])
1070     ])
1071 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1072                    [Define if we have the oprofile JIT-support library])
1073
1074 dnl===-----------------------------------------------------------------------===
1075 dnl===
1076 dnl=== SECTION 6: Check for header files
1077 dnl===
1078 dnl===-----------------------------------------------------------------------===
1079
1080 dnl First, use autoconf provided macros for specific headers that we need
1081 dnl We don't check for ancient stuff or things that are guaranteed to be there
1082 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1083 dnl Generally we're looking for POSIX headers.
1084 AC_HEADER_DIRENT
1085 AC_HEADER_MMAP_ANONYMOUS
1086 AC_HEADER_STAT
1087 AC_HEADER_STDC
1088 AC_HEADER_SYS_WAIT
1089 AC_HEADER_TIME
1090
1091 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1092 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1093 AC_CHECK_HEADERS([utime.h windows.h])
1094 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1095 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1096 if test "$ENABLE_THREADS" -eq 1 ; then
1097   AC_CHECK_HEADERS(pthread.h,
1098                    AC_SUBST(HAVE_PTHREAD, 1),
1099                    AC_SUBST(HAVE_PTHREAD, 0))
1100 else
1101   AC_SUBST(HAVE_PTHREAD, 0)
1102 fi
1103
1104 dnl Try to find ffi.h.
1105 if test "$llvm_cv_enable_libffi" = "yes" ; then
1106   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1107 fi
1108
1109 dnl===-----------------------------------------------------------------------===
1110 dnl===
1111 dnl=== SECTION 7: Check for types and structures
1112 dnl===
1113 dnl===-----------------------------------------------------------------------===
1114
1115 AC_HUGE_VAL_CHECK
1116 AC_TYPE_PID_T
1117 AC_TYPE_SIZE_T
1118 AC_TYPE_SIGNAL
1119 AC_STRUCT_TM
1120 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1121 AC_CHECK_TYPES([uint64_t],,
1122          AC_CHECK_TYPES([u_int64_t],,
1123          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1124
1125 dnl===-----------------------------------------------------------------------===
1126 dnl===
1127 dnl=== SECTION 8: Check for specific functions needed
1128 dnl===
1129 dnl===-----------------------------------------------------------------------===
1130
1131 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1132 AC_CHECK_FUNCS([powf fmodf strtof round ])
1133 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1134 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1135 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup ])
1136 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1137 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1138 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1139 AC_C_PRINTF_A
1140 dnl FIXME: This is no longer used, please remove (but test)!!!
1141 AC_FUNC_ALLOCA
1142 AC_FUNC_RAND48
1143
1144 dnl Check for variations in the Standard C++ library and STL. These macros are
1145 dnl provided by LLVM in the autoconf/m4 directory.
1146 AC_CXX_HAVE_STD_ITERATOR
1147 AC_CXX_HAVE_BI_ITERATOR
1148 AC_CXX_HAVE_FWD_ITERATOR
1149 AC_FUNC_ISNAN
1150 AC_FUNC_ISINF
1151
1152 dnl Check for mmap support.We also need to know if /dev/zero is required to
1153 dnl be opened for allocating RWX memory.
1154 dnl Make sure we aren't attempting to configure for an unknown system
1155 if test "$llvm_cv_platform_type" = "Unix" ; then
1156   AC_FUNC_MMAP
1157   AC_FUNC_MMAP_FILE
1158   AC_NEED_DEV_ZERO_FOR_MMAP
1159
1160   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1161   then
1162     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1163   fi
1164   if test "$ac_cv_func_mmap_file" = "no"
1165   then
1166     AC_MSG_WARN([mmap() of files required but not found])
1167   fi
1168 fi
1169
1170 dnl atomic builtins are required for threading support.
1171 AC_MSG_CHECKING(for GCC atomic builtins)
1172 AC_LINK_IFELSE(
1173   AC_LANG_SOURCE(
1174     [[int main() {
1175         volatile unsigned long val = 1;
1176         __sync_synchronize();
1177         __sync_val_compare_and_swap(&val, 1, 0);
1178         __sync_add_and_fetch(&val, 1);
1179         __sync_sub_and_fetch(&val, 1);
1180         return 0;
1181       }
1182     ]]),
1183   AC_MSG_RESULT(yes)
1184   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1185   AC_MSG_RESULT(no)
1186   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1187   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1188
1189
1190 dnl===-----------------------------------------------------------------------===
1191 dnl===
1192 dnl=== SECTION 9: Additional checks, variables, etc.
1193 dnl===
1194 dnl===-----------------------------------------------------------------------===
1195
1196 dnl Handle 32-bit linux systems running a 64-bit kernel.
1197 dnl This has to come after section 4 because it invokes the compiler.
1198 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1199   AC_IS_LINUX_MIXED
1200   if test "$llvm_cv_linux_mixed" = "yes"; then
1201     llvm_cv_target_arch="x86"
1202     ARCH="x86"
1203   fi
1204 fi
1205
1206 dnl Check, whether __dso_handle is present
1207 AC_CHECK_FUNCS([__dso_handle])
1208
1209 dnl See if the llvm-gcc executable can compile to LLVM assembly
1210 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1211 [llvm_cv_llvmgcc_sanity="no"
1212 if test -x "$LLVMGCC" ; then
1213   cp /dev/null conftest.c
1214   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1215       grep 'target datalayout =' > /dev/null 2>&1
1216   if test $? -eq 0 ; then
1217     llvm_cv_llvmgcc_sanity="yes"
1218   fi
1219   rm conftest.c
1220 fi])
1221
1222 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1223 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1224   AC_MSG_CHECKING([llvm-gcc component support])
1225   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1226   AC_SUBST(LLVMCC1,$llvmcc1path)
1227   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1228   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1229   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1230   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1231   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
1232   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
1233   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
1234   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
1235   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
1236   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
1237   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1238   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1239   AC_MSG_RESULT([ok])
1240 fi
1241
1242 dnl Propagate the shared library extension that the libltdl checks did to
1243 dnl the Makefiles so we can use it there too
1244 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1245
1246 # Translate the various configuration directories and other basic
1247 # information into substitutions that will end up in Makefile.config.in
1248 # that these configured values can be used by the makefiles
1249 if test "${prefix}" = "NONE" ; then
1250   prefix="/usr/local"
1251 fi
1252 eval LLVM_PREFIX="${prefix}";
1253 eval LLVM_BINDIR="${prefix}/bin";
1254 eval LLVM_LIBDIR="${prefix}/lib";
1255 eval LLVM_DATADIR="${prefix}/share/llvm";
1256 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
1257 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1258 eval LLVM_INCLUDEDIR="${prefix}/include";
1259 eval LLVM_INFODIR="${prefix}/info";
1260 eval LLVM_MANDIR="${prefix}/man";
1261 LLVM_CONFIGTIME=`date`
1262 AC_SUBST(LLVM_PREFIX)
1263 AC_SUBST(LLVM_BINDIR)
1264 AC_SUBST(LLVM_LIBDIR)
1265 AC_SUBST(LLVM_DATADIR)
1266 AC_SUBST(LLVM_DOCSDIR)
1267 AC_SUBST(LLVM_ETCDIR)
1268 AC_SUBST(LLVM_INCLUDEDIR)
1269 AC_SUBST(LLVM_INFODIR)
1270 AC_SUBST(LLVM_MANDIR)
1271 AC_SUBST(LLVM_CONFIGTIME)
1272
1273 # Place the various directores into the config.h file as #defines so that we
1274 # can know about the installation paths within LLVM.
1275 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1276                    [Installation prefix directory])
1277 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1278                    [Installation directory for binary executables])
1279 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1280                    [Installation directory for libraries])
1281 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1282                    [Installation directory for data files])
1283 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1284                    [Installation directory for documentation])
1285 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1286                    [Installation directory for config files])
1287 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1288                    [Installation directory for include files])
1289 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1290                    [Installation directory for .info files])
1291 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1292                    [Installation directory for man pages])
1293 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1294                    [Time at which LLVM was configured])
1295 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1296                    [Host triple we were built on])
1297
1298 # Determine which bindings to build.
1299 if test "$BINDINGS_TO_BUILD" = auto ; then
1300   BINDINGS_TO_BUILD=""
1301   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1302     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1303   fi
1304 fi
1305 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1306
1307 # This isn't really configurey, but it avoids having to repeat the list in
1308 # other files.
1309 AC_SUBST(ALL_BINDINGS,ocaml)
1310
1311 # Do any work necessary to ensure that bindings have what they need.
1312 binding_prereqs_failed=0
1313 for a_binding in $BINDINGS_TO_BUILD ; do
1314   case "$a_binding" in
1315   ocaml)
1316     if test "x$OCAMLC" = x ; then
1317       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1318       binding_prereqs_failed=1
1319     fi
1320     if test "x$OCAMLDEP" = x ; then
1321       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1322       binding_prereqs_failed=1
1323     fi
1324     if test "x$OCAMLOPT" = x ; then
1325       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1326       dnl ocamlopt is optional!
1327     fi
1328     if test "x$with_ocaml_libdir" != xauto ; then
1329       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1330     else
1331       ocaml_stdlib="`"$OCAMLC" -where`"
1332       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1333       then
1334         # ocaml stdlib is beneath our prefix; use stdlib
1335         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1336       else
1337         # ocaml stdlib is outside our prefix; use libdir/ocaml
1338         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1339       fi
1340     fi
1341     ;;
1342   esac
1343 done
1344 if test "$binding_prereqs_failed" = 1 ; then
1345   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1346 fi
1347
1348 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1349 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1350
1351 dnl Determine linker rpath flag
1352 if test "$llvm_cv_link_use_r" = "yes" ; then
1353   RPATH="-Wl,-R"
1354 else
1355   RPATH="-Wl,-rpath"
1356 fi
1357 AC_SUBST(RPATH)
1358
1359 dnl Determine linker rdynamic flag
1360 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1361   RDYNAMIC="-Wl,-export-dynamic"
1362 else
1363   RDYNAMIC=""
1364 fi
1365 AC_SUBST(RDYNAMIC)
1366
1367 dnl===-----------------------------------------------------------------------===
1368 dnl===
1369 dnl=== SECTION 10: Specify the output files and generate it
1370 dnl===
1371 dnl===-----------------------------------------------------------------------===
1372
1373 dnl Configure header files
1374 dnl WARNING: dnl If you add or remove any of the following config headers, then
1375 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1376 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1377 dnl files can be updated automatically when their *.in sources change.
1378 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1379 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1380 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1381 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1382 AC_CONFIG_HEADERS([include/llvm/System/DataTypes.h])
1383
1384 dnl Configure the makefile's configuration data
1385 AC_CONFIG_FILES([Makefile.config])
1386
1387 dnl Configure the RPM spec file for LLVM
1388 AC_CONFIG_FILES([llvm.spec])
1389
1390 dnl Configure doxygen's configuration file
1391 AC_CONFIG_FILES([docs/doxygen.cfg])
1392
1393 dnl Configure llvmc's Base plugin
1394 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1395
1396 dnl Do the first stage of configuration for llvm-config.in.
1397 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1398
1399 dnl Do special configuration of Makefiles
1400 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1401 AC_CONFIG_MAKEFILE(Makefile)
1402 AC_CONFIG_MAKEFILE(Makefile.common)
1403 AC_CONFIG_MAKEFILE(examples/Makefile)
1404 AC_CONFIG_MAKEFILE(lib/Makefile)
1405 AC_CONFIG_MAKEFILE(runtime/Makefile)
1406 AC_CONFIG_MAKEFILE(test/Makefile)
1407 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1408 AC_CONFIG_MAKEFILE(unittests/Makefile)
1409 AC_CONFIG_MAKEFILE(tools/Makefile)
1410 AC_CONFIG_MAKEFILE(utils/Makefile)
1411 AC_CONFIG_MAKEFILE(projects/Makefile)
1412 AC_CONFIG_MAKEFILE(bindings/Makefile)
1413 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1414
1415 dnl Finally, crank out the output
1416 AC_OUTPUT