autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[3.0svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2011 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2011 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65
  66 dnl
  67 dnl One tricky part of doing this is that some projects depend upon other
  68 dnl projects.  For example, several projects rely upon the LLVM test suite.
  69 dnl We want to configure those projects first so that their object trees are
  70 dnl created before running the configure scripts of projects that depend upon
  71 dnl them.
  72 dnl
  73
  74 dnl Several projects use llvm-gcc, so configure that first
  75 if test -d ${srcdir}/projects/llvm-gcc ; then
  76   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  77 fi
  78
  79 dnl Several projects use the LLVM test suite, so configure it next.
  80 if test -d ${srcdir}/projects/test-suite ; then
  81   AC_CONFIG_SUBDIRS([projects/test-suite])
  82 fi
  83
  84 dnl llvm-test is the old name of the test-suite, kept here for backwards
  85 dnl compatibility
  86 if test -d ${srcdir}/projects/llvm-test ; then
  87   AC_CONFIG_SUBDIRS([projects/llvm-test])
  88 fi
  89
  90 dnl Some projects use poolalloc; configure that next
  91 if test -d ${srcdir}/projects/poolalloc ; then
  92   AC_CONFIG_SUBDIRS([projects/poolalloc])
  93 fi
  94
  95 if test -d ${srcdir}/projects/llvm-poolalloc ; then
  96   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
  97 fi
  98
  99 dnl Check for all other projects
 100 for i in `ls ${srcdir}/projects`
 101 do
 102   if test -d ${srcdir}/projects/${i} ; then
 103     case ${i} in
 104       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 105       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 106       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 107       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 108       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 109       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 110       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 111       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 112       llvm-gcc)       ;;
 113       test-suite)     ;;
 114       llvm-test)      ;;
 115       poolalloc)      ;;
 116       llvm-poolalloc) ;;
 117       *)
 118         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 119         ;;
 120     esac
 121   fi
 122 done
 123
 124 dnl Disable the build of polly, even if it is checked out into tools/polly.
 125 AC_ARG_ENABLE(polly,
 126               AS_HELP_STRING([--enable-polly],
 127                              [Use polly if available (default is YES)]),,
 128                              enableval=default)
 129 case "$enableval" in
 130   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 131   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 132   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 133   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 134 esac
 135
 136
 137 dnl Check if polly is checked out into tools/polly and configure it if
 138 dnl available.
 139 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 140   AC_SUBST(LLVM_HAS_POLLY,1)
 141   AC_CONFIG_SUBDIRS([tools/polly])
 142 fi
 143
 144 dnl===-----------------------------------------------------------------------===
 145 dnl===
 146 dnl=== SECTION 2: Architecture, target, and host checks
 147 dnl===
 148 dnl===-----------------------------------------------------------------------===
 149
 150 dnl Check the target for which we're compiling and the host that will do the
 151 dnl compilations. This will tell us which LLVM compiler will be used for
 152 dnl compiling SSA into object code. This needs to be done early because
 153 dnl following tests depend on it.
 154 AC_CANONICAL_TARGET
 155
 156 dnl Determine the platform type and cache its value. This helps us configure
 157 dnl the System library to the correct build platform.
 158 AC_CACHE_CHECK([type of operating system we're going to host on],
 159                [llvm_cv_os_type],
 160 [case $host in
 161   *-*-aix*)
 162     llvm_cv_link_all_option="-Wl,--whole-archive"
 163     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 164     llvm_cv_os_type="AIX"
 165     llvm_cv_platform_type="Unix" ;;
 166   *-*-irix*)
 167     llvm_cv_link_all_option="-Wl,--whole-archive"
 168     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 169     llvm_cv_os_type="IRIX"
 170     llvm_cv_platform_type="Unix" ;;
 171   *-*-cygwin*)
 172     llvm_cv_link_all_option="-Wl,--whole-archive"
 173     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 174     llvm_cv_os_type="Cygwin"
 175     llvm_cv_platform_type="Unix" ;;
 176   *-*-darwin*)
 177     llvm_cv_link_all_option="-Wl,-all_load"
 178     llvm_cv_no_link_all_option="-Wl,-noall_load"
 179     llvm_cv_os_type="Darwin"
 180     llvm_cv_platform_type="Unix" ;;
 181   *-*-minix*)
 182     llvm_cv_link_all_option="-Wl,-all_load"
 183     llvm_cv_no_link_all_option="-Wl,-noall_load"
 184     llvm_cv_os_type="Minix"
 185     llvm_cv_platform_type="Unix" ;;
 186   *-*-freebsd*)
 187     llvm_cv_link_all_option="-Wl,--whole-archive"
 188     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 189     llvm_cv_os_type="FreeBSD"
 190     llvm_cv_platform_type="Unix" ;;
 191   *-*-openbsd*)
 192     llvm_cv_link_all_option="-Wl,--whole-archive"
 193     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 194     llvm_cv_os_type="OpenBSD"
 195     llvm_cv_platform_type="Unix" ;;
 196   *-*-netbsd*)
 197     llvm_cv_link_all_option="-Wl,--whole-archive"
 198     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 199     llvm_cv_os_type="NetBSD"
 200     llvm_cv_platform_type="Unix" ;;
 201   *-*-dragonfly*)
 202     llvm_cv_link_all_option="-Wl,--whole-archive"
 203     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 204     llvm_cv_os_type="DragonFly"
 205     llvm_cv_platform_type="Unix" ;;
 206   *-*-hpux*)
 207     llvm_cv_link_all_option="-Wl,--whole-archive"
 208     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 209     llvm_cv_os_type="HP-UX"
 210     llvm_cv_platform_type="Unix" ;;
 211   *-*-interix*)
 212     llvm_cv_link_all_option="-Wl,--whole-archive"
 213     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 214     llvm_cv_os_type="Interix"
 215     llvm_cv_platform_type="Unix" ;;
 216   *-*-linux*)
 217     llvm_cv_link_all_option="-Wl,--whole-archive"
 218     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 219     llvm_cv_os_type="Linux"
 220     llvm_cv_platform_type="Unix" ;;
 221   *-*-solaris*)
 222     llvm_cv_link_all_option="-Wl,-z,allextract"
 223     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 224     llvm_cv_os_type="SunOS"
 225     llvm_cv_platform_type="Unix" ;;
 226   *-*-auroraux*)
 227     llvm_cv_link_all_option="-Wl,-z,allextract"
 228     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 229     llvm_cv_os_type="AuroraUX"
 230     llvm_cv_platform_type="Unix" ;;
 231   *-*-win32*)
 232     llvm_cv_link_all_option="-Wl,--whole-archive"
 233     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 234     llvm_cv_os_type="Win32"
 235     llvm_cv_platform_type="Win32" ;;
 236   *-*-mingw*)
 237     llvm_cv_link_all_option="-Wl,--whole-archive"
 238     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 239     llvm_cv_os_type="MingW"
 240     llvm_cv_platform_type="Win32" ;;
 241   *-*-haiku*)
 242     llvm_cv_link_all_option="-Wl,--whole-archive"
 243     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 244     llvm_cv_os_type="Haiku"
 245     llvm_cv_platform_type="Unix" ;;
 246   *-unknown-eabi*)
 247     llvm_cv_link_all_option="-Wl,--whole-archive"
 248     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 249     llvm_cv_os_type="Freestanding"
 250     llvm_cv_platform_type="Unix" ;;
 251   *-unknown-elf*)
 252     llvm_cv_link_all_option="-Wl,--whole-archive"
 253     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 254     llvm_cv_os_type="Freestanding"
 255     llvm_cv_platform_type="Unix" ;;
 256   *)
 257     llvm_cv_link_all_option=""
 258     llvm_cv_no_link_all_option=""
 259     llvm_cv_os_type="Unknown"
 260     llvm_cv_platform_type="Unknown" ;;
 261 esac])
 262
 263 AC_CACHE_CHECK([type of operating system we're going to target],
 264                [llvm_cv_target_os_type],
 265 [case $target in
 266   *-*-aix*)
 267     llvm_cv_target_os_type="AIX" ;;
 268   *-*-irix*)
 269     llvm_cv_target_os_type="IRIX" ;;
 270   *-*-cygwin*)
 271     llvm_cv_target_os_type="Cygwin" ;;
 272   *-*-darwin*)
 273     llvm_cv_target_os_type="Darwin" ;;
 274   *-*-minix*)
 275     llvm_cv_target_os_type="Minix" ;;
 276   *-*-freebsd*)
 277     llvm_cv_target_os_type="FreeBSD" ;;
 278   *-*-openbsd*)
 279     llvm_cv_target_os_type="OpenBSD" ;;
 280   *-*-netbsd*)
 281     llvm_cv_target_os_type="NetBSD" ;;
 282   *-*-dragonfly*)
 283     llvm_cv_target_os_type="DragonFly" ;;
 284   *-*-hpux*)
 285     llvm_cv_target_os_type="HP-UX" ;;
 286   *-*-interix*)
 287     llvm_cv_target_os_type="Interix" ;;
 288   *-*-linux*)
 289     llvm_cv_target_os_type="Linux" ;;
 290   *-*-solaris*)
 291     llvm_cv_target_os_type="SunOS" ;;
 292   *-*-auroraux*)
 293     llvm_cv_target_os_type="AuroraUX" ;;
 294   *-*-win32*)
 295     llvm_cv_target_os_type="Win32" ;;
 296   *-*-mingw*)
 297     llvm_cv_target_os_type="MingW" ;;
 298   *-*-haiku*)
 299     llvm_cv_target_os_type="Haiku" ;;
 300   *-*-rtems*)
 301     llvm_cv_target_os_type="RTEMS" ;;
 302   *-unknown-eabi*)
 303     llvm_cv_target_os_type="Freestanding" ;;
 304   *)
 305     llvm_cv_target_os_type="Unknown" ;;
 306 esac])
 307
 308 dnl Make sure we aren't attempting to configure for an unknown system
 309 if test "$llvm_cv_os_type" = "Unknown" ; then
 310   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 311 fi
 312
 313 dnl Set the "OS" Makefile variable based on the platform type so the
 314 dnl makefile can configure itself to specific build hosts
 315 AC_SUBST(OS,$llvm_cv_os_type)
 316 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 317 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 318
 319 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 320 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 321 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 322
 323 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 324 dnl This is used by lib/Support to determine the basic kind of implementation
 325 dnl to use.
 326 case $llvm_cv_platform_type in
 327   Unix)
 328     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 329     AC_SUBST(LLVM_ON_UNIX,[1])
 330     AC_SUBST(LLVM_ON_WIN32,[0])
 331     ;;
 332   Win32)
 333     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 334     AC_SUBST(LLVM_ON_UNIX,[0])
 335     AC_SUBST(LLVM_ON_WIN32,[1])
 336     ;;
 337 esac
 338
 339 dnl Determine what our target architecture is and configure accordingly.
 340 dnl This will allow Makefiles to make a distinction between the hardware and
 341 dnl the OS.
 342 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 343 [case $target in
 344   i?86-*)                 llvm_cv_target_arch="x86" ;;
 345   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 346   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 347   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 348   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 349   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 350   mips-*)                 llvm_cv_target_arch="Mips" ;;
 351   xcore-*)                llvm_cv_target_arch="XCore" ;;
 352   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 353   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 354   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 355   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 356   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 357   *)                      llvm_cv_target_arch="Unknown" ;;
 358 esac])
 359
 360 if test "$llvm_cv_target_arch" = "Unknown" ; then
 361   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 362 fi
 363
 364 # Determine the LLVM native architecture for the target
 365 case "$llvm_cv_target_arch" in
 366     x86)     LLVM_NATIVE_ARCH="X86" ;;
 367     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 368     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 369 esac
 370
 371 dnl Define a substitution, ARCH, for the target architecture
 372 AC_SUBST(ARCH,$llvm_cv_target_arch)
 373
 374 dnl Check for the endianness of the target
 375 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 376
 377 dnl Check for build platform executable suffix if we're crosscompiling
 378 if test "$cross_compiling" = yes; then
 379   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 380   AC_BUILD_EXEEXT
 381   ac_build_prefix=${build_alias}-
 382   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 383   if test -z "$BUILD_CXX"; then
 384      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 385      if test -z "$BUILD_CXX"; then
 386        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 387      fi
 388   fi
 389 else
 390   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 391 fi
 392
 393 dnl Check to see if there's a .svn or .git directory indicating that this
 394 dnl build is being done from a checkout. This sets up several defaults for
 395 dnl the command line switches. When we build with a checkout directory,
 396 dnl we get a debug with assertions turned on. Without, we assume a source
 397 dnl release and we get an optimized build without assertions.
 398 dnl See --enable-optimized and --enable-assertions below
 399 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 400   cvsbuild="yes"
 401   optimize="no"
 402   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 403 else
 404   cvsbuild="no"
 405   optimize="yes"
 406 fi
 407
 408 dnl===-----------------------------------------------------------------------===
 409 dnl===
 410 dnl=== SECTION 3: Command line arguments for the configure script.
 411 dnl===
 412 dnl===-----------------------------------------------------------------------===
 413
 414 dnl --enable-optimized : check whether they want to do an optimized build:
 415 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 416  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 417 if test ${enableval} = "no" ; then
 418   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 419 else
 420   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 421 fi
 422
 423 dnl --enable-profiling : check whether they want to do a profile build:
 424 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 425  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 426 if test ${enableval} = "no" ; then
 427   AC_SUBST(ENABLE_PROFILING,[[]])
 428 else
 429   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 430 fi
 431
 432 dnl --enable-assertions : check whether they want to turn on assertions or not:
 433 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 434   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 435 if test ${enableval} = "yes" ; then
 436   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 437 else
 438   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 439 fi
 440
 441 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 442 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 443   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 444 if test ${enableval} = "yes" ; then
 445   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 446   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 447 else
 448   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 449   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 450 fi
 451
 452 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 453 AC_ARG_ENABLE(debug-runtime,
 454    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 455 if test ${enableval} = "no" ; then
 456   AC_SUBST(DEBUG_RUNTIME,[[]])
 457 else
 458   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 459 fi
 460
 461 dnl --enable-debug-symbols : should even optimized compiler libraries
 462 dnl have debug symbols?
 463 AC_ARG_ENABLE(debug-symbols,
 464    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 465 if test ${enableval} = "no" ; then
 466   AC_SUBST(DEBUG_SYMBOLS,[[]])
 467 else
 468   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 469 fi
 470
 471 dnl --enable-jit: check whether they want to enable the jit
 472 AC_ARG_ENABLE(jit,
 473   AS_HELP_STRING(--enable-jit,
 474                  [Enable Just In Time Compiling (default is YES)]),,
 475   enableval=default)
 476 if test ${enableval} = "no"
 477 then
 478   AC_SUBST(JIT,[[]])
 479 else
 480   case "$llvm_cv_target_arch" in
 481     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 482     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 483     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 484     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 485     Alpha)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 486     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 487     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 488     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 489     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 490     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 491     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 492     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 493     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 494     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 495   esac
 496 fi
 497
 498 dnl Allow enablement of building and installing docs
 499 AC_ARG_ENABLE(docs,
 500               AS_HELP_STRING([--enable-docs],
 501                              [Build documents (default is YES)]),,
 502                              enableval=default)
 503 case "$enableval" in
 504   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 505   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 506   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 507   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 508 esac
 509
 510 dnl Allow enablement of doxygen generated documentation
 511 AC_ARG_ENABLE(doxygen,
 512               AS_HELP_STRING([--enable-doxygen],
 513                              [Build doxygen documentation (default is NO)]),,
 514                              enableval=default)
 515 case "$enableval" in
 516   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 517   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 518   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 519   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 520 esac
 521
 522 dnl Allow disablement of threads
 523 AC_ARG_ENABLE(threads,
 524               AS_HELP_STRING([--enable-threads],
 525                              [Use threads if available (default is YES)]),,
 526                              enableval=default)
 527 case "$enableval" in
 528   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 529   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 530   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 531   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 532 esac
 533 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 534
 535 dnl Allow disablement of pthread.h
 536 AC_ARG_ENABLE(pthreads,
 537               AS_HELP_STRING([--enable-pthreads],
 538                              [Use pthreads if available (default is YES)]),,
 539                              enableval=default)
 540 case "$enableval" in
 541   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 542   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 543   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 544   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 545 esac
 546
 547 dnl Allow building without position independent code
 548 AC_ARG_ENABLE(pic,
 549   AS_HELP_STRING([--enable-pic],
 550                  [Build LLVM with Position Independent Code (default is YES)]),,
 551                  enableval=default)
 552 case "$enableval" in
 553   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 554   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 555   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 556   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 557 esac
 558 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 559                    [Define if position independent code is enabled])
 560
 561 dnl Allow building a shared library and linking tools against it.
 562 AC_ARG_ENABLE(shared,
 563   AS_HELP_STRING([--enable-shared],
 564                  [Build a shared library and link tools against it (default is NO)]),,
 565                  enableval=default)
 566 case "$enableval" in
 567   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 568   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 569   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 570   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 571 esac
 572
 573 dnl Allow libstdc++ is embedded in LLVM.dll.
 574 AC_ARG_ENABLE(embed-stdcxx,
 575   AS_HELP_STRING([--enable-embed-stdcxx],
 576                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is YES)]),,
 577                  enableval=default)
 578 case "$enableval" in
 579   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 580   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 581   default) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 582   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 583 esac
 584
 585 dnl Enable embedding timestamp information into build.
 586 AC_ARG_ENABLE(timestamps,
 587   AS_HELP_STRING([--enable-timestamps],
 588                  [Enable embedding timestamp information in build (default is YES)]),,
 589                  enableval=default)
 590 case "$enableval" in
 591   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 592   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 593   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 594   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 595 esac
 596 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 597                    [Define if timestamp information (e.g., __DATE___) is allowed])
 598
 599 dnl Allow specific targets to be specified for building (or not)
 600 TARGETS_TO_BUILD=""
 601 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 602     [Build specific host targets: all or target1,target2,... Valid targets are:
 603      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu,
 604      xcore, msp430, systemz, blackfin, ptx, cbe, and cpp (default=all)]),,
 605     enableval=all)
 606 if test "$enableval" = host-only ; then
 607   enableval=host
 608 fi
 609 case "$enableval" in
 610   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU XCore MSP430 SystemZ Blackfin CBackend CppBackend MBlaze PTX" ;;
 611   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 612       case "$a_target" in
 613         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 614         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 615         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 616         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 617         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 618         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 619         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 620         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 621         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 622         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 623         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 624         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 625         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 626         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 627         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 628         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 629         host) case "$llvm_cv_target_arch" in
 630             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 631             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 632             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 633             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 634             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 635             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 636             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 637             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 638             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 639             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 640             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 641             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 642             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 643             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 644             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 645           esac ;;
 646         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 647       esac
 648   done
 649   ;;
 650 esac
 651 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 652
 653 # Determine whether we are building LLVM support for the native architecture.
 654 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 655 for a_target in $TARGETS_TO_BUILD; do
 656   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 657     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 658       [LLVM architecture name for the native architecture, if available])
 659     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 660     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 661     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 662     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 663       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 664     fi
 665     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 666       [LLVM name for the native Target init function, if available])
 667     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 668       [LLVM name for the native TargetInfo init function, if available])
 669     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 670       [LLVM name for the native AsmPrinter init function, if available])
 671     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 672       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 673        [LLVM name for the native AsmParser init function, if available])
 674     fi
 675   fi
 676 done
 677
 678 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 679 # target feature def files.
 680 LLVM_ENUM_TARGETS=""
 681 LLVM_ENUM_ASM_PRINTERS=""
 682 LLVM_ENUM_ASM_PARSERS=""
 683 LLVM_ENUM_DISASSEMBLERS=""
 684 for target_to_build in $TARGETS_TO_BUILD; do
 685   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 686   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 687     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 688   fi
 689   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 690     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 691   fi
 692   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 693     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 694   fi
 695 done
 696 AC_SUBST(LLVM_ENUM_TARGETS)
 697 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 698 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 699 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 700
 701 dnl Prevent the CBackend from using printf("%a") for floating point so older
 702 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 703 dnl can still compile the CBE's output
 704 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 705   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 706   enableval=default)
 707 case "$enableval" in
 708   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 709   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 710   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 711   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 712 esac
 713 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 714                    [Define if CBE is enabled for printf %a output])
 715
 716 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 717 AC_ARG_WITH(llvmgccdir,
 718   AS_HELP_STRING([--with-llvmgccdir],
 719     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 720     withval=default)
 721 case "$withval" in
 722   default) WITH_LLVMGCCDIR=default ;;
 723   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 724   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 725 esac
 726
 727 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 728 AC_ARG_WITH(llvmgcc,
 729   AS_HELP_STRING([--with-llvmgcc],
 730     [Specify location of llvm-gcc driver (default searches PATH)]),
 731     LLVMGCC=$with_llvmgcc
 732       WITH_LLVMGCCDIR="",)
 733
 734 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 735 AC_ARG_WITH(llvmgxx,
 736   AS_HELP_STRING([--with-llvmgxx],
 737     [Specify location of llvm-g++ driver (default searches PATH)]),
 738     LLVMGXX=$with_llvmgxx
 739     WITH_LLVMGCCDIR="",)
 740
 741 if test -n "$LLVMGCC"; then
 742    LLVMGCCCOMMAND="$LLVMGCC"
 743 fi
 744
 745 if test -n "$LLVMGXX"; then
 746    LLVMGXXCOMMAND="$LLVMGXX"
 747 fi
 748
 749 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 750    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 751 fi
 752
 753 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 754    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 755 fi
 756
 757 dnl Allow a specific Clang compiler to be used with this LLVM config.
 758 AC_ARG_WITH(clang,
 759   AS_HELP_STRING([--with-clang],
 760     [Specify location of clang compiler (default is --with-built-clang)]),
 761     [],[with_clang=default])
 762
 763 dnl Enable use of the built Clang.
 764 AC_ARG_WITH(built-clang,
 765   AS_HELP_STRING([--with-built-clang],
 766     [Use the compiled Clang as the LLVM compiler (default=check)]),
 767     [],[with_built_clang=check])
 768
 769 dnl Select the Clang compiler option.
 770 dnl
 771 dnl If --with-clang is given, always honor that; otherwise honor
 772 dnl --with-built-clang, or check if we have the clang sources.
 773 AC_MSG_CHECKING([clang compiler])
 774 WITH_CLANGPATH=""
 775 WITH_BUILT_CLANG=0
 776 if test "$with_clang" != "default"; then
 777    WITH_CLANGPATH="$with_clang"
 778    if ! test -x "$WITH_CLANGPATH"; then
 779      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 780    fi
 781 elif test "$with_built_clang" = "yes"; then
 782    WITH_BUILT_CLANG=1
 783 elif test "$with_built_clang" = "no"; then
 784    WITH_BUILT_CLANG=0
 785 else
 786    if test "$with_built_clang" != "check"; then
 787       AC_MSG_ERROR([invalid value for --with-built-clang.])
 788    fi
 789
 790    if test -f ${srcdir}/tools/clang/README.txt; then
 791      WITH_BUILT_CLANG=1
 792    fi
 793 fi
 794
 795 if ! test -z "$WITH_CLANGPATH"; then
 796    AC_MSG_RESULT([$WITH_CLANGPATH])
 797    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 798 elif test "$WITH_BUILT_CLANG" = "1"; then
 799    AC_MSG_RESULT([built])
 800 else
 801    AC_MSG_RESULT([none])
 802 fi
 803 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 804 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 805 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 806
 807 dnl Override the option to use for optimized builds.
 808 AC_ARG_WITH(optimize-option,
 809   AS_HELP_STRING([--with-optimize-option],
 810                  [Select the compiler options to use for optimized builds]),,
 811                  withval=default)
 812 AC_MSG_CHECKING([optimization flags])
 813 case "$withval" in
 814   default)
 815     case "$llvm_cv_os_type" in
 816     FreeBSD) optimize_option=-O2 ;;
 817     MingW) optimize_option=-O2 ;;
 818     *)     optimize_option=-O3 ;;
 819     esac ;;
 820   *) optimize_option="$withval" ;;
 821 esac
 822 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 823 AC_MSG_RESULT([$optimize_option])
 824
 825 dnl Specify extra build options
 826 AC_ARG_WITH(extra-options,
 827   AS_HELP_STRING([--with-extra-options],
 828                  [Specify additional options to compile LLVM with]),,
 829                  withval=default)
 830 case "$withval" in
 831   default) EXTRA_OPTIONS= ;;
 832   *) EXTRA_OPTIONS=$withval ;;
 833 esac
 834 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 835
 836 dnl Specify extra linker build options
 837 AC_ARG_WITH(extra-ld-options,
 838   AS_HELP_STRING([--with-extra-ld-options],
 839                  [Specify additional options to link LLVM with]),,
 840                  withval=default)
 841 case "$withval" in
 842   default) EXTRA_LD_OPTIONS= ;;
 843   *) EXTRA_LD_OPTIONS=$withval ;;
 844 esac
 845 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 846
 847 dnl Allow specific bindings to be specified for building (or not)
 848 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 849     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 850     enableval=default)
 851 BINDINGS_TO_BUILD=""
 852 case "$enableval" in
 853   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 854   all ) BINDINGS_TO_BUILD="ocaml" ;;
 855   none | no) BINDINGS_TO_BUILD="" ;;
 856   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 857       case "$a_binding" in
 858         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 859         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 860       esac
 861   done
 862   ;;
 863 esac
 864
 865 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 866 dnl script for bindings/ocaml/configure, except that its auto value depends on
 867 dnl OCAMLC, which is found here to support tests.
 868 AC_ARG_WITH([ocaml-libdir],
 869   [AS_HELP_STRING([--with-ocaml-libdir],
 870     [Specify install location for ocaml bindings (default is stdlib)])],
 871   [],
 872   [withval=auto])
 873 case "$withval" in
 874   auto) with_ocaml_libdir="$withval" ;;
 875   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 876   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 877 esac
 878
 879 AC_ARG_WITH(clang-resource-dir,
 880   AS_HELP_STRING([--with-clang-resource-dir],
 881     [Relative directory from the Clang binary for resource files]),,
 882     withval="")
 883 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 884                    [Relative directory for resource files])
 885
 886 AC_ARG_WITH(c-include-dirs,
 887   AS_HELP_STRING([--with-c-include-dirs],
 888     [Colon separated list of directories clang will search for headers]),,
 889     withval="")
 890 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 891                    [Directories clang will search for headers])
 892
 893 AC_ARG_WITH(cxx-include-root,
 894   AS_HELP_STRING([--with-cxx-include-root],
 895     [Directory with the libstdc++ headers.]),,
 896     withval="")
 897 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 898                    [Directory with the libstdc++ headers.])
 899
 900 AC_ARG_WITH(cxx-include-arch,
 901   AS_HELP_STRING([--with-cxx-include-arch],
 902     [Architecture of the libstdc++ headers.]),,
 903     withval="")
 904 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 905                    [Arch the libstdc++ headers.])
 906
 907 AC_ARG_WITH(cxx-include-32bit-dir,
 908   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 909     [32 bit multilib dir.]),,
 910     withval="")
 911 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 912                    [32 bit multilib directory.])
 913
 914 AC_ARG_WITH(cxx-include-64bit-dir,
 915   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 916     [64 bit multilib directory.]),,
 917     withval="")
 918 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 919                    [64 bit multilib directory.])
 920
 921 dnl Allow linking of LLVM with GPLv3 binutils code.
 922 AC_ARG_WITH(binutils-include,
 923   AS_HELP_STRING([--with-binutils-include],
 924     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 925   withval=default)
 926 case "$withval" in
 927   default) WITH_BINUTILS_INCDIR=default ;;
 928   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 929   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 930 esac
 931 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 932   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 933   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 934      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 935      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 936   fi
 937 fi
 938
 939 dnl --enable-libffi : check whether the user wants to turn off libffi:
 940 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 941   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 942   [case "$enableval" in
 943     yes) llvm_cv_enable_libffi="yes" ;;
 944     no)  llvm_cv_enable_libffi="no"  ;;
 945     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 946   esac],
 947   llvm_cv_enable_libffi=no)
 948
 949 dnl===-----------------------------------------------------------------------===
 950 dnl===
 951 dnl=== SECTION 4: Check for programs we need and that they are the right version
 952 dnl===
 953 dnl===-----------------------------------------------------------------------===
 954
 955 dnl Check for compilation tools
 956 AC_PROG_CPP
 957 AC_PROG_CC(gcc)
 958 AC_PROG_CXX(g++)
 959
 960 AC_PROG_NM
 961 AC_SUBST(NM)
 962
 963 dnl Check for the tools that the makefiles require
 964 AC_CHECK_GNU_MAKE
 965 AC_PROG_LN_S
 966 AC_PATH_PROG(CMP, [cmp], [cmp])
 967 AC_PATH_PROG(CP, [cp], [cp])
 968 AC_PATH_PROG(DATE, [date], [date])
 969 AC_PATH_PROG(FIND, [find], [find])
 970 AC_PATH_PROG(GREP, [grep], [grep])
 971 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 972 AC_PATH_PROG(MV,   [mv],   [mv])
 973 AC_PROG_RANLIB
 974 AC_CHECK_TOOL(AR, ar, false)
 975 AC_PATH_PROG(RM,   [rm],   [rm])
 976 AC_PATH_PROG(SED,  [sed],  [sed])
 977 AC_PATH_PROG(TAR,  [tar],  [gtar])
 978 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 979
 980 dnl Looking for misc. graph plotting software
 981 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 982 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 983   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 984   dnl If we're targeting for mingw we should emit windows paths, not msys
 985   if test "$llvm_cv_os_type" = "MingW" ; then
 986     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 987   fi
 988   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 989    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 990 fi
 991 AC_PATH_PROG(DOT, [dot], [echo dot])
 992 if test "$DOT" != "echo dot" ; then
 993   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 994   dnl If we're targeting for mingw we should emit windows paths, not msys
 995   if test "$llvm_cv_os_type" = "MingW" ; then
 996     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 997   fi
 998   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 999    [Define to path to dot program if found or 'echo dot' otherwise])
