autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.6cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT($LLVM_COPYRIGHT)
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  78       *)
  79         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  80         ;;
  81     esac
  82   fi
  83 done
  84
  85 dnl===-----------------------------------------------------------------------===
  86 dnl===
  87 dnl=== SECTION 2: Architecture, target, and host checks
  88 dnl===
  89 dnl===-----------------------------------------------------------------------===
  90
  91 dnl Check the target for which we're compiling and the host that will do the
  92 dnl compilations. This will tell us which LLVM compiler will be used for
  93 dnl compiling SSA into object code. This needs to be done early because
  94 dnl following tests depend on it.
  95 AC_CANONICAL_TARGET
  96
  97 dnl Determine the platform type and cache its value. This helps us configure
  98 dnl the System library to the correct build platform.
  99 AC_CACHE_CHECK([type of operating system we're on],
 100                [llvm_cv_os_type],
 101 [case $build in
 102   *-*-aix*)
 103     llvm_cv_os_type="AIX"
 104     llvm_cv_platform_type="Unix" ;;
 105   *-*-cygwin*)
 106     llvm_cv_os_type="Cygwin"
 107     llvm_cv_platform_type="Unix" ;;
 108   *-*-darwin*)
 109     llvm_cv_os_type="Darwin"
 110     llvm_cv_platform_type="Unix" ;;
 111   *-*-freebsd*)
 112     llvm_cv_os_type="FreeBSD"
 113     llvm_cv_platform_type="Unix" ;;
 114   *-*-hpux*)
 115     llvm_cv_os_type="HP-UX"
 116     llvm_cv_platform_type="Unix" ;;
 117   *-*-interix*)
 118     llvm_cv_os_type="Interix"
 119     llvm_cv_platform_type="Unix" ;;
 120   *-*-linux*)
 121     llvm_cv_os_type="Linux"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-solaris*)
 124     llvm_cv_os_type="SunOS"
 125     llvm_cv_platform_type="Unix" ;;
 126   *-*-win32*)
 127     llvm_cv_os_type="Win32"
 128     llvm_cv_platform_type="Win32" ;;
 129   *-*-mingw*)
 130     llvm_cv_os_type="MingW"
 131     llvm_cv_platform_type="Win32" ;;
 132   *)
 133     llvm_cv_os_type="Unknown"
 134     llvm_cv_platform_type="Unknown" ;;
 135 esac])
 136
 137 dnl Make sure we aren't attempting to configure for an unknown system
 138 if test "$llvm_cv_os_type" = "Unknown" ; then
 139   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 140 fi
 141
 142 dnl Set the "OS" Makefile variable based on the platform type so the
 143 dnl makefile can configure itself to specific build hosts
 144 AC_SUBST(OS,$llvm_cv_os_type)
 145
 146 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 147 dnl This is used by lib/System to determine the basic kind of implementation
 148 dnl to use.
 149 case $llvm_cv_platform_type in
 150   Unix)
 151     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 152     AC_SUBST(LLVM_ON_UNIX,[1])
 153     AC_SUBST(LLVM_ON_WIN32,[0])
 154     ;;
 155   Win32)
 156     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 157     AC_SUBST(LLVM_ON_UNIX,[0])
 158     AC_SUBST(LLVM_ON_WIN32,[1])
 159     ;;
 160 esac
 161
 162 dnl Determine what our target architecture is and configure accordingly.
 163 dnl This will allow Makefiles to make a distinction between the hardware and
 164 dnl the OS.
 165 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 166 [case $target in
 167   i?86-*)                 llvm_cv_target_arch="x86" ;;
 168   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 169   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 170   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 171   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 172   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 173   *)                      llvm_cv_target_arch="Unknown" ;;
 174 esac])
 175
 176 if test "$llvm_cv_target_arch" = "Unknown" ; then
 177   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 178 fi
 179
 180 dnl Define a substitution, ARCH, for the target architecture
 181 AC_SUBST(ARCH,$llvm_cv_target_arch)
 182
 183 dnl Check for the endianness of the target
 184 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 185
 186 dnl===-----------------------------------------------------------------------===
 187 dnl===
 188 dnl=== SECTION 3: Command line arguments for the configure script.
 189 dnl===
 190 dnl===-----------------------------------------------------------------------===
 191
 192 dnl --enable-optimized : check whether they want to do an optimized build:
 193 AC_ARG_ENABLE(optimized,
 194               AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
 195 if test ${enableval} = "no" ; then
 196   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 197 else
 198   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 199 fi
 200
 201 dnl --enable-jit: check whether they want to enable the jit
 202 AC_ARG_ENABLE(jit,
 203   AS_HELP_STRING(--enable-jit,
 204                  [Enable Just In Time Compiling (default is YES)]),,
 205   enableval=default)
 206 if test ${enableval} = "no"
 207 then
 208   AC_SUBST(JIT,[[]])
 209 else
 210   case "$llvm_cv_target_arch" in
 211     x86)     AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 212     Sparc)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 213     PowerPC) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 214     x86_64)  AC_SUBST(JIT,[[]]) ;;
 215     Alpha)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 216     IA64)    AC_SUBST(JIT,[[]]) ;;
 217     *)       AC_SUBST(JIT,[[]]) ;;
 218   esac
 219 fi
 220
 221 dnl Allow enablement of doxygen generated documentation
 222 AC_ARG_ENABLE(doxygen,
 223               AS_HELP_STRING([--enable-doxygen],
 224                              [Build doxygen documentation (default is NO)]),,
 225                              enableval=default)
 226 case "$enableval" in
 227   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 228   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 229   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 230   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 231 esac
 232
 233 dnl Allow disablement of threads
 234 AC_ARG_ENABLE(threads,
 235               AS_HELP_STRING([--enable-threads],
 236                              [Use threads if available (default is YES)]),,
 237                              enableval=yes)
 238 case "$enableval" in
 239   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 240   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 241   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 242 esac
 243 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 244
 245 dnl Allow specific targets to be specified for building (or not)
 246 TARGETS_TO_BUILD=""
 247 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-target],
 248     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 249     enableval=all)
 250 case "$enableval" in
 251   all) TARGETS_TO_BUILD="X86 SparcV8 SparcV9 PowerPC Alpha IA64 Skeleton" ;;
 252   host-only)
 253     case "$llvm_cv_target_arch" in
 254       x86)     TARGETS_TO_BUILD="X86" ;;
 255       x86_64)  TARGETS_TO_BUILD="X86" ;;
 256       Sparc)   TARGETS_TO_BUILD="SparcV8 SparcV9" ;;
 257       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 258       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 259       IA64)    TARGETS_TO_BUILD="IA64" ;;
 260       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 261     esac
 262     ;;
 263   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 264       case "$a_target" in
 265         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 266         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 267         sparc)   TARGETS_TO_BUILD="SparcV8 SparcV9 $TARGETS_TO_BUILD" ;;
 268         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 269         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 270         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 271         skeleton)TARGETS_TO_BUILD="Skeleton $TARGETS_TO_BUILD";;
 272         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 273       esac
 274   done
 275   ;;
 276 esac
 277 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 278 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 279
 280 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 281 AC_ARG_WITH(llvmgccdir,
 282   AS_HELP_STRING([--with-llvmgccdir],
 283     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 284     withval=default)
 285 case "$withval" in
 286   default) WITH_LLVMGCCDIR=default ;;
 287   /*)      WITH_LLVMGCCDIR=$withval ;;
 288   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 289 esac
 290
 291
 292 dnl===-----------------------------------------------------------------------===
 293 dnl===
 294 dnl=== SECTION 4: Check for programs we need and that they are the right version
 295 dnl===
 296 dnl===-----------------------------------------------------------------------===
 297
 298 dnl Check for compilation tools
 299 AC_PROG_CPP
 300 AC_PROG_CC(gcc)
 301 AC_PROG_CXX(g++)
 302 AC_PROG_FLEX
 303 AC_PROG_BISON
 304
 305 dnl Check for the tools that the makefiles require
 306 AC_CHECK_GNU_MAKE
 307 AC_PROG_LN_S
 308 AC_PATH_PROG(CMP, [cmp], [cmp])
 309 AC_PATH_PROG(CP, [cp], [cp])
 310 AC_PATH_PROG(DATE, [date], [date])
 311 AC_PATH_PROG(FIND, [find], [find])
 312 AC_PATH_PROG(GREP, [grep], [grep])
 313 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 314 AC_PATH_PROG(MV,   [mv],   [mv])
 315 AC_PROG_RANLIB
 316 AC_PATH_PROG(RM,   [rm],   [rm])
 317 AC_PATH_PROG(SED,  [sed],  [sed])
 318 AC_PATH_PROG(TAR,  [tar],  [gtar])
 319 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 320 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 321   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 322   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ",
 323    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 324 fi
 325 AC_PATH_PROG(GV, [gv], [echo gv])
 326 if test "$GRAPHVIZ" != "echo gv" ; then
 327   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 328   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV",
 329    [Define to path to gv program if found or 'echo gv' otherwise])
 330 fi
 331
 332 dnl Find the install program
 333 AC_PROG_INSTALL
 334
 335 dnl Checks for documentation and testing tools that we can do without. If these
 336 dnl are not found then they are set to "true" which always succeeds but does
 337 dnl nothing. This just lets the build output show that we could have done
 338 dnl something if the tool was available.
 339 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 340 AC_PATH_PROG(DOT,[dot],[true dot])
 341 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 342 AC_PATH_PROG(ETAGS,[etags],[true etags])
 343 AC_PATH_PROG(GROFF,[groff],[true groff])
 344 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 345 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 346 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 347 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 348 DJ_AC_PATH_TCLSH
 349 AC_PATH_PROG(ZIP,[zip],[true zip])
 350
 351 dnl Determine if the linker supports the -R option.
 352 AC_LINK_USE_R
 353
 354 dnl Check for libtool and the library that has dlopen function (which must come
 355 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 356 dnl libtool).
 357 AC_LIBTOOL_DLOPEN
 358 AC_LIB_LTDL
 359 AC_PROG_LIBTOOL
 360
 361 if test "$lt_cv_dlopen_self" = "yes" ; then
 362   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 363               [Define if dlopen(0) will open the symbols of the program])
 364 fi
 365
 366 dnl Check if we know how to tell etags we are using C++:
 367 etags_version=`$ETAGS --version 2>&1`
 368 case "$etags_version" in
 369         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 370         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 371         *) ETAGSFLAGS="" ;;
 372 esac
 373 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 374
 375 if test "$WITH_LLVMGCCDIR" = "default" ; then
 376   LLVMGCC="llvm-gcc${EXEEXT}"
 377   LLVMGXX="llvm-g++${EXEEXT}"
 378   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 379   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 380 else
 381   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 382   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 383   AC_SUBST(LLVMGCC,$LLVMGCC)
 384   AC_SUBST(LLVMGXX,$LLVMGXX)
 385 fi
 386
 387 AC_MSG_CHECKING([tool compatibility])
 388
 389 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 390 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 391 dnl to support those options.
 392 dnl "icc" emits gcc signatures
 393 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 394 ICC=no
 395 IXX=no
 396 case $CC in
 397   icc*|icpc*)
 398     ICC=yes
 399     IXX=yes
 400     ;;
 401    *)
 402     ;;
 403 esac
 404
 405 if test "$GCC" != "yes" && test "$ICC" != "yes"
 406 then
 407   AC_MSG_ERROR([gcc|icc required but not found])
 408 fi
 409
 410 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 411 if test "$GXX" != "yes" && test "$IXX" != "yes"
 412 then
 413   AC_MSG_ERROR([g++|icc required but not found])
 414 fi
 415
 416 dnl Verify that GCC is version 3.0 or higher
 417 if test "$GCC" = "yes"
 418 then
 419   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 420   if test "$gccmajor" -lt "3"
 421   then
 422     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 423   fi
 424 fi
 425
 426 dnl Check for GNU Make.  We use its extensions, so don't build without it
 427 if test -z "$llvm_cv_gnu_make_command"
 428 then
 429   AC_MSG_ERROR([GNU Make required but not found])
 430 fi
 431
 432 dnl Tool compatibility is okay if we make it here.
 433 AC_MSG_RESULT([ok])
 434
 435 dnl===-----------------------------------------------------------------------===
 436 dnl===
 437 dnl=== SECTION 5: Check for libraries
 438 dnl===
 439 dnl===-----------------------------------------------------------------------===
 440
 441 dnl libelf is for sparc only; we can ignore it if we don't have it
 442 AC_CHECK_LIB(elf, elf_begin)
 443
 444
 445 dnl lt_dlopen may be required for plugin support.
 446 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 447               [Define if lt_dlopen() is available on this platform]),
 448               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 449                            not be available]))
 450
 451 dnl dlopen() is required for plugin support.
 452 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 453                [Define if dlopen() is available on this platform.]),
 454                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 455
 456 dnl mallinfo is optional; the code can compile (minus features) without it
 457 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 458                [Define if mallinfo() is available on this platform.]))
 459
 460 dnl pthread locking functions are optional - but llvm will not be thread-safe
 461 dnl without locks.
 462 if test "$ENABLE_THREADS" -eq 1 ; then
 463   AC_CHECK_LIB(pthread,pthread_mutex_init)
 464   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 465                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 466                            [Have pthread_mutex_lock]))
 467 fi
 468
 469 dnl===-----------------------------------------------------------------------===
 470 dnl===
 471 dnl=== SECTION 6: Check for header files
 472 dnl===
 473 dnl===-----------------------------------------------------------------------===
 474
 475 dnl First, use autoconf provided macros for specific headers that we need
 476 dnl We don't check for ancient stuff or things that are guaranteed to be there
 477 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 478 dnl Generally we're looking for POSIX headers.
 479 AC_HEADER_DIRENT
 480 AC_HEADER_MMAP_ANONYMOUS
 481 AC_HEADER_STAT
 482 AC_HEADER_STDC
 483 AC_HEADER_SYS_WAIT
 484 AC_HEADER_TIME
 485
 486 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 487 AC_CHECK_HEADERS([malloc.h signal.h stdint.h unistd.h utime.h windows.h])
 488 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/types.h])
 489 AC_CHECK_HEADERS([rw/stdex/hash_map.h rw/stdex/hash_set.h])
 490 if test "$ENABLE_THREADS" -eq 1 ; then
 491   AC_CHECK_HEADERS(pthread.h)
 492 fi
 493
 494 dnl===-----------------------------------------------------------------------===
 495 dnl===
 496 dnl=== SECTION 7: Check for types and structures
 497 dnl===
 498 dnl===-----------------------------------------------------------------------===
 499
 500 AC_TYPE_PID_T
 501 AC_TYPE_SIZE_T
 502 AC_TYPE_SIGNAL
 503 AC_STRUCT_TM
 504 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 505 AC_CHECK_TYPES([uint64_t],,
 506          AC_CHECK_TYPES([u_int64_t],,
 507          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 508
 509 dnl===-----------------------------------------------------------------------===
 510 dnl===
 511 dnl=== SECTION 8: Check for specific functions needed
 512 dnl===
 513 dnl===-----------------------------------------------------------------------===
 514
 515 AC_CHECK_FUNCS([backtrace getcwd getpagesize getrusage gettimeofday ])
 516 AC_CHECK_FUNCS([isatty mkdtemp mkstemp mktemp ])
 517 AC_CHECK_FUNCS([realpath sbrk setrlimit strdup strerror strerror_r ])
 518 AC_CHECK_FUNCS([strtoll strtoq sysconf])
 519 AC_C_PRINTF_A
 520 AC_FUNC_ALLOCA
 521 AC_FUNC_RAND48
 522
 523 dnl Check for variations in the Standard C++ library and STL. These macros are
 524 dnl provided by LLVM in the autoconf/m4 directory.
 525 AC_CXX_HAVE_HASH_MAP
 526 AC_CXX_HAVE_HASH_SET
 527 AC_CXX_HAVE_STD_ITERATOR
 528 AC_CXX_HAVE_BI_ITERATOR
 529 AC_CXX_HAVE_FWD_ITERATOR
 530 AC_FUNC_ISNAN
 531 AC_FUNC_ISINF
 532
 533 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 534 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 535 dnl be opened for allocating RWX memory.
 536 AC_FUNC_MMAP
 537 AC_FUNC_MMAP_FILE
 538 AC_NEED_DEV_ZERO_FOR_MMAP
 539 AC_CHECK_FUNC(mprotect,,
 540               AC_MSG_ERROR([Function mprotect() required but not found]))
 541
 542 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 543 then
 544   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 545 fi
 546 if test "$ac_cv_func_mmap_file" = "no"
 547 then
 548   AC_MSG_WARN([mmap() of files required but not found])
 549 fi
 550
 551 dnl===-----------------------------------------------------------------------===
 552 dnl===
 553 dnl=== SECTION 9: Additional checks, variables, etc.
 554 dnl===
 555 dnl===-----------------------------------------------------------------------===
 556
 557 dnl See if the llvm-gcc executable can compile to LLVM assembly
 558 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 559 [llvm_cv_llvmgcc_sanity="no"
 560 if test -x "$LLVMGCC" ; then
 561   cp /dev/null conftest.c
 562   "$LLVMGCC" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 563   if test $? -eq 0 ; then
 564     llvm_cv_llvmgcc_sanity="yes"
 565   fi
 566   rm conftest.c
 567 fi])
 568
 569 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 570 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 571   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 572   AC_SUBST(LLVMCC1,$llvmcc1path)
 573   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 574   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 575   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 576   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 577 fi
 578
 579 dnl Propagate the shared library extension that the libltdl checks did to
 580 dnl the Makefiles so we can use it there too
 581 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 582
 583 # Translate the various configuration directories and other basic
 584 # information into substitutions that will end up in Makefile.config.in
 585 # that these configured values can be used by the makefiles
 586 eval LLVM_PREFIX="${prefix}";
 587 eval LLVM_BINDIR="${prefix}/bin";
 588 eval LLVM_LIBDIR="${prefix}/lib";
 589 eval LLVM_DATADIR="${prefix}/share/llvm";
 590 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 591 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 592 eval LLVM_INCLUDEDIR="${prefix}/include";
 593 eval LLVM_INFODIR="${prefix}/info";
 594 eval LLVM_MANDIR="${prefix}/man";
 595 LLVM_CONFIGTIME=`date`
 596 AC_SUBST(LLVM_PREFIX)
 597 AC_SUBST(LLVM_BINDIR)
 598 AC_SUBST(LLVM_LIBDIR)
 599 AC_SUBST(LLVM_DATADIR)
 600 AC_SUBST(LLVM_DOCSDIR)
 601 AC_SUBST(LLVM_ETCDIR)
 602 AC_SUBST(LLVM_INCLUDEDIR)
 603 AC_SUBST(LLVM_INFODIR)
 604 AC_SUBST(LLVM_MANDIR)
 605 AC_SUBST(LLVM_CONFIGTIME)
 606
 607 # Place the various directores into the config.h file as #defines so that we
 608 # can know about the installation paths within LLVM.
 609 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 610                    [Installation prefix directory])
 611 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 612                    [Installation directory for binary executables])
 613 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 614                    [Installation directory for libraries])
 615 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 616                    [Installation directory for data files])
 617 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 618                    [Installation directory for documentation])
 619 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 620                    [Installation directory for config files])
 621 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 622                    [Installation directory for include files])
 623 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 624                    [Installation directory for .info files])
 625 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 626                    [Installation directory for man pages])
 627 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 628                    [Time at which LLVM was configured])
 629
 630 dnl===-----------------------------------------------------------------------===
 631 dnl===
 632 dnl=== SECTION 10: Specify the output files and generate it
 633 dnl===
 634 dnl===-----------------------------------------------------------------------===
 635
 636 dnl Configure header files
 637 dnl WARNING: dnl If you add or remove any of the following config headers, then
 638 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 639 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 640 dnl files can be updated automatically when their *.in sources change.
 641 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 642 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 643 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 644 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 645 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 646
 647 dnl Configure the makefile's configuration data
 648 AC_CONFIG_FILES([Makefile.config])
 649
 650 dnl Configure doxygen's configuration file
 651 AC_CONFIG_FILES([docs/doxygen.cfg])
 652
 653 dnl Do special configuration of Makefiles
 654 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 655 AC_CONFIG_MAKEFILE(Makefile)
 656 AC_CONFIG_MAKEFILE(Makefile.common)
 657 AC_CONFIG_MAKEFILE(examples/Makefile)
 658 AC_CONFIG_MAKEFILE(lib/Makefile)
 659 AC_CONFIG_MAKEFILE(runtime/Makefile)
 660 AC_CONFIG_MAKEFILE(test/Makefile)
 661 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 662 AC_CONFIG_MAKEFILE(tools/Makefile)
 663 AC_CONFIG_MAKEFILE(utils/Makefile)
 664 AC_CONFIG_MAKEFILE(projects/Makefile)
 665
 666 dnl Finally, crank out the output
 667 AC_OUTPUT
 668
 669 dnl Warn loudly if llvm-gcc was not obviously working
 670 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 671  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 672  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 673  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 674  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 675  AC_MSG_WARN([***** build the llvm tools.])
 676 fi