autoconf/configure.ac

   1 dnl Autoconf requirements
   2 dnl AC_INIT(package, version, bug-report-address)
   3 dnl information on the package
   4 dnl checks for programs
   5 dnl checks for libraries
   6 dnl checks for header files
   7 dnl checks for types
   8 dnl checks for structures
   9 dnl checks for compiler characteristics
  10 dnl checks for library functions
  11 dnl checks for system services
  12 dnl AC_CONFIG_FILES([file...])
  13 dnl AC_OUTPUT
  14
  15 dnl **************************************************************************
  16 dnl * Initialize
  17 dnl **************************************************************************
  18 AC_INIT([[[LLVM]]],[[[1.0]]],[llvmbugs@cs.uiuc.edu])
  19
  20 dnl Place all of the extra autoconf files into the config subdirectory
  21 AC_CONFIG_AUX_DIR([autoconf])
  22
  23 dnl Configure a header file
  24 AC_CONFIG_HEADERS(include/Config/config.h)
  25 AC_CONFIG_MAKEFILE(Makefile)
  26 AC_CONFIG_MAKEFILE(Makefile.common)
  27 AC_CONFIG_MAKEFILE(Makefile.rules)
  28 AC_CONFIG_MAKEFILE(lib/Makefile)
  29 AC_CONFIG_MAKEFILE(lib/Analysis/Makefile)
  30 AC_CONFIG_MAKEFILE(lib/Analysis/DataStructure/Makefile)
  31 AC_CONFIG_MAKEFILE(lib/Analysis/IPA/Makefile)
  32 AC_CONFIG_MAKEFILE(lib/Analysis/LiveVar/Makefile)
  33 AC_CONFIG_MAKEFILE(lib/AsmParser/Makefile)
  34 AC_CONFIG_MAKEFILE(lib/Bytecode/Makefile)
  35 AC_CONFIG_MAKEFILE(lib/Bytecode/Reader/Makefile)
  36 AC_CONFIG_MAKEFILE(lib/Bytecode/Writer/Makefile)
  37 AC_CONFIG_MAKEFILE(lib/CWriter/Makefile)
  38 AC_CONFIG_MAKEFILE(lib/CodeGen/Makefile)
  39 AC_CONFIG_MAKEFILE(lib/CodeGen/InstrSched/Makefile)
  40 AC_CONFIG_MAKEFILE(lib/CodeGen/InstrSelection/Makefile)
  41 AC_CONFIG_MAKEFILE(lib/CodeGen/ModuloScheduling/Makefile)
  42 AC_CONFIG_MAKEFILE(lib/CodeGen/RegAlloc/Makefile)
  43 AC_CONFIG_MAKEFILE(lib/CodeGen/SelectionDAG/Makefile)
  44 AC_CONFIG_MAKEFILE(lib/ExecutionEngine/Makefile)
  45 AC_CONFIG_MAKEFILE(lib/ExecutionEngine/Interpreter/Makefile)
  46 AC_CONFIG_MAKEFILE(lib/ExecutionEngine/JIT/Makefile)
  47 AC_CONFIG_MAKEFILE(lib/Support/Makefile)
  48 AC_CONFIG_MAKEFILE(lib/Target/Makefile)
  49 AC_CONFIG_MAKEFILE(lib/Target/Sparc/Makefile)
  50 AC_CONFIG_MAKEFILE(lib/Target/X86/Makefile)
  51 AC_CONFIG_MAKEFILE(lib/Transforms/Makefile)
  52 AC_CONFIG_MAKEFILE(lib/Transforms/Hello/Makefile)
  53 AC_CONFIG_MAKEFILE(lib/Transforms/IPO/Makefile)
  54 AC_CONFIG_MAKEFILE(lib/Transforms/Instrumentation/Makefile)
  55 AC_CONFIG_MAKEFILE(lib/Transforms/Instrumentation/ProfilePaths/Makefile)
  56 AC_CONFIG_MAKEFILE(lib/Transforms/Scalar/Makefile)
  57 AC_CONFIG_MAKEFILE(lib/Transforms/Utils/Makefile)
  58 AC_CONFIG_MAKEFILE(lib/VMCore/Makefile)
  59 AC_CONFIG_MAKEFILE(runtime/Makefile)
  60 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/Makefile)
  61 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/crtend/Makefile)
  62 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libc/Makefile)
  63 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libcurses/Makefile)
  64 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libexception/Makefile)
  65 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libg/Makefile)
  66 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libgcc/Makefile)
  67 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libm/Makefile)
  68 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libmalloc/Makefile)
  69 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libtermcap/Makefile)
  70 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libucb/Makefile)
  71 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libutempter/Makefile)
  72 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libutil/Makefile)
  73 AC_CONFIG_MAKEFILE(runtime/libdummy/Makefile)
  74 AC_CONFIG_MAKEFILE(runtime/libtrace/Makefile)
  75 AC_CONFIG_MAKEFILE(test/Makefile)
  76 AC_CONFIG_MAKEFILE(test/Makefile.tests)
  77 AC_CONFIG_MAKEFILE(test/Programs/Makefile)
  78 AC_CONFIG_MAKEFILE(test/Programs/Makefile.programs)
  79 AC_CONFIG_MAKEFILE(test/Programs/TEST.aa.Makefile)
  80 AC_CONFIG_MAKEFILE(test/Programs/TEST.dsgraph.report)
  81 AC_CONFIG_MAKEFILE(test/Programs/TEST.micro.report)
  82 AC_CONFIG_MAKEFILE(test/Programs/TEST.aa.report)
  83 AC_CONFIG_MAKEFILE(test/Programs/TEST.example.Makefile)
  84 AC_CONFIG_MAKEFILE(test/Programs/TEST.nightly.Makefile)
  85 AC_CONFIG_MAKEFILE(test/Programs/TEST.buildrepo.Makefile)
  86 AC_CONFIG_MAKEFILE(test/Programs/TEST.jit.Makefile)
  87 AC_CONFIG_MAKEFILE(test/Programs/TEST.nightly.report)
  88 AC_CONFIG_MAKEFILE(test/Programs/TEST.dsgraph.Makefile)
  89 AC_CONFIG_MAKEFILE(test/Programs/TEST.jit.report)
  90 AC_CONFIG_MAKEFILE(test/Programs/TEST.typesafe.Makefile)
  91 AC_CONFIG_MAKEFILE(test/Programs/TEST.dsgraph.gnuplot)
  92 AC_CONFIG_MAKEFILE(test/Programs/TEST.micro.Makefile)
  93 AC_CONFIG_MAKEFILE(test/Programs/External/Makefile)
  94 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/Makefile)
  95 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/Makefile.spec)
  96 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CFP2000/Makefile)
  97 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CFP2000/179.art/Makefile)
  98 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CFP2000/183.equake/Makefile)
  99 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CFP2000/188.ammp/Makefile)
 100 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/Makefile)
 101 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/164.gzip/Makefile)
 102 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/175.vpr/Makefile)
 103 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/176.gcc/Makefile)
 104 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/181.mcf/Makefile)
 105 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/186.crafty/Makefile)
 106 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/197.parser/Makefile)
 107 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/254.gap/Makefile)
 108 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/255.vortex/Makefile)
 109 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/256.bzip2/Makefile)
 110 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/300.twolf/Makefile)
 111 AC_CONFIG_MAKEFILE(test/Programs/LLVMSource/Makefile)
 112 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Makefile)
 113 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Makefile.multisrc)
 114 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Applications/Makefile)
 115 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Applications/Burg/Makefile)
 116 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Applications/aha/Makefile)
 117 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Applications/sgefa/Makefile)
 118 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Makefile)
 119 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Fhourstones/Makefile)
 120 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/Makefile)
 121 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/01-qbsort/Makefile)
 122 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/03-testtrie/Makefile)
 123 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/04-bisect/Makefile)
 124 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/05-eks/Makefile)
 125 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/08-main/Makefile)
 126 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/09-vor/Makefile)
 127 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/12-IOtest/Makefile)
 128 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/15-trie/Makefile)
 129 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/17-bintr/Makefile)
 130 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/18-imp/Makefile)
 131 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/Makefile)
 132 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/bh/Makefile)
 133 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/bisort/Makefile)
 134 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/em3d/Makefile)
 135 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/health/Makefile)
 136 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/mst/Makefile)
 137 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/perimeter/Makefile)
 138 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/power/Makefile)
 139 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/treeadd/Makefile)
 140 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/tsp/Makefile)
 141 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/voronoi/Makefile)
 142 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/OptimizerEval/Makefile)
 143 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/Makefile)
 144 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/anagram/Makefile)
 145 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/bc/Makefile)
 146 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/ft/Makefile)
 147 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/ks/Makefile)
 148 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/yacr2/Makefile)
 149 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/llubenchmark/Makefile)
 150 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/sim/Makefile)
 151 AC_CONFIG_MAKEFILE(test/Programs/NoSource/Makefile)
 152 AC_CONFIG_MAKEFILE(test/Programs/NoSource/Flex/Makefile)
 153 AC_CONFIG_MAKEFILE(test/Programs/NoSource/Larn/Makefile)
 154 AC_CONFIG_MAKEFILE(test/Programs/NoSource/Moria-5.5.2/Makefile)
 155 AC_CONFIG_MAKEFILE(test/Programs/NoSource/Povray31/Makefile)
 156 AC_CONFIG_MAKEFILE(test/Programs/NoSource/m4/Makefile)
 157 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Makefile)
 158 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Makefile.singlesrc)
 159 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Gizmos/Makefile)
 160 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Benchmarks/Makefile)
 161 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Benchmarks/Dhrystone/Makefile)
 162 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Benchmarks/Shootout/Makefile)
 163 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Benchmarks/Stanford/Makefile)
 164 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Benchmarks/Misc/Makefile)
 165 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/CustomChecked/Makefile)
 166 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/UnitTests/Makefile)
 167 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/UnitTests/SetjmpLongjmp/Makefile)
 168 AC_CONFIG_MAKEFILE(tools/Makefile)
 169 AC_CONFIG_MAKEFILE(tools/analyze/Makefile)
 170 AC_CONFIG_MAKEFILE(tools/as/Makefile)
 171 AC_CONFIG_MAKEFILE(tools/bugpoint/Makefile)
 172 AC_CONFIG_MAKEFILE(tools/dis/Makefile)
 173 AC_CONFIG_MAKEFILE(tools/extract/Makefile)
 174 AC_CONFIG_MAKEFILE(tools/gccas/Makefile)
 175 AC_CONFIG_MAKEFILE(tools/gccld/Makefile)
 176 AC_CONFIG_MAKEFILE(tools/link/Makefile)
 177 AC_CONFIG_MAKEFILE(tools/llc/Makefile)
 178 AC_CONFIG_MAKEFILE(tools/lli/Makefile)
 179 AC_CONFIG_MAKEFILE(tools/opt/Makefile)
 180 AC_CONFIG_MAKEFILE(tools/llee/Makefile)
 181 AC_CONFIG_MAKEFILE(tools/llvm-as/Makefile)
 182 AC_CONFIG_MAKEFILE(tools/llvm-dis/Makefile)
 183 AC_CONFIG_MAKEFILE(utils/Makefile)
 184 AC_CONFIG_MAKEFILE(utils/Burg/Makefile)
 185 AC_CONFIG_MAKEFILE(utils/Burg/Doc/Makefile)
 186 AC_CONFIG_MAKEFILE(utils/TableGen/Makefile)
 187 AC_CONFIG_MAKEFILE(www/docs/Makefile)
 188 AC_CONFIG_MAKEFILE(projects/Makefile)
 189 AC_CONFIG_MAKEFILE(projects/sample/Makefile)
 190 AC_CONFIG_MAKEFILE(projects/sample/Makefile.common)
 191 AC_CONFIG_MAKEFILE(projects/sample/Makefile.config)
 192 AC_CONFIG_MAKEFILE(projects/sample/lib/Makefile)
 193 AC_CONFIG_MAKEFILE(projects/sample/lib/sample/Makefile)
 194 AC_CONFIG_MAKEFILE(projects/sample/tools/Makefile)
 195 AC_CONFIG_MAKEFILE(projects/sample/tools/sample/Makefile)
 196 AC_CONFIG_MAKEFILE(projects/ModuleMaker/Makefile)
 197 AC_CONFIG_MAKEFILE(projects/ModuleMaker/Makefile.common)
 198 AC_CONFIG_MAKEFILE(projects/ModuleMaker/tools/Makefile)
 199 AC_CONFIG_MAKEFILE(projects/ModuleMaker/tools/ModuleMaker/Makefile)
 200
 201 dnl **************************************************************************
 202 dnl * Determine which system we are building on
 203 dnl **************************************************************************
 204
 205 dnl Check the install program (needs to be done before canonical stuff)
 206 AC_PROG_INSTALL
 207
 208 dnl Check which host for which we're compiling.  This will tell us which LLVM
 209 dnl compiler will be used for compiling SSA into object code.
 210 AC_CANONICAL_TARGET
 211
 212 dnl
 213 dnl Now, for some of our own magic:
 214 dnl We will use the build machine information to set some variables.
 215 dnl
 216 case $build in
 217         *i*86*)  AC_SUBST(OS,[Linux])
 218                  AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/x86/llvm-gcc/])
 219                  ;;
 220
 221         *sparc*) AC_SUBST(OS,[SunOS])
 222                  AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/sparc/llvm-gcc/])
 223                  ;;
 224
 225         *)       AC_SUBST(OS,[Unknown])
 226                  ;;
 227 esac
 228
 229 dnl
 230 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
 231 dnl V9, since that is all that we support at the moment, and autoconf will only
 232 dnl tell us we're a sparc.
 233 dnl
 234 case $target in
 235         *sparc*solaris*)  AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
 236                           ;;
 237 esac
 238
 239 dnl
 240 dnl Determine what our target architecture is and configure accordingly.
 241 dnl This will allow Makefiles to make a distinction between the hardware and
 242 dnl the OS.
 243 dnl
 244 case $target in
 245         *i*86*)           AC_SUBST(ARCH,[x86])
 246                           ;;
 247         *sparc*solaris*)  AC_SUBST(ARCH,[Sparc])
 248                           ;;
 249 esac
 250
 251 dnl **************************************************************************
 252 dnl * Check for programs.
 253 dnl **************************************************************************
 254
 255 dnl Check for compilation tools
 256 AC_PROG_CXX
 257 AC_PROG_CC(gcc)
 258 AC_PROG_CPP
 259
 260 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 261 if test "$GCC" != "yes"
 262 then
 263         AC_MSG_ERROR([gcc required but not found])
 264 fi
 265
 266 if test "$GXX" != "yes"
 267 then
 268         AC_MSG_ERROR([g++ required but not found])
 269 fi
 270
 271 dnl Verify that GCC is version 3.0 or higher
 272 gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 273 if test "$gccmajor" -lt "3"
 274 then
 275         AC_MSG_ERROR([gcc 3.x required])
 276 fi
 277
 278 dnl Check for GNU Make.  We use its extensions to, so don't build without it
 279 CHECK_GNU_MAKE
 280 if test -z "$_cv_gnu_make_command"
 281 then
 282         AC_MSG_ERROR([GNU Make required but not found])
 283 fi
 284
 285 dnl Check for compiler-compiler tools (reminds me of Little Caesar's Pizza)
 286 AC_PROG_FLEX
 287 AC_PROG_BISON
 288
 289 dnl Check for libtool
 290 AC_PROG_LIBTOOL
 291
 292 dnl Check for our special programs
 293 AC_PATH_PROG(RPWD,[pwd])
 294 AC_PATH_PROG(AR,[ar])
 295 AC_PATH_PROG(SED,[sed])
 296 AC_PATH_PROG(RM,[rm])
 297 AC_PATH_PROG(ECHO,[echo])
 298 AC_PATH_PROG(MKDIR,[mkdir])
 299 AC_PATH_PROG(DATE,[date])
 300 AC_PATH_PROG(MV,[mv])
 301 AC_PATH_PROG(DOT,[dot])
 302 AC_PATH_PROG(ETAGS,[etags])
 303 AC_PATH_PROG(PURIFY,[purify])
 304 AC_PATH_PROG(PYTHON,[python])
 305 AC_PATH_PROG(QMTEST,[qmtest])
 306
 307 dnl Verify that the version of python available is high enough for qmtest
 308 pyversion=`$PYTHON -V 2>&1 | cut -d\  -f2`
 309 pymajor=`echo $pyversion | cut -d. -f1`
 310 pyminor=`echo $pyversion | cut -d. -f2`
 311
 312 if test "$pymajor" -ge "2"
 313 then
 314         if test "$pymajor" -eq "2"
 315         then
 316                 if test "$pyminor" -lt "2"
 317                 then
 318                         AC_MSG_ERROR([Python 2.2 or greater required])
 319                 fi
 320         fi
 321 else
 322         AC_MSG_ERROR([Python 2.2 or greater required])
 323 fi
 324
 325 dnl Verify that the source directory is valid
 326 AC_CONFIG_SRCDIR(["Makefile.config.in"])
 327
 328 dnl **************************************************************************
 329 dnl * Check for libraries.
 330 dnl **************************************************************************
 331
 332 dnl libelf is for sparc only; we can ignore it if we don't have it
 333 AC_CHECK_LIB(elf, elf_begin)
 334
 335 dnl dlopen() is required.  If we don't find it, quit.
 336 AC_SEARCH_LIBS(dlopen,dl,,AC_MSG_ERROR([dlopen() required but not found]))
 337
 338 dnl mallinfo is optional; the code can compile (minus features) without it
 339 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1]))
 340
 341 dnl
 342 dnl The math libraries are used by the test code, but not by the actual LLVM
 343 dnl code.
 344 dnl
 345 dnl AC_CHECK_LIB(m, cos)
 346
 347 dnl **************************************************************************
 348 dnl * Checks for header files.
 349 dnl *   Chances are, if the standard C or POSIX type header files are missing,
 350 dnl *   then LLVM just isn't going to compile.  However, it is possible that
 351 dnl *   the necessary functions/macros will be included from other
 352 dnl *   (non-standard and non-obvious) header files.
 353 dnl *
 354 dnl *   So, we'll be gracious, give it a chance, and try to go on without
 355 dnl *   them.
 356 dnl **************************************************************************
 357 AC_HEADER_STDC
 358 AC_HEADER_SYS_WAIT
 359
 360 dnl Check for ANSI C/POSIX header files
 361 AC_CHECK_HEADERS(assert.h fcntl.h limits.h sys/time.h unistd.h errno.h signal.h math.h)
 362
 363 dnl Check for system specific header files
 364 AC_CHECK_HEADERS(malloc.h strings.h sys/mman.h sys/resource.h)
 365
 366 dnl Check for header files associated with dlopen and friends
 367 AC_CHECK_HEADERS(dlfcn.h link.h)
 368
 369 dnl **************************************************************************
 370 dnl * Checks for typedefs, structures, and compiler characteristics.
 371 dnl **************************************************************************
 372
 373 dnl Check for const and inline keywords
 374 AC_C_CONST
 375 AC_C_INLINE
 376
 377 dnl Check for machine endian-ness
 378 AC_C_BIGENDIAN(AC_DEFINE([ENDIAN_BIG]),AC_DEFINE(ENDIAN_LITTLE))
 379
 380 dnl Check for types
 381 AC_TYPE_PID_T
 382 AC_TYPE_SIZE_T
 383 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 384 AC_CHECK_TYPES([uint64_t],,AC_MSG_ERROR([Type uint64_t required but not found]))
 385 AC_HEADER_TIME
 386 AC_STRUCT_TM
 387
 388 dnl Check for C++ extensions
 389 AC_CXX_HAVE_EXT_HASH_MAP
 390 AC_CXX_HAVE_EXT_HASH_SET
 391 AC_CXX_HAVE_EXT_SLIST
 392 AC_CXX_HAVE_STD_ITERATOR
 393 AC_CXX_HAVE_BI_ITERATOR
 394 AC_CXX_HAVE_FWD_ITERATOR
 395
 396 dnl **************************************************************************
 397 dnl * Checks for library functions.
 398 dnl **************************************************************************
 399 AC_FUNC_ALLOCA
 400 AC_PROG_GCC_TRADITIONAL
 401 AC_FUNC_MEMCMP
 402 AC_FUNC_MMAP
 403 AC_FUNC_MMAP_FILE
 404 if test ${ac_cv_func_mmap_file} = "no"
 405 then
 406         AC_MSG_ERROR([mmap() of files required but not found])
 407 fi
 408 AC_HEADER_MMAP_ANONYMOUS
 409 AC_TYPE_SIGNAL
 410 AC_CHECK_FUNCS(getcwd gettimeofday strcspn strdup strerror strspn strstr strtod strtol)
 411
 412 dnl
 413 dnl Need to check mmap for MAP_PRIVATE, MAP_ANONYMOUS, MAP_ANON, MAP_FIXED
 414 dnl MAP_FIXED is only needed for Sparc
 415 dnl MAP_ANON is used for Sparc and BSD
 416 dnl Everyone should have MAP_PRIVATE
 417 dnl
 418
 419 dnl Check for certain functions (even if we've already found them) so that we
 420 dnl can quit with an error if they are unavailable.
 421 dnl
 422 dnl As the code is made more portable (i.e. less reliant on these functions,
 423 dnl these checks should go away.
 424 AC_CHECK_FUNC(mmap,,AC_MSG_ERROR([Function mmap() required but not found]))
 425 AC_CHECK_FUNC(mprotect,,AC_MSG_ERROR([Function mprotect() required but not found]))
 426
 427 dnl **************************************************************************
 428 dnl * Enable various compile-time options
 429 dnl **************************************************************************
 430
 431 dnl Purify Option
 432 AC_ARG_ENABLE(purify,AC_HELP_STRING([--enable-purify],[Compile with purify (default is NO)]),,enableval="no")
 433 if test ${enableval} = "no"
 434 then
 435         AC_SUBST(ENABLE_PURIFY,[[]])
 436 else
 437         AC_SUBST(ENABLE_PURIFY,[[ENABLE_PURIFY=1]])
 438 fi
 439
 440 dnl Optimized Option
 441 AC_ARG_ENABLE(optimized,AC_HELP_STRING([--enable-optimized],[Compile with optimizations enabled (default is NO)]),,enableval=no)
 442 if test ${enableval} = "no"
 443 then
 444         AC_SUBST(ENABLE_OPTIMIZED,[[]])
 445 else
 446         AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 447 fi
 448
 449 dnl Spec Benchmarks
 450 AC_ARG_ENABLE(spec,AC_HELP_STRING([--enable-spec],[Compile SPEC benchmarks (default is NO)]),,enableval=no)
 451 if test ${enableval} = "no"
 452 then
 453         AC_SUBST(USE_SPEC,[[]])
 454 else
 455         AC_SUBST(USE_SPEC,[[USE_SPEC=1]])
 456 fi
 457
 458 dnl Precompiled Bytecode Option
 459 AC_ARG_ENABLE(precompiled_bytecode,AC_HELP_STRING([--enable-precompiled_bytecode],[Use pre-compiled bytecode (default is NO)]),,enableval=no)
 460 if test ${enableval} = "no"
 461 then
 462         AC_SUBST(UPB,[[]])
 463 else
 464         AC_SUBST(UPB,[[USE_PRECOMPILED_BYTECODE=1]])
 465 fi
 466
 467
 468 dnl LLC Diff Option
 469 AC_ARG_ENABLE(llc_diffs,AC_HELP_STRING([--enable-llc_diffs],[Enable LLC Diffs when testing (default is YES)]),,enableval=yes)
 470 if test ${enableval} = "no"
 471 then
 472         AC_SUBST(DISABLE_LLC_DIFFS,[DISABLE_LLC_DIFFS:=1])
 473 else
 474         AC_SUBST(DISABLE_LLC_DIFFS,[[]])
 475 fi
 476
 477 dnl JIT Option
 478 AC_ARG_ENABLE(jit,AC_HELP_STRING([--enable-jit],[Enable Just In Time Compiling (default is YES)]),,enableval=default)
 479
 480 if test ${enableval} = "no"
 481 then
 482         AC_SUBST(JIT,[[]])
 483 else
 484         case $target in
 485                 *i*86*)
 486                         AC_SUBST(JIT,[[TARGET_HAS_JIT=1]])
 487                         ;;
 488                 *sparc*)
 489                         AC_SUBST(JIT,[[TARGET_HAS_JIT=1]])
 490                         ;;
 491                 *)
 492                         AC_SUBST(JIT,[[]])
 493                         ;;
 494         esac
 495 fi
 496
 497 dnl **************************************************************************
 498 dnl * Set the location of various third-party software packages
 499 dnl **************************************************************************
 500
 501 dnl Location of SPEC benchmarks
 502 AC_ARG_WITH(spec,AC_HELP_STRING([--with-spec],[Location of SPEC benchmarks]),AC_SUBST(SPEC_ROOT,[$withval]),AC_SUBST(SPEC_ROOT,[/home/vadve/shared/benchmarks/speccpu2000/benchspec]))
 503
 504 dnl Location of the LLVM C front end
 505 AC_ARG_WITH(llvmgccdir,AC_HELP_STRING([--with-llvmgccdir],[Location of LLVM GCC front-end]),AC_SUBST(LLVMGCCDIR,[$withval]))
 506
 507 dnl Location of the bytecode repository
 508 AC_ARG_WITH(bcrepos,AC_HELP_STRING([--with-bcrepos],[Location of Bytecode Repository]),AC_SUBST(BCR,[$withval]),AC_SUBST(BCR,[/home/vadve/lattner/LLVMPrograms]))
 509
 510 dnl Location of PAPI
 511 AC_ARG_WITH(papi,AC_HELP_STRING([--with-papi],[Location of PAPI]),AC_SUBST(PAPIDIR,[$withval]),AC_SUBST(PAPIDIR,[/home/vadve/shared/Sparc/papi-2.3.4.1]))
 512
 513 dnl Location of the purify program
 514 AC_ARG_WITH(purify,AC_HELP_STRING([--with-purify],[Location of purify program]),AC_SUBST(PURIFY,[$withval]))
 515
 516 dnl **************************************************************************
 517 dnl * Configure other software packages (via AC_CONFIG_SUBDIRS)
 518 dnl **************************************************************************
 519
 520 dnl **************************************************************************
 521 dnl * Create the output files
 522 dnl **************************************************************************
 523 AC_OUTPUT(Makefile.config)