autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.3svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [3], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2013 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2013 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl We need to check for the compiler up here to avoid anything else
  63 dnl starting with a different one.
  64 AC_PROG_CC(clang llvm-gcc gcc)
  65 AC_PROG_CXX(clang++ llvm-g++ g++)
  66 AC_PROG_CPP
  67
  68 dnl If CXX is Clang, check that it can find and parse C++ standard library
  69 dnl headers.
  70 if test "$CXX" = "clang++" ; then
  71   AC_MSG_CHECKING([whether clang works])
  72   AC_LANG_PUSH([C++])
  73   dnl Note that space between 'include' and '(' is required.  There's a broken
  74   dnl regex in aclocal that otherwise will think that we call m4's include
  75   dnl builtin.
  76   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  77 #if __has_include (<cxxabi.h>)
  78 #include <cxxabi.h>
  79 #endif
  80 #if __has_include (<unwind.h>)
  81 #include <unwind.h>
  82 #endif
  83 ]])],
  84 [
  85   AC_MSG_RESULT([yes])
  86 ],
  87 [
  88   AC_MSG_RESULT([no])
  89   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
  90 ])
  91   AC_LANG_POP([C++])
  92 fi
  93
  94 dnl Configure all of the projects present in our source tree. While we could
  95 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  96 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  97 dnl Instead we match on the known projects.
  98
  99 dnl
 100 dnl One tricky part of doing this is that some projects depend upon other
 101 dnl projects.  For example, several projects rely upon the LLVM test suite.
 102 dnl We want to configure those projects first so that their object trees are
 103 dnl created before running the configure scripts of projects that depend upon
 104 dnl them.
 105 dnl
 106
 107 dnl Several projects use llvm-gcc, so configure that first
 108 if test -d ${srcdir}/projects/llvm-gcc ; then
 109   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
 110 fi
 111
 112 dnl Several projects use the LLVM test suite, so configure it next.
 113 if test -d ${srcdir}/projects/test-suite ; then
 114   AC_CONFIG_SUBDIRS([projects/test-suite])
 115 fi
 116
 117 dnl llvm-test is the old name of the test-suite, kept here for backwards
 118 dnl compatibility
 119 if test -d ${srcdir}/projects/llvm-test ; then
 120   AC_CONFIG_SUBDIRS([projects/llvm-test])
 121 fi
 122
 123 dnl Some projects use poolalloc; configure that next
 124 if test -d ${srcdir}/projects/poolalloc ; then
 125   AC_CONFIG_SUBDIRS([projects/poolalloc])
 126 fi
 127
 128 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 129   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 130 fi
 131
 132 dnl Check for all other projects
 133 for i in `ls ${srcdir}/projects`
 134 do
 135   if test -d ${srcdir}/projects/${i} ; then
 136     case ${i} in
 137       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 138       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 139       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 140       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 141       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 142       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 143       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 144       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 145       compiler-rt)       ;;
 146       llvm-gcc)       ;;
 147       test-suite)     ;;
 148       llvm-test)      ;;
 149       poolalloc)      ;;
 150       llvm-poolalloc) ;;
 151       *)
 152         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 153         ;;
 154     esac
 155   fi
 156 done
 157
 158 dnl Disable the build of polly, even if it is checked out into tools/polly.
 159 AC_ARG_ENABLE(polly,
 160               AS_HELP_STRING([--enable-polly],
 161                              [Use polly if available (default is YES)]),,
 162                              enableval=default)
 163 case "$enableval" in
 164   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 165   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 166   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 167   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 168 esac
 169
 170
 171 dnl Check if polly is checked out into tools/polly and configure it if
 172 dnl available.
 173 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 174   AC_SUBST(LLVM_HAS_POLLY,1)
 175   AC_CONFIG_SUBDIRS([tools/polly])
 176 fi
 177
 178 dnl===-----------------------------------------------------------------------===
 179 dnl===
 180 dnl=== SECTION 2: Architecture, target, and host checks
 181 dnl===
 182 dnl===-----------------------------------------------------------------------===
 183
 184 dnl Check the target for which we're compiling and the host that will do the
 185 dnl compilations. This will tell us which LLVM compiler will be used for
 186 dnl compiling SSA into object code. This needs to be done early because
 187 dnl following tests depend on it.
 188 AC_CANONICAL_TARGET
 189
 190 dnl Determine the platform type and cache its value. This helps us configure
 191 dnl the System library to the correct build platform.
 192 AC_CACHE_CHECK([type of operating system we're going to host on],
 193                [llvm_cv_os_type],
 194 [case $host in
 195   *-*-aix*)
 196     llvm_cv_link_all_option="-Wl,--whole-archive"
 197     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 198     llvm_cv_os_type="AIX"
 199     llvm_cv_platform_type="Unix" ;;
 200   *-*-irix*)
 201     llvm_cv_link_all_option="-Wl,--whole-archive"
 202     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 203     llvm_cv_os_type="IRIX"
 204     llvm_cv_platform_type="Unix" ;;
 205   *-*-cygwin*)
 206     llvm_cv_link_all_option="-Wl,--whole-archive"
 207     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 208     llvm_cv_os_type="Cygwin"
 209     llvm_cv_platform_type="Unix" ;;
 210   *-*-darwin*)
 211     llvm_cv_link_all_option="-Wl,-all_load"
 212     llvm_cv_no_link_all_option="-Wl,-noall_load"
 213     llvm_cv_os_type="Darwin"
 214     llvm_cv_platform_type="Unix" ;;
 215   *-*-minix*)
 216     llvm_cv_link_all_option="-Wl,-all_load"
 217     llvm_cv_no_link_all_option="-Wl,-noall_load"
 218     llvm_cv_os_type="Minix"
 219     llvm_cv_platform_type="Unix" ;;
 220   *-*-freebsd* | *-*-kfreebsd-gnu)
 221     llvm_cv_link_all_option="-Wl,--whole-archive"
 222     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 223     llvm_cv_os_type="FreeBSD"
 224     llvm_cv_platform_type="Unix" ;;
 225   *-*-openbsd*)
 226     llvm_cv_link_all_option="-Wl,--whole-archive"
 227     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 228     llvm_cv_os_type="OpenBSD"
 229     llvm_cv_platform_type="Unix" ;;
 230   *-*-netbsd*)
 231     llvm_cv_link_all_option="-Wl,--whole-archive"
 232     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 233     llvm_cv_os_type="NetBSD"
 234     llvm_cv_platform_type="Unix" ;;
 235   *-*-dragonfly*)
 236     llvm_cv_link_all_option="-Wl,--whole-archive"
 237     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 238     llvm_cv_os_type="DragonFly"
 239     llvm_cv_platform_type="Unix" ;;
 240   *-*-hpux*)
 241     llvm_cv_link_all_option="-Wl,--whole-archive"
 242     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 243     llvm_cv_os_type="HP-UX"
 244     llvm_cv_platform_type="Unix" ;;
 245   *-*-interix*)
 246     llvm_cv_link_all_option="-Wl,--whole-archive"
 247     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 248     llvm_cv_os_type="Interix"
 249     llvm_cv_platform_type="Unix" ;;
 250   *-*-linux*)
 251     llvm_cv_link_all_option="-Wl,--whole-archive"
 252     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 253     llvm_cv_os_type="Linux"
 254     llvm_cv_platform_type="Unix" ;;
 255   *-*-gnu*)
 256     llvm_cv_link_all_option="-Wl,--whole-archive"
 257     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 258     llvm_cv_os_type="GNU"
 259     llvm_cv_platform_type="Unix" ;;
 260   *-*-solaris*)
 261     llvm_cv_link_all_option="-Wl,-z,allextract"
 262     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 263     llvm_cv_os_type="SunOS"
 264     llvm_cv_platform_type="Unix" ;;
 265   *-*-auroraux*)
 266     llvm_cv_link_all_option="-Wl,-z,allextract"
 267     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 268     llvm_cv_os_type="AuroraUX"
 269     llvm_cv_platform_type="Unix" ;;
 270   *-*-win32*)
 271     llvm_cv_link_all_option="-Wl,--whole-archive"
 272     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 273     llvm_cv_os_type="Win32"
 274     llvm_cv_platform_type="Win32" ;;
 275   *-*-mingw*)
 276     llvm_cv_link_all_option="-Wl,--whole-archive"
 277     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 278     llvm_cv_os_type="MingW"
 279     llvm_cv_platform_type="Win32" ;;
 280   *-*-haiku*)
 281     llvm_cv_link_all_option="-Wl,--whole-archive"
 282     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 283     llvm_cv_os_type="Haiku"
 284     llvm_cv_platform_type="Unix" ;;
 285   *-unknown-eabi*)
 286     llvm_cv_link_all_option="-Wl,--whole-archive"
 287     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 288     llvm_cv_os_type="Freestanding"
 289     llvm_cv_platform_type="Unix" ;;
 290   *-unknown-elf*)
 291     llvm_cv_link_all_option="-Wl,--whole-archive"
 292     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 293     llvm_cv_os_type="Freestanding"
 294     llvm_cv_platform_type="Unix" ;;
 295   *)
 296     llvm_cv_link_all_option=""
 297     llvm_cv_no_link_all_option=""
 298     llvm_cv_os_type="Unknown"
 299     llvm_cv_platform_type="Unknown" ;;
 300 esac])
 301
 302 AC_CACHE_CHECK([type of operating system we're going to target],
 303                [llvm_cv_target_os_type],
 304 [case $target in
 305   *-*-aix*)
 306     llvm_cv_target_os_type="AIX" ;;
 307   *-*-irix*)
 308     llvm_cv_target_os_type="IRIX" ;;
 309   *-*-cygwin*)
 310     llvm_cv_target_os_type="Cygwin" ;;
 311   *-*-darwin*)
 312     llvm_cv_target_os_type="Darwin" ;;
 313   *-*-minix*)
 314     llvm_cv_target_os_type="Minix" ;;
 315   *-*-freebsd* | *-*-kfreebsd-gnu)
 316     llvm_cv_target_os_type="FreeBSD" ;;
 317   *-*-openbsd*)
 318     llvm_cv_target_os_type="OpenBSD" ;;
 319   *-*-netbsd*)
 320     llvm_cv_target_os_type="NetBSD" ;;
 321   *-*-dragonfly*)
 322     llvm_cv_target_os_type="DragonFly" ;;
 323   *-*-hpux*)
 324     llvm_cv_target_os_type="HP-UX" ;;
 325   *-*-interix*)
 326     llvm_cv_target_os_type="Interix" ;;
 327   *-*-linux*)
 328     llvm_cv_target_os_type="Linux" ;;
 329   *-*-gnu*)
 330     llvm_cv_target_os_type="GNU" ;;
 331   *-*-solaris*)
 332     llvm_cv_target_os_type="SunOS" ;;
 333   *-*-auroraux*)
 334     llvm_cv_target_os_type="AuroraUX" ;;
 335   *-*-win32*)
 336     llvm_cv_target_os_type="Win32" ;;
 337   *-*-mingw*)
 338     llvm_cv_target_os_type="MingW" ;;
 339   *-*-haiku*)
 340     llvm_cv_target_os_type="Haiku" ;;
 341   *-*-rtems*)
 342     llvm_cv_target_os_type="RTEMS" ;;
 343   *-*-nacl*)
 344     llvm_cv_target_os_type="NativeClient" ;;
 345   *-unknown-eabi*)
 346     llvm_cv_target_os_type="Freestanding" ;;
 347   *)
 348     llvm_cv_target_os_type="Unknown" ;;
 349 esac])
 350
 351 dnl Make sure we aren't attempting to configure for an unknown system
 352 if test "$llvm_cv_os_type" = "Unknown" ; then
 353   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 354 fi
 355
 356 dnl Set the "OS" Makefile variable based on the platform type so the
 357 dnl makefile can configure itself to specific build hosts
 358 AC_SUBST(OS,$llvm_cv_os_type)
 359 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 360 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 361
 362 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 363 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 364 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 365
 366 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 367 dnl This is used by lib/Support to determine the basic kind of implementation
 368 dnl to use.
 369 case $llvm_cv_platform_type in
 370   Unix)
 371     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 372     AC_SUBST(LLVM_ON_UNIX,[1])
 373     AC_SUBST(LLVM_ON_WIN32,[0])
 374     ;;
 375   Win32)
 376     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 377     AC_SUBST(LLVM_ON_UNIX,[0])
 378     AC_SUBST(LLVM_ON_WIN32,[1])
 379     ;;
 380 esac
 381
 382 dnl Determine what our target architecture is and configure accordingly.
 383 dnl This will allow Makefiles to make a distinction between the hardware and
 384 dnl the OS.
 385 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 386 [case $target in
 387   i?86-*)                 llvm_cv_target_arch="x86" ;;
 388   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 389   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 390   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 391   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 392   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 393   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 394   xcore-*)                llvm_cv_target_arch="XCore" ;;
 395   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 396   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 397   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 398   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 399   *)                      llvm_cv_target_arch="Unknown" ;;
 400 esac])
 401
 402 if test "$llvm_cv_target_arch" = "Unknown" ; then
 403   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 404 fi
 405
 406 dnl Determine the LLVM native architecture for the target
 407 case "$llvm_cv_target_arch" in
 408     x86)     LLVM_NATIVE_ARCH="X86" ;;
 409     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 410     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 411 esac
 412
 413 dnl Define a substitution, ARCH, for the target architecture
 414 AC_SUBST(ARCH,$llvm_cv_target_arch)
 415
 416 dnl Determine what our host architecture.
 417 dnl This will allow MCJIT regress tests runs only for supported
 418 dnl platforms.
 419 case $host in
 420   i?86-*)                 host_arch="x86" ;;
 421   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 422   sparc*-*)               host_arch="Sparc" ;;
 423   powerpc*-*)             host_arch="PowerPC" ;;
 424   arm*-*)                 host_arch="ARM" ;;
 425   mips-* | mips64-*)      host_arch="Mips" ;;
 426   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 427   xcore-*)                host_arch="XCore" ;;
 428   msp430-*)               host_arch="MSP430" ;;
 429   hexagon-*)              host_arch="Hexagon" ;;
 430   mblaze-*)               host_arch="MBlaze" ;;
 431   *)                      host_arch="Unknown" ;;
 432 esac
 433
 434 if test "$host_arch" = "Unknown" ; then
 435   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 436 fi
 437
 438 AC_SUBST(HOST_ARCH,$host_arch)
 439
 440 dnl Check for the endianness of the target
 441 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 442
 443 dnl Check for build platform executable suffix if we're cross-compiling
 444 if test "$cross_compiling" = yes; then
 445   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 446   AC_BUILD_EXEEXT
 447   ac_build_prefix=${build_alias}-
 448   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 449   if test -z "$BUILD_CXX"; then
 450      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 451      if test -z "$BUILD_CXX"; then
 452        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 453      fi
 454   fi
 455 else
 456   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 457 fi
 458
 459 dnl Check to see if there's a .svn or .git directory indicating that this
 460 dnl build is being done from a checkout. This sets up several defaults for
 461 dnl the command line switches. When we build with a checkout directory,
 462 dnl we get a debug with assertions turned on. Without, we assume a source
 463 dnl release and we get an optimized build without assertions.
 464 dnl See --enable-optimized and --enable-assertions below
 465 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 466   cvsbuild="yes"
 467   optimize="no"
 468   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 469 else
 470   cvsbuild="no"
 471   optimize="yes"
 472 fi
 473
 474 dnl===-----------------------------------------------------------------------===
 475 dnl===
 476 dnl=== SECTION 3: Command line arguments for the configure script.
 477 dnl===
 478 dnl===-----------------------------------------------------------------------===
 479
 480 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 481 AC_ARG_ENABLE(libcpp,
 482               AS_HELP_STRING([--enable-libcpp],
 483                              [Use libc++ if available (default is NO)]),,
 484                              enableval=default)
 485 case "$enableval" in
 486   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 487   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 488   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 489   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 490 esac
 491
 492 dnl --enable-cxx11 : check whether or not to use -std=c++11 on the command line
 493 AC_ARG_ENABLE(cxx11,
 494               AS_HELP_STRING([--enable-cxx11],
 495                              [Use c++11 if available (default is NO)]),,
 496                              enableval=default)
 497 case "$enableval" in
 498   yes) AC_SUBST(ENABLE_CXX11,[1]) ;;
 499   no)  AC_SUBST(ENABLE_CXX11,[0]) ;;
 500   default) AC_SUBST(ENABLE_CXX11,[0]);;
 501   *) AC_MSG_ERROR([Invalid setting for --enable-cxx11. Use "yes" or "no"]) ;;
 502 esac
 503
 504 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 505 clang_arcmt="yes"
 506 AC_ARG_ENABLE(clang-arcmt,
 507               AS_HELP_STRING([--enable-clang-arcmt],
 508                              [Enable building of clang ARCMT (default is YES)]),
 509                              clang_arcmt="$enableval",
 510                              enableval="yes")
 511 case "$enableval" in
 512   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 513   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 514   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 515   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 516 esac
 517
 518 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 519 clang_static_analyzer="yes"
 520 AC_ARG_ENABLE(clang-static-analyzer,
 521               AS_HELP_STRING([--enable-clang-static-analyzer],
 522                              [Enable building of clang Static Analyzer (default is YES)]),
 523                              clang_static_analyzer="$enableval",
 524                              enableval="yes")
 525 case "$enableval" in
 526   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 527   no)  AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0]) ;;
 528   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 529   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 530 esac
 531
 532 dnl --enable-clang-rewriter: check whether to enable clang rewriter
 533 AC_ARG_ENABLE(clang-rewriter,
 534               AS_HELP_STRING([--enable-clang-rewriter],
 535                              [Enable building of clang rewriter (default is YES)]),,
 536                              enableval="yes")
 537 case "$enableval" in
 538   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
 539   no)
 540     if test ${clang_arcmt} != "no" ; then
 541       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
 542     fi
 543     if test ${clang_static_analyzer} != "no" ; then
 544       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
 545     fi
 546     AC_SUBST(ENABLE_CLANG_REWRITER,[0])
 547     ;;
 548   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
 549   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
 550 esac
 551
 552 dnl --enable-optimized : check whether they want to do an optimized build:
 553 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 554  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 555 if test ${enableval} = "no" ; then
 556   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 557 else
 558   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 559 fi
 560
 561 dnl --enable-profiling : check whether they want to do a profile build:
 562 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 563  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 564 if test ${enableval} = "no" ; then
 565   AC_SUBST(ENABLE_PROFILING,[[]])
 566 else
 567   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 568 fi
 569
 570 dnl --enable-assertions : check whether they want to turn on assertions or not:
 571 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 572   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 573 if test ${enableval} = "yes" ; then
 574   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 575 else
 576   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 577 fi
 578
 579 dnl --enable-werror : check whether we want Werror on by default
 580 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 581   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 582 case "$enableval" in
 583   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 584   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 585   default) AC_SUBST(ENABLE_WERROR,[0]);;
 586   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 587 esac
 588
 589 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 590 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 591   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 592 if test ${enableval} = "yes" ; then
 593   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 594   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 595 else
 596   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 597   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 598 fi
 599
 600 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 601 AC_ARG_ENABLE(debug-runtime,
 602    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 603 if test ${enableval} = "no" ; then
 604   AC_SUBST(DEBUG_RUNTIME,[[]])
 605 else
 606   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 607 fi
 608
 609 dnl --enable-debug-symbols : should even optimized compiler libraries
 610 dnl have debug symbols?
 611 AC_ARG_ENABLE(debug-symbols,
 612    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 613 if test ${enableval} = "no" ; then
 614   AC_SUBST(DEBUG_SYMBOLS,[[]])
 615 else
 616   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 617 fi
 618
 619 dnl --enable-keep-symbols : do not strip installed executables
 620 AC_ARG_ENABLE(keep-symbols,
 621    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 622 if test ${enableval} = "no" ; then
 623   AC_SUBST(KEEP_SYMBOLS,[[]])
 624 else
 625   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 626 fi
 627
 628 dnl --enable-jit: check whether they want to enable the jit
 629 AC_ARG_ENABLE(jit,
 630   AS_HELP_STRING(--enable-jit,
 631                  [Enable Just In Time Compiling (default is YES)]),,
 632   enableval=default)
 633 if test ${enableval} = "no"
 634 then
 635   AC_SUBST(JIT,[[]])
 636 else
 637   case "$llvm_cv_target_arch" in
 638     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 639     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 640     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 641     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 642     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 643     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 644     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 645     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 646     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 647     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 648     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 649     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 650   esac
 651 fi
 652
 653 dnl Allow enablement of building and installing docs
 654 AC_ARG_ENABLE(docs,
 655               AS_HELP_STRING([--enable-docs],
 656                              [Build documents (default is YES)]),,
 657                              enableval=default)
 658 case "$enableval" in
 659   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 660   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 661   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 662   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 663 esac
 664
 665 dnl Allow enablement of doxygen generated documentation
 666 AC_ARG_ENABLE(doxygen,
 667               AS_HELP_STRING([--enable-doxygen],
 668                              [Build doxygen documentation (default is NO)]),,
 669                              enableval=default)
 670 case "$enableval" in
 671   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 672   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 673   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 674   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 675 esac
 676
 677 dnl Allow disablement of threads
 678 AC_ARG_ENABLE(threads,
 679               AS_HELP_STRING([--enable-threads],
 680                              [Use threads if available (default is YES)]),,
 681                              enableval=default)
 682 case "$enableval" in
 683   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 684   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 685   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 686   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 687 esac
 688 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 689                    [Define if threads enabled])
 690
 691 dnl Allow disablement of pthread.h
 692 AC_ARG_ENABLE(pthreads,
 693               AS_HELP_STRING([--enable-pthreads],
 694                              [Use pthreads if available (default is YES)]),,
 695                              enableval=default)
 696 case "$enableval" in
 697   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 698   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 699   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 700   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 701 esac
 702
 703 dnl Allow building without position independent code
 704 AC_ARG_ENABLE(pic,
 705   AS_HELP_STRING([--enable-pic],
 706                  [Build LLVM with Position Independent Code (default is YES)]),,
 707                  enableval=default)
 708 case "$enableval" in
 709   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 710   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 711   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 712   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 713 esac
 714 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 715                    [Define if position independent code is enabled])
 716
 717 dnl Allow building a shared library and linking tools against it.
 718 AC_ARG_ENABLE(shared,
 719   AS_HELP_STRING([--enable-shared],
 720                  [Build a shared library and link tools against it (default is NO)]),,
 721                  enableval=default)
 722 case "$enableval" in
 723   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 724   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 725   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 726   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 727 esac
 728
 729 dnl Allow libstdc++ is embedded in LLVM.dll.
 730 AC_ARG_ENABLE(embed-stdcxx,
 731   AS_HELP_STRING([--enable-embed-stdcxx],
 732                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 733                  enableval=default)
 734 case "$enableval" in
 735   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 736   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 737   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 738   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 739 esac
 740
 741 dnl Enable embedding timestamp information into build.
 742 AC_ARG_ENABLE(timestamps,
 743   AS_HELP_STRING([--enable-timestamps],
 744                  [Enable embedding timestamp information in build (default is YES)]),,
 745                  enableval=default)
 746 case "$enableval" in
 747   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 748   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 749   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 750   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 751 esac
 752 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 753                    [Define if timestamp information (e.g., __DATE__) is allowed])
 754
 755 dnl Enable embedding timestamp information into build.
 756
 757 AC_ARG_ENABLE(backtraces,
 758   AS_HELP_STRING([--enable-backtraces],
 759                  [Enable embedding backtraces on crash (default is YES)]),,
 760                  enableval=default)
 761 case "$enableval" in
 762   yes) AC_SUBST(ENABLE_BACKTRACES,[1]) ;;
 763   no)  AC_SUBST(ENABLE_BACKTRACES,[0]) ;;
 764   default) AC_SUBST(ENABLE_BACKTRACES,[1]) ;;
 765   *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 766 esac
 767 AC_DEFINE_UNQUOTED([ENABLE_BACKTRACES],$ENABLE_BACKTRACES,
 768                    [Define if you want backtraces on crash])
 769
 770 dnl Allow specific targets to be specified for building (or not)
 771 TARGETS_TO_BUILD=""
 772 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 773     [Build specific host targets: all or target1,target2,... Valid targets are:
 774      host, x86, x86_64, sparc, powerpc, arm, mips, hexagon,
 775      xcore, msp430, nvptx, and cpp (default=all)]),,
 776     enableval=all)
 777 if test "$enableval" = host-only ; then
 778   enableval=host
 779 fi
 780 case "$enableval" in
 781   all) TARGETS_TO_BUILD="X86 Sparc PowerPC ARM Mips XCore MSP430 CppBackend MBlaze NVPTX Hexagon" ;;
 782   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 783       case "$a_target" in
 784         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 785         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 786         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 787         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 788         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 789         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 790         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 791         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 792         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 793         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 794         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 795         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 796         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 797         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 798         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 799         host) case "$llvm_cv_target_arch" in
 800             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 801             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 802             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 803             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 804             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 805             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 806             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 807             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 808             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 809             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 810             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 811             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 812           esac ;;
 813         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 814       esac
 815   done
 816   ;;
 817 esac
 818
 819 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
 820     [Build experimental host targets: disable or target1,target2,...
 821      (default=disable)]),,
 822     enableval=disable)
 823
 824 if test ${enableval} != "disable"
 825 then
 826   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
 827 fi
 828
 829 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 830
 831 dnl Determine whether we are building LLVM support for the native architecture.
 832 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 833 for a_target in $TARGETS_TO_BUILD; do
 834   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 835     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 836       [LLVM architecture name for the native architecture, if available])
 837     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 838     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 839     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 840     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 841     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 842       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 843     fi
 844     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 845       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 846     fi
 847     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 848       [LLVM name for the native Target init function, if available])
 849     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 850       [LLVM name for the native TargetInfo init function, if available])
 851     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 852       [LLVM name for the native target MC init function, if available])
 853     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 854       [LLVM name for the native AsmPrinter init function, if available])
 855     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 856       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 857        [LLVM name for the native AsmParser init function, if available])
 858     fi
 859     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 860       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 861        [LLVM name for the native Disassembler init function, if available])
 862     fi
 863   fi
 864 done
 865
 866 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 867 dnl target feature def files.
 868 LLVM_ENUM_TARGETS=""
 869 LLVM_ENUM_ASM_PRINTERS=""
 870 LLVM_ENUM_ASM_PARSERS=""
 871 LLVM_ENUM_DISASSEMBLERS=""
 872 for target_to_build in $TARGETS_TO_BUILD; do
 873   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 874   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 875     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 876   fi
 877   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 878     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 879   fi
 880   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 881     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 882   fi
 883 done
 884 AC_SUBST(LLVM_ENUM_TARGETS)
 885 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 886 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 887 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 888
 889 dnl Override the option to use for optimized builds.
 890 AC_ARG_WITH(optimize-option,
 891   AS_HELP_STRING([--with-optimize-option],
 892                  [Select the compiler options to use for optimized builds]),,
 893                  withval=default)
 894 AC_MSG_CHECKING([optimization flags])
 895 case "$withval" in
 896   default)
 897     case "$llvm_cv_os_type" in
 898     FreeBSD) optimize_option=-O2 ;;
 899     MingW) optimize_option=-O2 ;;
 900     *)     optimize_option=-O3 ;;
 901     esac ;;
 902   *) optimize_option="$withval" ;;
 903 esac
 904 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 905 AC_MSG_RESULT([$optimize_option])
 906
 907 dnl Specify extra build options
 908 AC_ARG_WITH(extra-options,
 909   AS_HELP_STRING([--with-extra-options],
 910                  [Specify additional options to compile LLVM with]),,
 911                  withval=default)
 912 case "$withval" in
 913   default) EXTRA_OPTIONS= ;;
 914   *) EXTRA_OPTIONS=$withval ;;
 915 esac
 916 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 917
 918 dnl Specify extra linker build options
 919 AC_ARG_WITH(extra-ld-options,
 920   AS_HELP_STRING([--with-extra-ld-options],
 921                  [Specify additional options to link LLVM with]),,
 922                  withval=default)
 923 case "$withval" in
 924   default) EXTRA_LD_OPTIONS= ;;
 925   *) EXTRA_LD_OPTIONS=$withval ;;
 926 esac
 927 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 928
 929 dnl Allow specific bindings to be specified for building (or not)
 930 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 931     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 932     enableval=default)
 933 BINDINGS_TO_BUILD=""
 934 case "$enableval" in
 935   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 936   all ) BINDINGS_TO_BUILD="ocaml" ;;
 937   none | no) BINDINGS_TO_BUILD="" ;;
 938   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 939       case "$a_binding" in
 940         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 941         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 942       esac
 943   done
 944   ;;
 945 esac
 946
 947 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 948 dnl script for bindings/ocaml/configure, except that its auto value depends on
 949 dnl OCAMLC, which is found here to support tests.
 950 AC_ARG_WITH([ocaml-libdir],
 951   [AS_HELP_STRING([--with-ocaml-libdir],
 952     [Specify install location for ocaml bindings (default is stdlib)])],
 953   [],
 954   [withval=auto])
 955 case "$withval" in
 956   auto) with_ocaml_libdir="$withval" ;;
 957   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 958   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 959 esac
 960
 961 AC_ARG_WITH(clang-srcdir,
 962   AS_HELP_STRING([--with-clang-srcdir],
 963     [Directory to the out-of-tree Clang source]),,
 964     withval="-")
 965 case "$withval" in
 966   -) clang_src_root="" ;;
 967   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 968   *) clang_src_root="$ac_pwd/$withval" ;;
 969 esac
 970 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
 971
 972 AC_ARG_WITH(clang-resource-dir,
 973   AS_HELP_STRING([--with-clang-resource-dir],
 974     [Relative directory from the Clang binary for resource files]),,
 975     withval="")
 976 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 977                    [Relative directory for resource files])
 978
 979 AC_ARG_WITH(c-include-dirs,
 980   AS_HELP_STRING([--with-c-include-dirs],
 981     [Colon separated list of directories clang will search for headers]),,
 982     withval="")
 983 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 984                    [Directories clang will search for headers])
 985
 986 # Clang normally uses the system c++ headers and libraries. With this option,
 987 # clang will use the ones provided by a gcc installation instead. This option should
 988 # be passed the same value that was used with --prefix when configuring gcc.
 989 AC_ARG_WITH(gcc-toolchain,
 990   AS_HELP_STRING([--with-gcc-toolchain],
 991     [Directory where gcc is installed.]),,
 992     withval="")
 993 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
 994                    [Directory where gcc is installed.])
 995
 996 AC_ARG_WITH(default-sysroot,
 997   AS_HELP_STRING([--with-default-sysroot],
 998     [Add --sysroot=<path> to all compiler invocations.]),,
 999     withval="")
