autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.1svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [1], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2012 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2012 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl We need to check for the compiler up here to avoid anything else
  63 dnl starting with a different one.
  64 AC_PROG_CC(clang llvm-gcc gcc)
  65 AC_PROG_CXX(clang++ llvm-g++ g++)
  66 AC_PROG_CPP
  67
  68 dnl Configure all of the projects present in our source tree. While we could
  69 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  70 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  71 dnl Instead we match on the known projects.
  72
  73 dnl
  74 dnl One tricky part of doing this is that some projects depend upon other
  75 dnl projects.  For example, several projects rely upon the LLVM test suite.
  76 dnl We want to configure those projects first so that their object trees are
  77 dnl created before running the configure scripts of projects that depend upon
  78 dnl them.
  79 dnl
  80
  81 dnl Several projects use llvm-gcc, so configure that first
  82 if test -d ${srcdir}/projects/llvm-gcc ; then
  83   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  84 fi
  85
  86 dnl Several projects use the LLVM test suite, so configure it next.
  87 if test -d ${srcdir}/projects/test-suite ; then
  88   AC_CONFIG_SUBDIRS([projects/test-suite])
  89 fi
  90
  91 dnl llvm-test is the old name of the test-suite, kept here for backwards
  92 dnl compatibility
  93 if test -d ${srcdir}/projects/llvm-test ; then
  94   AC_CONFIG_SUBDIRS([projects/llvm-test])
  95 fi
  96
  97 dnl Some projects use poolalloc; configure that next
  98 if test -d ${srcdir}/projects/poolalloc ; then
  99   AC_CONFIG_SUBDIRS([projects/poolalloc])
 100 fi
 101
 102 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 103   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 104 fi
 105
 106 dnl Check for all other projects
 107 for i in `ls ${srcdir}/projects`
 108 do
 109   if test -d ${srcdir}/projects/${i} ; then
 110     case ${i} in
 111       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 112       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 113       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 114       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 115       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 116       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 117       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 118       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 119       compiler-rt)       ;;
 120       llvm-gcc)       ;;
 121       test-suite)     ;;
 122       llvm-test)      ;;
 123       poolalloc)      ;;
 124       llvm-poolalloc) ;;
 125       *)
 126         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 127         ;;
 128     esac
 129   fi
 130 done
 131
 132 dnl Disable the build of polly, even if it is checked out into tools/polly.
 133 AC_ARG_ENABLE(polly,
 134               AS_HELP_STRING([--enable-polly],
 135                              [Use polly if available (default is YES)]),,
 136                              enableval=default)
 137 case "$enableval" in
 138   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 139   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 140   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 141   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 142 esac
 143
 144
 145 dnl Check if polly is checked out into tools/polly and configure it if
 146 dnl available.
 147 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 148   AC_SUBST(LLVM_HAS_POLLY,1)
 149   AC_CONFIG_SUBDIRS([tools/polly])
 150 fi
 151
 152 dnl===-----------------------------------------------------------------------===
 153 dnl===
 154 dnl=== SECTION 2: Architecture, target, and host checks
 155 dnl===
 156 dnl===-----------------------------------------------------------------------===
 157
 158 dnl Check the target for which we're compiling and the host that will do the
 159 dnl compilations. This will tell us which LLVM compiler will be used for
 160 dnl compiling SSA into object code. This needs to be done early because
 161 dnl following tests depend on it.
 162 AC_CANONICAL_TARGET
 163
 164 dnl Determine the platform type and cache its value. This helps us configure
 165 dnl the System library to the correct build platform.
 166 AC_CACHE_CHECK([type of operating system we're going to host on],
 167                [llvm_cv_os_type],
 168 [case $host in
 169   *-*-aix*)
 170     llvm_cv_link_all_option="-Wl,--whole-archive"
 171     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 172     llvm_cv_os_type="AIX"
 173     llvm_cv_platform_type="Unix" ;;
 174   *-*-irix*)
 175     llvm_cv_link_all_option="-Wl,--whole-archive"
 176     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 177     llvm_cv_os_type="IRIX"
 178     llvm_cv_platform_type="Unix" ;;
 179   *-*-cygwin*)
 180     llvm_cv_link_all_option="-Wl,--whole-archive"
 181     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 182     llvm_cv_os_type="Cygwin"
 183     llvm_cv_platform_type="Unix" ;;
 184   *-*-darwin*)
 185     llvm_cv_link_all_option="-Wl,-all_load"
 186     llvm_cv_no_link_all_option="-Wl,-noall_load"
 187     llvm_cv_os_type="Darwin"
 188     llvm_cv_platform_type="Unix" ;;
 189   *-*-minix*)
 190     llvm_cv_link_all_option="-Wl,-all_load"
 191     llvm_cv_no_link_all_option="-Wl,-noall_load"
 192     llvm_cv_os_type="Minix"
 193     llvm_cv_platform_type="Unix" ;;
 194   *-*-freebsd* | *-*-kfreebsd-gnu)
 195     llvm_cv_link_all_option="-Wl,--whole-archive"
 196     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 197     llvm_cv_os_type="FreeBSD"
 198     llvm_cv_platform_type="Unix" ;;
 199   *-*-openbsd*)
 200     llvm_cv_link_all_option="-Wl,--whole-archive"
 201     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 202     llvm_cv_os_type="OpenBSD"
 203     llvm_cv_platform_type="Unix" ;;
 204   *-*-netbsd*)
 205     llvm_cv_link_all_option="-Wl,--whole-archive"
 206     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 207     llvm_cv_os_type="NetBSD"
 208     llvm_cv_platform_type="Unix" ;;
 209   *-*-dragonfly*)
 210     llvm_cv_link_all_option="-Wl,--whole-archive"
 211     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 212     llvm_cv_os_type="DragonFly"
 213     llvm_cv_platform_type="Unix" ;;
 214   *-*-hpux*)
 215     llvm_cv_link_all_option="-Wl,--whole-archive"
 216     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 217     llvm_cv_os_type="HP-UX"
 218     llvm_cv_platform_type="Unix" ;;
 219   *-*-interix*)
 220     llvm_cv_link_all_option="-Wl,--whole-archive"
 221     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 222     llvm_cv_os_type="Interix"
 223     llvm_cv_platform_type="Unix" ;;
 224   *-*-linux*)
 225     llvm_cv_link_all_option="-Wl,--whole-archive"
 226     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 227     llvm_cv_os_type="Linux"
 228     llvm_cv_platform_type="Unix" ;;
 229   *-*-gnu*)
 230     llvm_cv_link_all_option="-Wl,--whole-archive"
 231     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 232     llvm_cv_os_type="GNU"
 233     llvm_cv_platform_type="Unix" ;;
 234   *-*-solaris*)
 235     llvm_cv_link_all_option="-Wl,-z,allextract"
 236     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 237     llvm_cv_os_type="SunOS"
 238     llvm_cv_platform_type="Unix" ;;
 239   *-*-auroraux*)
 240     llvm_cv_link_all_option="-Wl,-z,allextract"
 241     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 242     llvm_cv_os_type="AuroraUX"
 243     llvm_cv_platform_type="Unix" ;;
 244   *-*-win32*)
 245     llvm_cv_link_all_option="-Wl,--whole-archive"
 246     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 247     llvm_cv_os_type="Win32"
 248     llvm_cv_platform_type="Win32" ;;
 249   *-*-mingw*)
 250     llvm_cv_link_all_option="-Wl,--whole-archive"
 251     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 252     llvm_cv_os_type="MingW"
 253     llvm_cv_platform_type="Win32" ;;
 254   *-*-haiku*)
 255     llvm_cv_link_all_option="-Wl,--whole-archive"
 256     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 257     llvm_cv_os_type="Haiku"
 258     llvm_cv_platform_type="Unix" ;;
 259   *-unknown-eabi*)
 260     llvm_cv_link_all_option="-Wl,--whole-archive"
 261     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 262     llvm_cv_os_type="Freestanding"
 263     llvm_cv_platform_type="Unix" ;;
 264   *-unknown-elf*)
 265     llvm_cv_link_all_option="-Wl,--whole-archive"
 266     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 267     llvm_cv_os_type="Freestanding"
 268     llvm_cv_platform_type="Unix" ;;
 269   *)
 270     llvm_cv_link_all_option=""
 271     llvm_cv_no_link_all_option=""
 272     llvm_cv_os_type="Unknown"
 273     llvm_cv_platform_type="Unknown" ;;
 274 esac])
 275
 276 AC_CACHE_CHECK([type of operating system we're going to target],
 277                [llvm_cv_target_os_type],
 278 [case $target in
 279   *-*-aix*)
 280     llvm_cv_target_os_type="AIX" ;;
 281   *-*-irix*)
 282     llvm_cv_target_os_type="IRIX" ;;
 283   *-*-cygwin*)
 284     llvm_cv_target_os_type="Cygwin" ;;
 285   *-*-darwin*)
 286     llvm_cv_target_os_type="Darwin" ;;
 287   *-*-minix*)
 288     llvm_cv_target_os_type="Minix" ;;
 289   *-*-freebsd* | *-*-kfreebsd-gnu)
 290     llvm_cv_target_os_type="FreeBSD" ;;
 291   *-*-openbsd*)
 292     llvm_cv_target_os_type="OpenBSD" ;;
 293   *-*-netbsd*)
 294     llvm_cv_target_os_type="NetBSD" ;;
 295   *-*-dragonfly*)
 296     llvm_cv_target_os_type="DragonFly" ;;
 297   *-*-hpux*)
 298     llvm_cv_target_os_type="HP-UX" ;;
 299   *-*-interix*)
 300     llvm_cv_target_os_type="Interix" ;;
 301   *-*-linux*)
 302     llvm_cv_target_os_type="Linux" ;;
 303   *-*-solaris*)
 304     llvm_cv_target_os_type="SunOS" ;;
 305   *-*-auroraux*)
 306     llvm_cv_target_os_type="AuroraUX" ;;
 307   *-*-win32*)
 308     llvm_cv_target_os_type="Win32" ;;
 309   *-*-mingw*)
 310     llvm_cv_target_os_type="MingW" ;;
 311   *-*-haiku*)
 312     llvm_cv_target_os_type="Haiku" ;;
 313   *-*-rtems*)
 314     llvm_cv_target_os_type="RTEMS" ;;
 315   *-*-nacl*)
 316     llvm_cv_target_os_type="NativeClient" ;;
 317   *-unknown-eabi*)
 318     llvm_cv_target_os_type="Freestanding" ;;
 319   *)
 320     llvm_cv_target_os_type="Unknown" ;;
 321 esac])
 322
 323 dnl Make sure we aren't attempting to configure for an unknown system
 324 if test "$llvm_cv_os_type" = "Unknown" ; then
 325   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 326 fi
 327
 328 dnl Set the "OS" Makefile variable based on the platform type so the
 329 dnl makefile can configure itself to specific build hosts
 330 AC_SUBST(OS,$llvm_cv_os_type)
 331 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 332 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 333
 334 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 335 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 336 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 337
 338 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 339 dnl This is used by lib/Support to determine the basic kind of implementation
 340 dnl to use.
 341 case $llvm_cv_platform_type in
 342   Unix)
 343     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 344     AC_SUBST(LLVM_ON_UNIX,[1])
 345     AC_SUBST(LLVM_ON_WIN32,[0])
 346     ;;
 347   Win32)
 348     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 349     AC_SUBST(LLVM_ON_UNIX,[0])
 350     AC_SUBST(LLVM_ON_WIN32,[1])
 351     ;;
 352 esac
 353
 354 dnl Determine what our target architecture is and configure accordingly.
 355 dnl This will allow Makefiles to make a distinction between the hardware and
 356 dnl the OS.
 357 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 358 [case $target in
 359   i?86-*)                 llvm_cv_target_arch="x86" ;;
 360   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 361   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 362   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 363   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 364   mips-*)                 llvm_cv_target_arch="Mips" ;;
 365   mipsel-*)               llvm_cv_target_arch="Mips" ;;
 366   xcore-*)                llvm_cv_target_arch="XCore" ;;
 367   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 368   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 369   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 370   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 371   *)                      llvm_cv_target_arch="Unknown" ;;
 372 esac])
 373
 374 if test "$llvm_cv_target_arch" = "Unknown" ; then
 375   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 376 fi
 377
 378 dnl Determine the LLVM native architecture for the target
 379 case "$llvm_cv_target_arch" in
 380     x86)     LLVM_NATIVE_ARCH="X86" ;;
 381     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 382     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 383 esac
 384
 385 dnl Define a substitution, ARCH, for the target architecture
 386 AC_SUBST(ARCH,$llvm_cv_target_arch)
 387
 388 dnl Check for the endianness of the target
 389 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 390
 391 dnl Check for build platform executable suffix if we're cross-compiling
 392 if test "$cross_compiling" = yes; then
 393   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 394   AC_BUILD_EXEEXT
 395   ac_build_prefix=${build_alias}-
 396   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 397   if test -z "$BUILD_CXX"; then
 398      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 399      if test -z "$BUILD_CXX"; then
 400        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 401      fi
 402   fi
 403 else
 404   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 405 fi
 406
 407 dnl Check to see if there's a .svn or .git directory indicating that this
 408 dnl build is being done from a checkout. This sets up several defaults for
 409 dnl the command line switches. When we build with a checkout directory,
 410 dnl we get a debug with assertions turned on. Without, we assume a source
 411 dnl release and we get an optimized build without assertions.
 412 dnl See --enable-optimized and --enable-assertions below
 413 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 414   cvsbuild="yes"
 415   optimize="no"
 416   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 417 else
 418   cvsbuild="no"
 419   optimize="yes"
 420 fi
 421
 422 dnl===-----------------------------------------------------------------------===
 423 dnl===
 424 dnl=== SECTION 3: Command line arguments for the configure script.
 425 dnl===
 426 dnl===-----------------------------------------------------------------------===
 427
 428 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 429 AC_ARG_ENABLE(libcpp,
 430               AS_HELP_STRING([--enable-libcpp],
 431                              [Use libc++ if available (default is NO)]),,
 432                              enableval=default)
 433 case "$enableval" in
 434   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 435   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 436   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 437   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 438 esac
 439
 440 dnl --enable-optimized : check whether they want to do an optimized build:
 441 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 442  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 443 if test ${enableval} = "no" ; then
 444   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 445 else
 446   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 447 fi
 448
 449 dnl --enable-profiling : check whether they want to do a profile build:
 450 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 451  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 452 if test ${enableval} = "no" ; then
 453   AC_SUBST(ENABLE_PROFILING,[[]])
 454 else
 455   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 456 fi
 457
 458 dnl --enable-assertions : check whether they want to turn on assertions or not:
 459 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 460   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 461 if test ${enableval} = "yes" ; then
 462   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 463 else
 464   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 465 fi
 466
 467 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 468 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 469   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 470 if test ${enableval} = "yes" ; then
 471   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 472   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 473 else
 474   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 475   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 476 fi
 477
 478 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 479 AC_ARG_ENABLE(debug-runtime,
 480    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 481 if test ${enableval} = "no" ; then
 482   AC_SUBST(DEBUG_RUNTIME,[[]])
 483 else
 484   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 485 fi
 486
 487 dnl --enable-debug-symbols : should even optimized compiler libraries
 488 dnl have debug symbols?
 489 AC_ARG_ENABLE(debug-symbols,
 490    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 491 if test ${enableval} = "no" ; then
 492   AC_SUBST(DEBUG_SYMBOLS,[[]])
 493 else
 494   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 495 fi
 496
 497 dnl --enable-jit: check whether they want to enable the jit
 498 AC_ARG_ENABLE(jit,
 499   AS_HELP_STRING(--enable-jit,
 500                  [Enable Just In Time Compiling (default is YES)]),,
 501   enableval=default)
 502 if test ${enableval} = "no"
 503 then
 504   AC_SUBST(JIT,[[]])
 505 else
 506   case "$llvm_cv_target_arch" in
 507     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 508     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 509     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 510     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 511     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 512     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 513     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 514     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 515     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 516     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 517     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 518     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 519   esac
 520 fi
 521
 522 dnl Allow enablement of building and installing docs
 523 AC_ARG_ENABLE(docs,
 524               AS_HELP_STRING([--enable-docs],
 525                              [Build documents (default is YES)]),,
 526                              enableval=default)
 527 case "$enableval" in
 528   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 529   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 530   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 531   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 532 esac
 533
 534 dnl Allow enablement of doxygen generated documentation
 535 AC_ARG_ENABLE(doxygen,
 536               AS_HELP_STRING([--enable-doxygen],
 537                              [Build doxygen documentation (default is NO)]),,
 538                              enableval=default)
 539 case "$enableval" in
 540   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 541   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 542   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 543   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 544 esac
 545
 546 dnl Allow disablement of threads
 547 AC_ARG_ENABLE(threads,
 548               AS_HELP_STRING([--enable-threads],
 549                              [Use threads if available (default is YES)]),,
 550                              enableval=default)
 551 case "$enableval" in
 552   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 553   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 554   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 555   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 556 esac
 557 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 558                    [Define if threads enabled])
 559
 560 dnl Allow disablement of pthread.h
 561 AC_ARG_ENABLE(pthreads,
 562               AS_HELP_STRING([--enable-pthreads],
 563                              [Use pthreads if available (default is YES)]),,
 564                              enableval=default)
 565 case "$enableval" in
 566   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 567   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 568   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 569   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 570 esac
 571
 572 dnl Allow building without position independent code
 573 AC_ARG_ENABLE(pic,
 574   AS_HELP_STRING([--enable-pic],
 575                  [Build LLVM with Position Independent Code (default is YES)]),,
 576                  enableval=default)
 577 case "$enableval" in
 578   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 579   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 580   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 581   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 582 esac
 583 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 584                    [Define if position independent code is enabled])
 585
 586 dnl Allow building a shared library and linking tools against it.
 587 AC_ARG_ENABLE(shared,
 588   AS_HELP_STRING([--enable-shared],
 589                  [Build a shared library and link tools against it (default is NO)]),,
 590                  enableval=default)
 591 case "$enableval" in
 592   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 593   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 594   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 595   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 596 esac
 597
 598 dnl Allow libstdc++ is embedded in LLVM.dll.
 599 AC_ARG_ENABLE(embed-stdcxx,
 600   AS_HELP_STRING([--enable-embed-stdcxx],
 601                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 602                  enableval=default)
 603 case "$enableval" in
 604   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 605   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 606   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 607   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 608 esac
 609
 610 dnl Enable embedding timestamp information into build.
 611 AC_ARG_ENABLE(timestamps,
 612   AS_HELP_STRING([--enable-timestamps],
 613                  [Enable embedding timestamp information in build (default is YES)]),,
 614                  enableval=default)
 615 case "$enableval" in
 616   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 617   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 618   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 619   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 620 esac
 621 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 622                    [Define if timestamp information (e.g., __DATE___) is allowed])
 623
 624 dnl Allow specific targets to be specified for building (or not)
 625 TARGETS_TO_BUILD=""
 626 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 627     [Build specific host targets: all or target1,target2,... Valid targets are:
 628      host, x86, x86_64, sparc, powerpc, arm, mips, spu, hexagon,
 629      xcore, msp430, ptx, cbe, and cpp (default=all)]),,
 630     enableval=all)
 631 if test "$enableval" = host-only ; then
 632   enableval=host
 633 fi
 634 case "$enableval" in
 635   all) TARGETS_TO_BUILD="X86 Sparc PowerPC ARM Mips CellSPU XCore MSP430 CppBackend MBlaze PTX Hexagon" ;;
 636   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 637       case "$a_target" in
 638         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 639         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 640         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 641         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 642         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 643         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 644         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 645         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 646         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 647         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 648         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 649         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 650         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 651         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 652         host) case "$llvm_cv_target_arch" in
 653             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 654             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 655             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 656             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 657             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 658             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 659             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 660             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 661             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 662             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 663             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 664             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 665             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 666           esac ;;
 667         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 668       esac
 669   done
 670   ;;
 671 esac
 672 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 673
 674 dnl Determine whether we are building LLVM support for the native architecture.
 675 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 676 for a_target in $TARGETS_TO_BUILD; do
 677   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 678     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 679       [LLVM architecture name for the native architecture, if available])
 680     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 681     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 682     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 683     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 684     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 685       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 686     fi
 687     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 688       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 689     fi
 690     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 691       [LLVM name for the native Target init function, if available])
 692     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 693       [LLVM name for the native TargetInfo init function, if available])
 694     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 695       [LLVM name for the native target MC init function, if available])
 696     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 697       [LLVM name for the native AsmPrinter init function, if available])
 698     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 699       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 700        [LLVM name for the native AsmParser init function, if available])
 701     fi
 702     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 703       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 704        [LLVM name for the native Disassembler init function, if available])
 705     fi
 706   fi
 707 done
 708
 709 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 710 dnl target feature def files.
 711 LLVM_ENUM_TARGETS=""
 712 LLVM_ENUM_ASM_PRINTERS=""
 713 LLVM_ENUM_ASM_PARSERS=""
 714 LLVM_ENUM_DISASSEMBLERS=""
 715 for target_to_build in $TARGETS_TO_BUILD; do
 716   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 717   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 718     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 719   fi
 720   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 721     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 722   fi
 723   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 724     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 725   fi
 726 done
 727 AC_SUBST(LLVM_ENUM_TARGETS)
 728 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 729 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 730 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 731
 732 dnl Override the option to use for optimized builds.
 733 AC_ARG_WITH(optimize-option,
 734   AS_HELP_STRING([--with-optimize-option],
 735                  [Select the compiler options to use for optimized builds]),,
 736                  withval=default)
 737 AC_MSG_CHECKING([optimization flags])
 738 case "$withval" in
 739   default)
 740     case "$llvm_cv_os_type" in
 741     FreeBSD) optimize_option=-O2 ;;
 742     MingW) optimize_option=-O2 ;;
 743     *)     optimize_option=-O3 ;;
 744     esac ;;
 745   *) optimize_option="$withval" ;;
 746 esac
 747 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 748 AC_MSG_RESULT([$optimize_option])
 749
 750 dnl Specify extra build options
 751 AC_ARG_WITH(extra-options,
 752   AS_HELP_STRING([--with-extra-options],
 753                  [Specify additional options to compile LLVM with]),,
 754                  withval=default)
 755 case "$withval" in
 756   default) EXTRA_OPTIONS= ;;
 757   *) EXTRA_OPTIONS=$withval ;;
 758 esac
 759 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 760
 761 dnl Specify extra linker build options
 762 AC_ARG_WITH(extra-ld-options,
 763   AS_HELP_STRING([--with-extra-ld-options],
 764                  [Specify additional options to link LLVM with]),,
 765                  withval=default)
 766 case "$withval" in
 767   default) EXTRA_LD_OPTIONS= ;;
 768   *) EXTRA_LD_OPTIONS=$withval ;;
 769 esac
 770 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 771
 772 dnl Allow specific bindings to be specified for building (or not)
 773 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 774     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 775     enableval=default)
 776 BINDINGS_TO_BUILD=""
 777 case "$enableval" in
 778   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 779   all ) BINDINGS_TO_BUILD="ocaml" ;;
 780   none | no) BINDINGS_TO_BUILD="" ;;
 781   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 782       case "$a_binding" in
 783         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 784         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 785       esac
 786   done
 787   ;;
 788 esac
 789
 790 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 791 dnl script for bindings/ocaml/configure, except that its auto value depends on
 792 dnl OCAMLC, which is found here to support tests.
 793 AC_ARG_WITH([ocaml-libdir],
 794   [AS_HELP_STRING([--with-ocaml-libdir],
 795     [Specify install location for ocaml bindings (default is stdlib)])],
 796   [],
 797   [withval=auto])
 798 case "$withval" in
 799   auto) with_ocaml_libdir="$withval" ;;
 800   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 801   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 802 esac
 803
 804 AC_ARG_WITH(clang-srcdir,
 805   AS_HELP_STRING([--with-clang-srcdir],
 806     [Directory to the out-of-tree Clang source]),,
 807     withval="-")
 808 case "$withval" in
 809   -) clang_src_root="" ;;
 810   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 811   *) clang_src_root="$ac_pwd/$withval" ;;
 812 esac
 813 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
 814
 815 AC_ARG_WITH(clang-resource-dir,
 816   AS_HELP_STRING([--with-clang-resource-dir],
 817     [Relative directory from the Clang binary for resource files]),,
 818     withval="")
 819 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 820                    [Relative directory for resource files])
 821
 822 AC_ARG_WITH(c-include-dirs,
 823   AS_HELP_STRING([--with-c-include-dirs],
 824     [Colon separated list of directories clang will search for headers]),,
 825     withval="")
 826 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 827                    [Directories clang will search for headers])
 828
 829 # Clang normally uses the system c++ headers and libraries. With this option,
 830 # clang will use the ones provided by a gcc installation instead. This option should
 831 # be passed the same value that was used with --prefix when configuring gcc.
 832 AC_ARG_WITH(gcc-toolchain,
 833   AS_HELP_STRING([--with-gcc-toolchain],
 834     [Directory where gcc is installed.]),,
 835     withval="")
 836 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
 837                    [Directory where gcc is installed.])
 838
 839 dnl Allow linking of LLVM with GPLv3 binutils code.
 840 AC_ARG_WITH(binutils-include,
 841   AS_HELP_STRING([--with-binutils-include],
 842     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 843   withval=default)
 844 case "$withval" in
 845   default) WITH_BINUTILS_INCDIR=default ;;
 846   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 847   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 848 esac
 849 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 850   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 851   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 852      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 853      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 854   fi
 855 fi
 856
 857 dnl Specify the URL where bug reports should be submitted.
 858 AC_ARG_WITH(bug-report-url,
 859   AS_HELP_STRING([--with-bug-report-url],
 860     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 861     withval="http://llvm.org/bugs/")
 862 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 863                    [Bug report URL.])
 864
 865 dnl --enable-libffi : check whether the user wants to turn off libffi:
 866 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 867   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 868   [case "$enableval" in
 869     yes) llvm_cv_enable_libffi="yes" ;;
 870     no)  llvm_cv_enable_libffi="no"  ;;
 871     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 872   esac],
 873   llvm_cv_enable_libffi=no)
 874
 875 AC_ARG_WITH(internal-prefix,
 876   AS_HELP_STRING([--with-internal-prefix],
 877     [Installation directory for internal files]),,
 878     withval="")
 879 AC_SUBST(INTERNAL_PREFIX,[$withval])
 880
 881 dnl===-----------------------------------------------------------------------===
 882 dnl===
 883 dnl=== SECTION 4: Check for programs we need and that they are the right version
 884 dnl===
 885 dnl===-----------------------------------------------------------------------===
 886
 887 AC_PROG_NM
 888 AC_SUBST(NM)
 889
 890 dnl Check for the tools that the makefiles require
 891 AC_CHECK_GNU_MAKE
 892 AC_PROG_LN_S
 893 AC_PATH_PROG(CMP, [cmp], [cmp])
 894 AC_PATH_PROG(CP, [cp], [cp])
 895 AC_PATH_PROG(DATE, [date], [date])
 896 AC_PATH_PROG(FIND, [find], [find])
 897 AC_PATH_PROG(GREP, [grep], [grep])
 898 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 899 AC_PATH_PROG(MV,   [mv],   [mv])
 900 AC_PROG_RANLIB
 901 AC_CHECK_TOOL(AR, ar, false)
 902 AC_PATH_PROG(RM,   [rm],   [rm])
 903 AC_PATH_PROG(SED,  [sed],  [sed])
 904 AC_PATH_PROG(TAR,  [tar],  [gtar])
 905 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 906
 907 dnl Looking for misc. graph plotting software
 908 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 909 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 910   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 911   dnl If we're targeting for mingw we should emit windows paths, not msys
 912   if test "$llvm_cv_os_type" = "MingW" ; then
 913     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 914   fi
 915   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 916    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 917 fi
 918 AC_PATH_PROG(DOT, [dot], [echo dot])
 919 if test "$DOT" != "echo dot" ; then
 920   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 921   dnl If we're targeting for mingw we should emit windows paths, not msys
 922   if test "$llvm_cv_os_type" = "MingW" ; then
 923     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 924   fi
 925   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 926    [Define to path to dot program if found or 'echo dot' otherwise])
 927 fi
 928 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 929 if test "$FDP" != "echo fdp" ; then
 930   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 931   dnl If we're targeting for mingw we should emit windows paths, not msys
 932   if test "$llvm_cv_os_type" = "MingW" ; then
 933     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 934   fi
 935   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 936    [Define to path to fdp program if found or 'echo fdp' otherwise])
 937 fi
 938 AC_PATH_PROG(NEATO, [neato], [echo neato])
 939 if test "$NEATO" != "echo neato" ; then
 940   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 941   dnl If we're targeting for mingw we should emit windows paths, not msys
 942   if test "$llvm_cv_os_type" = "MingW" ; then
 943     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 944   fi
 945   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 946    [Define to path to neato program if found or 'echo neato' otherwise])
 947 fi
 948 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 949 if test "$TWOPI" != "echo twopi" ; then
 950   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 951   dnl If we're targeting for mingw we should emit windows paths, not msys
 952   if test "$llvm_cv_os_type" = "MingW" ; then
 953     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 954   fi
 955   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 956    [Define to path to twopi program if found or 'echo twopi' otherwise])
 957 fi
 958 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 959 if test "$CIRCO" != "echo circo" ; then
 960   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 961   dnl If we're targeting for mingw we should emit windows paths, not msys
 962   if test "$llvm_cv_os_type" = "MingW" ; then
 963     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 964   fi
 965   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 966    [Define to path to circo program if found or 'echo circo' otherwise])
 967 fi
 968 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 969 if test "$GV" != "echo gv" ; then
 970   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 971   dnl If we're targeting for mingw we should emit windows paths, not msys
 972   if test "$llvm_cv_os_type" = "MingW" ; then
 973     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 974   fi
 975   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 976    [Define to path to gv program if found or 'echo gv' otherwise])
 977 fi
 978 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 979 if test "$DOTTY" != "echo dotty" ; then
 980   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 981   dnl If we're targeting for mingw we should emit windows paths, not msys
 982   if test "$llvm_cv_os_type" = "MingW" ; then
 983     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 984   fi
 985   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 986    [Define to path to dotty program if found or 'echo dotty' otherwise])
 987 fi
 988 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
 989 if test "$XDOT_PY" != "echo xdot.py" ; then
 990   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
 991   dnl If we're targeting for mingw we should emit windows paths, not msys
 992   if test "$llvm_cv_os_type" = "MingW" ; then
 993     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 994   fi
 995   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
 996    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
 997 fi
 998
 999 dnl Find the install program
