autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.5svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [5], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  63 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  64 : ${CFLAGS=}
  65 : ${CXXFLAGS=}
  66
  67 dnl We need to check for the compiler up here to avoid anything else
  68 dnl starting with a different one.
  69 AC_PROG_CC(clang gcc)
  70 AC_PROG_CXX(clang++ g++)
  71 AC_PROG_CPP
  72
  73 dnl If CXX is Clang, check that it can find and parse C++ standard library
  74 dnl headers.
  75 if test "$CXX" = "clang++" ; then
  76   AC_MSG_CHECKING([whether clang works])
  77   AC_LANG_PUSH([C++])
  78   dnl Note that space between 'include' and '(' is required.  There's a broken
  79   dnl regex in aclocal that otherwise will think that we call m4's include
  80   dnl builtin.
  81   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  82 #if __has_include (<cxxabi.h>)
  83 #include <cxxabi.h>
  84 #endif
  85 #if __has_include (<unwind.h>)
  86 #include <unwind.h>
  87 #endif
  88 ]])],
  89 [
  90   AC_MSG_RESULT([yes])
  91 ],
  92 [
  93   AC_MSG_RESULT([no])
  94   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
  95 ])
  96   AC_LANG_POP([C++])
  97 fi
  98
  99 dnl Set up variables that track whether the host compiler is GCC or Clang where
 100 dnl we can effectively sanity check them. We don't try to sanity check all the
 101 dnl other possible compilers.
 102 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
 103 AC_LANG_PUSH([C++])
 104 llvm_cv_cxx_compiler=unknown
 105 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
 106                                     #error
 107                                     #endif
 108                                     ]])],
 109                   llvm_cv_cxx_compiler=clang,
 110                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
 111                                                        #error
 112                                                        #endif
 113                                                        ]])],
 114                                      llvm_cv_cxx_compiler=gcc, [])])
 115 AC_LANG_POP([C++])
 116 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
 117
 118 dnl Configure all of the projects present in our source tree. While we could
 119 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 120 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 121 dnl Instead we match on the known projects.
 122
 123 dnl
 124 dnl One tricky part of doing this is that some projects depend upon other
 125 dnl projects.  For example, several projects rely upon the LLVM test suite.
 126 dnl We want to configure those projects first so that their object trees are
 127 dnl created before running the configure scripts of projects that depend upon
 128 dnl them.
 129 dnl
 130
 131 dnl Several projects use the LLVM test suite, so configure it next.
 132 if test -d ${srcdir}/projects/test-suite ; then
 133   AC_CONFIG_SUBDIRS([projects/test-suite])
 134 fi
 135
 136 dnl llvm-test is the old name of the test-suite, kept here for backwards
 137 dnl compatibility
 138 if test -d ${srcdir}/projects/llvm-test ; then
 139   AC_CONFIG_SUBDIRS([projects/llvm-test])
 140 fi
 141
 142 dnl Some projects use poolalloc; configure that next
 143 if test -d ${srcdir}/projects/poolalloc ; then
 144   AC_CONFIG_SUBDIRS([projects/poolalloc])
 145 fi
 146
 147 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 148   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 149 fi
 150
 151 dnl Check for all other projects
 152 for i in `ls ${srcdir}/projects`
 153 do
 154   if test -d ${srcdir}/projects/${i} ; then
 155     case ${i} in
 156       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 157       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 158       compiler-rt)       ;;
 159       test-suite)     ;;
 160       llvm-test)      ;;
 161       poolalloc)      ;;
 162       llvm-poolalloc) ;;
 163       *)
 164         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 165         ;;
 166     esac
 167   fi
 168 done
 169
 170 dnl Disable the build of polly, even if it is checked out into tools/polly.
 171 AC_ARG_ENABLE(polly,
 172               AS_HELP_STRING([--enable-polly],
 173                              [Use polly if available (default is YES)]),,
 174                              enableval=default)
 175 case "$enableval" in
 176   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 177   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 178   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 179   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 180 esac
 181
 182
 183 dnl Check if polly is checked out into tools/polly and configure it if
 184 dnl available.
 185 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 186   AC_SUBST(LLVM_HAS_POLLY,1)
 187   AC_CONFIG_SUBDIRS([tools/polly])
 188 fi
 189
 190 dnl===-----------------------------------------------------------------------===
 191 dnl===
 192 dnl=== SECTION 2: Architecture, target, and host checks
 193 dnl===
 194 dnl===-----------------------------------------------------------------------===
 195
 196 dnl Check the target for which we're compiling and the host that will do the
 197 dnl compilations. This will tell us which LLVM compiler will be used for
 198 dnl compiling SSA into object code. This needs to be done early because
 199 dnl following tests depend on it.
 200 AC_CANONICAL_TARGET
 201
 202 dnl Determine the platform type and cache its value. This helps us configure
 203 dnl the System library to the correct build platform.
 204 AC_CACHE_CHECK([type of operating system we're going to host on],
 205                [llvm_cv_os_type],
 206 [case $host in
 207   *-*-aix*)
 208     llvm_cv_link_all_option="-Wl,--whole-archive"
 209     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 210     llvm_cv_os_type="AIX"
 211     llvm_cv_platform_type="Unix" ;;
 212   *-*-irix*)
 213     llvm_cv_link_all_option="-Wl,--whole-archive"
 214     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 215     llvm_cv_os_type="IRIX"
 216     llvm_cv_platform_type="Unix" ;;
 217   *-*-cygwin*)
 218     llvm_cv_link_all_option="-Wl,--whole-archive"
 219     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 220     llvm_cv_os_type="Cygwin"
 221     llvm_cv_platform_type="Unix" ;;
 222   *-*-darwin*)
 223     llvm_cv_link_all_option="-Wl,-all_load"
 224     llvm_cv_no_link_all_option="-Wl,-noall_load"
 225     llvm_cv_os_type="Darwin"
 226     llvm_cv_platform_type="Unix" ;;
 227   *-*-minix*)
 228     llvm_cv_link_all_option="-Wl,-all_load"
 229     llvm_cv_no_link_all_option="-Wl,-noall_load"
 230     llvm_cv_os_type="Minix"
 231     llvm_cv_platform_type="Unix" ;;
 232   *-*-freebsd*)
 233     llvm_cv_link_all_option="-Wl,--whole-archive"
 234     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 235     llvm_cv_os_type="FreeBSD"
 236     llvm_cv_platform_type="Unix" ;;
 237   *-*-kfreebsd-gnu)
 238     llvm_cv_link_all_option="-Wl,--whole-archive"
 239     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 240     llvm_cv_os_type="GNU/kFreeBSD"
 241     llvm_cv_platform_type="Unix" ;;
 242   *-*-openbsd*)
 243     llvm_cv_link_all_option="-Wl,--whole-archive"
 244     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 245     llvm_cv_os_type="OpenBSD"
 246     llvm_cv_platform_type="Unix" ;;
 247   *-*-netbsd*)
 248     llvm_cv_link_all_option="-Wl,--whole-archive"
 249     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 250     llvm_cv_os_type="NetBSD"
 251     llvm_cv_platform_type="Unix" ;;
 252   *-*-dragonfly*)
 253     llvm_cv_link_all_option="-Wl,--whole-archive"
 254     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 255     llvm_cv_os_type="DragonFly"
 256     llvm_cv_platform_type="Unix" ;;
 257   *-*-hpux*)
 258     llvm_cv_link_all_option="-Wl,--whole-archive"
 259     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 260     llvm_cv_os_type="HP-UX"
 261     llvm_cv_platform_type="Unix" ;;
 262   *-*-interix*)
 263     llvm_cv_link_all_option="-Wl,--whole-archive"
 264     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 265     llvm_cv_os_type="Interix"
 266     llvm_cv_platform_type="Unix" ;;
 267   *-*-linux*)
 268     llvm_cv_link_all_option="-Wl,--whole-archive"
 269     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 270     llvm_cv_os_type="Linux"
 271     llvm_cv_platform_type="Unix" ;;
 272   *-*-gnu*)
 273     llvm_cv_link_all_option="-Wl,--whole-archive"
 274     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 275     llvm_cv_os_type="GNU"
 276     llvm_cv_platform_type="Unix" ;;
 277   *-*-solaris*)
 278     llvm_cv_link_all_option="-Wl,-z,allextract"
 279     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 280     llvm_cv_os_type="SunOS"
 281     llvm_cv_platform_type="Unix" ;;
 282   *-*-auroraux*)
 283     llvm_cv_link_all_option="-Wl,-z,allextract"
 284     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 285     llvm_cv_os_type="AuroraUX"
 286     llvm_cv_platform_type="Unix" ;;
 287   *-*-win32*)
 288     llvm_cv_link_all_option="-Wl,--whole-archive"
 289     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 290     llvm_cv_os_type="Win32"
 291     llvm_cv_platform_type="Win32" ;;
 292   *-*-mingw*)
 293     llvm_cv_link_all_option="-Wl,--whole-archive"
 294     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 295     llvm_cv_os_type="MingW"
 296     llvm_cv_platform_type="Win32" ;;
 297   *-*-haiku*)
 298     llvm_cv_link_all_option="-Wl,--whole-archive"
 299     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 300     llvm_cv_os_type="Haiku"
 301     llvm_cv_platform_type="Unix" ;;
 302   *-unknown-eabi*)
 303     llvm_cv_link_all_option="-Wl,--whole-archive"
 304     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 305     llvm_cv_os_type="Freestanding"
 306     llvm_cv_platform_type="Unix" ;;
 307   *-unknown-elf*)
 308     llvm_cv_link_all_option="-Wl,--whole-archive"
 309     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 310     llvm_cv_os_type="Freestanding"
 311     llvm_cv_platform_type="Unix" ;;
 312   *)
 313     llvm_cv_link_all_option=""
 314     llvm_cv_no_link_all_option=""
 315     llvm_cv_os_type="Unknown"
 316     llvm_cv_platform_type="Unknown" ;;
 317 esac])
 318
 319 AC_CACHE_CHECK([type of operating system we're going to target],
 320                [llvm_cv_target_os_type],
 321 [case $target in
 322   *-*-aix*)
 323     llvm_cv_target_os_type="AIX" ;;
 324   *-*-irix*)
 325     llvm_cv_target_os_type="IRIX" ;;
 326   *-*-cygwin*)
 327     llvm_cv_target_os_type="Cygwin" ;;
 328   *-*-darwin*)
 329     llvm_cv_target_os_type="Darwin" ;;
 330   *-*-minix*)
 331     llvm_cv_target_os_type="Minix" ;;
 332   *-*-freebsd*)
 333     llvm_cv_target_os_type="FreeBSD" ;;
 334   *-*-kfreebsd-gnu)
 335     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 336   *-*-openbsd*)
 337     llvm_cv_target_os_type="OpenBSD" ;;
 338   *-*-netbsd*)
 339     llvm_cv_target_os_type="NetBSD" ;;
 340   *-*-dragonfly*)
 341     llvm_cv_target_os_type="DragonFly" ;;
 342   *-*-hpux*)
 343     llvm_cv_target_os_type="HP-UX" ;;
 344   *-*-interix*)
 345     llvm_cv_target_os_type="Interix" ;;
 346   *-*-linux*)
 347     llvm_cv_target_os_type="Linux" ;;
 348   *-*-gnu*)
 349     llvm_cv_target_os_type="GNU" ;;
 350   *-*-solaris*)
 351     llvm_cv_target_os_type="SunOS" ;;
 352   *-*-auroraux*)
 353     llvm_cv_target_os_type="AuroraUX" ;;
 354   *-*-win32*)
 355     llvm_cv_target_os_type="Win32" ;;
 356   *-*-mingw*)
 357     llvm_cv_target_os_type="MingW" ;;
 358   *-*-haiku*)
 359     llvm_cv_target_os_type="Haiku" ;;
 360   *-*-rtems*)
 361     llvm_cv_target_os_type="RTEMS" ;;
 362   *-*-nacl*)
 363     llvm_cv_target_os_type="NativeClient" ;;
 364   *-unknown-eabi*)
 365     llvm_cv_target_os_type="Freestanding" ;;
 366   *)
 367     llvm_cv_target_os_type="Unknown" ;;
 368 esac])
 369
 370 dnl Make sure we aren't attempting to configure for an unknown system
 371 if test "$llvm_cv_os_type" = "Unknown" ; then
 372   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 373 fi
 374
 375 dnl Set the "OS" Makefile variable based on the platform type so the
 376 dnl makefile can configure itself to specific build hosts
 377 AC_SUBST(OS,$llvm_cv_os_type)
 378 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 379 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 380
 381 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 382 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 383 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 384
 385 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 386 dnl This is used by lib/Support to determine the basic kind of implementation
 387 dnl to use.
 388 case $llvm_cv_platform_type in
 389   Unix)
 390     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 391     AC_SUBST(LLVM_ON_UNIX,[1])
 392     AC_SUBST(LLVM_ON_WIN32,[0])
 393     ;;
 394   Win32)
 395     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 396     AC_SUBST(LLVM_ON_UNIX,[0])
 397     AC_SUBST(LLVM_ON_WIN32,[1])
 398     ;;
 399 esac
 400
 401 dnl Determine what our target architecture is and configure accordingly.
 402 dnl This will allow Makefiles to make a distinction between the hardware and
 403 dnl the OS.
 404 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 405 [case $target in
 406   i?86-*)                 llvm_cv_target_arch="x86" ;;
 407   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 408   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 409   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 410   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 411   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 412   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 413   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 414   xcore-*)                llvm_cv_target_arch="XCore" ;;
 415   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 416   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 417   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 418   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 419   *)                      llvm_cv_target_arch="Unknown" ;;
 420 esac])
 421
 422 if test "$llvm_cv_target_arch" = "Unknown" ; then
 423   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 424 fi
 425
 426 dnl Determine the LLVM native architecture for the target
 427 case "$llvm_cv_target_arch" in
 428     x86)     LLVM_NATIVE_ARCH="X86" ;;
 429     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 430     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 431 esac
 432
 433 dnl Define a substitution, ARCH, for the target architecture
 434 AC_SUBST(ARCH,$llvm_cv_target_arch)
 435
 436 dnl Determine what our host architecture.
 437 dnl This will allow MCJIT regress tests runs only for supported
 438 dnl platforms.
 439 case $host in
 440   i?86-*)                 host_arch="x86" ;;
 441   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 442   sparc*-*)               host_arch="Sparc" ;;
 443   powerpc*-*)             host_arch="PowerPC" ;;
 444   arm*-*)                 host_arch="ARM" ;;
 445   aarch64*-*)             host_arch="AArch64" ;;
 446   mips-* | mips64-*)      host_arch="Mips" ;;
 447   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 448   xcore-*)                host_arch="XCore" ;;
 449   msp430-*)               host_arch="MSP430" ;;
 450   hexagon-*)              host_arch="Hexagon" ;;
 451   s390x-*)                host_arch="SystemZ" ;;
 452   *)                      host_arch="Unknown" ;;
 453 esac
 454
 455 if test "$host_arch" = "Unknown" ; then
 456   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 457 fi
 458
 459 AC_SUBST(HOST_ARCH,$host_arch)
 460
 461 dnl Check for build platform executable suffix if we're cross-compiling
 462 if test "$cross_compiling" = yes; then
 463   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 464   AC_BUILD_EXEEXT
 465   ac_build_prefix=${build_alias}-
 466   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 467   if test -z "$BUILD_CXX"; then
 468      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 469      if test -z "$BUILD_CXX"; then
 470        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 471      fi
 472   fi
 473 else
 474   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 475 fi
 476
 477 dnl Check to see if there's a .svn or .git directory indicating that this
 478 dnl build is being done from a checkout. This sets up several defaults for
 479 dnl the command line switches. When we build with a checkout directory,
 480 dnl we get a debug with assertions turned on. Without, we assume a source
 481 dnl release and we get an optimized build without assertions.
 482 dnl See --enable-optimized and --enable-assertions below
 483 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 484   cvsbuild="yes"
 485   optimize="no"
 486   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 487 else
 488   cvsbuild="no"
 489   optimize="yes"
 490 fi
 491
 492 dnl===-----------------------------------------------------------------------===
 493 dnl===
 494 dnl=== SECTION 3: Command line arguments for the configure script.
 495 dnl===
 496 dnl===-----------------------------------------------------------------------===
 497
 498 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 499 AC_ARG_ENABLE(libcpp,
 500               AS_HELP_STRING([--enable-libcpp],
 501                              [Use libc++ if available (default is NO)]),,
 502                              enableval=default)
 503 case "$enableval" in
 504   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 505   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 506   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 507   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 508 esac
 509
 510 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
 511 dnl be bypassed by passing a flag if necessary on a platform. We have to do
 512 dnl these checks here so that we have the configuration of the standard C++
 513 dnl library finished.
 514 AC_ARG_ENABLE(compiler-version-checks,
 515               AS_HELP_STRING([--enable-compiler-version-checks],
 516                              [Check the version of the host compiler (default is YES)]),,
 517                              enableval=default)
 518 case "$enableval" in
 519   no)
 520     ;;
 521   yes|default)
 522     AC_LANG_PUSH([C++])
 523     case "$llvm_cv_cxx_compiler" in
 524     clang)
 525       AC_MSG_CHECKING([whether Clang is new enough])
 526       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 527 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
 528 #error This version of Clang is too old to build LLVM
 529 #endif
 530 ]])],
 531           [AC_MSG_RESULT([yes])],
 532           [AC_MSG_RESULT([no])
 533            AC_MSG_ERROR([
 534 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
 535 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
 536 bypass these sanity checks.])])
 537
 538       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
 539       dnl are sometimes deeply confusing though. Here we test for an obvious
 540       dnl incomplete feature in 4.6's standard library that was completed in
 541       dnl 4.7's. We also have to disable this test if 'ENABLE_LIBCPP' is set
 542       dnl because the enable flags don't actually fix CXXFLAGS, they rely on
 543       dnl that happening in the Makefile.
 544       if test "$ENABLE_LIBCPP" -eq 0 ; then
 545         AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
 546         llvm_cv_old_cxxflags="$CXXFLAGS"
 547         CXXFLAGS="$CXXFLAGS -std=c++0x"
 548         AC_LINK_IFELSE([AC_LANG_SOURCE([[
 549 #include <atomic>
 550 std::atomic<float> x(0.0f);
 551 int main() { return (float)x; }
 552 ]])],
 553             [AC_MSG_RESULT([yes])],
 554             [AC_MSG_RESULT([no])
 555              AC_MSG_ERROR([
 556 We detected a missing feature in the standard C++ library that was known to be
 557 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
 558 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
 559 than 4.7. You will need to update your system and ensure Clang uses the newer
 560 standard library.
 561
 562 If this error is incorrect or you need to force things to work, you may pass
 563 '--disable-compiler-version-checks' to configure to bypass this test.])])
 564         CXXFLAGS="$llvm_cv_old_cxxflags"
 565       fi
 566       ;;
 567     gcc)
 568       AC_MSG_CHECKING([whether GCC is new enough])
 569       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 570 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 571 #error This version of GCC is too old to build LLVM
 572 #endif
 573 ]])],
 574           [AC_MSG_RESULT([yes])],
 575           [AC_MSG_RESULT([no])
 576            AC_MSG_ERROR([
 577 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
 578 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
 579 bypass these sanity checks.])])
 580       ;;
 581     unknown)
 582       ;;
 583     esac
 584     AC_LANG_POP([C++])
 585     ;;
 586   *)
 587     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
 588     ;;
 589 esac
 590
 591 dnl --enable-cxx11 : check whether or not to use -std=c++11 on the command line
 592 AC_ARG_ENABLE(cxx11,
 593               AS_HELP_STRING([--enable-cxx11],
 594                              [Use c++11 if available (default is NO)]),,
 595                              enableval=default)
 596 case "$enableval" in
 597   yes) AC_SUBST(ENABLE_CXX11,[1]) ;;
 598   no)  AC_SUBST(ENABLE_CXX11,[0]) ;;
 599   default) AC_SUBST(ENABLE_CXX11,[0]);;
 600   *) AC_MSG_ERROR([Invalid setting for --enable-cxx11. Use "yes" or "no"]) ;;
 601 esac
 602
 603 dnl --enable-fission : check whether or not to use -gsplit-dwarf on the command
 604 dnl line
 605 AC_ARG_ENABLE(split-dwarf,
 606               AS_HELP_STRING([--enable-split-dwarf],
 607                              [Use split-dwarf if available (default is NO)]),,
 608                              enableval=default)
 609 case "$enableval" in
 610   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 611   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 612   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 613   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 614 esac
 615
 616 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 617 clang_arcmt="yes"
 618 AC_ARG_ENABLE(clang-arcmt,
 619               AS_HELP_STRING([--enable-clang-arcmt],
 620                              [Enable building of clang ARCMT (default is YES)]),
 621                              clang_arcmt="$enableval",
 622                              enableval="yes")
 623 case "$enableval" in
 624   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 625   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 626   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 627   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 628 esac
 629
 630 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 631 clang_static_analyzer="yes"
 632 AC_ARG_ENABLE(clang-static-analyzer,
 633               AS_HELP_STRING([--enable-clang-static-analyzer],
 634                              [Enable building of clang Static Analyzer (default is YES)]),
 635                              clang_static_analyzer="$enableval",
 636                              enableval="yes")
 637 case "$enableval" in
 638   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 639   no)
 640     if test ${clang_arcmt} != "no" ; then
 641       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 642     fi
 643     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 644     ;;
 645   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 646   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 647 esac
 648
 649 dnl --enable-clang-rewriter: check whether to enable clang rewriter
 650 AC_ARG_ENABLE(clang-rewriter,
 651               AS_HELP_STRING([--enable-clang-rewriter],
 652                              [Enable building of clang rewriter (default is YES)]),,
 653                              enableval="yes")
 654 case "$enableval" in
 655   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
 656   no)
 657     if test ${clang_arcmt} != "no" ; then
 658       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
 659     fi
 660     if test ${clang_static_analyzer} != "no" ; then
 661       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
 662     fi
 663     AC_SUBST(ENABLE_CLANG_REWRITER,[0])
 664     ;;
 665   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
 666   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
 667 esac
 668
 669 dnl --enable-optimized : check whether they want to do an optimized build:
 670 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 671  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 672 if test ${enableval} = "no" ; then
 673   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 674 else
 675   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 676 fi
 677
 678 dnl --enable-profiling : check whether they want to do a profile build:
 679 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 680  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 681 if test ${enableval} = "no" ; then
 682   AC_SUBST(ENABLE_PROFILING,[[]])
 683 else
 684   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 685 fi
 686
 687 dnl --enable-assertions : check whether they want to turn on assertions or not:
 688 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 689   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 690 if test ${enableval} = "yes" ; then
 691   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 692 else
 693   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 694 fi
 695
 696 dnl --enable-werror : check whether we want Werror on by default
 697 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 698   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 699 case "$enableval" in
 700   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 701   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 702   default) AC_SUBST(ENABLE_WERROR,[0]);;
 703   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 704 esac
 705
 706 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 707 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 708   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 709 if test ${enableval} = "yes" ; then
 710   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 711   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 712 else
 713   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 714   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 715 fi
 716
 717 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 718 AC_ARG_ENABLE(debug-runtime,
 719    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 720 if test ${enableval} = "no" ; then
 721   AC_SUBST(DEBUG_RUNTIME,[[]])
 722 else
 723   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 724 fi
 725
 726 dnl --enable-debug-symbols : should even optimized compiler libraries
 727 dnl have debug symbols?
 728 AC_ARG_ENABLE(debug-symbols,
 729    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 730 if test ${enableval} = "no" ; then
 731   AC_SUBST(DEBUG_SYMBOLS,[[]])
 732 else
 733   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 734 fi
 735
 736 dnl --enable-keep-symbols : do not strip installed executables
 737 AC_ARG_ENABLE(keep-symbols,
 738    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 739 if test ${enableval} = "no" ; then
 740   AC_SUBST(KEEP_SYMBOLS,[[]])
 741 else
 742   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 743 fi
 744
 745 dnl --enable-jit: check whether they want to enable the jit
 746 AC_ARG_ENABLE(jit,
 747   AS_HELP_STRING(--enable-jit,
 748                  [Enable Just In Time Compiling (default is YES)]),,
 749   enableval=default)
 750 if test ${enableval} = "no"
 751 then
 752   AC_SUBST(JIT,[[]])
 753 else
 754   case "$llvm_cv_target_arch" in
 755     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 756     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 757     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 758     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 759     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 760     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 761     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 762     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 763     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 764     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 765     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 766     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 767     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 768   esac
 769 fi
 770
 771 dnl Allow enablement of building and installing docs
 772 AC_ARG_ENABLE(docs,
 773               AS_HELP_STRING([--enable-docs],
 774                              [Build documents (default is YES)]),,
 775                              enableval=default)
 776 case "$enableval" in
 777   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 778   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 779   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 780   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 781 esac
 782
 783 dnl Allow enablement of doxygen generated documentation
 784 AC_ARG_ENABLE(doxygen,
 785               AS_HELP_STRING([--enable-doxygen],
 786                              [Build doxygen documentation (default is NO)]),,
 787                              enableval=default)
 788 case "$enableval" in
 789   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 790   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 791   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 792   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 793 esac
 794
 795 dnl Allow disablement of threads
 796 AC_ARG_ENABLE(threads,
 797               AS_HELP_STRING([--enable-threads],
 798                              [Use threads if available (default is YES)]),,
 799                              enableval=default)
 800 case "$enableval" in
 801   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 802   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 803   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 804   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 805 esac
 806 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 807                    [Define if threads enabled])
 808
 809 dnl Allow disablement of pthread.h
 810 AC_ARG_ENABLE(pthreads,
 811               AS_HELP_STRING([--enable-pthreads],
 812                              [Use pthreads if available (default is YES)]),,
 813                              enableval=default)
 814 case "$enableval" in
 815   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 816   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 817   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 818   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 819 esac
 820
 821 dnl Allow disablement of zlib
 822 AC_ARG_ENABLE(zlib,
 823               AS_HELP_STRING([--enable-zlib],
 824                              [Use zlib for compression/decompression if
 825                               available (default is YES)]),,
 826                               enableval=default)
 827 case "$enableval" in
 828   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 829   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 830   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 831   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 832 esac
 833 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 834                    [Define if zlib is enabled])
 835
 836 dnl Allow building without position independent code
 837 AC_ARG_ENABLE(pic,
 838   AS_HELP_STRING([--enable-pic],
 839                  [Build LLVM with Position Independent Code (default is YES)]),,
 840                  enableval=default)
 841 case "$enableval" in
 842   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 843   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 844   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 845   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 846 esac
 847 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 848                    [Define if position independent code is enabled])
 849
 850 dnl Allow building a shared library and linking tools against it.
 851 AC_ARG_ENABLE(shared,
 852   AS_HELP_STRING([--enable-shared],
 853                  [Build a shared library and link tools against it (default is NO)]),,
 854                  enableval=default)
 855 case "$enableval" in
 856   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 857   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 858   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 859   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 860 esac
 861
 862 dnl Allow libstdc++ is embedded in LLVM.dll.
 863 AC_ARG_ENABLE(embed-stdcxx,
 864   AS_HELP_STRING([--enable-embed-stdcxx],
 865                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 866                  enableval=default)
 867 case "$enableval" in
 868   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 869   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 870   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 871   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 872 esac
 873
 874 dnl Enable embedding timestamp information into build.
 875 AC_ARG_ENABLE(timestamps,
 876   AS_HELP_STRING([--enable-timestamps],
 877                  [Enable embedding timestamp information in build (default is YES)]),,
 878                  enableval=default)
 879 case "$enableval" in
 880   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 881   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 882   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 883   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 884 esac
 885 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 886                    [Define if timestamp information (e.g., __DATE__) is allowed])
 887
 888 dnl Enable support for showing backtraces.
 889 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
 890   [--enable-backtraces],
 891   [Enable embedding backtraces on crash (default is YES)]),
 892   [case "$enableval" in
 893     yes) llvm_cv_enable_backtraces="yes" ;;
 894     no)  llvm_cv_enable_backtraces="no"  ;;
 895     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 896   esac],
 897   llvm_cv_enable_backtraces="yes")
 898 if test "$llvm_cv_enable_backtraces" = "yes" ; then
 899   AC_DEFINE([ENABLE_BACKTRACES],[1],
 900             [Define if you want backtraces on crash])
 901 fi
 902
 903 dnl Enable installing platform specific signal handling overrides, for improved
 904 dnl CrashRecovery support or interaction with crash reporting software. This
 905 dnl support may be inappropriate for some clients embedding LLVM as a library.
 906 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
 907   [--enable-crash-overrides],
 908   [Enable crash handling overrides (default is YES)]),
 909   [case "$enableval" in
 910     yes) llvm_cv_enable_crash_overrides="yes" ;;
 911     no)  llvm_cv_enable_crash_overrides="no"  ;;
 912     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
 913   esac],
 914   llvm_cv_enable_crash_overrides="yes")
 915 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
 916   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
 917             [Define to enable crash handling overrides])
 918 fi
 919
 920 dnl Allow specific targets to be specified for building (or not)
 921 TARGETS_TO_BUILD=""
 922 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 923     [Build specific host targets: all or target1,target2,... Valid targets are:
 924      host, x86, x86_64, sparc, powerpc, arm, aarch64, mips, hexagon,
 925      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
 926     enableval=all)
 927 if test "$enableval" = host-only ; then
 928   enableval=host
 929 fi
 930 case "$enableval" in
 931   all) TARGETS_TO_BUILD="X86 Sparc PowerPC AArch64 ARM Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600" ;;
 932   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 933       case "$a_target" in
 934         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 935         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 936         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 937         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 938         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 939         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 940         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 941         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 942         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 943         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 944         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 945         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 946         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 947         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 948         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 949         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 950         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
 951         host) case "$llvm_cv_target_arch" in
 952             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 953             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 954             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 955             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 956             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 957             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 958             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 959             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 960             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 961             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 962             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 963             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 964             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 965           esac ;;
 966         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 967       esac
 968   done
 969   ;;
 970 esac
 971
 972 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
 973     [Build experimental host targets: disable or target1,target2,...
 974      (default=disable)]),,
 975     enableval=disable)
 976
 977 if test ${enableval} != "disable"
 978 then
 979   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
 980 fi
 981
 982 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 983
 984 dnl Determine whether we are building LLVM support for the native architecture.
 985 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 986 for a_target in $TARGETS_TO_BUILD; do
 987   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 988     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 989       [LLVM architecture name for the native architecture, if available])
 990     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 991     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 992     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 993     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 994     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 995       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 996     fi
 997     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 998       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 999     fi
