autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.9svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65
  66 dnl
  67 dnl One tricky part of doing this is that some projects depend upon other
  68 dnl projects.  For example, several projects rely upon the LLVM test suite.
  69 dnl We want to configure those projects first so that their object trees are
  70 dnl created before running the configure scripts of projects that depend upon
  71 dnl them.
  72 dnl
  73
  74 dnl Several projects use llvm-gcc, so configure that first
  75 if test -d ${srcdir}/projects/llvm-gcc ; then
  76   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  77 fi
  78
  79 dnl Several projects use the LLVM test suite, so configure it next.
  80 if test -d ${srcdir}/projects/test-suite ; then
  81   AC_CONFIG_SUBDIRS([projects/test-suite])
  82 fi
  83
  84 dnl llvm-test is the old name of the test-suite, kept here for backwards
  85 dnl compatibility
  86 if test -d ${srcdir}/projects/llvm-test ; then
  87   AC_CONFIG_SUBDIRS([projects/llvm-test])
  88 fi
  89
  90 dnl Some projects use poolalloc; configure that next
  91 if test -d ${srcdir}/projects/poolalloc ; then
  92   AC_CONFIG_SUBDIRS([projects/poolalloc])
  93 fi
  94
  95 if test -d ${srcdir}/projects/llvm-poolalloc ; then
  96   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
  97 fi
  98
  99 dnl Check for all other projects
 100 for i in `ls ${srcdir}/projects`
 101 do
 102   if test -d ${srcdir}/projects/${i} ; then
 103     case ${i} in
 104       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 105       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 106       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 107       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 108       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 109       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 110       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 111       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 112       llvm-gcc)       ;;
 113       test-suite)     ;;
 114       llvm-test)      ;;
 115       poolalloc)      ;;
 116       llvm-poolalloc) ;;
 117       *)
 118         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 119         ;;
 120     esac
 121   fi
 122 done
 123
 124 dnl===-----------------------------------------------------------------------===
 125 dnl===
 126 dnl=== SECTION 2: Architecture, target, and host checks
 127 dnl===
 128 dnl===-----------------------------------------------------------------------===
 129
 130 dnl Check the target for which we're compiling and the host that will do the
 131 dnl compilations. This will tell us which LLVM compiler will be used for
 132 dnl compiling SSA into object code. This needs to be done early because
 133 dnl following tests depend on it.
 134 AC_CANONICAL_TARGET
 135
 136 dnl Determine the platform type and cache its value. This helps us configure
 137 dnl the System library to the correct build platform.
 138 AC_CACHE_CHECK([type of operating system we're going to host on],
 139                [llvm_cv_os_type],
 140 [case $host in
 141   *-*-aix*)
 142     llvm_cv_link_all_option="-Wl,--whole-archive"
 143     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 144     llvm_cv_os_type="AIX"
 145     llvm_cv_platform_type="Unix" ;;
 146   *-*-irix*)
 147     llvm_cv_link_all_option="-Wl,--whole-archive"
 148     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 149     llvm_cv_os_type="IRIX"
 150     llvm_cv_platform_type="Unix" ;;
 151   *-*-cygwin*)
 152     llvm_cv_link_all_option="-Wl,--whole-archive"
 153     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 154     llvm_cv_os_type="Cygwin"
 155     llvm_cv_platform_type="Unix" ;;
 156   *-*-darwin*)
 157     llvm_cv_link_all_option="-Wl,-all_load"
 158     llvm_cv_no_link_all_option="-Wl,-noall_load"
 159     llvm_cv_os_type="Darwin"
 160     llvm_cv_platform_type="Unix" ;;
 161   *-*-minix*)
 162     llvm_cv_link_all_option="-Wl,-all_load"
 163     llvm_cv_no_link_all_option="-Wl,-noall_load"
 164     llvm_cv_os_type="Minix"
 165     llvm_cv_platform_type="Unix" ;;
 166   *-*-freebsd*)
 167     llvm_cv_link_all_option="-Wl,--whole-archive"
 168     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 169     llvm_cv_os_type="FreeBSD"
 170     llvm_cv_platform_type="Unix" ;;
 171   *-*-openbsd*)
 172     llvm_cv_link_all_option="-Wl,--whole-archive"
 173     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 174     llvm_cv_os_type="OpenBSD"
 175     llvm_cv_platform_type="Unix" ;;
 176   *-*-netbsd*)
 177     llvm_cv_link_all_option="-Wl,--whole-archive"
 178     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 179     llvm_cv_os_type="NetBSD"
 180     llvm_cv_platform_type="Unix" ;;
 181   *-*-dragonfly*)
 182     llvm_cv_link_all_option="-Wl,--whole-archive"
 183     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 184     llvm_cv_os_type="DragonFly"
 185     llvm_cv_platform_type="Unix" ;;
 186   *-*-hpux*)
 187     llvm_cv_link_all_option="-Wl,--whole-archive"
 188     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 189     llvm_cv_os_type="HP-UX"
 190     llvm_cv_platform_type="Unix" ;;
 191   *-*-interix*)
 192     llvm_cv_link_all_option="-Wl,--whole-archive"
 193     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 194     llvm_cv_os_type="Interix"
 195     llvm_cv_platform_type="Unix" ;;
 196   *-*-linux*)
 197     llvm_cv_link_all_option="-Wl,--whole-archive"
 198     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 199     llvm_cv_os_type="Linux"
 200     llvm_cv_platform_type="Unix" ;;
 201   *-*-solaris*)
 202     llvm_cv_link_all_option="-Wl,-z,allextract"
 203     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 204     llvm_cv_os_type="SunOS"
 205     llvm_cv_platform_type="Unix" ;;
 206   *-*-auroraux*)
 207     llvm_cv_link_all_option="-Wl,-z,allextract"
 208     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 209     llvm_cv_os_type="AuroraUX"
 210     llvm_cv_platform_type="Unix" ;;
 211   *-*-win32*)
 212     llvm_cv_link_all_option="-Wl,--whole-archive"
 213     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 214     llvm_cv_os_type="Win32"
 215     llvm_cv_platform_type="Win32" ;;
 216   *-*-mingw*)
 217     llvm_cv_link_all_option="-Wl,--whole-archive"
 218     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 219     llvm_cv_os_type="MingW"
 220     llvm_cv_platform_type="Win32" ;;
 221   *-*-haiku*)
 222     llvm_cv_link_all_option="-Wl,--whole-archive"
 223     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 224     llvm_cv_os_type="Haiku"
 225     llvm_cv_platform_type="Unix" ;;
 226   *-unknown-eabi*)
 227     llvm_cv_link_all_option="-Wl,--whole-archive"
 228     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 229     llvm_cv_os_type="Freestanding"
 230     llvm_cv_platform_type="Unix" ;;
 231   *-unknown-elf*)
 232     llvm_cv_link_all_option="-Wl,--whole-archive"
 233     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 234     llvm_cv_os_type="Freestanding"
 235     llvm_cv_platform_type="Unix" ;;
 236   *)
 237     llvm_cv_link_all_option=""
 238     llvm_cv_no_link_all_option=""
 239     llvm_cv_os_type="Unknown"
 240     llvm_cv_platform_type="Unknown" ;;
 241 esac])
 242
 243 AC_CACHE_CHECK([type of operating system we're going to target],
 244                [llvm_cv_target_os_type],
 245 [case $target in
 246   *-*-aix*)
 247     llvm_cv_target_os_type="AIX" ;;
 248   *-*-irix*)
 249     llvm_cv_target_os_type="IRIX" ;;
 250   *-*-cygwin*)
 251     llvm_cv_target_os_type="Cygwin" ;;
 252   *-*-darwin*)
 253     llvm_cv_target_os_type="Darwin" ;;
 254   *-*-minix*)
 255     llvm_cv_target_os_type="Minix" ;;
 256   *-*-freebsd*)
 257     llvm_cv_target_os_type="FreeBSD" ;;
 258   *-*-openbsd*)
 259     llvm_cv_target_os_type="OpenBSD" ;;
 260   *-*-netbsd*)
 261     llvm_cv_target_os_type="NetBSD" ;;
 262   *-*-dragonfly*)
 263     llvm_cv_target_os_type="DragonFly" ;;
 264   *-*-hpux*)
 265     llvm_cv_target_os_type="HP-UX" ;;
 266   *-*-interix*)
 267     llvm_cv_target_os_type="Interix" ;;
 268   *-*-linux*)
 269     llvm_cv_target_os_type="Linux" ;;
 270   *-*-solaris*)
 271     llvm_cv_target_os_type="SunOS" ;;
 272   *-*-auroraux*)
 273     llvm_cv_target_os_type="AuroraUX" ;;
 274   *-*-win32*)
 275     llvm_cv_target_os_type="Win32" ;;
 276   *-*-mingw*)
 277     llvm_cv_target_os_type="MingW" ;;
 278   *-*-haiku*)
 279     llvm_cv_target_os_type="Haiku" ;;
 280   *-unknown-eabi*)
 281     llvm_cv_target_os_type="Freestanding" ;;
 282   *)
 283     llvm_cv_target_os_type="Unknown" ;;
 284 esac])
 285
 286 dnl Make sure we aren't attempting to configure for an unknown system
 287 if test "$llvm_cv_os_type" = "Unknown" ; then
 288   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 289 fi
 290
 291 dnl Set the "OS" Makefile variable based on the platform type so the
 292 dnl makefile can configure itself to specific build hosts
 293 AC_SUBST(OS,$llvm_cv_os_type)
 294 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 295 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 296
 297 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 298 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 299 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 300
 301 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 302 dnl This is used by lib/System to determine the basic kind of implementation
 303 dnl to use.
 304 case $llvm_cv_platform_type in
 305   Unix)
 306     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 307     AC_SUBST(LLVM_ON_UNIX,[1])
 308     AC_SUBST(LLVM_ON_WIN32,[0])
 309     ;;
 310   Win32)
 311     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 312     AC_SUBST(LLVM_ON_UNIX,[0])
 313     AC_SUBST(LLVM_ON_WIN32,[1])
 314     ;;
 315 esac
 316
 317 dnl Determine what our target architecture is and configure accordingly.
 318 dnl This will allow Makefiles to make a distinction between the hardware and
 319 dnl the OS.
 320 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 321 [case $target in
 322   i?86-*)                 llvm_cv_target_arch="x86" ;;
 323   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 324   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 325   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 326   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 327   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 328   mips-*)                 llvm_cv_target_arch="Mips" ;;
 329   xcore-*)                llvm_cv_target_arch="XCore" ;;
 330   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 331   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 332   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 333   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 334   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 335   *)                      llvm_cv_target_arch="Unknown" ;;
 336 esac])
 337
 338 if test "$llvm_cv_target_arch" = "Unknown" ; then
 339   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 340 fi
 341
 342 # Determine the LLVM native architecture for the target
 343 case "$llvm_cv_target_arch" in
 344     x86)     LLVM_NATIVE_ARCH="X86" ;;
 345     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 346     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 347 esac
 348
 349 dnl Define a substitution, ARCH, for the target architecture
 350 AC_SUBST(ARCH,$llvm_cv_target_arch)
 351
 352 dnl Check for the endianness of the target
 353 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 354
 355 dnl Check for build platform executable suffix if we're crosscompiling
 356 if test "$cross_compiling" = yes; then
 357   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 358   AC_BUILD_EXEEXT
 359   ac_build_prefix=${build_alias}-
 360   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 361   if test -z "$BUILD_CXX"; then
 362      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 363      if test -z "$BUILD_CXX"; then
 364        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 365      fi
 366   fi
 367 else
 368   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 369 fi
 370
 371 dnl Check to see if there's a .svn or .git directory indicating that this
 372 dnl build is being done from a checkout. This sets up several defaults for
 373 dnl the command line switches. When we build with a checkout directory,
 374 dnl we get a debug with assertions turned on. Without, we assume a source
 375 dnl release and we get an optimized build without assertions.
 376 dnl See --enable-optimized and --enable-assertions below
 377 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 378   cvsbuild="yes"
 379   optimize="no"
 380   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 381 else
 382   cvsbuild="no"
 383   optimize="yes"
 384 fi
 385
 386 dnl===-----------------------------------------------------------------------===
 387 dnl===
 388 dnl=== SECTION 3: Command line arguments for the configure script.
 389 dnl===
 390 dnl===-----------------------------------------------------------------------===
 391
 392 dnl --enable-optimized : check whether they want to do an optimized build:
 393 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 394  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 395 if test ${enableval} = "no" ; then
 396   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 397 else
 398   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 399 fi
 400
 401 dnl --enable-profiling : check whether they want to do a profile build:
 402 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 403  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 404 if test ${enableval} = "no" ; then
 405   AC_SUBST(ENABLE_PROFILING,[[]])
 406 else
 407   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 408 fi
 409
 410 dnl --enable-assertions : check whether they want to turn on assertions or not:
 411 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 412   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 413 if test ${enableval} = "yes" ; then
 414   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 415 else
 416   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 417 fi
 418
 419 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 420 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 421   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 422 if test ${enableval} = "yes" ; then
 423   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 424   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 425 else
 426   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 427   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 428 fi
 429
 430 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 431 AC_ARG_ENABLE(debug-runtime,
 432    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 433 if test ${enableval} = "no" ; then
 434   AC_SUBST(DEBUG_RUNTIME,[[]])
 435 else
 436   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 437 fi
 438
 439 dnl --enable-debug-symbols : should even optimized compiler libraries
 440 dnl have debug symbols?
 441 AC_ARG_ENABLE(debug-symbols,
 442    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 443 if test ${enableval} = "no" ; then
 444   AC_SUBST(DEBUG_SYMBOLS,[[]])
 445 else
 446   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 447 fi
 448
 449 dnl --enable-jit: check whether they want to enable the jit
 450 AC_ARG_ENABLE(jit,
 451   AS_HELP_STRING(--enable-jit,
 452                  [Enable Just In Time Compiling (default is YES)]),,
 453   enableval=default)
 454 if test ${enableval} = "no"
 455 then
 456   AC_SUBST(JIT,[[]])
 457 else
 458   case "$llvm_cv_target_arch" in
 459     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 460     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 461     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 462     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 463     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 464     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 465     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 466     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 467     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 468     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 469     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 470     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 471     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 472     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 473   esac
 474 fi
 475
 476 dnl Allow enablement of doxygen generated documentation
 477 AC_ARG_ENABLE(doxygen,
 478               AS_HELP_STRING([--enable-doxygen],
 479                              [Build doxygen documentation (default is NO)]),,
 480                              enableval=default)
 481 case "$enableval" in
 482   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 483   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 484   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 485   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 486 esac
 487
 488 dnl Allow disablement of threads
 489 AC_ARG_ENABLE(threads,
 490               AS_HELP_STRING([--enable-threads],
 491                              [Use threads if available (default is YES)]),,
 492                              enableval=default)
 493 case "$enableval" in
 494   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 495   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 496   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 497   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 498 esac
 499 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 500
 501 dnl Allow building without position independent code
 502 AC_ARG_ENABLE(pic,
 503   AS_HELP_STRING([--enable-pic],
 504                  [Build LLVM with Position Independent Code (default is YES)]),,
 505                  enableval=default)
 506 case "$enableval" in
 507   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 508   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 509   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 510   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 511 esac
 512 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 513                    [Define if position independent code is enabled])
 514
 515 dnl Allow building a shared library and linking tools against it.
 516 AC_ARG_ENABLE(shared,
 517   AS_HELP_STRING([--enable-shared],
 518                  [Build a shared library and link tools against it (default is NO)]),,
 519                  enableval=default)
 520 case "$enableval" in
 521   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 522   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 523   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 524   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 525 esac
 526
 527 dnl Enable embedding timestamp information into build.
 528 AC_ARG_ENABLE(timestamps,
 529   AS_HELP_STRING([--enable-timestamps],
 530                  [Enable embedding timestamp information in build (default is YES)]),,
 531                  enableval=default)
 532 case "$enableval" in
 533   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 534   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 535   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 536   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 537 esac
 538 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 539                    [Define if timestamp information (e.g., __DATE___) is allowed])
 540
 541 dnl Allow specific targets to be specified for building (or not)
 542 TARGETS_TO_BUILD=""
 543 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 544     [Build specific host targets: all or target1,target2,... Valid targets are:
 545      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu,
 546      xcore, msp430, systemz, blackfin, ptx, cbe, and cpp (default=all)]),,
 547     enableval=all)
 548 if test "$enableval" = host-only ; then
 549   enableval=host
 550 fi
 551 case "$enableval" in
 552   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU XCore MSP430 SystemZ Blackfin CBackend CppBackend MBlaze PTX" ;;
 553   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 554       case "$a_target" in
 555         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 556         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 557         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 558         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 559         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 560         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 561         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 562         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 563         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 564         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 565         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 566         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 567         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 568         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 569         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 570         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 571         host) case "$llvm_cv_target_arch" in
 572             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 573             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 574             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 575             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 576             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 577             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 578             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 579             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 580             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 581             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 582             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 583             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 584             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 585             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 586             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 587           esac ;;
 588         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 589       esac
 590   done
 591   ;;
 592 esac
 593 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 594
 595 # Determine whether we are building LLVM support for the native architecture.
 596 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 597 for a_target in $TARGETS_TO_BUILD; do
 598   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 599     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 600       [LLVM architecture name for the native architecture, if available])
 601     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 602     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 603     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 604     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 605       [LLVM name for the native Target init function, if available])
 606     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 607       [LLVM name for the native TargetInfo init function, if available])
 608     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 609       [LLVM name for the native AsmPrinter init function, if available])
 610   fi
 611 done
 612
 613 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 614 # target feature def files.
 615 LLVM_ENUM_TARGETS=""
 616 LLVM_ENUM_ASM_PRINTERS=""
 617 LLVM_ENUM_ASM_PARSERS=""
 618 LLVM_ENUM_DISASSEMBLERS=""
 619 for target_to_build in $TARGETS_TO_BUILD; do
 620   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 621   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 622     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 623   fi
 624   # MC-ized AsmPrinters live in TARGET/InstPrinter, not AsmPrinter
 625   if test -f ${srcdir}/lib/Target/${target_to_build}/InstPrinter/Makefile ; then
 626     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 627   fi
 628   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 629     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 630   fi
 631   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 632     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 633   fi
 634 done
 635 AC_SUBST(LLVM_ENUM_TARGETS)
 636 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 637 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 638 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 639
 640 dnl Prevent the CBackend from using printf("%a") for floating point so older
 641 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 642 dnl can still compile the CBE's output
 643 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 644   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 645   enableval=default)
 646 case "$enableval" in
 647   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 648   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 649   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 650   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 651 esac
 652 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 653                    [Define if CBE is enabled for printf %a output])
 654
 655 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 656 AC_ARG_WITH(llvmgccdir,
 657   AS_HELP_STRING([--with-llvmgccdir],
 658     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 659     withval=default)
 660 case "$withval" in
 661   default) WITH_LLVMGCCDIR=default ;;
 662   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 663   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 664 esac
 665
 666 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 667 AC_ARG_WITH(llvmgcc,
 668   AS_HELP_STRING([--with-llvmgcc],
 669     [Specify location of llvm-gcc driver (default searches PATH)]),
 670     LLVMGCC=$with_llvmgcc
 671       WITH_LLVMGCCDIR="",)
 672
 673 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 674 AC_ARG_WITH(llvmgxx,
 675   AS_HELP_STRING([--with-llvmgxx],
 676     [Specify location of llvm-g++ driver (default searches PATH)]),
 677     LLVMGXX=$with_llvmgxx
 678     WITH_LLVMGCCDIR="",)
 679
 680 if test -n "$LLVMGCC"; then
 681    LLVMGCCCOMMAND="$LLVMGCC"
 682 fi
 683
 684 if test -n "$LLVMGXX"; then
 685    LLVMGXXCOMMAND="$LLVMGXX"
 686 fi
 687
 688 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 689    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 690 fi
 691
 692 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 693    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 694 fi
 695
 696 dnl Allow a specific Clang compiler to be used with this LLVM config.
 697 AC_ARG_WITH(clang,
 698   AS_HELP_STRING([--with-clang],
 699     [Specify location of clang compiler (default is --with-built-clang)]),
 700     [],[with_clang=default])
 701
 702 dnl Enable use of the built Clang.
 703 AC_ARG_WITH(built-clang,
 704   AS_HELP_STRING([--with-built-clang],
 705     [Use the compiled Clang as the LLVM compiler (default=check)]),
 706     [],[with_built_clang=check])
 707
 708 dnl Select the Clang compiler option.
 709 dnl
 710 dnl If --with-clang is given, always honor that; otherwise honor
 711 dnl --with-built-clang, or check if we have the clang sources.
 712 AC_MSG_CHECKING([clang compiler])
 713 WITH_CLANGPATH=""
 714 WITH_BUILT_CLANG=0
 715 if test "$with_clang" != "default"; then
 716    WITH_CLANGPATH="$with_clang"
 717    if ! test -x "$WITH_CLANGPATH"; then
 718      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 719    fi
 720 elif test "$with_built_clang" = "yes"; then
 721    WITH_BUILT_CLANG=1
 722 elif test "$with_built_clang" = "no"; then
 723    WITH_BUILT_CLANG=0
 724 else
 725    if test "$with_built_clang" != "check"; then
 726       AC_MSG_ERROR([invalid value for --with-built-clang.])
 727    fi
 728
 729    if test -f ${srcdir}/tools/clang/README.txt; then
 730      WITH_BUILT_CLANG=1
 731    fi
 732 fi
 733
 734 if ! test -z "$WITH_CLANGPATH"; then
 735    AC_MSG_RESULT([$WITH_CLANGPATH])
 736    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 737 elif test "$WITH_BUILT_CLANG" = "1"; then
 738    AC_MSG_RESULT([built])
 739 else
 740    AC_MSG_RESULT([none])
 741 fi
 742 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 743 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 744 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 745
 746 dnl Override the option to use for optimized builds.
 747 AC_ARG_WITH(optimize-option,
 748   AS_HELP_STRING([--with-optimize-option],
 749                  [Select the compiler options to use for optimized builds]),,
 750                  withval=default)
 751 AC_MSG_CHECKING([optimization flags])
 752 case "$withval" in
 753   default)
 754     case "$llvm_cv_os_type" in
 755     FreeBSD) optimize_option=-O2 ;;
 756     MingW) optimize_option=-O2 ;;
 757     *)     optimize_option=-O3 ;;
 758     esac ;;
 759   *) optimize_option="$withval" ;;
 760 esac
 761 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 762 AC_MSG_RESULT([$optimize_option])
 763
 764 dnl Specify extra build options
 765 AC_ARG_WITH(extra-options,
 766   AS_HELP_STRING([--with-extra-options],
 767                  [Specify additional options to compile LLVM with]),,
 768                  withval=default)
 769 case "$withval" in
 770   default) EXTRA_OPTIONS= ;;
 771   *) EXTRA_OPTIONS=$withval ;;
 772 esac
 773 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 774
 775 dnl Allow specific bindings to be specified for building (or not)
 776 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 777     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 778     enableval=default)
 779 BINDINGS_TO_BUILD=""
 780 case "$enableval" in
 781   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 782   all ) BINDINGS_TO_BUILD="ocaml" ;;
 783   none | no) BINDINGS_TO_BUILD="" ;;
 784   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 785       case "$a_binding" in
 786         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 787         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 788       esac
 789   done
 790   ;;
 791 esac
 792
 793 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 794 dnl script for bindings/ocaml/configure, except that its auto value depends on
 795 dnl OCAMLC, which is found here to support tests.
 796 AC_ARG_WITH([ocaml-libdir],
 797   [AS_HELP_STRING([--with-ocaml-libdir],
 798     [Specify install location for ocaml bindings (default is stdlib)])],
 799   [],
 800   [withval=auto])
 801 case "$withval" in
 802   auto) with_ocaml_libdir="$withval" ;;
 803   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 804   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 805 esac
 806
 807 AC_ARG_WITH(clang-resource-dir,
 808   AS_HELP_STRING([--with-clang-resource-dir],
 809     [Relative directory from the Clang binary for resource files]),,
 810     withval="")
 811 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 812                    [Relative directory for resource files])
 813
 814 AC_ARG_WITH(c-include-dirs,
 815   AS_HELP_STRING([--with-c-include-dirs],
 816     [Colon separated list of directories clang will search for headers]),,
 817     withval="")
 818 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 819                    [Directories clang will search for headers])
 820
 821 AC_ARG_WITH(cxx-include-root,
 822   AS_HELP_STRING([--with-cxx-include-root],
 823     [Directory with the libstdc++ headers.]),,
 824     withval="")
 825 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 826                    [Directory with the libstdc++ headers.])
 827
 828 AC_ARG_WITH(cxx-include-arch,
 829   AS_HELP_STRING([--with-cxx-include-arch],
 830     [Architecture of the libstdc++ headers.]),,
 831     withval="")
 832 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 833                    [Arch the libstdc++ headers.])
 834
 835 AC_ARG_WITH(cxx-include-32bit-dir,
 836   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 837     [32 bit multilib dir.]),,
 838     withval="")
 839 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 840                    [32 bit multilib directory.])
 841
 842 AC_ARG_WITH(cxx-include-64bit-dir,
 843   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 844     [64 bit multilib directory.]),,
 845     withval="")
 846 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 847                    [64 bit multilib directory.])
 848
 849 dnl Allow linking of LLVM with GPLv3 binutils code.
 850 AC_ARG_WITH(binutils-include,
 851   AS_HELP_STRING([--with-binutils-include],
 852     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 853   withval=default)
 854 case "$withval" in
 855   default) WITH_BINUTILS_INCDIR=default ;;
 856   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 857   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 858 esac
 859 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 860   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 861   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 862      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 863      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 864   fi
 865 fi
 866
 867 dnl --enable-libffi : check whether the user wants to turn off libffi:
 868 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 869   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 870   [case "$enableval" in
 871     yes) llvm_cv_enable_libffi="yes" ;;
 872     no)  llvm_cv_enable_libffi="no"  ;;
 873     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 874   esac],
 875   llvm_cv_enable_libffi=no)
 876
 877 dnl===-----------------------------------------------------------------------===
 878 dnl===
 879 dnl=== SECTION 4: Check for programs we need and that they are the right version
 880 dnl===
 881 dnl===-----------------------------------------------------------------------===
 882
 883 dnl Check for compilation tools
 884 AC_PROG_CPP
 885 AC_PROG_CC(gcc)
 886 AC_PROG_CXX(g++)
 887
 888 AC_PROG_NM
 889 AC_SUBST(NM)
 890
 891 dnl Check for the tools that the makefiles require
 892 AC_CHECK_GNU_MAKE
 893 AC_PROG_LN_S
 894 AC_PATH_PROG(CMP, [cmp], [cmp])
 895 AC_PATH_PROG(CP, [cp], [cp])
 896 AC_PATH_PROG(DATE, [date], [date])
 897 AC_PATH_PROG(FIND, [find], [find])
 898 AC_PATH_PROG(GREP, [grep], [grep])
 899 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 900 AC_PATH_PROG(MV,   [mv],   [mv])
 901 AC_PROG_RANLIB
 902 AC_CHECK_TOOL(AR, ar, false)
 903 AC_PATH_PROG(RM,   [rm],   [rm])
 904 AC_PATH_PROG(SED,  [sed],  [sed])
 905 AC_PATH_PROG(TAR,  [tar],  [gtar])
 906 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 907
 908 dnl Looking for misc. graph plotting software
 909 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 910 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 911   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 912   dnl If we're targeting for mingw we should emit windows paths, not msys
 913   if test "$llvm_cv_os_type" = "MingW" ; then
 914     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 915   fi
 916   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 917    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 918 fi
 919 AC_PATH_PROG(DOT, [dot], [echo dot])
 920 if test "$DOT" != "echo dot" ; then
 921   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 922   dnl If we're targeting for mingw we should emit windows paths, not msys
 923   if test "$llvm_cv_os_type" = "MingW" ; then
 924     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 925   fi
 926   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 927    [Define to path to dot program if found or 'echo dot' otherwise])
 928 fi
 929 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 930 if test "$FDP" != "echo fdp" ; then
 931   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 932   dnl If we're targeting for mingw we should emit windows paths, not msys
 933   if test "$llvm_cv_os_type" = "MingW" ; then
 934     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 935   fi
 936   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 937    [Define to path to fdp program if found or 'echo fdp' otherwise])
 938 fi
 939 AC_PATH_PROG(NEATO, [neato], [echo neato])
 940 if test "$NEATO" != "echo neato" ; then
 941   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 942   dnl If we're targeting for mingw we should emit windows paths, not msys
 943   if test "$llvm_cv_os_type" = "MingW" ; then
 944     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 945   fi
 946   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 947    [Define to path to neato program if found or 'echo neato' otherwise])
 948 fi
 949 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 950 if test "$TWOPI" != "echo twopi" ; then
 951   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 952   dnl If we're targeting for mingw we should emit windows paths, not msys
 953   if test "$llvm_cv_os_type" = "MingW" ; then
 954     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 955   fi
 956   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 957    [Define to path to twopi program if found or 'echo twopi' otherwise])
 958 fi
 959 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 960 if test "$CIRCO" != "echo circo" ; then
 961   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 962   dnl If we're targeting for mingw we should emit windows paths, not msys
 963   if test "$llvm_cv_os_type" = "MingW" ; then
 964     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 965   fi
 966   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 967    [Define to path to circo program if found or 'echo circo' otherwise])
 968 fi
 969 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 970 if test "$GV" != "echo gv" ; then
 971   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 972   dnl If we're targeting for mingw we should emit windows paths, not msys
 973   if test "$llvm_cv_os_type" = "MingW" ; then
 974     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 975   fi
 976   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 977    [Define to path to gv program if found or 'echo gv' otherwise])
 978 fi
 979 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 980 if test "$DOTTY" != "echo dotty" ; then
 981   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 982   dnl If we're targeting for mingw we should emit windows paths, not msys
 983   if test "$llvm_cv_os_type" = "MingW" ; then
 984     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 985   fi
 986   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 987    [Define to path to dotty program if found or 'echo dotty' otherwise])
 988 fi
 989 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
 990 if test "$XDOT_PY" != "echo xdot.py" ; then
 991   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
 992   dnl If we're targeting for mingw we should emit windows paths, not msys
 993   if test "$llvm_cv_os_type" = "MingW" ; then
 994     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 995   fi
 996   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
 997    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
 998 fi
 999
