autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.8svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65
  66 dnl
  67 dnl One tricky part of doing this is that some projects depend upon other
  68 dnl projects.  For example, several projects rely upon the LLVM test suite.
  69 dnl We want to configure those projects first so that their object trees are
  70 dnl created before running the configure scripts of projects that depend upon
  71 dnl them.
  72 dnl
  73
  74 dnl Several projects use llvm-gcc, so configure that first
  75 if test -d ${srcdir}/projects/llvm-gcc ; then
  76   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  77 fi
  78
  79 dnl Several projects use the LLVM test suite, so configure it next.
  80 if test -d ${srcdir}/projects/test-suite ; then
  81   AC_CONFIG_SUBDIRS([projects/test-suite])
  82 fi
  83
  84 dnl llvm-test is the old name of the test-suite, kept here for backwards
  85 dnl compatibility
  86 if test -d ${srcdir}/projects/llvm-test ; then
  87   AC_CONFIG_SUBDIRS([projects/llvm-test])
  88 fi
  89
  90 dnl Some projects use poolalloc; configure that next
  91 if test -d ${srcdir}/projects/poolalloc ; then
  92   AC_CONFIG_SUBDIRS([projects/poolalloc])
  93 fi
  94
  95 if test -d ${srcdir}/projects/llvm-poolalloc ; then
  96   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
  97 fi
  98
  99 dnl Check for all other projects
 100 for i in `ls ${srcdir}/projects`
 101 do
 102   if test -d ${srcdir}/projects/${i} ; then
 103     case ${i} in
 104       CVS) ;;
 105       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 106       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 107       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 108       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 109       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 110       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 111       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 112       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 113       llvm-gcc)       ;;
 114       test-suite)     ;;
 115       llvm-test)      ;;
 116       poolalloc)      ;;
 117       llvm-poolalloc) ;;
 118       *)
 119         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 120         ;;
 121     esac
 122   fi
 123 done
 124
 125 dnl===-----------------------------------------------------------------------===
 126 dnl===
 127 dnl=== SECTION 2: Architecture, target, and host checks
 128 dnl===
 129 dnl===-----------------------------------------------------------------------===
 130
 131 dnl Check the target for which we're compiling and the host that will do the
 132 dnl compilations. This will tell us which LLVM compiler will be used for
 133 dnl compiling SSA into object code. This needs to be done early because
 134 dnl following tests depend on it.
 135 AC_CANONICAL_TARGET
 136
 137 dnl Determine the platform type and cache its value. This helps us configure
 138 dnl the System library to the correct build platform.
 139 AC_CACHE_CHECK([type of operating system we're going to host on],
 140                [llvm_cv_os_type],
 141 [case $host in
 142   *-*-aix*)
 143     llvm_cv_link_all_option="-Wl,--whole-archive"
 144     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 145     llvm_cv_os_type="AIX"
 146     llvm_cv_platform_type="Unix" ;;
 147   *-*-irix*)
 148     llvm_cv_link_all_option="-Wl,--whole-archive"
 149     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 150     llvm_cv_os_type="IRIX"
 151     llvm_cv_platform_type="Unix" ;;
 152   *-*-cygwin*)
 153     llvm_cv_link_all_option="-Wl,--whole-archive"
 154     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 155     llvm_cv_os_type="Cygwin"
 156     llvm_cv_platform_type="Unix" ;;
 157   *-*-darwin*)
 158     llvm_cv_link_all_option="-Wl,-all_load"
 159     llvm_cv_no_link_all_option="-Wl,-noall_load"
 160     llvm_cv_os_type="Darwin"
 161     llvm_cv_platform_type="Unix" ;;
 162   *-*-minix*)
 163     llvm_cv_link_all_option="-Wl,-all_load"
 164     llvm_cv_no_link_all_option="-Wl,-noall_load"
 165     llvm_cv_os_type="Minix"
 166     llvm_cv_platform_type="Unix" ;;
 167   *-*-freebsd*)
 168     llvm_cv_link_all_option="-Wl,--whole-archive"
 169     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 170     llvm_cv_os_type="FreeBSD"
 171     llvm_cv_platform_type="Unix" ;;
 172   *-*-openbsd*)
 173     llvm_cv_link_all_option="-Wl,--whole-archive"
 174     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 175     llvm_cv_os_type="OpenBSD"
 176     llvm_cv_platform_type="Unix" ;;
 177   *-*-netbsd*)
 178     llvm_cv_link_all_option="-Wl,--whole-archive"
 179     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 180     llvm_cv_os_type="NetBSD"
 181     llvm_cv_platform_type="Unix" ;;
 182   *-*-dragonfly*)
 183     llvm_cv_link_all_option="-Wl,--whole-archive"
 184     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 185     llvm_cv_os_type="DragonFly"
 186     llvm_cv_platform_type="Unix" ;;
 187   *-*-hpux*)
 188     llvm_cv_link_all_option="-Wl,--whole-archive"
 189     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 190     llvm_cv_os_type="HP-UX"
 191     llvm_cv_platform_type="Unix" ;;
 192   *-*-interix*)
 193     llvm_cv_link_all_option="-Wl,--whole-archive"
 194     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 195     llvm_cv_os_type="Interix"
 196     llvm_cv_platform_type="Unix" ;;
 197   *-*-linux*)
 198     llvm_cv_link_all_option="-Wl,--whole-archive"
 199     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 200     llvm_cv_os_type="Linux"
 201     llvm_cv_platform_type="Unix" ;;
 202   *-*-solaris*)
 203     llvm_cv_link_all_option="-Wl,-z,allextract"
 204     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 205     llvm_cv_os_type="SunOS"
 206     llvm_cv_platform_type="Unix" ;;
 207   *-*-auroraux*)
 208     llvm_cv_link_all_option="-Wl,-z,allextract"
 209     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 210     llvm_cv_os_type="AuroraUX"
 211     llvm_cv_platform_type="Unix" ;;
 212   *-*-win32*)
 213     llvm_cv_link_all_option="-Wl,--whole-archive"
 214     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 215     llvm_cv_os_type="Win32"
 216     llvm_cv_platform_type="Win32" ;;
 217   *-*-mingw*)
 218     llvm_cv_link_all_option="-Wl,--whole-archive"
 219     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 220     llvm_cv_os_type="MingW"
 221     llvm_cv_platform_type="Win32" ;;
 222   *-*-haiku*)
 223     llvm_cv_link_all_option="-Wl,--whole-archive"
 224     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 225     llvm_cv_os_type="Haiku"
 226     llvm_cv_platform_type="Unix" ;;
 227   *-unknown-eabi*)
 228     llvm_cv_link_all_option="-Wl,--whole-archive"
 229     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 230     llvm_cv_os_type="Freestanding"
 231     llvm_cv_platform_type="Unix" ;;
 232   *-unknown-elf*)
 233     llvm_cv_link_all_option="-Wl,--whole-archive"
 234     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 235     llvm_cv_os_type="Freestanding"
 236     llvm_cv_platform_type="Unix" ;;
 237   *)
 238     llvm_cv_link_all_option=""
 239     llvm_cv_no_link_all_option=""
 240     llvm_cv_os_type="Unknown"
 241     llvm_cv_platform_type="Unknown" ;;
 242 esac])
 243
 244 AC_CACHE_CHECK([type of operating system we're going to target],
 245                [llvm_cv_target_os_type],
 246 [case $target in
 247   *-*-aix*)
 248     llvm_cv_target_os_type="AIX" ;;
 249   *-*-irix*)
 250     llvm_cv_target_os_type="IRIX" ;;
 251   *-*-cygwin*)
 252     llvm_cv_target_os_type="Cygwin" ;;
 253   *-*-darwin*)
 254     llvm_cv_target_os_type="Darwin" ;;
 255   *-*-minix*)
 256     llvm_cv_target_os_type="Minix" ;;
 257   *-*-freebsd*)
 258     llvm_cv_target_os_type="FreeBSD" ;;
 259   *-*-openbsd*)
 260     llvm_cv_target_os_type="OpenBSD" ;;
 261   *-*-netbsd*)
 262     llvm_cv_target_os_type="NetBSD" ;;
 263   *-*-dragonfly*)
 264     llvm_cv_target_os_type="DragonFly" ;;
 265   *-*-hpux*)
 266     llvm_cv_target_os_type="HP-UX" ;;
 267   *-*-interix*)
 268     llvm_cv_target_os_type="Interix" ;;
 269   *-*-linux*)
 270     llvm_cv_target_os_type="Linux" ;;
 271   *-*-solaris*)
 272     llvm_cv_target_os_type="SunOS" ;;
 273   *-*-auroraux*)
 274     llvm_cv_target_os_type="AuroraUX" ;;
 275   *-*-win32*)
 276     llvm_cv_target_os_type="Win32" ;;
 277   *-*-mingw*)
 278     llvm_cv_target_os_type="MingW" ;;
 279   *-*-haiku*)
 280     llvm_cv_target_os_type="Haiku" ;;
 281   *-unknown-eabi*)
 282     llvm_cv_target_os_type="Freestanding" ;;
 283   *)
 284     llvm_cv_target_os_type="Unknown" ;;
 285 esac])
 286
 287 dnl Make sure we aren't attempting to configure for an unknown system
 288 if test "$llvm_cv_os_type" = "Unknown" ; then
 289   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 290 fi
 291
 292 dnl Set the "OS" Makefile variable based on the platform type so the
 293 dnl makefile can configure itself to specific build hosts
 294 AC_SUBST(OS,$llvm_cv_os_type)
 295 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 296 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 297
 298 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 299 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 300 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 301
 302 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 303 dnl This is used by lib/System to determine the basic kind of implementation
 304 dnl to use.
 305 case $llvm_cv_platform_type in
 306   Unix)
 307     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 308     AC_SUBST(LLVM_ON_UNIX,[1])
 309     AC_SUBST(LLVM_ON_WIN32,[0])
 310     ;;
 311   Win32)
 312     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 313     AC_SUBST(LLVM_ON_UNIX,[0])
 314     AC_SUBST(LLVM_ON_WIN32,[1])
 315     ;;
 316 esac
 317
 318 dnl Determine what our target architecture is and configure accordingly.
 319 dnl This will allow Makefiles to make a distinction between the hardware and
 320 dnl the OS.
 321 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 322 [case $target in
 323   i?86-*)                 llvm_cv_target_arch="x86" ;;
 324   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 325   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 326   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 327   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 328   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 329   mips-*)                 llvm_cv_target_arch="Mips" ;;
 330   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 331   xcore-*)                llvm_cv_target_arch="XCore" ;;
 332   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 333   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 334   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 335   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 336   *)                      llvm_cv_target_arch="Unknown" ;;
 337 esac])
 338
 339 if test "$llvm_cv_target_arch" = "Unknown" ; then
 340   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 341 fi
 342
 343 # Determine the LLVM native architecture for the target
 344 case "$llvm_cv_target_arch" in
 345     x86)     LLVM_NATIVE_ARCH="X86" ;;
 346     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 347     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 348 esac
 349
 350 dnl Define a substitution, ARCH, for the target architecture
 351 AC_SUBST(ARCH,$llvm_cv_target_arch)
 352
 353 dnl Check for the endianness of the target
 354 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 355
 356 dnl Check for build platform executable suffix if we're crosscompiling
 357 if test "$cross_compiling" = yes; then
 358   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 359   AC_BUILD_EXEEXT
 360   ac_build_prefix=${build_alias}-
 361   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 362   if test -z "$BUILD_CXX"; then
 363      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 364      if test -z "$BUILD_CXX"; then
 365        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 366      fi
 367   fi
 368 else
 369   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 370 fi
 371
 372 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 373 dnl that this build is being done from a checkout. This sets up several
 374 dnl defaults for the command line switches. When we build with a CVS directory,
 375 dnl we get a debug with assertions turned on. Without, we assume a source
 376 dnl release and we get an optimized build without assertions.
 377 dnl See --enable-optimized and --enable-assertions below
 378 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 379   cvsbuild="yes"
 380   optimize="no"
 381   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 382 else
 383   cvsbuild="no"
 384   optimize="yes"
 385 fi
 386
 387 dnl===-----------------------------------------------------------------------===
 388 dnl===
 389 dnl=== SECTION 3: Command line arguments for the configure script.
 390 dnl===
 391 dnl===-----------------------------------------------------------------------===
 392
 393 dnl --enable-optimized : check whether they want to do an optimized build:
 394 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 395  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 396 if test ${enableval} = "no" ; then
 397   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 398 else
 399   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 400 fi
 401
 402 dnl --enable-profiling : check whether they want to do a profile build:
 403 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 404  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 405 if test ${enableval} = "no" ; then
 406   AC_SUBST(ENABLE_PROFILING,[[]])
 407 else
 408   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 409 fi
 410
 411 dnl --enable-assertions : check whether they want to turn on assertions or not:
 412 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 413   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 414 if test ${enableval} = "yes" ; then
 415   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 416 else
 417   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 418 fi
 419
 420 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 421 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 422   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 423 if test ${enableval} = "yes" ; then
 424   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 425   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 426 else
 427   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 428   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 429 fi
 430
 431 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 432 AC_ARG_ENABLE(debug-runtime,
 433    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 434 if test ${enableval} = "no" ; then
 435   AC_SUBST(DEBUG_RUNTIME,[[]])
 436 else
 437   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 438 fi
 439
 440 dnl --enable-debug-symbols : should even optimized compiler libraries
 441 dnl have debug symbols?
 442 AC_ARG_ENABLE(debug-symbols,
 443    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 444 if test ${enableval} = "no" ; then
 445   AC_SUBST(DEBUG_SYMBOLS,[[]])
 446 else
 447   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 448 fi
 449
 450 dnl --enable-jit: check whether they want to enable the jit
 451 AC_ARG_ENABLE(jit,
 452   AS_HELP_STRING(--enable-jit,
 453                  [Enable Just In Time Compiling (default is YES)]),,
 454   enableval=default)
 455 if test ${enableval} = "no"
 456 then
 457   AC_SUBST(JIT,[[]])
 458 else
 459   case "$llvm_cv_target_arch" in
 460     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 461     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 462     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 463     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 464     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 465     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 466     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 467     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 468     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 469     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 470     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 471     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 472     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 473     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 474   esac
 475 fi
 476
 477 dnl Allow enablement of doxygen generated documentation
 478 AC_ARG_ENABLE(doxygen,
 479               AS_HELP_STRING([--enable-doxygen],
 480                              [Build doxygen documentation (default is NO)]),,
 481                              enableval=default)
 482 case "$enableval" in
 483   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 484   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 485   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 486   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 487 esac
 488
 489 dnl Allow disablement of threads
 490 AC_ARG_ENABLE(threads,
 491               AS_HELP_STRING([--enable-threads],
 492                              [Use threads if available (default is YES)]),,
 493                              enableval=default)
 494 case "$enableval" in
 495   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 496   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 497   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 498   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 499 esac
 500 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 501
 502 dnl Allow building without position independent code
 503 AC_ARG_ENABLE(pic,
 504   AS_HELP_STRING([--enable-pic],
 505                  [Build LLVM with Position Independent Code (default is YES)]),,
 506                  enableval=default)
 507 case "$enableval" in
 508   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 509   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 510   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 511   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 512 esac
 513 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 514                    [Define if position independent code is enabled])
 515
 516 dnl Allow building a shared library and linking tools against it.
 517 AC_ARG_ENABLE(shared,
 518   AS_HELP_STRING([--enable-shared],
 519                  [Build a shared library and link tools against it (default is NO)]),,
 520                  enableval=default)
 521 case "$enableval" in
 522   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 523   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 524   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 525   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 526 esac
 527
 528 dnl Allow specific targets to be specified for building (or not)
 529 TARGETS_TO_BUILD=""
 530 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 531     [Build specific host targets: all or target1,target2,... Valid targets are:
 532      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu, pic16,
 533      xcore, msp430, systemz, blackfin, cbe, msil, and cpp (default=all)]),,
 534     enableval=all)
 535 if test "$enableval" = host-only ; then
 536   enableval=host
 537 fi
 538 case "$enableval" in
 539   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend MSIL CppBackend MBlaze" ;;
 540   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 541       case "$a_target" in
 542         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 543         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 544         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 545         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 546         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 547         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 548         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 549         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 550         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 551         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 552         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 553         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 554         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 555         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 556         msil)     TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 557         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 558         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 559         host) case "$llvm_cv_target_arch" in
 560             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 561             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 562             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 563             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 564             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 565             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 566             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 567             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 568             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 569             PIC16)       TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 570             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 571             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 572             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 573             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 574             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 575           esac ;;
 576         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 577       esac
 578   done
 579   ;;
 580 esac
 581 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 582
 583 # Determine whether we are building LLVM support for the native architecture.
 584 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 585 for a_target in $TARGETS_TO_BUILD; do
 586   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 587     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 588     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 589       [LLVM architecture name for the native architecture, if available])
 590   fi
 591 done
 592
 593 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 594 # target feature def files.
 595 LLVM_ENUM_TARGETS=""
 596 LLVM_ENUM_ASM_PRINTERS=""
 597 LLVM_ENUM_ASM_PARSERS=""
 598 LLVM_ENUM_DISASSEMBLERS=""
 599 for target_to_build in $TARGETS_TO_BUILD; do
 600   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 601   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 602     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 603   fi
 604   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 605     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 606   fi
 607   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 608     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 609   fi
 610 done
 611 AC_SUBST(LLVM_ENUM_TARGETS)
 612 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 613 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 614 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 615
 616 dnl Prevent the CBackend from using printf("%a") for floating point so older
 617 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 618 dnl can still compile the CBE's output
 619 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 620   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 621   enableval=default)
 622 case "$enableval" in
 623   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 624   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 625   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 626   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 627 esac
 628 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 629                    [Define if CBE is enabled for printf %a output])
 630
 631 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 632 AC_ARG_WITH(llvmgccdir,
 633   AS_HELP_STRING([--with-llvmgccdir],
 634     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 635     withval=default)
 636 case "$withval" in
 637   default) WITH_LLVMGCCDIR=default ;;
 638   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 639   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 640 esac
 641
 642 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 643 AC_ARG_WITH(llvmgcc,
 644   AS_HELP_STRING([--with-llvmgcc],
 645     [Specify location of llvm-gcc driver (default searches PATH)]),
 646     LLVMGCC=$with_llvmgcc
 647       WITH_LLVMGCCDIR="",)
 648
 649 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 650 AC_ARG_WITH(llvmgxx,
 651   AS_HELP_STRING([--with-llvmgxx],
 652     [Specify location of llvm-g++ driver (default searches PATH)]),
 653     LLVMGXX=$with_llvmgxx
 654     WITH_LLVMGCCDIR="",)
 655
 656 if test -n "$LLVMGCC"; then
 657    LLVMGCCCOMMAND="$LLVMGCC"
 658 fi
 659
 660 if test -n "$LLVMGXX"; then
 661    LLVMGXXCOMMAND="$LLVMGXX"
 662 fi
 663
 664 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 665    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 666 fi
 667
 668 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 669    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 670 fi
 671
 672 dnl Allow a specific Clang compiler to be used with this LLVM config.
 673 AC_ARG_WITH(clang,
 674   AS_HELP_STRING([--with-clang],
 675     [Specify location of clang compiler (default is --with-built-clang)]),
 676     [],[with_clang=default])
 677
 678 dnl Enable use of the built Clang.
 679 AC_ARG_WITH(built-clang,
 680   AS_HELP_STRING([--with-built-clang],
 681     [Use the compiled Clang as the LLVM compiler (default=check)]),
 682     [],[with_built_clang=check])
 683
 684 dnl Select the Clang compiler option.
 685 dnl
 686 dnl If --with-clang is given, always honor that; otherwise honor
 687 dnl --with-built-clang, or check if we have the clang sources.
 688 AC_MSG_CHECKING([clang compiler])
 689 WITH_CLANGPATH=""
 690 WITH_BUILT_CLANG=0
 691 if test "$with_clang" != "default"; then
 692    WITH_CLANGPATH="$with_clang"
 693    if ! test -x "$WITH_CLANGPATH"; then
 694      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 695    fi
 696 elif test "$with_built_clang" = "yes"; then
 697    WITH_BUILT_CLANG=1
 698 elif test "$with_built_clang" = "no"; then
 699    WITH_BUILT_CLANG=0
 700 else
 701    if test "$with_built_clang" != "check"; then
 702       AC_MSG_ERROR([invalid value for --with-built-clang.])
 703    fi
 704
 705    if test -f ${srcdir}/tools/clang/README.txt; then
 706      WITH_BUILT_CLANG=1
 707    fi
 708 fi
 709
 710 if ! test -z "$WITH_CLANGPATH"; then
 711    AC_MSG_RESULT([$WITH_CLANGPATH])
 712    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 713 elif test "$WITH_BUILT_CLANG" = "1"; then
 714    AC_MSG_RESULT([built])
 715 else
 716    AC_MSG_RESULT([none])
 717 fi
 718 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 719 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 720 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 721
 722 dnl Override the option to use for optimized builds.
 723 AC_ARG_WITH(optimize-option,
 724   AS_HELP_STRING([--with-optimize-option],
 725                  [Select the compiler options to use for optimized builds]),,
 726                  withval=default)
 727 AC_MSG_CHECKING([optimization flags])
 728 case "$withval" in
 729   default)
 730     case "$llvm_cv_os_type" in
 731     MingW) optimize_option=-O3 ;;
 732     *)     optimize_option=-O2 ;;
 733     esac ;;
 734   *) optimize_option="$withval" ;;
 735 esac
 736 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 737 AC_MSG_RESULT([$optimize_option])
 738
 739 dnl Specify extra build options
 740 AC_ARG_WITH(extra-options,
 741   AS_HELP_STRING([--with-extra-options],
 742                  [Specify additional options to compile LLVM with]),,
 743                  withval=default)
 744 case "$withval" in
 745   default) EXTRA_OPTIONS= ;;
 746   *) EXTRA_OPTIONS=$withval ;;
 747 esac
 748 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 749
 750 dnl Allow specific bindings to be specified for building (or not)
 751 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 752     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 753     enableval=default)
 754 BINDINGS_TO_BUILD=""
 755 case "$enableval" in
 756   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 757   all ) BINDINGS_TO_BUILD="ocaml" ;;
 758   none | no) BINDINGS_TO_BUILD="" ;;
 759   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 760       case "$a_binding" in
 761         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 762         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 763       esac
 764   done
 765   ;;
 766 esac
 767
 768 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 769 dnl script for bindings/ocaml/configure, except that its auto value depends on
 770 dnl OCAMLC, which is found here to support tests.
 771 AC_ARG_WITH([ocaml-libdir],
 772   [AS_HELP_STRING([--with-ocaml-libdir],
 773     [Specify install location for ocaml bindings (default is stdlib)])],
 774   [],
 775   [withval=auto])
 776 case "$withval" in
 777   auto) with_ocaml_libdir="$withval" ;;
 778   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 779   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 780 esac
 781
 782 AC_ARG_WITH(c-include-dirs,
 783   AS_HELP_STRING([--with-c-include-dirs],
 784     [Colon separated list of directories clang will search for headers]),,
 785     withval="")
 786 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 787                    [Directories clang will search for headers])
 788
 789 AC_ARG_WITH(cxx-include-root,
 790   AS_HELP_STRING([--with-cxx-include-root],
 791     [Directory with the libstdc++ headers.]),,
 792     withval="")
 793 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 794                    [Directory with the libstdc++ headers.])
 795
 796 AC_ARG_WITH(cxx-include-arch,
 797   AS_HELP_STRING([--with-cxx-include-arch],
 798     [Architecture of the libstdc++ headers.]),,
 799     withval="")
 800 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 801                    [Arch the libstdc++ headers.])
 802
 803 AC_ARG_WITH(cxx-include-32bit-dir,
 804   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 805     [32 bit multilib dir.]),,
 806     withval="")
 807 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 808                    [32 bit multilib directory.])
 809
 810 AC_ARG_WITH(cxx-include-64bit-dir,
 811   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 812     [64 bit multilib directory.]),,
 813     withval="")
 814 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 815                    [64 bit multilib directory.])
 816
 817 dnl Allow linking of LLVM with GPLv3 binutils code.
 818 AC_ARG_WITH(binutils-include,
 819   AS_HELP_STRING([--with-binutils-include],
 820     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 821   withval=default)
 822 case "$withval" in
 823   default) WITH_BINUTILS_INCDIR=default ;;
 824   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 825   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 826 esac
 827 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 828   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 829   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 830      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 831      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 832   fi
 833 fi
 834
 835 dnl --enable-libffi : check whether the user wants to turn off libffi:
 836 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 837   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 838   [case "$enableval" in
 839     yes) llvm_cv_enable_libffi="yes" ;;
 840     no)  llvm_cv_enable_libffi="no"  ;;
 841     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 842   esac],
 843   llvm_cv_enable_libffi=no)
 844
 845 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 846 if test "$llvm_cv_os_type" = "Win32" ; then
 847    llvmc_dynamic="yes"
 848 else
 849    llvmc_dynamic="no"
 850 fi
 851
 852 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 853 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 854 --enable-llvmc-dynamic,
 855 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 856 enableval=$llvmc_dynamic)
 857 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 858    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 859 else
 860    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 861 fi
 862
 863 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 864 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 865 --enable-llvmc-dynamic-plugins,
 866 [Enable dynamic LLVMC plugins (default is YES)]),,
 867 enableval=yes)
 868 if test ${enableval} = "yes" ; then
 869    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 870 else
 871    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 872 fi
 873
 874 dnl===-----------------------------------------------------------------------===
 875 dnl===
 876 dnl=== SECTION 4: Check for programs we need and that they are the right version
 877 dnl===
 878 dnl===-----------------------------------------------------------------------===
 879
 880 dnl Check for compilation tools
 881 AC_PROG_CPP
 882 AC_PROG_CC(gcc)
 883 AC_PROG_CXX(g++)
 884
 885 AC_PROG_NM
 886 AC_SUBST(NM)
 887
 888 dnl Check for the tools that the makefiles require
 889 AC_CHECK_GNU_MAKE
 890 AC_PROG_LN_S
 891 AC_PATH_PROG(CMP, [cmp], [cmp])
 892 AC_PATH_PROG(CP, [cp], [cp])
 893 AC_PATH_PROG(DATE, [date], [date])
 894 AC_PATH_PROG(FIND, [find], [find])
 895 AC_PATH_PROG(GREP, [grep], [grep])
 896 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 897 AC_PATH_PROG(MV,   [mv],   [mv])
 898 AC_PROG_RANLIB
 899 AC_CHECK_TOOL(AR, ar, false)
 900 AC_PATH_PROG(RM,   [rm],   [rm])
 901 AC_PATH_PROG(SED,  [sed],  [sed])
 902 AC_PATH_PROG(TAR,  [tar],  [gtar])
 903 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 904
 905 dnl Looking for misc. graph plotting software
 906 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 907 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 908   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 909   dnl If we're targeting for mingw we should emit windows paths, not msys
 910   if test "$llvm_cv_os_type" = "MingW" ; then
 911     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 912   fi
 913   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 914    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 915 fi
 916 AC_PATH_PROG(DOT, [dot], [echo dot])
 917 if test "$DOT" != "echo dot" ; then
 918   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 919   dnl If we're targeting for mingw we should emit windows paths, not msys
 920   if test "$llvm_cv_os_type" = "MingW" ; then
 921     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 922   fi
 923   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 924    [Define to path to dot program if found or 'echo dot' otherwise])
 925 fi
 926 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 927 if test "$FDP" != "echo fdp" ; then
 928   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 929   dnl If we're targeting for mingw we should emit windows paths, not msys
 930   if test "$llvm_cv_os_type" = "MingW" ; then
 931     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 932   fi
 933   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 934    [Define to path to fdp program if found or 'echo fdp' otherwise])
 935 fi
 936 AC_PATH_PROG(NEATO, [neato], [echo neato])
 937 if test "$NEATO" != "echo neato" ; then
 938   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 939   dnl If we're targeting for mingw we should emit windows paths, not msys
 940   if test "$llvm_cv_os_type" = "MingW" ; then
 941     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 942   fi
 943   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 944    [Define to path to neato program if found or 'echo neato' otherwise])
 945 fi
 946 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 947 if test "$TWOPI" != "echo twopi" ; then
 948   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 949   dnl If we're targeting for mingw we should emit windows paths, not msys
 950   if test "$llvm_cv_os_type" = "MingW" ; then
 951     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 952   fi
 953   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 954    [Define to path to twopi program if found or 'echo twopi' otherwise])
 955 fi
 956 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 957 if test "$CIRCO" != "echo circo" ; then
 958   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 959   dnl If we're targeting for mingw we should emit windows paths, not msys
 960   if test "$llvm_cv_os_type" = "MingW" ; then
 961     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 962   fi
 963   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 964    [Define to path to circo program if found or 'echo circo' otherwise])
 965 fi
 966 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 967 if test "$GV" != "echo gv" ; then
 968   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 969   dnl If we're targeting for mingw we should emit windows paths, not msys
 970   if test "$llvm_cv_os_type" = "MingW" ; then
 971     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 972   fi
 973   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 974    [Define to path to gv program if found or 'echo gv' otherwise])
 975 fi
 976 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 977 if test "$DOTTY" != "echo dotty" ; then
 978   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 979   dnl If we're targeting for mingw we should emit windows paths, not msys
 980   if test "$llvm_cv_os_type" = "MingW" ; then
 981     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 982   fi
 983   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 984    [Define to path to dotty program if found or 'echo dotty' otherwise])
 985 fi
 986
 987 dnl Look for a sufficiently recent version of Perl.
 988 LLVM_PROG_PERL([5.006])
 989 AC_SUBST(PERL)
 990 if test x"$PERL" = xnone; then
 991    AC_SUBST(HAVE_PERL,0)
 992    AC_MSG_ERROR([perl is required but was not found, please install it])
 993 else
 994    AC_SUBST(HAVE_PERL,1)
 995 fi
 996
 997 dnl Find the install program
 998 AC_PROG_INSTALL
 999