1000 fi
1001 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1002 if test "$FDP" != "echo fdp" ; then
1003   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1004   dnl If we're targeting for mingw we should emit windows paths, not msys
1005   if test "$llvm_cv_os_type" = "MingW" ; then
1006     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1007   fi
1008   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1009    [Define to path to fdp program if found or 'echo fdp' otherwise])
1010 fi
1011 AC_PATH_PROG(NEATO, [neato], [echo neato])
1012 if test "$NEATO" != "echo neato" ; then
1013   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1014   dnl If we're targeting for mingw we should emit windows paths, not msys
1015   if test "$llvm_cv_os_type" = "MingW" ; then
1016     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1017   fi
1018   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1019    [Define to path to neato program if found or 'echo neato' otherwise])
1020 fi
1021 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1022 if test "$TWOPI" != "echo twopi" ; then
1023   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1024   dnl If we're targeting for mingw we should emit windows paths, not msys
1025   if test "$llvm_cv_os_type" = "MingW" ; then
1026     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1027   fi
1028   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1029    [Define to path to twopi program if found or 'echo twopi' otherwise])
1030 fi
1031 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1032 if test "$CIRCO" != "echo circo" ; then
1033   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1034   dnl If we're targeting for mingw we should emit windows paths, not msys
1035   if test "$llvm_cv_os_type" = "MingW" ; then
1036     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1037   fi
1038   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1039    [Define to path to circo program if found or 'echo circo' otherwise])
1040 fi
1041 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1042 if test "$GV" != "echo gv" ; then
1043   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1044   dnl If we're targeting for mingw we should emit windows paths, not msys
1045   if test "$llvm_cv_os_type" = "MingW" ; then
1046     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1047   fi
1048   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1049    [Define to path to gv program if found or 'echo gv' otherwise])
1050 fi
1051 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1052 if test "$DOTTY" != "echo dotty" ; then
1053   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1054   dnl If we're targeting for mingw we should emit windows paths, not msys
1055   if test "$llvm_cv_os_type" = "MingW" ; then
1056     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1057   fi
1058   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1059    [Define to path to dotty program if found or 'echo dotty' otherwise])
1060 fi
1061 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1062 if test "$XDOT_PY" != "echo xdot.py" ; then
1063   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1064   dnl If we're targeting for mingw we should emit windows paths, not msys
1065   if test "$llvm_cv_os_type" = "MingW" ; then
1066     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1067   fi
1068   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1069    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1070 fi
1071
1072 dnl Look for a sufficiently recent version of Perl.
1073 LLVM_PROG_PERL([5.006])
1074 AC_SUBST(PERL)
1075 if test x"$PERL" = xnone; then
1076    AC_SUBST(HAVE_PERL,0)
1077    AC_MSG_ERROR([perl is required but was not found, please install it])
1078 else
1079    AC_SUBST(HAVE_PERL,1)
1080 fi
1081
1082 dnl Find the install program
1083 AC_PROG_INSTALL
1084 dnl Prepend src dir to install path dir if it's a relative path
1085 dnl This is a hack for installs that take place in something other
1086 dnl than the top level.
1087 case "$INSTALL" in
1088  [[\\/$]]* | ?:[[\\/]]* ) ;;
1089  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1090 esac
1091
1092 dnl Checks for documentation and testing tools that we can do without. If these
1093 dnl are not found then they are set to "true" which always succeeds but does
1094 dnl nothing. This just lets the build output show that we could have done
1095 dnl something if the tool was available.
1096 AC_PATH_PROG(BZIP2, [bzip2])
1097 AC_PATH_PROG(CAT, [cat])
1098 AC_PATH_PROG(DOXYGEN, [doxygen])
1099 AC_PATH_PROG(GROFF, [groff])
1100 AC_PATH_PROG(GZIPBIN, [gzip])
1101 AC_PATH_PROG(POD2HTML, [pod2html])
1102 AC_PATH_PROG(POD2MAN, [pod2man])
1103 AC_PATH_PROG(PDFROFF, [pdfroff])
1104 AC_PATH_PROG(RUNTEST, [runtest])
1105 DJ_AC_PATH_TCLSH
1106 AC_PATH_PROG(ZIP, [zip])
1107 AC_PATH_PROGS(OCAMLC, [ocamlc])
1108 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1109 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1110 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1111 AC_PATH_PROGS(GAS, [gas as])
1112
1113 dnl Get the version of the linker in use.
1114 AC_LINK_GET_VERSION
1115
1116 dnl Determine whether the linker supports the -R option.
1117 AC_LINK_USE_R
1118
1119 dnl Determine whether the linker supports the -export-dynamic option.
1120 AC_LINK_EXPORT_DYNAMIC
1121
1122 dnl Determine whether the linker supports the --version-script option.
1123 AC_LINK_VERSION_SCRIPT
1124
1125 dnl Check for libtool and the library that has dlopen function (which must come
1126 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1127 dnl libtool).
1128 AC_LIBTOOL_DLOPEN
1129 AC_LIB_LTDL
1130
1131 if test "$WITH_LLVMGCCDIR" = "default" ; then
1132   LLVMGCC="llvm-gcc${EXEEXT}"
1133   LLVMGXX="llvm-g++${EXEEXT}"
1134   LLVMGCCCOMMAND="$LLVMGCC"
1135   LLVMGXXCOMMAND="$LLVMGXX"
1136   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1137   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1138   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
1139   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
1140 else
1141   if test -z "$LLVMGCC"; then
1142     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
1143     LLVMGCCCOMMAND="$LLVMGCC"
1144   fi
1145   if test -z "$LLVMGXX"; then
1146     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1147     LLVMGXXCOMMAND="$LLVMGXX"
1148   fi
1149
1150   AC_SUBST(LLVMGCC,$LLVMGCC)
1151   AC_SUBST(LLVMGXX,$LLVMGXX)
1152   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1153   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1154 fi
1155
1156 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1157 dnl found, otherwise clang if available.
1158 AC_ARG_WITH(llvmcc,
1159   AS_HELP_STRING([--with-llvmcc=<name>],
1160     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1161     [],[with_llvmcc=check])
1162 AC_MSG_CHECKING([LLVM capable compiler])
1163 if test "$with_llvmcc" != "check"; then
1164    if (test "$with_llvmcc" != "llvm-gcc" &&
1165        test "$with_llvmcc" != "clang" &&
1166        test "$with_llvmcc" != "none"); then
1167       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1168    fi
1169    WITH_LLVMCC="$with_llvmcc"
1170 elif test -n "$LLVMGCC"; then
1171    WITH_LLVMCC=llvm-gcc
1172 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1173    WITH_LLVMCC=clang
1174 else
1175    WITH_LLVMCC=none
1176 fi
1177 AC_MSG_RESULT([$WITH_LLVMCC])
1178 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1179
1180 AC_MSG_CHECKING([tool compatibility])
1181
1182 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1183 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1184 dnl to support those options.
1185 dnl "icc" emits gcc signatures
1186 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1187 ICC=no
1188 IXX=no
1189 case $CC in
1190   icc*|icpc*)
1191     ICC=yes
1192     IXX=yes
1193     ;;
1194    *)
1195     ;;
1196 esac
1197
1198 if test "$GCC" != "yes" && test "$ICC" != "yes"
1199 then
1200   AC_MSG_ERROR([gcc|icc required but not found])
1201 fi
1202
1203 dnl Ensure that compilation tools are compatible with GCC extensions
1204 if test "$GXX" != "yes" && test "$IXX" != "yes"
1205 then
1206   AC_MSG_ERROR([g++|clang++|icc required but not found])
1207 fi
1208
1209 dnl Verify that GCC is version 3.0 or higher
1210 if test "$GCC" = "yes"
1211 then
1212   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1213 #error Unsupported GCC version
1214 #endif
1215 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1216 fi
1217
1218 dnl Check for GNU Make.  We use its extensions, so don't build without it
1219 if test -z "$llvm_cv_gnu_make_command"
1220 then
1221   AC_MSG_ERROR([GNU Make required but not found])
1222 fi
1223
1224 dnl Tool compatibility is okay if we make it here.
1225 AC_MSG_RESULT([ok])
1226
1227 dnl Check optional compiler flags.
1228 AC_MSG_CHECKING([optional compiler flags])
1229 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1230 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1231 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1232
1233 dnl===-----------------------------------------------------------------------===
1234 dnl===
1235 dnl=== SECTION 5: Check for libraries
1236 dnl===
1237 dnl===-----------------------------------------------------------------------===
1238
1239 AC_CHECK_LIB(m,sin)
1240 if test "$llvm_cv_os_type" = "MingW" ; then
1241   AC_CHECK_LIB(imagehlp, main)
1242   AC_CHECK_LIB(psapi, main)
1243 fi
1244
1245 dnl dlopen() is required for plugin support.
1246 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1247                [Define if dlopen() is available on this platform.]),
1248                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1249
1250 dnl libffi is optional; used to call external functions from the interpreter
1251 if test "$llvm_cv_enable_libffi" = "yes" ; then
1252   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1253                  [Define if libffi is available on this platform.]),
1254                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1255 fi
1256
1257 dnl mallinfo is optional; the code can compile (minus features) without it
1258 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1259                [Define if mallinfo() is available on this platform.]))
1260
1261 dnl pthread locking functions are optional - but llvm will not be thread-safe
1262 dnl without locks.
1263 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1264   AC_CHECK_LIB(pthread, pthread_mutex_init)
1265   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1266                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1267                            [Have pthread_mutex_lock]))
1268   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1269                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1270                  [Have pthread_rwlock_init]))
1271   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1272                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1273                  [Have pthread_getspecific]))
1274 fi
1275
1276 dnl Allow extra x86-disassembler library
1277 AC_ARG_WITH(udis86,
1278   AS_HELP_STRING([--with-udis86=<path>],
1279     [Use udis86 external x86 disassembler library]),
1280     [
1281       AC_SUBST(USE_UDIS86, [1])
1282       case "$withval" in
1283         /usr/lib|yes) ;;
1284         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1285       esac
1286       AC_CHECK_LIB(udis86, ud_init, [], [
1287         echo "Error! You need to have libudis86 around."
1288         exit -1
1289       ])
1290     ],
1291     AC_SUBST(USE_UDIS86, [0]))
1292 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1293                    [Define if use udis86 library])
1294
1295 dnl Allow OProfile support for JIT output.
1296 AC_ARG_WITH(oprofile,
1297   AS_HELP_STRING([--with-oprofile=<prefix>],
1298     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1299     [
1300       AC_SUBST(USE_OPROFILE, [1])
1301       case "$withval" in
1302         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1303         no) llvm_cv_oppath=
1304             AC_SUBST(USE_OPROFILE, [0]) ;;
1305         *) llvm_cv_oppath="${withval}/lib/oprofile"
1306            CPPFLAGS="-I${withval}/include";;
1307       esac
1308       if test -n "$llvm_cv_oppath" ; then
1309         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1310         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1311         dnl libbfd is not included properly in libopagent in some Debian
1312         dnl versions.  If libbfd isn't found at all, we assume opagent works
1313         dnl anyway.
1314         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1315         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1316           echo "Error! You need to have libopagent around."
1317           exit -1
1318         ])
1319         AC_CHECK_HEADER([opagent.h], [], [
1320           echo "Error! You need to have opagent.h around."
1321           exit -1
1322           ])
1323       fi
1324     ],
1325     [
1326       AC_SUBST(USE_OPROFILE, [0])
1327     ])
1328 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1329                    [Define if we have the oprofile JIT-support library])
1330
1331 dnl===-----------------------------------------------------------------------===
1332 dnl===
1333 dnl=== SECTION 6: Check for header files
1334 dnl===
1335 dnl===-----------------------------------------------------------------------===
1336
1337 dnl First, use autoconf provided macros for specific headers that we need
1338 dnl We don't check for ancient stuff or things that are guaranteed to be there
1339 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1340 dnl Generally we're looking for POSIX headers.
1341 AC_HEADER_DIRENT
1342 AC_HEADER_MMAP_ANONYMOUS
1343 AC_HEADER_STAT
1344 AC_HEADER_STDC
1345 AC_HEADER_SYS_WAIT
1346 AC_HEADER_TIME
1347
1348 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1349 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1350 AC_CHECK_HEADERS([utime.h windows.h])
1351 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1352 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1353 AC_CHECK_HEADERS([valgrind/valgrind.h])
1354 AC_CHECK_HEADERS([fenv.h])
1355 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1356   AC_CHECK_HEADERS(pthread.h,
1357                    AC_SUBST(HAVE_PTHREAD, 1),
1358                    AC_SUBST(HAVE_PTHREAD, 0))
1359 else
1360   AC_SUBST(HAVE_PTHREAD, 0)
1361 fi
1362
1363 dnl Try to find ffi.h.
1364 if test "$llvm_cv_enable_libffi" = "yes" ; then
1365   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1366 fi
1367
1368 dnl Try to find Darwin specific crash reporting libraries.
1369 AC_CHECK_HEADERS([CrashReporterClient.h])
1370
1371 dnl Try to find Darwin specific crash reporting global.
1372 AC_MSG_CHECKING([__crashreporter_info__])
1373 AC_LINK_IFELSE(
1374   AC_LANG_SOURCE(
1375     [[extern const char *__crashreporter_info__;
1376       int main() {
1377         __crashreporter_info__ = "test";
1378         return 0;
1379       }
1380     ]]),
1381   AC_MSG_RESULT(yes)
1382   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1383   AC_MSG_RESULT(no)
1384   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1385             Define if __crashreporter_info__ exists.))
1386
1387 dnl===-----------------------------------------------------------------------===
1388 dnl===
1389 dnl=== SECTION 7: Check for types and structures
1390 dnl===
1391 dnl===-----------------------------------------------------------------------===
1392
1393 AC_HUGE_VAL_CHECK
1394 AC_TYPE_PID_T
1395 AC_TYPE_SIZE_T
1396 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1397 AC_STRUCT_TM
1398 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1399 AC_CHECK_TYPES([uint64_t],,
1400          AC_CHECK_TYPES([u_int64_t],,
1401          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1402
1403 dnl===-----------------------------------------------------------------------===
1404 dnl===
1405 dnl=== SECTION 8: Check for specific functions needed
1406 dnl===
1407 dnl===-----------------------------------------------------------------------===
1408
1409 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1410 AC_CHECK_FUNCS([powf fmodf strtof round ])
1411 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1412 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1413 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1414 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1415 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1416 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1417 AC_C_PRINTF_A
1418 AC_FUNC_RAND48
1419
1420 dnl Check the declaration "Secure API" on Windows environments.
1421 AC_CHECK_DECLS([strerror_s])
1422
1423 dnl Check symbols in libgcc.a for JIT on Mingw.
1424 if test "$llvm_cv_os_type" = "MingW" ; then
1425   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1426   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1427   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1428   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1429
1430   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1431   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1432   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1433   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1434   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1435   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1436   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1437   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1438   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1439   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1440
1441   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1442   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1443 fi
1444
1445 dnl Check Win32 API EnumerateLoadedModules.
1446 if test "$llvm_cv_os_type" = "MingW" ; then
1447   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1448   AC_COMPILE_IFELSE([[#include <windows.h>
1449 #include <imagehlp.h>
1450 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1451 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1452 [
1453   AC_MSG_RESULT([yes])
1454   llvm_cv_win32_elmcb_pcstr="PCSTR"
1455 ],
1456 [
1457   AC_MSG_RESULT([no])
1458   llvm_cv_win32_elmcb_pcstr="PSTR"
1459 ])
1460   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1461 fi
1462
1463 dnl Check for variations in the Standard C++ library and STL. These macros are
1464 dnl provided by LLVM in the autoconf/m4 directory.
1465 AC_FUNC_ISNAN
1466 AC_FUNC_ISINF
1467
1468 dnl Check for mmap support.We also need to know if /dev/zero is required to
1469 dnl be opened for allocating RWX memory.
1470 dnl Make sure we aren't attempting to configure for an unknown system
1471 if test "$llvm_cv_platform_type" = "Unix" ; then
1472   AC_FUNC_MMAP
1473   AC_FUNC_MMAP_FILE
1474   AC_NEED_DEV_ZERO_FOR_MMAP
1475
1476   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1477   then
1478     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1479   fi
1480   if test "$ac_cv_func_mmap_file" = "no"
1481   then
1482     AC_MSG_WARN([mmap() of files required but not found])
1483   fi
1484 fi
1485
1486 dnl atomic builtins are required for threading support.
1487 AC_MSG_CHECKING(for GCC atomic builtins)
1488 dnl Since we'll be using these atomic builtins in C++ files we should test
1489 dnl the C++ compiler.
1490 AC_LANG_PUSH([C++])
1491 AC_LINK_IFELSE(
1492   AC_LANG_SOURCE(
1493     [[int main() {
1494         volatile unsigned long val = 1;
1495         __sync_synchronize();
1496         __sync_val_compare_and_swap(&val, 1, 0);
1497         __sync_add_and_fetch(&val, 1);
1498         __sync_sub_and_fetch(&val, 1);
1499         return 0;
1500       }
1501     ]]),
1502   AC_LANG_POP([C++])
1503   AC_MSG_RESULT(yes)
1504   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1505   AC_MSG_RESULT(no)
1506   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1507   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1508
1509 dnl===-----------------------------------------------------------------------===
1510 dnl===
1511 dnl=== SECTION 9: Additional checks, variables, etc.
1512 dnl===
1513 dnl===-----------------------------------------------------------------------===
1514
1515 dnl Handle 32-bit linux systems running a 64-bit kernel.
1516 dnl This has to come after section 4 because it invokes the compiler.
1517 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1518   AC_IS_LINUX_MIXED
1519   if test "$llvm_cv_linux_mixed" = "yes"; then
1520     llvm_cv_target_arch="x86"
1521     ARCH="x86"
1522   fi
1523 fi
1524
1525 dnl Check, whether __dso_handle is present
1526 AC_CHECK_FUNCS([__dso_handle])
1527
1528 dnl Check wether llvm-gcc is based on dragonegg
1529 AC_CACHE_CHECK([whether llvm-gcc is dragonegg],[llvm_cv_llvmgcc_dragonegg],
1530 [llvm_cv_llvmgcc_dragonegg="no"
1531 if test -n "$LLVMGCC" ; then
1532   cp /dev/null conftest.c
1533   $LLVMGCC -fplugin-arg-dragonegg-emit-ir -S -o - conftest.c > /dev/null 2>&1
1534   if test $? -eq 0 ; then
1535     llvm_cv_llvmgcc_dragonegg="yes"
1536   fi
1537   rm conftest.c
1538 fi])
1539
1540 dnl Set the flags needed to emit LLVM IR and to disable optimizations
1541 dnl in llvmgcc
1542 if test "$llvm_cv_llvmgcc_dragonegg" = "yes" ; then
1543   LLVMCC_EMITIR_FLAG="-fplugin-arg-dragonegg-emit-ir"
1544   LLVMCC_DISABLEOPT_FLAGS="-fplugin-arg-dragonegg-llvm-ir-optimize=0"
1545 else
1546   LLVMCC_EMITIR_FLAG="-emit-llvm"
1547   LLVMCC_DISABLEOPT_FLAGS="-mllvm -disable-llvm-optzns"
1548 fi
1549
1550 AC_SUBST(LLVMCC_EMITIR_FLAG)
1551
1552 dnl See if the llvm-gcc executable can compile to LLVM assembly
1553 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1554 [llvm_cv_llvmgcc_sanity="no"
1555 if test -n "$LLVMGCC" ; then
1556   cp /dev/null conftest.c
1557   $LLVMGCC "$LLVMCC_EMITIR_FLAG" -S -o - conftest.c | \
1558       grep 'target datalayout =' > /dev/null 2>&1
1559   if test $? -eq 0 ; then
1560     llvm_cv_llvmgcc_sanity="yes"
1561   fi
1562   rm conftest.c
1563 fi])
1564
1565 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1566 dnl Furthermore, add some information about the tools
1567 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1568   AC_MSG_CHECKING([llvm-gcc component support])
1569   llvmcc1path=`$LLVMGCC --print-prog-name=cc1`
1570   AC_SUBST(LLVMCC1,$llvmcc1path)
1571   llvmcc1pluspath=`$LLVMGCC --print-prog-name=cc1plus`
1572   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1573   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1574   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1575   llvmgcclangs=[`$LLVMGCC -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1576   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1577   AC_SUBST(LLVMGCC_DRAGONEGG,$llvm_cv_llvmgcc_dragonegg)
1578   AC_SUBST(LLVMCC_DISABLEOPT_FLAGS)
1579   AC_MSG_RESULT([ok])
1580 fi
1581
1582 dnl Propagate the shared library extension that the libltdl checks did to
1583 dnl the Makefiles so we can use it there too
1584 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1585
1586 dnl Propagate the run-time library path variable that the libltdl
1587 dnl checks found to the Makefiles so we can use it there too
1588 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1589
1590 # Translate the various configuration directories and other basic
1591 # information into substitutions that will end up in Makefile.config.in
1592 # that these configured values can be used by the makefiles
1593 if test "${prefix}" = "NONE" ; then
1594   prefix="/usr/local"
1595 fi
1596 eval LLVM_PREFIX="${prefix}";
1597 eval LLVM_BINDIR="${prefix}/bin";
1598 eval LLVM_LIBDIR="${prefix}/lib";
1599 eval LLVM_DATADIR="${prefix}/share/llvm";
1600 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1601 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1602 eval LLVM_INCLUDEDIR="${prefix}/include";
1603 eval LLVM_INFODIR="${prefix}/info";
1604 eval LLVM_MANDIR="${prefix}/man";
1605 LLVM_CONFIGTIME=`date`
1606 AC_SUBST(LLVM_PREFIX)
1607 AC_SUBST(LLVM_BINDIR)
1608 AC_SUBST(LLVM_LIBDIR)
1609 AC_SUBST(LLVM_DATADIR)
1610 AC_SUBST(LLVM_DOCSDIR)
1611 AC_SUBST(LLVM_ETCDIR)
1612 AC_SUBST(LLVM_INCLUDEDIR)
1613 AC_SUBST(LLVM_INFODIR)
1614 AC_SUBST(LLVM_MANDIR)
1615 AC_SUBST(LLVM_CONFIGTIME)
1616
1617 # Place the various directores into the config.h file as #defines so that we
1618 # can know about the installation paths within LLVM.
1619 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1620                    [Installation prefix directory])
1621 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1622                    [Installation directory for binary executables])
1623 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1624                    [Installation directory for libraries])
1625 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1626                    [Installation directory for data files])
1627 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1628                    [Installation directory for documentation])
1629 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1630                    [Installation directory for config files])
1631 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1632                    [Installation directory for include files])
1633 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1634                    [Installation directory for .info files])
1635 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1636                    [Installation directory for man pages])
1637 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1638                    [Time at which LLVM was configured])
1639 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1640                    [Host triple we were built on])
1641
1642 # Determine which bindings to build.
1643 if test "$BINDINGS_TO_BUILD" = auto ; then
1644   BINDINGS_TO_BUILD=""
1645   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1646     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1647   fi
1648 fi
1649 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1650
1651 # This isn't really configurey, but it avoids having to repeat the list in
1652 # other files.
1653 AC_SUBST(ALL_BINDINGS,ocaml)
1654
1655 # Do any work necessary to ensure that bindings have what they need.
1656 binding_prereqs_failed=0
1657 for a_binding in $BINDINGS_TO_BUILD ; do
1658   case "$a_binding" in
1659   ocaml)
1660     if test "x$OCAMLC" = x ; then
1661       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1662       binding_prereqs_failed=1
1663     fi
1664     if test "x$OCAMLDEP" = x ; then
1665       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1666       binding_prereqs_failed=1
1667     fi
1668     if test "x$OCAMLOPT" = x ; then
1669       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1670       dnl ocamlopt is optional!
1671     fi
1672     if test "x$with_ocaml_libdir" != xauto ; then
1673       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1674     else
1675       ocaml_stdlib="`"$OCAMLC" -where`"
1676       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1677       then
1678         # ocaml stdlib is beneath our prefix; use stdlib
1679         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1680       else
1681         # ocaml stdlib is outside our prefix; use libdir/ocaml
1682         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1683       fi
1684     fi
1685     ;;
1686   esac
1687 done
1688 if test "$binding_prereqs_failed" = 1 ; then
1689   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1690 fi
1691
1692 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1693 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1694
1695 dnl Determine linker rpath flag
1696 if test "$llvm_cv_link_use_r" = "yes" ; then
1697   RPATH="-Wl,-R"
1698 else
1699   RPATH="-Wl,-rpath"
1700 fi
1701 AC_SUBST(RPATH)
1702
1703 dnl Determine linker rdynamic flag
1704 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1705   RDYNAMIC="-Wl,-export-dynamic"
1706 else
1707   RDYNAMIC=""
1708 fi
1709 AC_SUBST(RDYNAMIC)
1710
1711 dnl===-----------------------------------------------------------------------===
1712 dnl===
1713 dnl=== SECTION 10: Specify the output files and generate it
1714 dnl===
1715 dnl===-----------------------------------------------------------------------===
1716
1717 dnl Configure header files
1718 dnl WARNING: dnl If you add or remove any of the following config headers, then
1719 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1720 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1721 dnl files can be updated automatically when their *.in sources change.
1722 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1723 AH_TOP([#ifndef CONFIG_H
1724 #define CONFIG_H])
1725 AH_BOTTOM([#endif])
1726
1727 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1728 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1729 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1730 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1731 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1732
1733 dnl Configure the makefile's configuration data
1734 AC_CONFIG_FILES([Makefile.config])
1735
1736 dnl Configure the RPM spec file for LLVM
1737 AC_CONFIG_FILES([llvm.spec])
1738
1739 dnl Configure doxygen's configuration file
1740 AC_CONFIG_FILES([docs/doxygen.cfg])
1741 if test -f ${srcdir}/tools/clang/README.txt; then
1742   AC_CONFIG_FILES([tools/clang/docs/doxygen.cfg])
1743 fi
1744
1745 dnl Configure llvmc's Base plugin
1746 AC_CONFIG_FILES([tools/llvmc/src/Base.td])
1747
1748 dnl Do the first stage of configuration for llvm-config.in.
1749 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1750
1751 dnl Do special configuration of Makefiles
1752 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1753 AC_CONFIG_MAKEFILE(Makefile)
1754 AC_CONFIG_MAKEFILE(Makefile.common)
1755 AC_CONFIG_MAKEFILE(examples/Makefile)
1756 AC_CONFIG_MAKEFILE(lib/Makefile)
1757 AC_CONFIG_MAKEFILE(runtime/Makefile)
1758 AC_CONFIG_MAKEFILE(test/Makefile)
1759 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1760 AC_CONFIG_MAKEFILE(unittests/Makefile)
1761 AC_CONFIG_MAKEFILE(tools/Makefile)
1762 AC_CONFIG_MAKEFILE(utils/Makefile)
1763 AC_CONFIG_MAKEFILE(projects/Makefile)
1764 AC_CONFIG_MAKEFILE(bindings/Makefile)
1765 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1766
1767 dnl Finally, crank out the output
1768 AC_OUTPUT