1000 dnl Look for a sufficiently recent version of Perl.
1001 LLVM_PROG_PERL([5.006])
1002 AC_SUBST(PERL)
1003 if test x"$PERL" = xnone; then
1004    AC_SUBST(HAVE_PERL,0)
1005    AC_MSG_ERROR([perl is required but was not found, please install it])
1006 else
1007    AC_SUBST(HAVE_PERL,1)
1008 fi
1009
1010 dnl Find the install program
1011 AC_PROG_INSTALL
1012 dnl Prepend src dir to install path dir if it's a relative path
1013 dnl This is a hack for installs that take place in something other
1014 dnl than the top level.
1015 case "$INSTALL" in
1016  [[\\/$]]* | ?:[[\\/]]* ) ;;
1017  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1018 esac
1019
1020 dnl Checks for documentation and testing tools that we can do without. If these
1021 dnl are not found then they are set to "true" which always succeeds but does
1022 dnl nothing. This just lets the build output show that we could have done
1023 dnl something if the tool was available.
1024 AC_PATH_PROG(BZIP2, [bzip2])
1025 AC_PATH_PROG(CAT, [cat])
1026 AC_PATH_PROG(DOXYGEN, [doxygen])
1027 AC_PATH_PROG(GROFF, [groff])
1028 AC_PATH_PROG(GZIP, [gzip])
1029 AC_PATH_PROG(POD2HTML, [pod2html])
1030 AC_PATH_PROG(POD2MAN, [pod2man])
1031 AC_PATH_PROG(PDFROFF, [pdfroff])
1032 AC_PATH_PROG(RUNTEST, [runtest])
1033 DJ_AC_PATH_TCLSH
1034 AC_PATH_PROG(ZIP, [zip])
1035 AC_PATH_PROGS(OCAMLC, [ocamlc])
1036 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1037 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1038 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1039 AC_PATH_PROGS(GAS, [gas as])
1040
1041 dnl Get the version of the linker in use.
1042 AC_LINK_GET_VERSION
1043
1044 dnl Determine whether the linker supports the -R option.
1045 AC_LINK_USE_R
1046
1047 dnl Determine whether the linker supports the -export-dynamic option.
1048 AC_LINK_EXPORT_DYNAMIC
1049
1050 dnl Determine whether the linker supports the --version-script option.
1051 AC_LINK_VERSION_SCRIPT
1052
1053 dnl Check for libtool and the library that has dlopen function (which must come
1054 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1055 dnl libtool).
1056 AC_LIBTOOL_DLOPEN
1057 AC_LIB_LTDL
1058
1059 if test "$WITH_LLVMGCCDIR" = "default" ; then
1060   LLVMGCC="llvm-gcc${EXEEXT}"
1061   LLVMGXX="llvm-g++${EXEEXT}"
1062   LLVMGCCCOMMAND="$LLVMGCC"
1063   LLVMGXXCOMMAND="$LLVMGXX"
1064   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1065   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1066   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
1067   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
1068 else
1069   if test -z "$LLVMGCC"; then
1070     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
1071     LLVMGCCCOMMAND="$LLVMGCC"
1072   fi
1073   if test -z "$LLVMGXX"; then
1074     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1075     LLVMGXXCOMMAND="$LLVMGXX"
1076   fi
1077
1078   AC_SUBST(LLVMGCC,$LLVMGCC)
1079   AC_SUBST(LLVMGXX,$LLVMGXX)
1080   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1081   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1082 fi
1083
1084 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1085 dnl found, otherwise clang if available.
1086 AC_ARG_WITH(llvmcc,
1087   AS_HELP_STRING([--with-llvmcc=<name>],
1088     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1089     [],[with_llvmcc=check])
1090 AC_MSG_CHECKING([LLVM capable compiler])
1091 if test "$with_llvmcc" != "check"; then
1092    if (test "$with_llvmcc" != "llvm-gcc" &&
1093        test "$with_llvmcc" != "clang" &&
1094        test "$with_llvmcc" != "none"); then
1095       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1096    fi
1097    WITH_LLVMCC="$with_llvmcc"
1098 elif test -n "$LLVMGCC"; then
1099    WITH_LLVMCC=llvm-gcc
1100 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1101    WITH_LLVMCC=clang
1102 else
1103    WITH_LLVMCC=none
1104 fi
1105 AC_MSG_RESULT([$WITH_LLVMCC])
1106 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1107
1108 AC_MSG_CHECKING([tool compatibility])
1109
1110 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1111 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1112 dnl to support those options.
1113 dnl "icc" emits gcc signatures
1114 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1115 ICC=no
1116 IXX=no
1117 case $CC in
1118   icc*|icpc*)
1119     ICC=yes
1120     IXX=yes
1121     ;;
1122    *)
1123     ;;
1124 esac
1125
1126 if test "$GCC" != "yes" && test "$ICC" != "yes"
1127 then
1128   AC_MSG_ERROR([gcc|icc required but not found])
1129 fi
1130
1131 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
1132 if test "$GXX" != "yes" && test "$IXX" != "yes"
1133 then
1134   AC_MSG_ERROR([g++|icc required but not found])
1135 fi
1136
1137 dnl Verify that GCC is version 3.0 or higher
1138 if test "$GCC" = "yes"
1139 then
1140   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1141 #error Unsupported GCC version
1142 #endif
1143 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1144 fi
1145
1146 dnl Check for GNU Make.  We use its extensions, so don't build without it
1147 if test -z "$llvm_cv_gnu_make_command"
1148 then
1149   AC_MSG_ERROR([GNU Make required but not found])
1150 fi
1151
1152 dnl Tool compatibility is okay if we make it here.
1153 AC_MSG_RESULT([ok])
1154
1155 dnl Check optional compiler flags.
1156 AC_MSG_CHECKING([optional compiler flags])
1157 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1158 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1159 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1160
1161 dnl===-----------------------------------------------------------------------===
1162 dnl===
1163 dnl=== SECTION 5: Check for libraries
1164 dnl===
1165 dnl===-----------------------------------------------------------------------===
1166
1167 AC_CHECK_LIB(m,sin)
1168 if test "$llvm_cv_os_type" = "MingW" ; then
1169   AC_CHECK_LIB(imagehlp, main)
1170   AC_CHECK_LIB(psapi, main)
1171 fi
1172
1173 dnl dlopen() is required for plugin support.
1174 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1175                [Define if dlopen() is available on this platform.]),
1176                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1177
1178 dnl libffi is optional; used to call external functions from the interpreter
1179 if test "$llvm_cv_enable_libffi" = "yes" ; then
1180   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1181                  [Define if libffi is available on this platform.]),
1182                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1183 fi
1184
1185 dnl mallinfo is optional; the code can compile (minus features) without it
1186 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1187                [Define if mallinfo() is available on this platform.]))
1188
1189 dnl pthread locking functions are optional - but llvm will not be thread-safe
1190 dnl without locks.
1191 if test "$ENABLE_THREADS" -eq 1 ; then
1192   AC_CHECK_LIB(pthread, pthread_mutex_init)
1193   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1194                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1195                            [Have pthread_mutex_lock]))
1196   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1197                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1198                  [Have pthread_rwlock_init]))
1199   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1200                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1201                  [Have pthread_getspecific]))
1202 fi
1203
1204 dnl Allow extra x86-disassembler library
1205 AC_ARG_WITH(udis86,
1206   AS_HELP_STRING([--with-udis86=<path>],
1207     [Use udis86 external x86 disassembler library]),
1208     [
1209       AC_SUBST(USE_UDIS86, [1])
1210       case "$withval" in
1211         /usr/lib|yes) ;;
1212         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1213       esac
1214       AC_CHECK_LIB(udis86, ud_init, [], [
1215         echo "Error! You need to have libudis86 around."
1216         exit -1
1217       ])
1218     ],
1219     AC_SUBST(USE_UDIS86, [0]))
1220 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1221                    [Define if use udis86 library])
1222
1223 dnl Allow OProfile support for JIT output.
1224 AC_ARG_WITH(oprofile,
1225   AS_HELP_STRING([--with-oprofile=<prefix>],
1226     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1227     [
1228       AC_SUBST(USE_OPROFILE, [1])
1229       case "$withval" in
1230         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1231         no) llvm_cv_oppath=
1232             AC_SUBST(USE_OPROFILE, [0]) ;;
1233         *) llvm_cv_oppath="${withval}/lib/oprofile"
1234            CPPFLAGS="-I${withval}/include";;
1235       esac
1236       if test -n "$llvm_cv_oppath" ; then
1237         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1238         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1239         dnl libbfd is not included properly in libopagent in some Debian
1240         dnl versions.  If libbfd isn't found at all, we assume opagent works
1241         dnl anyway.
1242         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1243         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1244           echo "Error! You need to have libopagent around."
1245           exit -1
1246         ])
1247         AC_CHECK_HEADER([opagent.h], [], [
1248           echo "Error! You need to have opagent.h around."
1249           exit -1
1250           ])
1251       fi
1252     ],
1253     [
1254       AC_SUBST(USE_OPROFILE, [0])
1255     ])
1256 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1257                    [Define if we have the oprofile JIT-support library])
1258
1259 dnl===-----------------------------------------------------------------------===
1260 dnl===
1261 dnl=== SECTION 6: Check for header files
1262 dnl===
1263 dnl===-----------------------------------------------------------------------===
1264
1265 dnl First, use autoconf provided macros for specific headers that we need
1266 dnl We don't check for ancient stuff or things that are guaranteed to be there
1267 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1268 dnl Generally we're looking for POSIX headers.
1269 AC_HEADER_DIRENT
1270 AC_HEADER_MMAP_ANONYMOUS
1271 AC_HEADER_STAT
1272 AC_HEADER_STDC
1273 AC_HEADER_SYS_WAIT
1274 AC_HEADER_TIME
1275
1276 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1277 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1278 AC_CHECK_HEADERS([utime.h windows.h])
1279 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1280 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1281 AC_CHECK_HEADERS([valgrind/valgrind.h])
1282 AC_CHECK_HEADERS([fenv.h])
1283 if test "$ENABLE_THREADS" -eq 1 ; then
1284   AC_CHECK_HEADERS(pthread.h,
1285                    AC_SUBST(HAVE_PTHREAD, 1),
1286                    AC_SUBST(HAVE_PTHREAD, 0))
1287 else
1288   AC_SUBST(HAVE_PTHREAD, 0)
1289 fi
1290
1291 dnl Try to find ffi.h.
1292 if test "$llvm_cv_enable_libffi" = "yes" ; then
1293   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1294 fi
1295
1296 dnl Try to find Darwin specific crash reporting library.
1297 AC_CHECK_HEADERS([CrashReporterClient.h])
1298
1299 dnl===-----------------------------------------------------------------------===
1300 dnl===
1301 dnl=== SECTION 7: Check for types and structures
1302 dnl===
1303 dnl===-----------------------------------------------------------------------===
1304
1305 AC_HUGE_VAL_CHECK
1306 AC_TYPE_PID_T
1307 AC_TYPE_SIZE_T
1308 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1309 AC_STRUCT_TM
1310 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1311 AC_CHECK_TYPES([uint64_t],,
1312          AC_CHECK_TYPES([u_int64_t],,
1313          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1314
1315 dnl===-----------------------------------------------------------------------===
1316 dnl===
1317 dnl=== SECTION 8: Check for specific functions needed
1318 dnl===
1319 dnl===-----------------------------------------------------------------------===
1320
1321 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1322 AC_CHECK_FUNCS([powf fmodf strtof round ])
1323 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1324 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1325 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1326 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1327 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1328 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1329 AC_C_PRINTF_A
1330 AC_FUNC_RAND48
1331
1332 dnl Check for variations in the Standard C++ library and STL. These macros are
1333 dnl provided by LLVM in the autoconf/m4 directory.
1334 AC_FUNC_ISNAN
1335 AC_FUNC_ISINF
1336
1337 dnl Check for mmap support.We also need to know if /dev/zero is required to
1338 dnl be opened for allocating RWX memory.
1339 dnl Make sure we aren't attempting to configure for an unknown system
1340 if test "$llvm_cv_platform_type" = "Unix" ; then
1341   AC_FUNC_MMAP
1342   AC_FUNC_MMAP_FILE
1343   AC_NEED_DEV_ZERO_FOR_MMAP
1344
1345   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1346   then
1347     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1348   fi
1349   if test "$ac_cv_func_mmap_file" = "no"
1350   then
1351     AC_MSG_WARN([mmap() of files required but not found])
1352   fi
1353 fi
1354
1355 dnl atomic builtins are required for threading support.
1356 AC_MSG_CHECKING(for GCC atomic builtins)
1357 dnl Since we'll be using these atomic builtins in C++ files we should test
1358 dnl the C++ compiler.
1359 AC_LANG_PUSH([C++])
1360 AC_LINK_IFELSE(
1361   AC_LANG_SOURCE(
1362     [[int main() {
1363         volatile unsigned long val = 1;
1364         __sync_synchronize();
1365         __sync_val_compare_and_swap(&val, 1, 0);
1366         __sync_add_and_fetch(&val, 1);
1367         __sync_sub_and_fetch(&val, 1);
1368         return 0;
1369       }
1370     ]]),
1371   AC_LANG_POP([C++])
1372   AC_MSG_RESULT(yes)
1373   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1374   AC_MSG_RESULT(no)
1375   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1376   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1377
1378 dnl===-----------------------------------------------------------------------===
1379 dnl===
1380 dnl=== SECTION 9: Additional checks, variables, etc.
1381 dnl===
1382 dnl===-----------------------------------------------------------------------===
1383
1384 dnl Handle 32-bit linux systems running a 64-bit kernel.
1385 dnl This has to come after section 4 because it invokes the compiler.
1386 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1387   AC_IS_LINUX_MIXED
1388   if test "$llvm_cv_linux_mixed" = "yes"; then
1389     llvm_cv_target_arch="x86"
1390     ARCH="x86"
1391   fi
1392 fi
1393
1394 dnl Check, whether __dso_handle is present
1395 AC_CHECK_FUNCS([__dso_handle])
1396
1397 dnl See if the llvm-gcc executable can compile to LLVM assembly
1398 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1399 [llvm_cv_llvmgcc_sanity="no"
1400 if test -x "$LLVMGCC" ; then
1401   cp /dev/null conftest.c
1402   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1403       grep 'target datalayout =' > /dev/null 2>&1
1404   if test $? -eq 0 ; then
1405     llvm_cv_llvmgcc_sanity="yes"
1406   fi
1407   rm conftest.c
1408 fi])
1409
1410 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1411 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1412   AC_MSG_CHECKING([llvm-gcc component support])
1413   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1414   AC_SUBST(LLVMCC1,$llvmcc1path)
1415   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1416   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1417   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1418   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1419   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1420   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1421   AC_MSG_RESULT([ok])
1422 fi
1423
1424 dnl Propagate the shared library extension that the libltdl checks did to
1425 dnl the Makefiles so we can use it there too
1426 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1427
1428 dnl Propagate the run-time library path variable that the libltdl
1429 dnl checks found to the Makefiles so we can use it there too
1430 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1431
1432 # Translate the various configuration directories and other basic
1433 # information into substitutions that will end up in Makefile.config.in
1434 # that these configured values can be used by the makefiles
1435 if test "${prefix}" = "NONE" ; then
1436   prefix="/usr/local"
1437 fi
1438 eval LLVM_PREFIX="${prefix}";
1439 eval LLVM_BINDIR="${prefix}/bin";
1440 eval LLVM_LIBDIR="${prefix}/lib";
1441 eval LLVM_DATADIR="${prefix}/share/llvm";
1442 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1443 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1444 eval LLVM_INCLUDEDIR="${prefix}/include";
1445 eval LLVM_INFODIR="${prefix}/info";
1446 eval LLVM_MANDIR="${prefix}/man";
1447 LLVM_CONFIGTIME=`date`
1448 AC_SUBST(LLVM_PREFIX)
1449 AC_SUBST(LLVM_BINDIR)
1450 AC_SUBST(LLVM_LIBDIR)
1451 AC_SUBST(LLVM_DATADIR)
1452 AC_SUBST(LLVM_DOCSDIR)
1453 AC_SUBST(LLVM_ETCDIR)
1454 AC_SUBST(LLVM_INCLUDEDIR)
1455 AC_SUBST(LLVM_INFODIR)
1456 AC_SUBST(LLVM_MANDIR)
1457 AC_SUBST(LLVM_CONFIGTIME)
1458
1459 # Place the various directores into the config.h file as #defines so that we
1460 # can know about the installation paths within LLVM.
1461 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1462                    [Installation prefix directory])
1463 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1464                    [Installation directory for binary executables])
1465 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1466                    [Installation directory for libraries])
1467 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1468                    [Installation directory for data files])
1469 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1470                    [Installation directory for documentation])
1471 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1472                    [Installation directory for config files])
1473 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1474                    [Installation directory for include files])
1475 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1476                    [Installation directory for .info files])
1477 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1478                    [Installation directory for man pages])
1479 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1480                    [Time at which LLVM was configured])
1481 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1482                    [Host triple we were built on])
1483
1484 # Determine which bindings to build.
1485 if test "$BINDINGS_TO_BUILD" = auto ; then
1486   BINDINGS_TO_BUILD=""
1487   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1488     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1489   fi
1490 fi
1491 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1492
1493 # This isn't really configurey, but it avoids having to repeat the list in
1494 # other files.
1495 AC_SUBST(ALL_BINDINGS,ocaml)
1496
1497 # Do any work necessary to ensure that bindings have what they need.
1498 binding_prereqs_failed=0
1499 for a_binding in $BINDINGS_TO_BUILD ; do
1500   case "$a_binding" in
1501   ocaml)
1502     if test "x$OCAMLC" = x ; then
1503       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1504       binding_prereqs_failed=1
1505     fi
1506     if test "x$OCAMLDEP" = x ; then
1507       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1508       binding_prereqs_failed=1
1509     fi
1510     if test "x$OCAMLOPT" = x ; then
1511       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1512       dnl ocamlopt is optional!
1513     fi
1514     if test "x$with_ocaml_libdir" != xauto ; then
1515       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1516     else
1517       ocaml_stdlib="`"$OCAMLC" -where`"
1518       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1519       then
1520         # ocaml stdlib is beneath our prefix; use stdlib
1521         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1522       else
1523         # ocaml stdlib is outside our prefix; use libdir/ocaml
1524         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1525       fi
1526     fi
1527     ;;
1528   esac
1529 done
1530 if test "$binding_prereqs_failed" = 1 ; then
1531   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1532 fi
1533
1534 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1535 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1536
1537 dnl Determine linker rpath flag
1538 if test "$llvm_cv_link_use_r" = "yes" ; then
1539   RPATH="-Wl,-R"
1540 else
1541   RPATH="-Wl,-rpath"
1542 fi
1543 AC_SUBST(RPATH)
1544
1545 dnl Determine linker rdynamic flag
1546 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1547   RDYNAMIC="-Wl,-export-dynamic"
1548 else
1549   RDYNAMIC=""
1550 fi
1551 AC_SUBST(RDYNAMIC)
1552
1553 dnl===-----------------------------------------------------------------------===
1554 dnl===
1555 dnl=== SECTION 10: Specify the output files and generate it
1556 dnl===
1557 dnl===-----------------------------------------------------------------------===
1558
1559 dnl Configure header files
1560 dnl WARNING: dnl If you add or remove any of the following config headers, then
1561 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1562 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1563 dnl files can be updated automatically when their *.in sources change.
1564 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1565 AH_TOP([#ifndef CONFIG_H
1566 #define CONFIG_H])
1567 AH_BOTTOM([#endif])
1568
1569 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1570 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1571 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1572 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1573 AC_CONFIG_HEADERS([include/llvm/System/DataTypes.h])
1574
1575 dnl Configure the makefile's configuration data
1576 AC_CONFIG_FILES([Makefile.config])
1577
1578 dnl Configure the RPM spec file for LLVM
1579 AC_CONFIG_FILES([llvm.spec])
1580
1581 dnl Configure llvmc's Base plugin
1582 AC_CONFIG_FILES([tools/llvmc/src/Base.td])
1583
1584 dnl Do the first stage of configuration for llvm-config.in.
1585 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1586
1587 dnl Do special configuration of Makefiles
1588 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1589 AC_CONFIG_MAKEFILE(Makefile)
1590 AC_CONFIG_MAKEFILE(Makefile.common)
1591 AC_CONFIG_MAKEFILE(examples/Makefile)
1592 AC_CONFIG_MAKEFILE(lib/Makefile)
1593 AC_CONFIG_MAKEFILE(runtime/Makefile)
1594 AC_CONFIG_MAKEFILE(test/Makefile)
1595 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1596 AC_CONFIG_MAKEFILE(unittests/Makefile)
1597 AC_CONFIG_MAKEFILE(tools/Makefile)
1598 AC_CONFIG_MAKEFILE(utils/Makefile)
1599 AC_CONFIG_MAKEFILE(projects/Makefile)
1600 AC_CONFIG_MAKEFILE(bindings/Makefile)
1601 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1602
1603 dnl Finally, crank out the output
1604 AC_OUTPUT