1000 dnl Checks for documentation and testing tools that we can do without. If these
1001 dnl are not found then they are set to "true" which always succeeds but does
1002 dnl nothing. This just lets the build output show that we could have done
1003 dnl something if the tool was available.
1004 AC_PATH_PROG(BZIP2, [bzip2])
1005 AC_PATH_PROG(DOXYGEN, [doxygen])
1006 AC_PATH_PROG(GROFF, [groff])
1007 AC_PATH_PROG(GZIP, [gzip])
1008 AC_PATH_PROG(POD2HTML, [pod2html])
1009 AC_PATH_PROG(POD2MAN, [pod2man])
1010 AC_PATH_PROG(RUNTEST, [runtest])
1011 DJ_AC_PATH_TCLSH
1012 AC_PATH_PROG(ZIP, [zip])
1013 AC_PATH_PROGS(OCAMLC, [ocamlc])
1014 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1015 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1016 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1017 AC_PATH_PROGS(GAS, [gas as])
1018
1019 dnl Determine whether the linker supports the -R option.
1020 AC_LINK_USE_R
1021
1022 dnl Determine whether the linker supports the -export-dynamic option.
1023 AC_LINK_EXPORT_DYNAMIC
1024
1025 dnl Check for libtool and the library that has dlopen function (which must come
1026 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1027 dnl libtool).
1028 AC_LIBTOOL_DLOPEN
1029 AC_LIB_LTDL
1030
1031 if test "$WITH_LLVMGCCDIR" = "default" ; then
1032   LLVMGCC="llvm-gcc${EXEEXT}"
1033   LLVMGXX="llvm-g++${EXEEXT}"
1034   LLVMGCCCOMMAND="$LLVMGCC"
1035   LLVMGXXCOMMAND="$LLVMGXX"
1036   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1037   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1038   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
1039   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
1040 else
1041   if test -z "$LLVMGCC"; then
1042     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
1043     LLVMGCCCOMMAND="$LLVMGCC"
1044   fi
1045   if test -z "$LLVMGXX"; then
1046     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1047     LLVMGXXCOMMAND="$LLVMGXX"
1048   fi
1049
1050   AC_SUBST(LLVMGCC,$LLVMGCC)
1051   AC_SUBST(LLVMGXX,$LLVMGXX)
1052   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1053   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1054 fi
1055
1056 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1057 dnl found, otherwise clang if available.
1058 AC_ARG_WITH(llvmcc,
1059   AS_HELP_STRING([--with-llvmcc=<name>],
1060     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1061     [],[with_llvmcc=check])
1062 AC_MSG_CHECKING([LLVM capable compiler])
1063 if test "$with_llvmcc" != "check"; then
1064    if (test "$with_llvmcc" != "llvm-gcc" &&
1065        test "$with_llvmcc" != "clang" &&
1066        test "$with_llvmcc" != "none"); then
1067       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1068    fi
1069    WITH_LLVMCC="$with_llvmcc"
1070 elif test -n "$LLVMGCC"; then
1071    WITH_LLVMCC=llvm-gcc
1072 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1073    WITH_LLVMCC=clang
1074 else
1075    WITH_LLVMCC=none
1076 fi
1077 AC_MSG_RESULT([$WITH_LLVMCC])
1078 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1079
1080 AC_MSG_CHECKING([tool compatibility])
1081
1082 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1083 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1084 dnl to support those options.
1085 dnl "icc" emits gcc signatures
1086 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1087 ICC=no
1088 IXX=no
1089 case $CC in
1090   icc*|icpc*)
1091     ICC=yes
1092     IXX=yes
1093     ;;
1094    *)
1095     ;;
1096 esac
1097
1098 if test "$GCC" != "yes" && test "$ICC" != "yes"
1099 then
1100   AC_MSG_ERROR([gcc|icc required but not found])
1101 fi
1102
1103 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
1104 if test "$GXX" != "yes" && test "$IXX" != "yes"
1105 then
1106   AC_MSG_ERROR([g++|icc required but not found])
1107 fi
1108
1109 dnl Verify that GCC is version 3.0 or higher
1110 if test "$GCC" = "yes"
1111 then
1112   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1113 #error Unsupported GCC version
1114 #endif
1115 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1116 fi
1117
1118 dnl Check for GNU Make.  We use its extensions, so don't build without it
1119 if test -z "$llvm_cv_gnu_make_command"
1120 then
1121   AC_MSG_ERROR([GNU Make required but not found])
1122 fi
1123
1124 dnl Tool compatibility is okay if we make it here.
1125 AC_MSG_RESULT([ok])
1126
1127 dnl Check optional compiler flags.
1128 AC_MSG_CHECKING([optional compiler flags])
1129 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1130 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1131 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1132
1133 dnl===-----------------------------------------------------------------------===
1134 dnl===
1135 dnl=== SECTION 5: Check for libraries
1136 dnl===
1137 dnl===-----------------------------------------------------------------------===
1138
1139 AC_CHECK_LIB(m,sin)
1140 if test "$llvm_cv_os_type" = "MingW" ; then
1141   AC_CHECK_LIB(imagehlp, main)
1142   AC_CHECK_LIB(psapi, main)
1143 fi
1144
1145 dnl dlopen() is required for plugin support.
1146 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1147                [Define if dlopen() is available on this platform.]),
1148                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1149
1150 dnl libffi is optional; used to call external functions from the interpreter
1151 if test "$llvm_cv_enable_libffi" = "yes" ; then
1152   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1153                  [Define if libffi is available on this platform.]),
1154                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1155 fi
1156
1157 dnl mallinfo is optional; the code can compile (minus features) without it
1158 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1159                [Define if mallinfo() is available on this platform.]))
1160
1161 dnl pthread locking functions are optional - but llvm will not be thread-safe
1162 dnl without locks.
1163 if test "$ENABLE_THREADS" -eq 1 ; then
1164   AC_CHECK_LIB(pthread, pthread_mutex_init)
1165   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1166                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1167                            [Have pthread_mutex_lock]))
1168   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1169                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1170                  [Have pthread_rwlock_init]))
1171   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1172                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1173                  [Have pthread_getspecific]))
1174 fi
1175
1176 dnl Allow extra x86-disassembler library
1177 AC_ARG_WITH(udis86,
1178   AS_HELP_STRING([--with-udis86=<path>],
1179     [Use udis86 external x86 disassembler library]),
1180     [
1181       AC_SUBST(USE_UDIS86, [1])
1182       case "$withval" in
1183         /usr/lib|yes) ;;
1184         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1185       esac
1186       AC_CHECK_LIB(udis86, ud_init, [], [
1187         echo "Error! You need to have libudis86 around."
1188         exit -1
1189       ])
1190     ],
1191     AC_SUBST(USE_UDIS86, [0]))
1192 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1193                    [Define if use udis86 library])
1194
1195 dnl Allow OProfile support for JIT output.
1196 AC_ARG_WITH(oprofile,
1197   AS_HELP_STRING([--with-oprofile=<prefix>],
1198     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1199     [
1200       AC_SUBST(USE_OPROFILE, [1])
1201       case "$withval" in
1202         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1203         no) llvm_cv_oppath=
1204             AC_SUBST(USE_OPROFILE, [0]) ;;
1205         *) llvm_cv_oppath="${withval}/lib/oprofile"
1206            CPPFLAGS="-I${withval}/include";;
1207       esac
1208       if test -n "$llvm_cv_oppath" ; then
1209         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1210         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1211         dnl libbfd is not included properly in libopagent in some Debian
1212         dnl versions.  If libbfd isn't found at all, we assume opagent works
1213         dnl anyway.
1214         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1215         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1216           echo "Error! You need to have libopagent around."
1217           exit -1
1218         ])
1219         AC_CHECK_HEADER([opagent.h], [], [
1220           echo "Error! You need to have opagent.h around."
1221           exit -1
1222           ])
1223       fi
1224     ],
1225     [
1226       AC_SUBST(USE_OPROFILE, [0])
1227     ])
1228 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1229                    [Define if we have the oprofile JIT-support library])
1230
1231 dnl===-----------------------------------------------------------------------===
1232 dnl===
1233 dnl=== SECTION 6: Check for header files
1234 dnl===
1235 dnl===-----------------------------------------------------------------------===
1236
1237 dnl First, use autoconf provided macros for specific headers that we need
1238 dnl We don't check for ancient stuff or things that are guaranteed to be there
1239 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1240 dnl Generally we're looking for POSIX headers.
1241 AC_HEADER_DIRENT
1242 AC_HEADER_MMAP_ANONYMOUS
1243 AC_HEADER_STAT
1244 AC_HEADER_STDC
1245 AC_HEADER_SYS_WAIT
1246 AC_HEADER_TIME
1247
1248 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1249 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1250 AC_CHECK_HEADERS([utime.h windows.h])
1251 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1252 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1253 AC_CHECK_HEADERS([valgrind/valgrind.h])
1254 if test "$ENABLE_THREADS" -eq 1 ; then
1255   AC_CHECK_HEADERS(pthread.h,
1256                    AC_SUBST(HAVE_PTHREAD, 1),
1257                    AC_SUBST(HAVE_PTHREAD, 0))
1258 else
1259   AC_SUBST(HAVE_PTHREAD, 0)
1260 fi
1261
1262 dnl Try to find ffi.h.
1263 if test "$llvm_cv_enable_libffi" = "yes" ; then
1264   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1265 fi
1266
1267 dnl===-----------------------------------------------------------------------===
1268 dnl===
1269 dnl=== SECTION 7: Check for types and structures
1270 dnl===
1271 dnl===-----------------------------------------------------------------------===
1272
1273 AC_HUGE_VAL_CHECK
1274 AC_TYPE_PID_T
1275 AC_TYPE_SIZE_T
1276 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1277 AC_STRUCT_TM
1278 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1279 AC_CHECK_TYPES([uint64_t],,
1280          AC_CHECK_TYPES([u_int64_t],,
1281          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1282
1283 dnl===-----------------------------------------------------------------------===
1284 dnl===
1285 dnl=== SECTION 8: Check for specific functions needed
1286 dnl===
1287 dnl===-----------------------------------------------------------------------===
1288
1289 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1290 AC_CHECK_FUNCS([powf fmodf strtof round ])
1291 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1292 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1293 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup ])
1294 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1295 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1296 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1297 AC_C_PRINTF_A
1298 AC_FUNC_RAND48
1299
1300 dnl Check for variations in the Standard C++ library and STL. These macros are
1301 dnl provided by LLVM in the autoconf/m4 directory.
1302 AC_FUNC_ISNAN
1303 AC_FUNC_ISINF
1304
1305 dnl Check for mmap support.We also need to know if /dev/zero is required to
1306 dnl be opened for allocating RWX memory.
1307 dnl Make sure we aren't attempting to configure for an unknown system
1308 if test "$llvm_cv_platform_type" = "Unix" ; then
1309   AC_FUNC_MMAP
1310   AC_FUNC_MMAP_FILE
1311   AC_NEED_DEV_ZERO_FOR_MMAP
1312
1313   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1314   then
1315     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1316   fi
1317   if test "$ac_cv_func_mmap_file" = "no"
1318   then
1319     AC_MSG_WARN([mmap() of files required but not found])
1320   fi
1321 fi
1322
1323 dnl atomic builtins are required for threading support.
1324 AC_MSG_CHECKING(for GCC atomic builtins)
1325 AC_LINK_IFELSE(
1326   AC_LANG_SOURCE(
1327     [[int main() {
1328         volatile unsigned long val = 1;
1329         __sync_synchronize();
1330         __sync_val_compare_and_swap(&val, 1, 0);
1331         __sync_add_and_fetch(&val, 1);
1332         __sync_sub_and_fetch(&val, 1);
1333         return 0;
1334       }
1335     ]]),
1336   AC_MSG_RESULT(yes)
1337   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1338   AC_MSG_RESULT(no)
1339   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1340   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1341
1342
1343 dnl===-----------------------------------------------------------------------===
1344 dnl===
1345 dnl=== SECTION 9: Additional checks, variables, etc.
1346 dnl===
1347 dnl===-----------------------------------------------------------------------===
1348
1349 dnl Handle 32-bit linux systems running a 64-bit kernel.
1350 dnl This has to come after section 4 because it invokes the compiler.
1351 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1352   AC_IS_LINUX_MIXED
1353   if test "$llvm_cv_linux_mixed" = "yes"; then
1354     llvm_cv_target_arch="x86"
1355     ARCH="x86"
1356   fi
1357 fi
1358
1359 dnl Check, whether __dso_handle is present
1360 AC_CHECK_FUNCS([__dso_handle])
1361
1362 dnl See if the llvm-gcc executable can compile to LLVM assembly
1363 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1364 [llvm_cv_llvmgcc_sanity="no"
1365 if test -x "$LLVMGCC" ; then
1366   cp /dev/null conftest.c
1367   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1368       grep 'target datalayout =' > /dev/null 2>&1
1369   if test $? -eq 0 ; then
1370     llvm_cv_llvmgcc_sanity="yes"
1371   fi
1372   rm conftest.c
1373 fi])
1374
1375 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1376 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1377   AC_MSG_CHECKING([llvm-gcc component support])
1378   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1379   AC_SUBST(LLVMCC1,$llvmcc1path)
1380   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1381   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1382   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1383   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1384   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1385   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1386   AC_MSG_RESULT([ok])
1387 fi
1388
1389 dnl Propagate the shared library extension that the libltdl checks did to
1390 dnl the Makefiles so we can use it there too
1391 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1392
1393 dnl Propagate the run-time library path variable that the libltdl
1394 dnl checks found to the Makefiles so we can use it there too
1395 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1396
1397 # Translate the various configuration directories and other basic
1398 # information into substitutions that will end up in Makefile.config.in
1399 # that these configured values can be used by the makefiles
1400 if test "${prefix}" = "NONE" ; then
1401   prefix="/usr/local"
1402 fi
1403 eval LLVM_PREFIX="${prefix}";
1404 eval LLVM_BINDIR="${prefix}/bin";
1405 eval LLVM_LIBDIR="${prefix}/lib";
1406 eval LLVM_DATADIR="${prefix}/share/llvm";
1407 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1408 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1409 eval LLVM_INCLUDEDIR="${prefix}/include";
1410 eval LLVM_INFODIR="${prefix}/info";
1411 eval LLVM_MANDIR="${prefix}/man";
1412 LLVM_CONFIGTIME=`date`
1413 AC_SUBST(LLVM_PREFIX)
1414 AC_SUBST(LLVM_BINDIR)
1415 AC_SUBST(LLVM_LIBDIR)
1416 AC_SUBST(LLVM_DATADIR)
1417 AC_SUBST(LLVM_DOCSDIR)
1418 AC_SUBST(LLVM_ETCDIR)
1419 AC_SUBST(LLVM_INCLUDEDIR)
1420 AC_SUBST(LLVM_INFODIR)
1421 AC_SUBST(LLVM_MANDIR)
1422 AC_SUBST(LLVM_CONFIGTIME)
1423
1424 # Place the various directores into the config.h file as #defines so that we
1425 # can know about the installation paths within LLVM.
1426 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1427                    [Installation prefix directory])
1428 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1429                    [Installation directory for binary executables])
1430 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1431                    [Installation directory for libraries])
1432 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1433                    [Installation directory for data files])
1434 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1435                    [Installation directory for documentation])
1436 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1437                    [Installation directory for config files])
1438 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1439                    [Installation directory for include files])
1440 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1441                    [Installation directory for .info files])
1442 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1443                    [Installation directory for man pages])
1444 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1445                    [Time at which LLVM was configured])
1446 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1447                    [Host triple we were built on])
1448
1449 # Determine which bindings to build.
1450 if test "$BINDINGS_TO_BUILD" = auto ; then
1451   BINDINGS_TO_BUILD=""
1452   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1453     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1454   fi
1455 fi
1456 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1457
1458 # This isn't really configurey, but it avoids having to repeat the list in
1459 # other files.
1460 AC_SUBST(ALL_BINDINGS,ocaml)
1461
1462 # Do any work necessary to ensure that bindings have what they need.
1463 binding_prereqs_failed=0
1464 for a_binding in $BINDINGS_TO_BUILD ; do
1465   case "$a_binding" in
1466   ocaml)
1467     if test "x$OCAMLC" = x ; then
1468       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1469       binding_prereqs_failed=1
1470     fi
1471     if test "x$OCAMLDEP" = x ; then
1472       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1473       binding_prereqs_failed=1
1474     fi
1475     if test "x$OCAMLOPT" = x ; then
1476       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1477       dnl ocamlopt is optional!
1478     fi
1479     if test "x$with_ocaml_libdir" != xauto ; then
1480       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1481     else
1482       ocaml_stdlib="`"$OCAMLC" -where`"
1483       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1484       then
1485         # ocaml stdlib is beneath our prefix; use stdlib
1486         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1487       else
1488         # ocaml stdlib is outside our prefix; use libdir/ocaml
1489         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1490       fi
1491     fi
1492     ;;
1493   esac
1494 done
1495 if test "$binding_prereqs_failed" = 1 ; then
1496   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1497 fi
1498
1499 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1500 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1501
1502 dnl Determine linker rpath flag
1503 if test "$llvm_cv_link_use_r" = "yes" ; then
1504   RPATH="-Wl,-R"
1505 else
1506   RPATH="-Wl,-rpath"
1507 fi
1508 AC_SUBST(RPATH)
1509
1510 dnl Determine linker rdynamic flag
1511 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1512   RDYNAMIC="-Wl,-export-dynamic"
1513 else
1514   RDYNAMIC=""
1515 fi
1516 AC_SUBST(RDYNAMIC)
1517
1518 dnl===-----------------------------------------------------------------------===
1519 dnl===
1520 dnl=== SECTION 10: Specify the output files and generate it
1521 dnl===
1522 dnl===-----------------------------------------------------------------------===
1523
1524 dnl Configure header files
1525 dnl WARNING: dnl If you add or remove any of the following config headers, then
1526 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1527 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1528 dnl files can be updated automatically when their *.in sources change.
1529 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1530 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1531 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1532 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1533 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1534 AC_CONFIG_HEADERS([include/llvm/System/DataTypes.h])
1535
1536 dnl Configure the makefile's configuration data
1537 AC_CONFIG_FILES([Makefile.config])
1538
1539 dnl Configure the RPM spec file for LLVM
1540 AC_CONFIG_FILES([llvm.spec])
1541
1542 dnl Configure doxygen's configuration file
1543 AC_CONFIG_FILES([docs/doxygen.cfg])
1544
1545 dnl Configure llvmc's Base plugin
1546 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1547
1548 dnl Do the first stage of configuration for llvm-config.in.
1549 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1550
1551 dnl Do special configuration of Makefiles
1552 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1553 AC_CONFIG_MAKEFILE(Makefile)
1554 AC_CONFIG_MAKEFILE(Makefile.common)
1555 AC_CONFIG_MAKEFILE(examples/Makefile)
1556 AC_CONFIG_MAKEFILE(lib/Makefile)
1557 AC_CONFIG_MAKEFILE(runtime/Makefile)
1558 AC_CONFIG_MAKEFILE(test/Makefile)
1559 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1560 AC_CONFIG_MAKEFILE(unittests/Makefile)
1561 AC_CONFIG_MAKEFILE(tools/Makefile)
1562 AC_CONFIG_MAKEFILE(utils/Makefile)
1563 AC_CONFIG_MAKEFILE(projects/Makefile)
1564 AC_CONFIG_MAKEFILE(bindings/Makefile)
1565 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1566
1567 dnl Finally, crank out the output
1568 AC_OUTPUT