autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.8svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65
  66 dnl
  67 dnl One tricky part of doing this is that some projects depend upon other
  68 dnl projects.  For example, several projects rely upon the LLVM test suite.
  69 dnl We want to configure those projects first so that their object trees are
  70 dnl created before running the configure scripts of projects that depend upon
  71 dnl them.
  72 dnl
  73
  74 dnl Several projects use llvm-gcc, so configure that first
  75 if test -d ${srcdir}/projects/llvm-gcc ; then
  76   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  77 fi
  78
  79 dnl Several projects use the LLVM test suite, so configure it next.
  80 if test -d ${srcdir}/projects/test-suite ; then
  81   AC_CONFIG_SUBDIRS([projects/test-suite])
  82 fi
  83
  84 dnl llvm-test is the old name of the test-suite, kept here for backwards
  85 dnl compatibility
  86 if test -d ${srcdir}/projects/llvm-test ; then
  87   AC_CONFIG_SUBDIRS([projects/llvm-test])
  88 fi
  89
  90 dnl Some projects use poolalloc; configure that next
  91 if test -d ${srcdir}/projects/poolalloc ; then
  92   AC_CONFIG_SUBDIRS([projects/poolalloc])
  93 fi
  94
  95 if test -d ${srcdir}/projects/llvm-poolalloc ; then
  96   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
  97 fi
  98
  99 dnl Check for all other projects
 100 for i in `ls ${srcdir}/projects`
 101 do
 102   if test -d ${srcdir}/projects/${i} ; then
 103     case ${i} in
 104       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 105       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 106       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 107       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 108       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 109       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 110       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 111       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 112       llvm-gcc)       ;;
 113       test-suite)     ;;
 114       llvm-test)      ;;
 115       poolalloc)      ;;
 116       llvm-poolalloc) ;;
 117       *)
 118         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 119         ;;
 120     esac
 121   fi
 122 done
 123
 124 dnl===-----------------------------------------------------------------------===
 125 dnl===
 126 dnl=== SECTION 2: Architecture, target, and host checks
 127 dnl===
 128 dnl===-----------------------------------------------------------------------===
 129
 130 dnl Check the target for which we're compiling and the host that will do the
 131 dnl compilations. This will tell us which LLVM compiler will be used for
 132 dnl compiling SSA into object code. This needs to be done early because
 133 dnl following tests depend on it.
 134 AC_CANONICAL_TARGET
 135
 136 dnl Determine the platform type and cache its value. This helps us configure
 137 dnl the System library to the correct build platform.
 138 AC_CACHE_CHECK([type of operating system we're going to host on],
 139                [llvm_cv_os_type],
 140 [case $host in
 141   *-*-aix*)
 142     llvm_cv_link_all_option="-Wl,--whole-archive"
 143     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 144     llvm_cv_os_type="AIX"
 145     llvm_cv_platform_type="Unix" ;;
 146   *-*-irix*)
 147     llvm_cv_link_all_option="-Wl,--whole-archive"
 148     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 149     llvm_cv_os_type="IRIX"
 150     llvm_cv_platform_type="Unix" ;;
 151   *-*-cygwin*)
 152     llvm_cv_link_all_option="-Wl,--whole-archive"
 153     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 154     llvm_cv_os_type="Cygwin"
 155     llvm_cv_platform_type="Unix" ;;
 156   *-*-darwin*)
 157     llvm_cv_link_all_option="-Wl,-all_load"
 158     llvm_cv_no_link_all_option="-Wl,-noall_load"
 159     llvm_cv_os_type="Darwin"
 160     llvm_cv_platform_type="Unix" ;;
 161   *-*-minix*)
 162     llvm_cv_link_all_option="-Wl,-all_load"
 163     llvm_cv_no_link_all_option="-Wl,-noall_load"
 164     llvm_cv_os_type="Minix"
 165     llvm_cv_platform_type="Unix" ;;
 166   *-*-freebsd*)
 167     llvm_cv_link_all_option="-Wl,--whole-archive"
 168     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 169     llvm_cv_os_type="FreeBSD"
 170     llvm_cv_platform_type="Unix" ;;
 171   *-*-openbsd*)
 172     llvm_cv_link_all_option="-Wl,--whole-archive"
 173     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 174     llvm_cv_os_type="OpenBSD"
 175     llvm_cv_platform_type="Unix" ;;
 176   *-*-netbsd*)
 177     llvm_cv_link_all_option="-Wl,--whole-archive"
 178     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 179     llvm_cv_os_type="NetBSD"
 180     llvm_cv_platform_type="Unix" ;;
 181   *-*-dragonfly*)
 182     llvm_cv_link_all_option="-Wl,--whole-archive"
 183     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 184     llvm_cv_os_type="DragonFly"
 185     llvm_cv_platform_type="Unix" ;;
 186   *-*-hpux*)
 187     llvm_cv_link_all_option="-Wl,--whole-archive"
 188     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 189     llvm_cv_os_type="HP-UX"
 190     llvm_cv_platform_type="Unix" ;;
 191   *-*-interix*)
 192     llvm_cv_link_all_option="-Wl,--whole-archive"
 193     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 194     llvm_cv_os_type="Interix"
 195     llvm_cv_platform_type="Unix" ;;
 196   *-*-linux*)
 197     llvm_cv_link_all_option="-Wl,--whole-archive"
 198     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 199     llvm_cv_os_type="Linux"
 200     llvm_cv_platform_type="Unix" ;;
 201   *-*-solaris*)
 202     llvm_cv_link_all_option="-Wl,-z,allextract"
 203     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 204     llvm_cv_os_type="SunOS"
 205     llvm_cv_platform_type="Unix" ;;
 206   *-*-auroraux*)
 207     llvm_cv_link_all_option="-Wl,-z,allextract"
 208     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 209     llvm_cv_os_type="AuroraUX"
 210     llvm_cv_platform_type="Unix" ;;
 211   *-*-win32*)
 212     llvm_cv_link_all_option="-Wl,--whole-archive"
 213     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 214     llvm_cv_os_type="Win32"
 215     llvm_cv_platform_type="Win32" ;;
 216   *-*-mingw*)
 217     llvm_cv_link_all_option="-Wl,--whole-archive"
 218     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 219     llvm_cv_os_type="MingW"
 220     llvm_cv_platform_type="Win32" ;;
 221   *-*-haiku*)
 222     llvm_cv_link_all_option="-Wl,--whole-archive"
 223     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 224     llvm_cv_os_type="Haiku"
 225     llvm_cv_platform_type="Unix" ;;
 226   *-unknown-eabi*)
 227     llvm_cv_link_all_option="-Wl,--whole-archive"
 228     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 229     llvm_cv_os_type="Freestanding"
 230     llvm_cv_platform_type="Unix" ;;
 231   *-unknown-elf*)
 232     llvm_cv_link_all_option="-Wl,--whole-archive"
 233     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 234     llvm_cv_os_type="Freestanding"
 235     llvm_cv_platform_type="Unix" ;;
 236   *)
 237     llvm_cv_link_all_option=""
 238     llvm_cv_no_link_all_option=""
 239     llvm_cv_os_type="Unknown"
 240     llvm_cv_platform_type="Unknown" ;;
 241 esac])
 242
 243 AC_CACHE_CHECK([type of operating system we're going to target],
 244                [llvm_cv_target_os_type],
 245 [case $target in
 246   *-*-aix*)
 247     llvm_cv_target_os_type="AIX" ;;
 248   *-*-irix*)
 249     llvm_cv_target_os_type="IRIX" ;;
 250   *-*-cygwin*)
 251     llvm_cv_target_os_type="Cygwin" ;;
 252   *-*-darwin*)
 253     llvm_cv_target_os_type="Darwin" ;;
 254   *-*-minix*)
 255     llvm_cv_target_os_type="Minix" ;;
 256   *-*-freebsd*)
 257     llvm_cv_target_os_type="FreeBSD" ;;
 258   *-*-openbsd*)
 259     llvm_cv_target_os_type="OpenBSD" ;;
 260   *-*-netbsd*)
 261     llvm_cv_target_os_type="NetBSD" ;;
 262   *-*-dragonfly*)
 263     llvm_cv_target_os_type="DragonFly" ;;
 264   *-*-hpux*)
 265     llvm_cv_target_os_type="HP-UX" ;;
 266   *-*-interix*)
 267     llvm_cv_target_os_type="Interix" ;;
 268   *-*-linux*)
 269     llvm_cv_target_os_type="Linux" ;;
 270   *-*-solaris*)
 271     llvm_cv_target_os_type="SunOS" ;;
 272   *-*-auroraux*)
 273     llvm_cv_target_os_type="AuroraUX" ;;
 274   *-*-win32*)
 275     llvm_cv_target_os_type="Win32" ;;
 276   *-*-mingw*)
 277     llvm_cv_target_os_type="MingW" ;;
 278   *-*-haiku*)
 279     llvm_cv_target_os_type="Haiku" ;;
 280   *-unknown-eabi*)
 281     llvm_cv_target_os_type="Freestanding" ;;
 282   *)
 283     llvm_cv_target_os_type="Unknown" ;;
 284 esac])
 285
 286 dnl Make sure we aren't attempting to configure for an unknown system
 287 if test "$llvm_cv_os_type" = "Unknown" ; then
 288   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 289 fi
 290
 291 dnl Set the "OS" Makefile variable based on the platform type so the
 292 dnl makefile can configure itself to specific build hosts
 293 AC_SUBST(OS,$llvm_cv_os_type)
 294 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 295 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 296
 297 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 298 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 299 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 300
 301 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 302 dnl This is used by lib/System to determine the basic kind of implementation
 303 dnl to use.
 304 case $llvm_cv_platform_type in
 305   Unix)
 306     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 307     AC_SUBST(LLVM_ON_UNIX,[1])
 308     AC_SUBST(LLVM_ON_WIN32,[0])
 309     ;;
 310   Win32)
 311     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 312     AC_SUBST(LLVM_ON_UNIX,[0])
 313     AC_SUBST(LLVM_ON_WIN32,[1])
 314     ;;
 315 esac
 316
 317 dnl Determine what our target architecture is and configure accordingly.
 318 dnl This will allow Makefiles to make a distinction between the hardware and
 319 dnl the OS.
 320 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 321 [case $target in
 322   i?86-*)                 llvm_cv_target_arch="x86" ;;
 323   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 324   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 325   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 326   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 327   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 328   mips-*)                 llvm_cv_target_arch="Mips" ;;
 329   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 330   xcore-*)                llvm_cv_target_arch="XCore" ;;
 331   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 332   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 333   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 334   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 335   *)                      llvm_cv_target_arch="Unknown" ;;
 336 esac])
 337
 338 if test "$llvm_cv_target_arch" = "Unknown" ; then
 339   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 340 fi
 341
 342 # Determine the LLVM native architecture for the target
 343 case "$llvm_cv_target_arch" in
 344     x86)     LLVM_NATIVE_ARCH="X86" ;;
 345     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 346     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 347 esac
 348
 349 dnl Define a substitution, ARCH, for the target architecture
 350 AC_SUBST(ARCH,$llvm_cv_target_arch)
 351
 352 dnl Check for the endianness of the target
 353 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 354
 355 dnl Check for build platform executable suffix if we're crosscompiling
 356 if test "$cross_compiling" = yes; then
 357   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 358   AC_BUILD_EXEEXT
 359   ac_build_prefix=${build_alias}-
 360   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 361   if test -z "$BUILD_CXX"; then
 362      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 363      if test -z "$BUILD_CXX"; then
 364        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 365      fi
 366   fi
 367 else
 368   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 369 fi
 370
 371 dnl Check to see if there's a .svn or .git directory indicating that this
 372 dnl build is being done from a checkout. This sets up several defaults for
 373 dnl the command line switches. When we build with a checkout directory,
 374 dnl we get a debug with assertions turned on. Without, we assume a source
 375 dnl release and we get an optimized build without assertions.
 376 dnl See --enable-optimized and --enable-assertions below
 377 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 378   cvsbuild="yes"
 379   optimize="no"
 380   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 381 else
 382   cvsbuild="no"
 383   optimize="yes"
 384 fi
 385
 386 dnl===-----------------------------------------------------------------------===
 387 dnl===
 388 dnl=== SECTION 3: Command line arguments for the configure script.
 389 dnl===
 390 dnl===-----------------------------------------------------------------------===
 391
 392 dnl --enable-optimized : check whether they want to do an optimized build:
 393 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 394  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 395 if test ${enableval} = "no" ; then
 396   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 397 else
 398   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 399 fi
 400
 401 dnl --enable-profiling : check whether they want to do a profile build:
 402 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 403  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 404 if test ${enableval} = "no" ; then
 405   AC_SUBST(ENABLE_PROFILING,[[]])
 406 else
 407   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 408 fi
 409
 410 dnl --enable-assertions : check whether they want to turn on assertions or not:
 411 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 412   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 413 if test ${enableval} = "yes" ; then
 414   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 415 else
 416   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 417 fi
 418
 419 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 420 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 421   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 422 if test ${enableval} = "yes" ; then
 423   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 424   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 425 else
 426   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 427   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 428 fi
 429
 430 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 431 AC_ARG_ENABLE(debug-runtime,
 432    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 433 if test ${enableval} = "no" ; then
 434   AC_SUBST(DEBUG_RUNTIME,[[]])
 435 else
 436   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 437 fi
 438
 439 dnl --enable-debug-symbols : should even optimized compiler libraries
 440 dnl have debug symbols?
 441 AC_ARG_ENABLE(debug-symbols,
 442    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 443 if test ${enableval} = "no" ; then
 444   AC_SUBST(DEBUG_SYMBOLS,[[]])
 445 else
 446   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 447 fi
 448
 449 dnl --enable-jit: check whether they want to enable the jit
 450 AC_ARG_ENABLE(jit,
 451   AS_HELP_STRING(--enable-jit,
 452                  [Enable Just In Time Compiling (default is YES)]),,
 453   enableval=default)
 454 if test ${enableval} = "no"
 455 then
 456   AC_SUBST(JIT,[[]])
 457 else
 458   case "$llvm_cv_target_arch" in
 459     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 460     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 461     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 462     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 463     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 464     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 465     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 466     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 467     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 468     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 469     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 470     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 471     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 472     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 473   esac
 474 fi
 475
 476 dnl Allow enablement of doxygen generated documentation
 477 AC_ARG_ENABLE(doxygen,
 478               AS_HELP_STRING([--enable-doxygen],
 479                              [Build doxygen documentation (default is NO)]),,
 480                              enableval=default)
 481 case "$enableval" in
 482   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 483   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 484   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 485   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 486 esac
 487
 488 dnl Allow disablement of threads
 489 AC_ARG_ENABLE(threads,
 490               AS_HELP_STRING([--enable-threads],
 491                              [Use threads if available (default is YES)]),,
 492                              enableval=default)
 493 case "$enableval" in
 494   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 495   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 496   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 497   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 498 esac
 499 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 500
 501 dnl Allow building without position independent code
 502 AC_ARG_ENABLE(pic,
 503   AS_HELP_STRING([--enable-pic],
 504                  [Build LLVM with Position Independent Code (default is YES)]),,
 505                  enableval=default)
 506 case "$enableval" in
 507   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 508   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 509   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 510   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 511 esac
 512 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 513                    [Define if position independent code is enabled])
 514
 515 dnl Allow building a shared library and linking tools against it.
 516 AC_ARG_ENABLE(shared,
 517   AS_HELP_STRING([--enable-shared],
 518                  [Build a shared library and link tools against it (default is NO)]),,
 519                  enableval=default)
 520 case "$enableval" in
 521   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 522   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 523   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 524   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 525 esac
 526
 527 dnl Enable embedding timestamp information into build.
 528 AC_ARG_ENABLE(timestamps,
 529   AS_HELP_STRING([--enable-timestamps],
 530                  [Enable embedding timestamp information in build (default is YES)]),,
 531                  enableval=default)
 532 case "$enableval" in
 533   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 534   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 535   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 536   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 537 esac
 538 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 539                    [Define if timestamp information (e.g., __DATE___) is allowed])
 540
 541 dnl Allow specific targets to be specified for building (or not)
 542 TARGETS_TO_BUILD=""
 543 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 544     [Build specific host targets: all or target1,target2,... Valid targets are:
 545      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu, pic16,
 546      xcore, msp430, systemz, blackfin, cbe, msil, and cpp (default=all)]),,
 547     enableval=all)
 548 if test "$enableval" = host-only ; then
 549   enableval=host
 550 fi
 551 case "$enableval" in
 552   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend MSIL CppBackend MBlaze" ;;
 553   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 554       case "$a_target" in
 555         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 556         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 557         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 558         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 559         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 560         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 561         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 562         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 563         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 564         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 565         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 566         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 567         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 568         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 569         msil)     TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 570         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 571         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 572         host) case "$llvm_cv_target_arch" in
 573             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 574             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 575             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 576             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 577             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 578             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 579             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 580             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 581             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 582             PIC16)       TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 583             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 584             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 585             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 586             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 587             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 588           esac ;;
 589         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 590       esac
 591   done
 592   ;;
 593 esac
 594 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 595
 596 # Determine whether we are building LLVM support for the native architecture.
 597 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 598 for a_target in $TARGETS_TO_BUILD; do
 599   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 600     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 601     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCHNAME,$LLVM_NATIVE_ARCH,
 602       [Short LLVM architecture name for the native architecture, if available])
 603     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 604       [LLVM architecture name for the native architecture, if available])
 605   fi
 606 done
 607
 608 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 609 # target feature def files.
 610 LLVM_ENUM_TARGETS=""
 611 LLVM_ENUM_ASM_PRINTERS=""
 612 LLVM_ENUM_ASM_PARSERS=""
 613 LLVM_ENUM_DISASSEMBLERS=""
 614 for target_to_build in $TARGETS_TO_BUILD; do
 615   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 616   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 617     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 618   fi
 619   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 620     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 621   fi
 622   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 623     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 624   fi
 625 done
 626 AC_SUBST(LLVM_ENUM_TARGETS)
 627 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 628 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 629 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 630
 631 dnl Prevent the CBackend from using printf("%a") for floating point so older
 632 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 633 dnl can still compile the CBE's output
 634 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 635   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 636   enableval=default)
 637 case "$enableval" in
 638   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 639   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 640   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 641   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 642 esac
 643 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 644                    [Define if CBE is enabled for printf %a output])
 645
 646 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 647 AC_ARG_WITH(llvmgccdir,
 648   AS_HELP_STRING([--with-llvmgccdir],
 649     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 650     withval=default)
 651 case "$withval" in
 652   default) WITH_LLVMGCCDIR=default ;;
 653   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 654   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 655 esac
 656
 657 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 658 AC_ARG_WITH(llvmgcc,
 659   AS_HELP_STRING([--with-llvmgcc],
 660     [Specify location of llvm-gcc driver (default searches PATH)]),
 661     LLVMGCC=$with_llvmgcc
 662       WITH_LLVMGCCDIR="",)
 663
 664 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 665 AC_ARG_WITH(llvmgxx,
 666   AS_HELP_STRING([--with-llvmgxx],
 667     [Specify location of llvm-g++ driver (default searches PATH)]),
 668     LLVMGXX=$with_llvmgxx
 669     WITH_LLVMGCCDIR="",)
 670
 671 if test -n "$LLVMGCC"; then
 672    LLVMGCCCOMMAND="$LLVMGCC"
 673 fi
 674
 675 if test -n "$LLVMGXX"; then
 676    LLVMGXXCOMMAND="$LLVMGXX"
 677 fi
 678
 679 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 680    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 681 fi
 682
 683 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 684    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 685 fi
 686
 687 dnl Allow a specific Clang compiler to be used with this LLVM config.
 688 AC_ARG_WITH(clang,
 689   AS_HELP_STRING([--with-clang],
 690     [Specify location of clang compiler (default is --with-built-clang)]),
 691     [],[with_clang=default])
 692
 693 dnl Enable use of the built Clang.
 694 AC_ARG_WITH(built-clang,
 695   AS_HELP_STRING([--with-built-clang],
 696     [Use the compiled Clang as the LLVM compiler (default=check)]),
 697     [],[with_built_clang=check])
 698
 699 dnl Select the Clang compiler option.
 700 dnl
 701 dnl If --with-clang is given, always honor that; otherwise honor
 702 dnl --with-built-clang, or check if we have the clang sources.
 703 AC_MSG_CHECKING([clang compiler])
 704 WITH_CLANGPATH=""
 705 WITH_BUILT_CLANG=0
 706 if test "$with_clang" != "default"; then
 707    WITH_CLANGPATH="$with_clang"
 708    if ! test -x "$WITH_CLANGPATH"; then
 709      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 710    fi
 711 elif test "$with_built_clang" = "yes"; then
 712    WITH_BUILT_CLANG=1
 713 elif test "$with_built_clang" = "no"; then
 714    WITH_BUILT_CLANG=0
 715 else
 716    if test "$with_built_clang" != "check"; then
 717       AC_MSG_ERROR([invalid value for --with-built-clang.])
 718    fi
 719
 720    if test -f ${srcdir}/tools/clang/README.txt; then
 721      WITH_BUILT_CLANG=1
 722    fi
 723 fi
 724
 725 if ! test -z "$WITH_CLANGPATH"; then
 726    AC_MSG_RESULT([$WITH_CLANGPATH])
 727    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 728 elif test "$WITH_BUILT_CLANG" = "1"; then
 729    AC_MSG_RESULT([built])
 730 else
 731    AC_MSG_RESULT([none])
 732 fi
 733 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 734 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 735 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 736
 737 dnl Override the option to use for optimized builds.
 738 AC_ARG_WITH(optimize-option,
 739   AS_HELP_STRING([--with-optimize-option],
 740                  [Select the compiler options to use for optimized builds]),,
 741                  withval=default)
 742 AC_MSG_CHECKING([optimization flags])
 743 case "$withval" in
 744   default)
 745     case "$llvm_cv_os_type" in
 746     FreeBSD) optimize_option=-O2 ;;
 747     MingW) optimize_option=-O2 ;;
 748     *)     optimize_option=-O3 ;;
 749     esac ;;
 750   *) optimize_option="$withval" ;;
 751 esac
 752 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 753 AC_MSG_RESULT([$optimize_option])
 754
 755 dnl Specify extra build options
 756 AC_ARG_WITH(extra-options,
 757   AS_HELP_STRING([--with-extra-options],
 758                  [Specify additional options to compile LLVM with]),,
 759                  withval=default)
 760 case "$withval" in
 761   default) EXTRA_OPTIONS= ;;
 762   *) EXTRA_OPTIONS=$withval ;;
 763 esac
 764 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 765
 766 dnl Allow specific bindings to be specified for building (or not)
 767 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 768     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 769     enableval=default)
 770 BINDINGS_TO_BUILD=""
 771 case "$enableval" in
 772   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 773   all ) BINDINGS_TO_BUILD="ocaml" ;;
 774   none | no) BINDINGS_TO_BUILD="" ;;
 775   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 776       case "$a_binding" in
 777         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 778         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 779       esac
 780   done
 781   ;;
 782 esac
 783
 784 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 785 dnl script for bindings/ocaml/configure, except that its auto value depends on
 786 dnl OCAMLC, which is found here to support tests.
 787 AC_ARG_WITH([ocaml-libdir],
 788   [AS_HELP_STRING([--with-ocaml-libdir],
 789     [Specify install location for ocaml bindings (default is stdlib)])],
 790   [],
 791   [withval=auto])
 792 case "$withval" in
 793   auto) with_ocaml_libdir="$withval" ;;
 794   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 795   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 796 esac
 797
 798 AC_ARG_WITH(c-include-dirs,
 799   AS_HELP_STRING([--with-c-include-dirs],
 800     [Colon separated list of directories clang will search for headers]),,
 801     withval="")
 802 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 803                    [Directories clang will search for headers])
 804
 805 AC_ARG_WITH(cxx-include-root,
 806   AS_HELP_STRING([--with-cxx-include-root],
 807     [Directory with the libstdc++ headers.]),,
 808     withval="")
 809 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 810                    [Directory with the libstdc++ headers.])
 811
 812 AC_ARG_WITH(cxx-include-arch,
 813   AS_HELP_STRING([--with-cxx-include-arch],
 814     [Architecture of the libstdc++ headers.]),,
 815     withval="")
 816 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 817                    [Arch the libstdc++ headers.])
 818
 819 AC_ARG_WITH(cxx-include-32bit-dir,
 820   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 821     [32 bit multilib dir.]),,
 822     withval="")
 823 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 824                    [32 bit multilib directory.])
 825
 826 AC_ARG_WITH(cxx-include-64bit-dir,
 827   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 828     [64 bit multilib directory.]),,
 829     withval="")
 830 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 831                    [64 bit multilib directory.])
 832
 833 dnl Allow linking of LLVM with GPLv3 binutils code.
 834 AC_ARG_WITH(binutils-include,
 835   AS_HELP_STRING([--with-binutils-include],
 836     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 837   withval=default)
 838 case "$withval" in
 839   default) WITH_BINUTILS_INCDIR=default ;;
 840   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 841   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 842 esac
 843 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 844   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 845   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 846      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 847      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 848   fi
 849 fi
 850
 851 dnl --enable-libffi : check whether the user wants to turn off libffi:
 852 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 853   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 854   [case "$enableval" in
 855     yes) llvm_cv_enable_libffi="yes" ;;
 856     no)  llvm_cv_enable_libffi="no"  ;;
 857     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 858   esac],
 859   llvm_cv_enable_libffi=no)
 860
 861 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 862 if test "$llvm_cv_os_type" = "Win32" ; then
 863    llvmc_dynamic="yes"
 864 else
 865    llvmc_dynamic="no"
 866 fi
 867
 868 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 869 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 870 --enable-llvmc-dynamic,
 871 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 872 enableval=$llvmc_dynamic)
 873 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 874    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 875 else
 876    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 877 fi
 878
 879 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 880 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 881 --enable-llvmc-dynamic-plugins,
 882 [Enable dynamic LLVMC plugins (default is YES)]),,
 883 enableval=yes)
 884 if test ${enableval} = "yes" ; then
 885    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 886 else
 887    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 888 fi
 889
 890 dnl===-----------------------------------------------------------------------===
 891 dnl===
 892 dnl=== SECTION 4: Check for programs we need and that they are the right version
 893 dnl===
 894 dnl===-----------------------------------------------------------------------===
 895
 896 dnl Check for compilation tools
 897 AC_PROG_CPP
 898 AC_PROG_CC(gcc)
 899 AC_PROG_CXX(g++)
 900
 901 AC_PROG_NM
 902 AC_SUBST(NM)
 903
 904 dnl Check for the tools that the makefiles require
 905 AC_CHECK_GNU_MAKE
 906 AC_PROG_LN_S
 907 AC_PATH_PROG(CMP, [cmp], [cmp])
 908 AC_PATH_PROG(CP, [cp], [cp])
 909 AC_PATH_PROG(DATE, [date], [date])
 910 AC_PATH_PROG(FIND, [find], [find])
 911 AC_PATH_PROG(GREP, [grep], [grep])
 912 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 913 AC_PATH_PROG(MV,   [mv],   [mv])
 914 AC_PROG_RANLIB
 915 AC_CHECK_TOOL(AR, ar, false)
 916 AC_PATH_PROG(RM,   [rm],   [rm])
 917 AC_PATH_PROG(SED,  [sed],  [sed])
 918 AC_PATH_PROG(TAR,  [tar],  [gtar])
 919 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 920
 921 dnl Looking for misc. graph plotting software
 922 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 923 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 924   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 925   dnl If we're targeting for mingw we should emit windows paths, not msys
 926   if test "$llvm_cv_os_type" = "MingW" ; then
 927     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 928   fi
 929   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 930    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 931 fi
 932 AC_PATH_PROG(DOT, [dot], [echo dot])
 933 if test "$DOT" != "echo dot" ; then
 934   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 935   dnl If we're targeting for mingw we should emit windows paths, not msys
 936   if test "$llvm_cv_os_type" = "MingW" ; then
 937     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 938   fi
 939   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 940    [Define to path to dot program if found or 'echo dot' otherwise])
 941 fi
 942 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 943 if test "$FDP" != "echo fdp" ; then
 944   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 945   dnl If we're targeting for mingw we should emit windows paths, not msys
 946   if test "$llvm_cv_os_type" = "MingW" ; then
 947     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 948   fi
 949   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 950    [Define to path to fdp program if found or 'echo fdp' otherwise])
 951 fi
 952 AC_PATH_PROG(NEATO, [neato], [echo neato])
 953 if test "$NEATO" != "echo neato" ; then
 954   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 955   dnl If we're targeting for mingw we should emit windows paths, not msys
 956   if test "$llvm_cv_os_type" = "MingW" ; then
 957     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 958   fi
 959   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 960    [Define to path to neato program if found or 'echo neato' otherwise])
 961 fi
 962 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 963 if test "$TWOPI" != "echo twopi" ; then
 964   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 965   dnl If we're targeting for mingw we should emit windows paths, not msys
 966   if test "$llvm_cv_os_type" = "MingW" ; then
 967     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 968   fi
 969   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 970    [Define to path to twopi program if found or 'echo twopi' otherwise])
 971 fi
 972 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 973 if test "$CIRCO" != "echo circo" ; then
 974   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 975   dnl If we're targeting for mingw we should emit windows paths, not msys
 976   if test "$llvm_cv_os_type" = "MingW" ; then
 977     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 978   fi
 979   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 980    [Define to path to circo program if found or 'echo circo' otherwise])
 981 fi
 982 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 983 if test "$GV" != "echo gv" ; then
 984   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 985   dnl If we're targeting for mingw we should emit windows paths, not msys
 986   if test "$llvm_cv_os_type" = "MingW" ; then
 987     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 988   fi
 989   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 990    [Define to path to gv program if found or 'echo gv' otherwise])
 991 fi
 992 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 993 if test "$DOTTY" != "echo dotty" ; then
 994   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 995   dnl If we're targeting for mingw we should emit windows paths, not msys
 996   if test "$llvm_cv_os_type" = "MingW" ; then
 997     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 998   fi
 999   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1000    [Define to path to dotty program if found or 'echo dotty' otherwise])