1000     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
1001       [LLVM name for the native Target init function, if available])
1002     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
1003       [LLVM name for the native TargetInfo init function, if available])
1004     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
1005       [LLVM name for the native target MC init function, if available])
1006     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1007       [LLVM name for the native AsmPrinter init function, if available])
1008     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1009       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1010        [LLVM name for the native AsmParser init function, if available])
1011     fi
1012     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1013       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1014        [LLVM name for the native Disassembler init function, if available])
1015     fi
1016   fi
1017 done
1018
1019 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1020 dnl target feature def files.
1021 LLVM_ENUM_TARGETS=""
1022 LLVM_ENUM_ASM_PRINTERS=""
1023 LLVM_ENUM_ASM_PARSERS=""
1024 LLVM_ENUM_DISASSEMBLERS=""
1025 for target_to_build in $TARGETS_TO_BUILD; do
1026   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1027   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1028     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1029   fi
1030   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1031     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1032   fi
1033   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1034     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1035   fi
1036 done
1037 AC_SUBST(LLVM_ENUM_TARGETS)
1038 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1039 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1040 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1041
1042 dnl Override the option to use for optimized builds.
1043 AC_ARG_WITH(optimize-option,
1044   AS_HELP_STRING([--with-optimize-option],
1045                  [Select the compiler options to use for optimized builds]),,
1046                  withval=default)
1047 AC_MSG_CHECKING([optimization flags])
1048 case "$withval" in
1049   default)
1050     case "$llvm_cv_os_type" in
1051     FreeBSD) optimize_option=-O2 ;;
1052     MingW) optimize_option=-O2 ;;
1053     *)     optimize_option=-O3 ;;
1054     esac ;;
1055   *) optimize_option="$withval" ;;
1056 esac
1057 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1058 AC_MSG_RESULT([$optimize_option])
1059
1060 dnl Specify extra build options
1061 AC_ARG_WITH(extra-options,
1062   AS_HELP_STRING([--with-extra-options],
1063                  [Specify additional options to compile LLVM with]),,
1064                  withval=default)
1065 case "$withval" in
1066   default) EXTRA_OPTIONS= ;;
1067   *) EXTRA_OPTIONS=$withval ;;
1068 esac
1069 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1070
1071 dnl Specify extra linker build options
1072 AC_ARG_WITH(extra-ld-options,
1073   AS_HELP_STRING([--with-extra-ld-options],
1074                  [Specify additional options to link LLVM with]),,
1075                  withval=default)
1076 case "$withval" in
1077   default) EXTRA_LD_OPTIONS= ;;
1078   *) EXTRA_LD_OPTIONS=$withval ;;
1079 esac
1080 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1081
1082 dnl Allow specific bindings to be specified for building (or not)
1083 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1084     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1085     enableval=default)
1086 BINDINGS_TO_BUILD=""
1087 case "$enableval" in
1088   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1089   all ) BINDINGS_TO_BUILD="ocaml" ;;
1090   none | no) BINDINGS_TO_BUILD="" ;;
1091   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1092       case "$a_binding" in
1093         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1094         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1095       esac
1096   done
1097   ;;
1098 esac
1099
1100 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1101 dnl script for bindings/ocaml/configure, except that its auto value depends on
1102 dnl OCAMLC, which is found here to support tests.
1103 AC_ARG_WITH([ocaml-libdir],
1104   [AS_HELP_STRING([--with-ocaml-libdir],
1105     [Specify install location for ocaml bindings (default is stdlib)])],
1106   [],
1107   [withval=auto])
1108 case "$withval" in
1109   auto) with_ocaml_libdir="$withval" ;;
1110   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1111   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1112 esac
1113
1114 AC_ARG_WITH(clang-srcdir,
1115   AS_HELP_STRING([--with-clang-srcdir],
1116     [Directory to the out-of-tree Clang source]),,
1117     withval="-")
1118 case "$withval" in
1119   -) clang_src_root="" ;;
1120   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1121   *) clang_src_root="$ac_pwd/$withval" ;;
1122 esac
1123 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1124
1125 AC_ARG_WITH(clang-resource-dir,
1126   AS_HELP_STRING([--with-clang-resource-dir],
1127     [Relative directory from the Clang binary for resource files]),,
1128     withval="")
1129 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1130                    [Relative directory for resource files])
1131
1132 AC_ARG_WITH(c-include-dirs,
1133   AS_HELP_STRING([--with-c-include-dirs],
1134     [Colon separated list of directories clang will search for headers]),,
1135     withval="")
1136 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1137                    [Directories clang will search for headers])
1138
1139 # Clang normally uses the system c++ headers and libraries. With this option,
1140 # clang will use the ones provided by a gcc installation instead. This option should
1141 # be passed the same value that was used with --prefix when configuring gcc.
1142 AC_ARG_WITH(gcc-toolchain,
1143   AS_HELP_STRING([--with-gcc-toolchain],
1144     [Directory where gcc is installed.]),,
1145     withval="")
1146 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1147                    [Directory where gcc is installed.])
1148
1149 AC_ARG_WITH(default-sysroot,
1150   AS_HELP_STRING([--with-default-sysroot],
1151     [Add --sysroot=<path> to all compiler invocations.]),,
1152     withval="")
1153 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1154                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1155
1156 dnl Allow linking of LLVM with GPLv3 binutils code.
1157 AC_ARG_WITH(binutils-include,
1158   AS_HELP_STRING([--with-binutils-include],
1159     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1160   withval=default)
1161 case "$withval" in
1162   default) WITH_BINUTILS_INCDIR=default ;;
1163   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1164   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1165 esac
1166 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1167   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1168   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1169      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1170      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1171   fi
1172 fi
1173
1174 dnl Specify the URL where bug reports should be submitted.
1175 AC_ARG_WITH(bug-report-url,
1176   AS_HELP_STRING([--with-bug-report-url],
1177     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1178     withval="http://llvm.org/bugs/")
1179 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1180                    [Bug report URL.])
1181
1182 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1183 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1184   [--enable-terminfo],
1185   [Query the terminfo database if available (default is YES)]),
1186   [case "$enableval" in
1187     yes) llvm_cv_enable_terminfo="yes" ;;
1188     no)  llvm_cv_enable_terminfo="no"  ;;
1189     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1190   esac],
1191   llvm_cv_enable_terminfo="yes")
1192
1193 dnl --enable-libedit: check whether the user wants to turn off libedit.
1194 AC_ARG_ENABLE(libedit,AS_HELP_STRING(
1195   [--enable-libedit],
1196   [Use libedit if available (default is YES)]),
1197   [case "$enableval" in
1198     yes) llvm_cv_enable_libedit="yes" ;;
1199     no)  llvm_cv_enable_libedit="no"  ;;
1200     *) AC_MSG_ERROR([Invalid setting for --enable-libedit. Use "yes" or "no"]) ;;
1201   esac],
1202   llvm_cv_enable_libedit="yes")
1203
1204 dnl --enable-libffi : check whether the user wants to turn off libffi:
1205 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1206   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1207   [case "$enableval" in
1208     yes) llvm_cv_enable_libffi="yes" ;;
1209     no)  llvm_cv_enable_libffi="no"  ;;
1210     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1211   esac],
1212   llvm_cv_enable_libffi=no)
1213
1214 AC_ARG_WITH(internal-prefix,
1215   AS_HELP_STRING([--with-internal-prefix],
1216     [Installation directory for internal files]),,
1217     withval="")
1218 AC_SUBST(INTERNAL_PREFIX,[$withval])
1219
1220 dnl===-----------------------------------------------------------------------===
1221 dnl===
1222 dnl=== SECTION 4: Check for programs we need and that they are the right version
1223 dnl===
1224 dnl===-----------------------------------------------------------------------===
1225
1226 AC_PROG_NM
1227 AC_SUBST(NM)
1228
1229 dnl Check for the tools that the makefiles require
1230 AC_CHECK_GNU_MAKE
1231 AC_PROG_LN_S
1232 AC_PATH_PROG(CMP, [cmp], [cmp])
1233 AC_PATH_PROG(CP, [cp], [cp])
1234 AC_PATH_PROG(DATE, [date], [date])
1235 AC_PATH_PROG(FIND, [find], [find])
1236 AC_PATH_PROG(GREP, [grep], [grep])
1237 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1238 AC_PATH_PROG(MV,   [mv],   [mv])
1239 AC_PROG_RANLIB
1240 AC_CHECK_TOOL(AR, ar, false)
1241 AC_PATH_PROG(RM,   [rm],   [rm])
1242 AC_PATH_PROG(SED,  [sed],  [sed])
1243 AC_PATH_PROG(TAR,  [tar],  [gtar])
1244 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1245
1246 dnl Looking for misc. graph plotting software
1247 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
1248 if test "$GRAPHVIZ" != "echo Graphviz" ; then
1249   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
1250   dnl If we're targeting for mingw we should emit windows paths, not msys
1251   if test "$llvm_cv_os_type" = "MingW" ; then
1252     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1253   fi
1254   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1255    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1256 fi
1257 AC_PATH_PROG(DOT, [dot], [echo dot])
1258 if test "$DOT" != "echo dot" ; then
1259   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1260   dnl If we're targeting for mingw we should emit windows paths, not msys
1261   if test "$llvm_cv_os_type" = "MingW" ; then
1262     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1263   fi
1264   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1265    [Define to path to dot program if found or 'echo dot' otherwise])
1266 fi
1267 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1268 if test "$FDP" != "echo fdp" ; then
1269   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1270   dnl If we're targeting for mingw we should emit windows paths, not msys
1271   if test "$llvm_cv_os_type" = "MingW" ; then
1272     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1273   fi
1274   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1275    [Define to path to fdp program if found or 'echo fdp' otherwise])
1276 fi
1277 AC_PATH_PROG(NEATO, [neato], [echo neato])
1278 if test "$NEATO" != "echo neato" ; then
1279   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1280   dnl If we're targeting for mingw we should emit windows paths, not msys
1281   if test "$llvm_cv_os_type" = "MingW" ; then
1282     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1283   fi
1284   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1285    [Define to path to neato program if found or 'echo neato' otherwise])
1286 fi
1287 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1288 if test "$TWOPI" != "echo twopi" ; then
1289   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1290   dnl If we're targeting for mingw we should emit windows paths, not msys
1291   if test "$llvm_cv_os_type" = "MingW" ; then
1292     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1293   fi
1294   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1295    [Define to path to twopi program if found or 'echo twopi' otherwise])
1296 fi
1297 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1298 if test "$CIRCO" != "echo circo" ; then
1299   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1300   dnl If we're targeting for mingw we should emit windows paths, not msys
1301   if test "$llvm_cv_os_type" = "MingW" ; then
1302     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1303   fi
1304   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1305    [Define to path to circo program if found or 'echo circo' otherwise])
1306 fi
1307 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1308 if test "$GV" != "echo gv" ; then
1309   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1310   dnl If we're targeting for mingw we should emit windows paths, not msys
1311   if test "$llvm_cv_os_type" = "MingW" ; then
1312     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1313   fi
1314   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1315    [Define to path to gv program if found or 'echo gv' otherwise])
1316 fi
1317 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1318 if test "$DOTTY" != "echo dotty" ; then
1319   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1320   dnl If we're targeting for mingw we should emit windows paths, not msys
1321   if test "$llvm_cv_os_type" = "MingW" ; then
1322     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1323   fi
1324   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1325    [Define to path to dotty program if found or 'echo dotty' otherwise])
1326 fi
1327 AC_PATH_PROGS(XDOT, [xdot xdot.py], [echo xdot])
1328 if test "$XDOT" != "echo xdot" ; then
1329   AC_DEFINE([HAVE_XDOT],[1],[Define if the xdot program is available])
1330   dnl If we're targeting for mingw we should emit windows paths, not msys
1331   if test "$llvm_cv_os_type" = "MingW" ; then
1332     XDOT=`echo $XDOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1333   fi
1334   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT],"$XDOT${EXEEXT}",
1335    [Define to path to xdot program if found or 'echo xdot' otherwise])
1336 fi
1337
1338 dnl Find the install program
1339 AC_PROG_INSTALL
1340 dnl Prepend src dir to install path dir if it's a relative path
1341 dnl This is a hack for installs that take place in something other
1342 dnl than the top level.
1343 case "$INSTALL" in
1344  [[\\/$]]* | ?:[[\\/]]* ) ;;
1345  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1346 esac
1347
1348 dnl Checks for documentation and testing tools that we can do without. If these
1349 dnl are not found then they are set to "true" which always succeeds but does
1350 dnl nothing. This just lets the build output show that we could have done
1351 dnl something if the tool was available.
1352 AC_PATH_PROG(BZIP2, [bzip2])
1353 AC_PATH_PROG(CAT, [cat])
1354 AC_PATH_PROG(DOXYGEN, [doxygen])
1355 AC_PATH_PROG(GROFF, [groff])
1356 AC_PATH_PROG(GZIPBIN, [gzip])
1357 AC_PATH_PROG(PDFROFF, [pdfroff])
1358 AC_PATH_PROG(ZIP, [zip])
1359 AC_PATH_PROGS(OCAMLC, [ocamlc])
1360 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1361 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1362 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1363 AC_PATH_PROGS(GAS, [gas as])
1364
1365 dnl Get the version of the linker in use.
1366 AC_LINK_GET_VERSION
1367
1368 dnl Determine whether the linker supports the -R option.
1369 AC_LINK_USE_R
1370
1371 dnl Determine whether the compiler supports the -rdynamic option.
1372 AC_LINK_EXPORT_DYNAMIC
1373
1374 dnl Determine whether the linker supports the --version-script option.
1375 AC_LINK_VERSION_SCRIPT
1376
1377 dnl Check for libtool and the library that has dlopen function (which must come
1378 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1379 dnl libtool).
1380 AC_LIBTOOL_DLOPEN
1381 AC_LIB_LTDL
1382
1383 AC_MSG_CHECKING([tool compatibility])
1384
1385 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1386 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1387 dnl to support those options.
1388 dnl "icc" emits gcc signatures
1389 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1390 ICC=no
1391 IXX=no
1392 case $CC in
1393   icc*|icpc*)
1394     ICC=yes
1395     IXX=yes
1396     ;;
1397    *)
1398     ;;
1399 esac
1400
1401 if test "$GCC" != "yes" && test "$ICC" != "yes"
1402 then
1403   AC_MSG_ERROR([gcc|icc required but not found])
1404 fi
1405
1406 dnl Ensure that compilation tools are compatible with GCC extensions
1407 if test "$GXX" != "yes" && test "$IXX" != "yes"
1408 then
1409   AC_MSG_ERROR([g++|clang++|icc required but not found])
1410 fi
1411
1412 dnl Verify that GCC is version 3.0 or higher
1413 if test "$GCC" = "yes"
1414 then
1415   AC_COMPILE_IFELSE(
1416 [
1417   AC_LANG_SOURCE([[
1418     #if !defined(__GNUC__) || __GNUC__ < 3
1419     #error Unsupported GCC version
1420     #endif
1421   ]])
1422 ],
1423 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1424 fi
1425
1426 dnl Check for GNU Make.  We use its extensions, so don't build without it
1427 if test -z "$llvm_cv_gnu_make_command"
1428 then
1429   AC_MSG_ERROR([GNU Make required but not found])
1430 fi
1431
1432 dnl Tool compatibility is okay if we make it here.
1433 AC_MSG_RESULT([ok])
1434
1435 dnl Check optional compiler flags.
1436 AC_MSG_CHECKING([optional compiler flags])
1437 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1438 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1439 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1440
1441 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1442 dnl false positives, so disable it.
1443 NO_UNINITIALIZED=
1444 NO_MAYBE_UNINITIALIZED=
1445 if test "$GXX" = "yes"
1446 then
1447   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1448   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1449   dnl known to be uninitialized from cases which might be uninitialized.  We
1450   dnl still want to catch the first kind of errors.
1451   if test -z "$NO_MAYBE_UNINITIALIZED"
1452   then
1453     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1454   fi
1455 fi
1456 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1457
1458 AC_ARG_WITH([python],
1459             [AS_HELP_STRING([--with-python], [path to python])],
1460             [PYTHON="$withval"])
1461
1462 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1463   AC_MSG_CHECKING([for python])
1464   AC_MSG_RESULT([user defined: $with_python])
1465 else
1466   if test -n "$PYTHON" ; then
1467     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1468   fi
1469
1470   AC_PATH_PROG([PYTHON], [python python2 python26],
1471                [AC_MSG_RESULT([not found])
1472                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1473 fi
1474
1475 AC_MSG_CHECKING([for python >= 2.5])
1476 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1477 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1478 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1479 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1480 if test "$ac_python_version_major" -gt "2" || \
1481    (test "$ac_python_version_major" -eq "2" && \
1482     test "$ac_python_version_minor" -ge "5") ; then
1483   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1484 else
1485   AC_MSG_RESULT([not found])
1486   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1487 fi
1488
1489 dnl===-----------------------------------------------------------------------===
1490 dnl===
1491 dnl=== SECTION 5: Check for libraries
1492 dnl===
1493 dnl===-----------------------------------------------------------------------===
1494
1495 AC_CHECK_LIB(m,sin)
1496 if test "$llvm_cv_os_type" = "MingW" ; then
1497   AC_CHECK_LIB(imagehlp, main)
1498   AC_CHECK_LIB(psapi, main)
1499   AC_CHECK_LIB(shell32, main)
1500 fi
1501
1502 dnl dlopen() is required for plugin support.
1503 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1504                [Define if dlopen() is available on this platform.]),
1505                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1506
1507 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1508 dnl macros to detect whether clock_gettime is available, this just finds the
1509 dnl right libraries to link with.
1510 AC_SEARCH_LIBS(clock_gettime,rt)
1511
1512 dnl The curses library is optional; used for querying terminal info
1513 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1514   dnl We need the has_color functionality in curses for it to be useful.
1515   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1516                  AC_DEFINE([HAVE_TERMINFO],[1],
1517                            [Define if the setupterm() function is supported this platform.]))
1518 fi
1519
1520 dnl The libedit library is optional; used by lib/LineEditor
1521 if test "$llvm_cv_enable_libedit" = "yes" ; then
1522   AC_SEARCH_LIBS(el_init,edit,
1523                  AC_DEFINE([HAVE_LIBEDIT],[1],
1524                            [Define if libedit is available on this platform.]))
1525 fi
1526
1527 dnl libffi is optional; used to call external functions from the interpreter
1528 if test "$llvm_cv_enable_libffi" = "yes" ; then
1529   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1530                  [Define if libffi is available on this platform.]),
1531                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1532 fi
1533
1534 dnl mallinfo is optional; the code can compile (minus features) without it
1535 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1536                [Define if mallinfo() is available on this platform.]))
1537
1538 dnl pthread locking functions are optional - but llvm will not be thread-safe
1539 dnl without locks.
1540 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1541   AC_CHECK_LIB(pthread, pthread_mutex_init)
1542   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1543                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1544                            [Have pthread_mutex_lock]))
1545   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1546                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1547                  [Have pthread_rwlock_init]))
1548   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1549                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1550                  [Have pthread_getspecific]))
1551 fi
1552
1553 dnl zlib is optional; used for compression/uncompression
1554 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1555   AC_CHECK_LIB(z, compress2)
1556 fi
1557
1558 dnl Allow extra x86-disassembler library
1559 AC_ARG_WITH(udis86,
1560   AS_HELP_STRING([--with-udis86=<path>],
1561     [Use udis86 external x86 disassembler library]),
1562     [
1563       AC_SUBST(USE_UDIS86, [1])
1564       case "$withval" in
1565         /usr/lib|yes) ;;
1566         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1567       esac
1568       AC_CHECK_LIB(udis86, ud_init, [], [
1569         echo "Error! You need to have libudis86 around."
1570         exit -1
1571       ])
1572     ],
1573     AC_SUBST(USE_UDIS86, [0]))
1574 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1575                    [Define if use udis86 library])
1576
1577 dnl Allow OProfile support for JIT output.
1578 AC_ARG_WITH(oprofile,
1579   AS_HELP_STRING([--with-oprofile=<prefix>],
1580     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1581     [
1582       AC_SUBST(USE_OPROFILE, [1])
1583       case "$withval" in
1584         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1585         no) llvm_cv_oppath=
1586             AC_SUBST(USE_OPROFILE, [0]) ;;
1587         *) llvm_cv_oppath="${withval}/lib/oprofile"
1588            CPPFLAGS="-I${withval}/include";;
1589       esac
1590       case $llvm_cv_os_type in
1591         Linux)
1592           if test -n "$llvm_cv_oppath" ; then
1593             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1594             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1595             dnl libbfd is not included properly in libopagent in some Debian
1596             dnl versions.  If libbfd isn't found at all, we assume opagent works
1597             dnl anyway.
1598             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1599             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1600               echo "Error! You need to have libopagent around."
1601               exit -1
1602             ])
1603             AC_CHECK_HEADER([opagent.h], [], [
1604               echo "Error! You need to have opagent.h around."
1605               exit -1
1606               ])
1607           fi ;;
1608         *)
1609           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1610       esac
1611     ],
1612     [
1613       AC_SUBST(USE_OPROFILE, [0])
1614     ])
1615 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1616                    [Define if we have the oprofile JIT-support library])
1617
1618 dnl Enable support for Intel JIT Events API.
1619 AC_ARG_WITH(intel-jitevents,
1620   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1621     [
1622        case "$withval" in
1623           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1624           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1625           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1626        esac
1627
1628       case $llvm_cv_os_type in
1629         Linux|Win32|Cygwin|MingW) ;;
1630         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1631       esac
1632
1633       case "$llvm_cv_target_arch" in
1634         x86|x86_64) ;;
1635         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1636       esac
1637     ],
1638     [
1639       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1640     ])
1641 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1642                    [Define if we have the Intel JIT API runtime support library])
1643
1644 dnl Check for libxml2
1645 dnl Right now we're just checking for the existence, we could also check for a
1646 dnl particular version via --version on xml2-config
1647 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1648
1649 AC_MSG_CHECKING(for libxml2 includes)
1650 if test "x$XML2CONFIG" = "x"; then
1651  AC_MSG_RESULT(xml2-config not found)
1652 else
1653  LIBXML2_INC=`$XML2CONFIG --cflags`
1654  AC_MSG_RESULT($LIBXML2_INC)
1655  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1656                                 LIBXML2_LIBS="-lxml2"])
1657 fi
1658 AC_SUBST(LIBXML2_LIBS)
1659 AC_SUBST(LIBXML2_INC)
1660
1661 dnl===-----------------------------------------------------------------------===
1662 dnl===
1663 dnl=== SECTION 6: Check for header files
1664 dnl===
1665 dnl===-----------------------------------------------------------------------===
1666
1667 dnl First, use autoconf provided macros for specific headers that we need
1668 dnl We don't check for ancient stuff or things that are guaranteed to be there
1669 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1670 dnl Generally we're looking for POSIX headers.
1671 AC_HEADER_DIRENT
1672 AC_HEADER_MMAP_ANONYMOUS
1673 AC_HEADER_STAT
1674 AC_HEADER_SYS_WAIT
1675 AC_HEADER_TIME
1676
1677 AC_LANG_PUSH([C++])
1678 AC_CHECK_HEADERS([cxxabi.h])
1679 AC_LANG_POP([C++])
1680 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1681 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1682 AC_CHECK_HEADERS([utime.h])
1683 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1684 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1685 AC_CHECK_HEADERS([valgrind/valgrind.h])
1686 AC_CHECK_HEADERS([fenv.h])
1687 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1688 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1689   AC_CHECK_HEADERS(pthread.h,
1690                    AC_SUBST(HAVE_PTHREAD, 1),
1691                    AC_SUBST(HAVE_PTHREAD, 0))
1692 else
1693   AC_SUBST(HAVE_PTHREAD, 0)
1694 fi
1695 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1696   AC_CHECK_HEADERS(zlib.h,
1697                    AC_SUBST(HAVE_LIBZ, 1),
1698                    AC_SUBST(HAVE_LIBZ, 0))
1699 else
1700   AC_SUBST(HAVE_LIBZ, 0)
1701 fi
1702
1703 dnl Try to find ffi.h.
1704 if test "$llvm_cv_enable_libffi" = "yes" ; then
1705   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1706 fi
1707
1708 dnl Try to find Darwin specific crash reporting libraries.
1709 AC_CHECK_HEADERS([CrashReporterClient.h])
1710
1711 dnl Try to find Darwin specific crash reporting global.
1712 AC_MSG_CHECKING([__crashreporter_info__])
1713 AC_LINK_IFELSE(
1714 [
1715   AC_LANG_SOURCE([[
1716     extern const char *__crashreporter_info__;
1717     int main() {
1718       __crashreporter_info__ = "test";
1719       return 0;
1720     }
1721   ]])
1722 ],
1723 [
1724   AC_MSG_RESULT([yes])
1725   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1726 ],
1727 [
1728   AC_MSG_RESULT([no])
1729   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1730 ])
1731
1732 dnl===-----------------------------------------------------------------------===
1733 dnl===
1734 dnl=== SECTION 7: Check for types and structures
1735 dnl===
1736 dnl===-----------------------------------------------------------------------===
1737
1738 AC_HUGE_VAL_CHECK
1739 AC_TYPE_PID_T
1740 AC_TYPE_SIZE_T
1741 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1742 AC_STRUCT_TM
1743 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1744 AC_CHECK_TYPES([uint64_t],,
1745          AC_CHECK_TYPES([u_int64_t],,
1746          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1747
1748 dnl===-----------------------------------------------------------------------===
1749 dnl===
1750 dnl=== SECTION 8: Check for specific functions needed
1751 dnl===
1752 dnl===-----------------------------------------------------------------------===
1753
1754 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1755 AC_CHECK_FUNCS([powf fmodf strtof round ])
1756 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1757 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1758 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1759 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1760 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1761 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1762 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1763 AC_CHECK_FUNCS([futimes futimens])
1764 AC_C_PRINTF_A
1765 AC_FUNC_RAND48
1766
1767 dnl Check for arc4random accessible via AC_INCLUDES_DEFAULT.
1768 AC_CHECK_DECLS([arc4random])
1769
1770 dnl Check the declaration "Secure API" on Windows environments.
1771 AC_CHECK_DECLS([strerror_s])
1772
1773 dnl Check symbols in libgcc.a for JIT on Mingw.
1774 if test "$llvm_cv_os_type" = "MingW" ; then
1775   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1776   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1777   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1778   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1779
1780   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1781   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1782   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1783   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1784   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1785   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1786   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1787   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1788   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1789   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1790
1791   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1792   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1793 fi
1794
1795 dnl Check Win32 API EnumerateLoadedModules.
1796 if test "$llvm_cv_os_type" = "MingW" ; then
1797   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1798   AC_COMPILE_IFELSE(
1799 [
1800   AC_LANG_SOURCE([[
1801     #include <windows.h>
1802     #include <imagehlp.h>
1803     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1804     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1805   ]])
1806 ],
1807 [
1808   AC_MSG_RESULT([yes])
1809   llvm_cv_win32_elmcb_pcstr="PCSTR"
1810 ],
1811 [
1812   AC_MSG_RESULT([no])
1813   llvm_cv_win32_elmcb_pcstr="PSTR"
1814 ])
1815   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1816 fi
1817
1818 dnl Check for variations in the Standard C++ library and STL. These macros are
1819 dnl provided by LLVM in the autoconf/m4 directory.
1820 AC_FUNC_ISNAN
1821 AC_FUNC_ISINF
1822
1823 dnl Check for mmap support.We also need to know if /dev/zero is required to
1824 dnl be opened for allocating RWX memory.
1825 dnl Make sure we aren't attempting to configure for an unknown system
1826 if test "$llvm_cv_platform_type" = "Unix" ; then
1827   AC_FUNC_MMAP
1828   AC_FUNC_MMAP_FILE
1829   AC_NEED_DEV_ZERO_FOR_MMAP
1830
1831   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1832   then
1833     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1834   fi
1835   if test "$ac_cv_func_mmap_file" = "no"
1836   then
1837     AC_MSG_WARN([mmap() of files required but not found])
1838   fi
1839 fi
1840
1841 dnl atomic builtins are required for threading support.
1842 AC_MSG_CHECKING(for GCC atomic builtins)
1843 dnl Since we'll be using these atomic builtins in C++ files we should test
1844 dnl the C++ compiler.
1845 AC_LANG_PUSH([C++])
1846 AC_LINK_IFELSE(
1847 [
1848   AC_LANG_SOURCE([[
1849     int main() {
1850       volatile unsigned long val = 1;
1851       __sync_synchronize();
1852       __sync_val_compare_and_swap(&val, 1, 0);
1853       __sync_add_and_fetch(&val, 1);
1854       __sync_sub_and_fetch(&val, 1);
1855       return 0;
1856     }
1857   ]])
1858 ],
1859 [
1860   AC_MSG_RESULT([yes])
1861   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1862 ],
1863 [
1864   AC_MSG_RESULT([no])
1865   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1866   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1867 ])
1868 AC_LANG_POP([C++])
1869
1870 dnl===-----------------------------------------------------------------------===
1871 dnl===
1872 dnl=== SECTION 9: Additional checks, variables, etc.
1873 dnl===
1874 dnl===-----------------------------------------------------------------------===
1875
1876 dnl Handle 32-bit linux systems running a 64-bit kernel.
1877 dnl This has to come after section 4 because it invokes the compiler.
1878 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1879   AC_IS_LINUX_MIXED
1880   if test "$llvm_cv_linux_mixed" = "yes"; then
1881     llvm_cv_target_arch="x86"
1882     ARCH="x86"
1883   fi
1884 fi
1885
1886 dnl Check whether __dso_handle is present
1887 AC_CHECK_FUNCS([__dso_handle])
1888
1889 dnl Propagate the shared library extension that the libltdl checks did to
1890 dnl the Makefiles so we can use it there too
1891 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1892
1893 dnl Propagate the run-time library path variable that the libltdl
1894 dnl checks found to the Makefiles so we can use it there too
1895 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1896
1897 dnl Translate the various configuration directories and other basic
1898 dnl information into substitutions that will end up in Makefile.config.in
1899 dnl that these configured values can be used by the makefiles
1900 if test "${prefix}" = "NONE" ; then
1901   prefix="/usr/local"
1902 fi
1903 eval LLVM_PREFIX="${prefix}";
1904 eval LLVM_BINDIR="${prefix}/bin";
1905 eval LLVM_DATADIR="${prefix}/share/llvm";
1906 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1907 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1908 eval LLVM_INCLUDEDIR="${prefix}/include";
1909 eval LLVM_INFODIR="${prefix}/info";
1910 eval LLVM_MANDIR="${prefix}/man";
1911 LLVM_CONFIGTIME=`date`
1912 AC_SUBST(LLVM_PREFIX)
1913 AC_SUBST(LLVM_BINDIR)
1914 AC_SUBST(LLVM_DATADIR)
1915 AC_SUBST(LLVM_DOCSDIR)
1916 AC_SUBST(LLVM_ETCDIR)
1917 AC_SUBST(LLVM_INCLUDEDIR)
1918 AC_SUBST(LLVM_INFODIR)
1919 AC_SUBST(LLVM_MANDIR)
1920 AC_SUBST(LLVM_CONFIGTIME)
1921
1922 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1923 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1924   LLVM_CONFIGTIME="(timestamp not enabled)"
1925 fi
1926
1927 dnl Place the various directories into the config.h file as #defines so that we
1928 dnl can know about the installation paths within LLVM.
1929 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1930                    [Installation prefix directory])
1931 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1932                    [Installation directory for binary executables])
1933 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1934                    [Installation directory for data files])
1935 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1936                    [Installation directory for documentation])
1937 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1938                    [Installation directory for config files])
1939 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1940                    [Installation directory for include files])
1941 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1942                    [Installation directory for .info files])
1943 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1944                    [Installation directory for man pages])
1945 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1946                    [Time at which LLVM was configured])
1947 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
1948                    [Host triple LLVM will be executed on])
1949 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1950                    [Target triple LLVM will generate code for by default])
1951
1952 dnl Determine which bindings to build.
1953 if test "$BINDINGS_TO_BUILD" = auto ; then
1954   BINDINGS_TO_BUILD=""
1955   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1956     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1957   fi
1958 fi
1959 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1960
1961 dnl This isn't really configurey, but it avoids having to repeat the list in
1962 dnl other files.
1963 AC_SUBST(ALL_BINDINGS,ocaml)
1964
1965 dnl Do any work necessary to ensure that bindings have what they need.
1966 binding_prereqs_failed=0
1967 for a_binding in $BINDINGS_TO_BUILD ; do
1968   case "$a_binding" in
1969   ocaml)
1970     if test "x$OCAMLC" = x ; then
1971       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1972       binding_prereqs_failed=1
1973     fi
1974     if test "x$OCAMLDEP" = x ; then
1975       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1976       binding_prereqs_failed=1
1977     fi
1978     if test "x$OCAMLOPT" = x ; then
1979       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1980       dnl ocamlopt is optional!
1981     fi
1982     if test "x$with_ocaml_libdir" != xauto ; then
1983       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1984     else
1985       ocaml_stdlib="`"$OCAMLC" -where`"
1986       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1987       then
1988         # ocaml stdlib is beneath our prefix; use stdlib
1989         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1990       else
1991         # ocaml stdlib is outside our prefix; use libdir/ocaml
1992         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
1993       fi
1994     fi
1995     ;;
1996   esac
1997 done
1998 if test "$binding_prereqs_failed" = 1 ; then
1999   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
2000 fi
2001
2002 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
2003 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
2004
2005 dnl Determine linker rpath flag
2006 if test "$llvm_cv_link_use_r" = "yes" ; then
2007   RPATH="-Wl,-R"
2008 else
2009   RPATH="-Wl,-rpath"
2010 fi
2011 AC_SUBST(RPATH)
2012
2013 dnl Determine linker rdynamic flag
2014 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
2015   RDYNAMIC="-rdynamic"
2016 else
2017   RDYNAMIC=""
2018 fi
2019 AC_SUBST(RDYNAMIC)
2020
2021 dnl===-----------------------------------------------------------------------===
2022 dnl===
2023 dnl=== SECTION 10: Specify the output files and generate it
2024 dnl===
2025 dnl===-----------------------------------------------------------------------===
2026
2027 dnl Configure header files
2028 dnl WARNING: dnl If you add or remove any of the following config headers, then
2029 dnl you MUST also update Makefile so that the variable FilesToConfig
2030 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
2031 dnl files can be updated automatically when their *.in sources change.
2032 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
2033 AH_TOP([#ifndef CONFIG_H
2034 #define CONFIG_H])
2035 AH_BOTTOM([#endif])
2036
2037 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
2038 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
2039 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
2040 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
2041 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
2042
2043 dnl Configure the makefile's configuration data
2044 AC_CONFIG_FILES([Makefile.config])
2045
2046 dnl Configure the RPM spec file for LLVM
2047 AC_CONFIG_FILES([llvm.spec])
2048
2049 dnl Configure doxygen's configuration file
2050 AC_CONFIG_FILES([docs/doxygen.cfg])
2051
2052 dnl Configure clang, if present
2053 if test "${clang_src_root}" = ""; then
2054   clang_src_root="$srcdir/tools/clang"
2055 fi
2056 if test -f ${clang_src_root}/README.txt; then
2057   dnl Use variables to stay under 80 columns.
2058   configh="include/clang/Config/config.h"
2059   doxy="docs/doxygen.cfg"
2060   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
2061   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
2062 fi
2063
2064 dnl OCaml findlib META file
2065 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
2066
2067 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
2068 test "x$program_prefix" = "xNONE" && program_prefix=""
2069 AC_SUBST([program_prefix])
2070
2071
2072 dnl Do special configuration of Makefiles
2073 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2074 AC_CONFIG_MAKEFILE(Makefile)
2075 AC_CONFIG_MAKEFILE(Makefile.common)
2076 AC_CONFIG_MAKEFILE(examples/Makefile)
2077 AC_CONFIG_MAKEFILE(lib/Makefile)
2078 AC_CONFIG_MAKEFILE(test/Makefile)
2079 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2080 AC_CONFIG_MAKEFILE(unittests/Makefile)
2081 AC_CONFIG_MAKEFILE(tools/Makefile)
2082 AC_CONFIG_MAKEFILE(utils/Makefile)
2083 AC_CONFIG_MAKEFILE(projects/Makefile)
2084 AC_CONFIG_MAKEFILE(bindings/Makefile)
2085 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2086
2087 dnl Finally, crank out the output
2088 AC_OUTPUT