autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.8svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65
  66 dnl
  67 dnl One tricky part of doing this is that some projects depend upon other
  68 dnl projects.  For example, several projects rely upon the LLVM test suite.
  69 dnl We want to configure those projects first so that their object trees are
  70 dnl created before running the configure scripts of projects that depend upon
  71 dnl them.
  72 dnl
  73
  74 dnl Several projects use llvm-gcc, so configure that first
  75 if test -d ${srcdir}/projects/llvm-gcc ; then
  76   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  77 fi
  78
  79 dnl Several projects use the LLVM test suite, so configure it next.
  80 if test -d ${srcdir}/projects/test-suite ; then
  81   AC_CONFIG_SUBDIRS([projects/test-suite])
  82 fi
  83
  84 dnl llvm-test is the old name of the test-suite, kept here for backwards
  85 dnl compatibility
  86 if test -d ${srcdir}/projects/llvm-test ; then
  87   AC_CONFIG_SUBDIRS([projects/llvm-test])
  88 fi
  89
  90 dnl Some projects use poolalloc; configure that next
  91 if test -d ${srcdir}/projects/poolalloc ; then
  92   AC_CONFIG_SUBDIRS([projects/poolalloc])
  93 fi
  94
  95 if test -d ${srcdir}/projects/llvm-poolalloc ; then
  96   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
  97 fi
  98
  99 dnl Check for all other projects
 100 for i in `ls ${srcdir}/projects`
 101 do
 102   if test -d ${srcdir}/projects/${i} ; then
 103     case ${i} in
 104       CVS) ;;
 105       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 106       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 107       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 108       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 109       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 110       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 111       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 112       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 113       llvm-gcc)       ;;
 114       test-suite)     ;;
 115       llvm-test)      ;;
 116       poolalloc)      ;;
 117       llvm-poolalloc) ;;
 118       *)
 119         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 120         ;;
 121     esac
 122   fi
 123 done
 124
 125 dnl===-----------------------------------------------------------------------===
 126 dnl===
 127 dnl=== SECTION 2: Architecture, target, and host checks
 128 dnl===
 129 dnl===-----------------------------------------------------------------------===
 130
 131 dnl Check the target for which we're compiling and the host that will do the
 132 dnl compilations. This will tell us which LLVM compiler will be used for
 133 dnl compiling SSA into object code. This needs to be done early because
 134 dnl following tests depend on it.
 135 AC_CANONICAL_TARGET
 136
 137 dnl Determine the platform type and cache its value. This helps us configure
 138 dnl the System library to the correct build platform.
 139 AC_CACHE_CHECK([type of operating system we're going to host on],
 140                [llvm_cv_os_type],
 141 [case $host in
 142   *-*-aix*)
 143     llvm_cv_link_all_option="-Wl,--whole-archive"
 144     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 145     llvm_cv_os_type="AIX"
 146     llvm_cv_platform_type="Unix" ;;
 147   *-*-irix*)
 148     llvm_cv_link_all_option="-Wl,--whole-archive"
 149     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 150     llvm_cv_os_type="IRIX"
 151     llvm_cv_platform_type="Unix" ;;
 152   *-*-cygwin*)
 153     llvm_cv_link_all_option="-Wl,--whole-archive"
 154     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 155     llvm_cv_os_type="Cygwin"
 156     llvm_cv_platform_type="Unix" ;;
 157   *-*-darwin*)
 158     llvm_cv_link_all_option="-Wl,-all_load"
 159     llvm_cv_no_link_all_option="-Wl,-noall_load"
 160     llvm_cv_os_type="Darwin"
 161     llvm_cv_platform_type="Unix" ;;
 162   *-*-minix*)
 163     llvm_cv_link_all_option="-Wl,-all_load"
 164     llvm_cv_no_link_all_option="-Wl,-noall_load"
 165     llvm_cv_os_type="Minix"
 166     llvm_cv_platform_type="Unix" ;;
 167   *-*-freebsd*)
 168     llvm_cv_link_all_option="-Wl,--whole-archive"
 169     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 170     llvm_cv_os_type="FreeBSD"
 171     llvm_cv_platform_type="Unix" ;;
 172   *-*-openbsd*)
 173     llvm_cv_link_all_option="-Wl,--whole-archive"
 174     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 175     llvm_cv_os_type="OpenBSD"
 176     llvm_cv_platform_type="Unix" ;;
 177   *-*-netbsd*)
 178     llvm_cv_link_all_option="-Wl,--whole-archive"
 179     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 180     llvm_cv_os_type="NetBSD"
 181     llvm_cv_platform_type="Unix" ;;
 182   *-*-dragonfly*)
 183     llvm_cv_link_all_option="-Wl,--whole-archive"
 184     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 185     llvm_cv_os_type="DragonFly"
 186     llvm_cv_platform_type="Unix" ;;
 187   *-*-hpux*)
 188     llvm_cv_link_all_option="-Wl,--whole-archive"
 189     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 190     llvm_cv_os_type="HP-UX"
 191     llvm_cv_platform_type="Unix" ;;
 192   *-*-interix*)
 193     llvm_cv_link_all_option="-Wl,--whole-archive"
 194     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 195     llvm_cv_os_type="Interix"
 196     llvm_cv_platform_type="Unix" ;;
 197   *-*-linux*)
 198     llvm_cv_link_all_option="-Wl,--whole-archive"
 199     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 200     llvm_cv_os_type="Linux"
 201     llvm_cv_platform_type="Unix" ;;
 202   *-*-solaris*)
 203     llvm_cv_link_all_option="-Wl,-z,allextract"
 204     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 205     llvm_cv_os_type="SunOS"
 206     llvm_cv_platform_type="Unix" ;;
 207   *-*-auroraux*)
 208     llvm_cv_link_all_option="-Wl,-z,allextract"
 209     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 210     llvm_cv_os_type="AuroraUX"
 211     llvm_cv_platform_type="Unix" ;;
 212   *-*-win32*)
 213     llvm_cv_link_all_option="-Wl,--whole-archive"
 214     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 215     llvm_cv_os_type="Win32"
 216     llvm_cv_platform_type="Win32" ;;
 217   *-*-mingw*)
 218     llvm_cv_link_all_option="-Wl,--whole-archive"
 219     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 220     llvm_cv_os_type="MingW"
 221     llvm_cv_platform_type="Win32" ;;
 222   *-*-haiku*)
 223     llvm_cv_link_all_option="-Wl,--whole-archive"
 224     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 225     llvm_cv_os_type="Haiku"
 226     llvm_cv_platform_type="Unix" ;;
 227   *-unknown-eabi*)
 228     llvm_cv_link_all_option="-Wl,--whole-archive"
 229     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 230     llvm_cv_os_type="Freestanding"
 231     llvm_cv_platform_type="Unix" ;;
 232   *-unknown-elf*)
 233     llvm_cv_link_all_option="-Wl,--whole-archive"
 234     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 235     llvm_cv_os_type="Freestanding"
 236     llvm_cv_platform_type="Unix" ;;
 237   *)
 238     llvm_cv_link_all_option=""
 239     llvm_cv_no_link_all_option=""
 240     llvm_cv_os_type="Unknown"
 241     llvm_cv_platform_type="Unknown" ;;
 242 esac])
 243
 244 AC_CACHE_CHECK([type of operating system we're going to target],
 245                [llvm_cv_target_os_type],
 246 [case $target in
 247   *-*-aix*)
 248     llvm_cv_target_os_type="AIX" ;;
 249   *-*-irix*)
 250     llvm_cv_target_os_type="IRIX" ;;
 251   *-*-cygwin*)
 252     llvm_cv_target_os_type="Cygwin" ;;
 253   *-*-darwin*)
 254     llvm_cv_target_os_type="Darwin" ;;
 255   *-*-minix*)
 256     llvm_cv_target_os_type="Minix" ;;
 257   *-*-freebsd*)
 258     llvm_cv_target_os_type="FreeBSD" ;;
 259   *-*-openbsd*)
 260     llvm_cv_target_os_type="OpenBSD" ;;
 261   *-*-netbsd*)
 262     llvm_cv_target_os_type="NetBSD" ;;
 263   *-*-dragonfly*)
 264     llvm_cv_target_os_type="DragonFly" ;;
 265   *-*-hpux*)
 266     llvm_cv_target_os_type="HP-UX" ;;
 267   *-*-interix*)
 268     llvm_cv_target_os_type="Interix" ;;
 269   *-*-linux*)
 270     llvm_cv_target_os_type="Linux" ;;
 271   *-*-solaris*)
 272     llvm_cv_target_os_type="SunOS" ;;
 273   *-*-auroraux*)
 274     llvm_cv_target_os_type="AuroraUX" ;;
 275   *-*-win32*)
 276     llvm_cv_target_os_type="Win32" ;;
 277   *-*-mingw*)
 278     llvm_cv_target_os_type="MingW" ;;
 279   *-*-haiku*)
 280     llvm_cv_target_os_type="Haiku" ;;
 281   *-unknown-eabi*)
 282     llvm_cv_target_os_type="Freestanding" ;;
 283   *)
 284     llvm_cv_target_os_type="Unknown" ;;
 285 esac])
 286
 287 dnl Make sure we aren't attempting to configure for an unknown system
 288 if test "$llvm_cv_os_type" = "Unknown" ; then
 289   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 290 fi
 291
 292 dnl Set the "OS" Makefile variable based on the platform type so the
 293 dnl makefile can configure itself to specific build hosts
 294 AC_SUBST(OS,$llvm_cv_os_type)
 295 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 296 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 297
 298 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 299 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 300 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 301
 302 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 303 dnl This is used by lib/System to determine the basic kind of implementation
 304 dnl to use.
 305 case $llvm_cv_platform_type in
 306   Unix)
 307     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 308     AC_SUBST(LLVM_ON_UNIX,[1])
 309     AC_SUBST(LLVM_ON_WIN32,[0])
 310     ;;
 311   Win32)
 312     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 313     AC_SUBST(LLVM_ON_UNIX,[0])
 314     AC_SUBST(LLVM_ON_WIN32,[1])
 315     ;;
 316 esac
 317
 318 dnl Determine what our target architecture is and configure accordingly.
 319 dnl This will allow Makefiles to make a distinction between the hardware and
 320 dnl the OS.
 321 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 322 [case $target in
 323   i?86-*)                 llvm_cv_target_arch="x86" ;;
 324   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 325   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 326   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 327   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 328   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 329   mips-*)                 llvm_cv_target_arch="Mips" ;;
 330   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 331   xcore-*)                llvm_cv_target_arch="XCore" ;;
 332   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 333   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 334   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 335   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 336   *)                      llvm_cv_target_arch="Unknown" ;;
 337 esac])
 338
 339 if test "$llvm_cv_target_arch" = "Unknown" ; then
 340   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 341 fi
 342
 343 # Determine the LLVM native architecture for the target
 344 case "$llvm_cv_target_arch" in
 345     x86)     LLVM_NATIVE_ARCH="X86" ;;
 346     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 347     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 348 esac
 349
 350 dnl Define a substitution, ARCH, for the target architecture
 351 AC_SUBST(ARCH,$llvm_cv_target_arch)
 352
 353 dnl Check for the endianness of the target
 354 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 355
 356 dnl Check for build platform executable suffix if we're crosscompiling
 357 if test "$cross_compiling" = yes; then
 358   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 359   AC_BUILD_EXEEXT
 360   ac_build_prefix=${build_alias}-
 361   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 362   if test -z "$BUILD_CXX"; then
 363      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 364      if test -z "$BUILD_CXX"; then
 365        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 366      fi
 367   fi
 368 else
 369   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 370 fi
 371
 372 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 373 dnl that this build is being done from a checkout. This sets up several
 374 dnl defaults for the command line switches. When we build with a CVS directory,
 375 dnl we get a debug with assertions turned on. Without, we assume a source
 376 dnl release and we get an optimized build without assertions.
 377 dnl See --enable-optimized and --enable-assertions below
 378 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 379   cvsbuild="yes"
 380   optimize="no"
 381   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 382 else
 383   cvsbuild="no"
 384   optimize="yes"
 385 fi
 386
 387 dnl===-----------------------------------------------------------------------===
 388 dnl===
 389 dnl=== SECTION 3: Command line arguments for the configure script.
 390 dnl===
 391 dnl===-----------------------------------------------------------------------===
 392
 393 dnl --enable-optimized : check whether they want to do an optimized build:
 394 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 395  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 396 if test ${enableval} = "no" ; then
 397   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 398 else
 399   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 400 fi
 401
 402 dnl --enable-profiling : check whether they want to do a profile build:
 403 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 404  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 405 if test ${enableval} = "no" ; then
 406   AC_SUBST(ENABLE_PROFILING,[[]])
 407 else
 408   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 409 fi
 410
 411 dnl --enable-assertions : check whether they want to turn on assertions or not:
 412 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 413   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 414 if test ${enableval} = "yes" ; then
 415   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 416 else
 417   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 418 fi
 419
 420 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 421 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 422   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 423 if test ${enableval} = "yes" ; then
 424   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 425   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 426 else
 427   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 428   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 429 fi
 430
 431 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 432 AC_ARG_ENABLE(debug-runtime,
 433    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 434 if test ${enableval} = "no" ; then
 435   AC_SUBST(DEBUG_RUNTIME,[[]])
 436 else
 437   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 438 fi
 439
 440 dnl --enable-debug-symbols : should even optimized compiler libraries
 441 dnl have debug symbols?
 442 AC_ARG_ENABLE(debug-symbols,
 443    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 444 if test ${enableval} = "no" ; then
 445   AC_SUBST(DEBUG_SYMBOLS,[[]])
 446 else
 447   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 448 fi
 449
 450 dnl --enable-jit: check whether they want to enable the jit
 451 AC_ARG_ENABLE(jit,
 452   AS_HELP_STRING(--enable-jit,
 453                  [Enable Just In Time Compiling (default is YES)]),,
 454   enableval=default)
 455 if test ${enableval} = "no"
 456 then
 457   AC_SUBST(JIT,[[]])
 458 else
 459   case "$llvm_cv_target_arch" in
 460     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 461     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 462     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 463     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 464     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 465     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 466     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 467     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 468     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 469     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 470     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 471     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 472     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 473     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 474   esac
 475 fi
 476
 477 dnl Allow enablement of doxygen generated documentation
 478 AC_ARG_ENABLE(doxygen,
 479               AS_HELP_STRING([--enable-doxygen],
 480                              [Build doxygen documentation (default is NO)]),,
 481                              enableval=default)
 482 case "$enableval" in
 483   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 484   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 485   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 486   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 487 esac
 488
 489 dnl Allow disablement of threads
 490 AC_ARG_ENABLE(threads,
 491               AS_HELP_STRING([--enable-threads],
 492                              [Use threads if available (default is YES)]),,
 493                              enableval=default)
 494 case "$enableval" in
 495   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 496   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 497   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 498   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 499 esac
 500 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 501
 502 dnl Allow building without position independent code
 503 AC_ARG_ENABLE(pic,
 504   AS_HELP_STRING([--enable-pic],
 505                  [Build LLVM with Position Independent Code (default is YES)]),,
 506                  enableval=default)
 507 case "$enableval" in
 508   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 509   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 510   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 511   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 512 esac
 513 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 514                    [Define if position independent code is enabled])
 515
 516 dnl Allow building a shared library and linking tools against it.
 517 AC_ARG_ENABLE(shared,
 518   AS_HELP_STRING([--enable-shared],
 519                  [Build a shared library and link tools against it (default is NO)]),,
 520                  enableval=default)
 521 case "$enableval" in
 522   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 523   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 524   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 525   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 526 esac
 527
 528 dnl Allow specific targets to be specified for building (or not)
 529 TARGETS_TO_BUILD=""
 530 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 531     [Build specific host targets: all or target1,target2,... Valid targets are:
 532      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu, pic16,
 533      xcore, msp430, systemz, blackfin, cbe, msil, and cpp (default=all)]),,
 534     enableval=all)
 535 if test "$enableval" = host-only ; then
 536   enableval=host
 537 fi
 538 case "$enableval" in
 539   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend MSIL CppBackend MBlaze" ;;
 540   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 541       case "$a_target" in
 542         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 543         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 544         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 545         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 546         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 547         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 548         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 549         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 550         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 551         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 552         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 553         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 554         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 555         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 556         msil)     TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 557         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 558         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 559         host) case "$llvm_cv_target_arch" in
 560             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 561             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 562             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 563             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 564             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 565             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 566             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 567             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 568             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 569             PIC16)       TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 570             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 571             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 572             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 573             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 574             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 575           esac ;;
 576         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 577       esac
 578   done
 579   ;;
 580 esac
 581 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 582
 583 # Determine whether we are building LLVM support for the native architecture.
 584 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 585 for a_target in $TARGETS_TO_BUILD; do
 586   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 587     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 588     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 589       [LLVM architecture name for the native architecture, if available])
 590   fi
 591 done
 592
 593 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 594 # target feature def files.
 595 LLVM_ENUM_TARGETS=""
 596 LLVM_ENUM_ASM_PRINTERS=""
 597 LLVM_ENUM_ASM_PARSERS=""
 598 LLVM_ENUM_DISASSEMBLERS=""
 599 for target_to_build in $TARGETS_TO_BUILD; do
 600   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 601   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 602     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 603   fi
 604   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 605     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 606   fi
 607   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 608     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 609   fi
 610 done
 611 AC_SUBST(LLVM_ENUM_TARGETS)
 612 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 613 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 614 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 615
 616 dnl Prevent the CBackend from using printf("%a") for floating point so older
 617 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 618 dnl can still compile the CBE's output
 619 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 620   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 621   enableval=default)
 622 case "$enableval" in
 623   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 624   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 625   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 626   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 627 esac
 628 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 629                    [Define if CBE is enabled for printf %a output])
 630
 631 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 632 AC_ARG_WITH(llvmgccdir,
 633   AS_HELP_STRING([--with-llvmgccdir],
 634     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 635     withval=default)
 636 case "$withval" in
 637   default) WITH_LLVMGCCDIR=default ;;
 638   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 639   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 640 esac
 641
 642 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 643 AC_ARG_WITH(llvmgcc,
 644   AS_HELP_STRING([--with-llvmgcc],
 645     [Specify location of llvm-gcc driver (default searches PATH)]),
 646     LLVMGCC=$with_llvmgcc
 647       WITH_LLVMGCCDIR="",)
 648
 649 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 650 AC_ARG_WITH(llvmgxx,
 651   AS_HELP_STRING([--with-llvmgxx],
 652     [Specify location of llvm-g++ driver (default searches PATH)]),
 653     LLVMGXX=$with_llvmgxx
 654     WITH_LLVMGCCDIR="",)
 655
 656 if test -n "$LLVMGCC"; then
 657    LLVMGCCCOMMAND="$LLVMGCC"
 658 fi
 659
 660 if test -n "$LLVMGXX"; then
 661    LLVMGXXCOMMAND="$LLVMGXX"
 662 fi
 663
 664 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 665    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 666 fi
 667
 668 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 669    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 670 fi
 671
 672 dnl Allow a specific Clang compiler to be used with this LLVM config.
 673 AC_ARG_WITH(clang,
 674   AS_HELP_STRING([--with-clang],
 675     [Specify location of clang compiler (default is --with-built-clang)]),
 676     [],[with_clang=default])
 677
 678 dnl Enable use of the built Clang.
 679 AC_ARG_WITH(built-clang,
 680   AS_HELP_STRING([--with-built-clang],
 681     [Use the compiled Clang as the LLVM compiler (default=check)]),
 682     [],[with_built_clang=check])
 683
 684 dnl Select the Clang compiler option.
 685 dnl
 686 dnl If --with-clang is given, always honor that; otherwise honor
 687 dnl --with-built-clang, or check if we have the clang sources.
 688 AC_MSG_CHECKING([clang compiler])
 689 WITH_CLANGPATH=""
 690 WITH_BUILT_CLANG=0
 691 if test "$with_clang" != "default"; then
 692    WITH_CLANGPATH="$with_clang"
 693    if ! test -x "$WITH_CLANGPATH"; then
 694      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 695    fi
 696 elif test "$with_built_clang" = "yes"; then
 697    WITH_BUILT_CLANG=1
 698 elif test "$with_built_clang" = "no"; then
 699    WITH_BUILT_CLANG=0
 700 else
 701    if test "$with_built_clang" != "check"; then
 702       AC_MSG_ERROR([invalid value for --with-built-clang.])
 703    fi
 704
 705    if test -f ${srcdir}/tools/clang/README.txt; then
 706      WITH_BUILT_CLANG=1
 707    fi
 708 fi
 709
 710 if ! test -z "$WITH_CLANGPATH"; then
 711    AC_MSG_RESULT([$WITH_CLANGPATH])
 712    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 713 elif test "$WITH_BUILT_CLANG" = "1"; then
 714    AC_MSG_RESULT([built])
 715 else
 716    AC_MSG_RESULT([none])
 717 fi
 718 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 719 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 720 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 721
 722 dnl Override the option to use for optimized builds.
 723 AC_ARG_WITH(optimize-option,
 724   AS_HELP_STRING([--with-optimize-option],
 725                  [Select the compiler options to use for optimized builds]),,
 726                  withval=default)
 727 AC_MSG_CHECKING([optimization flags])
 728 case "$withval" in
 729   default)
 730     case "$llvm_cv_os_type" in
 731     FreeBSD) optimize_option=-O2 ;;
 732     MingW) optimize_option=-O2 ;;
 733     *)     optimize_option=-O3 ;;
 734     esac ;;
 735   *) optimize_option="$withval" ;;
 736 esac
 737 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 738 AC_MSG_RESULT([$optimize_option])
 739
 740 dnl Specify extra build options
 741 AC_ARG_WITH(extra-options,
 742   AS_HELP_STRING([--with-extra-options],
 743                  [Specify additional options to compile LLVM with]),,
 744                  withval=default)
 745 case "$withval" in
 746   default) EXTRA_OPTIONS= ;;
 747   *) EXTRA_OPTIONS=$withval ;;
 748 esac
 749 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 750
 751 dnl Allow specific bindings to be specified for building (or not)
 752 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 753     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 754     enableval=default)
 755 BINDINGS_TO_BUILD=""
 756 case "$enableval" in
 757   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 758   all ) BINDINGS_TO_BUILD="ocaml" ;;
 759   none | no) BINDINGS_TO_BUILD="" ;;
 760   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 761       case "$a_binding" in
 762         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 763         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 764       esac
 765   done
 766   ;;
 767 esac
 768
 769 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 770 dnl script for bindings/ocaml/configure, except that its auto value depends on
 771 dnl OCAMLC, which is found here to support tests.
 772 AC_ARG_WITH([ocaml-libdir],
 773   [AS_HELP_STRING([--with-ocaml-libdir],
 774     [Specify install location for ocaml bindings (default is stdlib)])],
 775   [],
 776   [withval=auto])
 777 case "$withval" in
 778   auto) with_ocaml_libdir="$withval" ;;
 779   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 780   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 781 esac
 782
 783 AC_ARG_WITH(c-include-dirs,
 784   AS_HELP_STRING([--with-c-include-dirs],
 785     [Colon separated list of directories clang will search for headers]),,
 786     withval="")
 787 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 788                    [Directories clang will search for headers])
 789
 790 AC_ARG_WITH(cxx-include-root,
 791   AS_HELP_STRING([--with-cxx-include-root],
 792     [Directory with the libstdc++ headers.]),,
 793     withval="")
 794 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 795                    [Directory with the libstdc++ headers.])
 796
 797 AC_ARG_WITH(cxx-include-arch,
 798   AS_HELP_STRING([--with-cxx-include-arch],
 799     [Architecture of the libstdc++ headers.]),,
 800     withval="")
 801 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 802                    [Arch the libstdc++ headers.])
 803
 804 AC_ARG_WITH(cxx-include-32bit-dir,
 805   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 806     [32 bit multilib dir.]),,
 807     withval="")
 808 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 809                    [32 bit multilib directory.])
 810
 811 AC_ARG_WITH(cxx-include-64bit-dir,
 812   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 813     [64 bit multilib directory.]),,
 814     withval="")
 815 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 816                    [64 bit multilib directory.])
 817
 818 dnl Allow linking of LLVM with GPLv3 binutils code.
 819 AC_ARG_WITH(binutils-include,
 820   AS_HELP_STRING([--with-binutils-include],
 821     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 822   withval=default)
 823 case "$withval" in
 824   default) WITH_BINUTILS_INCDIR=default ;;
 825   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 826   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 827 esac
 828 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 829   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 830   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 831      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 832      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 833   fi
 834 fi
 835
 836 dnl --enable-libffi : check whether the user wants to turn off libffi:
 837 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 838   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 839   [case "$enableval" in
 840     yes) llvm_cv_enable_libffi="yes" ;;
 841     no)  llvm_cv_enable_libffi="no"  ;;
 842     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 843   esac],
 844   llvm_cv_enable_libffi=no)
 845
 846 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 847 if test "$llvm_cv_os_type" = "Win32" ; then
 848    llvmc_dynamic="yes"
 849 else
 850    llvmc_dynamic="no"
 851 fi
 852
 853 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 854 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 855 --enable-llvmc-dynamic,
 856 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 857 enableval=$llvmc_dynamic)
 858 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 859    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 860 else
 861    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 862 fi
 863
 864 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 865 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 866 --enable-llvmc-dynamic-plugins,
 867 [Enable dynamic LLVMC plugins (default is YES)]),,
 868 enableval=yes)
 869 if test ${enableval} = "yes" ; then
 870    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 871 else
 872    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 873 fi
 874
 875 dnl===-----------------------------------------------------------------------===
 876 dnl===
 877 dnl=== SECTION 4: Check for programs we need and that they are the right version
 878 dnl===
 879 dnl===-----------------------------------------------------------------------===
 880
 881 dnl Check for compilation tools
 882 AC_PROG_CPP
 883 AC_PROG_CC(gcc)
 884 AC_PROG_CXX(g++)
 885
 886 AC_PROG_NM
 887 AC_SUBST(NM)
 888
 889 dnl Check for the tools that the makefiles require
 890 AC_CHECK_GNU_MAKE
 891 AC_PROG_LN_S
 892 AC_PATH_PROG(CMP, [cmp], [cmp])
 893 AC_PATH_PROG(CP, [cp], [cp])
 894 AC_PATH_PROG(DATE, [date], [date])
 895 AC_PATH_PROG(FIND, [find], [find])
 896 AC_PATH_PROG(GREP, [grep], [grep])
 897 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 898 AC_PATH_PROG(MV,   [mv],   [mv])
 899 AC_PROG_RANLIB
 900 AC_CHECK_TOOL(AR, ar, false)
 901 AC_PATH_PROG(RM,   [rm],   [rm])
 902 AC_PATH_PROG(SED,  [sed],  [sed])
 903 AC_PATH_PROG(TAR,  [tar],  [gtar])
 904 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 905
 906 dnl Looking for misc. graph plotting software
 907 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 908 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 909   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 910   dnl If we're targeting for mingw we should emit windows paths, not msys
 911   if test "$llvm_cv_os_type" = "MingW" ; then
 912     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 913   fi
 914   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 915    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 916 fi
 917 AC_PATH_PROG(DOT, [dot], [echo dot])
 918 if test "$DOT" != "echo dot" ; then
 919   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 920   dnl If we're targeting for mingw we should emit windows paths, not msys
 921   if test "$llvm_cv_os_type" = "MingW" ; then
 922     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 923   fi
 924   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 925    [Define to path to dot program if found or 'echo dot' otherwise])
 926 fi
 927 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 928 if test "$FDP" != "echo fdp" ; then
 929   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 930   dnl If we're targeting for mingw we should emit windows paths, not msys
 931   if test "$llvm_cv_os_type" = "MingW" ; then
 932     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 933   fi
 934   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 935    [Define to path to fdp program if found or 'echo fdp' otherwise])
 936 fi
 937 AC_PATH_PROG(NEATO, [neato], [echo neato])
 938 if test "$NEATO" != "echo neato" ; then
 939   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 940   dnl If we're targeting for mingw we should emit windows paths, not msys
 941   if test "$llvm_cv_os_type" = "MingW" ; then
 942     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 943   fi
 944   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 945    [Define to path to neato program if found or 'echo neato' otherwise])
 946 fi
 947 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 948 if test "$TWOPI" != "echo twopi" ; then
 949   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 950   dnl If we're targeting for mingw we should emit windows paths, not msys
 951   if test "$llvm_cv_os_type" = "MingW" ; then
 952     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 953   fi
 954   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 955    [Define to path to twopi program if found or 'echo twopi' otherwise])
 956 fi
 957 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 958 if test "$CIRCO" != "echo circo" ; then
 959   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 960   dnl If we're targeting for mingw we should emit windows paths, not msys
 961   if test "$llvm_cv_os_type" = "MingW" ; then
 962     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 963   fi
 964   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 965    [Define to path to circo program if found or 'echo circo' otherwise])
 966 fi
 967 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 968 if test "$GV" != "echo gv" ; then
 969   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 970   dnl If we're targeting for mingw we should emit windows paths, not msys
 971   if test "$llvm_cv_os_type" = "MingW" ; then
 972     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 973   fi
 974   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 975    [Define to path to gv program if found or 'echo gv' otherwise])
 976 fi
 977 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 978 if test "$DOTTY" != "echo dotty" ; then
 979   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 980   dnl If we're targeting for mingw we should emit windows paths, not msys
 981   if test "$llvm_cv_os_type" = "MingW" ; then
 982     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 983   fi
 984   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 985    [Define to path to dotty program if found or 'echo dotty' otherwise])
 986 fi
 987
 988 dnl Look for a sufficiently recent version of Perl.
 989 LLVM_PROG_PERL([5.006])
 990 AC_SUBST(PERL)
 991 if test x"$PERL" = xnone; then
 992    AC_SUBST(HAVE_PERL,0)
 993    AC_MSG_ERROR([perl is required but was not found, please install it])
 994 else
 995    AC_SUBST(HAVE_PERL,1)
 996 fi
 997
 998 dnl Find the install program
 999 AC_PROG_INSTALL
