autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[3.1svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2011 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2011 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.60 or later.
  42 AC_PREREQ(2.60)
  43
  44 dnl Verify that the source directory is valid. This makes sure that we are
  45 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  46 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  47
  48 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  49 dnl various tools where the m4 autoconf macros are.
  50 AC_CONFIG_AUX_DIR([autoconf])
  51
  52 dnl Quit if the source directory has already been configured.
  53 dnl NOTE: This relies upon undocumented autoconf behavior.
  54 if test ${srcdir} != "." ; then
  55   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  56     AC_MSG_ERROR([Already configured in ${srcdir}])
  57   fi
  58 fi
  59
  60 dnl We need to check for the compiler up here to avoid anything else
  61 dnl starting with a different one.
  62 AC_PROG_CC(clang llvm-gcc gcc)
  63 AC_PROG_CXX(clang++ llvm-g++ g++)
  64 AC_PROG_CPP
  65
  66 dnl Configure all of the projects present in our source tree. While we could
  67 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  68 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  69 dnl Instead we match on the known projects.
  70
  71 dnl
  72 dnl One tricky part of doing this is that some projects depend upon other
  73 dnl projects.  For example, several projects rely upon the LLVM test suite.
  74 dnl We want to configure those projects first so that their object trees are
  75 dnl created before running the configure scripts of projects that depend upon
  76 dnl them.
  77 dnl
  78
  79 dnl Several projects use llvm-gcc, so configure that first
  80 if test -d ${srcdir}/projects/llvm-gcc ; then
  81   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  82 fi
  83
  84 dnl Several projects use the LLVM test suite, so configure it next.
  85 if test -d ${srcdir}/projects/test-suite ; then
  86   AC_CONFIG_SUBDIRS([projects/test-suite])
  87 fi
  88
  89 dnl llvm-test is the old name of the test-suite, kept here for backwards
  90 dnl compatibility
  91 if test -d ${srcdir}/projects/llvm-test ; then
  92   AC_CONFIG_SUBDIRS([projects/llvm-test])
  93 fi
  94
  95 dnl Some projects use poolalloc; configure that next
  96 if test -d ${srcdir}/projects/poolalloc ; then
  97   AC_CONFIG_SUBDIRS([projects/poolalloc])
  98 fi
  99
 100 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 101   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 102 fi
 103
 104 dnl Check for all other projects
 105 for i in `ls ${srcdir}/projects`
 106 do
 107   if test -d ${srcdir}/projects/${i} ; then
 108     case ${i} in
 109       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 110       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 111       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 112       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 113       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 114       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 115       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 116       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 117       llvm-gcc)       ;;
 118       test-suite)     ;;
 119       llvm-test)      ;;
 120       poolalloc)      ;;
 121       llvm-poolalloc) ;;
 122       *)
 123         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 124         ;;
 125     esac
 126   fi
 127 done
 128
 129 dnl Disable the build of polly, even if it is checked out into tools/polly.
 130 AC_ARG_ENABLE(polly,
 131               AS_HELP_STRING([--enable-polly],
 132                              [Use polly if available (default is YES)]),,
 133                              enableval=default)
 134 case "$enableval" in
 135   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 136   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 137   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 138   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 139 esac
 140
 141
 142 dnl Check if polly is checked out into tools/polly and configure it if
 143 dnl available.
 144 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 145   AC_SUBST(LLVM_HAS_POLLY,1)
 146   AC_CONFIG_SUBDIRS([tools/polly])
 147 fi
 148
 149 dnl===-----------------------------------------------------------------------===
 150 dnl===
 151 dnl=== SECTION 2: Architecture, target, and host checks
 152 dnl===
 153 dnl===-----------------------------------------------------------------------===
 154
 155 dnl Check the target for which we're compiling and the host that will do the
 156 dnl compilations. This will tell us which LLVM compiler will be used for
 157 dnl compiling SSA into object code. This needs to be done early because
 158 dnl following tests depend on it.
 159 AC_CANONICAL_TARGET
 160
 161 dnl Determine the platform type and cache its value. This helps us configure
 162 dnl the System library to the correct build platform.
 163 AC_CACHE_CHECK([type of operating system we're going to host on],
 164                [llvm_cv_os_type],
 165 [case $host in
 166   *-*-aix*)
 167     llvm_cv_link_all_option="-Wl,--whole-archive"
 168     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 169     llvm_cv_os_type="AIX"
 170     llvm_cv_platform_type="Unix" ;;
 171   *-*-irix*)
 172     llvm_cv_link_all_option="-Wl,--whole-archive"
 173     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 174     llvm_cv_os_type="IRIX"
 175     llvm_cv_platform_type="Unix" ;;
 176   *-*-cygwin*)
 177     llvm_cv_link_all_option="-Wl,--whole-archive"
 178     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 179     llvm_cv_os_type="Cygwin"
 180     llvm_cv_platform_type="Unix" ;;
 181   *-*-darwin*)
 182     llvm_cv_link_all_option="-Wl,-all_load"
 183     llvm_cv_no_link_all_option="-Wl,-noall_load"
 184     llvm_cv_os_type="Darwin"
 185     llvm_cv_platform_type="Unix" ;;
 186   *-*-minix*)
 187     llvm_cv_link_all_option="-Wl,-all_load"
 188     llvm_cv_no_link_all_option="-Wl,-noall_load"
 189     llvm_cv_os_type="Minix"
 190     llvm_cv_platform_type="Unix" ;;
 191   *-*-freebsd*)
 192     llvm_cv_link_all_option="-Wl,--whole-archive"
 193     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 194     llvm_cv_os_type="FreeBSD"
 195     llvm_cv_platform_type="Unix" ;;
 196   *-*-openbsd*)
 197     llvm_cv_link_all_option="-Wl,--whole-archive"
 198     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 199     llvm_cv_os_type="OpenBSD"
 200     llvm_cv_platform_type="Unix" ;;
 201   *-*-netbsd*)
 202     llvm_cv_link_all_option="-Wl,--whole-archive"
 203     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 204     llvm_cv_os_type="NetBSD"
 205     llvm_cv_platform_type="Unix" ;;
 206   *-*-dragonfly*)
 207     llvm_cv_link_all_option="-Wl,--whole-archive"
 208     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 209     llvm_cv_os_type="DragonFly"
 210     llvm_cv_platform_type="Unix" ;;
 211   *-*-hpux*)
 212     llvm_cv_link_all_option="-Wl,--whole-archive"
 213     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 214     llvm_cv_os_type="HP-UX"
 215     llvm_cv_platform_type="Unix" ;;
 216   *-*-interix*)
 217     llvm_cv_link_all_option="-Wl,--whole-archive"
 218     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 219     llvm_cv_os_type="Interix"
 220     llvm_cv_platform_type="Unix" ;;
 221   *-*-linux*)
 222     llvm_cv_link_all_option="-Wl,--whole-archive"
 223     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 224     llvm_cv_os_type="Linux"
 225     llvm_cv_platform_type="Unix" ;;
 226   *-*-solaris*)
 227     llvm_cv_link_all_option="-Wl,-z,allextract"
 228     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 229     llvm_cv_os_type="SunOS"
 230     llvm_cv_platform_type="Unix" ;;
 231   *-*-auroraux*)
 232     llvm_cv_link_all_option="-Wl,-z,allextract"
 233     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 234     llvm_cv_os_type="AuroraUX"
 235     llvm_cv_platform_type="Unix" ;;
 236   *-*-win32*)
 237     llvm_cv_link_all_option="-Wl,--whole-archive"
 238     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 239     llvm_cv_os_type="Win32"
 240     llvm_cv_platform_type="Win32" ;;
 241   *-*-mingw*)
 242     llvm_cv_link_all_option="-Wl,--whole-archive"
 243     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 244     llvm_cv_os_type="MingW"
 245     llvm_cv_platform_type="Win32" ;;
 246   *-*-haiku*)
 247     llvm_cv_link_all_option="-Wl,--whole-archive"
 248     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 249     llvm_cv_os_type="Haiku"
 250     llvm_cv_platform_type="Unix" ;;
 251   *-unknown-eabi*)
 252     llvm_cv_link_all_option="-Wl,--whole-archive"
 253     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 254     llvm_cv_os_type="Freestanding"
 255     llvm_cv_platform_type="Unix" ;;
 256   *-unknown-elf*)
 257     llvm_cv_link_all_option="-Wl,--whole-archive"
 258     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 259     llvm_cv_os_type="Freestanding"
 260     llvm_cv_platform_type="Unix" ;;
 261   *)
 262     llvm_cv_link_all_option=""
 263     llvm_cv_no_link_all_option=""
 264     llvm_cv_os_type="Unknown"
 265     llvm_cv_platform_type="Unknown" ;;
 266 esac])
 267
 268 AC_CACHE_CHECK([type of operating system we're going to target],
 269                [llvm_cv_target_os_type],
 270 [case $target in
 271   *-*-aix*)
 272     llvm_cv_target_os_type="AIX" ;;
 273   *-*-irix*)
 274     llvm_cv_target_os_type="IRIX" ;;
 275   *-*-cygwin*)
 276     llvm_cv_target_os_type="Cygwin" ;;
 277   *-*-darwin*)
 278     llvm_cv_target_os_type="Darwin" ;;
 279   *-*-minix*)
 280     llvm_cv_target_os_type="Minix" ;;
 281   *-*-freebsd*)
 282     llvm_cv_target_os_type="FreeBSD" ;;
 283   *-*-openbsd*)
 284     llvm_cv_target_os_type="OpenBSD" ;;
 285   *-*-netbsd*)
 286     llvm_cv_target_os_type="NetBSD" ;;
 287   *-*-dragonfly*)
 288     llvm_cv_target_os_type="DragonFly" ;;
 289   *-*-hpux*)
 290     llvm_cv_target_os_type="HP-UX" ;;
 291   *-*-interix*)
 292     llvm_cv_target_os_type="Interix" ;;
 293   *-*-linux*)
 294     llvm_cv_target_os_type="Linux" ;;
 295   *-*-solaris*)
 296     llvm_cv_target_os_type="SunOS" ;;
 297   *-*-auroraux*)
 298     llvm_cv_target_os_type="AuroraUX" ;;
 299   *-*-win32*)
 300     llvm_cv_target_os_type="Win32" ;;
 301   *-*-mingw*)
 302     llvm_cv_target_os_type="MingW" ;;
 303   *-*-haiku*)
 304     llvm_cv_target_os_type="Haiku" ;;
 305   *-*-rtems*)
 306     llvm_cv_target_os_type="RTEMS" ;;
 307   *-*-nacl*)
 308     llvm_cv_target_os_type="NativeClient" ;;
 309   *-unknown-eabi*)
 310     llvm_cv_target_os_type="Freestanding" ;;
 311   *)
 312     llvm_cv_target_os_type="Unknown" ;;
 313 esac])
 314
 315 dnl Make sure we aren't attempting to configure for an unknown system
 316 if test "$llvm_cv_os_type" = "Unknown" ; then
 317   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 318 fi
 319
 320 dnl Set the "OS" Makefile variable based on the platform type so the
 321 dnl makefile can configure itself to specific build hosts
 322 AC_SUBST(OS,$llvm_cv_os_type)
 323 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 324 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 325
 326 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 327 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 328 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 329
 330 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 331 dnl This is used by lib/Support to determine the basic kind of implementation
 332 dnl to use.
 333 case $llvm_cv_platform_type in
 334   Unix)
 335     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 336     AC_SUBST(LLVM_ON_UNIX,[1])
 337     AC_SUBST(LLVM_ON_WIN32,[0])
 338     ;;
 339   Win32)
 340     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 341     AC_SUBST(LLVM_ON_UNIX,[0])
 342     AC_SUBST(LLVM_ON_WIN32,[1])
 343     ;;
 344 esac
 345
 346 dnl Determine what our target architecture is and configure accordingly.
 347 dnl This will allow Makefiles to make a distinction between the hardware and
 348 dnl the OS.
 349 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 350 [case $target in
 351   i?86-*)                 llvm_cv_target_arch="x86" ;;
 352   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 353   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 354   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 355   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 356   mips-*)                 llvm_cv_target_arch="Mips" ;;
 357   xcore-*)                llvm_cv_target_arch="XCore" ;;
 358   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 359   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 360   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 361   *)                      llvm_cv_target_arch="Unknown" ;;
 362 esac])
 363
 364 if test "$llvm_cv_target_arch" = "Unknown" ; then
 365   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 366 fi
 367
 368 # Determine the LLVM native architecture for the target
 369 case "$llvm_cv_target_arch" in
 370     x86)     LLVM_NATIVE_ARCH="X86" ;;
 371     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 372     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 373 esac
 374
 375 dnl Define a substitution, ARCH, for the target architecture
 376 AC_SUBST(ARCH,$llvm_cv_target_arch)
 377
 378 dnl Check for the endianness of the target
 379 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 380
 381 dnl Check for build platform executable suffix if we're crosscompiling
 382 if test "$cross_compiling" = yes; then
 383   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 384   AC_BUILD_EXEEXT
 385   ac_build_prefix=${build_alias}-
 386   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 387   if test -z "$BUILD_CXX"; then
 388      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 389      if test -z "$BUILD_CXX"; then
 390        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 391      fi
 392   fi
 393 else
 394   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 395 fi
 396
 397 dnl Check to see if there's a .svn or .git directory indicating that this
 398 dnl build is being done from a checkout. This sets up several defaults for
 399 dnl the command line switches. When we build with a checkout directory,
 400 dnl we get a debug with assertions turned on. Without, we assume a source
 401 dnl release and we get an optimized build without assertions.
 402 dnl See --enable-optimized and --enable-assertions below
 403 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 404   cvsbuild="yes"
 405   optimize="no"
 406   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 407 else
 408   cvsbuild="no"
 409   optimize="yes"
 410 fi
 411
 412 dnl===-----------------------------------------------------------------------===
 413 dnl===
 414 dnl=== SECTION 3: Command line arguments for the configure script.
 415 dnl===
 416 dnl===-----------------------------------------------------------------------===
 417
 418 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 419 AC_ARG_ENABLE(libcpp,
 420               AS_HELP_STRING([--enable-libcpp],
 421                              [Use libc++ if available (default is NO)]),,
 422                              enableval=default)
 423 case "$enableval" in
 424   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 425   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 426   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 427   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 428 esac
 429
 430 dnl --enable-optimized : check whether they want to do an optimized build:
 431 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 432  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 433 if test ${enableval} = "no" ; then
 434   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 435 else
 436   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 437 fi
 438
 439 dnl --enable-profiling : check whether they want to do a profile build:
 440 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 441  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 442 if test ${enableval} = "no" ; then
 443   AC_SUBST(ENABLE_PROFILING,[[]])
 444 else
 445   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 446 fi
 447
 448 dnl --enable-assertions : check whether they want to turn on assertions or not:
 449 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 450   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 451 if test ${enableval} = "yes" ; then
 452   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 453 else
 454   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 455 fi
 456
 457 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 458 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 459   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 460 if test ${enableval} = "yes" ; then
 461   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 462   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 463 else
 464   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 465   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 466 fi
 467
 468 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 469 AC_ARG_ENABLE(debug-runtime,
 470    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 471 if test ${enableval} = "no" ; then
 472   AC_SUBST(DEBUG_RUNTIME,[[]])
 473 else
 474   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 475 fi
 476
 477 dnl --enable-debug-symbols : should even optimized compiler libraries
 478 dnl have debug symbols?
 479 AC_ARG_ENABLE(debug-symbols,
 480    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 481 if test ${enableval} = "no" ; then
 482   AC_SUBST(DEBUG_SYMBOLS,[[]])
 483 else
 484   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 485 fi
 486
 487 dnl --enable-jit: check whether they want to enable the jit
 488 AC_ARG_ENABLE(jit,
 489   AS_HELP_STRING(--enable-jit,
 490                  [Enable Just In Time Compiling (default is YES)]),,
 491   enableval=default)
 492 if test ${enableval} = "no"
 493 then
 494   AC_SUBST(JIT,[[]])
 495 else
 496   case "$llvm_cv_target_arch" in
 497     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 498     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 499     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 500     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 501     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 502     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 503     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 504     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 505     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 506     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 507     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 508   esac
 509 fi
 510
 511 dnl Allow enablement of building and installing docs
 512 AC_ARG_ENABLE(docs,
 513               AS_HELP_STRING([--enable-docs],
 514                              [Build documents (default is YES)]),,
 515                              enableval=default)
 516 case "$enableval" in
 517   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 518   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 519   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 520   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 521 esac
 522
 523 dnl Allow enablement of doxygen generated documentation
 524 AC_ARG_ENABLE(doxygen,
 525               AS_HELP_STRING([--enable-doxygen],
 526                              [Build doxygen documentation (default is NO)]),,
 527                              enableval=default)
 528 case "$enableval" in
 529   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 530   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 531   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 532   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 533 esac
 534
 535 dnl Allow disablement of threads
 536 AC_ARG_ENABLE(threads,
 537               AS_HELP_STRING([--enable-threads],
 538                              [Use threads if available (default is YES)]),,
 539                              enableval=default)
 540 case "$enableval" in
 541   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 542   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 543   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 544   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 545 esac
 546 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 547
 548 dnl Allow disablement of pthread.h
 549 AC_ARG_ENABLE(pthreads,
 550               AS_HELP_STRING([--enable-pthreads],
 551                              [Use pthreads if available (default is YES)]),,
 552                              enableval=default)
 553 case "$enableval" in
 554   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 555   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 556   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 557   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 558 esac
 559
 560 dnl Allow building without position independent code
 561 AC_ARG_ENABLE(pic,
 562   AS_HELP_STRING([--enable-pic],
 563                  [Build LLVM with Position Independent Code (default is YES)]),,
 564                  enableval=default)
 565 case "$enableval" in
 566   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 567   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 568   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 569   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 570 esac
 571 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 572                    [Define if position independent code is enabled])
 573
 574 dnl Allow building a shared library and linking tools against it.
 575 AC_ARG_ENABLE(shared,
 576   AS_HELP_STRING([--enable-shared],
 577                  [Build a shared library and link tools against it (default is NO)]),,
 578                  enableval=default)
 579 case "$enableval" in
 580   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 581   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 582   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 583   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 584 esac
 585
 586 dnl Allow libstdc++ is embedded in LLVM.dll.
 587 AC_ARG_ENABLE(embed-stdcxx,
 588   AS_HELP_STRING([--enable-embed-stdcxx],
 589                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 590                  enableval=default)
 591 case "$enableval" in
 592   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 593   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 594   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 595   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 596 esac
 597
 598 dnl Enable embedding timestamp information into build.
 599 AC_ARG_ENABLE(timestamps,
 600   AS_HELP_STRING([--enable-timestamps],
 601                  [Enable embedding timestamp information in build (default is YES)]),,
 602                  enableval=default)
 603 case "$enableval" in
 604   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 605   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 606   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 607   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 608 esac
 609 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 610                    [Define if timestamp information (e.g., __DATE___) is allowed])
 611
 612 dnl Allow specific targets to be specified for building (or not)
 613 TARGETS_TO_BUILD=""
 614 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 615     [Build specific host targets: all or target1,target2,... Valid targets are:
 616      host, x86, x86_64, sparc, powerpc, arm, mips, spu,
 617      xcore, msp430, ptx, cbe, and cpp (default=all)]),,
 618     enableval=all)
 619 if test "$enableval" = host-only ; then
 620   enableval=host
 621 fi
 622 case "$enableval" in
 623   all) TARGETS_TO_BUILD="X86 Sparc PowerPC ARM Mips CellSPU XCore MSP430 CBackend CppBackend MBlaze PTX" ;;
 624   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 625       case "$a_target" in
 626         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 627         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 628         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 629         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 630         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 631         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 632         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 633         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 634         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 635         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 636         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 637         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 638         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 639         host) case "$llvm_cv_target_arch" in
 640             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 641             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 642             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 643             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 644             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 645             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 646             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 647             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 648             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 649             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 650             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 651             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 652           esac ;;
 653         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 654       esac
 655   done
 656   ;;
 657 esac
 658 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 659
 660 # Determine whether we are building LLVM support for the native architecture.
 661 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 662 for a_target in $TARGETS_TO_BUILD; do
 663   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 664     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 665       [LLVM architecture name for the native architecture, if available])
 666     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 667     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 668     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 669     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 670     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 671       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 672     fi
 673     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 674       [LLVM name for the native Target init function, if available])
 675     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 676       [LLVM name for the native TargetInfo init function, if available])
 677     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 678       [LLVM name for the native target MC init function, if available])
 679     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 680       [LLVM name for the native AsmPrinter init function, if available])
 681     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 682       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 683        [LLVM name for the native AsmParser init function, if available])
 684     fi
 685   fi
 686 done
 687
 688 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 689 # target feature def files.
 690 LLVM_ENUM_TARGETS=""
 691 LLVM_ENUM_ASM_PRINTERS=""
 692 LLVM_ENUM_ASM_PARSERS=""
 693 LLVM_ENUM_DISASSEMBLERS=""
 694 for target_to_build in $TARGETS_TO_BUILD; do
 695   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 696   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 697     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 698   fi
 699   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 700     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 701   fi
 702   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 703     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 704   fi
 705 done
 706 AC_SUBST(LLVM_ENUM_TARGETS)
 707 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 708 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 709 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 710
 711 dnl Prevent the CBackend from using printf("%a") for floating point so older
 712 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 713 dnl can still compile the CBE's output
 714 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 715   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 716   enableval=default)
 717 case "$enableval" in
 718   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 719   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 720   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 721   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 722 esac
 723 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 724                    [Define if CBE is enabled for printf %a output])
 725
 726 dnl Override the option to use for optimized builds.
 727 AC_ARG_WITH(optimize-option,
 728   AS_HELP_STRING([--with-optimize-option],
 729                  [Select the compiler options to use for optimized builds]),,
 730                  withval=default)
 731 AC_MSG_CHECKING([optimization flags])
 732 case "$withval" in
 733   default)
 734     case "$llvm_cv_os_type" in
 735     FreeBSD) optimize_option=-O2 ;;
 736     MingW) optimize_option=-O2 ;;
 737     *)     optimize_option=-O3 ;;
 738     esac ;;
 739   *) optimize_option="$withval" ;;
 740 esac
 741 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 742 AC_MSG_RESULT([$optimize_option])
 743
 744 dnl Specify extra build options
 745 AC_ARG_WITH(extra-options,
 746   AS_HELP_STRING([--with-extra-options],
 747                  [Specify additional options to compile LLVM with]),,
 748                  withval=default)
 749 case "$withval" in
 750   default) EXTRA_OPTIONS= ;;
 751   *) EXTRA_OPTIONS=$withval ;;
 752 esac
 753 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 754
 755 dnl Specify extra linker build options
 756 AC_ARG_WITH(extra-ld-options,
 757   AS_HELP_STRING([--with-extra-ld-options],
 758                  [Specify additional options to link LLVM with]),,
 759                  withval=default)
 760 case "$withval" in
 761   default) EXTRA_LD_OPTIONS= ;;
 762   *) EXTRA_LD_OPTIONS=$withval ;;
 763 esac
 764 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 765
 766 dnl Allow specific bindings to be specified for building (or not)
 767 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 768     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 769     enableval=default)
 770 BINDINGS_TO_BUILD=""
 771 case "$enableval" in
 772   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 773   all ) BINDINGS_TO_BUILD="ocaml" ;;
 774   none | no) BINDINGS_TO_BUILD="" ;;
 775   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 776       case "$a_binding" in
 777         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 778         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 779       esac
 780   done
 781   ;;
 782 esac
 783
 784 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 785 dnl script for bindings/ocaml/configure, except that its auto value depends on
 786 dnl OCAMLC, which is found here to support tests.
 787 AC_ARG_WITH([ocaml-libdir],
 788   [AS_HELP_STRING([--with-ocaml-libdir],
 789     [Specify install location for ocaml bindings (default is stdlib)])],
 790   [],
 791   [withval=auto])
 792 case "$withval" in
 793   auto) with_ocaml_libdir="$withval" ;;
 794   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 795   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 796 esac
 797
 798 AC_ARG_WITH(clang-srcdir,
 799   AS_HELP_STRING([--with-clang-srcdir],
 800     [Directory to the out-of-tree Clang source]),,
 801     withval="-")
 802 case "$withval" in
 803   -) clang_src_root="" ;;
 804   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 805   *) clang_src_root="$ac_pwd/$withval" ;;
 806 esac
 807 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
 808
 809 AC_ARG_WITH(clang-resource-dir,
 810   AS_HELP_STRING([--with-clang-resource-dir],
 811     [Relative directory from the Clang binary for resource files]),,
 812     withval="")
 813 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 814                    [Relative directory for resource files])
 815
 816 AC_ARG_WITH(c-include-dirs,
 817   AS_HELP_STRING([--with-c-include-dirs],
 818     [Colon separated list of directories clang will search for headers]),,
 819     withval="")
 820 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 821                    [Directories clang will search for headers])
 822
 823 AC_ARG_WITH(cxx-include-root,
 824   AS_HELP_STRING([--with-cxx-include-root],
 825     [Directory with the libstdc++ headers.]),,
 826     withval="")
 827 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 828                    [Directory with the libstdc++ headers.])
 829
 830 AC_ARG_WITH(cxx-include-arch,
 831   AS_HELP_STRING([--with-cxx-include-arch],
 832     [Architecture of the libstdc++ headers.]),,
 833     withval="")
 834 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 835                    [Arch the libstdc++ headers.])
 836
 837 AC_ARG_WITH(cxx-include-32bit-dir,
 838   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 839     [32 bit multilib dir.]),,
 840     withval="")
 841 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 842                    [32 bit multilib directory.])
 843
 844 AC_ARG_WITH(cxx-include-64bit-dir,
 845   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 846     [64 bit multilib directory.]),,
 847     withval="")
 848 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 849                    [64 bit multilib directory.])
 850
 851 dnl Allow linking of LLVM with GPLv3 binutils code.
 852 AC_ARG_WITH(binutils-include,
 853   AS_HELP_STRING([--with-binutils-include],
 854     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 855   withval=default)
 856 case "$withval" in
 857   default) WITH_BINUTILS_INCDIR=default ;;
 858   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 859   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 860 esac
 861 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 862   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 863   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 864      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 865      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 866   fi
 867 fi
 868
 869 dnl Specify the URL where bug reports should be submitted.
 870 AC_ARG_WITH(bug-report-url,
 871   AS_HELP_STRING([--with-bug-report-url],
 872     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 873     withval="http://llvm.org/bugs/")
 874 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 875                    [Bug report URL.])
 876
 877 dnl --enable-libffi : check whether the user wants to turn off libffi:
 878 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 879   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 880   [case "$enableval" in
 881     yes) llvm_cv_enable_libffi="yes" ;;
 882     no)  llvm_cv_enable_libffi="no"  ;;
 883     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 884   esac],
 885   llvm_cv_enable_libffi=no)
 886
 887 dnl===-----------------------------------------------------------------------===
 888 dnl===
 889 dnl=== SECTION 4: Check for programs we need and that they are the right version
 890 dnl===
 891 dnl===-----------------------------------------------------------------------===
 892
 893 AC_PROG_NM
 894 AC_SUBST(NM)
 895
 896 dnl Check for the tools that the makefiles require
 897 AC_CHECK_GNU_MAKE
 898 AC_PROG_LN_S
 899 AC_PATH_PROG(CMP, [cmp], [cmp])
 900 AC_PATH_PROG(CP, [cp], [cp])
 901 AC_PATH_PROG(DATE, [date], [date])
 902 AC_PATH_PROG(FIND, [find], [find])
 903 AC_PATH_PROG(GREP, [grep], [grep])
 904 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 905 AC_PATH_PROG(MV,   [mv],   [mv])
 906 AC_PROG_RANLIB
 907 AC_CHECK_TOOL(AR, ar, false)
 908 AC_PATH_PROG(RM,   [rm],   [rm])
 909 AC_PATH_PROG(SED,  [sed],  [sed])
 910 AC_PATH_PROG(TAR,  [tar],  [gtar])
 911 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 912
 913 dnl Looking for misc. graph plotting software
 914 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 915 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 916   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 917   dnl If we're targeting for mingw we should emit windows paths, not msys
 918   if test "$llvm_cv_os_type" = "MingW" ; then
 919     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 920   fi
 921   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 922    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 923 fi
 924 AC_PATH_PROG(DOT, [dot], [echo dot])
 925 if test "$DOT" != "echo dot" ; then
 926   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 927   dnl If we're targeting for mingw we should emit windows paths, not msys
 928   if test "$llvm_cv_os_type" = "MingW" ; then
 929     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 930   fi
 931   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 932    [Define to path to dot program if found or 'echo dot' otherwise])
 933 fi
 934 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 935 if test "$FDP" != "echo fdp" ; then
 936   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 937   dnl If we're targeting for mingw we should emit windows paths, not msys
 938   if test "$llvm_cv_os_type" = "MingW" ; then
 939     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 940   fi
 941   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 942    [Define to path to fdp program if found or 'echo fdp' otherwise])
 943 fi
 944 AC_PATH_PROG(NEATO, [neato], [echo neato])
 945 if test "$NEATO" != "echo neato" ; then
 946   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 947   dnl If we're targeting for mingw we should emit windows paths, not msys
 948   if test "$llvm_cv_os_type" = "MingW" ; then
 949     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 950   fi
 951   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 952    [Define to path to neato program if found or 'echo neato' otherwise])
 953 fi
 954 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 955 if test "$TWOPI" != "echo twopi" ; then
 956   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 957   dnl If we're targeting for mingw we should emit windows paths, not msys
 958   if test "$llvm_cv_os_type" = "MingW" ; then
 959     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 960   fi
 961   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 962    [Define to path to twopi program if found or 'echo twopi' otherwise])
 963 fi
 964 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 965 if test "$CIRCO" != "echo circo" ; then
 966   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 967   dnl If we're targeting for mingw we should emit windows paths, not msys
 968   if test "$llvm_cv_os_type" = "MingW" ; then
 969     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 970   fi
 971   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 972    [Define to path to circo program if found or 'echo circo' otherwise])
 973 fi
 974 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 975 if test "$GV" != "echo gv" ; then
 976   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 977   dnl If we're targeting for mingw we should emit windows paths, not msys
 978   if test "$llvm_cv_os_type" = "MingW" ; then
 979     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 980   fi
 981   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 982    [Define to path to gv program if found or 'echo gv' otherwise])
 983 fi
 984 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 985 if test "$DOTTY" != "echo dotty" ; then
 986   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 987   dnl If we're targeting for mingw we should emit windows paths, not msys
 988   if test "$llvm_cv_os_type" = "MingW" ; then
 989     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 990   fi
 991   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 992    [Define to path to dotty program if found or 'echo dotty' otherwise])
 993 fi
 994 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
 995 if test "$XDOT_PY" != "echo xdot.py" ; then
 996   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
 997   dnl If we're targeting for mingw we should emit windows paths, not msys
 998   if test "$llvm_cv_os_type" = "MingW" ; then
 999     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1000   fi
