autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.8svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65
  66 dnl
  67 dnl One tricky part of doing this is that some projects depend upon other
  68 dnl projects.  For example, several projects rely upon the LLVM test suite.
  69 dnl We want to configure those projects first so that their object trees are
  70 dnl created before running the configure scripts of projects that depend upon
  71 dnl them.
  72 dnl
  73
  74 dnl Several projects use llvm-gcc, so configure that first
  75 if test -d ${srcdir}/projects/llvm-gcc ; then
  76   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  77 fi
  78
  79 dnl Several projects use the LLVM test suite, so configure it next.
  80 if test -d ${srcdir}/projects/test-suite ; then
  81   AC_CONFIG_SUBDIRS([projects/test-suite])
  82 fi
  83
  84 dnl llvm-test is the old name of the test-suite, kept here for backwards
  85 dnl compatibility
  86 if test -d ${srcdir}/projects/llvm-test ; then
  87   AC_CONFIG_SUBDIRS([projects/llvm-test])
  88 fi
  89
  90 dnl Some projects use poolalloc; configure that next
  91 if test -d ${srcdir}/projects/poolalloc ; then
  92   AC_CONFIG_SUBDIRS([projects/poolalloc])
  93 fi
  94
  95 if test -d ${srcdir}/projects/llvm-poolalloc ; then
  96   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
  97 fi
  98
  99 dnl Check for all other projects
 100 for i in `ls ${srcdir}/projects`
 101 do
 102   if test -d ${srcdir}/projects/${i} ; then
 103     case ${i} in
 104       CVS) ;;
 105       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 106       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 107       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 108       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 109       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 110       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 111       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 112       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 113       llvm-gcc)       ;;
 114       test-suite)     ;;
 115       llvm-test)      ;;
 116       poolalloc)      ;;
 117       llvm-poolalloc) ;;
 118       *)
 119         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 120         ;;
 121     esac
 122   fi
 123 done
 124
 125 dnl===-----------------------------------------------------------------------===
 126 dnl===
 127 dnl=== SECTION 2: Architecture, target, and host checks
 128 dnl===
 129 dnl===-----------------------------------------------------------------------===
 130
 131 dnl Check the target for which we're compiling and the host that will do the
 132 dnl compilations. This will tell us which LLVM compiler will be used for
 133 dnl compiling SSA into object code. This needs to be done early because
 134 dnl following tests depend on it.
 135 AC_CANONICAL_TARGET
 136
 137 dnl Determine the platform type and cache its value. This helps us configure
 138 dnl the System library to the correct build platform.
 139 AC_CACHE_CHECK([type of operating system we're going to host on],
 140                [llvm_cv_os_type],
 141 [case $host in
 142   *-*-aix*)
 143     llvm_cv_link_all_option="-Wl,--whole-archive"
 144     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 145     llvm_cv_os_type="AIX"
 146     llvm_cv_platform_type="Unix" ;;
 147   *-*-irix*)
 148     llvm_cv_link_all_option="-Wl,--whole-archive"
 149     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 150     llvm_cv_os_type="IRIX"
 151     llvm_cv_platform_type="Unix" ;;
 152   *-*-cygwin*)
 153     llvm_cv_link_all_option="-Wl,--whole-archive"
 154     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 155     llvm_cv_os_type="Cygwin"
 156     llvm_cv_platform_type="Unix" ;;
 157   *-*-darwin*)
 158     llvm_cv_link_all_option="-Wl,-all_load"
 159     llvm_cv_no_link_all_option="-Wl,-noall_load"
 160     llvm_cv_os_type="Darwin"
 161     llvm_cv_platform_type="Unix" ;;
 162   *-*-freebsd*)
 163     llvm_cv_link_all_option="-Wl,--whole-archive"
 164     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 165     llvm_cv_os_type="FreeBSD"
 166     llvm_cv_platform_type="Unix" ;;
 167   *-*-openbsd*)
 168     llvm_cv_link_all_option="-Wl,--whole-archive"
 169     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 170     llvm_cv_os_type="OpenBSD"
 171     llvm_cv_platform_type="Unix" ;;
 172   *-*-netbsd*)
 173     llvm_cv_link_all_option="-Wl,--whole-archive"
 174     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 175     llvm_cv_os_type="NetBSD"
 176     llvm_cv_platform_type="Unix" ;;
 177   *-*-dragonfly*)
 178     llvm_cv_link_all_option="-Wl,--whole-archive"
 179     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 180     llvm_cv_os_type="DragonFly"
 181     llvm_cv_platform_type="Unix" ;;
 182   *-*-hpux*)
 183     llvm_cv_link_all_option="-Wl,--whole-archive"
 184     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 185     llvm_cv_os_type="HP-UX"
 186     llvm_cv_platform_type="Unix" ;;
 187   *-*-interix*)
 188     llvm_cv_link_all_option="-Wl,--whole-archive"
 189     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 190     llvm_cv_os_type="Interix"
 191     llvm_cv_platform_type="Unix" ;;
 192   *-*-linux*)
 193     llvm_cv_link_all_option="-Wl,--whole-archive"
 194     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 195     llvm_cv_os_type="Linux"
 196     llvm_cv_platform_type="Unix" ;;
 197   *-*-solaris*)
 198     llvm_cv_link_all_option="-Wl,-z,allextract"
 199     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 200     llvm_cv_os_type="SunOS"
 201     llvm_cv_platform_type="Unix" ;;
 202   *-*-auroraux*)
 203     llvm_cv_link_all_option="-Wl,-z,allextract"
 204     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 205     llvm_cv_os_type="AuroraUX"
 206     llvm_cv_platform_type="Unix" ;;
 207   *-*-win32*)
 208     llvm_cv_link_all_option="-Wl,--whole-archive"
 209     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 210     llvm_cv_os_type="Win32"
 211     llvm_cv_platform_type="Win32" ;;
 212   *-*-mingw*)
 213     llvm_cv_link_all_option="-Wl,--whole-archive"
 214     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 215     llvm_cv_os_type="MingW"
 216     llvm_cv_platform_type="Win32" ;;
 217   *-*-haiku*)
 218     llvm_cv_link_all_option="-Wl,--whole-archive"
 219     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 220     llvm_cv_os_type="Haiku"
 221     llvm_cv_platform_type="Unix" ;;
 222   *-unknown-eabi*)
 223     llvm_cv_link_all_option="-Wl,--whole-archive"
 224     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 225     llvm_cv_os_type="Freestanding"
 226     llvm_cv_platform_type="Unix" ;;
 227   *-unknown-elf*)
 228     llvm_cv_link_all_option="-Wl,--whole-archive"
 229     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 230     llvm_cv_os_type="Freestanding"
 231     llvm_cv_platform_type="Unix" ;;
 232   *)
 233     llvm_cv_link_all_option=""
 234     llvm_cv_no_link_all_option=""
 235     llvm_cv_os_type="Unknown"
 236     llvm_cv_platform_type="Unknown" ;;
 237 esac])
 238
 239 AC_CACHE_CHECK([type of operating system we're going to target],
 240                [llvm_cv_target_os_type],
 241 [case $target in
 242   *-*-aix*)
 243     llvm_cv_target_os_type="AIX" ;;
 244   *-*-irix*)
 245     llvm_cv_target_os_type="IRIX" ;;
 246   *-*-cygwin*)
 247     llvm_cv_target_os_type="Cygwin" ;;
 248   *-*-darwin*)
 249     llvm_cv_target_os_type="Darwin" ;;
 250   *-*-freebsd*)
 251     llvm_cv_target_os_type="FreeBSD" ;;
 252   *-*-openbsd*)
 253     llvm_cv_target_os_type="OpenBSD" ;;
 254   *-*-netbsd*)
 255     llvm_cv_target_os_type="NetBSD" ;;
 256   *-*-dragonfly*)
 257     llvm_cv_target_os_type="DragonFly" ;;
 258   *-*-hpux*)
 259     llvm_cv_target_os_type="HP-UX" ;;
 260   *-*-interix*)
 261     llvm_cv_target_os_type="Interix" ;;
 262   *-*-linux*)
 263     llvm_cv_target_os_type="Linux" ;;
 264   *-*-solaris*)
 265     llvm_cv_target_os_type="SunOS" ;;
 266   *-*-auroraux*)
 267     llvm_cv_target_os_type="AuroraUX" ;;
 268   *-*-win32*)
 269     llvm_cv_target_os_type="Win32" ;;
 270   *-*-mingw*)
 271     llvm_cv_target_os_type="MingW" ;;
 272   *-*-haiku*)
 273     llvm_cv_target_os_type="Haiku" ;;
 274   *-unknown-eabi*)
 275     llvm_cv_target_os_type="Freestanding" ;;
 276   *)
 277     llvm_cv_target_os_type="Unknown" ;;
 278 esac])
 279
 280 dnl Make sure we aren't attempting to configure for an unknown system
 281 if test "$llvm_cv_os_type" = "Unknown" ; then
 282   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 283 fi
 284
 285 dnl Set the "OS" Makefile variable based on the platform type so the
 286 dnl makefile can configure itself to specific build hosts
 287 AC_SUBST(OS,$llvm_cv_os_type)
 288 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 289 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 290
 291 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 292 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 293 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 294
 295 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 296 dnl This is used by lib/System to determine the basic kind of implementation
 297 dnl to use.
 298 case $llvm_cv_platform_type in
 299   Unix)
 300     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 301     AC_SUBST(LLVM_ON_UNIX,[1])
 302     AC_SUBST(LLVM_ON_WIN32,[0])
 303     ;;
 304   Win32)
 305     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 306     AC_SUBST(LLVM_ON_UNIX,[0])
 307     AC_SUBST(LLVM_ON_WIN32,[1])
 308     ;;
 309 esac
 310
 311 dnl Determine what our target architecture is and configure accordingly.
 312 dnl This will allow Makefiles to make a distinction between the hardware and
 313 dnl the OS.
 314 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 315 [case $target in
 316   i?86-*)                 llvm_cv_target_arch="x86" ;;
 317   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 318   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 319   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 320   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 321   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 322   mips-*)                 llvm_cv_target_arch="Mips" ;;
 323   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 324   xcore-*)                llvm_cv_target_arch="XCore" ;;
 325   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 326   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 327   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 328   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 329   *)                      llvm_cv_target_arch="Unknown" ;;
 330 esac])
 331
 332 if test "$llvm_cv_target_arch" = "Unknown" ; then
 333   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 334 fi
 335
 336 # Determine the LLVM native architecture for the target
 337 case "$llvm_cv_target_arch" in
 338     x86)     LLVM_NATIVE_ARCH="X86" ;;
 339     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 340     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 341 esac
 342
 343 dnl Define a substitution, ARCH, for the target architecture
 344 AC_SUBST(ARCH,$llvm_cv_target_arch)
 345
 346 dnl Check for the endianness of the target
 347 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 348
 349 dnl Check for build platform executable suffix if we're crosscompiling
 350 if test "$cross_compiling" = yes; then
 351   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 352   AC_BUILD_EXEEXT
 353   ac_build_prefix=${build_alias}-
 354   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 355   if test -z "$BUILD_CXX"; then
 356      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 357      if test -z "$BUILD_CXX"; then
 358        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 359      fi
 360   fi
 361 else
 362   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 363 fi
 364
 365 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 366 dnl that this build is being done from a checkout. This sets up several
 367 dnl defaults for the command line switches. When we build with a CVS directory,
 368 dnl we get a debug with assertions turned on. Without, we assume a source
 369 dnl release and we get an optimized build without assertions.
 370 dnl See --enable-optimized and --enable-assertions below
 371 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 372   cvsbuild="yes"
 373   optimize="no"
 374   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 375 else
 376   cvsbuild="no"
 377   optimize="yes"
 378 fi
 379
 380 dnl===-----------------------------------------------------------------------===
 381 dnl===
 382 dnl=== SECTION 3: Command line arguments for the configure script.
 383 dnl===
 384 dnl===-----------------------------------------------------------------------===
 385
 386 dnl --enable-optimized : check whether they want to do an optimized build:
 387 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 388  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 389 if test ${enableval} = "no" ; then
 390   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 391 else
 392   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 393 fi
 394
 395 dnl --enable-profiling : check whether they want to do a profile build:
 396 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 397  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 398 if test ${enableval} = "no" ; then
 399   AC_SUBST(ENABLE_PROFILING,[[]])
 400 else
 401   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 402 fi
 403
 404 dnl --enable-assertions : check whether they want to turn on assertions or not:
 405 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 406   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 407 if test ${enableval} = "yes" ; then
 408   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 409 else
 410   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 411 fi
 412
 413 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 414 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 415   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 416 if test ${enableval} = "yes" ; then
 417   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 418   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 419 else
 420   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 421   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 422 fi
 423
 424 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 425 AC_ARG_ENABLE(debug-runtime,
 426    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 427 if test ${enableval} = "no" ; then
 428   AC_SUBST(DEBUG_RUNTIME,[[]])
 429 else
 430   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 431 fi
 432
 433 dnl --enable-debug-symbols : should even optimized compiler libraries
 434 dnl have debug symbols?
 435 AC_ARG_ENABLE(debug-symbols,
 436    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 437 if test ${enableval} = "no" ; then
 438   AC_SUBST(DEBUG_SYMBOLS,[[]])
 439 else
 440   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 441 fi
 442
 443 dnl --enable-jit: check whether they want to enable the jit
 444 AC_ARG_ENABLE(jit,
 445   AS_HELP_STRING(--enable-jit,
 446                  [Enable Just In Time Compiling (default is YES)]),,
 447   enableval=default)
 448 if test ${enableval} = "no"
 449 then
 450   AC_SUBST(JIT,[[]])
 451 else
 452   case "$llvm_cv_target_arch" in
 453     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 454     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 455     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 456     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 457     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 458     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 459     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 460     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 461     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 462     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 463     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 464     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 465     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 466     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 467   esac
 468 fi
 469
 470 dnl Allow enablement of doxygen generated documentation
 471 AC_ARG_ENABLE(doxygen,
 472               AS_HELP_STRING([--enable-doxygen],
 473                              [Build doxygen documentation (default is NO)]),,
 474                              enableval=default)
 475 case "$enableval" in
 476   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 477   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 478   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 479   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 480 esac
 481
 482 dnl Allow disablement of threads
 483 AC_ARG_ENABLE(threads,
 484               AS_HELP_STRING([--enable-threads],
 485                              [Use threads if available (default is YES)]),,
 486                              enableval=default)
 487 case "$enableval" in
 488   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 489   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 490   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 491   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 492 esac
 493 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 494
 495 dnl Allow building without position independent code
 496 AC_ARG_ENABLE(pic,
 497   AS_HELP_STRING([--enable-pic],
 498                  [Build LLVM with Position Independent Code (default is YES)]),,
 499                  enableval=default)
 500 case "$enableval" in
 501   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 502   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 503   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 504   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 505 esac
 506 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 507                    [Define if position independent code is enabled])
 508
 509 dnl Allow building a shared library and linking tools against it.
 510 AC_ARG_ENABLE(shared,
 511   AS_HELP_STRING([--enable-shared],
 512                  [Build a shared library and link tools against it (default is NO)]),,
 513                  enableval=default)
 514 case "$enableval" in
 515   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 516   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 517   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 518   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 519 esac
 520
 521 dnl Allow specific targets to be specified for building (or not)
 522 TARGETS_TO_BUILD=""
 523 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 524     [Build specific host targets: all or target1,target2,... Valid targets are:
 525      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu, pic16,
 526      xcore, msp430, systemz, blackfin, cbe, msil, and cpp (default=all)]),,
 527     enableval=all)
 528 if test "$enableval" = host-only ; then
 529   enableval=host
 530 fi
 531 case "$enableval" in
 532   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend MSIL CppBackend MBlaze" ;;
 533   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 534       case "$a_target" in
 535         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 536         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 537         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 538         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 539         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 540         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 541         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 542         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 543         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 544         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 545         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 546         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 547         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 548         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 549         msil)     TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 550         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 551         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 552         host) case "$llvm_cv_target_arch" in
 553             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 554             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 555             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 556             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 557             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 558             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 559             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 560             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 561             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 562             PIC16)       TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 563             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 564             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 565             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 566             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 567             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 568           esac ;;
 569         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 570       esac
 571   done
 572   ;;
 573 esac
 574 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 575
 576 # Determine whether we are building LLVM support for the native architecture.
 577 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 578 for a_target in $TARGETS_TO_BUILD; do
 579   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 580     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 581     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 582       [LLVM architecture name for the native architecture, if available])
 583   fi
 584 done
 585
 586 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 587 # target feature def files.
 588 LLVM_ENUM_TARGETS=""
 589 LLVM_ENUM_ASM_PRINTERS=""
 590 LLVM_ENUM_ASM_PARSERS=""
 591 LLVM_ENUM_DISASSEMBLERS=""
 592 for target_to_build in $TARGETS_TO_BUILD; do
 593   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 594   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 595     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 596   fi
 597   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 598     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 599   fi
 600   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 601     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 602   fi
 603 done
 604 AC_SUBST(LLVM_ENUM_TARGETS)
 605 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 606 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 607 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 608
 609 dnl Prevent the CBackend from using printf("%a") for floating point so older
 610 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 611 dnl can still compile the CBE's output
 612 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 613   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 614   enableval=default)
 615 case "$enableval" in
 616   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 617   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 618   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 619   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 620 esac
 621 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 622                    [Define if CBE is enabled for printf %a output])
 623
 624 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 625 AC_ARG_WITH(llvmgccdir,
 626   AS_HELP_STRING([--with-llvmgccdir],
 627     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 628     withval=default)
 629 case "$withval" in
 630   default) WITH_LLVMGCCDIR=default ;;
 631   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 632   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 633 esac
 634
 635 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 636 AC_ARG_WITH(llvmgcc,
 637   AS_HELP_STRING([--with-llvmgcc],
 638     [Specify location of llvm-gcc driver (default searches PATH)]),
 639     LLVMGCC=$with_llvmgcc
 640       WITH_LLVMGCCDIR="",)
 641
 642 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 643 AC_ARG_WITH(llvmgxx,
 644   AS_HELP_STRING([--with-llvmgxx],
 645     [Specify location of llvm-g++ driver (default searches PATH)]),
 646     LLVMGXX=$with_llvmgxx
 647     WITH_LLVMGCCDIR="",)
 648
 649 if test -n "$LLVMGCC"; then
 650    LLVMGCCCOMMAND="$LLVMGCC"
 651 fi
 652
 653 if test -n "$LLVMGXX"; then
 654    LLVMGXXCOMMAND="$LLVMGXX"
 655 fi
 656
 657 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 658    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 659 fi
 660
 661 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 662    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 663 fi
 664
 665 dnl Allow a specific Clang compiler to be used with this LLVM config.
 666 AC_ARG_WITH(clang,
 667   AS_HELP_STRING([--with-clang],
 668     [Specify location of clang compiler (default is --with-built-clang)]),
 669     [],[with_clang=default])
 670
 671 dnl Enable use of the built Clang.
 672 AC_ARG_WITH(built-clang,
 673   AS_HELP_STRING([--with-built-clang],
 674     [Use the compiled Clang as the LLVM compiler (default=check)]),
 675     [],[with_built_clang=check])
 676
 677 dnl Select the Clang compiler option.
 678 dnl
 679 dnl If --with-clang is given, always honor that; otherwise honor
 680 dnl --with-built-clang, or check if we have the clang sources.
 681 AC_MSG_CHECKING([clang compiler])
 682 WITH_CLANGPATH=""
 683 WITH_BUILT_CLANG=0
 684 if test "$with_clang" != "default"; then
 685    WITH_CLANGPATH="$with_clang"
 686    if ! test -x "$WITH_CLANGPATH"; then
 687      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 688    fi
 689 elif test "$with_built_clang" = "yes"; then
 690    WITH_BUILT_CLANG=1
 691 elif test "$with_built_clang" = "no"; then
 692    WITH_BUILT_CLANG=0
 693 else
 694    if test "$with_built_clang" != "check"; then
 695       AC_MSG_ERROR([invalid value for --with-built-clang.])
 696    fi
 697
 698    if test -f ${srcdir}/tools/clang/README.txt; then
 699      WITH_BUILT_CLANG=1
 700    fi
 701 fi
 702
 703 if ! test -z "$WITH_CLANGPATH"; then
 704    AC_MSG_RESULT([$WITH_CLANGPATH])
 705    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 706 elif test "$WITH_BUILT_CLANG" = "1"; then
 707    AC_MSG_RESULT([built])
 708 else
 709    AC_MSG_RESULT([none])
 710 fi
 711 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 712 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 713 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 714
 715 dnl Override the option to use for optimized builds.
 716 AC_ARG_WITH(optimize-option,
 717   AS_HELP_STRING([--with-optimize-option],
 718                  [Select the compiler options to use for optimized builds]),,
 719                  withval=default)
 720 AC_MSG_CHECKING([optimization flags])
 721 case "$withval" in
 722   default)
 723     case "$llvm_cv_os_type" in
 724     MingW) optimize_option=-O3 ;;
 725     *)     optimize_option=-O2 ;;
 726     esac ;;
 727   *) optimize_option="$withval" ;;
 728 esac
 729 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 730 AC_MSG_RESULT([$optimize_option])
 731
 732 dnl Specify extra build options
 733 AC_ARG_WITH(extra-options,
 734   AS_HELP_STRING([--with-extra-options],
 735                  [Specify additional options to compile LLVM with]),,
 736                  withval=default)
 737 case "$withval" in
 738   default) EXTRA_OPTIONS= ;;
 739   *) EXTRA_OPTIONS=$withval ;;
 740 esac
 741 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 742
 743 dnl Allow specific bindings to be specified for building (or not)
 744 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 745     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 746     enableval=default)
 747 BINDINGS_TO_BUILD=""
 748 case "$enableval" in
 749   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 750   all ) BINDINGS_TO_BUILD="ocaml" ;;
 751   none | no) BINDINGS_TO_BUILD="" ;;
 752   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 753       case "$a_binding" in
 754         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 755         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 756       esac
 757   done
 758   ;;
 759 esac
 760
 761 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 762 dnl script for bindings/ocaml/configure, except that its auto value depends on
 763 dnl OCAMLC, which is found here to support tests.
 764 AC_ARG_WITH([ocaml-libdir],
 765   [AS_HELP_STRING([--with-ocaml-libdir],
 766     [Specify install location for ocaml bindings (default is stdlib)])],
 767   [],
 768   [withval=auto])
 769 case "$withval" in
 770   auto) with_ocaml_libdir="$withval" ;;
 771   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 772   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 773 esac
 774
 775 AC_ARG_WITH(c-include-dirs,
 776   AS_HELP_STRING([--with-c-include-dirs],
 777     [Colon separated list of directories clang will search for headers]),,
 778     withval="")
 779 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 780                    [Directories clang will search for headers])
 781
 782 AC_ARG_WITH(cxx-include-root,
 783   AS_HELP_STRING([--with-cxx-include-root],
 784     [Directory with the libstdc++ headers.]),,
 785     withval="")
 786 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 787                    [Directory with the libstdc++ headers.])
 788
 789 AC_ARG_WITH(cxx-include-arch,
 790   AS_HELP_STRING([--with-cxx-include-arch],
 791     [Architecture of the libstdc++ headers.]),,
 792     withval="")
 793 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 794                    [Arch the libstdc++ headers.])
 795
 796 AC_ARG_WITH(cxx-include-32bit-dir,
 797   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 798     [32 bit multilib dir.]),,
 799     withval="")
 800 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 801                    [32 bit multilib directory.])
 802
 803 AC_ARG_WITH(cxx-include-64bit-dir,
 804   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 805     [64 bit multilib directory.]),,
 806     withval="")
 807 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 808                    [64 bit multilib directory.])
 809
 810 dnl Allow linking of LLVM with GPLv3 binutils code.
 811 AC_ARG_WITH(binutils-include,
 812   AS_HELP_STRING([--with-binutils-include],
 813     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 814   withval=default)
 815 case "$withval" in
 816   default) WITH_BINUTILS_INCDIR=default ;;
 817   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 818   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 819 esac
 820 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 821   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 822   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 823      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 824      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 825   fi
 826 fi
 827
 828 dnl --enable-libffi : check whether the user wants to turn off libffi:
 829 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 830   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 831   [case "$enableval" in
 832     yes) llvm_cv_enable_libffi="yes" ;;
 833     no)  llvm_cv_enable_libffi="no"  ;;
 834     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 835   esac],
 836   llvm_cv_enable_libffi=no)
 837
 838 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 839 if test "$llvm_cv_os_type" = "Win32" ; then
 840    llvmc_dynamic="yes"
 841 else
 842    llvmc_dynamic="no"
 843 fi
 844
 845 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 846 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 847 --enable-llvmc-dynamic,
 848 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 849 enableval=$llvmc_dynamic)
 850 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 851    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 852 else
 853    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 854 fi
 855
 856 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 857 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 858 --enable-llvmc-dynamic-plugins,
 859 [Enable dynamic LLVMC plugins (default is YES)]),,
 860 enableval=yes)
 861 if test ${enableval} = "yes" ; then
 862    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 863 else
 864    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 865 fi
 866
 867 dnl===-----------------------------------------------------------------------===
 868 dnl===
 869 dnl=== SECTION 4: Check for programs we need and that they are the right version
 870 dnl===
 871 dnl===-----------------------------------------------------------------------===
 872
 873 dnl Check for compilation tools
 874 AC_PROG_CPP
 875 AC_PROG_CC(gcc)
 876 AC_PROG_CXX(g++)
 877
 878 AC_PROG_NM
 879 AC_SUBST(NM)
 880
 881 dnl Check for the tools that the makefiles require
 882 AC_CHECK_GNU_MAKE
 883 AC_PROG_LN_S
 884 AC_PATH_PROG(CMP, [cmp], [cmp])
 885 AC_PATH_PROG(CP, [cp], [cp])
 886 AC_PATH_PROG(DATE, [date], [date])
 887 AC_PATH_PROG(FIND, [find], [find])
 888 AC_PATH_PROG(GREP, [grep], [grep])
 889 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 890 AC_PATH_PROG(MV,   [mv],   [mv])
 891 AC_PROG_RANLIB
 892 AC_CHECK_TOOL(AR, ar, false)
 893 AC_PATH_PROG(RM,   [rm],   [rm])
 894 AC_PATH_PROG(SED,  [sed],  [sed])
 895 AC_PATH_PROG(TAR,  [tar],  [gtar])
 896 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 897
 898 dnl Looking for misc. graph plotting software
 899 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 900 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 901   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 902   dnl If we're targeting for mingw we should emit windows paths, not msys
 903   if test "$llvm_cv_os_type" = "MingW" ; then
 904     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 905   fi
 906   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 907    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 908 fi
 909 AC_PATH_PROG(DOT, [dot], [echo dot])
 910 if test "$DOT" != "echo dot" ; then
 911   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 912   dnl If we're targeting for mingw we should emit windows paths, not msys
 913   if test "$llvm_cv_os_type" = "MingW" ; then
 914     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 915   fi
 916   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 917    [Define to path to dot program if found or 'echo dot' otherwise])
 918 fi
 919 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 920 if test "$FDP" != "echo fdp" ; then
 921   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 922   dnl If we're targeting for mingw we should emit windows paths, not msys
 923   if test "$llvm_cv_os_type" = "MingW" ; then
 924     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 925   fi
 926   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 927    [Define to path to fdp program if found or 'echo fdp' otherwise])
 928 fi
 929 AC_PATH_PROG(NEATO, [neato], [echo neato])
 930 if test "$NEATO" != "echo neato" ; then
 931   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 932   dnl If we're targeting for mingw we should emit windows paths, not msys
 933   if test "$llvm_cv_os_type" = "MingW" ; then
 934     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 935   fi
 936   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 937    [Define to path to neato program if found or 'echo neato' otherwise])
 938 fi
 939 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 940 if test "$TWOPI" != "echo twopi" ; then
 941   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 942   dnl If we're targeting for mingw we should emit windows paths, not msys
 943   if test "$llvm_cv_os_type" = "MingW" ; then
 944     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 945   fi
 946   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 947    [Define to path to twopi program if found or 'echo twopi' otherwise])
 948 fi
 949 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 950 if test "$CIRCO" != "echo circo" ; then
 951   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 952   dnl If we're targeting for mingw we should emit windows paths, not msys
 953   if test "$llvm_cv_os_type" = "MingW" ; then
 954     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 955   fi
 956   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 957    [Define to path to circo program if found or 'echo circo' otherwise])
 958 fi
 959 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 960 if test "$GV" != "echo gv" ; then
 961   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 962   dnl If we're targeting for mingw we should emit windows paths, not msys
 963   if test "$llvm_cv_os_type" = "MingW" ; then
 964     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 965   fi
 966   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 967    [Define to path to gv program if found or 'echo gv' otherwise])
 968 fi
 969 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 970 if test "$DOTTY" != "echo dotty" ; then
 971   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 972   dnl If we're targeting for mingw we should emit windows paths, not msys
 973   if test "$llvm_cv_os_type" = "MingW" ; then
 974     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 975   fi
 976   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 977    [Define to path to dotty program if found or 'echo dotty' otherwise])
 978 fi
 979
 980 dnl Look for a sufficiently recent version of Perl.
 981 LLVM_PROG_PERL([5.006])
 982 AC_SUBST(PERL)
 983 if test x"$PERL" = xnone; then
 984    AC_SUBST(HAVE_PERL,0)
 985    AC_MSG_ERROR([perl is required but was not found, please install it])
 986 else
 987    AC_SUBST(HAVE_PERL,1)
 988 fi
 989
 990 dnl Find the install program
 991 AC_PROG_INSTALL
 992
 993 dnl Checks for documentation and testing tools that we can do without. If these
 994 dnl are not found then they are set to "true" which always succeeds but does
 995 dnl nothing. This just lets the build output show that we could have done
 996 dnl something if the tool was available.
 997 AC_PATH_PROG(BZIP2, [bzip2])
 998 AC_PATH_PROG(DOXYGEN, [doxygen])
 999 AC_PATH_PROG(GROFF, [groff])
