autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.8svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2010 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65
  66 dnl
  67 dnl One tricky part of doing this is that some projects depend upon other
  68 dnl projects.  For example, several projects rely upon the LLVM test suite.
  69 dnl We want to configure those projects first so that their object trees are
  70 dnl created before running the configure scripts of projects that depend upon
  71 dnl them.
  72 dnl
  73
  74 dnl Several projects use llvm-gcc, so configure that first
  75 if test -d ${srcdir}/projects/llvm-gcc ; then
  76   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  77 fi
  78
  79 dnl Several projects use the LLVM test suite, so configure it next.
  80 if test -d ${srcdir}/projects/test-suite ; then
  81   AC_CONFIG_SUBDIRS([projects/test-suite])
  82 fi
  83
  84 dnl llvm-test is the old name of the test-suite, kept here for backwards
  85 dnl compatibility
  86 if test -d ${srcdir}/projects/llvm-test ; then
  87   AC_CONFIG_SUBDIRS([projects/llvm-test])
  88 fi
  89
  90 dnl Some projects use poolalloc; configure that next
  91 if test -d ${srcdir}/projects/poolalloc ; then
  92   AC_CONFIG_SUBDIRS([projects/poolalloc])
  93 fi
  94
  95 if test -d ${srcdir}/projects/llvm-poolalloc ; then
  96   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
  97 fi
  98
  99 dnl Check for all other projects
 100 for i in `ls ${srcdir}/projects`
 101 do
 102   if test -d ${srcdir}/projects/${i} ; then
 103     case ${i} in
 104       CVS) ;;
 105       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 106       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 107       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 108       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 109       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 110       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 111       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 112       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 113       *)
 114         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 115         ;;
 116     esac
 117   fi
 118 done
 119
 120 dnl===-----------------------------------------------------------------------===
 121 dnl===
 122 dnl=== SECTION 2: Architecture, target, and host checks
 123 dnl===
 124 dnl===-----------------------------------------------------------------------===
 125
 126 dnl Check the target for which we're compiling and the host that will do the
 127 dnl compilations. This will tell us which LLVM compiler will be used for
 128 dnl compiling SSA into object code. This needs to be done early because
 129 dnl following tests depend on it.
 130 AC_CANONICAL_TARGET
 131
 132 dnl Determine the platform type and cache its value. This helps us configure
 133 dnl the System library to the correct build platform.
 134 AC_CACHE_CHECK([type of operating system we're going to host on],
 135                [llvm_cv_os_type],
 136 [case $host in
 137   *-*-aix*)
 138     llvm_cv_link_all_option="-Wl,--whole-archive"
 139     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 140     llvm_cv_os_type="AIX"
 141     llvm_cv_platform_type="Unix" ;;
 142   *-*-irix*)
 143     llvm_cv_link_all_option="-Wl,--whole-archive"
 144     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 145     llvm_cv_os_type="IRIX"
 146     llvm_cv_platform_type="Unix" ;;
 147   *-*-cygwin*)
 148     llvm_cv_link_all_option="-Wl,--whole-archive"
 149     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 150     llvm_cv_os_type="Cygwin"
 151     llvm_cv_platform_type="Unix" ;;
 152   *-*-darwin*)
 153     llvm_cv_link_all_option="-Wl,-all_load"
 154     llvm_cv_no_link_all_option="-Wl,-noall_load"
 155     llvm_cv_os_type="Darwin"
 156     llvm_cv_platform_type="Unix" ;;
 157   *-*-freebsd*)
 158     llvm_cv_link_all_option="-Wl,--whole-archive"
 159     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 160     llvm_cv_os_type="FreeBSD"
 161     llvm_cv_platform_type="Unix" ;;
 162   *-*-openbsd*)
 163     llvm_cv_link_all_option="-Wl,--whole-archive"
 164     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 165     llvm_cv_os_type="OpenBSD"
 166     llvm_cv_platform_type="Unix" ;;
 167   *-*-netbsd*)
 168     llvm_cv_link_all_option="-Wl,--whole-archive"
 169     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 170     llvm_cv_os_type="NetBSD"
 171     llvm_cv_platform_type="Unix" ;;
 172   *-*-dragonfly*)
 173     llvm_cv_link_all_option="-Wl,--whole-archive"
 174     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 175     llvm_cv_os_type="DragonFly"
 176     llvm_cv_platform_type="Unix" ;;
 177   *-*-hpux*)
 178     llvm_cv_link_all_option="-Wl,--whole-archive"
 179     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 180     llvm_cv_os_type="HP-UX"
 181     llvm_cv_platform_type="Unix" ;;
 182   *-*-interix*)
 183     llvm_cv_link_all_option="-Wl,--whole-archive"
 184     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 185     llvm_cv_os_type="Interix"
 186     llvm_cv_platform_type="Unix" ;;
 187   *-*-linux*)
 188     llvm_cv_link_all_option="-Wl,--whole-archive"
 189     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 190     llvm_cv_os_type="Linux"
 191     llvm_cv_platform_type="Unix" ;;
 192   *-*-solaris*)
 193     llvm_cv_link_all_option="-Wl,-z,allextract"
 194     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 195     llvm_cv_os_type="SunOS"
 196     llvm_cv_platform_type="Unix" ;;
 197   *-*-auroraux*)
 198     llvm_cv_link_all_option="-Wl,-z,allextract"
 199     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 200     llvm_cv_os_type="AuroraUX"
 201     llvm_cv_platform_type="Unix" ;;
 202   *-*-win32*)
 203     llvm_cv_link_all_option="-Wl,--whole-archive"
 204     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 205     llvm_cv_os_type="Win32"
 206     llvm_cv_platform_type="Win32" ;;
 207   *-*-mingw*)
 208     llvm_cv_link_all_option="-Wl,--whole-archive"
 209     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 210     llvm_cv_os_type="MingW"
 211     llvm_cv_platform_type="Win32" ;;
 212   *-*-haiku*)
 213     llvm_cv_link_all_option="-Wl,--whole-archive"
 214     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 215     llvm_cv_os_type="Haiku"
 216     llvm_cv_platform_type="Unix" ;;
 217   *-unknown-eabi*)
 218     llvm_cv_link_all_option="-Wl,--whole-archive"
 219     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 220     llvm_cv_os_type="Freestanding"
 221     llvm_cv_platform_type="Unix" ;;
 222   *-unknown-elf*)
 223     llvm_cv_link_all_option="-Wl,--whole-archive"
 224     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 225     llvm_cv_os_type="Freestanding"
 226     llvm_cv_platform_type="Unix" ;;
 227   *)
 228     llvm_cv_link_all_option=""
 229     llvm_cv_no_link_all_option=""
 230     llvm_cv_os_type="Unknown"
 231     llvm_cv_platform_type="Unknown" ;;
 232 esac])
 233
 234 AC_CACHE_CHECK([type of operating system we're going to target],
 235                [llvm_cv_target_os_type],
 236 [case $target in
 237   *-*-aix*)
 238     llvm_cv_target_os_type="AIX" ;;
 239   *-*-irix*)
 240     llvm_cv_target_os_type="IRIX" ;;
 241   *-*-cygwin*)
 242     llvm_cv_target_os_type="Cygwin" ;;
 243   *-*-darwin*)
 244     llvm_cv_target_os_type="Darwin" ;;
 245   *-*-freebsd*)
 246     llvm_cv_target_os_type="FreeBSD" ;;
 247   *-*-openbsd*)
 248     llvm_cv_target_os_type="OpenBSD" ;;
 249   *-*-netbsd*)
 250     llvm_cv_target_os_type="NetBSD" ;;
 251   *-*-dragonfly*)
 252     llvm_cv_target_os_type="DragonFly" ;;
 253   *-*-hpux*)
 254     llvm_cv_target_os_type="HP-UX" ;;
 255   *-*-interix*)
 256     llvm_cv_target_os_type="Interix" ;;
 257   *-*-linux*)
 258     llvm_cv_target_os_type="Linux" ;;
 259   *-*-solaris*)
 260     llvm_cv_target_os_type="SunOS" ;;
 261   *-*-auroraux*)
 262     llvm_cv_target_os_type="AuroraUX" ;;
 263   *-*-win32*)
 264     llvm_cv_target_os_type="Win32" ;;
 265   *-*-mingw*)
 266     llvm_cv_target_os_type="MingW" ;;
 267   *-*-haiku*)
 268     llvm_cv_target_os_type="Haiku" ;;
 269   *-unknown-eabi*)
 270     llvm_cv_target_os_type="Freestanding" ;;
 271   *)
 272     llvm_cv_target_os_type="Unknown" ;;
 273 esac])
 274
 275 dnl Make sure we aren't attempting to configure for an unknown system
 276 if test "$llvm_cv_os_type" = "Unknown" ; then
 277   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 278 fi
 279
 280 dnl Set the "OS" Makefile variable based on the platform type so the
 281 dnl makefile can configure itself to specific build hosts
 282 AC_SUBST(OS,$llvm_cv_os_type)
 283 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 284 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 285
 286 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 287 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 288 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 289
 290 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 291 dnl This is used by lib/System to determine the basic kind of implementation
 292 dnl to use.
 293 case $llvm_cv_platform_type in
 294   Unix)
 295     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 296     AC_SUBST(LLVM_ON_UNIX,[1])
 297     AC_SUBST(LLVM_ON_WIN32,[0])
 298     ;;
 299   Win32)
 300     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 301     AC_SUBST(LLVM_ON_UNIX,[0])
 302     AC_SUBST(LLVM_ON_WIN32,[1])
 303     ;;
 304 esac
 305
 306 dnl Determine what our target architecture is and configure accordingly.
 307 dnl This will allow Makefiles to make a distinction between the hardware and
 308 dnl the OS.
 309 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 310 [case $target in
 311   i?86-*)                 llvm_cv_target_arch="x86" ;;
 312   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 313   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 314   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 315   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 316   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 317   mips-*)                 llvm_cv_target_arch="Mips" ;;
 318   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 319   xcore-*)                llvm_cv_target_arch="XCore" ;;
 320   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 321   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 322   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 323   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 324   *)                      llvm_cv_target_arch="Unknown" ;;
 325 esac])
 326
 327 if test "$llvm_cv_target_arch" = "Unknown" ; then
 328   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 329 fi
 330
 331 # Determine the LLVM native architecture for the target
 332 case "$llvm_cv_target_arch" in
 333     x86)     LLVM_NATIVE_ARCH="X86" ;;
 334     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 335     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 336 esac
 337
 338 dnl Define a substitution, ARCH, for the target architecture
 339 AC_SUBST(ARCH,$llvm_cv_target_arch)
 340
 341 dnl Check for the endianness of the target
 342 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 343
 344 dnl Check for build platform executable suffix if we're crosscompiling
 345 if test "$cross_compiling" = yes; then
 346   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 347   AC_BUILD_EXEEXT
 348   ac_build_prefix=${build_alias}-
 349   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 350   if test -z "$BUILD_CXX"; then
 351      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 352      if test -z "$BUILD_CXX"; then
 353        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 354      fi
 355   fi
 356 else
 357   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 358 fi
 359
 360 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 361 dnl that this build is being done from a checkout. This sets up several
 362 dnl defaults for the command line switches. When we build with a CVS directory,
 363 dnl we get a debug with assertions turned on. Without, we assume a source
 364 dnl release and we get an optimized build without assertions.
 365 dnl See --enable-optimized and --enable-assertions below
 366 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 367   cvsbuild="yes"
 368   optimize="no"
 369   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 370 else
 371   cvsbuild="no"
 372   optimize="yes"
 373 fi
 374
 375 dnl===-----------------------------------------------------------------------===
 376 dnl===
 377 dnl=== SECTION 3: Command line arguments for the configure script.
 378 dnl===
 379 dnl===-----------------------------------------------------------------------===
 380
 381 dnl --enable-optimized : check whether they want to do an optimized build:
 382 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 383  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 384 if test ${enableval} = "no" ; then
 385   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 386 else
 387   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 388 fi
 389
 390 dnl --enable-profiling : check whether they want to do a profile build:
 391 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 392  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 393 if test ${enableval} = "no" ; then
 394   AC_SUBST(ENABLE_PROFILING,[[]])
 395 else
 396   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 397 fi
 398
 399 dnl --enable-assertions : check whether they want to turn on assertions or not:
 400 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 401   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 402 if test ${enableval} = "yes" ; then
 403   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 404 else
 405   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 406 fi
 407
 408 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 409 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 410   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 411 if test ${enableval} = "yes" ; then
 412   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 413   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 414 else
 415   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 416   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 417 fi
 418
 419 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 420 AC_ARG_ENABLE(debug-runtime,
 421    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 422 if test ${enableval} = "no" ; then
 423   AC_SUBST(DEBUG_RUNTIME,[[]])
 424 else
 425   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 426 fi
 427
 428 dnl --enable-debug-symbols : should even optimized compiler libraries
 429 dnl have debug symbols?
 430 AC_ARG_ENABLE(debug-symbols,
 431    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 432 if test ${enableval} = "no" ; then
 433   AC_SUBST(DEBUG_SYMBOLS,[[]])
 434 else
 435   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 436 fi
 437
 438 dnl --enable-jit: check whether they want to enable the jit
 439 AC_ARG_ENABLE(jit,
 440   AS_HELP_STRING(--enable-jit,
 441                  [Enable Just In Time Compiling (default is YES)]),,
 442   enableval=default)
 443 if test ${enableval} = "no"
 444 then
 445   AC_SUBST(JIT,[[]])
 446 else
 447   case "$llvm_cv_target_arch" in
 448     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 449     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 450     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 451     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 452     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 453     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 454     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 455     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 456     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 457     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 458     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 459     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 460     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 461     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 462   esac
 463 fi
 464
 465 dnl Allow enablement of doxygen generated documentation
 466 AC_ARG_ENABLE(doxygen,
 467               AS_HELP_STRING([--enable-doxygen],
 468                              [Build doxygen documentation (default is NO)]),,
 469                              enableval=default)
 470 case "$enableval" in
 471   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 472   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 473   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 474   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 475 esac
 476
 477 dnl Allow disablement of threads
 478 AC_ARG_ENABLE(threads,
 479               AS_HELP_STRING([--enable-threads],
 480                              [Use threads if available (default is YES)]),,
 481                              enableval=default)
 482 case "$enableval" in
 483   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 484   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 485   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 486   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 487 esac
 488 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 489
 490 dnl Allow building without position independent code
 491 AC_ARG_ENABLE(pic,
 492   AS_HELP_STRING([--enable-pic],
 493                  [Build LLVM with Position Independent Code (default is YES)]),,
 494                  enableval=default)
 495 case "$enableval" in
 496   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 497   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 498   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 499   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 500 esac
 501 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 502                    [Define if position independent code is enabled])
 503
 504 dnl Allow building a shared library and linking tools against it.
 505 AC_ARG_ENABLE(shared,
 506   AS_HELP_STRING([--enable-shared],
 507                  [Build a shared library and link tools against it (default is NO)]),,
 508                  enableval=default)
 509 case "$enableval" in
 510   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 511   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 512   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 513   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 514 esac
 515
 516 dnl Allow specific targets to be specified for building (or not)
 517 TARGETS_TO_BUILD=""
 518 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 519     [Build specific host targets: all or target1,target2,... Valid targets are:
 520      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu, pic16,
 521      xcore, msp430, systemz, blackfin, cbe, msil, and cpp (default=all)]),,
 522     enableval=all)
 523 if test "$enableval" = host-only ; then
 524   enableval=host
 525 fi
 526 case "$enableval" in
 527   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend MSIL CppBackend MBlaze" ;;
 528   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 529       case "$a_target" in
 530         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 531         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 532         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 533         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 534         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 535         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 536         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 537         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 538         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 539         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 540         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 541         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 542         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 543         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 544         msil)     TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 545         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 546         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 547         host) case "$llvm_cv_target_arch" in
 548             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 549             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 550             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 551             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 552             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 553             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 554             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 555             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 556             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 557             PIC16)       TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 558             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 559             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 560             s390x)       TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 561             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 562             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 563           esac ;;
 564         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 565       esac
 566   done
 567   ;;
 568 esac
 569 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 570
 571 # Determine whether we are building LLVM support for the native architecture.
 572 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 573 for a_target in $TARGETS_TO_BUILD; do
 574   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 575     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 576     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 577       [LLVM architecture name for the native architecture, if available])
 578   fi
 579 done
 580
 581 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 582 # target feature def files.
 583 LLVM_ENUM_TARGETS=""
 584 LLVM_ENUM_ASM_PRINTERS=""
 585 LLVM_ENUM_ASM_PARSERS=""
 586 LLVM_ENUM_DISASSEMBLERS=""
 587 for target_to_build in $TARGETS_TO_BUILD; do
 588   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 589   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 590     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 591   fi
 592   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 593     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 594   fi
 595   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 596     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 597   fi
 598 done
 599 AC_SUBST(LLVM_ENUM_TARGETS)
 600 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 601 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 602 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 603
 604 dnl Prevent the CBackend from using printf("%a") for floating point so older
 605 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 606 dnl can still compile the CBE's output
 607 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 608   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 609   enableval=default)
 610 case "$enableval" in
 611   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 612   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 613   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 614   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 615 esac
 616 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 617                    [Define if CBE is enabled for printf %a output])
 618
 619 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 620 AC_ARG_WITH(llvmgccdir,
 621   AS_HELP_STRING([--with-llvmgccdir],
 622     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 623     withval=default)
 624 case "$withval" in
 625   default) WITH_LLVMGCCDIR=default ;;
 626   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 627   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 628 esac
 629
 630 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 631 AC_ARG_WITH(llvmgcc,
 632   AS_HELP_STRING([--with-llvmgcc],
 633     [Specify location of llvm-gcc driver (default searches PATH)]),
 634     LLVMGCC=$with_llvmgcc
 635       WITH_LLVMGCCDIR="",)
 636
 637 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 638 AC_ARG_WITH(llvmgxx,
 639   AS_HELP_STRING([--with-llvmgxx],
 640     [Specify location of llvm-g++ driver (default searches PATH)]),
 641     LLVMGXX=$with_llvmgxx
 642     WITH_LLVMGCCDIR="",)
 643
 644 if test -n "$LLVMGCC"; then
 645    LLVMGCCCOMMAND="$LLVMGCC"
 646 fi
 647
 648 if test -n "$LLVMGXX"; then
 649    LLVMGXXCOMMAND="$LLVMGXX"
 650 fi
 651
 652 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 653    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 654 fi
 655
 656 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 657    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 658 fi
 659
 660 dnl Allow a specific Clang compiler to be used with this LLVM config.
 661 AC_ARG_WITH(clang,
 662   AS_HELP_STRING([--with-clang],
 663     [Specify location of clang compiler (default is --with-built-clang)]),
 664     [],[with_clang=default])
 665
 666 dnl Enable use of the built Clang.
 667 AC_ARG_WITH(built-clang,
 668   AS_HELP_STRING([--with-built-clang],
 669     [Use the compiled Clang as the LLVM compiler (default=check)]),
 670     [],[with_built_clang=check])
 671
 672 dnl Select the Clang compiler option.
 673 dnl
 674 dnl If --with-clang is given, always honor that; otherwise honor
 675 dnl --with-built-clang, or check if we have the clang sources.
 676 AC_MSG_CHECKING([clang compiler])
 677 WITH_CLANGPATH=""
 678 WITH_BUILT_CLANG=0
 679 if test "$with_clang" != "default"; then
 680    WITH_CLANGPATH="$with_clang"
 681    if ! test -x "$WITH_CLANGPATH"; then
 682      AC_MSG_ERROR([invalid --with-clang, path does not specify an executable])
 683    fi
 684 elif test "$with_built_clang" = "yes"; then
 685    WITH_BUILT_CLANG=1
 686 elif test "$with_built_clang" = "no"; then
 687    WITH_BUILT_CLANG=0
 688 else
 689    if test "$with_built_clang" != "check"; then
 690       AC_MSG_ERROR([invalid value for --with-built-clang.])
 691    fi
 692
 693    if test -f ${srcdir}/tools/clang/README.txt; then
 694      WITH_BUILT_CLANG=1
 695    fi
 696 fi
 697
 698 if ! test -z "$WITH_CLANGPATH"; then
 699    AC_MSG_RESULT([$WITH_CLANGPATH])
 700    WITH_CLANGXXPATH=`"$WITH_CLANGPATH" --print-prog-name=clang++`
 701 elif test "$WITH_BUILT_CLANG" = "1"; then
 702    AC_MSG_RESULT([built])
 703 else
 704    AC_MSG_RESULT([none])
 705 fi
 706 AC_SUBST(CLANGPATH,$WITH_CLANGPATH)
 707 AC_SUBST(CLANGXXPATH,$WITH_CLANGXXPATH)
 708 AC_SUBST(ENABLE_BUILT_CLANG,$WITH_BUILT_CLANG)
 709
 710 dnl Override the option to use for optimized builds.
 711 AC_ARG_WITH(optimize-option,
 712   AS_HELP_STRING([--with-optimize-option],
 713                  [Select the compiler options to use for optimized builds]),,
 714                  withval=default)
 715 AC_MSG_CHECKING([optimization flags])
 716 case "$withval" in
 717   default)
 718     case "$llvm_cv_os_type" in
 719     MingW) optimize_option=-O3 ;;
 720     *)     optimize_option=-O2 ;;
 721     esac ;;
 722   *) optimize_option="$withval" ;;
 723 esac
 724 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 725 AC_MSG_RESULT([$optimize_option])
 726
 727 dnl Specify extra build options
 728 AC_ARG_WITH(extra-options,
 729   AS_HELP_STRING([--with-extra-options],
 730                  [Specify additional options to compile LLVM with]),,
 731                  withval=default)
 732 case "$withval" in
 733   default) EXTRA_OPTIONS= ;;
 734   *) EXTRA_OPTIONS=$withval ;;
 735 esac
 736 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 737
 738 dnl Allow specific bindings to be specified for building (or not)
 739 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 740     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 741     enableval=default)
 742 BINDINGS_TO_BUILD=""
 743 case "$enableval" in
 744   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 745   all ) BINDINGS_TO_BUILD="ocaml" ;;
 746   none | no) BINDINGS_TO_BUILD="" ;;
 747   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 748       case "$a_binding" in
 749         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 750         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 751       esac
 752   done
 753   ;;
 754 esac
 755
 756 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 757 dnl script for bindings/ocaml/configure, except that its auto value depends on
 758 dnl OCAMLC, which is found here to support tests.
 759 AC_ARG_WITH([ocaml-libdir],
 760   [AS_HELP_STRING([--with-ocaml-libdir],
 761     [Specify install location for ocaml bindings (default is stdlib)])],
 762   [],
 763   [withval=auto])
 764 case "$withval" in
 765   auto) with_ocaml_libdir="$withval" ;;
 766   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 767   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 768 esac
 769
 770 AC_ARG_WITH(c-include-dirs,
 771   AS_HELP_STRING([--with-c-include-dirs],
 772     [Colon separated list of directories clang will search for headers]),,
 773     withval="")
 774 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 775                    [Directories clang will search for headers])
 776
 777 AC_ARG_WITH(cxx-include-root,
 778   AS_HELP_STRING([--with-cxx-include-root],
 779     [Directory with the libstdc++ headers.]),,
 780     withval="")
 781 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 782                    [Directory with the libstdc++ headers.])
 783
 784 AC_ARG_WITH(cxx-include-arch,
 785   AS_HELP_STRING([--with-cxx-include-arch],
 786     [Architecture of the libstdc++ headers.]),,
 787     withval="")
 788 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 789                    [Arch the libstdc++ headers.])
 790
 791 AC_ARG_WITH(cxx-include-32bit-dir,
 792   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 793     [32 bit multilib dir.]),,
 794     withval="")
 795 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 796                    [32 bit multilib directory.])
 797
 798 AC_ARG_WITH(cxx-include-64bit-dir,
 799   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 800     [64 bit multilib directory.]),,
 801     withval="")
 802 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 803                    [64 bit multilib directory.])
 804
 805 dnl Allow linking of LLVM with GPLv3 binutils code.
 806 AC_ARG_WITH(binutils-include,
 807   AS_HELP_STRING([--with-binutils-include],
 808     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 809   withval=default)
 810 case "$withval" in
 811   default) WITH_BINUTILS_INCDIR=default ;;
 812   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 813   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 814 esac
 815 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 816   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 817   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 818      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 819      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 820   fi
 821 fi
 822
 823 dnl --enable-libffi : check whether the user wants to turn off libffi:
 824 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 825   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 826   [case "$enableval" in
 827     yes) llvm_cv_enable_libffi="yes" ;;
 828     no)  llvm_cv_enable_libffi="no"  ;;
 829     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 830   esac],
 831   llvm_cv_enable_libffi=no)
 832
 833 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 834 if test "$llvm_cv_os_type" = "Win32" ; then
 835    llvmc_dynamic="yes"
 836 else
 837    llvmc_dynamic="no"
 838 fi
 839
 840 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 841 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 842 --enable-llvmc-dynamic,
 843 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 844 enableval=$llvmc_dynamic)
 845 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 846    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 847 else
 848    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 849 fi
 850
 851 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 852 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 853 --enable-llvmc-dynamic-plugins,
 854 [Enable dynamic LLVMC plugins (default is YES)]),,
 855 enableval=yes)
 856 if test ${enableval} = "yes" ; then
 857    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 858 else
 859    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 860 fi
 861
 862 dnl===-----------------------------------------------------------------------===
 863 dnl===
 864 dnl=== SECTION 4: Check for programs we need and that they are the right version
 865 dnl===
 866 dnl===-----------------------------------------------------------------------===
 867
 868 dnl Check for compilation tools
 869 AC_PROG_CPP
 870 AC_PROG_CC(gcc)
 871 AC_PROG_CXX(g++)
 872
 873 AC_PROG_NM
 874 AC_SUBST(NM)
 875
 876 dnl Check for the tools that the makefiles require
 877 AC_CHECK_GNU_MAKE
 878 AC_PROG_LN_S
 879 AC_PATH_PROG(CMP, [cmp], [cmp])
 880 AC_PATH_PROG(CP, [cp], [cp])
 881 AC_PATH_PROG(DATE, [date], [date])
 882 AC_PATH_PROG(FIND, [find], [find])
 883 AC_PATH_PROG(GREP, [grep], [grep])
 884 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 885 AC_PATH_PROG(MV,   [mv],   [mv])
 886 AC_PROG_RANLIB
 887 AC_CHECK_TOOL(AR, ar, false)
 888 AC_PATH_PROG(RM,   [rm],   [rm])
 889 AC_PATH_PROG(SED,  [sed],  [sed])
 890 AC_PATH_PROG(TAR,  [tar],  [gtar])
 891 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 892
 893 dnl Looking for misc. graph plotting software
 894 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 895 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 896   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 897   dnl If we're targeting for mingw we should emit windows paths, not msys
 898   if test "$llvm_cv_os_type" = "MingW" ; then
 899     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 900   fi
 901   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 902    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 903 fi
 904 AC_PATH_PROG(DOT, [dot], [echo dot])
 905 if test "$DOT" != "echo dot" ; then
 906   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 907   dnl If we're targeting for mingw we should emit windows paths, not msys
 908   if test "$llvm_cv_os_type" = "MingW" ; then
 909     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 910   fi
 911   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 912    [Define to path to dot program if found or 'echo dot' otherwise])
 913 fi
 914 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 915 if test "$FDP" != "echo fdp" ; then
 916   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 917   dnl If we're targeting for mingw we should emit windows paths, not msys
 918   if test "$llvm_cv_os_type" = "MingW" ; then
 919     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 920   fi
 921   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 922    [Define to path to fdp program if found or 'echo fdp' otherwise])
 923 fi
 924 AC_PATH_PROG(NEATO, [neato], [echo neato])
 925 if test "$NEATO" != "echo neato" ; then
 926   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 927   dnl If we're targeting for mingw we should emit windows paths, not msys
 928   if test "$llvm_cv_os_type" = "MingW" ; then
 929     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 930   fi
 931   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 932    [Define to path to neato program if found or 'echo neato' otherwise])
 933 fi
 934 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 935 if test "$TWOPI" != "echo twopi" ; then
 936   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 937   dnl If we're targeting for mingw we should emit windows paths, not msys
 938   if test "$llvm_cv_os_type" = "MingW" ; then
 939     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 940   fi
 941   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 942    [Define to path to twopi program if found or 'echo twopi' otherwise])
 943 fi
 944 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 945 if test "$CIRCO" != "echo circo" ; then
 946   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 947   dnl If we're targeting for mingw we should emit windows paths, not msys
 948   if test "$llvm_cv_os_type" = "MingW" ; then
 949     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 950   fi
 951   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 952    [Define to path to circo program if found or 'echo circo' otherwise])
 953 fi
 954 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 955 if test "$GV" != "echo gv" ; then
 956   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 957   dnl If we're targeting for mingw we should emit windows paths, not msys
 958   if test "$llvm_cv_os_type" = "MingW" ; then
 959     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 960   fi
 961   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 962    [Define to path to gv program if found or 'echo gv' otherwise])
 963 fi
 964 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 965 if test "$DOTTY" != "echo dotty" ; then
 966   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 967   dnl If we're targeting for mingw we should emit windows paths, not msys
 968   if test "$llvm_cv_os_type" = "MingW" ; then
 969     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 970   fi
 971   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 972    [Define to path to dotty program if found or 'echo dotty' otherwise])
 973 fi
 974
 975 dnl Look for a sufficiently recent version of Perl.
 976 LLVM_PROG_PERL([5.006])
 977 AC_SUBST(PERL)
 978 if test x"$PERL" = xnone; then
 979    AC_SUBST(HAVE_PERL,0)
 980    AC_MSG_ERROR([perl is required but was not found, please install it])
 981 else
 982    AC_SUBST(HAVE_PERL,1)
 983 fi
 984
 985 dnl Find the install program
 986 AC_PROG_INSTALL
 987
 988 dnl Checks for documentation and testing tools that we can do without. If these
 989 dnl are not found then they are set to "true" which always succeeds but does
 990 dnl nothing. This just lets the build output show that we could have done
 991 dnl something if the tool was available.
 992 AC_PATH_PROG(BZIP2, [bzip2])
 993 AC_PATH_PROG(DOXYGEN, [doxygen])
 994 AC_PATH_PROG(GROFF, [groff])
 995 AC_PATH_PROG(GZIP, [gzip])
 996 AC_PATH_PROG(POD2HTML, [pod2html])
 997 AC_PATH_PROG(POD2MAN, [pod2man])
 998 AC_PATH_PROG(RUNTEST, [runtest])
 999 DJ_AC_PATH_TCLSH
