autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.9svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65
  66 dnl
  67 dnl One tricky part of doing this is that some projects depend upon other
  68 dnl projects.  For example, several projects rely upon the LLVM test suite.
  69 dnl We want to configure those projects first so that their object trees are
  70 dnl created before running the configure scripts of projects that depend upon
  71 dnl them.
  72 dnl
  73
  74 dnl Several projects use llvm-gcc, so configure that first
  75 if test -d ${srcdir}/projects/llvm-gcc ; then
  76   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  77 fi
  78
  79 dnl Several projects use the LLVM test suite, so configure it next.
  80 if test -d ${srcdir}/projects/test-suite ; then
  81   AC_CONFIG_SUBDIRS([projects/test-suite])
  82 fi
  83
  84 dnl llvm-test is the old name of the test-suite, kept here for backwards
  85 dnl compatibility
  86 if test -d ${srcdir}/projects/llvm-test ; then
  87   AC_CONFIG_SUBDIRS([projects/llvm-test])
  88 fi
  89
  90 dnl Some projects use poolalloc; configure that next
  91 if test -d ${srcdir}/projects/poolalloc ; then
  92   AC_CONFIG_SUBDIRS([projects/poolalloc])
  93 fi
  94
  95 if test -d ${srcdir}/projects/llvm-poolalloc ; then
  96   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
  97 fi
  98
  99 dnl Check for all other projects
 100 for i in `ls ${srcdir}/projects`
 101 do
 102   if test -d ${srcdir}/projects/${i} ; then
 103     case ${i} in
 104       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 105       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 106       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 107       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 108       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 109       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 110       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 111       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 112       llvm-gcc)       ;;
 113       test-suite)     ;;
 114       llvm-test)      ;;
 115       poolalloc)      ;;
 116       llvm-poolalloc) ;;
 117       *)
 118         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 119         ;;
 120     esac
 121   fi
 122 done
 123
 124 dnl Disable the build of polly, even if it is checked out into tools/polly.
 125 AC_ARG_ENABLE(polly,
 126               AS_HELP_STRING([--enable-polly],
 127                              [Use polly if available (default is YES)]),,
 128                              enableval=default)
 129 case "$enableval" in
 130   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 131   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 132   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 133   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 134 esac
 135
 136
 137 dnl Check if polly is checked out into tools/polly and configure it if
 138 dnl available.
 139 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 140   AC_SUBST(LLVM_HAS_POLLY,1)
 141   AC_CONFIG_SUBDIRS([tools/polly])
 142 fi
 143
 144 dnl===-----------------------------------------------------------------------===
 145 dnl===
 146 dnl=== SECTION 2: Architecture, target, and host checks
 147 dnl===
 148 dnl===-----------------------------------------------------------------------===
 149
 150 dnl Check the target for which we're compiling and the host that will do the
 151 dnl compilations. This will tell us which LLVM compiler will be used for
 152 dnl compiling SSA into object code. This needs to be done early because
 153 dnl following tests depend on it.
 154 AC_CANONICAL_TARGET
 155
 156 dnl Determine the platform type and cache its value. This helps us configure
 157 dnl the System library to the correct build platform.
 158 AC_CACHE_CHECK([type of operating system we're going to host on],
 159                [llvm_cv_os_type],
 160 [case $host in
 161   *-*-aix*)
 162     llvm_cv_link_all_option="-Wl,--whole-archive"
 163     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 164     llvm_cv_os_type="AIX"
 165     llvm_cv_platform_type="Unix" ;;
 166   *-*-irix*)
 167     llvm_cv_link_all_option="-Wl,--whole-archive"
 168     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 169     llvm_cv_os_type="IRIX"
 170     llvm_cv_platform_type="Unix" ;;
 171   *-*-cygwin*)
 172     llvm_cv_link_all_option="-Wl,--whole-archive"
 173     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 174     llvm_cv_os_type="Cygwin"
 175     llvm_cv_platform_type="Unix" ;;
 176   *-*-darwin*)
 177     llvm_cv_link_all_option="-Wl,-all_load"
 178     llvm_cv_no_link_all_option="-Wl,-noall_load"
 179     llvm_cv_os_type="Darwin"
 180     llvm_cv_platform_type="Unix" ;;
 181   *-*-minix*)
 182     llvm_cv_link_all_option="-Wl,-all_load"
 183     llvm_cv_no_link_all_option="-Wl,-noall_load"
 184     llvm_cv_os_type="Minix"
 185     llvm_cv_platform_type="Unix" ;;
 186   *-*-freebsd*)
 187     llvm_cv_link_all_option="-Wl,--whole-archive"
 188     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 189     llvm_cv_os_type="FreeBSD"
 190     llvm_cv_platform_type="Unix" ;;
 191   *-*-openbsd*)
 192     llvm_cv_link_all_option="-Wl,--whole-archive"
 193     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 194     llvm_cv_os_type="OpenBSD"
 195     llvm_cv_platform_type="Unix" ;;
 196   *-*-netbsd*)
 197     llvm_cv_link_all_option="-Wl,--whole-archive"
 198     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 199     llvm_cv_os_type="NetBSD"
 200     llvm_cv_platform_type="Unix" ;;
 201   *-*-dragonfly*)
 202     llvm_cv_link_all_option="-Wl,--whole-archive"
 203     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 204     llvm_cv_os_type="DragonFly"
 205     llvm_cv_platform_type="Unix" ;;
 206   *-*-hpux*)
 207     llvm_cv_link_all_option="-Wl,--whole-archive"
 208     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 209     llvm_cv_os_type="HP-UX"
 210     llvm_cv_platform_type="Unix" ;;
 211   *-*-interix*)
 212     llvm_cv_link_all_option="-Wl,--whole-archive"
 213     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 214     llvm_cv_os_type="Interix"
 215     llvm_cv_platform_type="Unix" ;;
 216   *-*-linux*)
 217     llvm_cv_link_all_option="-Wl,--whole-archive"
 218     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 219     llvm_cv_os_type="Linux"
 220     llvm_cv_platform_type="Unix" ;;
 221   *-*-solaris*)
 222     llvm_cv_link_all_option="-Wl,-z,allextract"
 223     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 224     llvm_cv_os_type="SunOS"
 225     llvm_cv_platform_type="Unix" ;;
 226   *-*-auroraux*)
 227     llvm_cv_link_all_option="-Wl,-z,allextract"
 228     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 229     llvm_cv_os_type="AuroraUX"
 230     llvm_cv_platform_type="Unix" ;;
 231   *-*-win32*)
 232     llvm_cv_link_all_option="-Wl,--whole-archive"
 233     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 234     llvm_cv_os_type="Win32"
 235     llvm_cv_platform_type="Win32" ;;
 236   *-*-mingw*)
 237     llvm_cv_link_all_option="-Wl,--whole-archive"
 238     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 239     llvm_cv_os_type="MingW"
 240     llvm_cv_platform_type="Win32" ;;
 241   *-*-haiku*)
 242     llvm_cv_link_all_option="-Wl,--whole-archive"
 243     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 244     llvm_cv_os_type="Haiku"
 245     llvm_cv_platform_type="Unix" ;;
 246   *-unknown-eabi*)
 247     llvm_cv_link_all_option="-Wl,--whole-archive"
 248     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 249     llvm_cv_os_type="Freestanding"
 250     llvm_cv_platform_type="Unix" ;;
 251   *-unknown-elf*)
 252     llvm_cv_link_all_option="-Wl,--whole-archive"
 253     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 254     llvm_cv_os_type="Freestanding"
 255     llvm_cv_platform_type="Unix" ;;
 256   *)
 257     llvm_cv_link_all_option=""
 258     llvm_cv_no_link_all_option=""
 259     llvm_cv_os_type="Unknown"
 260     llvm_cv_platform_type="Unknown" ;;
 261 esac])
 262
 263 AC_CACHE_CHECK([type of operating system we're going to target],
 264                [llvm_cv_target_os_type],
 265 [case $target in
 266   *-*-aix*)
 267     llvm_cv_target_os_type="AIX" ;;
 268   *-*-irix*)
 269     llvm_cv_target_os_type="IRIX" ;;
 270   *-*-cygwin*)
 271     llvm_cv_target_os_type="Cygwin" ;;
 272   *-*-darwin*)
 273     llvm_cv_target_os_type="Darwin" ;;
 274   *-*-minix*)
 275     llvm_cv_target_os_type="Minix" ;;
 276   *-*-freebsd*)
 277     llvm_cv_target_os_type="FreeBSD" ;;
 278   *-*-openbsd*)
 279     llvm_cv_target_os_type="OpenBSD" ;;
 280   *-*-netbsd*)
 281     llvm_cv_target_os_type="NetBSD" ;;
 282   *-*-dragonfly*)
 283     llvm_cv_target_os_type="DragonFly" ;;
 284   *-*-hpux*)
 285     llvm_cv_target_os_type="HP-UX" ;;
 286   *-*-interix*)
 287     llvm_cv_target_os_type="Interix" ;;
 288   *-*-linux*)
 289     llvm_cv_target_os_type="Linux" ;;
 290   *-*-solaris*)
 291     llvm_cv_target_os_type="SunOS" ;;
 292   *-*-auroraux*)
 293     llvm_cv_target_os_type="AuroraUX" ;;
 294   *-*-win32*)
 295     llvm_cv_target_os_type="Win32" ;;
 296   *-*-mingw*)
 297     llvm_cv_target_os_type="MingW" ;;
 298   *-*-haiku*)
 299     llvm_cv_target_os_type="Haiku" ;;
 300   *-unknown-eabi*)
 301     llvm_cv_target_os_type="Freestanding" ;;
 302   *)
 303     llvm_cv_target_os_type="Unknown" ;;
 304 esac])
 305
 306 dnl Make sure we aren't attempting to configure for an unknown system
 307 if test "$llvm_cv_os_type" = "Unknown" ; then
 308   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 309 fi
 310
 311 dnl Set the "OS" Makefile variable based on the platform type so the
 312 dnl makefile can configure itself to specific build hosts
 313 AC_SUBST(OS,$llvm_cv_os_type)
 314 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 315 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 316
 317 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 318 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 319 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 320
 321 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 322 dnl This is used by lib/Support to determine the basic kind of implementation
 323 dnl to use.
 324 case $llvm_cv_platform_type in
 325   Unix)
 326     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 327     AC_SUBST(LLVM_ON_UNIX,[1])
 328     AC_SUBST(LLVM_ON_WIN32,[0])
 329     ;;
 330   Win32)
 331     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 332     AC_SUBST(LLVM_ON_UNIX,[0])
 333     AC_SUBST(LLVM_ON_WIN32,[1])
 334     ;;
 335 esac
 336
 337 dnl Determine what our target architecture is and configure accordingly.
 338 dnl This will allow Makefiles to make a distinction between the hardware and
 339 dnl the OS.
 340 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 341 [case $target in
 342   i?86-*)                 llvm_cv_target_arch="x86" ;;
 343   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 344   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 345   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 346   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 347   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 348   mips-*)                 llvm_cv_target_arch="Mips" ;;
 349   xcore-*)                llvm_cv_target_arch="XCore" ;;
 350   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 351   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 352   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 353   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 354   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 355   *)                      llvm_cv_target_arch="Unknown" ;;
 356 esac])
 357
 358 if test "$llvm_cv_target_arch" = "Unknown" ; then
 359   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 360 fi
 361
 362 # Determine the LLVM native architecture for the target
 363 case "$llvm_cv_target_arch" in
 364     x86)     LLVM_NATIVE_ARCH="X86" ;;
 365     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 366     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 367 esac
 368
 369 dnl Define a substitution, ARCH, for the target architecture
 370 AC_SUBST(ARCH,$llvm_cv_target_arch)
 371
 372 dnl Check for the endianness of the target
 373 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 374
 375 dnl Check for build platform executable suffix if we're crosscompiling
 376 if test "$cross_compiling" = yes; then
 377   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 378   AC_BUILD_EXEEXT
 379   ac_build_prefix=${build_alias}-
 380   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 381   if test -z "$BUILD_CXX"; then
 382      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 383      if test -z "$BUILD_CXX"; then
 384        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 385      fi
 386   fi
 387 else
 388   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 389 fi
 390
 391 dnl Check to see if there's a .svn or .git directory indicating that this
 392 dnl build is being done from a checkout. This sets up several defaults for
 393 dnl the command line switches. When we build with a checkout directory,
 394 dnl we get a debug with assertions turned on. Without, we assume a source
 395 dnl release and we get an optimized build without assertions.
 396 dnl See --enable-optimized and --enable-assertions below
 397 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 398   cvsbuild="yes"
 399   optimize="no"
 400   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 401 else
 402   cvsbuild="no"
 403   optimize="yes"
 404 fi
 405
 406 dnl===-----------------------------------------------------------------------===
 407 dnl===
 408 dnl=== SECTION 3: Command line arguments for the configure script.
 409 dnl===
 410 dnl===-----------------------------------------------------------------------===
 411
 412 dnl --enable-optimized : check whether they want to do an optimized build:
 413 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 414  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 415 if test ${enableval} = "no" ; then
 416   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 417 else
 418   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 419 fi
 420
 421 dnl --enable-profiling : check whether they want to do a profile build:
 422 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 423  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 424 if test ${enableval} = "no" ; then
 425   AC_SUBST(ENABLE_PROFILING,[[]])
 426 else
 427   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 428 fi
 429
 430 dnl --enable-assertions : check whether they want to turn on assertions or not:
 431 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 432   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 433 if test ${enableval} = "yes" ; then
 434   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 435 else
 436   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 437 fi
 438
 439 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 440 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 441   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 442 if test ${enableval} = "yes" ; then
 443   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 444   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 445 else
 446   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 447   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 448 fi
 449
 450 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 451 AC_ARG_ENABLE(debug-runtime,
 452    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 453 if test ${enableval} = "no" ; then
 454   AC_SUBST(DEBUG_RUNTIME,[[]])
 455 else
 456   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 457 fi
 458
 459 dnl --enable-debug-symbols : should even optimized compiler libraries
 460 dnl have debug symbols?
 461 AC_ARG_ENABLE(debug-symbols,
 462    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 463 if test ${enableval} = "no" ; then
 464   AC_SUBST(DEBUG_SYMBOLS,[[]])
 465 else
 466   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 467 fi
 468
 469 dnl --enable-jit: check whether they want to enable the jit
 470 AC_ARG_ENABLE(jit,
 471   AS_HELP_STRING(--enable-jit,
 472                  [Enable Just In Time Compiling (default is YES)]),,
 473   enableval=default)
 474 if test ${enableval} = "no"
 475 then
 476   AC_SUBST(JIT,[[]])
 477 else
 478   case "$llvm_cv_target_arch" in
 479     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 480     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 481     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 482     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 483     Alpha)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 484     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 485     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 486     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 487     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 488     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 489     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 490     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 491     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 492     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 493   esac
 494 fi
 495
 496 dnl Allow enablement of building and installing docs
 497 AC_ARG_ENABLE(docs,
 498               AS_HELP_STRING([--enable-docs],
 499                              [Build documents (default is YES)]),,
 500                              enableval=default)
 501 case "$enableval" in
 502   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 503   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 504   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 505   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 506 esac
 507
 508 dnl Allow enablement of doxygen generated documentation
 509 AC_ARG_ENABLE(doxygen,
 510               AS_HELP_STRING([--enable-doxygen],
 511                              [Build doxygen documentation (default is NO)]),,
 512                              enableval=default)
 513 case "$enableval" in
 514   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 515   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 516   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 517   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 518 esac
 519
 520 dnl Allow disablement of threads
 521 AC_ARG_ENABLE(threads,
 522               AS_HELP_STRING([--enable-threads],
 523                              [Use threads if available (default is YES)]),,
 524                              enableval=default)
 525 case "$enableval" in
 526   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 527   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 528   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 529   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 530 esac
 531 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 532
 533 dnl Allow disablement of pthread.h
 534 AC_ARG_ENABLE(pthreads,
 535               AS_HELP_STRING([--enable-pthreads],
 536                              [Use pthreads if available (default is YES)]),,
 537                              enableval=default)
 538 case "$enableval" in
 539   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 540   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 541   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 542   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 543 esac
 544
 545 dnl Allow building without position independent code
 546 AC_ARG_ENABLE(pic,
 547   AS_HELP_STRING([--enable-pic],
 548                  [Build LLVM with Position Independent Code (default is YES)]),,
 549                  enableval=default)
 550 case "$enableval" in
 551   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 552   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 553   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 554   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 555 esac
 556 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 557                    [Define if position independent code is enabled])
 558
 559 dnl Allow building a shared library and linking tools against it.
 560 AC_ARG_ENABLE(shared,
 561   AS_HELP_STRING([--enable-shared],
 562                  [Build a shared library and link tools against it (default is NO)]),,
 563                  enableval=default)
 564 case "$enableval" in
 565   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 566   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 567   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 568   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 569 esac
 570
 571 dnl Enable embedding timestamp information into build.
 572 AC_ARG_ENABLE(timestamps,
 573   AS_HELP_STRING([--enable-timestamps],
 574                  [Enable embedding timestamp information in build (default is YES)]),,
 575                  enableval=default)
 576 case "$enableval" in
 577   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 578   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 579   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 580   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 581 esac
 582 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 583                    [Define if timestamp information (e.g., __DATE___) is allowed])
 584
 585 dnl Allow specific targets to be specified for building (or not)
 586 TARGETS_TO_BUILD=""
 587 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 588     [Build specific host targets: all or target1,target2,... Valid targets are:
 589      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu,
 590      xcore, msp430, systemz, blackfin, ptx, cbe, and cpp (default=all)]),,
 591     enableval=all)
 592 if test "$enableval" = host-only ; then
 593   enableval=host
 594 fi
 595 case "$enableval" in
 596   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU XCore MSP430 SystemZ Blackfin CBackend CppBackend MBlaze PTX" ;;
 597   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 598       case "$a_target" in
 599         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 600         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 601         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 602         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 603         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 604         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 605         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 606         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 607         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 608         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 609         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 610         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 611         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 612         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 613         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 614         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 615         host) case "$llvm_cv_target_arch" in
 616             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 617             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 618             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 619             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 620             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 621             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 622             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 623             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 624             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 625             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 626             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 627             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 628             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 629             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 630             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 631           esac ;;
 632         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 633       esac
 634   done
 635   ;;
 636 esac
 637 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 638
 639 # Determine whether we are building LLVM support for the native architecture.
 640 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 641 for a_target in $TARGETS_TO_BUILD; do
 642   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 643     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 644       [LLVM architecture name for the native architecture, if available])
 645     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 646     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 647     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 648     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 649       [LLVM name for the native Target init function, if available])
 650     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 651       [LLVM name for the native TargetInfo init function, if available])
 652     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 653       [LLVM name for the native AsmPrinter init function, if available])
 654   fi
 655 done
 656
 657 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 658 # target feature def files.
 659 LLVM_ENUM_TARGETS=""
 660 LLVM_ENUM_ASM_PRINTERS=""
 661 LLVM_ENUM_ASM_PARSERS=""
 662 LLVM_ENUM_DISASSEMBLERS=""
 663 for target_to_build in $TARGETS_TO_BUILD; do
 664   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 665   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 666     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 667   fi
 668   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 669     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 670   fi
 671   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 672     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 673   fi
 674 done
 675 AC_SUBST(LLVM_ENUM_TARGETS)
 676 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 677 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 678 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 679
 680 dnl Prevent the CBackend from using printf("%a") for floating point so older
 681 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 682 dnl can still compile the CBE's output
 683 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 684   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 685   enableval=default)
 686 case "$enableval" in
 687   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 688   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 689   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 690   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 691 esac
 692 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 693                    [Define if CBE is enabled for printf %a output])
 694
 695 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 696 AC_ARG_WITH(llvmgccdir,
 697   AS_HELP_STRING([--with-llvmgccdir],
 698     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 699     withval=default)
 700 case "$withval" in
 701   default) WITH_LLVMGCCDIR=default ;;
 702   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 703   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 704 esac
 705
 706 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 707 AC_ARG_WITH(llvmgcc,
 708   AS_HELP_STRING([--with-llvmgcc],
 709     [Specify location of llvm-gcc driver (default searches PATH)]),
 710     LLVMGCC=$with_llvmgcc
 711       WITH_LLVMGCCDIR="",)
 712
 713 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 714 AC_ARG_WITH(llvmgxx,
 715   AS_HELP_STRING([--with-llvmgxx],
 716     [Specify location of llvm-g++ driver (default searches PATH)]),
 717     LLVMGXX=$with_llvmgxx
 718     WITH_LLVMGCCDIR="",)
 719
 720 if test -n "$LLVMGCC"; then
 721    LLVMGCCCOMMAND="$LLVMGCC"
 722 fi
 723
 724 if test -n "$LLVMGXX"; then
 725    LLVMGXXCOMMAND="$LLVMGXX"
 726 fi
 727
 728 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 729    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 730 fi
 731
 732 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 733    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 734 fi
 735
 736 dnl Allow a specific Clang compiler to be used with this LLVM config.
 737 AC_ARG_WITH(clang,
 738   AS_HELP_STRING([--with-clang],
 739     [Specify location of clang compiler (default is --with-built-clang)]),
 740     [],[with_clang=default])
 741
 742 dnl Enable use of the built Clang.
 743 AC_ARG_WITH(built-clang,
 744   AS_HELP_STRING([--with-built-clang],
 745     [Use the compiled Clang as the LLVM compiler (default=check)]),
 746     [],[with_built_clang=check])
 747
 748 dnl Select the Clang compiler option.
 749 dnl
 750 dnl If --with-clang is given, always honor that; otherwise honor
 751 dnl --with-built-clang, or check if we have the clang sources.
 752 AC_MSG_CHECKING([clang compiler])
 753 WITH_CLANGPATH=""
 754 WITH_BUILT_CLANG=0
 755 if test "$with_clang" != "default"; then
 756    WITH_CLANGPATH="$with_clang"
 757    if ! test -x "$WITH_CLANGPATH"; then
 758      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 759    fi
 760 elif test "$with_built_clang" = "yes"; then
 761    WITH_BUILT_CLANG=1
 762 elif test "$with_built_clang" = "no"; then
 763    WITH_BUILT_CLANG=0
 764 else
 765    if test "$with_built_clang" != "check"; then
 766       AC_MSG_ERROR([invalid value for --with-built-clang.])
 767    fi
 768
 769    if test -f ${srcdir}/tools/clang/README.txt; then
 770      WITH_BUILT_CLANG=1
 771    fi
 772 fi
 773
 774 if ! test -z "$WITH_CLANGPATH"; then
 775    AC_MSG_RESULT([$WITH_CLANGPATH])
 776    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 777 elif test "$WITH_BUILT_CLANG" = "1"; then
 778    AC_MSG_RESULT([built])
 779 else
 780    AC_MSG_RESULT([none])
 781 fi
 782 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 783 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 784 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 785
 786 dnl Override the option to use for optimized builds.
 787 AC_ARG_WITH(optimize-option,
 788   AS_HELP_STRING([--with-optimize-option],
 789                  [Select the compiler options to use for optimized builds]),,
 790                  withval=default)
 791 AC_MSG_CHECKING([optimization flags])
 792 case "$withval" in
 793   default)
 794     case "$llvm_cv_os_type" in
 795     FreeBSD) optimize_option=-O2 ;;
 796     MingW) optimize_option=-O2 ;;
 797     *)     optimize_option=-O3 ;;
 798     esac ;;
 799   *) optimize_option="$withval" ;;
 800 esac
 801 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 802 AC_MSG_RESULT([$optimize_option])
 803
 804 dnl Specify extra build options
 805 AC_ARG_WITH(extra-options,
 806   AS_HELP_STRING([--with-extra-options],
 807                  [Specify additional options to compile LLVM with]),,
 808                  withval=default)
 809 case "$withval" in
 810   default) EXTRA_OPTIONS= ;;
 811   *) EXTRA_OPTIONS=$withval ;;
 812 esac
 813 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 814
 815 dnl Allow specific bindings to be specified for building (or not)
 816 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 817     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 818     enableval=default)
 819 BINDINGS_TO_BUILD=""
 820 case "$enableval" in
 821   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 822   all ) BINDINGS_TO_BUILD="ocaml" ;;
 823   none | no) BINDINGS_TO_BUILD="" ;;
 824   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 825       case "$a_binding" in
 826         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 827         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 828       esac
 829   done
 830   ;;
 831 esac
 832
 833 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 834 dnl script for bindings/ocaml/configure, except that its auto value depends on
 835 dnl OCAMLC, which is found here to support tests.
 836 AC_ARG_WITH([ocaml-libdir],
 837   [AS_HELP_STRING([--with-ocaml-libdir],
 838     [Specify install location for ocaml bindings (default is stdlib)])],
 839   [],
 840   [withval=auto])
 841 case "$withval" in
 842   auto) with_ocaml_libdir="$withval" ;;
 843   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 844   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 845 esac
 846
 847 AC_ARG_WITH(clang-resource-dir,
 848   AS_HELP_STRING([--with-clang-resource-dir],
 849     [Relative directory from the Clang binary for resource files]),,
 850     withval="")
 851 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 852                    [Relative directory for resource files])
 853
 854 AC_ARG_WITH(c-include-dirs,
 855   AS_HELP_STRING([--with-c-include-dirs],
 856     [Colon separated list of directories clang will search for headers]),,
 857     withval="")
 858 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 859                    [Directories clang will search for headers])
 860
 861 AC_ARG_WITH(cxx-include-root,
 862   AS_HELP_STRING([--with-cxx-include-root],
 863     [Directory with the libstdc++ headers.]),,
 864     withval="")
 865 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 866                    [Directory with the libstdc++ headers.])
 867
 868 AC_ARG_WITH(cxx-include-arch,
 869   AS_HELP_STRING([--with-cxx-include-arch],
 870     [Architecture of the libstdc++ headers.]),,
 871     withval="")
 872 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 873                    [Arch the libstdc++ headers.])
 874
 875 AC_ARG_WITH(cxx-include-32bit-dir,
 876   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 877     [32 bit multilib dir.]),,
 878     withval="")
 879 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 880                    [32 bit multilib directory.])
 881
 882 AC_ARG_WITH(cxx-include-64bit-dir,
 883   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 884     [64 bit multilib directory.]),,
 885     withval="")
 886 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 887                    [64 bit multilib directory.])
 888
 889 dnl Allow linking of LLVM with GPLv3 binutils code.
 890 AC_ARG_WITH(binutils-include,
 891   AS_HELP_STRING([--with-binutils-include],
 892     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 893   withval=default)
 894 case "$withval" in
 895   default) WITH_BINUTILS_INCDIR=default ;;
 896   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 897   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 898 esac
 899 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 900   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 901   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 902      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 903      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 904   fi
 905 fi
 906
 907 dnl --enable-libffi : check whether the user wants to turn off libffi:
 908 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 909   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 910   [case "$enableval" in
 911     yes) llvm_cv_enable_libffi="yes" ;;
 912     no)  llvm_cv_enable_libffi="no"  ;;
 913     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 914   esac],
 915   llvm_cv_enable_libffi=no)
 916
 917 dnl===-----------------------------------------------------------------------===
 918 dnl===
 919 dnl=== SECTION 4: Check for programs we need and that they are the right version
 920 dnl===
 921 dnl===-----------------------------------------------------------------------===
 922
 923 dnl Check for compilation tools
 924 AC_PROG_CPP
 925 AC_PROG_CC(gcc)
 926 AC_PROG_CXX(g++)
 927
 928 AC_PROG_NM
 929 AC_SUBST(NM)
 930
 931 dnl Check for the tools that the makefiles require
 932 AC_CHECK_GNU_MAKE
 933 AC_PROG_LN_S
 934 AC_PATH_PROG(CMP, [cmp], [cmp])
 935 AC_PATH_PROG(CP, [cp], [cp])
 936 AC_PATH_PROG(DATE, [date], [date])
 937 AC_PATH_PROG(FIND, [find], [find])
 938 AC_PATH_PROG(GREP, [grep], [grep])
 939 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 940 AC_PATH_PROG(MV,   [mv],   [mv])
 941 AC_PROG_RANLIB
 942 AC_CHECK_TOOL(AR, ar, false)
 943 AC_PATH_PROG(RM,   [rm],   [rm])
 944 AC_PATH_PROG(SED,  [sed],  [sed])
 945 AC_PATH_PROG(TAR,  [tar],  [gtar])
 946 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 947
 948 dnl Looking for misc. graph plotting software
 949 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 950 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 951   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 952   dnl If we're targeting for mingw we should emit windows paths, not msys
 953   if test "$llvm_cv_os_type" = "MingW" ; then
 954     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 955   fi
 956   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 957    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 958 fi
 959 AC_PATH_PROG(DOT, [dot], [echo dot])
 960 if test "$DOT" != "echo dot" ; then
 961   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 962   dnl If we're targeting for mingw we should emit windows paths, not msys
 963   if test "$llvm_cv_os_type" = "MingW" ; then
 964     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 965   fi
 966   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 967    [Define to path to dot program if found or 'echo dot' otherwise])
 968 fi
 969 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 970 if test "$FDP" != "echo fdp" ; then
 971   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 972   dnl If we're targeting for mingw we should emit windows paths, not msys
 973   if test "$llvm_cv_os_type" = "MingW" ; then
 974     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 975   fi
 976   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 977    [Define to path to fdp program if found or 'echo fdp' otherwise])
 978 fi
 979 AC_PATH_PROG(NEATO, [neato], [echo neato])
 980 if test "$NEATO" != "echo neato" ; then
 981   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 982   dnl If we're targeting for mingw we should emit windows paths, not msys
 983   if test "$llvm_cv_os_type" = "MingW" ; then
 984     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 985   fi
 986   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 987    [Define to path to neato program if found or 'echo neato' otherwise])
 988 fi
 989 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 990 if test "$TWOPI" != "echo twopi" ; then
 991   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 992   dnl If we're targeting for mingw we should emit windows paths, not msys
 993   if test "$llvm_cv_os_type" = "MingW" ; then
 994     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 995   fi
 996   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 997    [Define to path to twopi program if found or 'echo twopi' otherwise])
 998 fi
 999 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1000 if test "$CIRCO" != "echo circo" ; then