1000 AC_PATH_PROG(GZIP, [gzip])
1001 AC_PATH_PROG(POD2HTML, [pod2html])
1002 AC_PATH_PROG(POD2MAN, [pod2man])
1003 AC_PATH_PROG(RUNTEST, [runtest])
1004 DJ_AC_PATH_TCLSH
1005 AC_PATH_PROG(ZIP, [zip])
1006 AC_PATH_PROGS(OCAMLC, [ocamlc])
1007 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1008 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1009 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1010 AC_PATH_PROGS(GAS, [gas as])
1011
1012 dnl Determine whether the linker supports the -R option.
1013 AC_LINK_USE_R
1014
1015 dnl Determine whether the linker supports the -export-dynamic option.
1016 AC_LINK_EXPORT_DYNAMIC
1017
1018 dnl Check for libtool and the library that has dlopen function (which must come
1019 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1020 dnl libtool).
1021 AC_LIBTOOL_DLOPEN
1022 AC_LIB_LTDL
1023
1024 if test "$WITH_LLVMGCCDIR" = "default" ; then
1025   LLVMGCC="llvm-gcc${EXEEXT}"
1026   LLVMGXX="llvm-g++${EXEEXT}"
1027   LLVMGCCCOMMAND="$LLVMGCC"
1028   LLVMGXXCOMMAND="$LLVMGXX"
1029   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1030   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1031   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
1032   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
1033 else
1034   if test -z "$LLVMGCC"; then
1035     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
1036     LLVMGCCCOMMAND="$LLVMGCC"
1037   fi
1038   if test -z "$LLVMGXX"; then
1039     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1040     LLVMGXXCOMMAND="$LLVMGXX"
1041   fi
1042
1043   AC_SUBST(LLVMGCC,$LLVMGCC)
1044   AC_SUBST(LLVMGXX,$LLVMGXX)
1045   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1046   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1047 fi
1048
1049 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1050 dnl found, otherwise clang if available.
1051 AC_ARG_WITH(llvmcc,
1052   AS_HELP_STRING([--with-llvmcc=<name>],
1053     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1054     [],[with_llvmcc=check])
1055 AC_MSG_CHECKING([LLVM capable compiler])
1056 if test "$with_llvmcc" != "check"; then
1057    if (test "$with_llvmcc" != "llvm-gcc" &&
1058        test "$with_llvmcc" != "clang" &&
1059        test "$with_llvmcc" != "none"); then
1060       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1061    fi
1062    WITH_LLVMCC="$with_llvmcc"
1063 elif test -n "$LLVMGCC"; then
1064    WITH_LLVMCC=llvm-gcc
1065 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1066    WITH_LLVMCC=clang
1067 else
1068    WITH_LLVMCC=none
1069 fi
1070 AC_MSG_RESULT([$WITH_LLVMCC])
1071 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1072
1073 AC_MSG_CHECKING([tool compatibility])
1074
1075 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1076 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1077 dnl to support those options.
1078 dnl "icc" emits gcc signatures
1079 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1080 ICC=no
1081 IXX=no
1082 case $CC in
1083   icc*|icpc*)
1084     ICC=yes
1085     IXX=yes
1086     ;;
1087    *)
1088     ;;
1089 esac
1090
1091 if test "$GCC" != "yes" && test "$ICC" != "yes"
1092 then
1093   AC_MSG_ERROR([gcc|icc required but not found])
1094 fi
1095
1096 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
1097 if test "$GXX" != "yes" && test "$IXX" != "yes"
1098 then
1099   AC_MSG_ERROR([g++|icc required but not found])
1100 fi
1101
1102 dnl Verify that GCC is version 3.0 or higher
1103 if test "$GCC" = "yes"
1104 then
1105   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1106 #error Unsupported GCC version
1107 #endif
1108 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1109 fi
1110
1111 dnl Check for GNU Make.  We use its extensions, so don't build without it
1112 if test -z "$llvm_cv_gnu_make_command"
1113 then
1114   AC_MSG_ERROR([GNU Make required but not found])
1115 fi
1116
1117 dnl Tool compatibility is okay if we make it here.
1118 AC_MSG_RESULT([ok])
1119
1120 dnl Check optional compiler flags.
1121 AC_MSG_CHECKING([optional compiler flags])
1122 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1123 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1124 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1125
1126 dnl===-----------------------------------------------------------------------===
1127 dnl===
1128 dnl=== SECTION 5: Check for libraries
1129 dnl===
1130 dnl===-----------------------------------------------------------------------===
1131
1132 AC_CHECK_LIB(m,sin)
1133 if test "$llvm_cv_os_type" = "MingW" ; then
1134   AC_CHECK_LIB(imagehlp, main)
1135   AC_CHECK_LIB(psapi, main)
1136 fi
1137
1138 dnl dlopen() is required for plugin support.
1139 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1140                [Define if dlopen() is available on this platform.]),
1141                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1142
1143 dnl libffi is optional; used to call external functions from the interpreter
1144 if test "$llvm_cv_enable_libffi" = "yes" ; then
1145   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1146                  [Define if libffi is available on this platform.]),
1147                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1148 fi
1149
1150 dnl mallinfo is optional; the code can compile (minus features) without it
1151 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1152                [Define if mallinfo() is available on this platform.]))
1153
1154 dnl pthread locking functions are optional - but llvm will not be thread-safe
1155 dnl without locks.
1156 if test "$ENABLE_THREADS" -eq 1 ; then
1157   AC_CHECK_LIB(pthread, pthread_mutex_init)
1158   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1159                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1160                            [Have pthread_mutex_lock]))
1161   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1162                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1163                  [Have pthread_rwlock_init]))
1164   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1165                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1166                  [Have pthread_getspecific]))
1167 fi
1168
1169 dnl Allow extra x86-disassembler library
1170 AC_ARG_WITH(udis86,
1171   AS_HELP_STRING([--with-udis86=<path>],
1172     [Use udis86 external x86 disassembler library]),
1173     [
1174       AC_SUBST(USE_UDIS86, [1])
1175       case "$withval" in
1176         /usr/lib|yes) ;;
1177         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1178       esac
1179       AC_CHECK_LIB(udis86, ud_init, [], [
1180         echo "Error! You need to have libudis86 around."
1181         exit -1
1182       ])
1183     ],
1184     AC_SUBST(USE_UDIS86, [0]))
1185 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1186                    [Define if use udis86 library])
1187
1188 dnl Allow OProfile support for JIT output.
1189 AC_ARG_WITH(oprofile,
1190   AS_HELP_STRING([--with-oprofile=<prefix>],
1191     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1192     [
1193       AC_SUBST(USE_OPROFILE, [1])
1194       case "$withval" in
1195         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1196         no) llvm_cv_oppath=
1197             AC_SUBST(USE_OPROFILE, [0]) ;;
1198         *) llvm_cv_oppath="${withval}/lib/oprofile"
1199            CPPFLAGS="-I${withval}/include";;
1200       esac
1201       if test -n "$llvm_cv_oppath" ; then
1202         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1203         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1204         dnl libbfd is not included properly in libopagent in some Debian
1205         dnl versions.  If libbfd isn't found at all, we assume opagent works
1206         dnl anyway.
1207         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1208         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1209           echo "Error! You need to have libopagent around."
1210           exit -1
1211         ])
1212         AC_CHECK_HEADER([opagent.h], [], [
1213           echo "Error! You need to have opagent.h around."
1214           exit -1
1215           ])
1216       fi
1217     ],
1218     [
1219       AC_SUBST(USE_OPROFILE, [0])
1220     ])
1221 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1222                    [Define if we have the oprofile JIT-support library])
1223
1224 dnl===-----------------------------------------------------------------------===
1225 dnl===
1226 dnl=== SECTION 6: Check for header files
1227 dnl===
1228 dnl===-----------------------------------------------------------------------===
1229
1230 dnl First, use autoconf provided macros for specific headers that we need
1231 dnl We don't check for ancient stuff or things that are guaranteed to be there
1232 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1233 dnl Generally we're looking for POSIX headers.
1234 AC_HEADER_DIRENT
1235 AC_HEADER_MMAP_ANONYMOUS
1236 AC_HEADER_STAT
1237 AC_HEADER_STDC
1238 AC_HEADER_SYS_WAIT
1239 AC_HEADER_TIME
1240
1241 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1242 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1243 AC_CHECK_HEADERS([utime.h windows.h])
1244 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1245 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1246 AC_CHECK_HEADERS([valgrind/valgrind.h])
1247 if test "$ENABLE_THREADS" -eq 1 ; then
1248   AC_CHECK_HEADERS(pthread.h,
1249                    AC_SUBST(HAVE_PTHREAD, 1),
1250                    AC_SUBST(HAVE_PTHREAD, 0))
1251 else
1252   AC_SUBST(HAVE_PTHREAD, 0)
1253 fi
1254
1255 dnl Try to find ffi.h.
1256 if test "$llvm_cv_enable_libffi" = "yes" ; then
1257   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1258 fi
1259
1260 dnl===-----------------------------------------------------------------------===
1261 dnl===
1262 dnl=== SECTION 7: Check for types and structures
1263 dnl===
1264 dnl===-----------------------------------------------------------------------===
1265
1266 AC_HUGE_VAL_CHECK
1267 AC_TYPE_PID_T
1268 AC_TYPE_SIZE_T
1269 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1270 AC_STRUCT_TM
1271 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1272 AC_CHECK_TYPES([uint64_t],,
1273          AC_CHECK_TYPES([u_int64_t],,
1274          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1275
1276 dnl===-----------------------------------------------------------------------===
1277 dnl===
1278 dnl=== SECTION 8: Check for specific functions needed
1279 dnl===
1280 dnl===-----------------------------------------------------------------------===
1281
1282 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1283 AC_CHECK_FUNCS([powf fmodf strtof round ])
1284 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1285 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1286 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup ])
1287 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1288 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1289 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1290 AC_C_PRINTF_A
1291 AC_FUNC_RAND48
1292
1293 dnl Check for variations in the Standard C++ library and STL. These macros are
1294 dnl provided by LLVM in the autoconf/m4 directory.
1295 AC_FUNC_ISNAN
1296 AC_FUNC_ISINF
1297
1298 dnl Check for mmap support.We also need to know if /dev/zero is required to
1299 dnl be opened for allocating RWX memory.
1300 dnl Make sure we aren't attempting to configure for an unknown system
1301 if test "$llvm_cv_platform_type" = "Unix" ; then
1302   AC_FUNC_MMAP
1303   AC_FUNC_MMAP_FILE
1304   AC_NEED_DEV_ZERO_FOR_MMAP
1305
1306   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1307   then
1308     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1309   fi
1310   if test "$ac_cv_func_mmap_file" = "no"
1311   then
1312     AC_MSG_WARN([mmap() of files required but not found])
1313   fi
1314 fi
1315
1316 dnl atomic builtins are required for threading support.
1317 AC_MSG_CHECKING(for GCC atomic builtins)
1318 AC_LINK_IFELSE(
1319   AC_LANG_SOURCE(
1320     [[int main() {
1321         volatile unsigned long val = 1;
1322         __sync_synchronize();
1323         __sync_val_compare_and_swap(&val, 1, 0);
1324         __sync_add_and_fetch(&val, 1);
1325         __sync_sub_and_fetch(&val, 1);
1326         return 0;
1327       }
1328     ]]),
1329   AC_MSG_RESULT(yes)
1330   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1331   AC_MSG_RESULT(no)
1332   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1333   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1334
1335
1336 dnl===-----------------------------------------------------------------------===
1337 dnl===
1338 dnl=== SECTION 9: Additional checks, variables, etc.
1339 dnl===
1340 dnl===-----------------------------------------------------------------------===
1341
1342 dnl Handle 32-bit linux systems running a 64-bit kernel.
1343 dnl This has to come after section 4 because it invokes the compiler.
1344 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1345   AC_IS_LINUX_MIXED
1346   if test "$llvm_cv_linux_mixed" = "yes"; then
1347     llvm_cv_target_arch="x86"
1348     ARCH="x86"
1349   fi
1350 fi
1351
1352 dnl Check, whether __dso_handle is present
1353 AC_CHECK_FUNCS([__dso_handle])
1354
1355 dnl See if the llvm-gcc executable can compile to LLVM assembly
1356 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1357 [llvm_cv_llvmgcc_sanity="no"
1358 if test -x "$LLVMGCC" ; then
1359   cp /dev/null conftest.c
1360   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1361       grep 'target datalayout =' > /dev/null 2>&1
1362   if test $? -eq 0 ; then
1363     llvm_cv_llvmgcc_sanity="yes"
1364   fi
1365   rm conftest.c
1366 fi])
1367
1368 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1369 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1370   AC_MSG_CHECKING([llvm-gcc component support])
1371   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1372   AC_SUBST(LLVMCC1,$llvmcc1path)
1373   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1374   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1375   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1376   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1377   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1378   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1379   AC_MSG_RESULT([ok])
1380 fi
1381
1382 dnl Propagate the shared library extension that the libltdl checks did to
1383 dnl the Makefiles so we can use it there too
1384 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1385
1386 dnl Propagate the run-time library path variable that the libltdl
1387 dnl checks found to the Makefiles so we can use it there too
1388 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1389
1390 # Translate the various configuration directories and other basic
1391 # information into substitutions that will end up in Makefile.config.in
1392 # that these configured values can be used by the makefiles
1393 if test "${prefix}" = "NONE" ; then
1394   prefix="/usr/local"
1395 fi
1396 eval LLVM_PREFIX="${prefix}";
1397 eval LLVM_BINDIR="${prefix}/bin";
1398 eval LLVM_LIBDIR="${prefix}/lib";
1399 eval LLVM_DATADIR="${prefix}/share/llvm";
1400 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1401 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1402 eval LLVM_INCLUDEDIR="${prefix}/include";
1403 eval LLVM_INFODIR="${prefix}/info";
1404 eval LLVM_MANDIR="${prefix}/man";
1405 LLVM_CONFIGTIME=`date`
1406 AC_SUBST(LLVM_PREFIX)
1407 AC_SUBST(LLVM_BINDIR)
1408 AC_SUBST(LLVM_LIBDIR)
1409 AC_SUBST(LLVM_DATADIR)
1410 AC_SUBST(LLVM_DOCSDIR)
1411 AC_SUBST(LLVM_ETCDIR)
1412 AC_SUBST(LLVM_INCLUDEDIR)
1413 AC_SUBST(LLVM_INFODIR)
1414 AC_SUBST(LLVM_MANDIR)
1415 AC_SUBST(LLVM_CONFIGTIME)
1416
1417 # Place the various directores into the config.h file as #defines so that we
1418 # can know about the installation paths within LLVM.
1419 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1420                    [Installation prefix directory])
1421 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1422                    [Installation directory for binary executables])
1423 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1424                    [Installation directory for libraries])
1425 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1426                    [Installation directory for data files])
1427 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1428                    [Installation directory for documentation])
1429 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1430                    [Installation directory for config files])
1431 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1432                    [Installation directory for include files])
1433 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1434                    [Installation directory for .info files])
1435 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1436                    [Installation directory for man pages])
1437 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1438                    [Time at which LLVM was configured])
1439 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1440                    [Host triple we were built on])
1441
1442 # Determine which bindings to build.
1443 if test "$BINDINGS_TO_BUILD" = auto ; then
1444   BINDINGS_TO_BUILD=""
1445   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1446     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1447   fi
1448 fi
1449 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1450
1451 # This isn't really configurey, but it avoids having to repeat the list in
1452 # other files.
1453 AC_SUBST(ALL_BINDINGS,ocaml)
1454
1455 # Do any work necessary to ensure that bindings have what they need.
1456 binding_prereqs_failed=0
1457 for a_binding in $BINDINGS_TO_BUILD ; do
1458   case "$a_binding" in
1459   ocaml)
1460     if test "x$OCAMLC" = x ; then
1461       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1462       binding_prereqs_failed=1
1463     fi
1464     if test "x$OCAMLDEP" = x ; then
1465       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1466       binding_prereqs_failed=1
1467     fi
1468     if test "x$OCAMLOPT" = x ; then
1469       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1470       dnl ocamlopt is optional!
1471     fi
1472     if test "x$with_ocaml_libdir" != xauto ; then
1473       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1474     else
1475       ocaml_stdlib="`"$OCAMLC" -where`"
1476       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1477       then
1478         # ocaml stdlib is beneath our prefix; use stdlib
1479         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1480       else
1481         # ocaml stdlib is outside our prefix; use libdir/ocaml
1482         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1483       fi
1484     fi
1485     ;;
1486   esac
1487 done
1488 if test "$binding_prereqs_failed" = 1 ; then
1489   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1490 fi
1491
1492 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1493 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1494
1495 dnl Determine linker rpath flag
1496 if test "$llvm_cv_link_use_r" = "yes" ; then
1497   RPATH="-Wl,-R"
1498 else
1499   RPATH="-Wl,-rpath"
1500 fi
1501 AC_SUBST(RPATH)
1502
1503 dnl Determine linker rdynamic flag
1504 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1505   RDYNAMIC="-Wl,-export-dynamic"
1506 else
1507   RDYNAMIC=""
1508 fi
1509 AC_SUBST(RDYNAMIC)
1510
1511 dnl===-----------------------------------------------------------------------===
1512 dnl===
1513 dnl=== SECTION 10: Specify the output files and generate it
1514 dnl===
1515 dnl===-----------------------------------------------------------------------===
1516
1517 dnl Configure header files
1518 dnl WARNING: dnl If you add or remove any of the following config headers, then
1519 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1520 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1521 dnl files can be updated automatically when their *.in sources change.
1522 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1523 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1524 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1525 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1526 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1527 AC_CONFIG_HEADERS([include/llvm/System/DataTypes.h])
1528
1529 dnl Configure the makefile's configuration data
1530 AC_CONFIG_FILES([Makefile.config])
1531
1532 dnl Configure the RPM spec file for LLVM
1533 AC_CONFIG_FILES([llvm.spec])
1534
1535 dnl Configure doxygen's configuration file
1536 AC_CONFIG_FILES([docs/doxygen.cfg])
1537
1538 dnl Configure llvmc's Base plugin
1539 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1540
1541 dnl Do the first stage of configuration for llvm-config.in.
1542 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1543
1544 dnl Do special configuration of Makefiles
1545 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1546 AC_CONFIG_MAKEFILE(Makefile)
1547 AC_CONFIG_MAKEFILE(Makefile.common)
1548 AC_CONFIG_MAKEFILE(examples/Makefile)
1549 AC_CONFIG_MAKEFILE(lib/Makefile)
1550 AC_CONFIG_MAKEFILE(runtime/Makefile)
1551 AC_CONFIG_MAKEFILE(test/Makefile)
1552 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1553 AC_CONFIG_MAKEFILE(unittests/Makefile)
1554 AC_CONFIG_MAKEFILE(tools/Makefile)
1555 AC_CONFIG_MAKEFILE(utils/Makefile)
1556 AC_CONFIG_MAKEFILE(projects/Makefile)
1557 AC_CONFIG_MAKEFILE(bindings/Makefile)
1558 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1559
1560 dnl Finally, crank out the output
1561 AC_OUTPUT