1001 fi
1002
1003 dnl Look for a sufficiently recent version of Perl.
1004 LLVM_PROG_PERL([5.006])
1005 AC_SUBST(PERL)
1006 if test x"$PERL" = xnone; then
1007    AC_SUBST(HAVE_PERL,0)
1008    AC_MSG_ERROR([perl is required but was not found, please install it])
1009 else
1010    AC_SUBST(HAVE_PERL,1)
1011 fi
1012
1013 dnl Find the install program
1014 AC_PROG_INSTALL
1015 dnl Prepend src dir to install path dir if it's a relative path
1016 dnl This is a hack for installs that take place in something other
1017 dnl than the top level.
1018 case "$INSTALL" in
1019  [[\\/$]]* | ?:[[\\/]]* ) ;;
1020  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1021 esac
1022
1023 dnl Checks for documentation and testing tools that we can do without. If these
1024 dnl are not found then they are set to "true" which always succeeds but does
1025 dnl nothing. This just lets the build output show that we could have done
1026 dnl something if the tool was available.
1027 AC_PATH_PROG(BZIP2, [bzip2])
1028 AC_PATH_PROG(CAT, [cat])
1029 AC_PATH_PROG(DOXYGEN, [doxygen])
1030 AC_PATH_PROG(GROFF, [groff])
1031 AC_PATH_PROG(GZIP, [gzip])
1032 AC_PATH_PROG(POD2HTML, [pod2html])
1033 AC_PATH_PROG(POD2MAN, [pod2man])
1034 AC_PATH_PROG(PDFROFF, [pdfroff])
1035 AC_PATH_PROG(RUNTEST, [runtest])
1036 DJ_AC_PATH_TCLSH
1037 AC_PATH_PROG(ZIP, [zip])
1038 AC_PATH_PROGS(OCAMLC, [ocamlc])
1039 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1040 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1041 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1042 AC_PATH_PROGS(GAS, [gas as])
1043
1044 dnl Determine whether the linker supports the -R option.
1045 AC_LINK_USE_R
1046
1047 dnl Determine whether the linker supports the -export-dynamic option.
1048 AC_LINK_EXPORT_DYNAMIC
1049
1050 dnl Determine whether the linker supports the --version-script option.
1051 AC_LINK_VERSION_SCRIPT
1052
1053 dnl Check for libtool and the library that has dlopen function (which must come
1054 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1055 dnl libtool).
1056 AC_LIBTOOL_DLOPEN
1057 AC_LIB_LTDL
1058
1059 if test "$WITH_LLVMGCCDIR" = "default" ; then
1060   LLVMGCC="llvm-gcc${EXEEXT}"
1061   LLVMGXX="llvm-g++${EXEEXT}"
1062   LLVMGCCCOMMAND="$LLVMGCC"
1063   LLVMGXXCOMMAND="$LLVMGXX"
1064   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1065   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1066   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
1067   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
1068 else
1069   if test -z "$LLVMGCC"; then
1070     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
1071     LLVMGCCCOMMAND="$LLVMGCC"
1072   fi
1073   if test -z "$LLVMGXX"; then
1074     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1075     LLVMGXXCOMMAND="$LLVMGXX"
1076   fi
1077
1078   AC_SUBST(LLVMGCC,$LLVMGCC)
1079   AC_SUBST(LLVMGXX,$LLVMGXX)
1080   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1081   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1082 fi
1083
1084 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1085 dnl found, otherwise clang if available.
1086 AC_ARG_WITH(llvmcc,
1087   AS_HELP_STRING([--with-llvmcc=<name>],
1088     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1089     [],[with_llvmcc=check])
1090 AC_MSG_CHECKING([LLVM capable compiler])
1091 if test "$with_llvmcc" != "check"; then
1092    if (test "$with_llvmcc" != "llvm-gcc" &&
1093        test "$with_llvmcc" != "clang" &&
1094        test "$with_llvmcc" != "none"); then
1095       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1096    fi
1097    WITH_LLVMCC="$with_llvmcc"
1098 elif test -n "$LLVMGCC"; then
1099    WITH_LLVMCC=llvm-gcc
1100 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1101    WITH_LLVMCC=clang
1102 else
1103    WITH_LLVMCC=none
1104 fi
1105 AC_MSG_RESULT([$WITH_LLVMCC])
1106 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1107
1108 AC_MSG_CHECKING([tool compatibility])
1109
1110 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1111 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1112 dnl to support those options.
1113 dnl "icc" emits gcc signatures
1114 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1115 ICC=no
1116 IXX=no
1117 case $CC in
1118   icc*|icpc*)
1119     ICC=yes
1120     IXX=yes
1121     ;;
1122    *)
1123     ;;
1124 esac
1125
1126 if test "$GCC" != "yes" && test "$ICC" != "yes"
1127 then
1128   AC_MSG_ERROR([gcc|icc required but not found])
1129 fi
1130
1131 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
1132 if test "$GXX" != "yes" && test "$IXX" != "yes"
1133 then
1134   AC_MSG_ERROR([g++|icc required but not found])
1135 fi
1136
1137 dnl Verify that GCC is version 3.0 or higher
1138 if test "$GCC" = "yes"
1139 then
1140   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1141 #error Unsupported GCC version
1142 #endif
1143 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1144 fi
1145
1146 dnl Check for GNU Make.  We use its extensions, so don't build without it
1147 if test -z "$llvm_cv_gnu_make_command"
1148 then
1149   AC_MSG_ERROR([GNU Make required but not found])
1150 fi
1151
1152 dnl Tool compatibility is okay if we make it here.
1153 AC_MSG_RESULT([ok])
1154
1155 dnl Check optional compiler flags.
1156 AC_MSG_CHECKING([optional compiler flags])
1157 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1158 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1159 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1160
1161 dnl===-----------------------------------------------------------------------===
1162 dnl===
1163 dnl=== SECTION 5: Check for libraries
1164 dnl===
1165 dnl===-----------------------------------------------------------------------===
1166
1167 AC_CHECK_LIB(m,sin)
1168 if test "$llvm_cv_os_type" = "MingW" ; then
1169   AC_CHECK_LIB(imagehlp, main)
1170   AC_CHECK_LIB(psapi, main)
1171 fi
1172
1173 dnl dlopen() is required for plugin support.
1174 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1175                [Define if dlopen() is available on this platform.]),
1176                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1177
1178 dnl libffi is optional; used to call external functions from the interpreter
1179 if test "$llvm_cv_enable_libffi" = "yes" ; then
1180   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1181                  [Define if libffi is available on this platform.]),
1182                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1183 fi
1184
1185 dnl mallinfo is optional; the code can compile (minus features) without it
1186 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1187                [Define if mallinfo() is available on this platform.]))
1188
1189 dnl pthread locking functions are optional - but llvm will not be thread-safe
1190 dnl without locks.
1191 if test "$ENABLE_THREADS" -eq 1 ; then
1192   AC_CHECK_LIB(pthread, pthread_mutex_init)
1193   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1194                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1195                            [Have pthread_mutex_lock]))
1196   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1197                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1198                  [Have pthread_rwlock_init]))
1199   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1200                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1201                  [Have pthread_getspecific]))
1202 fi
1203
1204 dnl Allow extra x86-disassembler library
1205 AC_ARG_WITH(udis86,
1206   AS_HELP_STRING([--with-udis86=<path>],
1207     [Use udis86 external x86 disassembler library]),
1208     [
1209       AC_SUBST(USE_UDIS86, [1])
1210       case "$withval" in
1211         /usr/lib|yes) ;;
1212         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1213       esac
1214       AC_CHECK_LIB(udis86, ud_init, [], [
1215         echo "Error! You need to have libudis86 around."
1216         exit -1
1217       ])
1218     ],
1219     AC_SUBST(USE_UDIS86, [0]))
1220 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1221                    [Define if use udis86 library])
1222
1223 dnl Allow OProfile support for JIT output.
1224 AC_ARG_WITH(oprofile,
1225   AS_HELP_STRING([--with-oprofile=<prefix>],
1226     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1227     [
1228       AC_SUBST(USE_OPROFILE, [1])
1229       case "$withval" in
1230         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1231         no) llvm_cv_oppath=
1232             AC_SUBST(USE_OPROFILE, [0]) ;;
1233         *) llvm_cv_oppath="${withval}/lib/oprofile"
1234            CPPFLAGS="-I${withval}/include";;
1235       esac
1236       if test -n "$llvm_cv_oppath" ; then
1237         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1238         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1239         dnl libbfd is not included properly in libopagent in some Debian
1240         dnl versions.  If libbfd isn't found at all, we assume opagent works
1241         dnl anyway.
1242         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1243         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1244           echo "Error! You need to have libopagent around."
1245           exit -1
1246         ])
1247         AC_CHECK_HEADER([opagent.h], [], [
1248           echo "Error! You need to have opagent.h around."
1249           exit -1
1250           ])
1251       fi
1252     ],
1253     [
1254       AC_SUBST(USE_OPROFILE, [0])
1255     ])
1256 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1257                    [Define if we have the oprofile JIT-support library])
1258
1259 dnl===-----------------------------------------------------------------------===
1260 dnl===
1261 dnl=== SECTION 6: Check for header files
1262 dnl===
1263 dnl===-----------------------------------------------------------------------===
1264
1265 dnl First, use autoconf provided macros for specific headers that we need
1266 dnl We don't check for ancient stuff or things that are guaranteed to be there
1267 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1268 dnl Generally we're looking for POSIX headers.
1269 AC_HEADER_DIRENT
1270 AC_HEADER_MMAP_ANONYMOUS
1271 AC_HEADER_STAT
1272 AC_HEADER_STDC
1273 AC_HEADER_SYS_WAIT
1274 AC_HEADER_TIME
1275
1276 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1277 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1278 AC_CHECK_HEADERS([utime.h windows.h])
1279 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1280 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1281 AC_CHECK_HEADERS([valgrind/valgrind.h])
1282 if test "$ENABLE_THREADS" -eq 1 ; then
1283   AC_CHECK_HEADERS(pthread.h,
1284                    AC_SUBST(HAVE_PTHREAD, 1),
1285                    AC_SUBST(HAVE_PTHREAD, 0))
1286 else
1287   AC_SUBST(HAVE_PTHREAD, 0)
1288 fi
1289
1290 dnl Try to find ffi.h.
1291 if test "$llvm_cv_enable_libffi" = "yes" ; then
1292   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1293 fi
1294
1295 dnl Try to find Darwin specific crash reporting library.
1296 AC_CHECK_HEADERS([CrashReporterClient.h])
1297
1298 dnl Try to find Darwin specific linker-section library.
1299 AC_CHECK_HEADERS([mach-o/getsect.h])
1300
1301 dnl===-----------------------------------------------------------------------===
1302 dnl===
1303 dnl=== SECTION 7: Check for types and structures
1304 dnl===
1305 dnl===-----------------------------------------------------------------------===
1306
1307 AC_HUGE_VAL_CHECK
1308 AC_TYPE_PID_T
1309 AC_TYPE_SIZE_T
1310 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1311 AC_STRUCT_TM
1312 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1313 AC_CHECK_TYPES([uint64_t],,
1314          AC_CHECK_TYPES([u_int64_t],,
1315          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1316
1317 dnl===-----------------------------------------------------------------------===
1318 dnl===
1319 dnl=== SECTION 8: Check for specific functions needed
1320 dnl===
1321 dnl===-----------------------------------------------------------------------===
1322
1323 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1324 AC_CHECK_FUNCS([powf fmodf strtof round ])
1325 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1326 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1327 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1328 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1329 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1330 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1331 AC_C_PRINTF_A
1332 AC_FUNC_RAND48
1333
1334 dnl Check for variations in the Standard C++ library and STL. These macros are
1335 dnl provided by LLVM in the autoconf/m4 directory.
1336 AC_FUNC_ISNAN
1337 AC_FUNC_ISINF
1338
1339 dnl Check for mmap support.We also need to know if /dev/zero is required to
1340 dnl be opened for allocating RWX memory.
1341 dnl Make sure we aren't attempting to configure for an unknown system
1342 if test "$llvm_cv_platform_type" = "Unix" ; then
1343   AC_FUNC_MMAP
1344   AC_FUNC_MMAP_FILE
1345   AC_NEED_DEV_ZERO_FOR_MMAP
1346
1347   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1348   then
1349     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1350   fi
1351   if test "$ac_cv_func_mmap_file" = "no"
1352   then
1353     AC_MSG_WARN([mmap() of files required but not found])
1354   fi
1355 fi
1356
1357 dnl atomic builtins are required for threading support.
1358 AC_MSG_CHECKING(for GCC atomic builtins)
1359 dnl Since we'll be using these atomic builtins in C++ files we should test
1360 dnl the C++ compiler.
1361 AC_LANG_PUSH([C++])
1362 AC_LINK_IFELSE(
1363   AC_LANG_SOURCE(
1364     [[int main() {
1365         volatile unsigned long val = 1;
1366         __sync_synchronize();
1367         __sync_val_compare_and_swap(&val, 1, 0);
1368         __sync_add_and_fetch(&val, 1);
1369         __sync_sub_and_fetch(&val, 1);
1370         return 0;
1371       }
1372     ]]),
1373   AC_LANG_POP([C++])
1374   AC_MSG_RESULT(yes)
1375   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1376   AC_MSG_RESULT(no)
1377   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1378   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1379
1380 dnl Check for Darwin-specific getsect().
1381 AC_MSG_CHECKING(for getsect())
1382 AC_COMPILE_IFELSE(
1383   AC_LANG_SOURCE(
1384     [[#include <mach-o/getsect.h>
1385       int main() {
1386         unsigned long p;
1387         return (int)getsect("__DATA","__pass_info", &p);
1388       }
1389     ]]),
1390   AC_MSG_RESULT(yes)
1391     AC_DEFINE(HAVE_GETSECT, 1, Have Darwin getsect() support),
1392   AC_MSG_RESULT(no)
1393     AC_DEFINE(HAVE_GETSECT, 1, Have Darwin getsect() support)
1394 )
1395
1396
1397 dnl===-----------------------------------------------------------------------===
1398 dnl===
1399 dnl=== SECTION 9: Additional checks, variables, etc.
1400 dnl===
1401 dnl===-----------------------------------------------------------------------===
1402
1403 dnl Handle 32-bit linux systems running a 64-bit kernel.
1404 dnl This has to come after section 4 because it invokes the compiler.
1405 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1406   AC_IS_LINUX_MIXED
1407   if test "$llvm_cv_linux_mixed" = "yes"; then
1408     llvm_cv_target_arch="x86"
1409     ARCH="x86"
1410   fi
1411 fi
1412
1413 dnl Check, whether __dso_handle is present
1414 AC_CHECK_FUNCS([__dso_handle])
1415
1416 dnl See if the llvm-gcc executable can compile to LLVM assembly
1417 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1418 [llvm_cv_llvmgcc_sanity="no"
1419 if test -x "$LLVMGCC" ; then
1420   cp /dev/null conftest.c
1421   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1422       grep 'target datalayout =' > /dev/null 2>&1
1423   if test $? -eq 0 ; then
1424     llvm_cv_llvmgcc_sanity="yes"
1425   fi
1426   rm conftest.c
1427 fi])
1428
1429 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1430 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1431   AC_MSG_CHECKING([llvm-gcc component support])
1432   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1433   AC_SUBST(LLVMCC1,$llvmcc1path)
1434   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1435   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1436   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1437   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1438   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1439   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1440   AC_MSG_RESULT([ok])
1441 fi
1442
1443 dnl Propagate the shared library extension that the libltdl checks did to
1444 dnl the Makefiles so we can use it there too
1445 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1446
1447 dnl Propagate the run-time library path variable that the libltdl
1448 dnl checks found to the Makefiles so we can use it there too
1449 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1450
1451 # Translate the various configuration directories and other basic
1452 # information into substitutions that will end up in Makefile.config.in
1453 # that these configured values can be used by the makefiles
1454 if test "${prefix}" = "NONE" ; then
1455   prefix="/usr/local"
1456 fi
1457 eval LLVM_PREFIX="${prefix}";
1458 eval LLVM_BINDIR="${prefix}/bin";
1459 eval LLVM_LIBDIR="${prefix}/lib";
1460 eval LLVM_DATADIR="${prefix}/share/llvm";
1461 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1462 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1463 eval LLVM_INCLUDEDIR="${prefix}/include";
1464 eval LLVM_INFODIR="${prefix}/info";
1465 eval LLVM_MANDIR="${prefix}/man";
1466 LLVM_CONFIGTIME=`date`
1467 AC_SUBST(LLVM_PREFIX)
1468 AC_SUBST(LLVM_BINDIR)
1469 AC_SUBST(LLVM_LIBDIR)
1470 AC_SUBST(LLVM_DATADIR)
1471 AC_SUBST(LLVM_DOCSDIR)
1472 AC_SUBST(LLVM_ETCDIR)
1473 AC_SUBST(LLVM_INCLUDEDIR)
1474 AC_SUBST(LLVM_INFODIR)
1475 AC_SUBST(LLVM_MANDIR)
1476 AC_SUBST(LLVM_CONFIGTIME)
1477
1478 # Place the various directores into the config.h file as #defines so that we
1479 # can know about the installation paths within LLVM.
1480 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1481                    [Installation prefix directory])
1482 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1483                    [Installation directory for binary executables])
1484 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1485                    [Installation directory for libraries])
1486 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1487                    [Installation directory for data files])
1488 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1489                    [Installation directory for documentation])
1490 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1491                    [Installation directory for config files])
1492 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1493                    [Installation directory for include files])
1494 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1495                    [Installation directory for .info files])
1496 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1497                    [Installation directory for man pages])
1498 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1499                    [Time at which LLVM was configured])
1500 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1501                    [Host triple we were built on])
1502
1503 # Determine which bindings to build.
1504 if test "$BINDINGS_TO_BUILD" = auto ; then
1505   BINDINGS_TO_BUILD=""
1506   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1507     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1508   fi
1509 fi
1510 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1511
1512 # This isn't really configurey, but it avoids having to repeat the list in
1513 # other files.
1514 AC_SUBST(ALL_BINDINGS,ocaml)
1515
1516 # Do any work necessary to ensure that bindings have what they need.
1517 binding_prereqs_failed=0
1518 for a_binding in $BINDINGS_TO_BUILD ; do
1519   case "$a_binding" in
1520   ocaml)
1521     if test "x$OCAMLC" = x ; then
1522       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1523       binding_prereqs_failed=1
1524     fi
1525     if test "x$OCAMLDEP" = x ; then
1526       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1527       binding_prereqs_failed=1
1528     fi
1529     if test "x$OCAMLOPT" = x ; then
1530       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1531       dnl ocamlopt is optional!
1532     fi
1533     if test "x$with_ocaml_libdir" != xauto ; then
1534       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1535     else
1536       ocaml_stdlib="`"$OCAMLC" -where`"
1537       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1538       then
1539         # ocaml stdlib is beneath our prefix; use stdlib
1540         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1541       else
1542         # ocaml stdlib is outside our prefix; use libdir/ocaml
1543         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1544       fi
1545     fi
1546     ;;
1547   esac
1548 done
1549 if test "$binding_prereqs_failed" = 1 ; then
1550   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1551 fi
1552
1553 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1554 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1555
1556 dnl Determine linker rpath flag
1557 if test "$llvm_cv_link_use_r" = "yes" ; then
1558   RPATH="-Wl,-R"
1559 else
1560   RPATH="-Wl,-rpath"
1561 fi
1562 AC_SUBST(RPATH)
1563
1564 dnl Determine linker rdynamic flag
1565 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1566   RDYNAMIC="-Wl,-export-dynamic"
1567 else
1568   RDYNAMIC=""
1569 fi
1570 AC_SUBST(RDYNAMIC)
1571
1572 dnl===-----------------------------------------------------------------------===
1573 dnl===
1574 dnl=== SECTION 10: Specify the output files and generate it
1575 dnl===
1576 dnl===-----------------------------------------------------------------------===
1577
1578 dnl Configure header files
1579 dnl WARNING: dnl If you add or remove any of the following config headers, then
1580 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1581 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1582 dnl files can be updated automatically when their *.in sources change.
1583 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1584 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1585 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1586 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1587 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1588 AC_CONFIG_HEADERS([include/llvm/System/DataTypes.h])
1589
1590 dnl Configure the makefile's configuration data
1591 AC_CONFIG_FILES([Makefile.config])
1592
1593 dnl Configure the RPM spec file for LLVM
1594 AC_CONFIG_FILES([llvm.spec])
1595
1596 dnl Configure llvmc's Base plugin
1597 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1598
1599 dnl Do the first stage of configuration for llvm-config.in.
1600 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1601
1602 dnl Do special configuration of Makefiles
1603 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1604 AC_CONFIG_MAKEFILE(Makefile)
1605 AC_CONFIG_MAKEFILE(Makefile.common)
1606 AC_CONFIG_MAKEFILE(examples/Makefile)
1607 AC_CONFIG_MAKEFILE(lib/Makefile)
1608 AC_CONFIG_MAKEFILE(runtime/Makefile)
1609 AC_CONFIG_MAKEFILE(test/Makefile)
1610 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1611 AC_CONFIG_MAKEFILE(unittests/Makefile)
1612 AC_CONFIG_MAKEFILE(tools/Makefile)
1613 AC_CONFIG_MAKEFILE(utils/Makefile)
1614 AC_CONFIG_MAKEFILE(projects/Makefile)
1615 AC_CONFIG_MAKEFILE(bindings/Makefile)
1616 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1617
1618 dnl Finally, crank out the output
1619 AC_OUTPUT