1001   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1002   dnl If we're targeting for mingw we should emit windows paths, not msys
1003   if test "$llvm_cv_os_type" = "MingW" ; then
1004     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1005   fi
1006   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1007    [Define to path to circo program if found or 'echo circo' otherwise])
1008 fi
1009 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1010 if test "$GV" != "echo gv" ; then
1011   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1012   dnl If we're targeting for mingw we should emit windows paths, not msys
1013   if test "$llvm_cv_os_type" = "MingW" ; then
1014     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1015   fi
1016   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1017    [Define to path to gv program if found or 'echo gv' otherwise])
1018 fi
1019 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1020 if test "$DOTTY" != "echo dotty" ; then
1021   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1022   dnl If we're targeting for mingw we should emit windows paths, not msys
1023   if test "$llvm_cv_os_type" = "MingW" ; then
1024     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1025   fi
1026   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1027    [Define to path to dotty program if found or 'echo dotty' otherwise])
1028 fi
1029 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1030 if test "$XDOT_PY" != "echo xdot.py" ; then
1031   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1032   dnl If we're targeting for mingw we should emit windows paths, not msys
1033   if test "$llvm_cv_os_type" = "MingW" ; then
1034     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1035   fi
1036   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1037    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1038 fi
1039
1040 dnl Look for a sufficiently recent version of Perl.
1041 LLVM_PROG_PERL([5.006])
1042 AC_SUBST(PERL)
1043 if test x"$PERL" = xnone; then
1044    AC_SUBST(HAVE_PERL,0)
1045    AC_MSG_ERROR([perl is required but was not found, please install it])
1046 else
1047    AC_SUBST(HAVE_PERL,1)
1048 fi
1049
1050 dnl Find the install program
1051 AC_PROG_INSTALL
1052 dnl Prepend src dir to install path dir if it's a relative path
1053 dnl This is a hack for installs that take place in something other
1054 dnl than the top level.
1055 case "$INSTALL" in
1056  [[\\/$]]* | ?:[[\\/]]* ) ;;
1057  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1058 esac
1059
1060 dnl Checks for documentation and testing tools that we can do without. If these
1061 dnl are not found then they are set to "true" which always succeeds but does
1062 dnl nothing. This just lets the build output show that we could have done
1063 dnl something if the tool was available.
1064 AC_PATH_PROG(BZIP2, [bzip2])
1065 AC_PATH_PROG(CAT, [cat])
1066 AC_PATH_PROG(DOXYGEN, [doxygen])
1067 AC_PATH_PROG(GROFF, [groff])
1068 AC_PATH_PROG(GZIPBIN, [gzip])
1069 AC_PATH_PROG(POD2HTML, [pod2html])
1070 AC_PATH_PROG(POD2MAN, [pod2man])
1071 AC_PATH_PROG(PDFROFF, [pdfroff])
1072 AC_PATH_PROG(RUNTEST, [runtest])
1073 DJ_AC_PATH_TCLSH
1074 AC_PATH_PROG(ZIP, [zip])
1075 AC_PATH_PROGS(OCAMLC, [ocamlc])
1076 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1077 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1078 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1079 AC_PATH_PROGS(GAS, [gas as])
1080
1081 dnl Get the version of the linker in use.
1082 AC_LINK_GET_VERSION
1083
1084 dnl Determine whether the linker supports the -R option.
1085 AC_LINK_USE_R
1086
1087 dnl Determine whether the linker supports the -export-dynamic option.
1088 AC_LINK_EXPORT_DYNAMIC
1089
1090 dnl Determine whether the linker supports the --version-script option.
1091 AC_LINK_VERSION_SCRIPT
1092
1093 dnl Check for libtool and the library that has dlopen function (which must come
1094 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1095 dnl libtool).
1096 AC_LIBTOOL_DLOPEN
1097 AC_LIB_LTDL
1098
1099 if test "$WITH_LLVMGCCDIR" = "default" ; then
1100   LLVMGCC="llvm-gcc${EXEEXT}"
1101   LLVMGXX="llvm-g++${EXEEXT}"
1102   LLVMGCCCOMMAND="$LLVMGCC"
1103   LLVMGXXCOMMAND="$LLVMGXX"
1104   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1105   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1106   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
1107   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
1108 else
1109   if test -z "$LLVMGCC"; then
1110     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
1111     LLVMGCCCOMMAND="$LLVMGCC"
1112   fi
1113   if test -z "$LLVMGXX"; then
1114     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1115     LLVMGXXCOMMAND="$LLVMGXX"
1116   fi
1117
1118   AC_SUBST(LLVMGCC,$LLVMGCC)
1119   AC_SUBST(LLVMGXX,$LLVMGXX)
1120   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1121   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1122 fi
1123
1124 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1125 dnl found, otherwise clang if available.
1126 AC_ARG_WITH(llvmcc,
1127   AS_HELP_STRING([--with-llvmcc=<name>],
1128     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1129     [],[with_llvmcc=check])
1130 AC_MSG_CHECKING([LLVM capable compiler])
1131 if test "$with_llvmcc" != "check"; then
1132    if (test "$with_llvmcc" != "llvm-gcc" &&
1133        test "$with_llvmcc" != "clang" &&
1134        test "$with_llvmcc" != "none"); then
1135       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1136    fi
1137    WITH_LLVMCC="$with_llvmcc"
1138 elif test -n "$LLVMGCC"; then
1139    WITH_LLVMCC=llvm-gcc
1140 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1141    WITH_LLVMCC=clang
1142 else
1143    WITH_LLVMCC=none
1144 fi
1145 AC_MSG_RESULT([$WITH_LLVMCC])
1146 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1147
1148 AC_MSG_CHECKING([tool compatibility])
1149
1150 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1151 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1152 dnl to support those options.
1153 dnl "icc" emits gcc signatures
1154 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1155 ICC=no
1156 IXX=no
1157 case $CC in
1158   icc*|icpc*)
1159     ICC=yes
1160     IXX=yes
1161     ;;
1162    *)
1163     ;;
1164 esac
1165
1166 if test "$GCC" != "yes" && test "$ICC" != "yes"
1167 then
1168   AC_MSG_ERROR([gcc|icc required but not found])
1169 fi
1170
1171 dnl Ensure that compilation tools are compatible with GCC extensions
1172 if test "$GXX" != "yes" && test "$IXX" != "yes"
1173 then
1174   AC_MSG_ERROR([g++|clang++|icc required but not found])
1175 fi
1176
1177 dnl Verify that GCC is version 3.0 or higher
1178 if test "$GCC" = "yes"
1179 then
1180   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1181 #error Unsupported GCC version
1182 #endif
1183 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1184 fi
1185
1186 dnl Check for GNU Make.  We use its extensions, so don't build without it
1187 if test -z "$llvm_cv_gnu_make_command"
1188 then
1189   AC_MSG_ERROR([GNU Make required but not found])
1190 fi
1191
1192 dnl Tool compatibility is okay if we make it here.
1193 AC_MSG_RESULT([ok])
1194
1195 dnl Check optional compiler flags.
1196 AC_MSG_CHECKING([optional compiler flags])
1197 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1198 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1199 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1200
1201 dnl===-----------------------------------------------------------------------===
1202 dnl===
1203 dnl=== SECTION 5: Check for libraries
1204 dnl===
1205 dnl===-----------------------------------------------------------------------===
1206
1207 AC_CHECK_LIB(m,sin)
1208 if test "$llvm_cv_os_type" = "MingW" ; then
1209   AC_CHECK_LIB(imagehlp, main)
1210   AC_CHECK_LIB(psapi, main)
1211 fi
1212
1213 dnl dlopen() is required for plugin support.
1214 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1215                [Define if dlopen() is available on this platform.]),
1216                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1217
1218 dnl libffi is optional; used to call external functions from the interpreter
1219 if test "$llvm_cv_enable_libffi" = "yes" ; then
1220   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1221                  [Define if libffi is available on this platform.]),
1222                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1223 fi
1224
1225 dnl mallinfo is optional; the code can compile (minus features) without it
1226 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1227                [Define if mallinfo() is available on this platform.]))
1228
1229 dnl pthread locking functions are optional - but llvm will not be thread-safe
1230 dnl without locks.
1231 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1232   AC_CHECK_LIB(pthread, pthread_mutex_init)
1233   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1234                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1235                            [Have pthread_mutex_lock]))
1236   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1237                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1238                  [Have pthread_rwlock_init]))
1239   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1240                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1241                  [Have pthread_getspecific]))
1242 fi
1243
1244 dnl Allow extra x86-disassembler library
1245 AC_ARG_WITH(udis86,
1246   AS_HELP_STRING([--with-udis86=<path>],
1247     [Use udis86 external x86 disassembler library]),
1248     [
1249       AC_SUBST(USE_UDIS86, [1])
1250       case "$withval" in
1251         /usr/lib|yes) ;;
1252         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1253       esac
1254       AC_CHECK_LIB(udis86, ud_init, [], [
1255         echo "Error! You need to have libudis86 around."
1256         exit -1
1257       ])
1258     ],
1259     AC_SUBST(USE_UDIS86, [0]))
1260 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1261                    [Define if use udis86 library])
1262
1263 dnl Allow OProfile support for JIT output.
1264 AC_ARG_WITH(oprofile,
1265   AS_HELP_STRING([--with-oprofile=<prefix>],
1266     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1267     [
1268       AC_SUBST(USE_OPROFILE, [1])
1269       case "$withval" in
1270         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1271         no) llvm_cv_oppath=
1272             AC_SUBST(USE_OPROFILE, [0]) ;;
1273         *) llvm_cv_oppath="${withval}/lib/oprofile"
1274            CPPFLAGS="-I${withval}/include";;
1275       esac
1276       if test -n "$llvm_cv_oppath" ; then
1277         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1278         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1279         dnl libbfd is not included properly in libopagent in some Debian
1280         dnl versions.  If libbfd isn't found at all, we assume opagent works
1281         dnl anyway.
1282         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1283         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1284           echo "Error! You need to have libopagent around."
1285           exit -1
1286         ])
1287         AC_CHECK_HEADER([opagent.h], [], [
1288           echo "Error! You need to have opagent.h around."
1289           exit -1
1290           ])
1291       fi
1292     ],
1293     [
1294       AC_SUBST(USE_OPROFILE, [0])
1295     ])
1296 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1297                    [Define if we have the oprofile JIT-support library])
1298
1299 dnl===-----------------------------------------------------------------------===
1300 dnl===
1301 dnl=== SECTION 6: Check for header files
1302 dnl===
1303 dnl===-----------------------------------------------------------------------===
1304
1305 dnl First, use autoconf provided macros for specific headers that we need
1306 dnl We don't check for ancient stuff or things that are guaranteed to be there
1307 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1308 dnl Generally we're looking for POSIX headers.
1309 AC_HEADER_DIRENT
1310 AC_HEADER_MMAP_ANONYMOUS
1311 AC_HEADER_STAT
1312 AC_HEADER_STDC
1313 AC_HEADER_SYS_WAIT
1314 AC_HEADER_TIME
1315
1316 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1317 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1318 AC_CHECK_HEADERS([utime.h windows.h])
1319 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1320 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1321 AC_CHECK_HEADERS([valgrind/valgrind.h])
1322 AC_CHECK_HEADERS([fenv.h])
1323 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1324   AC_CHECK_HEADERS(pthread.h,
1325                    AC_SUBST(HAVE_PTHREAD, 1),
1326                    AC_SUBST(HAVE_PTHREAD, 0))
1327 else
1328   AC_SUBST(HAVE_PTHREAD, 0)
1329 fi
1330
1331 dnl Try to find ffi.h.
1332 if test "$llvm_cv_enable_libffi" = "yes" ; then
1333   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1334 fi
1335
1336 dnl Try to find Darwin specific crash reporting libraries.
1337 AC_CHECK_HEADERS([CrashReporterClient.h])
1338
1339 dnl Try to find Darwin specific crash reporting global.
1340 AC_MSG_CHECKING([__crashreporter_info__])
1341 AC_LINK_IFELSE(
1342   AC_LANG_SOURCE(
1343     [[extern const char *__crashreporter_info__;
1344       int main() {
1345         __crashreporter_info__ = "test";
1346         return 0;
1347       }
1348     ]]),
1349   AC_MSG_RESULT(yes)
1350   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1351   AC_MSG_RESULT(no)
1352   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1353             Define if __crashreporter_info__ exists.))
1354
1355 dnl===-----------------------------------------------------------------------===
1356 dnl===
1357 dnl=== SECTION 7: Check for types and structures
1358 dnl===
1359 dnl===-----------------------------------------------------------------------===
1360
1361 AC_HUGE_VAL_CHECK
1362 AC_TYPE_PID_T
1363 AC_TYPE_SIZE_T
1364 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1365 AC_STRUCT_TM
1366 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1367 AC_CHECK_TYPES([uint64_t],,
1368          AC_CHECK_TYPES([u_int64_t],,
1369          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1370
1371 dnl===-----------------------------------------------------------------------===
1372 dnl===
1373 dnl=== SECTION 8: Check for specific functions needed
1374 dnl===
1375 dnl===-----------------------------------------------------------------------===
1376
1377 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1378 AC_CHECK_FUNCS([powf fmodf strtof round ])
1379 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1380 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1381 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1382 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1383 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1384 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1385 AC_C_PRINTF_A
1386 AC_FUNC_RAND48
1387
1388 dnl Check for variations in the Standard C++ library and STL. These macros are
1389 dnl provided by LLVM in the autoconf/m4 directory.
1390 AC_FUNC_ISNAN
1391 AC_FUNC_ISINF
1392
1393 dnl Check for mmap support.We also need to know if /dev/zero is required to
1394 dnl be opened for allocating RWX memory.
1395 dnl Make sure we aren't attempting to configure for an unknown system
1396 if test "$llvm_cv_platform_type" = "Unix" ; then
1397   AC_FUNC_MMAP
1398   AC_FUNC_MMAP_FILE
1399   AC_NEED_DEV_ZERO_FOR_MMAP
1400
1401   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1402   then
1403     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1404   fi
1405   if test "$ac_cv_func_mmap_file" = "no"
1406   then
1407     AC_MSG_WARN([mmap() of files required but not found])
1408   fi
1409 fi
1410
1411 dnl atomic builtins are required for threading support.
1412 AC_MSG_CHECKING(for GCC atomic builtins)
1413 dnl Since we'll be using these atomic builtins in C++ files we should test
1414 dnl the C++ compiler.
1415 AC_LANG_PUSH([C++])
1416 AC_LINK_IFELSE(
1417   AC_LANG_SOURCE(
1418     [[int main() {
1419         volatile unsigned long val = 1;
1420         __sync_synchronize();
1421         __sync_val_compare_and_swap(&val, 1, 0);
1422         __sync_add_and_fetch(&val, 1);
1423         __sync_sub_and_fetch(&val, 1);
1424         return 0;
1425       }
1426     ]]),
1427   AC_LANG_POP([C++])
1428   AC_MSG_RESULT(yes)
1429   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1430   AC_MSG_RESULT(no)
1431   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1432   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1433
1434 dnl===-----------------------------------------------------------------------===
1435 dnl===
1436 dnl=== SECTION 9: Additional checks, variables, etc.
1437 dnl===
1438 dnl===-----------------------------------------------------------------------===
1439
1440 dnl Handle 32-bit linux systems running a 64-bit kernel.
1441 dnl This has to come after section 4 because it invokes the compiler.
1442 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1443   AC_IS_LINUX_MIXED
1444   if test "$llvm_cv_linux_mixed" = "yes"; then
1445     llvm_cv_target_arch="x86"
1446     ARCH="x86"
1447   fi
1448 fi
1449
1450 dnl Check, whether __dso_handle is present
1451 AC_CHECK_FUNCS([__dso_handle])
1452
1453 dnl Check wether llvm-gcc is based on dragonegg
1454 AC_CACHE_CHECK([whether llvm-gcc is dragonegg],[llvm_cv_llvmgcc_dragonegg],
1455 [llvm_cv_llvmgcc_dragonegg="no"
1456 if test -n "$LLVMGCC" ; then
1457   cp /dev/null conftest.c
1458   $LLVMGCC -fplugin-arg-dragonegg-emit-ir -S -o - conftest.c > /dev/null 2>&1
1459   if test $? -eq 0 ; then
1460     llvm_cv_llvmgcc_dragonegg="yes"
1461   fi
1462   rm conftest.c
1463 fi])
1464
1465 dnl Set the flags needed to emit LLVM IR and to disable optimizations
1466 dnl in llvmgcc
1467 if test "$llvm_cv_llvmgcc_dragonegg" = "yes" ; then
1468   LLVMCC_EMITIR_FLAG="-fplugin-arg-dragonegg-emit-ir"
1469   LLVMCC_DISABLEOPT_FLAGS="-fplugin-arg-dragonegg-disable-llvm-optzns"
1470 else
1471   LLVMCC_EMITIR_FLAG="-emit-llvm"
1472   LLVMCC_DISABLEOPT_FLAGS="-mllvm -disable-llvm-optzns"
1473 fi
1474
1475 AC_SUBST(LLVMCC_EMITIR_FLAG)
1476
1477 dnl See if the llvm-gcc executable can compile to LLVM assembly
1478 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1479 [llvm_cv_llvmgcc_sanity="no"
1480 if test -n "$LLVMGCC" ; then
1481   cp /dev/null conftest.c
1482   $LLVMGCC "$LLVMCC_EMITIR_FLAG" -S -o - conftest.c | \
1483       grep 'target datalayout =' > /dev/null 2>&1
1484   if test $? -eq 0 ; then
1485     llvm_cv_llvmgcc_sanity="yes"
1486   fi
1487   rm conftest.c
1488 fi])
1489
1490 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1491 dnl Furthermore, add some information about the tools
1492 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1493   AC_MSG_CHECKING([llvm-gcc component support])
1494   llvmcc1path=`$LLVMGCC --print-prog-name=cc1`
1495   AC_SUBST(LLVMCC1,$llvmcc1path)
1496   llvmcc1pluspath=`$LLVMGCC --print-prog-name=cc1plus`
1497   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1498   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1499   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1500   llvmgcclangs=[`$LLVMGCC -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1501   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1502   AC_SUBST(LLVMGCC_DRAGONEGG,$llvm_cv_llvmgcc_dragonegg)
1503   AC_SUBST(LLVMCC_DISABLEOPT_FLAGS)
1504   AC_MSG_RESULT([ok])
1505 fi
1506
1507 dnl Propagate the shared library extension that the libltdl checks did to
1508 dnl the Makefiles so we can use it there too
1509 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1510
1511 dnl Propagate the run-time library path variable that the libltdl
1512 dnl checks found to the Makefiles so we can use it there too
1513 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1514
1515 # Translate the various configuration directories and other basic
1516 # information into substitutions that will end up in Makefile.config.in
1517 # that these configured values can be used by the makefiles
1518 if test "${prefix}" = "NONE" ; then
1519   prefix="/usr/local"
1520 fi
1521 eval LLVM_PREFIX="${prefix}";
1522 eval LLVM_BINDIR="${prefix}/bin";
1523 eval LLVM_LIBDIR="${prefix}/lib";
1524 eval LLVM_DATADIR="${prefix}/share/llvm";
1525 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1526 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1527 eval LLVM_INCLUDEDIR="${prefix}/include";
1528 eval LLVM_INFODIR="${prefix}/info";
1529 eval LLVM_MANDIR="${prefix}/man";
1530 LLVM_CONFIGTIME=`date`
1531 AC_SUBST(LLVM_PREFIX)
1532 AC_SUBST(LLVM_BINDIR)
1533 AC_SUBST(LLVM_LIBDIR)
1534 AC_SUBST(LLVM_DATADIR)
1535 AC_SUBST(LLVM_DOCSDIR)
1536 AC_SUBST(LLVM_ETCDIR)
1537 AC_SUBST(LLVM_INCLUDEDIR)
1538 AC_SUBST(LLVM_INFODIR)
1539 AC_SUBST(LLVM_MANDIR)
1540 AC_SUBST(LLVM_CONFIGTIME)
1541
1542 # Place the various directores into the config.h file as #defines so that we
1543 # can know about the installation paths within LLVM.
1544 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1545                    [Installation prefix directory])
1546 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1547                    [Installation directory for binary executables])
1548 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1549                    [Installation directory for libraries])
1550 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1551                    [Installation directory for data files])
1552 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1553                    [Installation directory for documentation])
1554 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1555                    [Installation directory for config files])
1556 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1557                    [Installation directory for include files])
1558 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1559                    [Installation directory for .info files])
1560 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1561                    [Installation directory for man pages])
1562 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1563                    [Time at which LLVM was configured])
1564 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1565                    [Host triple we were built on])
1566
1567 # Determine which bindings to build.
1568 if test "$BINDINGS_TO_BUILD" = auto ; then
1569   BINDINGS_TO_BUILD=""
1570   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1571     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1572   fi
1573 fi
1574 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1575
1576 # This isn't really configurey, but it avoids having to repeat the list in
1577 # other files.
1578 AC_SUBST(ALL_BINDINGS,ocaml)
1579
1580 # Do any work necessary to ensure that bindings have what they need.
1581 binding_prereqs_failed=0
1582 for a_binding in $BINDINGS_TO_BUILD ; do
1583   case "$a_binding" in
1584   ocaml)
1585     if test "x$OCAMLC" = x ; then
1586       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1587       binding_prereqs_failed=1
1588     fi
1589     if test "x$OCAMLDEP" = x ; then
1590       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1591       binding_prereqs_failed=1
1592     fi
1593     if test "x$OCAMLOPT" = x ; then
1594       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1595       dnl ocamlopt is optional!
1596     fi
1597     if test "x$with_ocaml_libdir" != xauto ; then
1598       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1599     else
1600       ocaml_stdlib="`"$OCAMLC" -where`"
1601       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1602       then
1603         # ocaml stdlib is beneath our prefix; use stdlib
1604         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1605       else
1606         # ocaml stdlib is outside our prefix; use libdir/ocaml
1607         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1608       fi
1609     fi
1610     ;;
1611   esac
1612 done
1613 if test "$binding_prereqs_failed" = 1 ; then
1614   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1615 fi
1616
1617 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1618 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1619
1620 dnl Determine linker rpath flag
1621 if test "$llvm_cv_link_use_r" = "yes" ; then
1622   RPATH="-Wl,-R"
1623 else
1624   RPATH="-Wl,-rpath"
1625 fi
1626 AC_SUBST(RPATH)
1627
1628 dnl Determine linker rdynamic flag
1629 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1630   RDYNAMIC="-Wl,-export-dynamic"
1631 else
1632   RDYNAMIC=""
1633 fi
1634 AC_SUBST(RDYNAMIC)
1635
1636 dnl===-----------------------------------------------------------------------===
1637 dnl===
1638 dnl=== SECTION 10: Specify the output files and generate it
1639 dnl===
1640 dnl===-----------------------------------------------------------------------===
1641
1642 dnl Configure header files
1643 dnl WARNING: dnl If you add or remove any of the following config headers, then
1644 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1645 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1646 dnl files can be updated automatically when their *.in sources change.
1647 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1648 AH_TOP([#ifndef CONFIG_H
1649 #define CONFIG_H])
1650 AH_BOTTOM([#endif])
1651
1652 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1653 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1654 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1655 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1656 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1657
1658 dnl Configure the makefile's configuration data
1659 AC_CONFIG_FILES([Makefile.config])
1660
1661 dnl Configure the RPM spec file for LLVM
1662 AC_CONFIG_FILES([llvm.spec])
1663
1664 dnl Configure llvmc's Base plugin
1665 AC_CONFIG_FILES([tools/llvmc/src/Base.td])
1666
1667 dnl Do the first stage of configuration for llvm-config.in.
1668 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1669
1670 dnl Do special configuration of Makefiles
1671 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1672 AC_CONFIG_MAKEFILE(Makefile)
1673 AC_CONFIG_MAKEFILE(Makefile.common)
1674 AC_CONFIG_MAKEFILE(examples/Makefile)
1675 AC_CONFIG_MAKEFILE(lib/Makefile)
1676 AC_CONFIG_MAKEFILE(runtime/Makefile)
1677 AC_CONFIG_MAKEFILE(test/Makefile)
1678 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1679 AC_CONFIG_MAKEFILE(unittests/Makefile)
1680 AC_CONFIG_MAKEFILE(tools/Makefile)
1681 AC_CONFIG_MAKEFILE(utils/Makefile)
1682 AC_CONFIG_MAKEFILE(projects/Makefile)
1683 AC_CONFIG_MAKEFILE(bindings/Makefile)
1684 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1685
1686 dnl Finally, crank out the output
1687 AC_OUTPUT