1000
1001 dnl Checks for documentation and testing tools that we can do without. If these
1002 dnl are not found then they are set to "true" which always succeeds but does
1003 dnl nothing. This just lets the build output show that we could have done
1004 dnl something if the tool was available.
1005 AC_PATH_PROG(BZIP2, [bzip2])
1006 AC_PATH_PROG(DOXYGEN, [doxygen])
1007 AC_PATH_PROG(GROFF, [groff])
1008 AC_PATH_PROG(GZIP, [gzip])
1009 AC_PATH_PROG(POD2HTML, [pod2html])
1010 AC_PATH_PROG(POD2MAN, [pod2man])
1011 AC_PATH_PROG(RUNTEST, [runtest])
1012 DJ_AC_PATH_TCLSH
1013 AC_PATH_PROG(ZIP, [zip])
1014 AC_PATH_PROGS(OCAMLC, [ocamlc])
1015 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1016 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1017 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1018 AC_PATH_PROGS(GAS, [gas as])
1019
1020 dnl Determine whether the linker supports the -R option.
1021 AC_LINK_USE_R
1022
1023 dnl Determine whether the linker supports the -export-dynamic option.
1024 AC_LINK_EXPORT_DYNAMIC
1025
1026 dnl Determine whether the linker supports the -retain-symbols-file option.
1027 AC_LINK_RETAIN_SYMBOLS_FILE
1028
1029 dnl Check for libtool and the library that has dlopen function (which must come
1030 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1031 dnl libtool).
1032 AC_LIBTOOL_DLOPEN
1033 AC_LIB_LTDL
1034
1035 if test "$WITH_LLVMGCCDIR" = "default" ; then
1036   LLVMGCC="llvm-gcc${EXEEXT}"
1037   LLVMGXX="llvm-g++${EXEEXT}"
1038   LLVMGCCCOMMAND="$LLVMGCC"
1039   LLVMGXXCOMMAND="$LLVMGXX"
1040   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1041   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1042   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
1043   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
1044 else
1045   if test -z "$LLVMGCC"; then
1046     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
1047     LLVMGCCCOMMAND="$LLVMGCC"
1048   fi
1049   if test -z "$LLVMGXX"; then
1050     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1051     LLVMGXXCOMMAND="$LLVMGXX"
1052   fi
1053
1054   AC_SUBST(LLVMGCC,$LLVMGCC)
1055   AC_SUBST(LLVMGXX,$LLVMGXX)
1056   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1057   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1058 fi
1059
1060 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1061 dnl found, otherwise clang if available.
1062 AC_ARG_WITH(llvmcc,
1063   AS_HELP_STRING([--with-llvmcc=<name>],
1064     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1065     [],[with_llvmcc=check])
1066 AC_MSG_CHECKING([LLVM capable compiler])
1067 if test "$with_llvmcc" != "check"; then
1068    if (test "$with_llvmcc" != "llvm-gcc" &&
1069        test "$with_llvmcc" != "clang" &&
1070        test "$with_llvmcc" != "none"); then
1071       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1072    fi
1073    WITH_LLVMCC="$with_llvmcc"
1074 elif test -n "$LLVMGCC"; then
1075    WITH_LLVMCC=llvm-gcc
1076 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1077    WITH_LLVMCC=clang
1078 else
1079    WITH_LLVMCC=none
1080 fi
1081 AC_MSG_RESULT([$WITH_LLVMCC])
1082 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1083
1084 AC_MSG_CHECKING([tool compatibility])
1085
1086 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1087 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1088 dnl to support those options.
1089 dnl "icc" emits gcc signatures
1090 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1091 ICC=no
1092 IXX=no
1093 case $CC in
1094   icc*|icpc*)
1095     ICC=yes
1096     IXX=yes
1097     ;;
1098    *)
1099     ;;
1100 esac
1101
1102 if test "$GCC" != "yes" && test "$ICC" != "yes"
1103 then
1104   AC_MSG_ERROR([gcc|icc required but not found])
1105 fi
1106
1107 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
1108 if test "$GXX" != "yes" && test "$IXX" != "yes"
1109 then
1110   AC_MSG_ERROR([g++|icc required but not found])
1111 fi
1112
1113 dnl Verify that GCC is version 3.0 or higher
1114 if test "$GCC" = "yes"
1115 then
1116   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1117 #error Unsupported GCC version
1118 #endif
1119 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1120 fi
1121
1122 dnl Check for GNU Make.  We use its extensions, so don't build without it
1123 if test -z "$llvm_cv_gnu_make_command"
1124 then
1125   AC_MSG_ERROR([GNU Make required but not found])
1126 fi
1127
1128 dnl Tool compatibility is okay if we make it here.
1129 AC_MSG_RESULT([ok])
1130
1131 dnl Check optional compiler flags.
1132 AC_MSG_CHECKING([optional compiler flags])
1133 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1134 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1135 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1136
1137 dnl===-----------------------------------------------------------------------===
1138 dnl===
1139 dnl=== SECTION 5: Check for libraries
1140 dnl===
1141 dnl===-----------------------------------------------------------------------===
1142
1143 AC_CHECK_LIB(m,sin)
1144 if test "$llvm_cv_os_type" = "MingW" ; then
1145   AC_CHECK_LIB(imagehlp, main)
1146   AC_CHECK_LIB(psapi, main)
1147 fi
1148
1149 dnl dlopen() is required for plugin support.
1150 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1151                [Define if dlopen() is available on this platform.]),
1152                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1153
1154 dnl libffi is optional; used to call external functions from the interpreter
1155 if test "$llvm_cv_enable_libffi" = "yes" ; then
1156   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1157                  [Define if libffi is available on this platform.]),
1158                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1159 fi
1160
1161 dnl mallinfo is optional; the code can compile (minus features) without it
1162 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1163                [Define if mallinfo() is available on this platform.]))
1164
1165 dnl pthread locking functions are optional - but llvm will not be thread-safe
1166 dnl without locks.
1167 if test "$ENABLE_THREADS" -eq 1 ; then
1168   AC_CHECK_LIB(pthread, pthread_mutex_init)
1169   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1170                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1171                            [Have pthread_mutex_lock]))
1172   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1173                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1174                  [Have pthread_rwlock_init]))
1175   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1176                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1177                  [Have pthread_getspecific]))
1178 fi
1179
1180 dnl Allow extra x86-disassembler library
1181 AC_ARG_WITH(udis86,
1182   AS_HELP_STRING([--with-udis86=<path>],
1183     [Use udis86 external x86 disassembler library]),
1184     [
1185       AC_SUBST(USE_UDIS86, [1])
1186       case "$withval" in
1187         /usr/lib|yes) ;;
1188         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1189       esac
1190       AC_CHECK_LIB(udis86, ud_init, [], [
1191         echo "Error! You need to have libudis86 around."
1192         exit -1
1193       ])
1194     ],
1195     AC_SUBST(USE_UDIS86, [0]))
1196 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1197                    [Define if use udis86 library])
1198
1199 dnl Allow OProfile support for JIT output.
1200 AC_ARG_WITH(oprofile,
1201   AS_HELP_STRING([--with-oprofile=<prefix>],
1202     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1203     [
1204       AC_SUBST(USE_OPROFILE, [1])
1205       case "$withval" in
1206         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1207         no) llvm_cv_oppath=
1208             AC_SUBST(USE_OPROFILE, [0]) ;;
1209         *) llvm_cv_oppath="${withval}/lib/oprofile"
1210            CPPFLAGS="-I${withval}/include";;
1211       esac
1212       if test -n "$llvm_cv_oppath" ; then
1213         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1214         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1215         dnl libbfd is not included properly in libopagent in some Debian
1216         dnl versions.  If libbfd isn't found at all, we assume opagent works
1217         dnl anyway.
1218         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1219         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1220           echo "Error! You need to have libopagent around."
1221           exit -1
1222         ])
1223         AC_CHECK_HEADER([opagent.h], [], [
1224           echo "Error! You need to have opagent.h around."
1225           exit -1
1226           ])
1227       fi
1228     ],
1229     [
1230       AC_SUBST(USE_OPROFILE, [0])
1231     ])
1232 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1233                    [Define if we have the oprofile JIT-support library])
1234
1235 dnl===-----------------------------------------------------------------------===
1236 dnl===
1237 dnl=== SECTION 6: Check for header files
1238 dnl===
1239 dnl===-----------------------------------------------------------------------===
1240
1241 dnl First, use autoconf provided macros for specific headers that we need
1242 dnl We don't check for ancient stuff or things that are guaranteed to be there
1243 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1244 dnl Generally we're looking for POSIX headers.
1245 AC_HEADER_DIRENT
1246 AC_HEADER_MMAP_ANONYMOUS
1247 AC_HEADER_STAT
1248 AC_HEADER_STDC
1249 AC_HEADER_SYS_WAIT
1250 AC_HEADER_TIME
1251
1252 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1253 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1254 AC_CHECK_HEADERS([utime.h windows.h])
1255 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1256 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1257 AC_CHECK_HEADERS([valgrind/valgrind.h])
1258 if test "$ENABLE_THREADS" -eq 1 ; then
1259   AC_CHECK_HEADERS(pthread.h,
1260                    AC_SUBST(HAVE_PTHREAD, 1),
1261                    AC_SUBST(HAVE_PTHREAD, 0))
1262 else
1263   AC_SUBST(HAVE_PTHREAD, 0)
1264 fi
1265
1266 dnl Try to find ffi.h.
1267 if test "$llvm_cv_enable_libffi" = "yes" ; then
1268   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1269 fi
1270
1271 dnl===-----------------------------------------------------------------------===
1272 dnl===
1273 dnl=== SECTION 7: Check for types and structures
1274 dnl===
1275 dnl===-----------------------------------------------------------------------===
1276
1277 AC_HUGE_VAL_CHECK
1278 AC_TYPE_PID_T
1279 AC_TYPE_SIZE_T
1280 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1281 AC_STRUCT_TM
1282 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1283 AC_CHECK_TYPES([uint64_t],,
1284          AC_CHECK_TYPES([u_int64_t],,
1285          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1286
1287 dnl===-----------------------------------------------------------------------===
1288 dnl===
1289 dnl=== SECTION 8: Check for specific functions needed
1290 dnl===
1291 dnl===-----------------------------------------------------------------------===
1292
1293 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1294 AC_CHECK_FUNCS([powf fmodf strtof round ])
1295 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1296 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1297 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1298 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1299 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1300 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1301 AC_C_PRINTF_A
1302 AC_FUNC_RAND48
1303
1304 dnl Check for variations in the Standard C++ library and STL. These macros are
1305 dnl provided by LLVM in the autoconf/m4 directory.
1306 AC_FUNC_ISNAN
1307 AC_FUNC_ISINF
1308
1309 dnl Check for mmap support.We also need to know if /dev/zero is required to
1310 dnl be opened for allocating RWX memory.
1311 dnl Make sure we aren't attempting to configure for an unknown system
1312 if test "$llvm_cv_platform_type" = "Unix" ; then
1313   AC_FUNC_MMAP
1314   AC_FUNC_MMAP_FILE
1315   AC_NEED_DEV_ZERO_FOR_MMAP
1316
1317   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1318   then
1319     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1320   fi
1321   if test "$ac_cv_func_mmap_file" = "no"
1322   then
1323     AC_MSG_WARN([mmap() of files required but not found])
1324   fi
1325 fi
1326
1327 dnl atomic builtins are required for threading support.
1328 AC_MSG_CHECKING(for GCC atomic builtins)
1329 AC_LINK_IFELSE(
1330   AC_LANG_SOURCE(
1331     [[int main() {
1332         volatile unsigned long val = 1;
1333         __sync_synchronize();
1334         __sync_val_compare_and_swap(&val, 1, 0);
1335         __sync_add_and_fetch(&val, 1);
1336         __sync_sub_and_fetch(&val, 1);
1337         return 0;
1338       }
1339     ]]),
1340   AC_MSG_RESULT(yes)
1341   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1342   AC_MSG_RESULT(no)
1343   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1344   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1345
1346
1347 dnl===-----------------------------------------------------------------------===
1348 dnl===
1349 dnl=== SECTION 9: Additional checks, variables, etc.
1350 dnl===
1351 dnl===-----------------------------------------------------------------------===
1352
1353 dnl Handle 32-bit linux systems running a 64-bit kernel.
1354 dnl This has to come after section 4 because it invokes the compiler.
1355 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1356   AC_IS_LINUX_MIXED
1357   if test "$llvm_cv_linux_mixed" = "yes"; then
1358     llvm_cv_target_arch="x86"
1359     ARCH="x86"
1360   fi
1361 fi
1362
1363 dnl Check, whether __dso_handle is present
1364 AC_CHECK_FUNCS([__dso_handle])
1365
1366 dnl See if the llvm-gcc executable can compile to LLVM assembly
1367 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1368 [llvm_cv_llvmgcc_sanity="no"
1369 if test -x "$LLVMGCC" ; then
1370   cp /dev/null conftest.c
1371   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1372       grep 'target datalayout =' > /dev/null 2>&1
1373   if test $? -eq 0 ; then
1374     llvm_cv_llvmgcc_sanity="yes"
1375   fi
1376   rm conftest.c
1377 fi])
1378
1379 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1380 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1381   AC_MSG_CHECKING([llvm-gcc component support])
1382   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1383   AC_SUBST(LLVMCC1,$llvmcc1path)
1384   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1385   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1386   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1387   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1388   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1389   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1390   AC_MSG_RESULT([ok])
1391 fi
1392
1393 dnl Propagate the shared library extension that the libltdl checks did to
1394 dnl the Makefiles so we can use it there too
1395 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1396
1397 dnl Propagate the run-time library path variable that the libltdl
1398 dnl checks found to the Makefiles so we can use it there too
1399 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1400
1401 # Translate the various configuration directories and other basic
1402 # information into substitutions that will end up in Makefile.config.in
1403 # that these configured values can be used by the makefiles
1404 if test "${prefix}" = "NONE" ; then
1405   prefix="/usr/local"
1406 fi
1407 eval LLVM_PREFIX="${prefix}";
1408 eval LLVM_BINDIR="${prefix}/bin";
1409 eval LLVM_LIBDIR="${prefix}/lib";
1410 eval LLVM_DATADIR="${prefix}/share/llvm";
1411 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1412 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1413 eval LLVM_INCLUDEDIR="${prefix}/include";
1414 eval LLVM_INFODIR="${prefix}/info";
1415 eval LLVM_MANDIR="${prefix}/man";
1416 LLVM_CONFIGTIME=`date`
1417 AC_SUBST(LLVM_PREFIX)
1418 AC_SUBST(LLVM_BINDIR)
1419 AC_SUBST(LLVM_LIBDIR)
1420 AC_SUBST(LLVM_DATADIR)
1421 AC_SUBST(LLVM_DOCSDIR)
1422 AC_SUBST(LLVM_ETCDIR)
1423 AC_SUBST(LLVM_INCLUDEDIR)
1424 AC_SUBST(LLVM_INFODIR)
1425 AC_SUBST(LLVM_MANDIR)
1426 AC_SUBST(LLVM_CONFIGTIME)
1427
1428 # Place the various directores into the config.h file as #defines so that we
1429 # can know about the installation paths within LLVM.
1430 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1431                    [Installation prefix directory])
1432 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1433                    [Installation directory for binary executables])
1434 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1435                    [Installation directory for libraries])
1436 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1437                    [Installation directory for data files])
1438 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1439                    [Installation directory for documentation])
1440 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1441                    [Installation directory for config files])
1442 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1443                    [Installation directory for include files])
1444 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1445                    [Installation directory for .info files])
1446 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1447                    [Installation directory for man pages])
1448 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1449                    [Time at which LLVM was configured])
1450 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1451                    [Host triple we were built on])
1452
1453 # Determine which bindings to build.
1454 if test "$BINDINGS_TO_BUILD" = auto ; then
1455   BINDINGS_TO_BUILD=""
1456   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1457     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1458   fi
1459 fi
1460 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1461
1462 # This isn't really configurey, but it avoids having to repeat the list in
1463 # other files.
1464 AC_SUBST(ALL_BINDINGS,ocaml)
1465
1466 # Do any work necessary to ensure that bindings have what they need.
1467 binding_prereqs_failed=0
1468 for a_binding in $BINDINGS_TO_BUILD ; do
1469   case "$a_binding" in
1470   ocaml)
1471     if test "x$OCAMLC" = x ; then
1472       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1473       binding_prereqs_failed=1
1474     fi
1475     if test "x$OCAMLDEP" = x ; then
1476       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1477       binding_prereqs_failed=1
1478     fi
1479     if test "x$OCAMLOPT" = x ; then
1480       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1481       dnl ocamlopt is optional!
1482     fi
1483     if test "x$with_ocaml_libdir" != xauto ; then
1484       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1485     else
1486       ocaml_stdlib="`"$OCAMLC" -where`"
1487       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1488       then
1489         # ocaml stdlib is beneath our prefix; use stdlib
1490         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1491       else
1492         # ocaml stdlib is outside our prefix; use libdir/ocaml
1493         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1494       fi
1495     fi
1496     ;;
1497   esac
1498 done
1499 if test "$binding_prereqs_failed" = 1 ; then
1500   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1501 fi
1502
1503 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1504 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1505
1506 dnl Determine linker rpath flag
1507 if test "$llvm_cv_link_use_r" = "yes" ; then
1508   RPATH="-Wl,-R"
1509 else
1510   RPATH="-Wl,-rpath"
1511 fi
1512 AC_SUBST(RPATH)
1513
1514 dnl Determine linker rdynamic flag
1515 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1516   RDYNAMIC="-Wl,-export-dynamic"
1517 else
1518   RDYNAMIC=""
1519 fi
1520 AC_SUBST(RDYNAMIC)
1521
1522 dnl===-----------------------------------------------------------------------===
1523 dnl===
1524 dnl=== SECTION 10: Specify the output files and generate it
1525 dnl===
1526 dnl===-----------------------------------------------------------------------===
1527
1528 dnl Configure header files
1529 dnl WARNING: dnl If you add or remove any of the following config headers, then
1530 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1531 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1532 dnl files can be updated automatically when their *.in sources change.
1533 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1534 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1535 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1536 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1537 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1538 AC_CONFIG_HEADERS([include/llvm/System/DataTypes.h])
1539
1540 dnl Configure the makefile's configuration data
1541 AC_CONFIG_FILES([Makefile.config])
1542
1543 dnl Configure the RPM spec file for LLVM
1544 AC_CONFIG_FILES([llvm.spec])
1545
1546 dnl Configure doxygen's configuration file
1547 AC_CONFIG_FILES([docs/doxygen.cfg])
1548
1549 dnl Configure llvmc's Base plugin
1550 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1551
1552 dnl Do the first stage of configuration for llvm-config.in.
1553 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1554
1555 dnl Do special configuration of Makefiles
1556 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1557 AC_CONFIG_MAKEFILE(Makefile)
1558 AC_CONFIG_MAKEFILE(Makefile.common)
1559 AC_CONFIG_MAKEFILE(examples/Makefile)
1560 AC_CONFIG_MAKEFILE(lib/Makefile)
1561 AC_CONFIG_MAKEFILE(runtime/Makefile)
1562 AC_CONFIG_MAKEFILE(test/Makefile)
1563 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1564 AC_CONFIG_MAKEFILE(unittests/Makefile)
1565 AC_CONFIG_MAKEFILE(tools/Makefile)
1566 AC_CONFIG_MAKEFILE(utils/Makefile)
1567 AC_CONFIG_MAKEFILE(projects/Makefile)
1568 AC_CONFIG_MAKEFILE(bindings/Makefile)
1569 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1570
1571 dnl Finally, crank out the output
1572 AC_OUTPUT