1000 AC_PATH_PROG(ZIP, [zip])
1001 AC_PATH_PROGS(OCAMLC, [ocamlc])
1002 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1003 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1004 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1005 AC_PATH_PROGS(GAS, [gas as])
1006
1007 dnl Determine whether the linker supports the -R option.
1008 AC_LINK_USE_R
1009
1010 dnl Determine whether the linker supports the -export-dynamic option.
1011 AC_LINK_EXPORT_DYNAMIC
1012
1013 dnl Check for libtool and the library that has dlopen function (which must come
1014 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1015 dnl libtool).
1016 AC_LIBTOOL_DLOPEN
1017 AC_LIB_LTDL
1018
1019 if test "$WITH_LLVMGCCDIR" = "default" ; then
1020   LLVMGCC="llvm-gcc${EXEEXT}"
1021   LLVMGXX="llvm-g++${EXEEXT}"
1022   LLVMGCCCOMMAND="$LLVMGCC"
1023   LLVMGXXCOMMAND="$LLVMGXX"
1024   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1025   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1026   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
1027   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
1028 else
1029   if test -z "$LLVMGCC"; then
1030     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
1031     LLVMGCCCOMMAND="$LLVMGCC"
1032   fi
1033   if test -z "$LLVMGXX"; then
1034     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
1035     LLVMGXXCOMMAND="$LLVMGXX"
1036   fi
1037
1038   AC_SUBST(LLVMGCC,$LLVMGCC)
1039   AC_SUBST(LLVMGXX,$LLVMGXX)
1040   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
1041   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
1042 fi
1043
1044 dnl Select the LLVM capable compiler to use, we default to using llvm-gcc if
1045 dnl found, otherwise clang if available.
1046 AC_ARG_WITH(llvmcc,
1047   AS_HELP_STRING([--with-llvmcc=<name>],
1048     [Choose the LLVM capable compiler to use (llvm-gcc, clang, or none; default=check)]),
1049     [],[with_llvmcc=check])
1050 AC_MSG_CHECKING([LLVM capable compiler])
1051 if test "$with_llvmcc" != "check"; then
1052    if (test "$with_llvmcc" != "llvm-gcc" &&
1053        test "$with_llvmcc" != "clang" &&
1054        test "$with_llvmcc" != "none"); then
1055       AC_MSG_ERROR([invalid value for --with-llvmcc, expected 'llvm-gcc', 'clang', or 'none'.])
1056    fi
1057    WITH_LLVMCC="$with_llvmcc"
1058 elif test -n "$LLVMGCC"; then
1059    WITH_LLVMCC=llvm-gcc
1060 elif test -n "$WITH_CLANGPATH" || test "$WITH_BUILT_CLANG" -ne "0"; then
1061    WITH_LLVMCC=clang
1062 else
1063    WITH_LLVMCC=none
1064 fi
1065 AC_MSG_RESULT([$WITH_LLVMCC])
1066 AC_SUBST(LLVMCC_OPTION,$WITH_LLVMCC)
1067
1068 AC_MSG_CHECKING([tool compatibility])
1069
1070 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1071 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1072 dnl to support those options.
1073 dnl "icc" emits gcc signatures
1074 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1075 ICC=no
1076 IXX=no
1077 case $CC in
1078   icc*|icpc*)
1079     ICC=yes
1080     IXX=yes
1081     ;;
1082    *)
1083     ;;
1084 esac
1085
1086 if test "$GCC" != "yes" && test "$ICC" != "yes"
1087 then
1088   AC_MSG_ERROR([gcc|icc required but not found])
1089 fi
1090
1091 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
1092 if test "$GXX" != "yes" && test "$IXX" != "yes"
1093 then
1094   AC_MSG_ERROR([g++|icc required but not found])
1095 fi
1096
1097 dnl Verify that GCC is version 3.0 or higher
1098 if test "$GCC" = "yes"
1099 then
1100   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1101 #error Unsupported GCC version
1102 #endif
1103 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1104 fi
1105
1106 dnl Check for GNU Make.  We use its extensions, so don't build without it
1107 if test -z "$llvm_cv_gnu_make_command"
1108 then
1109   AC_MSG_ERROR([GNU Make required but not found])
1110 fi
1111
1112 dnl Tool compatibility is okay if we make it here.
1113 AC_MSG_RESULT([ok])
1114
1115 dnl Check optional compiler flags.
1116 AC_MSG_CHECKING([optional compiler flags])
1117 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1118 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1119 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1120
1121 dnl===-----------------------------------------------------------------------===
1122 dnl===
1123 dnl=== SECTION 5: Check for libraries
1124 dnl===
1125 dnl===-----------------------------------------------------------------------===
1126
1127 AC_CHECK_LIB(m,sin)
1128 if test "$llvm_cv_os_type" = "MingW" ; then
1129   AC_CHECK_LIB(imagehlp, main)
1130   AC_CHECK_LIB(psapi, main)
1131 fi
1132
1133 dnl dlopen() is required for plugin support.
1134 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1135                [Define if dlopen() is available on this platform.]),
1136                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1137
1138 dnl libffi is optional; used to call external functions from the interpreter
1139 if test "$llvm_cv_enable_libffi" = "yes" ; then
1140   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1141                  [Define if libffi is available on this platform.]),
1142                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1143 fi
1144
1145 dnl mallinfo is optional; the code can compile (minus features) without it
1146 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1147                [Define if mallinfo() is available on this platform.]))
1148
1149 dnl pthread locking functions are optional - but llvm will not be thread-safe
1150 dnl without locks.
1151 if test "$ENABLE_THREADS" -eq 1 ; then
1152   AC_CHECK_LIB(pthread, pthread_mutex_init)
1153   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1154                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1155                            [Have pthread_mutex_lock]))
1156   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1157                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1158                  [Have pthread_rwlock_init]))
1159   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1160                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1161                  [Have pthread_getspecific]))
1162 fi
1163
1164 dnl Allow extra x86-disassembler library
1165 AC_ARG_WITH(udis86,
1166   AS_HELP_STRING([--with-udis86=<path>],
1167     [Use udis86 external x86 disassembler library]),
1168     [
1169       AC_SUBST(USE_UDIS86, [1])
1170       case "$withval" in
1171         /usr/lib|yes) ;;
1172         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1173       esac
1174       AC_CHECK_LIB(udis86, ud_init, [], [
1175         echo "Error! You need to have libudis86 around."
1176         exit -1
1177       ])
1178     ],
1179     AC_SUBST(USE_UDIS86, [0]))
1180 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1181                    [Define if use udis86 library])
1182
1183 dnl Allow OProfile support for JIT output.
1184 AC_ARG_WITH(oprofile,
1185   AS_HELP_STRING([--with-oprofile=<prefix>],
1186     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1187     [
1188       AC_SUBST(USE_OPROFILE, [1])
1189       case "$withval" in
1190         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1191         no) llvm_cv_oppath=
1192             AC_SUBST(USE_OPROFILE, [0]) ;;
1193         *) llvm_cv_oppath="${withval}/lib/oprofile"
1194            CPPFLAGS="-I${withval}/include";;
1195       esac
1196       if test -n "$llvm_cv_oppath" ; then
1197         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1198         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1199         dnl libbfd is not included properly in libopagent in some Debian
1200         dnl versions.  If libbfd isn't found at all, we assume opagent works
1201         dnl anyway.
1202         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1203         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1204           echo "Error! You need to have libopagent around."
1205           exit -1
1206         ])
1207         AC_CHECK_HEADER([opagent.h], [], [
1208           echo "Error! You need to have opagent.h around."
1209           exit -1
1210           ])
1211       fi
1212     ],
1213     [
1214       AC_SUBST(USE_OPROFILE, [0])
1215     ])
1216 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1217                    [Define if we have the oprofile JIT-support library])
1218
1219 dnl===-----------------------------------------------------------------------===
1220 dnl===
1221 dnl=== SECTION 6: Check for header files
1222 dnl===
1223 dnl===-----------------------------------------------------------------------===
1224
1225 dnl First, use autoconf provided macros for specific headers that we need
1226 dnl We don't check for ancient stuff or things that are guaranteed to be there
1227 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1228 dnl Generally we're looking for POSIX headers.
1229 AC_HEADER_DIRENT
1230 AC_HEADER_MMAP_ANONYMOUS
1231 AC_HEADER_STAT
1232 AC_HEADER_STDC
1233 AC_HEADER_SYS_WAIT
1234 AC_HEADER_TIME
1235
1236 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1237 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1238 AC_CHECK_HEADERS([utime.h windows.h])
1239 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1240 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1241 AC_CHECK_HEADERS([valgrind/valgrind.h])
1242 if test "$ENABLE_THREADS" -eq 1 ; then
1243   AC_CHECK_HEADERS(pthread.h,
1244                    AC_SUBST(HAVE_PTHREAD, 1),
1245                    AC_SUBST(HAVE_PTHREAD, 0))
1246 else
1247   AC_SUBST(HAVE_PTHREAD, 0)
1248 fi
1249
1250 dnl Try to find ffi.h.
1251 if test "$llvm_cv_enable_libffi" = "yes" ; then
1252   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1253 fi
1254
1255 dnl===-----------------------------------------------------------------------===
1256 dnl===
1257 dnl=== SECTION 7: Check for types and structures
1258 dnl===
1259 dnl===-----------------------------------------------------------------------===
1260
1261 AC_HUGE_VAL_CHECK
1262 AC_TYPE_PID_T
1263 AC_TYPE_SIZE_T
1264 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1265 AC_STRUCT_TM
1266 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1267 AC_CHECK_TYPES([uint64_t],,
1268          AC_CHECK_TYPES([u_int64_t],,
1269          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1270
1271 dnl===-----------------------------------------------------------------------===
1272 dnl===
1273 dnl=== SECTION 8: Check for specific functions needed
1274 dnl===
1275 dnl===-----------------------------------------------------------------------===
1276
1277 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1278 AC_CHECK_FUNCS([powf fmodf strtof round ])
1279 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1280 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1281 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup ])
1282 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1283 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1284 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1285 AC_C_PRINTF_A
1286 AC_FUNC_RAND48
1287
1288 dnl Check for variations in the Standard C++ library and STL. These macros are
1289 dnl provided by LLVM in the autoconf/m4 directory.
1290 AC_FUNC_ISNAN
1291 AC_FUNC_ISINF
1292
1293 dnl Check for mmap support.We also need to know if /dev/zero is required to
1294 dnl be opened for allocating RWX memory.
1295 dnl Make sure we aren't attempting to configure for an unknown system
1296 if test "$llvm_cv_platform_type" = "Unix" ; then
1297   AC_FUNC_MMAP
1298   AC_FUNC_MMAP_FILE
1299   AC_NEED_DEV_ZERO_FOR_MMAP
1300
1301   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1302   then
1303     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1304   fi
1305   if test "$ac_cv_func_mmap_file" = "no"
1306   then
1307     AC_MSG_WARN([mmap() of files required but not found])
1308   fi
1309 fi
1310
1311 dnl atomic builtins are required for threading support.
1312 AC_MSG_CHECKING(for GCC atomic builtins)
1313 AC_LINK_IFELSE(
1314   AC_LANG_SOURCE(
1315     [[int main() {
1316         volatile unsigned long val = 1;
1317         __sync_synchronize();
1318         __sync_val_compare_and_swap(&val, 1, 0);
1319         __sync_add_and_fetch(&val, 1);
1320         __sync_sub_and_fetch(&val, 1);
1321         return 0;
1322       }
1323     ]]),
1324   AC_MSG_RESULT(yes)
1325   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1326   AC_MSG_RESULT(no)
1327   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1328   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1329
1330
1331 dnl===-----------------------------------------------------------------------===
1332 dnl===
1333 dnl=== SECTION 9: Additional checks, variables, etc.
1334 dnl===
1335 dnl===-----------------------------------------------------------------------===
1336
1337 dnl Handle 32-bit linux systems running a 64-bit kernel.
1338 dnl This has to come after section 4 because it invokes the compiler.
1339 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1340   AC_IS_LINUX_MIXED
1341   if test "$llvm_cv_linux_mixed" = "yes"; then
1342     llvm_cv_target_arch="x86"
1343     ARCH="x86"
1344   fi
1345 fi
1346
1347 dnl Check, whether __dso_handle is present
1348 AC_CHECK_FUNCS([__dso_handle])
1349
1350 dnl See if the llvm-gcc executable can compile to LLVM assembly
1351 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1352 [llvm_cv_llvmgcc_sanity="no"
1353 if test -x "$LLVMGCC" ; then
1354   cp /dev/null conftest.c
1355   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1356       grep 'target datalayout =' > /dev/null 2>&1
1357   if test $? -eq 0 ; then
1358     llvm_cv_llvmgcc_sanity="yes"
1359   fi
1360   rm conftest.c
1361 fi])
1362
1363 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1364 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1365   AC_MSG_CHECKING([llvm-gcc component support])
1366   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1367   AC_SUBST(LLVMCC1,$llvmcc1path)
1368   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1369   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1370   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1371   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1372   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1373   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1374   AC_MSG_RESULT([ok])
1375 fi
1376
1377 dnl Propagate the shared library extension that the libltdl checks did to
1378 dnl the Makefiles so we can use it there too
1379 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1380
1381 dnl Propagate the run-time library path variable that the libltdl
1382 dnl checks found to the Makefiles so we can use it there too
1383 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1384
1385 # Translate the various configuration directories and other basic
1386 # information into substitutions that will end up in Makefile.config.in
1387 # that these configured values can be used by the makefiles
1388 if test "${prefix}" = "NONE" ; then
1389   prefix="/usr/local"
1390 fi
1391 eval LLVM_PREFIX="${prefix}";
1392 eval LLVM_BINDIR="${prefix}/bin";
1393 eval LLVM_LIBDIR="${prefix}/lib";
1394 eval LLVM_DATADIR="${prefix}/share/llvm";
1395 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1396 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1397 eval LLVM_INCLUDEDIR="${prefix}/include";
1398 eval LLVM_INFODIR="${prefix}/info";
1399 eval LLVM_MANDIR="${prefix}/man";
1400 LLVM_CONFIGTIME=`date`
1401 AC_SUBST(LLVM_PREFIX)
1402 AC_SUBST(LLVM_BINDIR)
1403 AC_SUBST(LLVM_LIBDIR)
1404 AC_SUBST(LLVM_DATADIR)
1405 AC_SUBST(LLVM_DOCSDIR)
1406 AC_SUBST(LLVM_ETCDIR)
1407 AC_SUBST(LLVM_INCLUDEDIR)
1408 AC_SUBST(LLVM_INFODIR)
1409 AC_SUBST(LLVM_MANDIR)
1410 AC_SUBST(LLVM_CONFIGTIME)
1411
1412 # Place the various directores into the config.h file as #defines so that we
1413 # can know about the installation paths within LLVM.
1414 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1415                    [Installation prefix directory])
1416 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1417                    [Installation directory for binary executables])
1418 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1419                    [Installation directory for libraries])
1420 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1421                    [Installation directory for data files])
1422 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1423                    [Installation directory for documentation])
1424 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1425                    [Installation directory for config files])
1426 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1427                    [Installation directory for include files])
1428 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1429                    [Installation directory for .info files])
1430 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1431                    [Installation directory for man pages])
1432 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1433                    [Time at which LLVM was configured])
1434 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1435                    [Host triple we were built on])
1436
1437 # Determine which bindings to build.
1438 if test "$BINDINGS_TO_BUILD" = auto ; then
1439   BINDINGS_TO_BUILD=""
1440   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1441     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1442   fi
1443 fi
1444 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1445
1446 # This isn't really configurey, but it avoids having to repeat the list in
1447 # other files.
1448 AC_SUBST(ALL_BINDINGS,ocaml)
1449
1450 # Do any work necessary to ensure that bindings have what they need.
1451 binding_prereqs_failed=0
1452 for a_binding in $BINDINGS_TO_BUILD ; do
1453   case "$a_binding" in
1454   ocaml)
1455     if test "x$OCAMLC" = x ; then
1456       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1457       binding_prereqs_failed=1
1458     fi
1459     if test "x$OCAMLDEP" = x ; then
1460       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1461       binding_prereqs_failed=1
1462     fi
1463     if test "x$OCAMLOPT" = x ; then
1464       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1465       dnl ocamlopt is optional!
1466     fi
1467     if test "x$with_ocaml_libdir" != xauto ; then
1468       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1469     else
1470       ocaml_stdlib="`"$OCAMLC" -where`"
1471       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1472       then
1473         # ocaml stdlib is beneath our prefix; use stdlib
1474         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1475       else
1476         # ocaml stdlib is outside our prefix; use libdir/ocaml
1477         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1478       fi
1479     fi
1480     ;;
1481   esac
1482 done
1483 if test "$binding_prereqs_failed" = 1 ; then
1484   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1485 fi
1486
1487 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1488 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1489
1490 dnl Determine linker rpath flag
1491 if test "$llvm_cv_link_use_r" = "yes" ; then
1492   RPATH="-Wl,-R"
1493 else
1494   RPATH="-Wl,-rpath"
1495 fi
1496 AC_SUBST(RPATH)
1497
1498 dnl Determine linker rdynamic flag
1499 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1500   RDYNAMIC="-Wl,-export-dynamic"
1501 else
1502   RDYNAMIC=""
1503 fi
1504 AC_SUBST(RDYNAMIC)
1505
1506 dnl===-----------------------------------------------------------------------===
1507 dnl===
1508 dnl=== SECTION 10: Specify the output files and generate it
1509 dnl===
1510 dnl===-----------------------------------------------------------------------===
1511
1512 dnl Configure header files
1513 dnl WARNING: dnl If you add or remove any of the following config headers, then
1514 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1515 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1516 dnl files can be updated automatically when their *.in sources change.
1517 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1518 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1519 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1520 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1521 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1522 AC_CONFIG_HEADERS([include/llvm/System/DataTypes.h])
1523
1524 dnl Configure the makefile's configuration data
1525 AC_CONFIG_FILES([Makefile.config])
1526
1527 dnl Configure the RPM spec file for LLVM
1528 AC_CONFIG_FILES([llvm.spec])
1529
1530 dnl Configure doxygen's configuration file
1531 AC_CONFIG_FILES([docs/doxygen.cfg])
1532
1533 dnl Configure llvmc's Base plugin
1534 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1535
1536 dnl Do the first stage of configuration for llvm-config.in.
1537 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1538
1539 dnl Do special configuration of Makefiles
1540 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1541 AC_CONFIG_MAKEFILE(Makefile)
1542 AC_CONFIG_MAKEFILE(Makefile.common)
1543 AC_CONFIG_MAKEFILE(examples/Makefile)
1544 AC_CONFIG_MAKEFILE(lib/Makefile)
1545 AC_CONFIG_MAKEFILE(runtime/Makefile)
1546 AC_CONFIG_MAKEFILE(test/Makefile)
1547 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1548 AC_CONFIG_MAKEFILE(unittests/Makefile)
1549 AC_CONFIG_MAKEFILE(tools/Makefile)
1550 AC_CONFIG_MAKEFILE(utils/Makefile)
1551 AC_CONFIG_MAKEFILE(projects/Makefile)
1552 AC_CONFIG_MAKEFILE(bindings/Makefile)
1553 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1554
1555 dnl Finally, crank out the output
1556 AC_OUTPUT