1001   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1002    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1003 fi
1004
1005 dnl Look for a sufficiently recent version of Perl.
1006 LLVM_PROG_PERL([5.006])
1007 AC_SUBST(PERL)
1008 if test x"$PERL" = xnone; then
1009    AC_SUBST(HAVE_PERL,0)
1010    AC_MSG_ERROR([perl is required but was not found, please install it])
1011 else
1012    AC_SUBST(HAVE_PERL,1)
1013 fi
1014
1015 dnl Find the install program
1016 AC_PROG_INSTALL
1017 dnl Prepend src dir to install path dir if it's a relative path
1018 dnl This is a hack for installs that take place in something other
1019 dnl than the top level.
1020 case "$INSTALL" in
1021  [[\\/$]]* | ?:[[\\/]]* ) ;;
1022  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1023 esac
1024
1025 dnl Checks for documentation and testing tools that we can do without. If these
1026 dnl are not found then they are set to "true" which always succeeds but does
1027 dnl nothing. This just lets the build output show that we could have done
1028 dnl something if the tool was available.
1029 AC_PATH_PROG(BZIP2, [bzip2])
1030 AC_PATH_PROG(CAT, [cat])
1031 AC_PATH_PROG(DOXYGEN, [doxygen])
1032 AC_PATH_PROG(GROFF, [groff])
1033 AC_PATH_PROG(GZIPBIN, [gzip])
1034 AC_PATH_PROG(POD2HTML, [pod2html])
1035 AC_PATH_PROG(POD2MAN, [pod2man])
1036 AC_PATH_PROG(PDFROFF, [pdfroff])
1037 AC_PATH_PROG(RUNTEST, [runtest])
1038 DJ_AC_PATH_TCLSH
1039 AC_PATH_PROG(ZIP, [zip])
1040 AC_PATH_PROGS(OCAMLC, [ocamlc])
1041 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1042 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1043 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1044 AC_PATH_PROGS(GAS, [gas as])
1045
1046 dnl Get the version of the linker in use.
1047 AC_LINK_GET_VERSION
1048
1049 dnl Determine whether the linker supports the -R option.
1050 AC_LINK_USE_R
1051
1052 dnl Determine whether the linker supports the -export-dynamic option.
1053 AC_LINK_EXPORT_DYNAMIC
1054
1055 dnl Determine whether the linker supports the --version-script option.
1056 AC_LINK_VERSION_SCRIPT
1057
1058 dnl Check for libtool and the library that has dlopen function (which must come
1059 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1060 dnl libtool).
1061 AC_LIBTOOL_DLOPEN
1062 AC_LIB_LTDL
1063
1064 AC_MSG_CHECKING([tool compatibility])
1065
1066 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1067 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1068 dnl to support those options.
1069 dnl "icc" emits gcc signatures
1070 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1071 ICC=no
1072 IXX=no
1073 case $CC in
1074   icc*|icpc*)
1075     ICC=yes
1076     IXX=yes
1077     ;;
1078    *)
1079     ;;
1080 esac
1081
1082 if test "$GCC" != "yes" && test "$ICC" != "yes"
1083 then
1084   AC_MSG_ERROR([gcc|icc required but not found])
1085 fi
1086
1087 dnl Ensure that compilation tools are compatible with GCC extensions
1088 if test "$GXX" != "yes" && test "$IXX" != "yes"
1089 then
1090   AC_MSG_ERROR([g++|clang++|icc required but not found])
1091 fi
1092
1093 dnl Verify that GCC is version 3.0 or higher
1094 if test "$GCC" = "yes"
1095 then
1096   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1097 #error Unsupported GCC version
1098 #endif
1099 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1100 fi
1101
1102 dnl Check for GNU Make.  We use its extensions, so don't build without it
1103 if test -z "$llvm_cv_gnu_make_command"
1104 then
1105   AC_MSG_ERROR([GNU Make required but not found])
1106 fi
1107
1108 dnl Tool compatibility is okay if we make it here.
1109 AC_MSG_RESULT([ok])
1110
1111 dnl Check optional compiler flags.
1112 AC_MSG_CHECKING([optional compiler flags])
1113 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1114 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1115 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1116
1117 dnl===-----------------------------------------------------------------------===
1118 dnl===
1119 dnl=== SECTION 5: Check for libraries
1120 dnl===
1121 dnl===-----------------------------------------------------------------------===
1122
1123 AC_CHECK_LIB(m,sin)
1124 if test "$llvm_cv_os_type" = "MingW" ; then
1125   AC_CHECK_LIB(imagehlp, main)
1126   AC_CHECK_LIB(psapi, main)
1127 fi
1128
1129 dnl dlopen() is required for plugin support.
1130 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1131                [Define if dlopen() is available on this platform.]),
1132                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1133
1134 dnl libffi is optional; used to call external functions from the interpreter
1135 if test "$llvm_cv_enable_libffi" = "yes" ; then
1136   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1137                  [Define if libffi is available on this platform.]),
1138                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1139 fi
1140
1141 dnl mallinfo is optional; the code can compile (minus features) without it
1142 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1143                [Define if mallinfo() is available on this platform.]))
1144
1145 dnl pthread locking functions are optional - but llvm will not be thread-safe
1146 dnl without locks.
1147 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1148   AC_CHECK_LIB(pthread, pthread_mutex_init)
1149   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1150                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1151                            [Have pthread_mutex_lock]))
1152   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1153                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1154                  [Have pthread_rwlock_init]))
1155   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1156                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1157                  [Have pthread_getspecific]))
1158 fi
1159
1160 dnl Allow extra x86-disassembler library
1161 AC_ARG_WITH(udis86,
1162   AS_HELP_STRING([--with-udis86=<path>],
1163     [Use udis86 external x86 disassembler library]),
1164     [
1165       AC_SUBST(USE_UDIS86, [1])
1166       case "$withval" in
1167         /usr/lib|yes) ;;
1168         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1169       esac
1170       AC_CHECK_LIB(udis86, ud_init, [], [
1171         echo "Error! You need to have libudis86 around."
1172         exit -1
1173       ])
1174     ],
1175     AC_SUBST(USE_UDIS86, [0]))
1176 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1177                    [Define if use udis86 library])
1178
1179 dnl Allow OProfile support for JIT output.
1180 AC_ARG_WITH(oprofile,
1181   AS_HELP_STRING([--with-oprofile=<prefix>],
1182     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1183     [
1184       AC_SUBST(USE_OPROFILE, [1])
1185       case "$withval" in
1186         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1187         no) llvm_cv_oppath=
1188             AC_SUBST(USE_OPROFILE, [0]) ;;
1189         *) llvm_cv_oppath="${withval}/lib/oprofile"
1190            CPPFLAGS="-I${withval}/include";;
1191       esac
1192       if test -n "$llvm_cv_oppath" ; then
1193         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1194         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1195         dnl libbfd is not included properly in libopagent in some Debian
1196         dnl versions.  If libbfd isn't found at all, we assume opagent works
1197         dnl anyway.
1198         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1199         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1200           echo "Error! You need to have libopagent around."
1201           exit -1
1202         ])
1203         AC_CHECK_HEADER([opagent.h], [], [
1204           echo "Error! You need to have opagent.h around."
1205           exit -1
1206           ])
1207       fi
1208     ],
1209     [
1210       AC_SUBST(USE_OPROFILE, [0])
1211     ])
1212 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1213                    [Define if we have the oprofile JIT-support library])
1214
1215 dnl===-----------------------------------------------------------------------===
1216 dnl===
1217 dnl=== SECTION 6: Check for header files
1218 dnl===
1219 dnl===-----------------------------------------------------------------------===
1220
1221 dnl First, use autoconf provided macros for specific headers that we need
1222 dnl We don't check for ancient stuff or things that are guaranteed to be there
1223 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1224 dnl Generally we're looking for POSIX headers.
1225 AC_HEADER_DIRENT
1226 AC_HEADER_MMAP_ANONYMOUS
1227 AC_HEADER_STAT
1228 AC_HEADER_SYS_WAIT
1229 AC_HEADER_TIME
1230
1231 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1232 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1233 AC_CHECK_HEADERS([utime.h windows.h])
1234 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1235 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1236 AC_CHECK_HEADERS([valgrind/valgrind.h])
1237 AC_CHECK_HEADERS([fenv.h])
1238 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1239   AC_CHECK_HEADERS(pthread.h,
1240                    AC_SUBST(HAVE_PTHREAD, 1),
1241                    AC_SUBST(HAVE_PTHREAD, 0))
1242 else
1243   AC_SUBST(HAVE_PTHREAD, 0)
1244 fi
1245
1246 dnl Try to find ffi.h.
1247 if test "$llvm_cv_enable_libffi" = "yes" ; then
1248   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1249 fi
1250
1251 dnl Try to find Darwin specific crash reporting libraries.
1252 AC_CHECK_HEADERS([CrashReporterClient.h])
1253
1254 dnl Try to find Darwin specific crash reporting global.
1255 AC_MSG_CHECKING([__crashreporter_info__])
1256 AC_LINK_IFELSE(
1257   AC_LANG_SOURCE(
1258     [[extern const char *__crashreporter_info__;
1259       int main() {
1260         __crashreporter_info__ = "test";
1261         return 0;
1262       }
1263     ]]),
1264   AC_MSG_RESULT(yes)
1265   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1266   AC_MSG_RESULT(no)
1267   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1268             Define if __crashreporter_info__ exists.))
1269
1270 dnl===-----------------------------------------------------------------------===
1271 dnl===
1272 dnl=== SECTION 7: Check for types and structures
1273 dnl===
1274 dnl===-----------------------------------------------------------------------===
1275
1276 AC_HUGE_VAL_CHECK
1277 AC_TYPE_PID_T
1278 AC_TYPE_SIZE_T
1279 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1280 AC_STRUCT_TM
1281 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1282 AC_CHECK_TYPES([uint64_t],,
1283          AC_CHECK_TYPES([u_int64_t],,
1284          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1285
1286 dnl===-----------------------------------------------------------------------===
1287 dnl===
1288 dnl=== SECTION 8: Check for specific functions needed
1289 dnl===
1290 dnl===-----------------------------------------------------------------------===
1291
1292 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1293 AC_CHECK_FUNCS([powf fmodf strtof round ])
1294 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1295 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1296 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit strdup ])
1297 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1298 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1299 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1300 AC_C_PRINTF_A
1301 AC_FUNC_RAND48
1302
1303 dnl Check the declaration "Secure API" on Windows environments.
1304 AC_CHECK_DECLS([strerror_s])
1305
1306 dnl Check symbols in libgcc.a for JIT on Mingw.
1307 if test "$llvm_cv_os_type" = "MingW" ; then
1308   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1309   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1310   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1311   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1312
1313   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1314   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1315   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1316   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1317   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1318   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1319   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1320   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1321   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1322   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1323
1324   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1325   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1326 fi
1327
1328 dnl Check Win32 API EnumerateLoadedModules.
1329 if test "$llvm_cv_os_type" = "MingW" ; then
1330   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1331   AC_COMPILE_IFELSE([[#include <windows.h>
1332 #include <imagehlp.h>
1333 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1334 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1335 [
1336   AC_MSG_RESULT([yes])
1337   llvm_cv_win32_elmcb_pcstr="PCSTR"
1338 ],
1339 [
1340   AC_MSG_RESULT([no])
1341   llvm_cv_win32_elmcb_pcstr="PSTR"
1342 ])
1343   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1344 fi
1345
1346 dnl Check for variations in the Standard C++ library and STL. These macros are
1347 dnl provided by LLVM in the autoconf/m4 directory.
1348 AC_FUNC_ISNAN
1349 AC_FUNC_ISINF
1350
1351 dnl Check for mmap support.We also need to know if /dev/zero is required to
1352 dnl be opened for allocating RWX memory.
1353 dnl Make sure we aren't attempting to configure for an unknown system
1354 if test "$llvm_cv_platform_type" = "Unix" ; then
1355   AC_FUNC_MMAP
1356   AC_FUNC_MMAP_FILE
1357   AC_NEED_DEV_ZERO_FOR_MMAP
1358
1359   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1360   then
1361     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1362   fi
1363   if test "$ac_cv_func_mmap_file" = "no"
1364   then
1365     AC_MSG_WARN([mmap() of files required but not found])
1366   fi
1367 fi
1368
1369 dnl atomic builtins are required for threading support.
1370 AC_MSG_CHECKING(for GCC atomic builtins)
1371 dnl Since we'll be using these atomic builtins in C++ files we should test
1372 dnl the C++ compiler.
1373 AC_LANG_PUSH([C++])
1374 AC_LINK_IFELSE(
1375   AC_LANG_SOURCE(
1376     [[int main() {
1377         volatile unsigned long val = 1;
1378         __sync_synchronize();
1379         __sync_val_compare_and_swap(&val, 1, 0);
1380         __sync_add_and_fetch(&val, 1);
1381         __sync_sub_and_fetch(&val, 1);
1382         return 0;
1383       }
1384     ]]),
1385   AC_LANG_POP([C++])
1386   AC_MSG_RESULT(yes)
1387   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1388   AC_MSG_RESULT(no)
1389   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1390   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1391
1392 dnl===-----------------------------------------------------------------------===
1393 dnl===
1394 dnl=== SECTION 9: Additional checks, variables, etc.
1395 dnl===
1396 dnl===-----------------------------------------------------------------------===
1397
1398 dnl Handle 32-bit linux systems running a 64-bit kernel.
1399 dnl This has to come after section 4 because it invokes the compiler.
1400 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1401   AC_IS_LINUX_MIXED
1402   if test "$llvm_cv_linux_mixed" = "yes"; then
1403     llvm_cv_target_arch="x86"
1404     ARCH="x86"
1405   fi
1406 fi
1407
1408 dnl Check whether __dso_handle is present
1409 AC_CHECK_FUNCS([__dso_handle])
1410
1411 dnl Propagate the shared library extension that the libltdl checks did to
1412 dnl the Makefiles so we can use it there too
1413 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1414
1415 dnl Propagate the run-time library path variable that the libltdl
1416 dnl checks found to the Makefiles so we can use it there too
1417 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1418
1419 # Translate the various configuration directories and other basic
1420 # information into substitutions that will end up in Makefile.config.in
1421 # that these configured values can be used by the makefiles
1422 if test "${prefix}" = "NONE" ; then
1423   prefix="/usr/local"
1424 fi
1425 eval LLVM_PREFIX="${prefix}";
1426 eval LLVM_BINDIR="${prefix}/bin";
1427 eval LLVM_LIBDIR="${prefix}/lib";
1428 eval LLVM_DATADIR="${prefix}/share/llvm";
1429 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1430 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1431 eval LLVM_INCLUDEDIR="${prefix}/include";
1432 eval LLVM_INFODIR="${prefix}/info";
1433 eval LLVM_MANDIR="${prefix}/man";
1434 LLVM_CONFIGTIME=`date`
1435 AC_SUBST(LLVM_PREFIX)
1436 AC_SUBST(LLVM_BINDIR)
1437 AC_SUBST(LLVM_LIBDIR)
1438 AC_SUBST(LLVM_DATADIR)
1439 AC_SUBST(LLVM_DOCSDIR)
1440 AC_SUBST(LLVM_ETCDIR)
1441 AC_SUBST(LLVM_INCLUDEDIR)
1442 AC_SUBST(LLVM_INFODIR)
1443 AC_SUBST(LLVM_MANDIR)
1444 AC_SUBST(LLVM_CONFIGTIME)
1445
1446 # Place the various directores into the config.h file as #defines so that we
1447 # can know about the installation paths within LLVM.
1448 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1449                    [Installation prefix directory])
1450 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1451                    [Installation directory for binary executables])
1452 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1453                    [Installation directory for libraries])
1454 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1455                    [Installation directory for data files])
1456 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1457                    [Installation directory for documentation])
1458 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1459                    [Installation directory for config files])
1460 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1461                    [Installation directory for include files])
1462 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1463                    [Installation directory for .info files])
1464 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1465                    [Installation directory for man pages])
1466 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1467                    [Time at which LLVM was configured])
1468 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1469                    [Target triple LLVM will generate code for by default])
1470
1471 # Determine which bindings to build.
1472 if test "$BINDINGS_TO_BUILD" = auto ; then
1473   BINDINGS_TO_BUILD=""
1474   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1475     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1476   fi
1477 fi
1478 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1479
1480 # This isn't really configurey, but it avoids having to repeat the list in
1481 # other files.
1482 AC_SUBST(ALL_BINDINGS,ocaml)
1483
1484 # Do any work necessary to ensure that bindings have what they need.
1485 binding_prereqs_failed=0
1486 for a_binding in $BINDINGS_TO_BUILD ; do
1487   case "$a_binding" in
1488   ocaml)
1489     if test "x$OCAMLC" = x ; then
1490       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1491       binding_prereqs_failed=1
1492     fi
1493     if test "x$OCAMLDEP" = x ; then
1494       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1495       binding_prereqs_failed=1
1496     fi
1497     if test "x$OCAMLOPT" = x ; then
1498       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1499       dnl ocamlopt is optional!
1500     fi
1501     if test "x$with_ocaml_libdir" != xauto ; then
1502       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1503     else
1504       ocaml_stdlib="`"$OCAMLC" -where`"
1505       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1506       then
1507         # ocaml stdlib is beneath our prefix; use stdlib
1508         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1509       else
1510         # ocaml stdlib is outside our prefix; use libdir/ocaml
1511         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1512       fi
1513     fi
1514     ;;
1515   esac
1516 done
1517 if test "$binding_prereqs_failed" = 1 ; then
1518   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1519 fi
1520
1521 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1522 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1523
1524 dnl Determine linker rpath flag
1525 if test "$llvm_cv_link_use_r" = "yes" ; then
1526   RPATH="-Wl,-R"
1527 else
1528   RPATH="-Wl,-rpath"
1529 fi
1530 AC_SUBST(RPATH)
1531
1532 dnl Determine linker rdynamic flag
1533 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1534   RDYNAMIC="-Wl,-export-dynamic"
1535 else
1536   RDYNAMIC=""
1537 fi
1538 AC_SUBST(RDYNAMIC)
1539
1540 dnl===-----------------------------------------------------------------------===
1541 dnl===
1542 dnl=== SECTION 10: Specify the output files and generate it
1543 dnl===
1544 dnl===-----------------------------------------------------------------------===
1545
1546 dnl Configure header files
1547 dnl WARNING: dnl If you add or remove any of the following config headers, then
1548 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1549 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1550 dnl files can be updated automatically when their *.in sources change.
1551 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1552 AH_TOP([#ifndef CONFIG_H
1553 #define CONFIG_H])
1554 AH_BOTTOM([#endif])
1555
1556 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1557 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1558 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1559 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1560 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1561
1562 dnl Configure the makefile's configuration data
1563 AC_CONFIG_FILES([Makefile.config])
1564
1565 dnl Configure the RPM spec file for LLVM
1566 AC_CONFIG_FILES([llvm.spec])
1567
1568 dnl Configure doxygen's configuration file
1569 AC_CONFIG_FILES([docs/doxygen.cfg])
1570 if test -f ${srcdir}/tools/clang/README.txt; then
1571   AC_CONFIG_FILES([tools/clang/docs/doxygen.cfg])
1572 fi
1573
1574 dnl Do the first stage of configuration for llvm-config.in.
1575 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1576
1577 dnl OCaml findlib META file
1578 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1579
1580 dnl Do special configuration of Makefiles
1581 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1582 AC_CONFIG_MAKEFILE(Makefile)
1583 AC_CONFIG_MAKEFILE(Makefile.common)
1584 AC_CONFIG_MAKEFILE(examples/Makefile)
1585 AC_CONFIG_MAKEFILE(lib/Makefile)
1586 AC_CONFIG_MAKEFILE(runtime/Makefile)
1587 AC_CONFIG_MAKEFILE(test/Makefile)
1588 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1589 AC_CONFIG_MAKEFILE(unittests/Makefile)
1590 AC_CONFIG_MAKEFILE(tools/Makefile)
1591 AC_CONFIG_MAKEFILE(utils/Makefile)
1592 AC_CONFIG_MAKEFILE(projects/Makefile)
1593 AC_CONFIG_MAKEFILE(bindings/Makefile)
1594 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1595
1596 dnl Finally, crank out the output
1597 AC_OUTPUT