autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.6svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *)
 179     llvm_cv_link_all_option=""
 180     llvm_cv_no_link_all_option=""
 181     llvm_cv_os_type="Unknown"
 182     llvm_cv_platform_type="Unknown" ;;
 183 esac])
 184
 185 dnl Make sure we aren't attempting to configure for an unknown system
 186 if test "$llvm_cv_os_type" = "Unknown" ; then
 187   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 188 fi
 189
 190 dnl Set the "OS" Makefile variable based on the platform type so the
 191 dnl makefile can configure itself to specific build hosts
 192 AC_SUBST(OS,$llvm_cv_os_type)
 193
 194 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 195 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 196 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 197
 198 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 199 dnl This is used by lib/System to determine the basic kind of implementation
 200 dnl to use.
 201 case $llvm_cv_platform_type in
 202   Unix)
 203     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 204     AC_SUBST(LLVM_ON_UNIX,[1])
 205     AC_SUBST(LLVM_ON_WIN32,[0])
 206     ;;
 207   Win32)
 208     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 209     AC_SUBST(LLVM_ON_UNIX,[0])
 210     AC_SUBST(LLVM_ON_WIN32,[1])
 211     ;;
 212 esac
 213
 214 dnl Determine what our target architecture is and configure accordingly.
 215 dnl This will allow Makefiles to make a distinction between the hardware and
 216 dnl the OS.
 217 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 218 [case $target in
 219   i?86-*)                 llvm_cv_target_arch="x86" ;;
 220   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 221   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 222   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 223   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 224   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 225   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 226   mips-*)                 llvm_cv_target_arch="Mips" ;;
 227   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 228   xcore-*)                llvm_cv_target_arch="XCore" ;;
 229   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 230   *)                      llvm_cv_target_arch="Unknown" ;;
 231 esac])
 232
 233 if test "$llvm_cv_target_arch" = "Unknown" ; then
 234   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 235 fi
 236
 237 # Determine the LLVM native architecture for the target
 238 case "$llvm_cv_target_arch" in
 239     x86)     LLVM_NATIVE_ARCH="X86" ;;
 240     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 241     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 242 esac
 243
 244 dnl Define a substitution, ARCH, for the target architecture
 245 AC_SUBST(ARCH,$llvm_cv_target_arch)
 246
 247 dnl Check for the endianness of the target
 248 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 249
 250 dnl Check for build platform executable suffix if we're crosscompiling
 251 if test "$cross_compiling" = yes; then
 252   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 253   AC_BUILD_EXEEXT
 254   ac_build_prefix=${build_alias}-
 255   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 256   if test -z "$BUILD_CXX"; then
 257      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 258      if test -z "$BUILD_CXX"; then
 259        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 260      fi
 261   fi
 262 else
 263   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 264 fi
 265
 266 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 267 dnl that this build is being done from a checkout. This sets up several
 268 dnl defaults for the command line switches. When we build with a CVS directory,
 269 dnl we get a debug with assertions turned on. Without, we assume a source
 270 dnl release and we get an optimized build without assertions.
 271 dnl See --enable-optimized and --enable-assertions below
 272 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 273   cvsbuild="yes"
 274   optimize="no"
 275   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 276 else
 277   cvsbuild="no"
 278   optimize="yes"
 279 fi
 280
 281 dnl===-----------------------------------------------------------------------===
 282 dnl===
 283 dnl=== SECTION 3: Command line arguments for the configure script.
 284 dnl===
 285 dnl===-----------------------------------------------------------------------===
 286
 287 dnl --enable-optimized : check whether they want to do an optimized build:
 288 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 289  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 290 if test ${enableval} = "no" ; then
 291   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 292 else
 293   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 294 fi
 295
 296 dnl --enable-profiling : check whether they want to do a profile build:
 297 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 298  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 299 if test ${enableval} = "no" ; then
 300   AC_SUBST(ENABLE_PROFILING,[[]])
 301 else
 302   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 303 fi
 304
 305 dnl --enable-assertions : check whether they want to turn on assertions or not:
 306 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 307   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 308 if test ${enableval} = "yes" ; then
 309   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 310 else
 311   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 312 fi
 313
 314 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 315 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 316   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 317 if test ${enableval} = "yes" ; then
 318   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 319   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 320 else
 321   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 322   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 323 fi
 324
 325 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 326 AC_ARG_ENABLE(debug-runtime,
 327    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 328 if test ${enableval} = "no" ; then
 329   AC_SUBST(DEBUG_RUNTIME,[[]])
 330 else
 331   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 332 fi
 333
 334 dnl --enable-jit: check whether they want to enable the jit
 335 AC_ARG_ENABLE(jit,
 336   AS_HELP_STRING(--enable-jit,
 337                  [Enable Just In Time Compiling (default is YES)]),,
 338   enableval=default)
 339 if test ${enableval} = "no"
 340 then
 341   AC_SUBST(JIT,[[]])
 342 else
 343   case "$llvm_cv_target_arch" in
 344     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 345     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 346     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 347     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 348     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 349     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 350     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 351     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 352     PIC16)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 353     XCore)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 354     MSP430)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 355     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 356   esac
 357 fi
 358
 359 dnl Allow enablement of doxygen generated documentation
 360 AC_ARG_ENABLE(doxygen,
 361               AS_HELP_STRING([--enable-doxygen],
 362                              [Build doxygen documentation (default is NO)]),,
 363                              enableval=default)
 364 case "$enableval" in
 365   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 366   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 367   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 368   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 369 esac
 370
 371 dnl Allow disablement of threads
 372 AC_ARG_ENABLE(threads,
 373               AS_HELP_STRING([--enable-threads],
 374                              [Use threads if available (default is YES)]),,
 375                              enableval=default)
 376 case "$enableval" in
 377   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 378   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 379   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 380   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 381 esac
 382 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 383
 384 dnl Allow building without position independent code
 385 AC_ARG_ENABLE(pic,
 386   AS_HELP_STRING([--enable-pic],
 387                  [Build LLVM with Position Independent Code (default is YES)]),,
 388                  enableval=default)
 389 case "$enableval" in
 390   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 391   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 392   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 393   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 394 esac
 395 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 396                    [Define if position independent code is enabled])
 397
 398 dnl Allow specific targets to be specified for building (or not)
 399 TARGETS_TO_BUILD=""
 400 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 401     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 402     enableval=all)
 403 case "$enableval" in
 404   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU PIC16 XCore MSP430 CBackend MSIL CppBackend" ;;
 405   host-only)
 406     case "$llvm_cv_target_arch" in
 407       x86)     TARGETS_TO_BUILD="X86" ;;
 408       x86_64)  TARGETS_TO_BUILD="X86" ;;
 409       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 410       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 411       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 412       IA64)    TARGETS_TO_BUILD="IA64" ;;
 413       ARM)     TARGETS_TO_BUILD="ARM" ;;
 414       Mips)    TARGETS_TO_BUILD="Mips" ;;
 415       CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
 416       PIC16)   TARGETS_TO_BUILD="PIC16" ;;
 417       XCore)   TARGETS_TO_BUILD="XCore" ;;
 418       MSP430)  TARGETS_TO_BUILD="MSP430" ;;
 419       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 420     esac
 421     ;;
 422   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 423       case "$a_target" in
 424         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 425         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 426         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 427         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 428         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 429         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 430         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 431         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 432         spu)     TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 433         pic16)   TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 434         xcore)   TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 435         msp430)  TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 436         cbe)     TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 437         msil)    TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 438         cpp)     TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 439         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 440       esac
 441   done
 442   ;;
 443 esac
 444 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 445
 446 # Determine whether we are building LLVM support for the native architecture.
 447 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 448 for a_target in $TARGETS_TO_BUILD; do
 449   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 450     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCH,
 451       [LLVM architecture name for the native architecture, if available])
 452   fi
 453 done
 454
 455 # Build the LLVM_TARGET and LLVM_ASM_PRINTER macro uses for
 456 # Targets.def and AsmPrinters.def.
 457 LLVM_ENUM_TARGETS=""
 458 LLVM_ENUM_ASM_PRINTERS=""
 459 for target_to_build in $TARGETS_TO_BUILD; do
 460   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 461   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 462     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 463   fi
 464 done
 465 AC_SUBST(LLVM_ENUM_TARGETS)
 466 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 467
 468 dnl Prevent the CBackend from using printf("%a") for floating point so older
 469 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 470 dnl can still compile the CBE's output
 471 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 472   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 473   enableval=default)
 474 case "$enableval" in
 475   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 476   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 477   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 478   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 479 esac
 480 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 481                    [Define if CBE is enabled for printf %a output])
 482
 483 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 484 AC_ARG_WITH(llvmgccdir,
 485   AS_HELP_STRING([--with-llvmgccdir],
 486     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 487     withval=default)
 488 case "$withval" in
 489   default) WITH_LLVMGCCDIR=default ;;
 490   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 491   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 492 esac
 493
 494 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 495 AC_ARG_WITH(llvmgcc,
 496   AS_HELP_STRING([--with-llvmgcc],
 497     [Specify location of llvm-gcc driver (default searches PATH)]),
 498     LLVMGCC=$with_llvmgcc
 499       WITH_LLVMGCCDIR="",)
 500
 501 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 502 AC_ARG_WITH(llvmgxx,
 503   AS_HELP_STRING([--with-llvmgxx],
 504     [Specify location of llvm-g++ driver (default searches PATH)]),
 505     LLVMGXX=$with_llvmgxx
 506     WITH_LLVMGCCDIR="",)
 507
 508 if test -n "$LLVMGCC"; then
 509    LLVMGCCCOMMAND="$LLVMGCC"
 510 fi
 511
 512 if test -n "$LLVMGXX"; then
 513    LLVMGXXCOMMAND="$LLVMGXX"
 514 fi
 515
 516 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 517    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 518 fi
 519
 520 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 521    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 522 fi
 523
 524 dnl Specify extra build options
 525 AC_ARG_WITH(extra-options,
 526   AS_HELP_STRING([--with-extra-options],
 527                  [Specify additional options to compile LLVM with]),,
 528                  withval=default)
 529 case "$withval" in
 530   default) EXTRA_OPTIONS= ;;
 531   *) EXTRA_OPTIONS=$withval ;;
 532 esac
 533 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 534
 535 dnl Allow specific bindings to be specified for building (or not)
 536 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 537     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 538     enableval=default)
 539 BINDINGS_TO_BUILD=""
 540 case "$enableval" in
 541   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 542   all ) BINDINGS_TO_BUILD="ocaml" ;;
 543   none | no) BINDINGS_TO_BUILD="" ;;
 544   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 545       case "$a_binding" in
 546         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 547         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 548       esac
 549   done
 550   ;;
 551 esac
 552
 553 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 554 dnl script for bindings/ocaml/configure, except that its auto value depends on
 555 dnl OCAMLC, which is found here to support tests.
 556 AC_ARG_WITH([ocaml-libdir],
 557   [AS_HELP_STRING([--with-ocaml-libdir],
 558     [Specify install location for ocaml bindings (default is stdlib)])],
 559   [],
 560   [withval=auto])
 561 case "$withval" in
 562   auto) with_ocaml_libdir="$withval" ;;
 563   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 564   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 565 esac
 566
 567 dnl Allow linking of LLVM with GPLv3 binutils code.
 568 AC_ARG_WITH(binutils-include,
 569   AS_HELP_STRING([--with-binutils-include],
 570     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 571   withval=default)
 572 case "$withval" in
 573   default) WITH_BINUTILS_INCDIR=default ;;
 574   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 575   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 576 esac
 577 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 578   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 579   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 580      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 581      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 582   fi
 583 fi
 584
 585 dnl --enable-libffi : check whether the user wants to turn off libffi:
 586 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 587   --enable-libffi,[Check for the presence of libffi (default is YES)]),,
 588   enableval=yes)
 589 case "$enableval" in
 590   yes) llvm_cv_enable_libffi="yes" ;;
 591   no)  llvm_cv_enable_libffi="no"  ;;
 592   *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 593 esac
 594
 595 dnl===-----------------------------------------------------------------------===
 596 dnl===
 597 dnl=== SECTION 4: Check for programs we need and that they are the right version
 598 dnl===
 599 dnl===-----------------------------------------------------------------------===
 600
 601 dnl Check for compilation tools
 602 AC_PROG_CPP
 603 AC_PROG_CC(gcc)
 604 AC_PROG_CXX(g++)
 605
 606 AC_PROG_NM
 607 AC_SUBST(NM)
 608
 609 dnl Check for the tools that the makefiles require
 610 AC_CHECK_GNU_MAKE
 611 AC_PROG_LN_S
 612 AC_PATH_PROG(CMP, [cmp], [cmp])
 613 AC_PATH_PROG(CP, [cp], [cp])
 614 AC_PATH_PROG(DATE, [date], [date])
 615 AC_PATH_PROG(FIND, [find], [find])
 616 AC_PATH_PROG(GREP, [grep], [grep])
 617 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 618 AC_PATH_PROG(MV,   [mv],   [mv])
 619 AC_PROG_RANLIB
 620 AC_PATH_PROG(RM,   [rm],   [rm])
 621 AC_PATH_PROG(SED,  [sed],  [sed])
 622 AC_PATH_PROG(TAR,  [tar],  [gtar])
 623 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 624
 625 dnl Looking for misc. graph plotting software
 626 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 627 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 628   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 629   dnl If we're targeting for mingw we should emit windows paths, not msys
 630   if test "$llvm_cv_os_type" = "MingW" ; then
 631     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 632   fi
 633   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 634    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 635 fi
 636 AC_PATH_PROG(DOT, [dot], [echo dot])
 637 if test "$DOT" != "echo dot" ; then
 638   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 639   dnl If we're targeting for mingw we should emit windows paths, not msys
 640   if test "$llvm_cv_os_type" = "MingW" ; then
 641     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 642   fi
 643   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 644    [Define to path to dot program if found or 'echo dot' otherwise])
 645 fi
 646 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 647 if test "$GV" != "echo gv" ; then
 648   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 649   dnl If we're targeting for mingw we should emit windows paths, not msys
 650   if test "$llvm_cv_os_type" = "MingW" ; then
 651     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 652   fi
 653   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 654    [Define to path to gv program if found or 'echo gv' otherwise])
 655 fi
 656 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 657 if test "$DOTTY" != "echo dotty" ; then
 658   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 659   dnl If we're targeting for mingw we should emit windows paths, not msys
 660   if test "$llvm_cv_os_type" = "MingW" ; then
 661     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 662   fi
 663   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 664    [Define to path to dotty program if found or 'echo dotty' otherwise])
 665 fi
 666
 667 dnl Look for a sufficiently recent version of Perl.
 668 LLVM_PROG_PERL([5.006])
 669 AC_SUBST(PERL)
 670 if test x"$PERL" = xnone; then
 671    AC_SUBST(HAVE_PERL,0)
 672    AC_MSG_ERROR([perl is required but was not found, please install it])
 673 else
 674    AC_SUBST(HAVE_PERL,1)
 675 fi
 676
 677 dnl Find the install program
 678 AC_PROG_INSTALL
 679
 680 dnl Checks for documentation and testing tools that we can do without. If these
 681 dnl are not found then they are set to "true" which always succeeds but does
 682 dnl nothing. This just lets the build output show that we could have done
 683 dnl something if the tool was available.
 684 AC_PATH_PROG(BZIP2, [bzip2])
 685 AC_PATH_PROG(DOXYGEN, [doxygen])
 686 AC_PATH_PROG(GROFF, [groff])
 687 AC_PATH_PROG(GZIP, [gzip])
 688 AC_PATH_PROG(POD2HTML, [pod2html])
 689 AC_PATH_PROG(POD2MAN, [pod2man])
 690 AC_PATH_PROG(RUNTEST, [runtest])
 691 DJ_AC_PATH_TCLSH
 692 AC_PATH_PROG(ZIP, [zip])
 693 AC_PATH_PROGS(OCAMLC, [ocamlc])
 694 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 695 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 696 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 697 AC_PATH_PROGS(GAS, [gas as])
 698
 699 dnl Determine whether the linker supports the -R option.
 700 AC_LINK_USE_R
 701
 702 dnl Determine whether the linker supports the -export-dynamic option.
 703 AC_LINK_EXPORT_DYNAMIC
 704
 705 dnl Check for libtool and the library that has dlopen function (which must come
 706 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 707 dnl libtool).
 708 AC_LIBTOOL_DLOPEN
 709 AC_LIB_LTDL
 710 AC_PROG_LIBTOOL
 711
 712 if test "$lt_cv_dlopen_self" = "yes" ; then
 713   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 714               [Define if dlopen(0) will open the symbols of the program])
 715 fi
 716
 717
 718 if test "$WITH_LLVMGCCDIR" = "default" ; then
 719   LLVMGCC="llvm-gcc${EXEEXT}"
 720   LLVMGXX="llvm-g++${EXEEXT}"
 721   LLVMGCCCOMMAND="$LLVMGCC"
 722   LLVMGXXCOMMAND="$LLVMGXX"
 723   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 724   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 725   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 726   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 727 else
 728   if test -z "$LLVMGCC"; then
 729     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 730     LLVMGCCCOMMAND="$LLVMGCC"
 731   fi
 732   if test -z "$LLVMGXX"; then
 733     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 734     LLVMGXXCOMMAND="$LLVMGXX"
 735   fi
 736
 737   AC_SUBST(LLVMGCC,$LLVMGCC)
 738   AC_SUBST(LLVMGXX,$LLVMGXX)
 739   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 740   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 741 fi
 742
 743
 744 AC_MSG_CHECKING([tool compatibility])
 745
 746 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 747 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 748 dnl to support those options.
 749 dnl "icc" emits gcc signatures
 750 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 751 ICC=no
 752 IXX=no
 753 case $CC in
 754   icc*|icpc*)
 755     ICC=yes
 756     IXX=yes
 757     ;;
 758    *)
 759     ;;
 760 esac
 761
 762 if test "$GCC" != "yes" && test "$ICC" != "yes"
 763 then
 764   AC_MSG_ERROR([gcc|icc required but not found])
 765 fi
 766
 767 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 768 if test "$GXX" != "yes" && test "$IXX" != "yes"
 769 then
 770   AC_MSG_ERROR([g++|icc required but not found])
 771 fi
 772
 773 dnl Verify that GCC is version 3.0 or higher
 774 if test "$GCC" = "yes"
 775 then
 776   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 777 #error Unsupported GCC version
 778 #endif
 779 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 780 fi
 781
 782 dnl Check for GNU Make.  We use its extensions, so don't build without it
 783 if test -z "$llvm_cv_gnu_make_command"
 784 then
 785   AC_MSG_ERROR([GNU Make required but not found])
 786 fi
 787
 788 dnl Tool compatibility is okay if we make it here.
 789 AC_MSG_RESULT([ok])
 790
 791 dnl===-----------------------------------------------------------------------===
 792 dnl===
 793 dnl=== SECTION 5: Check for libraries
 794 dnl===
 795 dnl===-----------------------------------------------------------------------===
 796
 797 dnl libelf is for sparc only; we can ignore it if we don't have it
 798 AC_CHECK_LIB(elf, elf_begin)
 799 AC_CHECK_LIB(m,sin)
 800 if test "$llvm_cv_os_type" = "MingW" ; then
 801   AC_CHECK_LIB(imagehlp, main)
 802   AC_CHECK_LIB(psapi, main)
 803 fi
 804
 805 dnl dlopen() is required for plugin support.
 806 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 807                [Define if dlopen() is available on this platform.]),
 808                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 809
 810 dnl libffi is optional; used to call external functions from the interpreter
 811 if test "$llvm_cv_enable_libffi" = "yes" ; then
 812   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
 813                  [Define if libffi is available on this platform.]),
 814                  AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
 815 fi
 816
 817 dnl mallinfo is optional; the code can compile (minus features) without it
 818 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 819                [Define if mallinfo() is available on this platform.]))
 820
 821 dnl pthread locking functions are optional - but llvm will not be thread-safe
 822 dnl without locks.
 823 if test "$ENABLE_THREADS" -eq 1 ; then
 824   AC_CHECK_LIB(pthread,pthread_mutex_init)
 825   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 826                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 827                            [Have pthread_mutex_lock]))
 828   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
 829                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
 830                  [Have pthread_rwlock_init]))
 831 fi
 832
 833 dnl Allow extra x86-disassembler library
 834 AC_ARG_WITH(udis86,
 835   AS_HELP_STRING([--with-udis86=<path>],
 836     [Use udis86 external x86 disassembler library]),
 837     [
 838       AC_SUBST(USE_UDIS86, [1])
 839       case "$withval" in
 840         /usr/lib|yes) ;;
 841         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 842       esac
 843       AC_CHECK_LIB(udis86, ud_init, [], [
 844         echo "Error! You need to have libudis86 around."
 845         exit -1
 846       ])
 847     ],
 848     AC_SUBST(USE_UDIS86, [0]))
 849 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 850                    [Define if use udis86 library])
 851
 852 dnl===-----------------------------------------------------------------------===
 853 dnl===
 854 dnl=== SECTION 6: Check for header files
 855 dnl===
 856 dnl===-----------------------------------------------------------------------===
 857
 858 dnl First, use autoconf provided macros for specific headers that we need
 859 dnl We don't check for ancient stuff or things that are guaranteed to be there
 860 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 861 dnl Generally we're looking for POSIX headers.
 862 AC_HEADER_DIRENT
 863 AC_HEADER_MMAP_ANONYMOUS
 864 AC_HEADER_STAT
 865 AC_HEADER_STDC
 866 AC_HEADER_SYS_WAIT
 867 AC_HEADER_TIME
 868
 869 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 870 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
 871 AC_CHECK_HEADERS([utime.h windows.h])
 872 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 873 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
 874 if test "$ENABLE_THREADS" -eq 1 ; then
 875   AC_CHECK_HEADERS(pthread.h,
 876                    AC_SUBST(HAVE_PTHREAD, 1),
 877                    AC_SUBST(HAVE_PTHREAD, 0))
 878 else
 879   AC_SUBST(HAVE_PTHREAD, 0)
 880 fi
 881
 882 dnl Try to find ffi.h.
 883 if test "$llvm_cv_enable_libffi" = "yes" ; then
 884   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
 885 fi
 886
 887 dnl===-----------------------------------------------------------------------===
 888 dnl===
 889 dnl=== SECTION 7: Check for types and structures
 890 dnl===
 891 dnl===-----------------------------------------------------------------------===
 892
 893 AC_HUGE_VAL_CHECK
 894 AC_TYPE_PID_T
 895 AC_TYPE_SIZE_T
 896 AC_TYPE_SIGNAL
 897 AC_STRUCT_TM
 898 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 899 AC_CHECK_TYPES([uint64_t],,
 900          AC_CHECK_TYPES([u_int64_t],,
 901          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 902
 903 dnl===-----------------------------------------------------------------------===
 904 dnl===
 905 dnl=== SECTION 8: Check for specific functions needed
 906 dnl===
 907 dnl===-----------------------------------------------------------------------===
 908
 909 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 910 AC_CHECK_FUNCS([powf fmodf strtof round ])
 911 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 912 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 913 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 914 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 915 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 916 AC_C_PRINTF_A
 917 AC_FUNC_ALLOCA
 918 AC_FUNC_RAND48
 919
 920 dnl Check for variations in the Standard C++ library and STL. These macros are
 921 dnl provided by LLVM in the autoconf/m4 directory.
 922 AC_CXX_HAVE_STD_ITERATOR
 923 AC_CXX_HAVE_BI_ITERATOR
 924 AC_CXX_HAVE_FWD_ITERATOR
 925 AC_FUNC_ISNAN
 926 AC_FUNC_ISINF
 927
 928 dnl Check for mmap support.We also need to know if /dev/zero is required to
 929 dnl be opened for allocating RWX memory.
 930 dnl Make sure we aren't attempting to configure for an unknown system
 931 if test "$llvm_cv_platform_type" = "Unix" ; then
 932   AC_FUNC_MMAP
 933   AC_FUNC_MMAP_FILE
 934   AC_NEED_DEV_ZERO_FOR_MMAP
 935
 936   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 937   then
 938     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 939   fi
 940   if test "$ac_cv_func_mmap_file" = "no"
 941   then
 942     AC_MSG_WARN([mmap() of files required but not found])
 943   fi
 944 fi
 945
 946 dnl atomic builtins are required for threading support.
 947 AC_MSG_CHECKING(for GCC atomic builtins)
 948 AC_LINK_IFELSE(
 949   AC_LANG_SOURCE(
 950     [[int main() {
 951         volatile unsigned long val = 1;
 952         __sync_synchronize();
 953         __sync_val_compare_and_swap(&val, 1, 0);
 954         __sync_add_and_fetch(&val, 1);
 955         __sync_sub_and_fetch(&val, 1);
 956         return 0;
 957       }
 958     ]]),
 959   AC_MSG_RESULT(yes)
 960   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
 961   AC_MSG_RESULT(no)
 962   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
 963   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
 964
 965
 966 dnl===-----------------------------------------------------------------------===
 967 dnl===
 968 dnl=== SECTION 9: Additional checks, variables, etc.
 969 dnl===
 970 dnl===-----------------------------------------------------------------------===
 971
 972 dnl Check, whether __dso_handle is present
 973 AC_CHECK_FUNCS([__dso_handle])
 974
 975 dnl See if the llvm-gcc executable can compile to LLVM assembly
 976 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 977 [llvm_cv_llvmgcc_sanity="no"
 978 if test -x "$LLVMGCC" ; then
 979   cp /dev/null conftest.c
 980   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 981       grep 'target datalayout =' > /dev/null 2>&1
 982   if test $? -eq 0 ; then
 983     llvm_cv_llvmgcc_sanity="yes"
 984   fi
 985   rm conftest.c
 986 fi])
 987
 988 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 989 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 990   AC_MSG_CHECKING([llvm-gcc component support])
 991   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 992   AC_SUBST(LLVMCC1,$llvmcc1path)
 993   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 994   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 995   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 996   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 997   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 998   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 999   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
1000   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
1001   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
1002   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
1003   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1004   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1005   AC_MSG_RESULT([ok])
1006 fi
1007
1008 dnl Propagate the shared library extension that the libltdl checks did to
1009 dnl the Makefiles so we can use it there too
1010 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1011
1012 # Translate the various configuration directories and other basic
1013 # information into substitutions that will end up in Makefile.config.in
1014 # that these configured values can be used by the makefiles
1015 if test "${prefix}" = "NONE" ; then
1016   prefix="/usr/local"
1017 fi
1018 eval LLVM_PREFIX="${prefix}";
1019 eval LLVM_BINDIR="${prefix}/bin";
1020 eval LLVM_LIBDIR="${prefix}/lib";
1021 eval LLVM_DATADIR="${prefix}/share/llvm";
1022 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
1023 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1024 eval LLVM_INCLUDEDIR="${prefix}/include";
1025 eval LLVM_INFODIR="${prefix}/info";
1026 eval LLVM_MANDIR="${prefix}/man";
1027 LLVM_CONFIGTIME=`date`
1028 AC_SUBST(LLVM_PREFIX)
1029 AC_SUBST(LLVM_BINDIR)
1030 AC_SUBST(LLVM_LIBDIR)
1031 AC_SUBST(LLVM_DATADIR)
1032 AC_SUBST(LLVM_DOCSDIR)
1033 AC_SUBST(LLVM_ETCDIR)
1034 AC_SUBST(LLVM_INCLUDEDIR)
1035 AC_SUBST(LLVM_INFODIR)
1036 AC_SUBST(LLVM_MANDIR)
1037 AC_SUBST(LLVM_CONFIGTIME)
1038
1039 # Place the various directores into the config.h file as #defines so that we
1040 # can know about the installation paths within LLVM.
1041 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1042                    [Installation prefix directory])
1043 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1044                    [Installation directory for binary executables])
1045 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1046                    [Installation directory for libraries])
1047 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1048                    [Installation directory for data files])
1049 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1050                    [Installation directory for documentation])
1051 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1052                    [Installation directory for config files])
1053 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1054                    [Installation directory for include files])
1055 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1056                    [Installation directory for .info files])
1057 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1058                    [Installation directory for man pages])
1059 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1060                    [Time at which LLVM was configured])
1061 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1062                    [Host triple we were built on])
1063
1064 # Determine which bindings to build.
1065 if test "$BINDINGS_TO_BUILD" = auto ; then
1066   BINDINGS_TO_BUILD=""
1067   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1068     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1069   fi
1070 fi
1071 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1072
1073 # This isn't really configurey, but it avoids having to repeat the list in
1074 # other files.
1075 AC_SUBST(ALL_BINDINGS,ocaml)
1076
1077 # Do any work necessary to ensure that bindings have what they need.
1078 binding_prereqs_failed=0
1079 for a_binding in $BINDINGS_TO_BUILD ; do
1080   case "$a_binding" in
1081   ocaml)
1082     if test "x$OCAMLC" = x ; then
1083       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1084       binding_prereqs_failed=1
1085     fi
1086     if test "x$OCAMLDEP" = x ; then
1087       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1088       binding_prereqs_failed=1
1089     fi
1090     if test "x$OCAMLOPT" = x ; then
1091       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1092       dnl ocamlopt is optional!
1093     fi
1094     if test "x$with_ocaml_libdir" != xauto ; then
1095       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1096     else
1097       ocaml_stdlib="`"$OCAMLC" -where`"
1098       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1099       then
1100         # ocaml stdlib is beneath our prefix; use stdlib
1101         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1102       else
1103         # ocaml stdlib is outside our prefix; use libdir/ocaml
1104         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1105       fi
1106     fi
1107     ;;
1108   esac
1109 done
1110 if test "$binding_prereqs_failed" = 1 ; then
1111   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1112 fi
1113
1114 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1115 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1116
1117 dnl Determine linker rpath flag
1118 if test "$llvm_cv_link_use_r" = "yes" ; then
1119   RPATH="-Wl,-R"
1120 else
1121   RPATH="-Wl,-rpath"
1122 fi
1123 AC_SUBST(RPATH)
1124
1125 dnl Determine linker rdynamic flag
1126 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1127   RDYNAMIC="-Wl,-export-dynamic"
1128 else
1129   RDYNAMIC=""
1130 fi
1131 AC_SUBST(RDYNAMIC)
1132
1133 dnl===-----------------------------------------------------------------------===
1134 dnl===
1135 dnl=== SECTION 10: Specify the output files and generate it
1136 dnl===
1137 dnl===-----------------------------------------------------------------------===
1138
1139 dnl Configure header files
1140 dnl WARNING: dnl If you add or remove any of the following config headers, then
1141 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1142 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1143 dnl files can be updated automatically when their *.in sources change.
1144 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1145 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1146 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1147 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1148 AC_CONFIG_HEADERS([include/llvm/ADT/iterator.h])
1149
1150 dnl Configure the makefile's configuration data
1151 AC_CONFIG_FILES([Makefile.config])
1152
1153 dnl Configure the RPM spec file for LLVM
1154 AC_CONFIG_FILES([llvm.spec])
1155
1156 dnl Configure doxygen's configuration file
1157 AC_CONFIG_FILES([docs/doxygen.cfg])
1158
1159 dnl Configure llvmc's Base plugin
1160 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1161
1162 dnl Do the first stage of configuration for llvm-config.in.
1163 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1164
1165 dnl Do special configuration of Makefiles
1166 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1167 AC_CONFIG_MAKEFILE(Makefile)
1168 AC_CONFIG_MAKEFILE(Makefile.common)
1169 AC_CONFIG_MAKEFILE(examples/Makefile)
1170 AC_CONFIG_MAKEFILE(lib/Makefile)
1171 AC_CONFIG_MAKEFILE(runtime/Makefile)
1172 AC_CONFIG_MAKEFILE(test/Makefile)
1173 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1174 AC_CONFIG_MAKEFILE(unittests/Makefile)
1175 AC_CONFIG_MAKEFILE(tools/Makefile)
1176 AC_CONFIG_MAKEFILE(utils/Makefile)
1177 AC_CONFIG_MAKEFILE(projects/Makefile)
1178 AC_CONFIG_MAKEFILE(bindings/Makefile)
1179 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1180
1181 dnl Finally, crank out the output
1182 AC_OUTPUT