autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.0cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  80       *)
  81         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  82         ;;
  83     esac
  84   fi
  85 done
  86
  87 dnl===-----------------------------------------------------------------------===
  88 dnl===
  89 dnl=== SECTION 2: Architecture, target, and host checks
  90 dnl===
  91 dnl===-----------------------------------------------------------------------===
  92
  93 dnl Check the target for which we're compiling and the host that will do the
  94 dnl compilations. This will tell us which LLVM compiler will be used for
  95 dnl compiling SSA into object code. This needs to be done early because
  96 dnl following tests depend on it.
  97 AC_CANONICAL_TARGET
  98
  99 dnl Determine the platform type and cache its value. This helps us configure
 100 dnl the System library to the correct build platform.
 101 AC_CACHE_CHECK([type of operating system we're going to host on],
 102                [llvm_cv_os_type],
 103 [case $host in
 104   *-*-aix*)
 105     llvm_cv_link_all_option="-Wl,--whole-archive"
 106     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 107     llvm_cv_os_type="AIX"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-irix*)
 110     llvm_cv_link_all_option="-Wl,--whole-archive"
 111     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 112     llvm_cv_os_type="IRIX"
 113     llvm_cv_platform_type="Unix" ;;
 114   *-*-cygwin*)
 115     llvm_cv_link_all_option="-Wl,--whole-archive"
 116     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 117     llvm_cv_os_type="Cygwin"
 118     llvm_cv_platform_type="Unix" ;;
 119   *-*-darwin*)
 120     llvm_cv_link_all_option="-Wl,-all_load"
 121     llvm_cv_link_all_option="-Wl,-noall_load"
 122     llvm_cv_os_type="Darwin"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-freebsd*)
 125     llvm_cv_link_all_option="-Wl,--whole-archive"
 126     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 127     llvm_cv_os_type="FreeBSD"
 128     llvm_cv_platform_type="Unix" ;;
 129   *-*-openbsd*)
 130     llvm_cv_link_all_option="-Wl,--whole-archive"
 131     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 132     llvm_cv_os_type="OpenBSD"
 133     llvm_cv_platform_type="Unix" ;;
 134   *-*-netbsd*)
 135     llvm_cv_link_all_option="-Wl,--whole-archive"
 136     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 137     llvm_cv_os_type="NetBSD"
 138     llvm_cv_platform_type="Unix" ;;
 139   *-*-hpux*)
 140     llvm_cv_link_all_option="-Wl,--whole-archive"
 141     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 142     llvm_cv_os_type="HP-UX"
 143     llvm_cv_platform_type="Unix" ;;
 144   *-*-interix*)
 145     llvm_cv_link_all_option="-Wl,--whole-archive"
 146     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 147     llvm_cv_os_type="Interix"
 148     llvm_cv_platform_type="Unix" ;;
 149   *-*-linux*)
 150     llvm_cv_link_all_option="-Wl,--whole-archive"
 151     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 152     llvm_cv_os_type="Linux"
 153     llvm_cv_platform_type="Unix" ;;
 154   *-*-solaris*)
 155     llvm_cv_link_all_option="-Wl,-z,allextract"
 156     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 157     llvm_cv_os_type="SunOS"
 158     llvm_cv_platform_type="Unix" ;;
 159   *-*-win32*)
 160     llvm_cv_link_all_option="-Wl,--whole-archive"
 161     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 162     llvm_cv_os_type="Win32"
 163     llvm_cv_platform_type="Win32" ;;
 164   *-*-mingw*)
 165     llvm_cv_link_all_option="-Wl,--whole-archive"
 166     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 167     llvm_cv_os_type="MingW"
 168     llvm_cv_platform_type="Win32" ;;
 169   *)
 170     llvm_cv_link_all_option=""
 171     llvm_cv_no_link_all_option=""
 172     llvm_cv_os_type="Unknown"
 173     llvm_cv_platform_type="Unknown" ;;
 174 esac])
 175
 176 dnl Make sure we aren't attempting to configure for an unknown system
 177 if test "$llvm_cv_os_type" = "Unknown" ; then
 178   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 179 fi
 180
 181 dnl Set the "OS" Makefile variable based on the platform type so the
 182 dnl makefile can configure itself to specific build hosts
 183 AC_SUBST(OS,$llvm_cv_os_type)
 184
 185 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 186 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 187 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 188
 189 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 190 dnl This is used by lib/System to determine the basic kind of implementation
 191 dnl to use.
 192 case $llvm_cv_platform_type in
 193   Unix)
 194     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 195     AC_SUBST(LLVM_ON_UNIX,[1])
 196     AC_SUBST(LLVM_ON_WIN32,[0])
 197     ;;
 198   Win32)
 199     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 200     AC_SUBST(LLVM_ON_UNIX,[0])
 201     AC_SUBST(LLVM_ON_WIN32,[1])
 202     ;;
 203 esac
 204
 205 dnl Determine what our target architecture is and configure accordingly.
 206 dnl This will allow Makefiles to make a distinction between the hardware and
 207 dnl the OS.
 208 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 209 [case $target in
 210   i?86-*)                 llvm_cv_target_arch="x86" ;;
 211   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 212   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 213   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 214   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 215   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 216   *)                      llvm_cv_target_arch="Unknown" ;;
 217 esac])
 218
 219 if test "$llvm_cv_target_arch" = "Unknown" ; then
 220   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 221 fi
 222
 223 dnl Define a substitution, ARCH, for the target architecture
 224 AC_SUBST(ARCH,$llvm_cv_target_arch)
 225
 226 dnl Check for the endianness of the target
 227 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 228
 229 dnl Check for build platform executable suffix if we're crosscompiling
 230 if test "$cross_compiling" = yes; then
 231   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 232   AC_BUILD_EXEEXT
 233 else
 234   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 235 fi
 236
 237 dnl Check to see if there's a "CVS" directory indicating that this build is
 238 dnl being done from a CVS checkout. This sets up several defaults for the
 239 dnl command line switches. When we build with a CVS directory, we get a
 240 dnl debug with assertions turned on. Without, we assume a source release and we
 241 dnl get an optimized build without assertions. See --enable-optimized and
 242 dnl --enable-assertions below
 243 if test -d "CVS" -o -d "${srcdir}/CVS"; then
 244   cvsbuild="yes"
 245   optimize="no"
 246   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 247 else
 248   cvsbuild="no"
 249   optimize="yes"
 250 fi
 251
 252 dnl===-----------------------------------------------------------------------===
 253 dnl===
 254 dnl=== SECTION 3: Command line arguments for the configure script.
 255 dnl===
 256 dnl===-----------------------------------------------------------------------===
 257
 258 dnl --enable-optimized : check whether they want to do an optimized build:
 259 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 260  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 261 if test ${enableval} = "no" ; then
 262   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 263 else
 264   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 265 fi
 266
 267 dnl --enable-assertions : check whether they want to turn on assertions or not:
 268 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 269   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 270 if test ${enableval} = "yes" ; then
 271   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 272 else
 273   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 274 fi
 275
 276 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 277 AC_ARG_ENABLE(debug-runtime,
 278    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 279 if test ${enableval} = "no" ; then
 280   AC_SUBST(DEBUG_RUNTIME,[[]])
 281 else
 282   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 283 fi
 284
 285 dnl --enable-jit: check whether they want to enable the jit
 286 AC_ARG_ENABLE(jit,
 287   AS_HELP_STRING(--enable-jit,
 288                  [Enable Just In Time Compiling (default is YES)]),,
 289   enableval=default)
 290 if test ${enableval} = "no"
 291 then
 292   AC_SUBST(JIT,[[]])
 293 else
 294   case "$llvm_cv_target_arch" in
 295     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 296     Sparc)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 297     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 298     x86_64)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 299     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 300     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 301     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 302   esac
 303 fi
 304
 305 dnl Allow enablement of doxygen generated documentation
 306 AC_ARG_ENABLE(doxygen,
 307               AS_HELP_STRING([--enable-doxygen],
 308                              [Build doxygen documentation (default is NO)]),,
 309                              enableval=default)
 310 case "$enableval" in
 311   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 312   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 313   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 314   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 315 esac
 316
 317 dnl Allow disablement of threads
 318 AC_ARG_ENABLE(threads,
 319               AS_HELP_STRING([--enable-threads],
 320                              [Use threads if available (default is YES)]),,
 321                              enableval=default)
 322 case "$enableval" in
 323   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 324   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 325   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 326   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 327 esac
 328 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 329
 330 dnl Allow building with position independent code
 331 AC_ARG_ENABLE(pic,
 332   AS_HELP_STRING([--enable-pic],
 333                  [Build LLVM with Position Independent Code (default is NO)]),,
 334                  enableval=default)
 335 case "$enableval" in
 336   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 337   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 338   default) AC_SUBST(ENABLE_PIC,[0]) ;;
 339   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 340 esac
 341 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 342                    [Define if position independent code is enabled])
 343
 344 dnl Allow specific targets to be specified for building (or not)
 345 TARGETS_TO_BUILD=""
 346 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 347     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 348     enableval=all)
 349 case "$enableval" in
 350   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM" ;;
 351   host-only)
 352     case "$llvm_cv_target_arch" in
 353       x86)     TARGETS_TO_BUILD="X86" ;;
 354       x86_64)  TARGETS_TO_BUILD="X86" ;;
 355       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 356       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 357       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 358       IA64)    TARGETS_TO_BUILD="IA64" ;;
 359       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 360     esac
 361     ;;
 362   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 363       case "$a_target" in
 364         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 365         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 366         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 367         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 368         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 369         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 370         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 371       esac
 372   done
 373   ;;
 374 esac
 375 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 376 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 377
 378 dnl Prevent the CBackend from using printf("%a") for floating point so older
 379 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 380 dnl can still compile the CBE's output
 381 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 382   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 383   enableval=default)
 384 case "$enableval" in
 385   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 386   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 387   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 388   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 389 esac
 390 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 391                    [Define if CBE is enabled for printf %a output])
 392
 393 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 394 AC_ARG_WITH(llvmgccdir,
 395   AS_HELP_STRING([--with-llvmgccdir],
 396     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 397     withval=default)
 398 case "$withval" in
 399   default) WITH_LLVMGCCDIR=default ;;
 400   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 401   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 402 esac
 403
 404 dnl Specify extra build options
 405 AC_ARG_WITH(extra-options,
 406   AS_HELP_STRING([--with-extra-options],
 407                  [Specify addtional options to compile LLVM with]),,
 408                  withval=default)
 409 case "$withval" in
 410   default) EXTRA_OPTIONS= ;;
 411   *) EXTRA_OPTIONS=$withval ;;
 412 esac
 413 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 414
 415 dnl===-----------------------------------------------------------------------===
 416 dnl===
 417 dnl=== SECTION 4: Check for programs we need and that they are the right version
 418 dnl===
 419 dnl===-----------------------------------------------------------------------===
 420
 421 dnl Check for compilation tools
 422 AC_PROG_CPP
 423 AC_PROG_CC(gcc)
 424 AC_PROG_CXX(g++)
 425 AC_PROG_FLEX
 426 AC_PROG_BISON
 427
 428 AC_PROG_NM
 429 AC_SUBST(NM)
 430
 431 dnl Check for the tools that the makefiles require
 432 AC_CHECK_GNU_MAKE
 433 AC_PROG_LN_S
 434 AC_PATH_PROG(CMP, [cmp], [cmp])
 435 AC_PATH_PROG(CP, [cp], [cp])
 436 AC_PATH_PROG(DATE, [date], [date])
 437 AC_PATH_PROG(FIND, [find], [find])
 438 AC_PATH_PROG(GREP, [grep], [grep])
 439 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 440 AC_PATH_PROG(MV,   [mv],   [mv])
 441 AC_PROG_RANLIB
 442 AC_PATH_PROG(RM,   [rm],   [rm])
 443 AC_PATH_PROG(SED,  [sed],  [sed])
 444 AC_PATH_PROG(TAR,  [tar],  [gtar])
 445 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 446
 447 dnl Looking for misc. graph plotting software
 448 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 449 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 450   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 451   dnl If we're targeting for mingw we should emit windows paths, not msys
 452   if test "$llvm_cv_os_type" = "MingW" ; then
 453     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 454   fi
 455   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 456    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 457 fi
 458 AC_PATH_PROG(DOT, [dot], [echo dot])
 459 if test "$DOT" != "echo dot" ; then
 460   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 461   dnl If we're targeting for mingw we should emit windows paths, not msys
 462   if test "$llvm_cv_os_type" = "MingW" ; then
 463     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 464   fi
 465   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 466    [Define to path to dot program if found or 'echo dot' otherwise])
 467 fi
 468 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 469 if test "$GV" != "echo gv" ; then
 470   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 471   dnl If we're targeting for mingw we should emit windows paths, not msys
 472   if test "$llvm_cv_os_type" = "MingW" ; then
 473     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 474   fi
 475   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 476    [Define to path to gv program if found or 'echo gv' otherwise])
 477 fi
 478 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 479 if test "$DOTTY" != "echo dotty" ; then
 480   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 481   dnl If we're targeting for mingw we should emit windows paths, not msys
 482   if test "$llvm_cv_os_type" = "MingW" ; then
 483     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 484   fi
 485   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 486    [Define to path to dotty program if found or 'echo dotty' otherwise])
 487 fi
 488
 489 dnl Look for a sufficiently recent version of Perl.
 490 LLVM_PROG_PERL([5.006])
 491 AC_SUBST(PERL)
 492 if test x"$PERL" = xnone; then
 493    AC_SUBST(HAVE_PERL,0)
 494 else
 495    AC_SUBST(HAVE_PERL,1)
 496 fi
 497
 498 dnl Find the install program
 499 AC_PROG_INSTALL
 500
 501 dnl Checks for documentation and testing tools that we can do without. If these
 502 dnl are not found then they are set to "true" which always succeeds but does
 503 dnl nothing. This just lets the build output show that we could have done
 504 dnl something if the tool was available.
 505 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 506 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 507 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 508 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 509 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 510 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 511 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 512 DJ_AC_PATH_TCLSH
 513 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 514
 515 dnl Determine if the linker supports the -R option.
 516 AC_LINK_USE_R
 517
 518 dnl Check for libtool and the library that has dlopen function (which must come
 519 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 520 dnl libtool).
 521 AC_LIBTOOL_DLOPEN
 522 AC_LIB_LTDL
 523 AC_PROG_LIBTOOL
 524
 525 if test "$lt_cv_dlopen_self" = "yes" ; then
 526   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 527               [Define if dlopen(0) will open the symbols of the program])
 528 fi
 529
 530 dnl Check if we know how to tell etags we are using C++:
 531 etags_version=`$ETAGS --version 2>&1`
 532 case "$etags_version" in
 533         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 534         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 535         *) ETAGSFLAGS="" ;;
 536 esac
 537 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 538
 539 if test "$WITH_LLVMGCCDIR" = "default" ; then
 540   LLVMGCC="llvm-gcc${EXEEXT}"
 541   LLVMGXX="llvm-g++${EXEEXT}"
 542   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 543   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 544 else
 545   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 546   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 547   AC_SUBST(LLVMGCC,$LLVMGCC)
 548   AC_SUBST(LLVMGXX,$LLVMGXX)
 549 fi
 550
 551 AC_MSG_CHECKING([tool compatibility])
 552
 553 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 554 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 555 dnl to support those options.
 556 dnl "icc" emits gcc signatures
 557 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 558 ICC=no
 559 IXX=no
 560 case $CC in
 561   icc*|icpc*)
 562     ICC=yes
 563     IXX=yes
 564     ;;
 565    *)
 566     ;;
 567 esac
 568
 569 if test "$GCC" != "yes" && test "$ICC" != "yes"
 570 then
 571   AC_MSG_ERROR([gcc|icc required but not found])
 572 fi
 573
 574 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 575 if test "$GXX" != "yes" && test "$IXX" != "yes"
 576 then
 577   AC_MSG_ERROR([g++|icc required but not found])
 578 fi
 579
 580 dnl Verify that GCC is version 3.0 or higher
 581 if test "$GCC" = "yes"
 582 then
 583   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 584   if test "$gccmajor" -lt "3"
 585   then
 586     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 587   fi
 588 fi
 589
 590 dnl Check for GNU Make.  We use its extensions, so don't build without it
 591 if test -z "$llvm_cv_gnu_make_command"
 592 then
 593   AC_MSG_ERROR([GNU Make required but not found])
 594 fi
 595
 596 dnl Tool compatibility is okay if we make it here.
 597 AC_MSG_RESULT([ok])
 598
 599 dnl===-----------------------------------------------------------------------===
 600 dnl===
 601 dnl=== SECTION 5: Check for libraries
 602 dnl===
 603 dnl===-----------------------------------------------------------------------===
 604
 605 dnl libelf is for sparc only; we can ignore it if we don't have it
 606 AC_CHECK_LIB(elf, elf_begin)
 607 AC_CHECK_LIB(m,sin)
 608 if test "$llvm_cv_os_type" = "MingW" ; then
 609   AC_CHECK_LIB(imagehlp, main)
 610   AC_CHECK_LIB(psapi, main)
 611 fi
 612
 613 dnl lt_dlopen may be required for plugin support.
 614 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 615               [Define if lt_dlopen() is available on this platform]),
 616               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 617                            not be available]))
 618
 619 dnl dlopen() is required for plugin support.
 620 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 621                [Define if dlopen() is available on this platform.]),
 622                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 623
 624 dnl mallinfo is optional; the code can compile (minus features) without it
 625 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 626                [Define if mallinfo() is available on this platform.]))
 627
 628 dnl pthread locking functions are optional - but llvm will not be thread-safe
 629 dnl without locks.
 630 if test "$ENABLE_THREADS" -eq 1 ; then
 631   AC_CHECK_LIB(pthread,pthread_mutex_init)
 632   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 633                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 634                            [Have pthread_mutex_lock]))
 635 fi
 636
 637 dnl Allow extra x86-disassembler library
 638 AC_ARG_WITH(udis86,
 639   AS_HELP_STRING([--with-udis86=<path>],
 640     [Use udis86 external x86 disassembler library]),
 641     [
 642       AC_SUBST(USE_UDIS86, [1])
 643       case "$withval" in
 644         /usr/lib|yes) ;;
 645         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 646       esac
 647       AC_CHECK_LIB(udis86, ud_init, [], [
 648         echo "Error! You need to have libudis86 around."
 649         exit -1
 650       ])
 651     ],
 652     AC_SUBST(USE_UDIS86, [0]))
 653 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 654                    [Define if use udis86 library])
 655
 656 dnl===-----------------------------------------------------------------------===
 657 dnl===
 658 dnl=== SECTION 6: Check for header files
 659 dnl===
 660 dnl===-----------------------------------------------------------------------===
 661
 662 dnl First, use autoconf provided macros for specific headers that we need
 663 dnl We don't check for ancient stuff or things that are guaranteed to be there
 664 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 665 dnl Generally we're looking for POSIX headers.
 666 AC_HEADER_DIRENT
 667 AC_HEADER_MMAP_ANONYMOUS
 668 AC_HEADER_STAT
 669 AC_HEADER_STDC
 670 AC_HEADER_SYS_WAIT
 671 AC_HEADER_TIME
 672
 673 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 674 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 675 AC_CHECK_HEADERS([windows.h sys/mman.h sys/param.h sys/resource.h sys/time.h])
 676 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 677 if test "$ENABLE_THREADS" -eq 1 ; then
 678   AC_CHECK_HEADER(pthread.h,
 679                   AC_SUBST(HAVE_PTHREAD, 1),
 680                    AC_SUBST(HAVE_PTHREAD, 0))
 681 else
 682   AC_SUBST(HAVE_PTHREAD, 0)
 683 fi
 684
 685 dnl===-----------------------------------------------------------------------===
 686 dnl===
 687 dnl=== SECTION 7: Check for types and structures
 688 dnl===
 689 dnl===-----------------------------------------------------------------------===
 690
 691 AC_HUGE_VAL_CHECK
 692 AC_TYPE_PID_T
 693 AC_TYPE_SIZE_T
 694 AC_TYPE_SIGNAL
 695 AC_STRUCT_TM
 696 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 697 AC_CHECK_TYPES([uint64_t],,
 698          AC_CHECK_TYPES([u_int64_t],,
 699          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 700
 701 dnl===-----------------------------------------------------------------------===
 702 dnl===
 703 dnl=== SECTION 8: Check for specific functions needed
 704 dnl===
 705 dnl===-----------------------------------------------------------------------===
 706
 707 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 708 AC_CHECK_FUNCS([getpagesize getrusage gettimeofday isatty mkdtemp mkstemp ])
 709 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 710 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 711 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 712 AC_C_PRINTF_A
 713 AC_FUNC_ALLOCA
 714 AC_FUNC_RAND48
 715
 716 dnl Check for variations in the Standard C++ library and STL. These macros are
 717 dnl provided by LLVM in the autoconf/m4 directory.
 718 AC_CXX_HAVE_HASH_MAP
 719 AC_CXX_HAVE_HASH_SET
 720 AC_CXX_HAVE_STD_ITERATOR
 721 AC_CXX_HAVE_BI_ITERATOR
 722 AC_CXX_HAVE_FWD_ITERATOR
 723 AC_FUNC_ISNAN
 724 AC_FUNC_ISINF
 725
 726 dnl Check for mmap support.We also need to know if /dev/zero is required to
 727 dnl be opened for allocating RWX memory.
 728 dnl Make sure we aren't attempting to configure for an unknown system
 729 if test "$llvm_cv_platform_type" = "Unix" ; then
 730   AC_FUNC_MMAP
 731   AC_FUNC_MMAP_FILE
 732   AC_NEED_DEV_ZERO_FOR_MMAP
 733
 734   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 735   then
 736     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 737   fi
 738   if test "$ac_cv_func_mmap_file" = "no"
 739   then
 740     AC_MSG_WARN([mmap() of files required but not found])
 741   fi
 742 fi
 743
 744 dnl===-----------------------------------------------------------------------===
 745 dnl===
 746 dnl=== SECTION 9: Additional checks, variables, etc.
 747 dnl===
 748 dnl===-----------------------------------------------------------------------===
 749
 750 dnl See if the llvm-gcc executable can compile to LLVM assembly
 751 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 752 [llvm_cv_llvmgcc_sanity="no"
 753 if test -x "$LLVMGCC" ; then
 754   cp /dev/null conftest.c
 755   "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
 756   if test $? -eq 0 ; then
 757     llvm_cv_llvmgcc_sanity="yes"
 758   fi
 759   rm conftest.c
 760 fi])
 761
 762 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 763 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 764   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 765   AC_SUBST(LLVMCC1,$llvmcc1path)
 766   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 767   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 768   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 769   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 770   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 771   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 772   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 773   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 774   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 775   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 776 fi
 777
 778 dnl Propagate the shared library extension that the libltdl checks did to
 779 dnl the Makefiles so we can use it there too
 780 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 781
 782 # Translate the various configuration directories and other basic
 783 # information into substitutions that will end up in Makefile.config.in
 784 # that these configured values can be used by the makefiles
 785 if test "${prefix}" = "NONE" ; then
 786   prefix="/usr/local"
 787 fi
 788 eval LLVM_PREFIX="${prefix}";
 789 eval LLVM_BINDIR="${prefix}/bin";
 790 eval LLVM_LIBDIR="${prefix}/lib";
 791 eval LLVM_DATADIR="${prefix}/share/llvm";
 792 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 793 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 794 eval LLVM_INCLUDEDIR="${prefix}/include";
 795 eval LLVM_INFODIR="${prefix}/info";
 796 eval LLVM_MANDIR="${prefix}/man";
 797 LLVM_CONFIGTIME=`date`
 798 AC_SUBST(LLVM_PREFIX)
 799 AC_SUBST(LLVM_BINDIR)
 800 AC_SUBST(LLVM_LIBDIR)
 801 AC_SUBST(LLVM_DATADIR)
 802 AC_SUBST(LLVM_DOCSDIR)
 803 AC_SUBST(LLVM_ETCDIR)
 804 AC_SUBST(LLVM_INCLUDEDIR)
 805 AC_SUBST(LLVM_INFODIR)
 806 AC_SUBST(LLVM_MANDIR)
 807 AC_SUBST(LLVM_CONFIGTIME)
 808
 809 # Place the various directores into the config.h file as #defines so that we
 810 # can know about the installation paths within LLVM.
 811 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 812                    [Installation prefix directory])
 813 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 814                    [Installation directory for binary executables])
 815 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 816                    [Installation directory for libraries])
 817 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 818                    [Installation directory for data files])
 819 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 820                    [Installation directory for documentation])
 821 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 822                    [Installation directory for config files])
 823 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 824                    [Installation directory for include files])
 825 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 826                    [Installation directory for .info files])
 827 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 828                    [Installation directory for man pages])
 829 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 830                    [Time at which LLVM was configured])
 831
 832 dnl===-----------------------------------------------------------------------===
 833 dnl===
 834 dnl=== SECTION 10: Specify the output files and generate it
 835 dnl===
 836 dnl===-----------------------------------------------------------------------===
 837
 838 dnl Configure header files
 839 dnl WARNING: dnl If you add or remove any of the following config headers, then
 840 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 841 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 842 dnl files can be updated automatically when their *.in sources change.
 843 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 844 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 845 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 846 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 847 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 848
 849 dnl Configure the makefile's configuration data
 850 AC_CONFIG_FILES([Makefile.config])
 851
 852 dnl Configure the RPM spec file for LLVM
 853 AC_CONFIG_FILES([llvm.spec])
 854
 855 dnl Configure doxygen's configuration file
 856 AC_CONFIG_FILES([docs/doxygen.cfg])
 857
 858 dnl Do the first stage of configuration for llvm-config.in.
 859 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 860
 861 dnl Do special configuration of Makefiles
 862 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 863 AC_CONFIG_MAKEFILE(Makefile)
 864 AC_CONFIG_MAKEFILE(Makefile.common)
 865 AC_CONFIG_MAKEFILE(examples/Makefile)
 866 AC_CONFIG_MAKEFILE(lib/Makefile)
 867 AC_CONFIG_MAKEFILE(runtime/Makefile)
 868 AC_CONFIG_MAKEFILE(test/Makefile)
 869 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 870 AC_CONFIG_MAKEFILE(tools/Makefile)
 871 AC_CONFIG_MAKEFILE(utils/Makefile)
 872 AC_CONFIG_MAKEFILE(projects/Makefile)
 873
 874 dnl Finally, crank out the output
 875 AC_OUTPUT
 876