1000 AC_PROG_INSTALL
1001 dnl Prepend src dir to install path dir if it's a relative path
1002 dnl This is a hack for installs that take place in something other
1003 dnl than the top level.
1004 case "$INSTALL" in
1005  [[\\/$]]* | ?:[[\\/]]* ) ;;
1006  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1007 esac
1008
1009 dnl Checks for documentation and testing tools that we can do without. If these
1010 dnl are not found then they are set to "true" which always succeeds but does
1011 dnl nothing. This just lets the build output show that we could have done
1012 dnl something if the tool was available.
1013 AC_PATH_PROG(BZIP2, [bzip2])
1014 AC_PATH_PROG(CAT, [cat])
1015 AC_PATH_PROG(DOXYGEN, [doxygen])
1016 AC_PATH_PROG(GROFF, [groff])
1017 AC_PATH_PROG(GZIPBIN, [gzip])
1018 AC_PATH_PROG(POD2HTML, [pod2html])
1019 AC_PATH_PROG(POD2MAN, [pod2man])
1020 AC_PATH_PROG(PDFROFF, [pdfroff])
1021 AC_PATH_PROG(RUNTEST, [runtest])
1022 DJ_AC_PATH_TCLSH
1023 AC_PATH_PROG(ZIP, [zip])
1024 AC_PATH_PROGS(OCAMLC, [ocamlc])
1025 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1026 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1027 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1028 AC_PATH_PROGS(GAS, [gas as])
1029
1030 dnl Get the version of the linker in use.
1031 AC_LINK_GET_VERSION
1032
1033 dnl Determine whether the linker supports the -R option.
1034 AC_LINK_USE_R
1035
1036 dnl Determine whether the linker supports the -export-dynamic option.
1037 AC_LINK_EXPORT_DYNAMIC
1038
1039 dnl Determine whether the linker supports the --version-script option.
1040 AC_LINK_VERSION_SCRIPT
1041
1042 dnl Check for libtool and the library that has dlopen function (which must come
1043 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1044 dnl libtool).
1045 AC_LIBTOOL_DLOPEN
1046 AC_LIB_LTDL
1047
1048 AC_MSG_CHECKING([tool compatibility])
1049
1050 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1051 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1052 dnl to support those options.
1053 dnl "icc" emits gcc signatures
1054 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1055 ICC=no
1056 IXX=no
1057 case $CC in
1058   icc*|icpc*)
1059     ICC=yes
1060     IXX=yes
1061     ;;
1062    *)
1063     ;;
1064 esac
1065
1066 if test "$GCC" != "yes" && test "$ICC" != "yes"
1067 then
1068   AC_MSG_ERROR([gcc|icc required but not found])
1069 fi
1070
1071 dnl Ensure that compilation tools are compatible with GCC extensions
1072 if test "$GXX" != "yes" && test "$IXX" != "yes"
1073 then
1074   AC_MSG_ERROR([g++|clang++|icc required but not found])
1075 fi
1076
1077 dnl Verify that GCC is version 3.0 or higher
1078 if test "$GCC" = "yes"
1079 then
1080   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1081 #error Unsupported GCC version
1082 #endif
1083 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1084 fi
1085
1086 dnl Check for GNU Make.  We use its extensions, so don't build without it
1087 if test -z "$llvm_cv_gnu_make_command"
1088 then
1089   AC_MSG_ERROR([GNU Make required but not found])
1090 fi
1091
1092 dnl Tool compatibility is okay if we make it here.
1093 AC_MSG_RESULT([ok])
1094
1095 dnl Check optional compiler flags.
1096 AC_MSG_CHECKING([optional compiler flags])
1097 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1098 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1099 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1100 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT])
1101
1102 dnl===-----------------------------------------------------------------------===
1103 dnl===
1104 dnl=== SECTION 5: Check for libraries
1105 dnl===
1106 dnl===-----------------------------------------------------------------------===
1107
1108 AC_CHECK_LIB(m,sin)
1109 if test "$llvm_cv_os_type" = "MingW" ; then
1110   AC_CHECK_LIB(imagehlp, main)
1111   AC_CHECK_LIB(psapi, main)
1112 fi
1113
1114 dnl dlopen() is required for plugin support.
1115 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1116                [Define if dlopen() is available on this platform.]),
1117                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1118
1119 dnl libffi is optional; used to call external functions from the interpreter
1120 if test "$llvm_cv_enable_libffi" = "yes" ; then
1121   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1122                  [Define if libffi is available on this platform.]),
1123                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1124 fi
1125
1126 dnl mallinfo is optional; the code can compile (minus features) without it
1127 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1128                [Define if mallinfo() is available on this platform.]))
1129
1130 dnl pthread locking functions are optional - but llvm will not be thread-safe
1131 dnl without locks.
1132 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1133   AC_CHECK_LIB(pthread, pthread_mutex_init)
1134   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1135                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1136                            [Have pthread_mutex_lock]))
1137   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1138                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1139                  [Have pthread_rwlock_init]))
1140   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1141                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1142                  [Have pthread_getspecific]))
1143 fi
1144
1145 dnl Allow extra x86-disassembler library
1146 AC_ARG_WITH(udis86,
1147   AS_HELP_STRING([--with-udis86=<path>],
1148     [Use udis86 external x86 disassembler library]),
1149     [
1150       AC_SUBST(USE_UDIS86, [1])
1151       case "$withval" in
1152         /usr/lib|yes) ;;
1153         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1154       esac
1155       AC_CHECK_LIB(udis86, ud_init, [], [
1156         echo "Error! You need to have libudis86 around."
1157         exit -1
1158       ])
1159     ],
1160     AC_SUBST(USE_UDIS86, [0]))
1161 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1162                    [Define if use udis86 library])
1163
1164 dnl Allow OProfile support for JIT output.
1165 AC_ARG_WITH(oprofile,
1166   AS_HELP_STRING([--with-oprofile=<prefix>],
1167     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1168     [
1169       AC_SUBST(USE_OPROFILE, [1])
1170       case "$withval" in
1171         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1172         no) llvm_cv_oppath=
1173             AC_SUBST(USE_OPROFILE, [0]) ;;
1174         *) llvm_cv_oppath="${withval}/lib/oprofile"
1175            CPPFLAGS="-I${withval}/include";;
1176       esac
1177       case $llvm_cv_os_type in
1178         Linux)
1179           if test -n "$llvm_cv_oppath" ; then
1180             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1181             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1182             dnl libbfd is not included properly in libopagent in some Debian
1183             dnl versions.  If libbfd isn't found at all, we assume opagent works
1184             dnl anyway.
1185             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1186             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1187               echo "Error! You need to have libopagent around."
1188               exit -1
1189             ])
1190             AC_CHECK_HEADER([opagent.h], [], [
1191               echo "Error! You need to have opagent.h around."
1192               exit -1
1193               ])
1194           fi ;;
1195         *)
1196           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1197       esac
1198     ],
1199     [
1200       AC_SUBST(USE_OPROFILE, [0])
1201     ])
1202 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1203                    [Define if we have the oprofile JIT-support library])
1204
1205 dnl Enable support for Intel JIT Events API.
1206 AC_ARG_WITH(intel-jitevents,
1207   AS_HELP_STRING([--with-intel-jitevents=<vtune-amplifier-dir>],
1208     [Specify location of run-time support library for Intel JIT API (default=/opt/intel/vtune_amplifier_xe_2011)]),
1209     [
1210       case $llvm_cv_os_type in
1211         Linux|Win32|Cygwin|MingW) ;;
1212         *)
1213           AC_MSG_ERROR([
1214             Intel JIT API support is available on Linux and Windows only."]) ;;
1215       esac
1216
1217       AC_SUBST(USE_INTEL_JITEVENTS, [1])
1218       case "$llvm_cv_target_arch" in
1219         x86)    llvm_intel_jitevents_archdir="lib32";;
1220         x86_64) llvm_intel_jitevents_archdir="lib64";;
1221         *)      echo "Target architecture $llvm_cv_target_arch does not support Intel JIT Events API"
1222                 exit -1;;
1223       esac
1224       INTEL_JITEVENTS_INCDIR="/opt/intel/vtune_amplifier_xe_2011/include"
1225       INTEL_JITEVENTS_LIBDIR="/opt/intel/vtune_amplifier_xe_2011/$llvm_intel_jitevents_archdir"
1226       case "$withval" in
1227         /* | [[A-Za-z]]:[[\\/]]*) INTEL_JITEVENTS_INCDIR=$withval/include
1228                                   INTEL_JITEVENTS_LIBDIR=$withval/$llvm_intel_jitevents_archdir ;;
1229         *) ;;
1230       esac
1231
1232       AC_SUBST(INTEL_JITEVENTS_INCDIR)
1233       AC_SUBST(INTEL_JITEVENTS_LIBDIR)
1234
1235       LIBS="$LIBS -L${INTEL_JITEVENTS_LIBDIR}"
1236       CPPFLAGS="$CPPFLAGS -I$INTEL_JITEVENTS_INCDIR"
1237
1238       AC_SEARCH_LIBS(iJIT_IsProfilingActive, jitprofiling, [], [
1239         echo "Error! Cannot find libjitprofiling.a. Please check path specified in flag --with-intel-jitevents"
1240         exit -1
1241       ])
1242       AC_CHECK_HEADER([jitprofiling.h], [], [
1243         echo "Error! Cannot find jitprofiling.h. Please check path specified in flag --with-intel-jitevents"
1244         exit -1
1245       ])
1246
1247     ],
1248     [
1249       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1250     ])
1251 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1252                    [Define if we have the Intel JIT API runtime support library])
1253
1254 dnl===-----------------------------------------------------------------------===
1255 dnl===
1256 dnl=== SECTION 6: Check for header files
1257 dnl===
1258 dnl===-----------------------------------------------------------------------===
1259
1260 dnl First, use autoconf provided macros for specific headers that we need
1261 dnl We don't check for ancient stuff or things that are guaranteed to be there
1262 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1263 dnl Generally we're looking for POSIX headers.
1264 AC_HEADER_DIRENT
1265 AC_HEADER_MMAP_ANONYMOUS
1266 AC_HEADER_STAT
1267 AC_HEADER_SYS_WAIT
1268 AC_HEADER_TIME
1269
1270 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1271 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1272 AC_CHECK_HEADERS([utime.h windows.h])
1273 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1274 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1275 AC_CHECK_HEADERS([valgrind/valgrind.h])
1276 AC_CHECK_HEADERS([fenv.h])
1277 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1278   AC_CHECK_HEADERS(pthread.h,
1279                    AC_SUBST(HAVE_PTHREAD, 1),
1280                    AC_SUBST(HAVE_PTHREAD, 0))
1281 else
1282   AC_SUBST(HAVE_PTHREAD, 0)
1283 fi
1284
1285 dnl Try to find ffi.h.
1286 if test "$llvm_cv_enable_libffi" = "yes" ; then
1287   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1288 fi
1289
1290 dnl Try to find Darwin specific crash reporting libraries.
1291 AC_CHECK_HEADERS([CrashReporterClient.h])
1292
1293 dnl Try to find Darwin specific crash reporting global.
1294 AC_MSG_CHECKING([__crashreporter_info__])
1295 AC_LINK_IFELSE(
1296   AC_LANG_SOURCE(
1297     [[extern const char *__crashreporter_info__;
1298       int main() {
1299         __crashreporter_info__ = "test";
1300         return 0;
1301       }
1302     ]]),
1303   AC_MSG_RESULT(yes)
1304   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1305   AC_MSG_RESULT(no)
1306   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1307             Define if __crashreporter_info__ exists.))
1308
1309 dnl===-----------------------------------------------------------------------===
1310 dnl===
1311 dnl=== SECTION 7: Check for types and structures
1312 dnl===
1313 dnl===-----------------------------------------------------------------------===
1314
1315 AC_HUGE_VAL_CHECK
1316 AC_TYPE_PID_T
1317 AC_TYPE_SIZE_T
1318 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1319 AC_STRUCT_TM
1320 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1321 AC_CHECK_TYPES([uint64_t],,
1322          AC_CHECK_TYPES([u_int64_t],,
1323          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1324
1325 dnl===-----------------------------------------------------------------------===
1326 dnl===
1327 dnl=== SECTION 8: Check for specific functions needed
1328 dnl===
1329 dnl===-----------------------------------------------------------------------===
1330
1331 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1332 AC_CHECK_FUNCS([powf fmodf strtof round ])
1333 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1334 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1335 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit strdup ])
1336 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1337 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1338 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1339 AC_C_PRINTF_A
1340 AC_FUNC_RAND48
1341
1342 dnl Check the declaration "Secure API" on Windows environments.
1343 AC_CHECK_DECLS([strerror_s])
1344
1345 dnl Check symbols in libgcc.a for JIT on Mingw.
1346 if test "$llvm_cv_os_type" = "MingW" ; then
1347   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1348   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1349   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1350   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1351
1352   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1353   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1354   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1355   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1356   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1357   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1358   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1359   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1360   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1361   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1362
1363   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1364   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1365 fi
1366
1367 dnl Check Win32 API EnumerateLoadedModules.
1368 if test "$llvm_cv_os_type" = "MingW" ; then
1369   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1370   AC_COMPILE_IFELSE([[#include <windows.h>
1371 #include <imagehlp.h>
1372 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1373 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1374 [
1375   AC_MSG_RESULT([yes])
1376   llvm_cv_win32_elmcb_pcstr="PCSTR"
1377 ],
1378 [
1379   AC_MSG_RESULT([no])
1380   llvm_cv_win32_elmcb_pcstr="PSTR"
1381 ])
1382   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1383 fi
1384
1385 dnl Check for variations in the Standard C++ library and STL. These macros are
1386 dnl provided by LLVM in the autoconf/m4 directory.
1387 AC_FUNC_ISNAN
1388 AC_FUNC_ISINF
1389
1390 dnl Check for mmap support.We also need to know if /dev/zero is required to
1391 dnl be opened for allocating RWX memory.
1392 dnl Make sure we aren't attempting to configure for an unknown system
1393 if test "$llvm_cv_platform_type" = "Unix" ; then
1394   AC_FUNC_MMAP
1395   AC_FUNC_MMAP_FILE
1396   AC_NEED_DEV_ZERO_FOR_MMAP
1397
1398   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1399   then
1400     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1401   fi
1402   if test "$ac_cv_func_mmap_file" = "no"
1403   then
1404     AC_MSG_WARN([mmap() of files required but not found])
1405   fi
1406 fi
1407
1408 dnl atomic builtins are required for threading support.
1409 AC_MSG_CHECKING(for GCC atomic builtins)
1410 dnl Since we'll be using these atomic builtins in C++ files we should test
1411 dnl the C++ compiler.
1412 AC_LANG_PUSH([C++])
1413 AC_LINK_IFELSE(
1414   AC_LANG_SOURCE(
1415     [[int main() {
1416         volatile unsigned long val = 1;
1417         __sync_synchronize();
1418         __sync_val_compare_and_swap(&val, 1, 0);
1419         __sync_add_and_fetch(&val, 1);
1420         __sync_sub_and_fetch(&val, 1);
1421         return 0;
1422       }
1423     ]]),
1424   AC_LANG_POP([C++])
1425   AC_MSG_RESULT(yes)
1426   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1427   AC_MSG_RESULT(no)
1428   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1429   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1430
1431 dnl===-----------------------------------------------------------------------===
1432 dnl===
1433 dnl=== SECTION 9: Additional checks, variables, etc.
1434 dnl===
1435 dnl===-----------------------------------------------------------------------===
1436
1437 dnl Handle 32-bit linux systems running a 64-bit kernel.
1438 dnl This has to come after section 4 because it invokes the compiler.
1439 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1440   AC_IS_LINUX_MIXED
1441   if test "$llvm_cv_linux_mixed" = "yes"; then
1442     llvm_cv_target_arch="x86"
1443     ARCH="x86"
1444   fi
1445 fi
1446
1447 dnl Check whether __dso_handle is present
1448 AC_CHECK_FUNCS([__dso_handle])
1449
1450 dnl Propagate the shared library extension that the libltdl checks did to
1451 dnl the Makefiles so we can use it there too
1452 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1453
1454 dnl Propagate the run-time library path variable that the libltdl
1455 dnl checks found to the Makefiles so we can use it there too
1456 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1457
1458 dnl Translate the various configuration directories and other basic
1459 dnl information into substitutions that will end up in Makefile.config.in
1460 dnl that these configured values can be used by the makefiles
1461 if test "${prefix}" = "NONE" ; then
1462   prefix="/usr/local"
1463 fi
1464 eval LLVM_PREFIX="${prefix}";
1465 eval LLVM_BINDIR="${prefix}/bin";
1466 eval LLVM_LIBDIR="${prefix}/lib";
1467 eval LLVM_DATADIR="${prefix}/share/llvm";
1468 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1469 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1470 eval LLVM_INCLUDEDIR="${prefix}/include";
1471 eval LLVM_INFODIR="${prefix}/info";
1472 eval LLVM_MANDIR="${prefix}/man";
1473 LLVM_CONFIGTIME=`date`
1474 AC_SUBST(LLVM_PREFIX)
1475 AC_SUBST(LLVM_BINDIR)
1476 AC_SUBST(LLVM_LIBDIR)
1477 AC_SUBST(LLVM_DATADIR)
1478 AC_SUBST(LLVM_DOCSDIR)
1479 AC_SUBST(LLVM_ETCDIR)
1480 AC_SUBST(LLVM_INCLUDEDIR)
1481 AC_SUBST(LLVM_INFODIR)
1482 AC_SUBST(LLVM_MANDIR)
1483 AC_SUBST(LLVM_CONFIGTIME)
1484
1485 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1486 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1487   LLVM_CONFIGTIME="(timestamp not enabled)"
1488 fi
1489
1490 dnl Place the various directories into the config.h file as #defines so that we
1491 dnl can know about the installation paths within LLVM.
1492 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1493                    [Installation prefix directory])
1494 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1495                    [Installation directory for binary executables])
1496 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1497                    [Installation directory for libraries])
1498 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1499                    [Installation directory for data files])
1500 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1501                    [Installation directory for documentation])
1502 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1503                    [Installation directory for config files])
1504 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1505                    [Installation directory for include files])
1506 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1507                    [Installation directory for .info files])
1508 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1509                    [Installation directory for man pages])
1510 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1511                    [Time at which LLVM was configured])
1512 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1513                    [Target triple LLVM will generate code for by default])
1514
1515 dnl Determine which bindings to build.
1516 if test "$BINDINGS_TO_BUILD" = auto ; then
1517   BINDINGS_TO_BUILD=""
1518   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1519     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1520   fi
1521 fi
1522 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1523
1524 dnl This isn't really configurey, but it avoids having to repeat the list in
1525 dnl other files.
1526 AC_SUBST(ALL_BINDINGS,ocaml)
1527
1528 dnl Do any work necessary to ensure that bindings have what they need.
1529 binding_prereqs_failed=0
1530 for a_binding in $BINDINGS_TO_BUILD ; do
1531   case "$a_binding" in
1532   ocaml)
1533     if test "x$OCAMLC" = x ; then
1534       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1535       binding_prereqs_failed=1
1536     fi
1537     if test "x$OCAMLDEP" = x ; then
1538       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1539       binding_prereqs_failed=1
1540     fi
1541     if test "x$OCAMLOPT" = x ; then
1542       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1543       dnl ocamlopt is optional!
1544     fi
1545     if test "x$with_ocaml_libdir" != xauto ; then
1546       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1547     else
1548       ocaml_stdlib="`"$OCAMLC" -where`"
1549       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1550       then
1551         # ocaml stdlib is beneath our prefix; use stdlib
1552         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1553       else
1554         # ocaml stdlib is outside our prefix; use libdir/ocaml
1555         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1556       fi
1557     fi
1558     ;;
1559   esac
1560 done
1561 if test "$binding_prereqs_failed" = 1 ; then
1562   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1563 fi
1564
1565 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1566 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1567
1568 dnl Determine linker rpath flag
1569 if test "$llvm_cv_link_use_r" = "yes" ; then
1570   RPATH="-Wl,-R"
1571 else
1572   RPATH="-Wl,-rpath"
1573 fi
1574 AC_SUBST(RPATH)
1575
1576 dnl Determine linker rdynamic flag
1577 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1578   RDYNAMIC="-Wl,-export-dynamic"
1579 else
1580   RDYNAMIC=""
1581 fi
1582 AC_SUBST(RDYNAMIC)
1583
1584 dnl===-----------------------------------------------------------------------===
1585 dnl===
1586 dnl=== SECTION 10: Specify the output files and generate it
1587 dnl===
1588 dnl===-----------------------------------------------------------------------===
1589
1590 dnl Configure header files
1591 dnl WARNING: dnl If you add or remove any of the following config headers, then
1592 dnl you MUST also update Makefile so that the variable FilesToConfig
1593 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1594 dnl files can be updated automatically when their *.in sources change.
1595 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1596 AH_TOP([#ifndef CONFIG_H
1597 #define CONFIG_H])
1598 AH_BOTTOM([#endif])
1599
1600 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1601 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1602 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1603 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1604 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1605
1606 dnl Configure the makefile's configuration data
1607 AC_CONFIG_FILES([Makefile.config])
1608
1609 dnl Configure the RPM spec file for LLVM
1610 AC_CONFIG_FILES([llvm.spec])
1611
1612 dnl Configure doxygen's configuration file
1613 AC_CONFIG_FILES([docs/doxygen.cfg])
1614
1615 dnl Configure clang, if present
1616 if test "${clang_src_root}" = ""; then
1617   clang_src_root="$srcdir/tools/clang"
1618 fi
1619 if test -f ${clang_src_root}/README.txt; then
1620   dnl Use variables to stay under 80 columns.
1621   configh="include/clang/Config/config.h"
1622   doxy="docs/doxygen.cfg"
1623   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
1624   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
1625 fi
1626
1627 dnl OCaml findlib META file
1628 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1629
1630 dnl Do special configuration of Makefiles
1631 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1632 AC_CONFIG_MAKEFILE(Makefile)
1633 AC_CONFIG_MAKEFILE(Makefile.common)
1634 AC_CONFIG_MAKEFILE(examples/Makefile)
1635 AC_CONFIG_MAKEFILE(lib/Makefile)
1636 AC_CONFIG_MAKEFILE(runtime/Makefile)
1637 AC_CONFIG_MAKEFILE(test/Makefile)
1638 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1639 AC_CONFIG_MAKEFILE(unittests/Makefile)
1640 AC_CONFIG_MAKEFILE(tools/Makefile)
1641 AC_CONFIG_MAKEFILE(utils/Makefile)
1642 AC_CONFIG_MAKEFILE(projects/Makefile)
1643 AC_CONFIG_MAKEFILE(bindings/Makefile)
1644 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1645
1646 dnl Finally, crank out the output
1647 AC_OUTPUT