autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.4]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 U University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT($LLVM_COPYRIGHT)
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "Java")         AC_CONFIG_SUBDIRS([projects/Java])      ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-fefw")    AC_CONFIG_SUBDIRS([projects/llvm-fefw]) ;;
  78       "poolalloc")    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  79       *)
  80         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  81         ;;
  82     esac
  83   fi
  84 done
  85
  86 dnl===-----------------------------------------------------------------------===
  87 dnl===
  88 dnl=== SECTION 2: Architecture, target, and host checks
  89 dnl===
  90 dnl===-----------------------------------------------------------------------===
  91
  92 dnl Check the target for which we're compiling and the host that will do the
  93 dnl compilations. This will tell us which LLVM compiler will be used for
  94 dnl compiling SSA into object code. This needs to be done early because
  95 dnl following tests depend on it.
  96 AC_CANONICAL_TARGET
  97
  98 dnl Determine the platform type and cache its value. This helps us configure
  99 dnl the System library to the correct build platform.
 100 AC_CACHE_CHECK([support for generic build operating system],
 101                [llvm_cv_platform_type],
 102 [case $build in
 103   *-*-aix*) llvm_cv_platform_type="AIX" ;;
 104   *-*-cygwin*) llvm_cv_platform_type="Cygwin" ;;
 105   *-*-darwin*) llvm_cv_platform_type="Darwin" ;;
 106   *-*-freebsd*) llvm_cv_platform_type="FreeBSD" ;;
 107   *-*-interix*) llvm_cv_platform_type="Interix" ;;
 108   *-*-linux*) llvm_cv_platform_type="Linux" ;;
 109   *-*-solaris*) llvm_cv_platform_type="SunOS" ;;
 110   *-*-win32*) llvm_cv_platform_type="Win32" ;;
 111   *-*-mingw*) llvm_cv_platform_type="Win32" ;;
 112   *) llvm_cv_platform_type="Unknown" ;;
 113 esac])
 114
 115 dnl Make sure we aren't attempting to configure for an unknown system
 116 if test "$llvm_cv_platform_type" = "Unknown" ; then
 117   AC_MSG_ERROR([Operating system platform is unknown, configure can't continue])
 118 fi
 119
 120 dnl Set the "OS" Makefile variable based on the platform type so the
 121 dnl makefile can configure itself to specific build hosts
 122 AC_SUBST(OS,$llvm_cv_platform_type)
 123
 124 dnl Make a link from lib/System/platform to lib/System/$llvm_cv_platform_type
 125 dnl This helps the #inclusion of the system specific include files
 126 dnl for the operating system abstraction library, lib/System.
 127 AC_CONFIG_LINKS(lib/System/platform:lib/System/$llvm_cv_platform_type)
 128
 129 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
 130 dnl V9, since that is all that we support at the moment, and autoconf will only
 131 dnl tell us we're a sparc.
 132 case $target in
 133   sparc*-*-solaris*)  AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
 134   ;;
 135 esac
 136
 137 dnl Determine what our target architecture is and configure accordingly.
 138 dnl This will allow Makefiles to make a distinction between the hardware and
 139 dnl the OS.
 140 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 141 [case $target in
 142   i*86-*)      llvm_cv_target_arch="x86" ;;
 143   sparc*-*)    llvm_cv_target_arch="Sparc" ;;
 144   powerpc*-*)  llvm_cv_target_arch="PowerPC" ;;
 145   *)           llvm_cv_target_arch="Unknown" ;;
 146 esac])
 147
 148 if test "$llvm_cv_target_arch" = "Unknown" ; then
 149   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 150 fi
 151
 152 dnl Define a substitution, ARCH, for the target architecture
 153 AC_SUBST(ARCH,$llvm_cv_target_arch)
 154
 155 dnl Check for the endianness of the target
 156 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 157
 158 dnl===-----------------------------------------------------------------------===
 159 dnl===
 160 dnl=== SECTION 3: Command line arguments for the configure script.
 161 dnl===
 162 dnl===-----------------------------------------------------------------------===
 163
 164 dnl --enable-optimized : check whether they want to do an optimized build:
 165 AC_ARG_ENABLE(optimized,
 166               AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
 167 if test ${enableval} = "no" ; then
 168   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 169 else
 170   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 171 fi
 172
 173 dnl --enable-jit: check whether they want to enable the jit
 174 AC_ARG_ENABLE(jit,
 175   AS_HELP_STRING(--enable-jit,
 176                  [Enable Just In Time Compiling (default is YES)]),,
 177   enableval=default)
 178 if test ${enableval} = "no"
 179 then
 180   AC_SUBST(JIT,[[]])
 181 else
 182   case "$llvm_cv_target_arch" in
 183     x86)     AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 184     Sparc)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 185     PowerPC) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 186     *)       AC_SUBST(JIT,[[]]) ;;
 187   esac
 188 fi
 189
 190 dnl Allow enablement of doxygen generated documentation
 191 AC_ARG_ENABLE(doxygen,
 192               AS_HELP_STRING([--enable-doxygen],
 193                              [Build doxygen documentation (default is NO)]),,
 194                              enableval=default)
 195 case "$enableval" in
 196   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 197   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 198   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 199   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 200 esac
 201
 202 dnl===-----------------------------------------------------------------------===
 203 dnl===
 204 dnl=== SECTION 4: Check for programs we need and that they are the right version
 205 dnl===
 206 dnl===-----------------------------------------------------------------------===
 207
 208 dnl Check for compilation tools
 209 AC_PROG_CPP
 210 AC_PROG_CC(gcc)
 211 AC_PROG_CXX(g++)
 212 AC_PROG_FLEX
 213 AC_PROG_BISON
 214
 215 dnl Check for the tools that the makefiles require
 216 AC_CHECK_GNU_MAKE
 217 AC_PROG_LN_S
 218 AC_PATH_PROG(CMP, [cmp], [cmp])
 219 AC_PATH_PROG(CP, [cp], [cp])
 220 AC_PATH_PROG(DATE, [date], [date])
 221 AC_PATH_PROG(FIND, [find], [find])
 222 AC_PATH_PROG(GREP, [grep], [grep])
 223 AC_PATH_PROG(LLVMGCC, [llvm-gcc], [llvm-gcc])
 224 AC_PATH_PROG(LLVMGXX, [llvm-g++], [llvm-g++])
 225 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 226 AC_PATH_PROG(MV,   [mv],   [mv])
 227 AC_PATH_PROG(PAX,  [pax],  [pax])
 228 AC_PROG_RANLIB
 229 AC_PATH_PROG(RM,   [rm],   [rm])
 230 AC_PATH_PROG(SED,  [sed],  [sed])
 231 AC_PATH_PROG(TAR,  [tar],  [gtar])
 232
 233 dnl Find the install program
 234 AC_PROG_INSTALL
 235
 236 dnl Checks for documentation and testing tools that we can do without. If these
 237 dnl are not found then they are set to "true" which always succeeds but does
 238 dnl nothing. This just lets the build output show that we could have done
 239 dnl something if the tool was available.
 240 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 241 AC_PATH_PROG(DOT,[dot],[true dot])
 242 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 243 AC_PATH_PROG(ETAGS,[etags],[true etags])
 244 AC_PATH_PROG(GROFF,[groff],[true groff])
 245 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 246 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 247 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 248 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 249 DJ_AC_PATH_TCLSH
 250 AC_PATH_PROG(ZIP,[zip],[true zip])
 251
 252 dnl Determine if the linker supports the -R option.
 253 AC_LINK_USE_R
 254
 255 dnl Check for libtool and the library that has dlopen function (which must come
 256 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 257 dnl libtool).
 258 AC_LIBTOOL_DLOPEN
 259 AC_LIB_LTDL
 260 AC_PROG_LIBTOOL
 261
 262 dnl Check if we know how to tell etags we are using C++:
 263 etags_version=`$ETAGS --version 2>&1`
 264 case "$etags_version" in
 265         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 266         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 267         *) ETAGSFLAGS="" ;;
 268 esac
 269 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 270
 271 AC_MSG_CHECKING([tool compatibility])
 272
 273 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 274 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 275 dnl to support those options.
 276 dnl "icc" emits gcc signatures
 277 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 278 ICC=no
 279 IXX=no
 280 case $CC in
 281   icc*|icpc*)
 282     ICC=yes
 283     IXX=yes
 284     ;;
 285    *)
 286     ;;
 287 esac
 288
 289 if test "$GCC" != "yes" && test "$ICC" != "yes"
 290 then
 291   AC_MSG_ERROR([gcc|icc required but not found])
 292 fi
 293
 294 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 295 if test "$GXX" != "yes" && test "$IXX" != "yes"
 296 then
 297   AC_MSG_ERROR([g++|icc required but not found])
 298 fi
 299
 300 dnl Verify that GCC is version 3.0 or higher
 301 if test "$GCC" = "yes"
 302 then
 303   gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 304   if test "$gccmajor" -lt "3"
 305   then
 306     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 307   fi
 308 fi
 309
 310 dnl Check for GNU Make.  We use its extensions, so don't build without it
 311 if test -z "$llvm_cv_gnu_make_command"
 312 then
 313   AC_MSG_ERROR([GNU Make required but not found])
 314 fi
 315
 316 dnl Tool compatibility is okay if we make it here.
 317 AC_MSG_RESULT([ok])
 318
 319 dnl===-----------------------------------------------------------------------===
 320 dnl===
 321 dnl=== SECTION 5: Check for libraries
 322 dnl===
 323 dnl===-----------------------------------------------------------------------===
 324
 325 dnl libelf is for sparc only; we can ignore it if we don't have it
 326 AC_CHECK_LIB(elf, elf_begin)
 327
 328 dnl lt_dlopen may be required for plugin support.
 329 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 330               [Define if lt_dlopen() is available on this platform]),
 331               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 332                            not be available]))
 333
 334 dnl dlopen() is required for plugin support.
 335 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 336                [Define if dlopen() is available on this platform.]),
 337                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 338
 339 dnl mallinfo is optional; the code can compile (minus features) without it
 340 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 341                [Define if mallinfo() is available on this platform.]))
 342
 343 dnl pthread locking functions are optional - but llvm will not be thread-safe
 344 dnl without locks.
 345 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 346                AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 347                          [Have pthread_mutex_lock]))
 348
 349 dnl===-----------------------------------------------------------------------===
 350 dnl===
 351 dnl=== SECTION 6: Check for header files
 352 dnl===
 353 dnl===-----------------------------------------------------------------------===
 354
 355 dnl We don't check for ancient stuff or things that are guaranteed to be there
 356 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 357 AC_HEADER_STDC
 358
 359 dnl However, we do need some system specific header files. Generally we're
 360 dnl looking for POSIX headers.
 361 AC_HEADER_SYS_WAIT
 362 AC_CHECK_HEADERS([sys/time.h sys/mman.h sys/resource.h sys/time.h sys/types.h])
 363 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h limits.h link.h])
 364 AC_CHECK_HEADERS([malloc.h unistd.h windows.h])
 365 AC_HEADER_TIME
 366 AC_HEADER_MMAP_ANONYMOUS
 367
 368 dnl Check for things that need to be included in public headers, and so
 369 dnl for which we may not have access to a HAVE_* preprocessor #define.
 370 dnl (primarily used in DataTypes.h)
 371 AC_CHECK_HEADERS([inttypes.h stdint.h])
 372
 373 dnl===-----------------------------------------------------------------------===
 374 dnl===
 375 dnl=== SECTION 7: Check for types and structures
 376 dnl===
 377 dnl===-----------------------------------------------------------------------===
 378
 379 AC_TYPE_PID_T
 380 AC_TYPE_SIZE_T
 381 AC_TYPE_SIGNAL
 382 AC_STRUCT_TM
 383 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 384 AC_CHECK_TYPES([uint64_t],,
 385          AC_CHECK_TYPES([u_int64_t],,
 386          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 387
 388 dnl===-----------------------------------------------------------------------===
 389 dnl===
 390 dnl=== SECTION 8: Check for specific functions needed
 391 dnl===
 392 dnl===-----------------------------------------------------------------------===
 393
 394 AC_CHECK_FUNCS([backtrace getcwd getpagesize getrusage gettimeofday isatty ])
 395 AC_CHECK_FUNCS([mkdtemp mkstemp mktemp ])
 396 AC_CHECK_FUNCS([realpath strdup strtoq strtoll sysconf ])
 397 AC_C_PRINTF_A
 398 AC_FUNC_ALLOCA
 399 AC_FUNC_RAND48
 400
 401 dnl Check for variations in the Standard C++ library and STL. These macros are
 402 dnl provided by LLVM in the autoconf/m4 directory.
 403 AC_CXX_HAVE_HASH_MAP
 404 AC_CXX_HAVE_HASH_SET
 405 AC_CXX_HAVE_STD_ITERATOR
 406 AC_CXX_HAVE_BI_ITERATOR
 407 AC_CXX_HAVE_FWD_ITERATOR
 408 AC_FUNC_ISNAN
 409 AC_FUNC_ISINF
 410
 411 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 412 dnl bytecode loading, etc.
 413 AC_FUNC_MMAP
 414 AC_FUNC_MMAP_FILE
 415 AC_CHECK_FUNC(mprotect,,
 416               AC_MSG_ERROR([Function mprotect() required but not found]))
 417
 418 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 419 then
 420   AC_MSG_WARN([mmap() required but not found])
 421 fi
 422 if test "$ac_cv_func_mmap_file" = "no"
 423 then
 424   AC_MSG_WARN([mmap() of files required but not found])
 425 fi
 426
 427 dnl===-----------------------------------------------------------------------===
 428 dnl===
 429 dnl=== SECTION 9: Additional checks, variables, etc.
 430 dnl===
 431 dnl===-----------------------------------------------------------------------===
 432
 433 dnl See if the llvmgcc executable can compile to LLVM assembly
 434 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 435 [llvm_cv_llvmgcc_sanity="no"
 436 if test -x "$LLVMGCC" ; then
 437   cp /dev/null conftest.c
 438   "$LLVMGCC" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 439   if test $? -eq 0 ; then
 440     llvm_cv_llvmgcc_sanity="yes"
 441   fi
 442   rm conftest.c
 443 fi])
 444
 445 dnl Since we have a sane llvmgcc, identify it and its sub-tools
 446 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 447   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 448   AC_SUBST(LLVMCC1,$llvmcc1path)
 449   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 450   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 451   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 452   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 453 fi
 454
 455 dnl Propagate the shared library extension that the libltdl checks did to
 456 dnl the Makefiles so we can use it there too
 457 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 458
 459 # Translate the various configuration directories and other basic
 460 # information into substitutions that will end up in Makefile.config.in
 461 # that these configured values can be used by the makefiles
 462 eval LLVM_PREFIX="${prefix}";
 463 eval LLVM_BINDIR="${prefix}/bin";
 464 eval LLVM_LIBDIR="${prefix}/lib";
 465 eval LLVM_DATADIR="${prefix}/share/llvm";
 466 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 467 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 468 eval LLVM_INCLUDEDIR="${prefix}/include";
 469 eval LLVM_INFODIR="${prefix}/info";
 470 eval LLVM_MANDIR="${prefix}/man";
 471 LLVM_CONFIGTIME=`date`
 472 AC_SUBST(LLVM_PREFIX)
 473 AC_SUBST(LLVM_BINDIR)
 474 AC_SUBST(LLVM_LIBDIR)
 475 AC_SUBST(LLVM_DATADIR)
 476 AC_SUBST(LLVM_DOCSDIR)
 477 AC_SUBST(LLVM_ETCDIR)
 478 AC_SUBST(LLVM_INCLUDEDIR)
 479 AC_SUBST(LLVM_INFODIR)
 480 AC_SUBST(LLVM_MANDIR)
 481 AC_SUBST(LLVM_CONFIGTIME)
 482
 483 # Place the various directores into the config.h file as #defines so that we
 484 # can know about the installation paths within LLVM.
 485 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 486                    [Installation prefix directory])
 487 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 488                    [Installation directory for binary executables])
 489 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 490                    [Installation directory for libraries])
 491 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 492                    [Installation directory for data files])
 493 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 494                    [Installation directory for documentation])
 495 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 496                    [Installation directory for config files])
 497 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 498                    [Installation directory for include files])
 499 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 500                    [Installation directory for .info files])
 501 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 502                    [Installation directory for man pages])
 503 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 504                    [Time at which LLVM was configured])
 505
 506 dnl===-----------------------------------------------------------------------===
 507 dnl===
 508 dnl=== SECTION 10: Specify the output files and generate it
 509 dnl===
 510 dnl===-----------------------------------------------------------------------===
 511
 512 dnl Configure header files
 513 AC_CONFIG_HEADERS(include/llvm/Config/config.h)
 514
 515 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 516 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 517 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 518 AC_CONFIG_HEADERS([include/llvm/Support/ThreadSupport.h])
 519 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 520
 521 dnl Configure the makefile's configuration data
 522 AC_CONFIG_FILES([Makefile.config])
 523
 524 dnl Configure llvmc's configuration files
 525 AC_CONFIG_FILES([tools/llvmc/st tools/llvmc/cpp tools/llvmc/ll tools/llvmc/c])
 526
 527 dnl Configure doxygen's configuration file
 528 AC_CONFIG_FILES([docs/doxygen.cfg])
 529
 530 dnl Do special configuration of Makefiles
 531 AC_CONFIG_MAKEFILE(Makefile)
 532 AC_CONFIG_MAKEFILE(Makefile.common)
 533 AC_CONFIG_MAKEFILE(examples/Makefile)
 534 AC_CONFIG_MAKEFILE(lib/Makefile)
 535 AC_CONFIG_MAKEFILE(runtime/Makefile)
 536 AC_CONFIG_MAKEFILE(test/Makefile)
 537 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 538 AC_CONFIG_MAKEFILE(tools/Makefile)
 539 AC_CONFIG_MAKEFILE(utils/Makefile)
 540 AC_CONFIG_MAKEFILE(projects/Makefile)
 541
 542 dnl Finally, crank out the output
 543 AC_OUTPUT
 544
 545 dnl Warn loudly if llvm-gcc was not obviously working
 546 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 547  AC_MSG_WARN([***** llvmgcc/llvmg++ was not found, or does not appear to be ])
 548  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 549  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 550  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 551  AC_MSG_WARN([***** build the llvm tools.])
 552 fi