autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.0cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  80       *)
  81         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  82         ;;
  83     esac
  84   fi
  85 done
  86
  87 dnl===-----------------------------------------------------------------------===
  88 dnl===
  89 dnl=== SECTION 2: Architecture, target, and host checks
  90 dnl===
  91 dnl===-----------------------------------------------------------------------===
  92
  93 dnl Check the target for which we're compiling and the host that will do the
  94 dnl compilations. This will tell us which LLVM compiler will be used for
  95 dnl compiling SSA into object code. This needs to be done early because
  96 dnl following tests depend on it.
  97 AC_CANONICAL_TARGET
  98
  99 dnl Determine the platform type and cache its value. This helps us configure
 100 dnl the System library to the correct build platform.
 101 AC_CACHE_CHECK([type of operating system we're going to host on],
 102                [llvm_cv_os_type],
 103 [case $host in
 104   *-*-aix*)
 105     llvm_cv_link_all_option="-Wl,--whole-archive"
 106     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 107     llvm_cv_os_type="AIX"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-irix*)
 110     llvm_cv_link_all_option="-Wl,--whole-archive"
 111     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 112     llvm_cv_os_type="IRIX"
 113     llvm_cv_platform_type="Unix" ;;
 114   *-*-cygwin*)
 115     llvm_cv_link_all_option="-Wl,--whole-archive"
 116     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 117     llvm_cv_os_type="Cygwin"
 118     llvm_cv_platform_type="Unix" ;;
 119   *-*-darwin*)
 120     llvm_cv_link_all_option="-Wl,-all_load"
 121     llvm_cv_link_all_option="-Wl,-noall_load"
 122     llvm_cv_os_type="Darwin"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-freebsd*)
 125     llvm_cv_link_all_option="-Wl,--whole-archive"
 126     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 127     llvm_cv_os_type="FreeBSD"
 128     llvm_cv_platform_type="Unix" ;;
 129   *-*-openbsd*)
 130     llvm_cv_link_all_option="-Wl,--whole-archive"
 131     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 132     llvm_cv_os_type="OpenBSD"
 133     llvm_cv_platform_type="Unix" ;;
 134   *-*-netbsd*)
 135     llvm_cv_link_all_option="-Wl,--whole-archive"
 136     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 137     llvm_cv_os_type="NetBSD"
 138     llvm_cv_platform_type="Unix" ;;
 139   *-*-hpux*)
 140     llvm_cv_link_all_option="-Wl,--whole-archive"
 141     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 142     llvm_cv_os_type="HP-UX"
 143     llvm_cv_platform_type="Unix" ;;
 144   *-*-interix*)
 145     llvm_cv_link_all_option="-Wl,--whole-archive"
 146     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 147     llvm_cv_os_type="Interix"
 148     llvm_cv_platform_type="Unix" ;;
 149   *-*-linux*)
 150     llvm_cv_link_all_option="-Wl,--whole-archive"
 151     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 152     llvm_cv_os_type="Linux"
 153     llvm_cv_platform_type="Unix" ;;
 154   *-*-solaris*)
 155     llvm_cv_link_all_option="-Wl,-z,allextract"
 156     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 157     llvm_cv_os_type="SunOS"
 158     llvm_cv_platform_type="Unix" ;;
 159   *-*-win32*)
 160     llvm_cv_link_all_option="-Wl,--whole-archive"
 161     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 162     llvm_cv_os_type="Win32"
 163     llvm_cv_platform_type="Win32" ;;
 164   *-*-mingw*)
 165     llvm_cv_link_all_option="-Wl,--whole-archive"
 166     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 167     llvm_cv_os_type="MingW"
 168     llvm_cv_platform_type="Win32" ;;
 169   *)
 170     llvm_cv_link_all_option=""
 171     llvm_cv_no_link_all_option=""
 172     llvm_cv_os_type="Unknown"
 173     llvm_cv_platform_type="Unknown" ;;
 174 esac])
 175
 176 dnl Make sure we aren't attempting to configure for an unknown system
 177 if test "$llvm_cv_os_type" = "Unknown" ; then
 178   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 179 fi
 180
 181 dnl Set the "OS" Makefile variable based on the platform type so the
 182 dnl makefile can configure itself to specific build hosts
 183 AC_SUBST(OS,$llvm_cv_os_type)
 184
 185 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 186 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 187 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 188
 189 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 190 dnl This is used by lib/System to determine the basic kind of implementation
 191 dnl to use.
 192 case $llvm_cv_platform_type in
 193   Unix)
 194     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 195     AC_SUBST(LLVM_ON_UNIX,[1])
 196     AC_SUBST(LLVM_ON_WIN32,[0])
 197     ;;
 198   Win32)
 199     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 200     AC_SUBST(LLVM_ON_UNIX,[0])
 201     AC_SUBST(LLVM_ON_WIN32,[1])
 202     ;;
 203 esac
 204
 205 dnl Determine what our target architecture is and configure accordingly.
 206 dnl This will allow Makefiles to make a distinction between the hardware and
 207 dnl the OS.
 208 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 209 [case $target in
 210   i?86-*)                 llvm_cv_target_arch="x86" ;;
 211   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 212   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 213   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 214   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 215   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 216   arm-*)                  llvm_cv_target_arch="ARM" ;;
 217   *)                      llvm_cv_target_arch="Unknown" ;;
 218 esac])
 219
 220 if test "$llvm_cv_target_arch" = "Unknown" ; then
 221   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 222 fi
 223
 224 dnl Define a substitution, ARCH, for the target architecture
 225 AC_SUBST(ARCH,$llvm_cv_target_arch)
 226
 227 dnl Check for the endianness of the target
 228 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 229
 230 dnl Check for build platform executable suffix if we're crosscompiling
 231 if test "$cross_compiling" = yes; then
 232   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 233   AC_BUILD_EXEEXT
 234 else
 235   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 236 fi
 237
 238 dnl Check to see if there's a "CVS" directory indicating that this build is
 239 dnl being done from a CVS checkout. This sets up several defaults for the
 240 dnl command line switches. When we build with a CVS directory, we get a
 241 dnl debug with assertions turned on. Without, we assume a source release and we
 242 dnl get an optimized build without assertions. See --enable-optimized and
 243 dnl --enable-assertions below
 244 if test -d "CVS" -o -d "${srcdir}/CVS"; then
 245   cvsbuild="yes"
 246   optimize="no"
 247   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 248 else
 249   cvsbuild="no"
 250   optimize="yes"
 251 fi
 252
 253 dnl===-----------------------------------------------------------------------===
 254 dnl===
 255 dnl=== SECTION 3: Command line arguments for the configure script.
 256 dnl===
 257 dnl===-----------------------------------------------------------------------===
 258
 259 dnl --enable-optimized : check whether they want to do an optimized build:
 260 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 261  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 262 if test ${enableval} = "no" ; then
 263   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 264 else
 265   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 266 fi
 267
 268 dnl --enable-assertions : check whether they want to turn on assertions or not:
 269 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 270   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 271 if test ${enableval} = "yes" ; then
 272   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 273 else
 274   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 275 fi
 276
 277 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 278 AC_ARG_ENABLE(debug-runtime,
 279    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 280 if test ${enableval} = "no" ; then
 281   AC_SUBST(DEBUG_RUNTIME,[[]])
 282 else
 283   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 284 fi
 285
 286 dnl --enable-jit: check whether they want to enable the jit
 287 AC_ARG_ENABLE(jit,
 288   AS_HELP_STRING(--enable-jit,
 289                  [Enable Just In Time Compiling (default is YES)]),,
 290   enableval=default)
 291 if test ${enableval} = "no"
 292 then
 293   AC_SUBST(JIT,[[]])
 294 else
 295   case "$llvm_cv_target_arch" in
 296     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 297     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 298     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 299     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 300     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 301     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 302     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 303     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 304   esac
 305 fi
 306
 307 dnl Allow enablement of doxygen generated documentation
 308 AC_ARG_ENABLE(doxygen,
 309               AS_HELP_STRING([--enable-doxygen],
 310                              [Build doxygen documentation (default is NO)]),,
 311                              enableval=default)
 312 case "$enableval" in
 313   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 314   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 315   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 316   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 317 esac
 318
 319 dnl Allow disablement of threads
 320 AC_ARG_ENABLE(threads,
 321               AS_HELP_STRING([--enable-threads],
 322                              [Use threads if available (default is YES)]),,
 323                              enableval=default)
 324 case "$enableval" in
 325   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 326   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 327   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 328   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 329 esac
 330 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 331
 332 dnl Allow building with position independent code
 333 AC_ARG_ENABLE(pic,
 334   AS_HELP_STRING([--enable-pic],
 335                  [Build LLVM with Position Independent Code (default is NO)]),,
 336                  enableval=default)
 337 case "$enableval" in
 338   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 339   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 340   default) AC_SUBST(ENABLE_PIC,[0]) ;;
 341   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 342 esac
 343 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 344                    [Define if position independent code is enabled])
 345
 346 dnl Allow specific targets to be specified for building (or not)
 347 TARGETS_TO_BUILD=""
 348 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 349     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 350     enableval=all)
 351 case "$enableval" in
 352   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM" ;;
 353   host-only)
 354     case "$llvm_cv_target_arch" in
 355       x86)     TARGETS_TO_BUILD="X86" ;;
 356       x86_64)  TARGETS_TO_BUILD="X86" ;;
 357       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 358       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 359       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 360       IA64)    TARGETS_TO_BUILD="IA64" ;;
 361       ARM)     TARGETS_TO_BUILD="ARM" ;;
 362       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 363     esac
 364     ;;
 365   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 366       case "$a_target" in
 367         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 368         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 369         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 370         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 371         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 372         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 373         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 374         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 375       esac
 376   done
 377   ;;
 378 esac
 379 TARGETS_TO_BUILD="CBackend MSIL $TARGETS_TO_BUILD"
 380 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 381
 382 dnl Prevent the CBackend from using printf("%a") for floating point so older
 383 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 384 dnl can still compile the CBE's output
 385 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 386   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 387   enableval=default)
 388 case "$enableval" in
 389   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 390   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 391   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 392   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 393 esac
 394 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 395                    [Define if CBE is enabled for printf %a output])
 396
 397 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 398 AC_ARG_WITH(llvmgccdir,
 399   AS_HELP_STRING([--with-llvmgccdir],
 400     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 401     withval=default)
 402 case "$withval" in
 403   default) WITH_LLVMGCCDIR=default ;;
 404   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 405   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 406 esac
 407
 408 dnl Specify extra build options
 409 AC_ARG_WITH(extra-options,
 410   AS_HELP_STRING([--with-extra-options],
 411                  [Specify addtional options to compile LLVM with]),,
 412                  withval=default)
 413 case "$withval" in
 414   default) EXTRA_OPTIONS= ;;
 415   *) EXTRA_OPTIONS=$withval ;;
 416 esac
 417 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 418
 419 dnl===-----------------------------------------------------------------------===
 420 dnl===
 421 dnl=== SECTION 4: Check for programs we need and that they are the right version
 422 dnl===
 423 dnl===-----------------------------------------------------------------------===
 424
 425 dnl Check for compilation tools
 426 AC_PROG_CPP
 427 AC_PROG_CC(gcc)
 428 AC_PROG_CXX(g++)
 429 AC_PROG_FLEX
 430 AC_PROG_BISON
 431
 432 AC_PROG_NM
 433 AC_SUBST(NM)
 434
 435 dnl Check for the tools that the makefiles require
 436 AC_CHECK_GNU_MAKE
 437 AC_PROG_LN_S
 438 AC_PATH_PROG(CMP, [cmp], [cmp])
 439 AC_PATH_PROG(CP, [cp], [cp])
 440 AC_PATH_PROG(DATE, [date], [date])
 441 AC_PATH_PROG(FIND, [find], [find])
 442 AC_PATH_PROG(GREP, [grep], [grep])
 443 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 444 AC_PATH_PROG(MV,   [mv],   [mv])
 445 AC_PROG_RANLIB
 446 AC_PATH_PROG(RM,   [rm],   [rm])
 447 AC_PATH_PROG(SED,  [sed],  [sed])
 448 AC_PATH_PROG(TAR,  [tar],  [gtar])
 449 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 450
 451 dnl Looking for misc. graph plotting software
 452 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 453 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 454   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 455   dnl If we're targeting for mingw we should emit windows paths, not msys
 456   if test "$llvm_cv_os_type" = "MingW" ; then
 457     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 458   fi
 459   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 460    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 461 fi
 462 AC_PATH_PROG(DOT, [dot], [echo dot])
 463 if test "$DOT" != "echo dot" ; then
 464   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 465   dnl If we're targeting for mingw we should emit windows paths, not msys
 466   if test "$llvm_cv_os_type" = "MingW" ; then
 467     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 468   fi
 469   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 470    [Define to path to dot program if found or 'echo dot' otherwise])
 471 fi
 472 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 473 if test "$GV" != "echo gv" ; then
 474   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 475   dnl If we're targeting for mingw we should emit windows paths, not msys
 476   if test "$llvm_cv_os_type" = "MingW" ; then
 477     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 478   fi
 479   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 480    [Define to path to gv program if found or 'echo gv' otherwise])
 481 fi
 482 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 483 if test "$DOTTY" != "echo dotty" ; then
 484   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 485   dnl If we're targeting for mingw we should emit windows paths, not msys
 486   if test "$llvm_cv_os_type" = "MingW" ; then
 487     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 488   fi
 489   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 490    [Define to path to dotty program if found or 'echo dotty' otherwise])
 491 fi
 492
 493 dnl Look for a sufficiently recent version of Perl.
 494 LLVM_PROG_PERL([5.006])
 495 AC_SUBST(PERL)
 496 if test x"$PERL" = xnone; then
 497    AC_SUBST(HAVE_PERL,0)
 498 else
 499    AC_SUBST(HAVE_PERL,1)
 500 fi
 501
 502 dnl Find the install program
 503 AC_PROG_INSTALL
 504
 505 dnl Checks for documentation and testing tools that we can do without. If these
 506 dnl are not found then they are set to "true" which always succeeds but does
 507 dnl nothing. This just lets the build output show that we could have done
 508 dnl something if the tool was available.
 509 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 510 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 511 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 512 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 513 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 514 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 515 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 516 DJ_AC_PATH_TCLSH
 517 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 518
 519 dnl Determine if the linker supports the -R option.
 520 AC_LINK_USE_R
 521
 522 dnl Check for libtool and the library that has dlopen function (which must come
 523 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 524 dnl libtool).
 525 AC_LIBTOOL_DLOPEN
 526 AC_LIB_LTDL
 527 AC_PROG_LIBTOOL
 528
 529 if test "$lt_cv_dlopen_self" = "yes" ; then
 530   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 531               [Define if dlopen(0) will open the symbols of the program])
 532 fi
 533
 534 dnl Check if we know how to tell etags we are using C++:
 535 etags_version=`$ETAGS --version 2>&1`
 536 case "$etags_version" in
 537         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 538         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 539         *) ETAGSFLAGS="" ;;
 540 esac
 541 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 542
 543 if test "$WITH_LLVMGCCDIR" = "default" ; then
 544   LLVMGCC="llvm-gcc${EXEEXT}"
 545   LLVMGXX="llvm-g++${EXEEXT}"
 546   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 547   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 548 else
 549   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 550   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 551   AC_SUBST(LLVMGCC,$LLVMGCC)
 552   AC_SUBST(LLVMGXX,$LLVMGXX)
 553 fi
 554
 555 AC_MSG_CHECKING([tool compatibility])
 556
 557 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 558 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 559 dnl to support those options.
 560 dnl "icc" emits gcc signatures
 561 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 562 ICC=no
 563 IXX=no
 564 case $CC in
 565   icc*|icpc*)
 566     ICC=yes
 567     IXX=yes
 568     ;;
 569    *)
 570     ;;
 571 esac
 572
 573 if test "$GCC" != "yes" && test "$ICC" != "yes"
 574 then
 575   AC_MSG_ERROR([gcc|icc required but not found])
 576 fi
 577
 578 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 579 if test "$GXX" != "yes" && test "$IXX" != "yes"
 580 then
 581   AC_MSG_ERROR([g++|icc required but not found])
 582 fi
 583
 584 dnl Verify that GCC is version 3.0 or higher
 585 if test "$GCC" = "yes"
 586 then
 587   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 588   if test "$gccmajor" -lt "3"
 589   then
 590     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 591   fi
 592 fi
 593
 594 dnl Check for GNU Make.  We use its extensions, so don't build without it
 595 if test -z "$llvm_cv_gnu_make_command"
 596 then
 597   AC_MSG_ERROR([GNU Make required but not found])
 598 fi
 599
 600 dnl Tool compatibility is okay if we make it here.
 601 AC_MSG_RESULT([ok])
 602
 603 dnl===-----------------------------------------------------------------------===
 604 dnl===
 605 dnl=== SECTION 5: Check for libraries
 606 dnl===
 607 dnl===-----------------------------------------------------------------------===
 608
 609 dnl libelf is for sparc only; we can ignore it if we don't have it
 610 AC_CHECK_LIB(elf, elf_begin)
 611 AC_CHECK_LIB(m,sin)
 612 if test "$llvm_cv_os_type" = "MingW" ; then
 613   AC_CHECK_LIB(imagehlp, main)
 614   AC_CHECK_LIB(psapi, main)
 615 fi
 616
 617 dnl lt_dlopen may be required for plugin support.
 618 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 619               [Define if lt_dlopen() is available on this platform]),
 620               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 621                            not be available]))
 622
 623 dnl dlopen() is required for plugin support.
 624 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 625                [Define if dlopen() is available on this platform.]),
 626                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 627
 628 dnl mallinfo is optional; the code can compile (minus features) without it
 629 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 630                [Define if mallinfo() is available on this platform.]))
 631
 632 dnl pthread locking functions are optional - but llvm will not be thread-safe
 633 dnl without locks.
 634 if test "$ENABLE_THREADS" -eq 1 ; then
 635   AC_CHECK_LIB(pthread,pthread_mutex_init)
 636   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 637                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 638                            [Have pthread_mutex_lock]))
 639 fi
 640
 641 dnl Allow extra x86-disassembler library
 642 AC_ARG_WITH(udis86,
 643   AS_HELP_STRING([--with-udis86=<path>],
 644     [Use udis86 external x86 disassembler library]),
 645     [
 646       AC_SUBST(USE_UDIS86, [1])
 647       case "$withval" in
 648         /usr/lib|yes) ;;
 649         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 650       esac
 651       AC_CHECK_LIB(udis86, ud_init, [], [
 652         echo "Error! You need to have libudis86 around."
 653         exit -1
 654       ])
 655     ],
 656     AC_SUBST(USE_UDIS86, [0]))
 657 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 658                    [Define if use udis86 library])
 659
 660 dnl===-----------------------------------------------------------------------===
 661 dnl===
 662 dnl=== SECTION 6: Check for header files
 663 dnl===
 664 dnl===-----------------------------------------------------------------------===
 665
 666 dnl First, use autoconf provided macros for specific headers that we need
 667 dnl We don't check for ancient stuff or things that are guaranteed to be there
 668 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 669 dnl Generally we're looking for POSIX headers.
 670 AC_HEADER_DIRENT
 671 AC_HEADER_MMAP_ANONYMOUS
 672 AC_HEADER_STAT
 673 AC_HEADER_STDC
 674 AC_HEADER_SYS_WAIT
 675 AC_HEADER_TIME
 676
 677 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 678 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 679 AC_CHECK_HEADERS([windows.h sys/mman.h sys/param.h sys/resource.h sys/time.h])
 680 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 681 if test "$ENABLE_THREADS" -eq 1 ; then
 682   AC_CHECK_HEADER(pthread.h,
 683                   AC_SUBST(HAVE_PTHREAD, 1),
 684                    AC_SUBST(HAVE_PTHREAD, 0))
 685 else
 686   AC_SUBST(HAVE_PTHREAD, 0)
 687 fi
 688
 689 dnl===-----------------------------------------------------------------------===
 690 dnl===
 691 dnl=== SECTION 7: Check for types and structures
 692 dnl===
 693 dnl===-----------------------------------------------------------------------===
 694
 695 AC_HUGE_VAL_CHECK
 696 AC_TYPE_PID_T
 697 AC_TYPE_SIZE_T
 698 AC_TYPE_SIGNAL
 699 AC_STRUCT_TM
 700 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 701 AC_CHECK_TYPES([uint64_t],,
 702          AC_CHECK_TYPES([u_int64_t],,
 703          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 704
 705 dnl===-----------------------------------------------------------------------===
 706 dnl===
 707 dnl=== SECTION 8: Check for specific functions needed
 708 dnl===
 709 dnl===-----------------------------------------------------------------------===
 710
 711 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 712 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday])
 713 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 714 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 715 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 716 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 717 AC_C_PRINTF_A
 718 AC_FUNC_ALLOCA
 719 AC_FUNC_RAND48
 720
 721 dnl Check for variations in the Standard C++ library and STL. These macros are
 722 dnl provided by LLVM in the autoconf/m4 directory.
 723 AC_CXX_HAVE_HASH_MAP
 724 AC_CXX_HAVE_HASH_SET
 725 AC_CXX_HAVE_STD_ITERATOR
 726 AC_CXX_HAVE_BI_ITERATOR
 727 AC_CXX_HAVE_FWD_ITERATOR
 728 AC_FUNC_ISNAN
 729 AC_FUNC_ISINF
 730
 731 dnl Check for mmap support.We also need to know if /dev/zero is required to
 732 dnl be opened for allocating RWX memory.
 733 dnl Make sure we aren't attempting to configure for an unknown system
 734 if test "$llvm_cv_platform_type" = "Unix" ; then
 735   AC_FUNC_MMAP
 736   AC_FUNC_MMAP_FILE
 737   AC_NEED_DEV_ZERO_FOR_MMAP
 738
 739   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 740   then
 741     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 742   fi
 743   if test "$ac_cv_func_mmap_file" = "no"
 744   then
 745     AC_MSG_WARN([mmap() of files required but not found])
 746   fi
 747 fi
 748
 749 dnl===-----------------------------------------------------------------------===
 750 dnl===
 751 dnl=== SECTION 9: Additional checks, variables, etc.
 752 dnl===
 753 dnl===-----------------------------------------------------------------------===
 754
 755 dnl See if the llvm-gcc executable can compile to LLVM assembly
 756 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 757 [llvm_cv_llvmgcc_sanity="no"
 758 if test -x "$LLVMGCC" ; then
 759   cp /dev/null conftest.c
 760   "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
 761   if test $? -eq 0 ; then
 762     llvm_cv_llvmgcc_sanity="yes"
 763   fi
 764   rm conftest.c
 765 fi])
 766
 767 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 768 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 769   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 770   AC_SUBST(LLVMCC1,$llvmcc1path)
 771   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 772   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 773   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 774   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 775   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 776   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 777   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 778   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 779   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 780   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 781 fi
 782
 783 dnl Propagate the shared library extension that the libltdl checks did to
 784 dnl the Makefiles so we can use it there too
 785 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 786
 787 # Translate the various configuration directories and other basic
 788 # information into substitutions that will end up in Makefile.config.in
 789 # that these configured values can be used by the makefiles
 790 if test "${prefix}" = "NONE" ; then
 791   prefix="/usr/local"
 792 fi
 793 eval LLVM_PREFIX="${prefix}";
 794 eval LLVM_BINDIR="${prefix}/bin";
 795 eval LLVM_LIBDIR="${prefix}/lib";
 796 eval LLVM_DATADIR="${prefix}/share/llvm";
 797 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 798 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 799 eval LLVM_INCLUDEDIR="${prefix}/include";
 800 eval LLVM_INFODIR="${prefix}/info";
 801 eval LLVM_MANDIR="${prefix}/man";
 802 LLVM_CONFIGTIME=`date`
 803 AC_SUBST(LLVM_PREFIX)
 804 AC_SUBST(LLVM_BINDIR)
 805 AC_SUBST(LLVM_LIBDIR)
 806 AC_SUBST(LLVM_DATADIR)
 807 AC_SUBST(LLVM_DOCSDIR)
 808 AC_SUBST(LLVM_ETCDIR)
 809 AC_SUBST(LLVM_INCLUDEDIR)
 810 AC_SUBST(LLVM_INFODIR)
 811 AC_SUBST(LLVM_MANDIR)
 812 AC_SUBST(LLVM_CONFIGTIME)
 813
 814 # Place the various directores into the config.h file as #defines so that we
 815 # can know about the installation paths within LLVM.
 816 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 817                    [Installation prefix directory])
 818 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 819                    [Installation directory for binary executables])
 820 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 821                    [Installation directory for libraries])
 822 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 823                    [Installation directory for data files])
 824 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 825                    [Installation directory for documentation])
 826 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 827                    [Installation directory for config files])
 828 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 829                    [Installation directory for include files])
 830 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 831                    [Installation directory for .info files])
 832 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 833                    [Installation directory for man pages])
 834 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 835                    [Time at which LLVM was configured])
 836
 837 dnl===-----------------------------------------------------------------------===
 838 dnl===
 839 dnl=== SECTION 10: Specify the output files and generate it
 840 dnl===
 841 dnl===-----------------------------------------------------------------------===
 842
 843 dnl Configure header files
 844 dnl WARNING: dnl If you add or remove any of the following config headers, then
 845 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 846 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 847 dnl files can be updated automatically when their *.in sources change.
 848 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 849 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 850 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 851 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 852 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 853
 854 dnl Configure the makefile's configuration data
 855 AC_CONFIG_FILES([Makefile.config])
 856
 857 dnl Configure the RPM spec file for LLVM
 858 AC_CONFIG_FILES([llvm.spec])
 859
 860 dnl Configure doxygen's configuration file
 861 AC_CONFIG_FILES([docs/doxygen.cfg])
 862
 863 dnl Do the first stage of configuration for llvm-config.in.
 864 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 865
 866 dnl Do special configuration of Makefiles
 867 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 868 AC_CONFIG_MAKEFILE(Makefile)
 869 AC_CONFIG_MAKEFILE(Makefile.common)
 870 AC_CONFIG_MAKEFILE(examples/Makefile)
 871 AC_CONFIG_MAKEFILE(lib/Makefile)
 872 AC_CONFIG_MAKEFILE(runtime/Makefile)
 873 AC_CONFIG_MAKEFILE(test/Makefile)
 874 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 875 AC_CONFIG_MAKEFILE(tools/Makefile)
 876 AC_CONFIG_MAKEFILE(utils/Makefile)
 877 AC_CONFIG_MAKEFILE(projects/Makefile)
 878
 879 dnl Finally, crank out the output
 880 AC_OUTPUT
 881