autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.7cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  78       "llvm-kernel")  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  79       *)
  80         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  81         ;;
  82     esac
  83   fi
  84 done
  85
  86 dnl===-----------------------------------------------------------------------===
  87 dnl===
  88 dnl=== SECTION 2: Architecture, target, and host checks
  89 dnl===
  90 dnl===-----------------------------------------------------------------------===
  91
  92 dnl Check the target for which we're compiling and the host that will do the
  93 dnl compilations. This will tell us which LLVM compiler will be used for
  94 dnl compiling SSA into object code. This needs to be done early because
  95 dnl following tests depend on it.
  96 AC_CANONICAL_TARGET
  97
  98 dnl Determine the platform type and cache its value. This helps us configure
  99 dnl the System library to the correct build platform.
 100 AC_CACHE_CHECK([type of operating system we're on],
 101                [llvm_cv_os_type],
 102 [case $build in
 103   *-*-aix*)
 104     llvm_cv_os_type="AIX"
 105     llvm_cv_platform_type="Unix" ;;
 106   *-*-cygwin*)
 107     llvm_cv_os_type="Cygwin"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-darwin*)
 110     llvm_cv_os_type="Darwin"
 111     llvm_cv_platform_type="Unix" ;;
 112   *-*-freebsd*)
 113     llvm_cv_os_type="FreeBSD"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-hpux*)
 116     llvm_cv_os_type="HP-UX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-interix*)
 119     llvm_cv_os_type="Interix"
 120     llvm_cv_platform_type="Unix" ;;
 121   *-*-linux*)
 122     llvm_cv_os_type="Linux"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-solaris*)
 125     llvm_cv_os_type="SunOS"
 126     llvm_cv_platform_type="Unix" ;;
 127   *-*-win32*)
 128     llvm_cv_os_type="Win32"
 129     llvm_cv_platform_type="Win32" ;;
 130   *-*-mingw*)
 131     llvm_cv_os_type="MingW"
 132     llvm_cv_platform_type="Win32" ;;
 133   *)
 134     llvm_cv_os_type="Unknown"
 135     llvm_cv_platform_type="Unknown" ;;
 136 esac])
 137
 138 dnl Make sure we aren't attempting to configure for an unknown system
 139 if test "$llvm_cv_os_type" = "Unknown" ; then
 140   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 141 fi
 142
 143 dnl Set the "OS" Makefile variable based on the platform type so the
 144 dnl makefile can configure itself to specific build hosts
 145 AC_SUBST(OS,$llvm_cv_os_type)
 146
 147 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 148 dnl This is used by lib/System to determine the basic kind of implementation
 149 dnl to use.
 150 case $llvm_cv_platform_type in
 151   Unix)
 152     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 153     AC_SUBST(LLVM_ON_UNIX,[1])
 154     AC_SUBST(LLVM_ON_WIN32,[0])
 155     ;;
 156   Win32)
 157     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 158     AC_SUBST(LLVM_ON_UNIX,[0])
 159     AC_SUBST(LLVM_ON_WIN32,[1])
 160     ;;
 161 esac
 162
 163 dnl Determine what our target architecture is and configure accordingly.
 164 dnl This will allow Makefiles to make a distinction between the hardware and
 165 dnl the OS.
 166 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 167 [case $target in
 168   i?86-*)                 llvm_cv_target_arch="x86" ;;
 169   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 170   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 171   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 172   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 173   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 174   *)                      llvm_cv_target_arch="Unknown" ;;
 175 esac])
 176
 177 if test "$llvm_cv_target_arch" = "Unknown" ; then
 178   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 179 fi
 180
 181 dnl Define a substitution, ARCH, for the target architecture
 182 AC_SUBST(ARCH,$llvm_cv_target_arch)
 183
 184 dnl Check for the endianness of the target
 185 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 186
 187 dnl===-----------------------------------------------------------------------===
 188 dnl===
 189 dnl=== SECTION 3: Command line arguments for the configure script.
 190 dnl===
 191 dnl===-----------------------------------------------------------------------===
 192
 193 dnl --enable-optimized : check whether they want to do an optimized build:
 194 AC_ARG_ENABLE(optimized,
 195               AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
 196 if test ${enableval} = "no" ; then
 197   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 198 else
 199   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 200 fi
 201
 202 dnl --enable-jit: check whether they want to enable the jit
 203 AC_ARG_ENABLE(jit,
 204   AS_HELP_STRING(--enable-jit,
 205                  [Enable Just In Time Compiling (default is YES)]),,
 206   enableval=default)
 207 if test ${enableval} = "no"
 208 then
 209   AC_SUBST(JIT,[[]])
 210 else
 211   case "$llvm_cv_target_arch" in
 212     x86)     AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 213     Sparc)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 214     PowerPC) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 215     x86_64)  AC_SUBST(JIT,[[]]) ;;
 216     Alpha)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 217     IA64)    AC_SUBST(JIT,[[]]) ;;
 218     *)       AC_SUBST(JIT,[[]]) ;;
 219   esac
 220 fi
 221
 222 dnl Allow enablement of doxygen generated documentation
 223 AC_ARG_ENABLE(doxygen,
 224               AS_HELP_STRING([--enable-doxygen],
 225                              [Build doxygen documentation (default is NO)]),,
 226                              enableval=default)
 227 case "$enableval" in
 228   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 229   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 230   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 231   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 232 esac
 233
 234 dnl Allow disablement of threads
 235 AC_ARG_ENABLE(threads,
 236               AS_HELP_STRING([--enable-threads],
 237                              [Use threads if available (default is YES)]),,
 238                              enableval=yes)
 239 case "$enableval" in
 240   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 241   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 242   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 243 esac
 244 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 245
 246 dnl Allow specific targets to be specified for building (or not)
 247 TARGETS_TO_BUILD=""
 248 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-target],
 249     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 250     enableval=all)
 251 case "$enableval" in
 252   all) TARGETS_TO_BUILD="X86 SparcV8 SparcV9 PowerPC Alpha IA64 Skeleton" ;;
 253   host-only)
 254     case "$llvm_cv_target_arch" in
 255       x86)     TARGETS_TO_BUILD="X86" ;;
 256       x86_64)  TARGETS_TO_BUILD="X86" ;;
 257       Sparc)   TARGETS_TO_BUILD="SparcV8 SparcV9" ;;
 258       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 259       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 260       IA64)    TARGETS_TO_BUILD="IA64" ;;
 261       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 262     esac
 263     ;;
 264   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 265       case "$a_target" in
 266         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 267         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 268         sparc)   TARGETS_TO_BUILD="SparcV8 SparcV9 $TARGETS_TO_BUILD" ;;
 269         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 270         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 271         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 272         skeleton)TARGETS_TO_BUILD="Skeleton $TARGETS_TO_BUILD";;
 273         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 274       esac
 275   done
 276   ;;
 277 esac
 278 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 279 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 280
 281 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 282 AC_ARG_WITH(llvmgccdir,
 283   AS_HELP_STRING([--with-llvmgccdir],
 284     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 285     withval=default)
 286 case "$withval" in
 287   default) WITH_LLVMGCCDIR=default ;;
 288   /*)      WITH_LLVMGCCDIR=$withval ;;
 289   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 290 esac
 291
 292
 293 dnl===-----------------------------------------------------------------------===
 294 dnl===
 295 dnl=== SECTION 4: Check for programs we need and that they are the right version
 296 dnl===
 297 dnl===-----------------------------------------------------------------------===
 298
 299 dnl Check for compilation tools
 300 AC_PROG_CPP
 301 AC_PROG_CC(gcc)
 302 AC_PROG_CXX(g++)
 303 AC_PROG_FLEX
 304 AC_PROG_BISON
 305
 306 dnl Check for the tools that the makefiles require
 307 AC_CHECK_GNU_MAKE
 308 AC_PROG_LN_S
 309 AC_PATH_PROG(CMP, [cmp], [cmp])
 310 AC_PATH_PROG(CP, [cp], [cp])
 311 AC_PATH_PROG(DATE, [date], [date])
 312 AC_PATH_PROG(FIND, [find], [find])
 313 AC_PATH_PROG(GREP, [grep], [grep])
 314 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 315 AC_PATH_PROG(MV,   [mv],   [mv])
 316 AC_PROG_RANLIB
 317 AC_PATH_PROG(RM,   [rm],   [rm])
 318 AC_PATH_PROG(SED,  [sed],  [sed])
 319 AC_PATH_PROG(TAR,  [tar],  [gtar])
 320 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 321 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 322   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 323   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ",
 324    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 325 fi
 326 AC_PATH_PROG(GV, [gv], [echo gv])
 327 if test "$GV" != "echo gv" ; then
 328   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 329   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV",
 330    [Define to path to gv program if found or 'echo gv' otherwise])
 331 fi
 332
 333 dnl Find the install program
 334 AC_PROG_INSTALL
 335
 336 dnl Checks for documentation and testing tools that we can do without. If these
 337 dnl are not found then they are set to "true" which always succeeds but does
 338 dnl nothing. This just lets the build output show that we could have done
 339 dnl something if the tool was available.
 340 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 341 AC_PATH_PROG(DOT,[dot],[true dot])
 342 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 343 AC_PATH_PROG(ETAGS,[etags],[true etags])
 344 AC_PATH_PROG(GROFF,[groff],[true groff])
 345 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 346 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 347 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 348 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 349 DJ_AC_PATH_TCLSH
 350 AC_PATH_PROG(ZIP,[zip],[true zip])
 351
 352 dnl Determine if the linker supports the -R option.
 353 AC_LINK_USE_R
 354
 355 dnl Check for libtool and the library that has dlopen function (which must come
 356 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 357 dnl libtool).
 358 AC_LIBTOOL_DLOPEN
 359 AC_LIB_LTDL
 360 AC_PROG_LIBTOOL
 361
 362 if test "$lt_cv_dlopen_self" = "yes" ; then
 363   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 364               [Define if dlopen(0) will open the symbols of the program])
 365 fi
 366
 367 dnl Check if we know how to tell etags we are using C++:
 368 etags_version=`$ETAGS --version 2>&1`
 369 case "$etags_version" in
 370         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 371         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 372         *) ETAGSFLAGS="" ;;
 373 esac
 374 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 375
 376 if test "$WITH_LLVMGCCDIR" = "default" ; then
 377   LLVMGCC="llvm-gcc${EXEEXT}"
 378   LLVMGXX="llvm-g++${EXEEXT}"
 379   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 380   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 381 else
 382   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 383   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 384   AC_SUBST(LLVMGCC,$LLVMGCC)
 385   AC_SUBST(LLVMGXX,$LLVMGXX)
 386 fi
 387
 388 AC_MSG_CHECKING([tool compatibility])
 389
 390 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 391 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 392 dnl to support those options.
 393 dnl "icc" emits gcc signatures
 394 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 395 ICC=no
 396 IXX=no
 397 case $CC in
 398   icc*|icpc*)
 399     ICC=yes
 400     IXX=yes
 401     ;;
 402    *)
 403     ;;
 404 esac
 405
 406 if test "$GCC" != "yes" && test "$ICC" != "yes"
 407 then
 408   AC_MSG_ERROR([gcc|icc required but not found])
 409 fi
 410
 411 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 412 if test "$GXX" != "yes" && test "$IXX" != "yes"
 413 then
 414   AC_MSG_ERROR([g++|icc required but not found])
 415 fi
 416
 417 dnl Verify that GCC is version 3.0 or higher
 418 if test "$GCC" = "yes"
 419 then
 420   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 421   if test "$gccmajor" -lt "3"
 422   then
 423     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 424   fi
 425 fi
 426
 427 dnl Check for GNU Make.  We use its extensions, so don't build without it
 428 if test -z "$llvm_cv_gnu_make_command"
 429 then
 430   AC_MSG_ERROR([GNU Make required but not found])
 431 fi
 432
 433 dnl Tool compatibility is okay if we make it here.
 434 AC_MSG_RESULT([ok])
 435
 436 dnl===-----------------------------------------------------------------------===
 437 dnl===
 438 dnl=== SECTION 5: Check for libraries
 439 dnl===
 440 dnl===-----------------------------------------------------------------------===
 441
 442 dnl libelf is for sparc only; we can ignore it if we don't have it
 443 AC_CHECK_LIB(elf, elf_begin)
 444
 445
 446 dnl lt_dlopen may be required for plugin support.
 447 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 448               [Define if lt_dlopen() is available on this platform]),
 449               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 450                            not be available]))
 451
 452 dnl dlopen() is required for plugin support.
 453 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 454                [Define if dlopen() is available on this platform.]),
 455                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 456
 457 dnl mallinfo is optional; the code can compile (minus features) without it
 458 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 459                [Define if mallinfo() is available on this platform.]))
 460
 461 dnl pthread locking functions are optional - but llvm will not be thread-safe
 462 dnl without locks.
 463 if test "$ENABLE_THREADS" -eq 1 ; then
 464   AC_CHECK_LIB(pthread,pthread_mutex_init)
 465   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 466                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 467                            [Have pthread_mutex_lock]))
 468 fi
 469
 470 dnl===-----------------------------------------------------------------------===
 471 dnl===
 472 dnl=== SECTION 6: Check for header files
 473 dnl===
 474 dnl===-----------------------------------------------------------------------===
 475
 476 dnl First, use autoconf provided macros for specific headers that we need
 477 dnl We don't check for ancient stuff or things that are guaranteed to be there
 478 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 479 dnl Generally we're looking for POSIX headers.
 480 AC_HEADER_DIRENT
 481 AC_HEADER_MMAP_ANONYMOUS
 482 AC_HEADER_STAT
 483 AC_HEADER_STDC
 484 AC_HEADER_SYS_WAIT
 485 AC_HEADER_TIME
 486
 487 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 488 AC_CHECK_HEADERS([malloc.h signal.h stdint.h unistd.h utime.h windows.h])
 489 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/types.h])
 490 AC_CHECK_HEADERS([malloc/malloc.h])
 491 AC_CHECK_HEADERS([rw/stdex/hash_map.h rw/stdex/hash_set.h])
 492 if test "$ENABLE_THREADS" -eq 1 ; then
 493   AC_CHECK_HEADERS(pthread.h)
 494 fi
 495
 496 dnl===-----------------------------------------------------------------------===
 497 dnl===
 498 dnl=== SECTION 7: Check for types and structures
 499 dnl===
 500 dnl===-----------------------------------------------------------------------===
 501
 502 AC_TYPE_PID_T
 503 AC_TYPE_SIZE_T
 504 AC_TYPE_SIGNAL
 505 AC_STRUCT_TM
 506 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 507 AC_CHECK_TYPES([uint64_t],,
 508          AC_CHECK_TYPES([u_int64_t],,
 509          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 510
 511 dnl===-----------------------------------------------------------------------===
 512 dnl===
 513 dnl=== SECTION 8: Check for specific functions needed
 514 dnl===
 515 dnl===-----------------------------------------------------------------------===
 516
 517 AC_CHECK_FUNCS([backtrace getcwd getpagesize getrusage gettimeofday ])
 518 AC_CHECK_FUNCS([isatty mkdtemp mkstemp mktemp ])
 519 AC_CHECK_FUNCS([realpath sbrk setrlimit strdup strerror strerror_r ])
 520 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 521 AC_C_PRINTF_A
 522 AC_FUNC_ALLOCA
 523 AC_FUNC_RAND48
 524
 525 dnl Check for variations in the Standard C++ library and STL. These macros are
 526 dnl provided by LLVM in the autoconf/m4 directory.
 527 AC_CXX_HAVE_HASH_MAP
 528 AC_CXX_HAVE_HASH_SET
 529 AC_CXX_HAVE_STD_ITERATOR
 530 AC_CXX_HAVE_BI_ITERATOR
 531 AC_CXX_HAVE_FWD_ITERATOR
 532 AC_FUNC_ISNAN
 533 AC_FUNC_ISINF
 534
 535 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 536 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 537 dnl be opened for allocating RWX memory.
 538 AC_FUNC_MMAP
 539 AC_FUNC_MMAP_FILE
 540 AC_NEED_DEV_ZERO_FOR_MMAP
 541 AC_CHECK_FUNC(mprotect,,
 542               AC_MSG_ERROR([Function mprotect() required but not found]))
 543
 544 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 545 then
 546   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 547 fi
 548 if test "$ac_cv_func_mmap_file" = "no"
 549 then
 550   AC_MSG_WARN([mmap() of files required but not found])
 551 fi
 552
 553 dnl===-----------------------------------------------------------------------===
 554 dnl===
 555 dnl=== SECTION 9: Additional checks, variables, etc.
 556 dnl===
 557 dnl===-----------------------------------------------------------------------===
 558
 559 dnl See if the llvm-gcc executable can compile to LLVM assembly
 560 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 561 [llvm_cv_llvmgcc_sanity="no"
 562 if test -x "$LLVMGCC" ; then
 563   cp /dev/null conftest.c
 564   "$LLVMGCC" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 565   if test $? -eq 0 ; then
 566     llvm_cv_llvmgcc_sanity="yes"
 567   fi
 568   rm conftest.c
 569 fi])
 570
 571 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 572 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 573   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 574   AC_SUBST(LLVMCC1,$llvmcc1path)
 575   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 576   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 577   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 578   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 579 fi
 580
 581 dnl Propagate the shared library extension that the libltdl checks did to
 582 dnl the Makefiles so we can use it there too
 583 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 584
 585 # Translate the various configuration directories and other basic
 586 # information into substitutions that will end up in Makefile.config.in
 587 # that these configured values can be used by the makefiles
 588 eval LLVM_PREFIX="${prefix}";
 589 eval LLVM_BINDIR="${prefix}/bin";
 590 eval LLVM_LIBDIR="${prefix}/lib";
 591 eval LLVM_DATADIR="${prefix}/share/llvm";
 592 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 593 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 594 eval LLVM_INCLUDEDIR="${prefix}/include";
 595 eval LLVM_INFODIR="${prefix}/info";
 596 eval LLVM_MANDIR="${prefix}/man";
 597 LLVM_CONFIGTIME=`date`
 598 AC_SUBST(LLVM_PREFIX)
 599 AC_SUBST(LLVM_BINDIR)
 600 AC_SUBST(LLVM_LIBDIR)
 601 AC_SUBST(LLVM_DATADIR)
 602 AC_SUBST(LLVM_DOCSDIR)
 603 AC_SUBST(LLVM_ETCDIR)
 604 AC_SUBST(LLVM_INCLUDEDIR)
 605 AC_SUBST(LLVM_INFODIR)
 606 AC_SUBST(LLVM_MANDIR)
 607 AC_SUBST(LLVM_CONFIGTIME)
 608
 609 # Place the various directores into the config.h file as #defines so that we
 610 # can know about the installation paths within LLVM.
 611 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 612                    [Installation prefix directory])
 613 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 614                    [Installation directory for binary executables])
 615 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 616                    [Installation directory for libraries])
 617 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 618                    [Installation directory for data files])
 619 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 620                    [Installation directory for documentation])
 621 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 622                    [Installation directory for config files])
 623 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 624                    [Installation directory for include files])
 625 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 626                    [Installation directory for .info files])
 627 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 628                    [Installation directory for man pages])
 629 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 630                    [Time at which LLVM was configured])
 631
 632 dnl===-----------------------------------------------------------------------===
 633 dnl===
 634 dnl=== SECTION 10: Specify the output files and generate it
 635 dnl===
 636 dnl===-----------------------------------------------------------------------===
 637
 638 dnl Configure header files
 639 dnl WARNING: dnl If you add or remove any of the following config headers, then
 640 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 641 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 642 dnl files can be updated automatically when their *.in sources change.
 643 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 644 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 645 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 646 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 647 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 648
 649 dnl Configure the makefile's configuration data
 650 AC_CONFIG_FILES([Makefile.config])
 651
 652 dnl Configure doxygen's configuration file
 653 AC_CONFIG_FILES([docs/doxygen.cfg])
 654
 655 dnl Do special configuration of Makefiles
 656 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 657 AC_CONFIG_MAKEFILE(Makefile)
 658 AC_CONFIG_MAKEFILE(Makefile.common)
 659 AC_CONFIG_MAKEFILE(examples/Makefile)
 660 AC_CONFIG_MAKEFILE(lib/Makefile)
 661 AC_CONFIG_MAKEFILE(runtime/Makefile)
 662 AC_CONFIG_MAKEFILE(test/Makefile)
 663 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 664 AC_CONFIG_MAKEFILE(tools/Makefile)
 665 AC_CONFIG_MAKEFILE(utils/Makefile)
 666 AC_CONFIG_MAKEFILE(projects/Makefile)
 667
 668 dnl Finally, crank out the output
 669 AC_OUTPUT
 670
 671 dnl Warn loudly if llvm-gcc was not obviously working
 672 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 673  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 674  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 675  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 676  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 677  AC_MSG_WARN([***** build the llvm tools.])
 678 fi