1000 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1001                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1002
1003 dnl Allow linking of LLVM with GPLv3 binutils code.
1004 AC_ARG_WITH(binutils-include,
1005   AS_HELP_STRING([--with-binutils-include],
1006     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1007   withval=default)
1008 case "$withval" in
1009   default) WITH_BINUTILS_INCDIR=default ;;
1010   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1011   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1012 esac
1013 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1014   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1015   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1016      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1017      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1018   fi
1019 fi
1020
1021 dnl Specify the URL where bug reports should be submitted.
1022 AC_ARG_WITH(bug-report-url,
1023   AS_HELP_STRING([--with-bug-report-url],
1024     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1025     withval="http://llvm.org/bugs/")
1026 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1027                    [Bug report URL.])
1028
1029 dnl --enable-libffi : check whether the user wants to turn off libffi:
1030 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1031   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1032   [case "$enableval" in
1033     yes) llvm_cv_enable_libffi="yes" ;;
1034     no)  llvm_cv_enable_libffi="no"  ;;
1035     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1036   esac],
1037   llvm_cv_enable_libffi=no)
1038
1039 AC_ARG_WITH(internal-prefix,
1040   AS_HELP_STRING([--with-internal-prefix],
1041     [Installation directory for internal files]),,
1042     withval="")
1043 AC_SUBST(INTERNAL_PREFIX,[$withval])
1044
1045 dnl===-----------------------------------------------------------------------===
1046 dnl===
1047 dnl=== SECTION 4: Check for programs we need and that they are the right version
1048 dnl===
1049 dnl===-----------------------------------------------------------------------===
1050
1051 AC_PROG_NM
1052 AC_SUBST(NM)
1053
1054 dnl Check for the tools that the makefiles require
1055 AC_CHECK_GNU_MAKE
1056 AC_PROG_LN_S
1057 AC_PATH_PROG(CMP, [cmp], [cmp])
1058 AC_PATH_PROG(CP, [cp], [cp])
1059 AC_PATH_PROG(DATE, [date], [date])
1060 AC_PATH_PROG(FIND, [find], [find])
1061 AC_PATH_PROG(GREP, [grep], [grep])
1062 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1063 AC_PATH_PROG(MV,   [mv],   [mv])
1064 AC_PROG_RANLIB
1065 AC_CHECK_TOOL(AR, ar, false)
1066 AC_PATH_PROG(RM,   [rm],   [rm])
1067 AC_PATH_PROG(SED,  [sed],  [sed])
1068 AC_PATH_PROG(TAR,  [tar],  [gtar])
1069 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1070
1071 dnl Looking for misc. graph plotting software
1072 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
1073 if test "$GRAPHVIZ" != "echo Graphviz" ; then
1074   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
1075   dnl If we're targeting for mingw we should emit windows paths, not msys
1076   if test "$llvm_cv_os_type" = "MingW" ; then
1077     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1078   fi
1079   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1080    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1081 fi
1082 AC_PATH_PROG(DOT, [dot], [echo dot])
1083 if test "$DOT" != "echo dot" ; then
1084   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1085   dnl If we're targeting for mingw we should emit windows paths, not msys
1086   if test "$llvm_cv_os_type" = "MingW" ; then
1087     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1088   fi
1089   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1090    [Define to path to dot program if found or 'echo dot' otherwise])
1091 fi
1092 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1093 if test "$FDP" != "echo fdp" ; then
1094   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1095   dnl If we're targeting for mingw we should emit windows paths, not msys
1096   if test "$llvm_cv_os_type" = "MingW" ; then
1097     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1098   fi
1099   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1100    [Define to path to fdp program if found or 'echo fdp' otherwise])
1101 fi
1102 AC_PATH_PROG(NEATO, [neato], [echo neato])
1103 if test "$NEATO" != "echo neato" ; then
1104   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1105   dnl If we're targeting for mingw we should emit windows paths, not msys
1106   if test "$llvm_cv_os_type" = "MingW" ; then
1107     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1108   fi
1109   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1110    [Define to path to neato program if found or 'echo neato' otherwise])
1111 fi
1112 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1113 if test "$TWOPI" != "echo twopi" ; then
1114   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1115   dnl If we're targeting for mingw we should emit windows paths, not msys
1116   if test "$llvm_cv_os_type" = "MingW" ; then
1117     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1118   fi
1119   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1120    [Define to path to twopi program if found or 'echo twopi' otherwise])
1121 fi
1122 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1123 if test "$CIRCO" != "echo circo" ; then
1124   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1125   dnl If we're targeting for mingw we should emit windows paths, not msys
1126   if test "$llvm_cv_os_type" = "MingW" ; then
1127     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1128   fi
1129   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1130    [Define to path to circo program if found or 'echo circo' otherwise])
1131 fi
1132 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1133 if test "$GV" != "echo gv" ; then
1134   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1135   dnl If we're targeting for mingw we should emit windows paths, not msys
1136   if test "$llvm_cv_os_type" = "MingW" ; then
1137     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1138   fi
1139   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1140    [Define to path to gv program if found or 'echo gv' otherwise])
1141 fi
1142 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1143 if test "$DOTTY" != "echo dotty" ; then
1144   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1145   dnl If we're targeting for mingw we should emit windows paths, not msys
1146   if test "$llvm_cv_os_type" = "MingW" ; then
1147     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1148   fi
1149   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1150    [Define to path to dotty program if found or 'echo dotty' otherwise])
1151 fi
1152 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1153 if test "$XDOT_PY" != "echo xdot.py" ; then
1154   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1155   dnl If we're targeting for mingw we should emit windows paths, not msys
1156   if test "$llvm_cv_os_type" = "MingW" ; then
1157     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1158   fi
1159   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1160    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1161 fi
1162
1163 dnl Find the install program
1164 AC_PROG_INSTALL
1165 dnl Prepend src dir to install path dir if it's a relative path
1166 dnl This is a hack for installs that take place in something other
1167 dnl than the top level.
1168 case "$INSTALL" in
1169  [[\\/$]]* | ?:[[\\/]]* ) ;;
1170  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1171 esac
1172
1173 dnl Checks for documentation and testing tools that we can do without. If these
1174 dnl are not found then they are set to "true" which always succeeds but does
1175 dnl nothing. This just lets the build output show that we could have done
1176 dnl something if the tool was available.
1177 AC_PATH_PROG(BZIP2, [bzip2])
1178 AC_PATH_PROG(CAT, [cat])
1179 AC_PATH_PROG(DOXYGEN, [doxygen])
1180 AC_PATH_PROG(GROFF, [groff])
1181 AC_PATH_PROG(GZIPBIN, [gzip])
1182 AC_PATH_PROG(PDFROFF, [pdfroff])
1183 AC_PATH_PROG(ZIP, [zip])
1184 AC_PATH_PROGS(OCAMLC, [ocamlc])
1185 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1186 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1187 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1188 AC_PATH_PROGS(GAS, [gas as])
1189
1190 dnl Get the version of the linker in use.
1191 AC_LINK_GET_VERSION
1192
1193 dnl Determine whether the linker supports the -R option.
1194 AC_LINK_USE_R
1195
1196 dnl Determine whether the linker supports the -export-dynamic option.
1197 AC_LINK_EXPORT_DYNAMIC
1198
1199 dnl Determine whether the linker supports the --version-script option.
1200 AC_LINK_VERSION_SCRIPT
1201
1202 dnl Check for libtool and the library that has dlopen function (which must come
1203 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1204 dnl libtool).
1205 AC_LIBTOOL_DLOPEN
1206 AC_LIB_LTDL
1207
1208 AC_MSG_CHECKING([tool compatibility])
1209
1210 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1211 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1212 dnl to support those options.
1213 dnl "icc" emits gcc signatures
1214 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1215 ICC=no
1216 IXX=no
1217 case $CC in
1218   icc*|icpc*)
1219     ICC=yes
1220     IXX=yes
1221     ;;
1222    *)
1223     ;;
1224 esac
1225
1226 if test "$GCC" != "yes" && test "$ICC" != "yes"
1227 then
1228   AC_MSG_ERROR([gcc|icc required but not found])
1229 fi
1230
1231 dnl Ensure that compilation tools are compatible with GCC extensions
1232 if test "$GXX" != "yes" && test "$IXX" != "yes"
1233 then
1234   AC_MSG_ERROR([g++|clang++|icc required but not found])
1235 fi
1236
1237 dnl Verify that GCC is version 3.0 or higher
1238 if test "$GCC" = "yes"
1239 then
1240   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1241 #error Unsupported GCC version
1242 #endif
1243 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1244 fi
1245
1246 dnl Check for GNU Make.  We use its extensions, so don't build without it
1247 if test -z "$llvm_cv_gnu_make_command"
1248 then
1249   AC_MSG_ERROR([GNU Make required but not found])
1250 fi
1251
1252 dnl Tool compatibility is okay if we make it here.
1253 AC_MSG_RESULT([ok])
1254
1255 dnl Check optional compiler flags.
1256 AC_MSG_CHECKING([optional compiler flags])
1257 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1258 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1259 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1260 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1261 dnl false positives, so disable it.
1262 if test "$GXX" = "yes"
1263 then
1264   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1265   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1266   dnl known to be uninitialized from cases which might be uninitialized.  We
1267   dnl still want to catch the first kind of errors.
1268   if test "$NO_MAYBE_UNINITIALIZED" != "-Wno-maybe-uninitialized"
1269   then
1270     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1271   else
1272     dnl Some versions of gcc accept unsupported -W flags if there is
1273     dnl no warning but stop with an error when a warning is
1274     dnl encountered.  If this gcc is earlier than 4.7, just use
1275     dnl -Wno-uninitialized.
1276     gxx_version=`$CXX -dumpversion`
1277     gxx_version_major=`echo $gxx_version | cut -d'.' -f1`
1278     gxx_version_minor=`echo $gxx_version | cut -d'.' -f2`
1279     gxx_version_patch=`echo $gxx_version | cut -d'.' -f3`
1280
1281     if    test "$gxx_version_major" -ge "4" \
1282        && test "$gxx_version_minor" -ge "7"; then
1283       dnl AC_SUBST doesn't work with empty strings.
1284       NO_UNINITIALIZED=
1285     else
1286       NO_MAYBE_UNINITIALIZED=
1287       CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1288     fi
1289   fi
1290 else
1291   NO_UNINITIALIZED=
1292   NO_MAYBE_UNINITIALIZED=
1293 fi
1294 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1295
1296
1297 dnl===-----------------------------------------------------------------------===
1298 dnl===
1299 dnl=== SECTION 5: Check for libraries
1300 dnl===
1301 dnl===-----------------------------------------------------------------------===
1302
1303 AC_CHECK_LIB(m,sin)
1304 if test "$llvm_cv_os_type" = "MingW" ; then
1305   AC_CHECK_LIB(imagehlp, main)
1306   AC_CHECK_LIB(psapi, main)
1307 fi
1308
1309 dnl dlopen() is required for plugin support.
1310 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1311                [Define if dlopen() is available on this platform.]),
1312                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1313
1314 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1315 dnl macros to detect whether clock_gettime is available, this just finds the
1316 dnl right libraries to link with.
1317 AC_SEARCH_LIBS(clock_gettime,rt)
1318
1319 dnl libffi is optional; used to call external functions from the interpreter
1320 if test "$llvm_cv_enable_libffi" = "yes" ; then
1321   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1322                  [Define if libffi is available on this platform.]),
1323                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1324 fi
1325
1326 dnl mallinfo is optional; the code can compile (minus features) without it
1327 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1328                [Define if mallinfo() is available on this platform.]))
1329
1330 dnl pthread locking functions are optional - but llvm will not be thread-safe
1331 dnl without locks.
1332 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1333   AC_CHECK_LIB(pthread, pthread_mutex_init)
1334   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1335                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1336                            [Have pthread_mutex_lock]))
1337   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1338                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1339                  [Have pthread_rwlock_init]))
1340   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1341                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1342                  [Have pthread_getspecific]))
1343 fi
1344
1345 dnl Allow extra x86-disassembler library
1346 AC_ARG_WITH(udis86,
1347   AS_HELP_STRING([--with-udis86=<path>],
1348     [Use udis86 external x86 disassembler library]),
1349     [
1350       AC_SUBST(USE_UDIS86, [1])
1351       case "$withval" in
1352         /usr/lib|yes) ;;
1353         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1354       esac
1355       AC_CHECK_LIB(udis86, ud_init, [], [
1356         echo "Error! You need to have libudis86 around."
1357         exit -1
1358       ])
1359     ],
1360     AC_SUBST(USE_UDIS86, [0]))
1361 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1362                    [Define if use udis86 library])
1363
1364 dnl Allow OProfile support for JIT output.
1365 AC_ARG_WITH(oprofile,
1366   AS_HELP_STRING([--with-oprofile=<prefix>],
1367     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1368     [
1369       AC_SUBST(USE_OPROFILE, [1])
1370       case "$withval" in
1371         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1372         no) llvm_cv_oppath=
1373             AC_SUBST(USE_OPROFILE, [0]) ;;
1374         *) llvm_cv_oppath="${withval}/lib/oprofile"
1375            CPPFLAGS="-I${withval}/include";;
1376       esac
1377       case $llvm_cv_os_type in
1378         Linux)
1379           if test -n "$llvm_cv_oppath" ; then
1380             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1381             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1382             dnl libbfd is not included properly in libopagent in some Debian
1383             dnl versions.  If libbfd isn't found at all, we assume opagent works
1384             dnl anyway.
1385             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1386             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1387               echo "Error! You need to have libopagent around."
1388               exit -1
1389             ])
1390             AC_CHECK_HEADER([opagent.h], [], [
1391               echo "Error! You need to have opagent.h around."
1392               exit -1
1393               ])
1394           fi ;;
1395         *)
1396           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1397       esac
1398     ],
1399     [
1400       AC_SUBST(USE_OPROFILE, [0])
1401     ])
1402 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1403                    [Define if we have the oprofile JIT-support library])
1404
1405 dnl Enable support for Intel JIT Events API.
1406 AC_ARG_WITH(intel-jitevents,
1407   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1408     [
1409        case "$withval" in
1410           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1411           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1412           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1413        esac
1414
1415       case $llvm_cv_os_type in
1416         Linux|Win32|Cygwin|MingW) ;;
1417         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1418       esac
1419
1420       case "$llvm_cv_target_arch" in
1421         x86|x86_64) ;;
1422         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1423       esac
1424     ],
1425     [
1426       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1427     ])
1428 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1429                    [Define if we have the Intel JIT API runtime support library])
1430
1431 dnl Check for libxml2
1432 dnl Right now we're just checking for the existence, we could also check for a
1433 dnl particular version via --version on xml2-config
1434 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1435
1436 AC_MSG_CHECKING(for libxml2 includes)
1437 if test "x$XML2CONFIG" = "x"; then
1438  AC_MSG_RESULT(xml2-config not found)
1439 else
1440  LIBXML2_INC=`$XML2CONFIG --cflags`
1441  AC_MSG_RESULT($LIBXML2_INC)
1442  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1443                                 LIBXML2_LIBS="-lxml2"])
1444 fi
1445 AC_SUBST(LIBXML2_LIBS)
1446 AC_SUBST(LIBXML2_INC)
1447
1448 dnl===-----------------------------------------------------------------------===
1449 dnl===
1450 dnl=== SECTION 6: Check for header files
1451 dnl===
1452 dnl===-----------------------------------------------------------------------===
1453
1454 dnl First, use autoconf provided macros for specific headers that we need
1455 dnl We don't check for ancient stuff or things that are guaranteed to be there
1456 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1457 dnl Generally we're looking for POSIX headers.
1458 AC_HEADER_DIRENT
1459 AC_HEADER_MMAP_ANONYMOUS
1460 AC_HEADER_STAT
1461 AC_HEADER_SYS_WAIT
1462 AC_HEADER_TIME
1463
1464 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1465 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1466 AC_CHECK_HEADERS([utime.h windows.h])
1467 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1468 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1469 AC_CHECK_HEADERS([valgrind/valgrind.h])
1470 AC_CHECK_HEADERS([fenv.h])
1471 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1472   AC_CHECK_HEADERS(pthread.h,
1473                    AC_SUBST(HAVE_PTHREAD, 1),
1474                    AC_SUBST(HAVE_PTHREAD, 0))
1475 else
1476   AC_SUBST(HAVE_PTHREAD, 0)
1477 fi
1478
1479 dnl Try to find ffi.h.
1480 if test "$llvm_cv_enable_libffi" = "yes" ; then
1481   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1482 fi
1483
1484 dnl Try to find Darwin specific crash reporting libraries.
1485 AC_CHECK_HEADERS([CrashReporterClient.h])
1486
1487 dnl Try to find Darwin specific crash reporting global.
1488 AC_MSG_CHECKING([__crashreporter_info__])
1489 AC_LINK_IFELSE(
1490   AC_LANG_SOURCE(
1491     [[extern const char *__crashreporter_info__;
1492       int main() {
1493         __crashreporter_info__ = "test";
1494         return 0;
1495       }
1496     ]]),
1497   AC_MSG_RESULT(yes)
1498   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1499   AC_MSG_RESULT(no)
1500   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1501             Define if __crashreporter_info__ exists.))
1502
1503 dnl===-----------------------------------------------------------------------===
1504 dnl===
1505 dnl=== SECTION 7: Check for types and structures
1506 dnl===
1507 dnl===-----------------------------------------------------------------------===
1508
1509 AC_HUGE_VAL_CHECK
1510 AC_TYPE_PID_T
1511 AC_TYPE_SIZE_T
1512 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1513 AC_STRUCT_TM
1514 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1515 AC_CHECK_TYPES([uint64_t],,
1516          AC_CHECK_TYPES([u_int64_t],,
1517          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1518
1519 dnl===-----------------------------------------------------------------------===
1520 dnl===
1521 dnl=== SECTION 8: Check for specific functions needed
1522 dnl===
1523 dnl===-----------------------------------------------------------------------===
1524
1525 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1526 AC_CHECK_FUNCS([powf fmodf strtof round ])
1527 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1528 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1529 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit strdup ])
1530 AC_CHECK_FUNCS([strerror strerror_r setenv arc4random ])
1531 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1532 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1533 AC_C_PRINTF_A
1534 AC_FUNC_RAND48
1535
1536 dnl Check the declaration "Secure API" on Windows environments.
1537 AC_CHECK_DECLS([strerror_s])
1538
1539 dnl Check symbols in libgcc.a for JIT on Mingw.
1540 if test "$llvm_cv_os_type" = "MingW" ; then
1541   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1542   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1543   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1544   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1545
1546   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1547   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1548   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1549   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1550   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1551   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1552   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1553   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1554   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1555   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1556
1557   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1558   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1559 fi
1560
1561 dnl Check Win32 API EnumerateLoadedModules.
1562 if test "$llvm_cv_os_type" = "MingW" ; then
1563   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1564   AC_COMPILE_IFELSE([[#include <windows.h>
1565 #include <imagehlp.h>
1566 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1567 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1568 [
1569   AC_MSG_RESULT([yes])
1570   llvm_cv_win32_elmcb_pcstr="PCSTR"
1571 ],
1572 [
1573   AC_MSG_RESULT([no])
1574   llvm_cv_win32_elmcb_pcstr="PSTR"
1575 ])
1576   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1577 fi
1578
1579 dnl Check for variations in the Standard C++ library and STL. These macros are
1580 dnl provided by LLVM in the autoconf/m4 directory.
1581 AC_FUNC_ISNAN
1582 AC_FUNC_ISINF
1583
1584 dnl Check for mmap support.We also need to know if /dev/zero is required to
1585 dnl be opened for allocating RWX memory.
1586 dnl Make sure we aren't attempting to configure for an unknown system
1587 if test "$llvm_cv_platform_type" = "Unix" ; then
1588   AC_FUNC_MMAP
1589   AC_FUNC_MMAP_FILE
1590   AC_NEED_DEV_ZERO_FOR_MMAP
1591
1592   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1593   then
1594     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1595   fi
1596   if test "$ac_cv_func_mmap_file" = "no"
1597   then
1598     AC_MSG_WARN([mmap() of files required but not found])
1599   fi
1600 fi
1601
1602 dnl atomic builtins are required for threading support.
1603 AC_MSG_CHECKING(for GCC atomic builtins)
1604 dnl Since we'll be using these atomic builtins in C++ files we should test
1605 dnl the C++ compiler.
1606 AC_LANG_PUSH([C++])
1607 AC_LINK_IFELSE(
1608   AC_LANG_SOURCE(
1609     [[int main() {
1610         volatile unsigned long val = 1;
1611         __sync_synchronize();
1612         __sync_val_compare_and_swap(&val, 1, 0);
1613         __sync_add_and_fetch(&val, 1);
1614         __sync_sub_and_fetch(&val, 1);
1615         return 0;
1616       }
1617     ]]),
1618   AC_LANG_POP([C++])
1619   AC_MSG_RESULT(yes)
1620   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1621   AC_MSG_RESULT(no)
1622   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1623   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1624
1625 dnl===-----------------------------------------------------------------------===
1626 dnl===
1627 dnl=== SECTION 9: Additional checks, variables, etc.
1628 dnl===
1629 dnl===-----------------------------------------------------------------------===
1630
1631 dnl Handle 32-bit linux systems running a 64-bit kernel.
1632 dnl This has to come after section 4 because it invokes the compiler.
1633 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1634   AC_IS_LINUX_MIXED
1635   if test "$llvm_cv_linux_mixed" = "yes"; then
1636     llvm_cv_target_arch="x86"
1637     ARCH="x86"
1638   fi
1639 fi
1640
1641 dnl Check whether __dso_handle is present
1642 AC_CHECK_FUNCS([__dso_handle])
1643
1644 dnl Propagate the shared library extension that the libltdl checks did to
1645 dnl the Makefiles so we can use it there too
1646 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1647
1648 dnl Propagate the run-time library path variable that the libltdl
1649 dnl checks found to the Makefiles so we can use it there too
1650 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1651
1652 dnl Translate the various configuration directories and other basic
1653 dnl information into substitutions that will end up in Makefile.config.in
1654 dnl that these configured values can be used by the makefiles
1655 if test "${prefix}" = "NONE" ; then
1656   prefix="/usr/local"
1657 fi
1658 eval LLVM_PREFIX="${prefix}";
1659 eval LLVM_BINDIR="${prefix}/bin";
1660 eval LLVM_LIBDIR="${prefix}/lib";
1661 eval LLVM_DATADIR="${prefix}/share/llvm";
1662 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1663 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1664 eval LLVM_INCLUDEDIR="${prefix}/include";
1665 eval LLVM_INFODIR="${prefix}/info";
1666 eval LLVM_MANDIR="${prefix}/man";
1667 LLVM_CONFIGTIME=`date`
1668 AC_SUBST(LLVM_PREFIX)
1669 AC_SUBST(LLVM_BINDIR)
1670 AC_SUBST(LLVM_LIBDIR)
1671 AC_SUBST(LLVM_DATADIR)
1672 AC_SUBST(LLVM_DOCSDIR)
1673 AC_SUBST(LLVM_ETCDIR)
1674 AC_SUBST(LLVM_INCLUDEDIR)
1675 AC_SUBST(LLVM_INFODIR)
1676 AC_SUBST(LLVM_MANDIR)
1677 AC_SUBST(LLVM_CONFIGTIME)
1678
1679 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1680 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1681   LLVM_CONFIGTIME="(timestamp not enabled)"
1682 fi
1683
1684 dnl Place the various directories into the config.h file as #defines so that we
1685 dnl can know about the installation paths within LLVM.
1686 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1687                    [Installation prefix directory])
1688 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1689                    [Installation directory for binary executables])
1690 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1691                    [Installation directory for libraries])
1692 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1693                    [Installation directory for data files])
1694 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1695                    [Installation directory for documentation])
1696 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1697                    [Installation directory for config files])
1698 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1699                    [Installation directory for include files])
1700 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1701                    [Installation directory for .info files])
1702 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1703                    [Installation directory for man pages])
1704 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1705                    [Time at which LLVM was configured])
1706 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1707                    [Host triple LLVM will be executed on])
1708 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1709                    [Target triple LLVM will generate code for by default])
1710
1711 dnl Determine which bindings to build.
1712 if test "$BINDINGS_TO_BUILD" = auto ; then
1713   BINDINGS_TO_BUILD=""
1714   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1715     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1716   fi
1717 fi
1718 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1719
1720 dnl This isn't really configurey, but it avoids having to repeat the list in
1721 dnl other files.
1722 AC_SUBST(ALL_BINDINGS,ocaml)
1723
1724 dnl Do any work necessary to ensure that bindings have what they need.
1725 binding_prereqs_failed=0
1726 for a_binding in $BINDINGS_TO_BUILD ; do
1727   case "$a_binding" in
1728   ocaml)
1729     if test "x$OCAMLC" = x ; then
1730       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1731       binding_prereqs_failed=1
1732     fi
1733     if test "x$OCAMLDEP" = x ; then
1734       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1735       binding_prereqs_failed=1
1736     fi
1737     if test "x$OCAMLOPT" = x ; then
1738       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1739       dnl ocamlopt is optional!
1740     fi
1741     if test "x$with_ocaml_libdir" != xauto ; then
1742       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1743     else
1744       ocaml_stdlib="`"$OCAMLC" -where`"
1745       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1746       then
1747         # ocaml stdlib is beneath our prefix; use stdlib
1748         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1749       else
1750         # ocaml stdlib is outside our prefix; use libdir/ocaml
1751         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1752       fi
1753     fi
1754     ;;
1755   esac
1756 done
1757 if test "$binding_prereqs_failed" = 1 ; then
1758   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1759 fi
1760
1761 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1762 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1763
1764 dnl Determine linker rpath flag
1765 if test "$llvm_cv_link_use_r" = "yes" ; then
1766   RPATH="-Wl,-R"
1767 else
1768   RPATH="-Wl,-rpath"
1769 fi
1770 AC_SUBST(RPATH)
1771
1772 dnl Determine linker rdynamic flag
1773 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1774   RDYNAMIC="-Wl,-export-dynamic"
1775 else
1776   RDYNAMIC=""
1777 fi
1778 AC_SUBST(RDYNAMIC)
1779
1780 dnl===-----------------------------------------------------------------------===
1781 dnl===
1782 dnl=== SECTION 10: Specify the output files and generate it
1783 dnl===
1784 dnl===-----------------------------------------------------------------------===
1785
1786 dnl Configure header files
1787 dnl WARNING: dnl If you add or remove any of the following config headers, then
1788 dnl you MUST also update Makefile so that the variable FilesToConfig
1789 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1790 dnl files can be updated automatically when their *.in sources change.
1791 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1792 AH_TOP([#ifndef CONFIG_H
1793 #define CONFIG_H])
1794 AH_BOTTOM([#endif])
1795
1796 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1797 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1798 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1799 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1800 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1801
1802 dnl Configure the makefile's configuration data
1803 AC_CONFIG_FILES([Makefile.config])
1804
1805 dnl Configure the RPM spec file for LLVM
1806 AC_CONFIG_FILES([llvm.spec])
1807
1808 dnl Configure doxygen's configuration file
1809 AC_CONFIG_FILES([docs/doxygen.cfg])
1810
1811 dnl Configure clang, if present
1812 if test "${clang_src_root}" = ""; then
1813   clang_src_root="$srcdir/tools/clang"
1814 fi
1815 if test -f ${clang_src_root}/README.txt; then
1816   dnl Use variables to stay under 80 columns.
1817   configh="include/clang/Config/config.h"
1818   doxy="docs/doxygen.cfg"
1819   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
1820   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
1821 fi
1822
1823 dnl OCaml findlib META file
1824 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1825
1826 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
1827 test "x$program_prefix" = "xNONE" && program_prefix=""
1828 AC_SUBST([program_prefix])
1829
1830
1831 dnl Do special configuration of Makefiles
1832 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1833 AC_CONFIG_MAKEFILE(Makefile)
1834 AC_CONFIG_MAKEFILE(Makefile.common)
1835 AC_CONFIG_MAKEFILE(examples/Makefile)
1836 AC_CONFIG_MAKEFILE(lib/Makefile)
1837 AC_CONFIG_MAKEFILE(runtime/Makefile)
1838 AC_CONFIG_MAKEFILE(test/Makefile)
1839 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1840 AC_CONFIG_MAKEFILE(unittests/Makefile)
1841 AC_CONFIG_MAKEFILE(tools/Makefile)
1842 AC_CONFIG_MAKEFILE(utils/Makefile)
1843 AC_CONFIG_MAKEFILE(projects/Makefile)
1844 AC_CONFIG_MAKEFILE(bindings/Makefile)
1845 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1846
1847 dnl Finally, crank out the output
1848 AC_OUTPUT