autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34
  35 AC_INIT([LLVM],[3.5.0svn],[http://llvm.org/bugs/])
  36
  37 LLVM_VERSION_MAJOR=3
  38 LLVM_VERSION_MINOR=5
  39 LLVM_VERSION_PATCH=0
  40 LLVM_VERSION_SUFFIX=svn
  41
  42 AC_DEFINE_UNQUOTED([LLVM_VERSION_MAJOR], $LLVM_VERSION_MAJOR, [Major version of the LLVM API])
  43 AC_DEFINE_UNQUOTED([LLVM_VERSION_MINOR], $LLVM_VERSION_MINOR, [Minor version of the LLVM API])
  44 AC_DEFINE_UNQUOTED([LLVM_VERSION_PATCH], $LLVM_VERSION_PATCH, [Patch version of the LLVM API])
  45
  46 AC_SUBST([LLVM_VERSION_MAJOR])
  47 AC_SUBST([LLVM_VERSION_MINOR])
  48 AC_SUBST([LLVM_VERSION_PATCH])
  49 AC_SUBST([LLVM_VERSION_SUFFIX])
  50
  51 dnl Provide a copyright substitution and ensure the copyright notice is included
  52 dnl in the output of --version option of the generated configure script.
  53 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign."])
  54 AC_COPYRIGHT([Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign.])
  55
  56 dnl Indicate that we require autoconf 2.60 or later.
  57 AC_PREREQ(2.60)
  58
  59 dnl Verify that the source directory is valid. This makes sure that we are
  60 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  61 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  62
  63 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  64 dnl various tools where the m4 autoconf macros are.
  65 AC_CONFIG_AUX_DIR([autoconf])
  66
  67 dnl Quit if the source directory has already been configured.
  68 dnl NOTE: This relies upon undocumented autoconf behavior.
  69 if test ${srcdir} != "." ; then
  70   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  71     AC_MSG_ERROR([Already configured in ${srcdir}])
  72   fi
  73 fi
  74
  75 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  76 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  77 : ${CFLAGS=}
  78 : ${CXXFLAGS=}
  79
  80 dnl We need to check for the compiler up here to avoid anything else
  81 dnl starting with a different one.
  82 AC_PROG_CC(clang gcc)
  83 AC_PROG_CXX(clang++ g++)
  84 AC_PROG_CPP
  85
  86 dnl If CXX is Clang, check that it can find and parse C++ standard library
  87 dnl headers.
  88 if test "$CXX" = "clang++" ; then
  89   AC_MSG_CHECKING([whether clang works])
  90   AC_LANG_PUSH([C++])
  91   dnl Note that space between 'include' and '(' is required.  There's a broken
  92   dnl regex in aclocal that otherwise will think that we call m4's include
  93   dnl builtin.
  94   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  95 #if __has_include (<cxxabi.h>)
  96 #include <cxxabi.h>
  97 #endif
  98 #if __has_include (<unwind.h>)
  99 #include <unwind.h>
 100 #endif
 101 ]])],
 102 [
 103   AC_MSG_RESULT([yes])
 104 ],
 105 [
 106   AC_MSG_RESULT([no])
 107   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
 108 ])
 109   AC_LANG_POP([C++])
 110 fi
 111
 112 dnl Set up variables that track whether the host compiler is GCC or Clang where
 113 dnl we can effectively sanity check them. We don't try to sanity check all the
 114 dnl other possible compilers.
 115 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
 116 AC_LANG_PUSH([C++])
 117 llvm_cv_cxx_compiler=unknown
 118 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
 119                                     #error
 120                                     #endif
 121                                     ]])],
 122                   llvm_cv_cxx_compiler=clang,
 123                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
 124                                                        #error
 125                                                        #endif
 126                                                        ]])],
 127                                      llvm_cv_cxx_compiler=gcc, [])])
 128 AC_LANG_POP([C++])
 129 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
 130
 131 dnl Configure all of the projects present in our source tree. While we could
 132 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 133 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 134 dnl Instead we match on the known projects.
 135
 136 dnl
 137 dnl One tricky part of doing this is that some projects depend upon other
 138 dnl projects.  For example, several projects rely upon the LLVM test suite.
 139 dnl We want to configure those projects first so that their object trees are
 140 dnl created before running the configure scripts of projects that depend upon
 141 dnl them.
 142 dnl
 143
 144 dnl Several projects use the LLVM test suite, so configure it next.
 145 if test -d ${srcdir}/projects/test-suite ; then
 146   AC_CONFIG_SUBDIRS([projects/test-suite])
 147 fi
 148
 149 dnl llvm-test is the old name of the test-suite, kept here for backwards
 150 dnl compatibility
 151 if test -d ${srcdir}/projects/llvm-test ; then
 152   AC_CONFIG_SUBDIRS([projects/llvm-test])
 153 fi
 154
 155 dnl Some projects use poolalloc; configure that next
 156 if test -d ${srcdir}/projects/poolalloc ; then
 157   AC_CONFIG_SUBDIRS([projects/poolalloc])
 158 fi
 159
 160 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 161   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 162 fi
 163
 164 dnl Check for all other projects
 165 for i in `ls ${srcdir}/projects`
 166 do
 167   if test -d ${srcdir}/projects/${i} ; then
 168     case ${i} in
 169       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 170       compiler-rt)       ;;
 171       test-suite)     ;;
 172       llvm-test)      ;;
 173       poolalloc)      ;;
 174       llvm-poolalloc) ;;
 175       *)
 176         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 177         ;;
 178     esac
 179   fi
 180 done
 181
 182 dnl Disable the build of polly, even if it is checked out into tools/polly.
 183 AC_ARG_ENABLE(polly,
 184               AS_HELP_STRING([--enable-polly],
 185                              [Use polly if available (default is YES)]),,
 186                              enableval=default)
 187 case "$enableval" in
 188   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 189   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 190   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 191   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 192 esac
 193
 194
 195 dnl Check if polly is checked out into tools/polly and configure it if
 196 dnl available.
 197 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 198   AC_SUBST(LLVM_HAS_POLLY,1)
 199   AC_CONFIG_SUBDIRS([tools/polly])
 200 fi
 201
 202 dnl===-----------------------------------------------------------------------===
 203 dnl===
 204 dnl=== SECTION 2: Architecture, target, and host checks
 205 dnl===
 206 dnl===-----------------------------------------------------------------------===
 207
 208 dnl Check the target for which we're compiling and the host that will do the
 209 dnl compilations. This will tell us which LLVM compiler will be used for
 210 dnl compiling SSA into object code. This needs to be done early because
 211 dnl following tests depend on it.
 212 AC_CANONICAL_TARGET
 213
 214 dnl Determine the platform type and cache its value. This helps us configure
 215 dnl the System library to the correct build platform.
 216 AC_CACHE_CHECK([type of operating system we're going to host on],
 217                [llvm_cv_os_type],
 218 [case $host in
 219   *-*-aix*)
 220     llvm_cv_link_all_option="-Wl,--whole-archive"
 221     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 222     llvm_cv_os_type="AIX"
 223     llvm_cv_platform_type="Unix" ;;
 224   *-*-irix*)
 225     llvm_cv_link_all_option="-Wl,--whole-archive"
 226     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 227     llvm_cv_os_type="IRIX"
 228     llvm_cv_platform_type="Unix" ;;
 229   *-*-cygwin*)
 230     llvm_cv_link_all_option="-Wl,--whole-archive"
 231     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 232     llvm_cv_os_type="Cygwin"
 233     llvm_cv_platform_type="Unix" ;;
 234   *-*-darwin*)
 235     llvm_cv_link_all_option="-Wl,-all_load"
 236     llvm_cv_no_link_all_option="-Wl,-noall_load"
 237     llvm_cv_os_type="Darwin"
 238     llvm_cv_platform_type="Unix" ;;
 239   *-*-minix*)
 240     llvm_cv_link_all_option="-Wl,-all_load"
 241     llvm_cv_no_link_all_option="-Wl,-noall_load"
 242     llvm_cv_os_type="Minix"
 243     llvm_cv_platform_type="Unix" ;;
 244   *-*-freebsd*)
 245     llvm_cv_link_all_option="-Wl,--whole-archive"
 246     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 247     llvm_cv_os_type="FreeBSD"
 248     llvm_cv_platform_type="Unix" ;;
 249   *-*-kfreebsd-gnu)
 250     llvm_cv_link_all_option="-Wl,--whole-archive"
 251     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 252     llvm_cv_os_type="GNU/kFreeBSD"
 253     llvm_cv_platform_type="Unix" ;;
 254   *-*-openbsd*)
 255     llvm_cv_link_all_option="-Wl,--whole-archive"
 256     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 257     llvm_cv_os_type="OpenBSD"
 258     llvm_cv_platform_type="Unix" ;;
 259   *-*-netbsd*)
 260     llvm_cv_link_all_option="-Wl,--whole-archive"
 261     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 262     llvm_cv_os_type="NetBSD"
 263     llvm_cv_platform_type="Unix" ;;
 264   *-*-dragonfly*)
 265     llvm_cv_link_all_option="-Wl,--whole-archive"
 266     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 267     llvm_cv_os_type="DragonFly"
 268     llvm_cv_platform_type="Unix" ;;
 269   *-*-hpux*)
 270     llvm_cv_link_all_option="-Wl,--whole-archive"
 271     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 272     llvm_cv_os_type="HP-UX"
 273     llvm_cv_platform_type="Unix" ;;
 274   *-*-interix*)
 275     llvm_cv_link_all_option="-Wl,--whole-archive"
 276     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 277     llvm_cv_os_type="Interix"
 278     llvm_cv_platform_type="Unix" ;;
 279   *-*-linux*)
 280     llvm_cv_link_all_option="-Wl,--whole-archive"
 281     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 282     llvm_cv_os_type="Linux"
 283     llvm_cv_platform_type="Unix" ;;
 284   *-*-gnu*)
 285     llvm_cv_link_all_option="-Wl,--whole-archive"
 286     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 287     llvm_cv_os_type="GNU"
 288     llvm_cv_platform_type="Unix" ;;
 289   *-*-solaris*)
 290     llvm_cv_link_all_option="-Wl,-z,allextract"
 291     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 292     llvm_cv_os_type="SunOS"
 293     llvm_cv_platform_type="Unix" ;;
 294   *-*-auroraux*)
 295     llvm_cv_link_all_option="-Wl,-z,allextract"
 296     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 297     llvm_cv_os_type="AuroraUX"
 298     llvm_cv_platform_type="Unix" ;;
 299   *-*-win32*)
 300     llvm_cv_link_all_option="-Wl,--whole-archive"
 301     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 302     llvm_cv_os_type="Win32"
 303     llvm_cv_platform_type="Win32" ;;
 304   *-*-mingw*)
 305     llvm_cv_link_all_option="-Wl,--whole-archive"
 306     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 307     llvm_cv_os_type="MingW"
 308     llvm_cv_platform_type="Win32" ;;
 309   *-*-haiku*)
 310     llvm_cv_link_all_option="-Wl,--whole-archive"
 311     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 312     llvm_cv_os_type="Haiku"
 313     llvm_cv_platform_type="Unix" ;;
 314   *-unknown-eabi*)
 315     llvm_cv_link_all_option="-Wl,--whole-archive"
 316     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 317     llvm_cv_os_type="Freestanding"
 318     llvm_cv_platform_type="Unix" ;;
 319   *-unknown-elf*)
 320     llvm_cv_link_all_option="-Wl,--whole-archive"
 321     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 322     llvm_cv_os_type="Freestanding"
 323     llvm_cv_platform_type="Unix" ;;
 324   *)
 325     llvm_cv_link_all_option=""
 326     llvm_cv_no_link_all_option=""
 327     llvm_cv_os_type="Unknown"
 328     llvm_cv_platform_type="Unknown" ;;
 329 esac])
 330
 331 AC_CACHE_CHECK([type of operating system we're going to target],
 332                [llvm_cv_target_os_type],
 333 [case $target in
 334   *-*-aix*)
 335     llvm_cv_target_os_type="AIX" ;;
 336   *-*-irix*)
 337     llvm_cv_target_os_type="IRIX" ;;
 338   *-*-cygwin*)
 339     llvm_cv_target_os_type="Cygwin" ;;
 340   *-*-darwin*)
 341     llvm_cv_target_os_type="Darwin" ;;
 342   *-*-minix*)
 343     llvm_cv_target_os_type="Minix" ;;
 344   *-*-freebsd*)
 345     llvm_cv_target_os_type="FreeBSD" ;;
 346   *-*-kfreebsd-gnu)
 347     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 348   *-*-openbsd*)
 349     llvm_cv_target_os_type="OpenBSD" ;;
 350   *-*-netbsd*)
 351     llvm_cv_target_os_type="NetBSD" ;;
 352   *-*-dragonfly*)
 353     llvm_cv_target_os_type="DragonFly" ;;
 354   *-*-hpux*)
 355     llvm_cv_target_os_type="HP-UX" ;;
 356   *-*-interix*)
 357     llvm_cv_target_os_type="Interix" ;;
 358   *-*-linux*)
 359     llvm_cv_target_os_type="Linux" ;;
 360   *-*-gnu*)
 361     llvm_cv_target_os_type="GNU" ;;
 362   *-*-solaris*)
 363     llvm_cv_target_os_type="SunOS" ;;
 364   *-*-auroraux*)
 365     llvm_cv_target_os_type="AuroraUX" ;;
 366   *-*-win32*)
 367     llvm_cv_target_os_type="Win32" ;;
 368   *-*-mingw*)
 369     llvm_cv_target_os_type="MingW" ;;
 370   *-*-haiku*)
 371     llvm_cv_target_os_type="Haiku" ;;
 372   *-*-rtems*)
 373     llvm_cv_target_os_type="RTEMS" ;;
 374   *-*-nacl*)
 375     llvm_cv_target_os_type="NativeClient" ;;
 376   *-unknown-eabi*)
 377     llvm_cv_target_os_type="Freestanding" ;;
 378   *)
 379     llvm_cv_target_os_type="Unknown" ;;
 380 esac])
 381
 382 dnl Make sure we aren't attempting to configure for an unknown system
 383 if test "$llvm_cv_os_type" = "Unknown" ; then
 384   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 385 fi
 386
 387 dnl Set the "OS" Makefile variable based on the platform type so the
 388 dnl makefile can configure itself to specific build hosts
 389 AC_SUBST(OS,$llvm_cv_os_type)
 390 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 391 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 392
 393 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 394 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 395 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 396
 397 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 398 dnl This is used by lib/Support to determine the basic kind of implementation
 399 dnl to use.
 400 case $llvm_cv_platform_type in
 401   Unix)
 402     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 403     AC_SUBST(LLVM_ON_UNIX,[1])
 404     AC_SUBST(LLVM_ON_WIN32,[0])
 405     ;;
 406   Win32)
 407     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 408     AC_SUBST(LLVM_ON_UNIX,[0])
 409     AC_SUBST(LLVM_ON_WIN32,[1])
 410     ;;
 411 esac
 412
 413 dnl Determine what our target architecture is and configure accordingly.
 414 dnl This will allow Makefiles to make a distinction between the hardware and
 415 dnl the OS.
 416 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 417 [case $target in
 418   i?86-*)                 llvm_cv_target_arch="x86" ;;
 419   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 420   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 421   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 422   arm64*-*)               llvm_cv_target_arch="AArch64" ;;
 423   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 424   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 425   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 426   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 427   xcore-*)                llvm_cv_target_arch="XCore" ;;
 428   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 429   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 430   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 431   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 432   *)                      llvm_cv_target_arch="Unknown" ;;
 433 esac])
 434
 435 if test "$llvm_cv_target_arch" = "Unknown" ; then
 436   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 437 fi
 438
 439 dnl Determine the LLVM native architecture for the target
 440 case "$llvm_cv_target_arch" in
 441     x86)     LLVM_NATIVE_ARCH="X86" ;;
 442     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 443     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 444 esac
 445
 446 dnl Define a substitution, ARCH, for the target architecture
 447 AC_SUBST(ARCH,$llvm_cv_target_arch)
 448 AC_SUBST(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCH)
 449
 450 dnl Determine what our host architecture.
 451 dnl This will allow MCJIT regress tests runs only for supported
 452 dnl platforms.
 453 case $host in
 454   i?86-*)                 host_arch="x86" ;;
 455   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 456   sparc*-*)               host_arch="Sparc" ;;
 457   powerpc*-*)             host_arch="PowerPC" ;;
 458   arm64*-*)               host_arch="AArch64" ;;
 459   arm*-*)                 host_arch="ARM" ;;
 460   aarch64*-*)             host_arch="AArch64" ;;
 461   mips-* | mips64-*)      host_arch="Mips" ;;
 462   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 463   xcore-*)                host_arch="XCore" ;;
 464   msp430-*)               host_arch="MSP430" ;;
 465   hexagon-*)              host_arch="Hexagon" ;;
 466   s390x-*)                host_arch="SystemZ" ;;
 467   *)                      host_arch="Unknown" ;;
 468 esac
 469
 470 if test "$host_arch" = "Unknown" ; then
 471   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 472 fi
 473
 474 AC_SUBST(HOST_ARCH,$host_arch)
 475
 476 dnl Check for build platform executable suffix if we're cross-compiling
 477 if test "$cross_compiling" = yes; then
 478   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 479   AC_BUILD_EXEEXT
 480   ac_build_prefix=${build_alias}-
 481   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 482   if test -z "$BUILD_CXX"; then
 483      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 484      if test -z "$BUILD_CXX"; then
 485        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 486      fi
 487   fi
 488 else
 489   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 490 fi
 491
 492 dnl Check to see if there's a .svn or .git directory indicating that this
 493 dnl build is being done from a checkout. This sets up several defaults for
 494 dnl the command line switches. When we build with a checkout directory,
 495 dnl we get a debug with assertions turned on. Without, we assume a source
 496 dnl release and we get an optimized build without assertions.
 497 dnl See --enable-optimized and --enable-assertions below
 498 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 499   cvsbuild="yes"
 500   optimize="no"
 501   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 502 else
 503   cvsbuild="no"
 504   optimize="yes"
 505 fi
 506
 507 dnl===-----------------------------------------------------------------------===
 508 dnl===
 509 dnl=== SECTION 3: Command line arguments for the configure script.
 510 dnl===
 511 dnl===-----------------------------------------------------------------------===
 512
 513 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 514 AC_ARG_ENABLE(libcpp,
 515               AS_HELP_STRING([--enable-libcpp],
 516                              [Use libc++ if available (default is NO)]),,
 517                              enableval=default)
 518 case "$enableval" in
 519   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 520   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 521   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 522   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 523 esac
 524
 525 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
 526 dnl be bypassed by passing a flag if necessary on a platform. We have to do
 527 dnl these checks here so that we have the configuration of the standard C++
 528 dnl library finished.
 529 AC_ARG_ENABLE(compiler-version-checks,
 530               AS_HELP_STRING([--enable-compiler-version-checks],
 531                              [Check the version of the host compiler (default is YES)]),,
 532                              enableval=default)
 533 case "$enableval" in
 534   no)
 535     ;;
 536   yes|default)
 537     AC_LANG_PUSH([C++])
 538     case "$llvm_cv_cxx_compiler" in
 539     clang)
 540       AC_MSG_CHECKING([whether Clang is new enough])
 541       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 542 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
 543 #error This version of Clang is too old to build LLVM
 544 #endif
 545 ]])],
 546           [AC_MSG_RESULT([yes])],
 547           [AC_MSG_RESULT([no])
 548            AC_MSG_ERROR([
 549 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
 550 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
 551 bypass these sanity checks.])])
 552
 553       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
 554       dnl are sometimes deeply confusing though. Here we test for an obvious
 555       dnl incomplete feature in 4.6's standard library that was completed in
 556       dnl 4.7's. We also have to disable this test if 'ENABLE_LIBCPP' is set
 557       dnl because the enable flags don't actually fix CXXFLAGS, they rely on
 558       dnl that happening in the Makefile.
 559       if test "$ENABLE_LIBCPP" -eq 0 ; then
 560         AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
 561         llvm_cv_old_cxxflags="$CXXFLAGS"
 562         CXXFLAGS="$CXXFLAGS -std=c++0x"
 563         AC_LINK_IFELSE([AC_LANG_SOURCE([[
 564 #include <atomic>
 565 std::atomic<float> x(0.0f);
 566 int main() { return (float)x; }
 567 ]])],
 568             [AC_MSG_RESULT([yes])],
 569             [AC_MSG_RESULT([no])
 570              AC_MSG_ERROR([
 571 We detected a missing feature in the standard C++ library that was known to be
 572 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
 573 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
 574 than 4.7. You will need to update your system and ensure Clang uses the newer
 575 standard library.
 576
 577 If this error is incorrect or you need to force things to work, you may pass
 578 '--disable-compiler-version-checks' to configure to bypass this test.])])
 579         CXXFLAGS="$llvm_cv_old_cxxflags"
 580       fi
 581       ;;
 582     gcc)
 583       AC_MSG_CHECKING([whether GCC is new enough])
 584       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 585 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 586 #error This version of GCC is too old to build LLVM
 587 #endif
 588 ]])],
 589           [AC_MSG_RESULT([yes])],
 590           [AC_MSG_RESULT([no])
 591            AC_MSG_ERROR([
 592 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
 593 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
 594 bypass these sanity checks.])])
 595       ;;
 596     unknown)
 597       ;;
 598     esac
 599     AC_LANG_POP([C++])
 600     ;;
 601   *)
 602     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
 603     ;;
 604 esac
 605
 606 dnl --enable-cxx1y : check whether or not to use -std=c++1y on the command line
 607 AC_ARG_ENABLE(cxx1y,
 608               AS_HELP_STRING([--enable-cxx1y],
 609                              [Use c++1y if available (default is NO)]),,
 610                              enableval=default)
 611 case "$enableval" in
 612   yes) AC_SUBST(ENABLE_CXX1Y,[1]) ;;
 613   no)  AC_SUBST(ENABLE_CXX1Y,[0]) ;;
 614   default) AC_SUBST(ENABLE_CXX1Y,[0]);;
 615   *) AC_MSG_ERROR([Invalid setting for --enable-cxx1y. Use "yes" or "no"]) ;;
 616 esac
 617
 618 dnl --enable-split-dwarf : check whether or not to use -gsplit-dwarf on the command
 619 dnl line
 620 AC_ARG_ENABLE(split-dwarf,
 621               AS_HELP_STRING([--enable-split-dwarf],
 622                              [Use split-dwarf if available (default is NO)]),,
 623                              enableval=default)
 624 case "$enableval" in
 625   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 626   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 627   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 628   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 629 esac
 630
 631 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 632 clang_arcmt="yes"
 633 AC_ARG_ENABLE(clang-arcmt,
 634               AS_HELP_STRING([--enable-clang-arcmt],
 635                              [Enable building of clang ARCMT (default is YES)]),
 636                              clang_arcmt="$enableval",
 637                              enableval="yes")
 638 case "$enableval" in
 639   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 640   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 641   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 642   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 643 esac
 644
 645 dnl --enable-clang-plugin-support: check whether to enable plugins in clang
 646 clang_plugin_support="yes"
 647 AC_ARG_ENABLE(clang-plugin-support,
 648               AS_HELP_STRING([--enable-clang-plugin-support],
 649                              [Enable plugin support in clang (default is YES)]),
 650                              clang_plugin_support="$enableval",
 651                              enableval="yes")
 652 case "$enableval" in
 653   yes) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]) ;;
 654   no)  AC_SUBST(CLANG_PLUGIN_SUPPORT,[0]) ;;
 655   default) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]);;
 656   *) AC_MSG_ERROR([Invalid setting for --enable-clang-plugin-support. Use "yes" or "no"]) ;;
 657 esac
 658
 659 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 660 clang_static_analyzer="yes"
 661 AC_ARG_ENABLE(clang-static-analyzer,
 662               AS_HELP_STRING([--enable-clang-static-analyzer],
 663                              [Enable building of clang Static Analyzer (default is YES)]),
 664                              clang_static_analyzer="$enableval",
 665                              enableval="yes")
 666 case "$enableval" in
 667   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 668   no)
 669     if test ${clang_arcmt} != "no" ; then
 670       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 671     fi
 672     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 673     ;;
 674   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 675   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 676 esac
 677
 678 dnl --enable-clang-rewriter: check whether to enable clang rewriter
 679 AC_ARG_ENABLE(clang-rewriter,
 680               AS_HELP_STRING([--enable-clang-rewriter],
 681                              [Enable building of clang rewriter (default is YES)]),,
 682                              enableval="yes")
 683 case "$enableval" in
 684   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
 685   no)
 686     if test ${clang_arcmt} != "no" ; then
 687       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
 688     fi
 689     if test ${clang_static_analyzer} != "no" ; then
 690       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
 691     fi
 692     AC_SUBST(ENABLE_CLANG_REWRITER,[0])
 693     ;;
 694   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
 695   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
 696 esac
 697
 698 dnl --enable-optimized : check whether they want to do an optimized build:
 699 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 700  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 701 if test ${enableval} = "no" ; then
 702   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 703 else
 704   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 705 fi
 706
 707 dnl --enable-profiling : check whether they want to do a profile build:
 708 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 709  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 710 if test ${enableval} = "no" ; then
 711   AC_SUBST(ENABLE_PROFILING,[[]])
 712 else
 713   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 714 fi
 715
 716 dnl --enable-assertions : check whether they want to turn on assertions or not:
 717 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 718   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 719 if test ${enableval} = "yes" ; then
 720   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 721 else
 722   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 723 fi
 724
 725 dnl --enable-werror : check whether we want Werror on by default
 726 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 727   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 728 case "$enableval" in
 729   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 730   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 731   default) AC_SUBST(ENABLE_WERROR,[0]);;
 732   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 733 esac
 734
 735 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 736 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 737   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 738 if test ${enableval} = "yes" ; then
 739   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 740   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 741 else
 742   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 743   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 744 fi
 745
 746 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 747 AC_ARG_ENABLE(debug-runtime,
 748    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 749 if test ${enableval} = "no" ; then
 750   AC_SUBST(DEBUG_RUNTIME,[[]])
 751 else
 752   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 753 fi
 754
 755 dnl --enable-debug-symbols : should even optimized compiler libraries
 756 dnl have debug symbols?
 757 AC_ARG_ENABLE(debug-symbols,
 758    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 759 if test ${enableval} = "no" ; then
 760   AC_SUBST(DEBUG_SYMBOLS,[[]])
 761 else
 762   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 763 fi
 764
 765 dnl --enable-keep-symbols : do not strip installed executables
 766 AC_ARG_ENABLE(keep-symbols,
 767    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 768 if test ${enableval} = "no" ; then
 769   AC_SUBST(KEEP_SYMBOLS,[[]])
 770 else
 771   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 772 fi
 773
 774 dnl --enable-jit: check whether they want to enable the jit
 775 AC_ARG_ENABLE(jit,
 776   AS_HELP_STRING(--enable-jit,
 777                  [Enable Just In Time Compiling (default is YES)]),,
 778   enableval=default)
 779 if test ${enableval} = "no"
 780 then
 781   AC_SUBST(JIT,[[]])
 782 else
 783   case "$llvm_cv_target_arch" in
 784     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 785     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 786     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 787     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 788     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 789     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 790     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 791     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 792     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 793     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 794     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 795     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 796   esac
 797 fi
 798
 799 TARGETS_WITH_JIT="ARM AArch64 Mips PowerPC SystemZ X86"
 800 AC_SUBST(TARGETS_WITH_JIT,$TARGETS_WITH_JIT)
 801
 802 dnl Allow enablement of building and installing docs
 803 AC_ARG_ENABLE(docs,
 804               AS_HELP_STRING([--enable-docs],
 805                              [Build documents (default is YES)]),,
 806                              enableval=default)
 807 case "$enableval" in
 808   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 809   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 810   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 811   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 812 esac
 813
 814 dnl Allow enablement of doxygen generated documentation
 815 AC_ARG_ENABLE(doxygen,
 816               AS_HELP_STRING([--enable-doxygen],
 817                              [Build doxygen documentation (default is NO)]),,
 818                              enableval=default)
 819 case "$enableval" in
 820   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 821   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 822   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 823   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 824 esac
 825
 826 dnl Allow disablement of threads
 827 AC_ARG_ENABLE(threads,
 828               AS_HELP_STRING([--enable-threads],
 829                              [Use threads if available (default is YES)]),,
 830                              enableval=default)
 831 case "$enableval" in
 832   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 833   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 834   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 835   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 836 esac
 837 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 838                    [Define if threads enabled])
 839
 840 dnl Allow disablement of pthread.h
 841 AC_ARG_ENABLE(pthreads,
 842               AS_HELP_STRING([--enable-pthreads],
 843                              [Use pthreads if available (default is YES)]),,
 844                              enableval=default)
 845 case "$enableval" in
 846   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 847   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 848   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 849   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 850 esac
 851
 852 dnl Allow disablement of zlib
 853 AC_ARG_ENABLE(zlib,
 854               AS_HELP_STRING([--enable-zlib],
 855                              [Use zlib for compression/decompression if
 856                               available (default is YES)]),,
 857                               enableval=default)
 858 case "$enableval" in
 859   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 860   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 861   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 862   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 863 esac
 864 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 865                    [Define if zlib is enabled])
 866
 867 dnl Allow building without position independent code
 868 AC_ARG_ENABLE(pic,
 869   AS_HELP_STRING([--enable-pic],
 870                  [Build LLVM with Position Independent Code (default is YES)]),,
 871                  enableval=default)
 872 case "$enableval" in
 873   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 874   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 875   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 876   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 877 esac
 878 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 879                    [Define if position independent code is enabled])
 880
 881 dnl Allow building a shared library and linking tools against it.
 882 AC_ARG_ENABLE(shared,
 883   AS_HELP_STRING([--enable-shared],
 884                  [Build a shared library and link tools against it (default is NO)]),,
 885                  enableval=default)
 886 case "$enableval" in
 887   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 888   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 889   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 890   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 891 esac
 892
 893 dnl Allow libstdc++ is embedded in LLVM.dll.
 894 AC_ARG_ENABLE(embed-stdcxx,
 895   AS_HELP_STRING([--enable-embed-stdcxx],
 896                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 897                  enableval=default)
 898 case "$enableval" in
 899   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 900   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 901   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 902   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 903 esac
 904
 905 dnl Enable embedding timestamp information into build.
 906 AC_ARG_ENABLE(timestamps,
 907   AS_HELP_STRING([--enable-timestamps],
 908                  [Enable embedding timestamp information in build (default is YES)]),,
 909                  enableval=default)
 910 case "$enableval" in
 911   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 912   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 913   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 914   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 915 esac
 916 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 917                    [Define if timestamp information (e.g., __DATE__) is allowed])
 918
 919 dnl Enable support for showing backtraces.
 920 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
 921   [--enable-backtraces],
 922   [Enable embedding backtraces on crash (default is YES)]),
 923   [case "$enableval" in
 924     yes) llvm_cv_enable_backtraces="yes" ;;
 925     no)  llvm_cv_enable_backtraces="no"  ;;
 926     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 927   esac],
 928   llvm_cv_enable_backtraces="yes")
 929 if test "$llvm_cv_enable_backtraces" = "yes" ; then
 930   AC_DEFINE([ENABLE_BACKTRACES],[1],
 931             [Define if you want backtraces on crash])
 932 fi
 933
 934 dnl Enable installing platform specific signal handling overrides, for improved
 935 dnl CrashRecovery support or interaction with crash reporting software. This
 936 dnl support may be inappropriate for some clients embedding LLVM as a library.
 937 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
 938   [--enable-crash-overrides],
 939   [Enable crash handling overrides (default is YES)]),
 940   [case "$enableval" in
 941     yes) llvm_cv_enable_crash_overrides="yes" ;;
 942     no)  llvm_cv_enable_crash_overrides="no"  ;;
 943     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
 944   esac],
 945   llvm_cv_enable_crash_overrides="yes")
 946 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
 947   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
 948             [Define to enable crash handling overrides])
 949 fi
 950
 951 dnl List all possible targets
 952 ALL_TARGETS="X86 Sparc PowerPC ARM AArch64 Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600"
 953 AC_SUBST(ALL_TARGETS,$ALL_TARGETS)
 954
 955 dnl Allow specific targets to be specified for building (or not)
 956 TARGETS_TO_BUILD=""
 957 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 958     [Build specific host targets: all or target1,target2,... Valid targets are:
 959      host, x86, x86_64, sparc, powerpc, arm64, arm, aarch64, mips, hexagon,
 960      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
 961     enableval=all)
 962 if test "$enableval" = host-only ; then
 963   enableval=host
 964 fi
 965 case "$enableval" in
 966   all) TARGETS_TO_BUILD="$ALL_TARGETS" ;;
 967   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 968       case "$a_target" in
 969         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 970         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 971         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 972         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 973         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 974         arm64)    TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 975         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 976         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 977         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 978         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 979         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 980         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 981         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 982         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 983         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 984         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 985         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 986         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
 987         host) case "$llvm_cv_target_arch" in
 988             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 989             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 990             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 991             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 992             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 993             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 994             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 995             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 996             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 997             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 998             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 999             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
1000             *)       AC_MSG_ERROR([Can not set target to build]) ;;
1001           esac ;;
1002         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
1003       esac
1004   done
1005   ;;
1006 esac
1007
1008 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
1009     [Build experimental host targets: disable or target1,target2,...
1010      (default=disable)]),,
1011     enableval=disable)
1012
1013 if test ${enableval} != "disable"
1014 then
1015   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
1016 fi
1017
1018 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
1019
1020 dnl Determine whether we are building LLVM support for the native architecture.
1021 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
1022 for a_target in $TARGETS_TO_BUILD; do
1023   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
1024     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
1025       [LLVM architecture name for the native architecture, if available])
1026     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
1027     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
1028     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
1029     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
1030     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1031       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
1032     fi
1033     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1034       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
1035     fi
1036     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
1037       [LLVM name for the native Target init function, if available])
1038     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
1039       [LLVM name for the native TargetInfo init function, if available])
1040     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
1041       [LLVM name for the native target MC init function, if available])
1042     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1043       [LLVM name for the native AsmPrinter init function, if available])
1044     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1045       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1046        [LLVM name for the native AsmParser init function, if available])
1047     fi
1048     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1049       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1050        [LLVM name for the native Disassembler init function, if available])
1051     fi
1052   fi
1053 done
1054
1055 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1056 dnl target feature def files.
1057 LLVM_ENUM_TARGETS=""
1058 LLVM_ENUM_ASM_PRINTERS=""
1059 LLVM_ENUM_ASM_PARSERS=""
1060 LLVM_ENUM_DISASSEMBLERS=""
1061 for target_to_build in $TARGETS_TO_BUILD; do
1062   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1063   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1064     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1065   fi
1066   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1067     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1068   fi
1069   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1070     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1071   fi
1072 done
1073 AC_SUBST(LLVM_ENUM_TARGETS)
1074 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1075 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1076 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1077
1078 dnl Override the option to use for optimized builds.
1079 AC_ARG_WITH(optimize-option,
1080   AS_HELP_STRING([--with-optimize-option],
1081                  [Select the compiler options to use for optimized builds]),,
1082                  withval=default)
1083 AC_MSG_CHECKING([optimization flags])
1084 case "$withval" in
1085   default)
1086     case "$llvm_cv_os_type" in
1087     FreeBSD) optimize_option=-O2 ;;
1088     MingW) optimize_option=-O2 ;;
1089     *)     optimize_option=-O3 ;;
1090     esac ;;
1091   *) optimize_option="$withval" ;;
1092 esac
1093 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1094 AC_MSG_RESULT([$optimize_option])
1095
1096 dnl Specify extra build options
1097 AC_ARG_WITH(extra-options,
1098   AS_HELP_STRING([--with-extra-options],
1099                  [Specify additional options to compile LLVM with]),,
1100                  withval=default)
1101 case "$withval" in
1102   default) EXTRA_OPTIONS= ;;
1103   *) EXTRA_OPTIONS=$withval ;;
1104 esac
1105 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1106
1107 dnl Specify extra linker build options
1108 AC_ARG_WITH(extra-ld-options,
1109   AS_HELP_STRING([--with-extra-ld-options],
1110                  [Specify additional options to link LLVM with]),,
1111                  withval=default)
1112 case "$withval" in
1113   default) EXTRA_LD_OPTIONS= ;;
1114   *) EXTRA_LD_OPTIONS=$withval ;;
1115 esac
1116 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1117
1118 dnl Allow specific bindings to be specified for building (or not)
1119 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1120     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1121     enableval=default)
1122 BINDINGS_TO_BUILD=""
1123 case "$enableval" in
1124   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1125   all ) BINDINGS_TO_BUILD="ocaml" ;;
1126   none | no) BINDINGS_TO_BUILD="" ;;
1127   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1128       case "$a_binding" in
1129         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1130         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1131       esac
1132   done
1133   ;;
1134 esac
1135
1136 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1137 dnl script for bindings/ocaml/configure, except that its auto value depends on
1138 dnl OCAMLC, which is found here to support tests.
1139 AC_ARG_WITH([ocaml-libdir],
1140   [AS_HELP_STRING([--with-ocaml-libdir],
1141     [Specify install location for ocaml bindings (default is stdlib)])],
1142   [],
1143   [withval=auto])
1144 case "$withval" in
1145   auto) with_ocaml_libdir="$withval" ;;
1146   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1147   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1148 esac
1149
1150 AC_ARG_WITH(clang-srcdir,
1151   AS_HELP_STRING([--with-clang-srcdir],
1152     [Directory to the out-of-tree Clang source]),,
1153     withval="-")
1154 case "$withval" in
1155   -) clang_src_root="" ;;
1156   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1157   *) clang_src_root="$ac_pwd/$withval" ;;
1158 esac
1159 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1160
1161 AC_ARG_WITH(clang-resource-dir,
1162   AS_HELP_STRING([--with-clang-resource-dir],
1163     [Relative directory from the Clang binary for resource files]),,
1164     withval="")
1165 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1166                    [Relative directory for resource files])
1167
1168 AC_ARG_WITH(c-include-dirs,
1169   AS_HELP_STRING([--with-c-include-dirs],
1170     [Colon separated list of directories clang will search for headers]),,
1171     withval="")
1172 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1173                    [Directories clang will search for headers])
1174
1175 # Clang normally uses the system c++ headers and libraries. With this option,
1176 # clang will use the ones provided by a gcc installation instead. This option should
1177 # be passed the same value that was used with --prefix when configuring gcc.
1178 AC_ARG_WITH(gcc-toolchain,
1179   AS_HELP_STRING([--with-gcc-toolchain],
1180     [Directory where gcc is installed.]),,
1181     withval="")
1182 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1183                    [Directory where gcc is installed.])
1184
1185 AC_ARG_WITH(default-sysroot,
1186   AS_HELP_STRING([--with-default-sysroot],
1187     [Add --sysroot=<path> to all compiler invocations.]),,
1188     withval="")
1189 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1190                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1191
1192 dnl Allow linking of LLVM with GPLv3 binutils code.
1193 AC_ARG_WITH(binutils-include,
1194   AS_HELP_STRING([--with-binutils-include],
1195     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1196   withval=default)
1197 case "$withval" in
1198   default) WITH_BINUTILS_INCDIR=default ;;
1199   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1200   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1201 esac
1202 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1203   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1204   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1205      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1206      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1207   fi
1208 fi
1209
1210 dnl Specify the URL where bug reports should be submitted.
1211 AC_ARG_WITH(bug-report-url,
1212   AS_HELP_STRING([--with-bug-report-url],
1213     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1214     withval="http://llvm.org/bugs/")
1215 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1216                    [Bug report URL.])
1217
1218 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1219 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1220   [--enable-terminfo],
1221   [Query the terminfo database if available (default is YES)]),
1222   [case "$enableval" in
1223     yes) llvm_cv_enable_terminfo="yes" ;;
1224     no)  llvm_cv_enable_terminfo="no"  ;;
1225     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1226   esac],
1227   llvm_cv_enable_terminfo="yes")
1228 case "$llvm_cv_enable_terminfo" in
1229   yes) AC_SUBST(ENABLE_TERMINFO,[1]) ;;
1230   no)  AC_SUBST(ENABLE_TERMINFO,[0]) ;;
1231 esac
1232
1233 dnl --enable-libedit: check whether the user wants to turn off libedit.
1234 AC_ARG_ENABLE(libedit,AS_HELP_STRING(
1235   [--enable-libedit],
1236   [Use libedit if available (default is YES)]),
1237   [case "$enableval" in
1238     yes) llvm_cv_enable_libedit="yes" ;;
1239     no)  llvm_cv_enable_libedit="no"  ;;
1240     *) AC_MSG_ERROR([Invalid setting for --enable-libedit. Use "yes" or "no"]) ;;
1241   esac],
1242   llvm_cv_enable_libedit="yes")
1243
1244 dnl --enable-libffi : check whether the user wants to turn off libffi:
1245 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1246   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1247   [case "$enableval" in
1248     yes) llvm_cv_enable_libffi="yes" ;;
1249     no)  llvm_cv_enable_libffi="no"  ;;
1250     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1251   esac],
1252   llvm_cv_enable_libffi=no)
1253
1254 AC_ARG_WITH(internal-prefix,
1255   AS_HELP_STRING([--with-internal-prefix],
1256     [Installation directory for internal files]),,
1257     withval="")
1258 AC_SUBST(INTERNAL_PREFIX,[$withval])
1259
1260 dnl===-----------------------------------------------------------------------===
1261 dnl===
1262 dnl=== SECTION 4: Check for programs we need and that they are the right version
1263 dnl===
1264 dnl===-----------------------------------------------------------------------===
1265
1266 dnl Check for the tools that the makefiles require
1267 AC_CHECK_GNU_MAKE
1268 AC_PROG_LN_S
1269 AC_PATH_PROG(NM, [nm], [nm])
1270 AC_PATH_PROG(CMP, [cmp], [cmp])
1271 AC_PATH_PROG(CP, [cp], [cp])
1272 AC_PATH_PROG(DATE, [date], [date])
1273 AC_PATH_PROG(FIND, [find], [find])
1274 AC_PATH_PROG(GREP, [grep], [grep])
1275 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1276 AC_PATH_PROG(MV,   [mv],   [mv])
1277 AC_PROG_RANLIB
1278 AC_CHECK_TOOL(AR, ar, false)
1279 AC_PATH_PROG(RM,   [rm],   [rm])
1280 AC_PATH_PROG(SED,  [sed],  [sed])
1281 AC_PATH_PROG(TAR,  [tar],  [gtar])
1282 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1283
1284 dnl Looking for misc. graph plotting software
1285 AC_PATH_PROG(DOT, [dot], [echo dot])
1286 if test "$DOT" != "echo dot" ; then
1287   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1288   dnl If we're targeting for mingw we should emit windows paths, not msys
1289   if test "$llvm_cv_os_type" = "MingW" ; then
1290     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1291   fi
1292   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1293    [Define to path to dot program if found or 'echo dot' otherwise])
1294 fi
1295
1296 dnl Find the install program
1297 AC_PROG_INSTALL
1298 dnl Prepend src dir to install path dir if it's a relative path
1299 dnl This is a hack for installs that take place in something other
1300 dnl than the top level.
1301 case "$INSTALL" in
1302  [[\\/$]]* | ?:[[\\/]]* ) ;;
1303  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1304 esac
1305
1306 dnl Checks for documentation and testing tools that we can do without. If these
1307 dnl are not found then they are set to "true" which always succeeds but does
1308 dnl nothing. This just lets the build output show that we could have done
1309 dnl something if the tool was available.
1310 AC_PATH_PROG(BZIP2, [bzip2])
1311 AC_PATH_PROG(CAT, [cat])
1312 AC_PATH_PROG(DOXYGEN, [doxygen])
1313 AC_PATH_PROG(GROFF, [groff])
1314 AC_PATH_PROG(GZIPBIN, [gzip])
1315 AC_PATH_PROG(PDFROFF, [pdfroff])
1316 AC_PATH_PROG(ZIP, [zip])
1317 AC_PATH_PROGS(OCAMLC, [ocamlc])
1318 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1319 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1320 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1321 AC_PATH_PROGS(GAS, [gas as])
1322
1323 dnl Get the version of the linker in use.
1324 AC_LINK_GET_VERSION
1325
1326 dnl Determine whether the linker supports the -R option.
1327 AC_LINK_USE_R
1328
1329 dnl Determine whether the compiler supports the -rdynamic option.
1330 AC_LINK_EXPORT_DYNAMIC
1331
1332 dnl Determine whether the linker supports the --version-script option.
1333 AC_LINK_VERSION_SCRIPT
1334
1335 AC_CHECK_HEADERS([errno.h])
1336
1337 case "$llvm_cv_os_type" in
1338   Cygwin|MingW|Win32) llvm_shlib_ext=.dll ;;
1339   Darwin) llvm_shlib_ext=.dylib ;;
1340   *) llvm_shlib_ext=.so ;;
1341 esac
1342
1343 AC_DEFINE_UNQUOTED([LTDL_SHLIB_EXT], ["$llvm_shlib_ext"], [The shared library extension])
1344
1345 AC_MSG_CHECKING([tool compatibility])
1346
1347 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1348 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1349 dnl to support those options.
1350 dnl "icc" emits gcc signatures
1351 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1352 ICC=no
1353 IXX=no
1354 case $CC in
1355   icc*|icpc*)
1356     ICC=yes
1357     IXX=yes
1358     ;;
1359    *)
1360     ;;
1361 esac
1362
1363 if test "$GCC" != "yes" && test "$ICC" != "yes"
1364 then
1365   AC_MSG_ERROR([gcc|icc required but not found])
1366 fi
1367
1368 dnl Ensure that compilation tools are compatible with GCC extensions
1369 if test "$GXX" != "yes" && test "$IXX" != "yes"
1370 then
1371   AC_MSG_ERROR([g++|clang++|icc required but not found])
1372 fi
1373
1374 dnl Verify that GCC is version 3.0 or higher
1375 if test "$GCC" = "yes"
1376 then
1377   AC_COMPILE_IFELSE(
1378 [
1379   AC_LANG_SOURCE([[
1380     #if !defined(__GNUC__) || __GNUC__ < 3
1381     #error Unsupported GCC version
1382     #endif
1383   ]])
1384 ],
1385 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1386 fi
1387
1388 dnl Check for GNU Make.  We use its extensions, so don't build without it
1389 if test -z "$llvm_cv_gnu_make_command"
1390 then
1391   AC_MSG_ERROR([GNU Make required but not found])
1392 fi
1393
1394 dnl Tool compatibility is okay if we make it here.
1395 AC_MSG_RESULT([ok])
1396
1397 dnl Check optional compiler flags.
1398 AC_MSG_CHECKING([optional compiler flags])
1399 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1400 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1401 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1402
1403 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1404 dnl false positives, so disable it.
1405 NO_UNINITIALIZED=
1406 NO_MAYBE_UNINITIALIZED=
1407 if test "$GXX" = "yes"
1408 then
1409   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1410   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1411   dnl known to be uninitialized from cases which might be uninitialized.  We
1412   dnl still want to catch the first kind of errors.
1413   if test -z "$NO_MAYBE_UNINITIALIZED"
1414   then
1415     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1416   fi
1417 fi
1418 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1419
1420 AC_ARG_WITH([python],
1421             [AS_HELP_STRING([--with-python], [path to python])],
1422             [PYTHON="$withval"])
1423
1424 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1425   AC_MSG_CHECKING([for python])
1426   AC_MSG_RESULT([user defined: $with_python])
1427 else
1428   if test -n "$PYTHON" ; then
1429     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1430   fi
1431
1432   AC_PATH_PROG([PYTHON], [python python2 python26],
1433                [AC_MSG_RESULT([not found])
1434                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1435 fi
1436
1437 AC_MSG_CHECKING([for python >= 2.5])
1438 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1439 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1440 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1441 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1442 if test "$ac_python_version_major" -gt "2" || \
1443    (test "$ac_python_version_major" -eq "2" && \
1444     test "$ac_python_version_minor" -ge "5") ; then
1445   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1446 else
1447   AC_MSG_RESULT([not found])
1448   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1449 fi
1450
1451 dnl===-----------------------------------------------------------------------===
1452 dnl===
1453 dnl=== SECTION 5: Check for libraries
1454 dnl===
1455 dnl===-----------------------------------------------------------------------===
1456
1457 AC_CHECK_LIB(m,sin)
1458 if test "$llvm_cv_os_type" = "MingW" ; then
1459   AC_CHECK_LIB(imagehlp, main)
1460   AC_CHECK_LIB(psapi, main)
1461   AC_CHECK_LIB(shell32, main)
1462 fi
1463
1464 dnl dlopen() is required for plugin support.
1465 AC_SEARCH_LIBS(dlopen,dl,LLVM_DEFINE_SUBST([HAVE_DLOPEN],[1],
1466                [Define if dlopen() is available on this platform.]),
1467                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1468
1469 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1470 dnl macros to detect whether clock_gettime is available, this just finds the
1471 dnl right libraries to link with.
1472 AC_SEARCH_LIBS(clock_gettime,rt)
1473
1474 dnl The curses library is optional; used for querying terminal info
1475 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1476   dnl We need the has_color functionality in curses for it to be useful.
1477   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1478                  LLVM_DEFINE_SUBST([HAVE_TERMINFO],[1],
1479                                    [Define if the setupterm() function is supported this platform.]))
1480 fi
1481
1482 dnl The libedit library is optional; used by lib/LineEditor
1483 if test "$llvm_cv_enable_libedit" = "yes" ; then
1484   AC_SEARCH_LIBS(el_init,edit,
1485                  AC_DEFINE([HAVE_LIBEDIT],[1],
1486                            [Define if libedit is available on this platform.]))
1487 fi
1488
1489 dnl libffi is optional; used to call external functions from the interpreter
1490 if test "$llvm_cv_enable_libffi" = "yes" ; then
1491   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1492                  [Define if libffi is available on this platform.]),
1493                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1494 fi
1495
1496 dnl mallinfo is optional; the code can compile (minus features) without it
1497 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1498                [Define if mallinfo() is available on this platform.]))
1499
1500 dnl pthread locking functions are optional - but llvm will not be thread-safe
1501 dnl without locks.
1502 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1503   AC_CHECK_LIB(pthread, pthread_mutex_init)
1504   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1505                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1506                            [Have pthread_mutex_lock]))
1507   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1508                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1509                  [Have pthread_rwlock_init]))
1510   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1511                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1512                  [Have pthread_getspecific]))
1513 fi
1514
1515 dnl zlib is optional; used for compression/uncompression
1516 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1517   AC_CHECK_LIB(z, compress2)
1518 fi
1519
1520 dnl Allow extra x86-disassembler library
1521 AC_ARG_WITH(udis86,
1522   AS_HELP_STRING([--with-udis86=<path>],
1523     [Use udis86 external x86 disassembler library]),
1524     [
1525       AC_SUBST(USE_UDIS86, [1])
1526       case "$withval" in
1527         /usr/lib|yes) ;;
1528         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1529       esac
1530       AC_CHECK_LIB(udis86, ud_init, [], [
1531         echo "Error! You need to have libudis86 around."
1532         exit -1
1533       ])
1534     ],
1535     AC_SUBST(USE_UDIS86, [0]))
1536 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1537                    [Define if use udis86 library])
1538
1539 dnl Allow OProfile support for JIT output.
1540 AC_ARG_WITH(oprofile,
1541   AS_HELP_STRING([--with-oprofile=<prefix>],
1542     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1543     [
1544       AC_SUBST(USE_OPROFILE, [1])
1545       case "$withval" in
1546         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1547         no) llvm_cv_oppath=
1548             AC_SUBST(USE_OPROFILE, [0]) ;;
1549         *) llvm_cv_oppath="${withval}/lib/oprofile"
1550            CPPFLAGS="-I${withval}/include";;
1551       esac
1552       case $llvm_cv_os_type in
1553         Linux)
1554           if test -n "$llvm_cv_oppath" ; then
1555             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1556             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1557             dnl libbfd is not included properly in libopagent in some Debian
1558             dnl versions.  If libbfd isn't found at all, we assume opagent works
1559             dnl anyway.
1560             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1561             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1562               echo "Error! You need to have libopagent around."
1563               exit -1
1564             ])
1565             AC_CHECK_HEADER([opagent.h], [], [
1566               echo "Error! You need to have opagent.h around."
1567               exit -1
1568               ])
1569           fi ;;
1570         *)
1571           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1572       esac
1573     ],
1574     [
1575       AC_SUBST(USE_OPROFILE, [0])
1576     ])
1577 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1578                    [Define if we have the oprofile JIT-support library])
1579
1580 dnl Enable support for Intel JIT Events API.
1581 AC_ARG_WITH(intel-jitevents,
1582   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1583     [
1584        case "$withval" in
1585           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1586           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1587           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1588        esac
1589
1590       case $llvm_cv_os_type in
1591         Linux|Win32|Cygwin|MingW) ;;
1592         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1593       esac
1594
1595       case "$llvm_cv_target_arch" in
1596         x86|x86_64) ;;
1597         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1598       esac
1599     ],
1600     [
1601       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1602     ])
1603 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1604                    [Define if we have the Intel JIT API runtime support library])
1605
1606 dnl Check for libxml2
1607 dnl Right now we're just checking for the existence, we could also check for a
1608 dnl particular version via --version on xml2-config
1609 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1610
1611 AC_MSG_CHECKING(for libxml2 includes)
1612 if test "x$XML2CONFIG" = "x"; then
1613  AC_MSG_RESULT(xml2-config not found)
1614 else
1615  LIBXML2_INC=`$XML2CONFIG --cflags`
1616  AC_MSG_RESULT($LIBXML2_INC)
1617  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1618                                 LIBXML2_LIBS="-lxml2"])
1619 fi
1620 AC_SUBST(LIBXML2_LIBS)
1621 AC_SUBST(LIBXML2_INC)
1622
1623 dnl===-----------------------------------------------------------------------===
1624 dnl===
1625 dnl=== SECTION 6: Check for header files
1626 dnl===
1627 dnl===-----------------------------------------------------------------------===
1628
1629 dnl First, use autoconf provided macros for specific headers that we need
1630 dnl We don't check for ancient stuff or things that are guaranteed to be there
1631 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1632 dnl Generally we're looking for POSIX headers.
1633 AC_HEADER_DIRENT
1634 AC_HEADER_MMAP_ANONYMOUS
1635 AC_HEADER_STAT
1636 AC_HEADER_SYS_WAIT
1637 AC_HEADER_TIME
1638
1639 AC_LANG_PUSH([C++])
1640 AC_CHECK_HEADERS([cxxabi.h])
1641 AC_LANG_POP([C++])
1642 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1643 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1644 AC_CHECK_HEADERS([utime.h])
1645 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1646 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1647 AC_CHECK_HEADERS([valgrind/valgrind.h])
1648 AC_CHECK_HEADERS([fenv.h])
1649 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1650 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1651   AC_CHECK_HEADERS(pthread.h,
1652                    AC_SUBST(HAVE_PTHREAD, 1),
1653                    AC_SUBST(HAVE_PTHREAD, 0))
1654 else
1655   AC_SUBST(HAVE_PTHREAD, 0)
1656 fi
1657 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1658   AC_CHECK_HEADERS(zlib.h,
1659                    AC_SUBST(HAVE_LIBZ, 1),
1660                    AC_SUBST(HAVE_LIBZ, 0))
1661 else
1662   AC_SUBST(HAVE_LIBZ, 0)
1663 fi
1664
1665 dnl Try to find ffi.h.
1666 if test "$llvm_cv_enable_libffi" = "yes" ; then
1667   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1668 fi
1669
1670 dnl Try to find Darwin specific crash reporting libraries.
1671 AC_CHECK_HEADERS([CrashReporterClient.h])
1672
1673 dnl Try to find Darwin specific crash reporting global.
1674 AC_MSG_CHECKING([__crashreporter_info__])
1675 AC_LINK_IFELSE(
1676 [
1677   AC_LANG_SOURCE([[
1678     extern const char *__crashreporter_info__;
1679     int main() {
1680       __crashreporter_info__ = "test";
1681       return 0;
1682     }
1683   ]])
1684 ],
1685 [
1686   AC_MSG_RESULT([yes])
1687   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1688 ],
1689 [
1690   AC_MSG_RESULT([no])
1691   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1692 ])
1693
1694 dnl===-----------------------------------------------------------------------===
1695 dnl===
1696 dnl=== SECTION 7: Check for types and structures
1697 dnl===
1698 dnl===-----------------------------------------------------------------------===
1699
1700 AC_HUGE_VAL_CHECK
1701 AC_TYPE_PID_T
1702 AC_TYPE_SIZE_T
1703 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1704 AC_STRUCT_TM
1705 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1706 AC_CHECK_TYPES([uint64_t],,
1707          AC_CHECK_TYPES([u_int64_t],,
1708          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1709
1710 dnl===-----------------------------------------------------------------------===
1711 dnl===
1712 dnl=== SECTION 8: Check for specific functions needed
1713 dnl===
1714 dnl===-----------------------------------------------------------------------===
1715
1716 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1717 AC_CHECK_FUNCS([powf fmodf strtof round ])
1718 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1719 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1720 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1721 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1722 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1723 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1724 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1725 AC_CHECK_FUNCS([futimes futimens])
1726 AC_C_PRINTF_A
1727 AC_FUNC_RAND48
1728
1729 dnl Check for arc4random accessible via AC_INCLUDES_DEFAULT.
1730 AC_CHECK_DECLS([arc4random])
1731
1732 dnl Check the declaration "Secure API" on Windows environments.
1733 AC_CHECK_DECLS([strerror_s])
1734
1735 dnl Check symbols in libgcc.a for JIT on Mingw.
1736 if test "$llvm_cv_os_type" = "MingW" ; then
1737   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1738   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1739   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1740   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1741
1742   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1743   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1744   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1745   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1746   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1747   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1748   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1749   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1750   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1751   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1752
1753   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1754   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1755 fi
1756
1757 dnl Check Win32 API EnumerateLoadedModules.
1758 if test "$llvm_cv_os_type" = "MingW" ; then
1759   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1760   AC_COMPILE_IFELSE(
1761 [
1762   AC_LANG_SOURCE([[
1763     #include <windows.h>
1764     #include <imagehlp.h>
1765     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1766     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1767   ]])
1768 ],
1769 [
1770   AC_MSG_RESULT([yes])
1771   llvm_cv_win32_elmcb_pcstr="PCSTR"
1772 ],
1773 [
1774   AC_MSG_RESULT([no])
1775   llvm_cv_win32_elmcb_pcstr="PSTR"
1776 ])
1777   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1778 fi
1779
1780 dnl Check for variations in the Standard C++ library and STL. These macros are
1781 dnl provided by LLVM in the autoconf/m4 directory.
1782 AC_FUNC_ISNAN
1783 AC_FUNC_ISINF
1784
1785 dnl Check for mmap support.We also need to know if /dev/zero is required to
1786 dnl be opened for allocating RWX memory.
1787 dnl Make sure we aren't attempting to configure for an unknown system
1788 if test "$llvm_cv_platform_type" = "Unix" ; then
1789   AC_FUNC_MMAP
1790   AC_FUNC_MMAP_FILE
1791   AC_NEED_DEV_ZERO_FOR_MMAP
1792
1793   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1794   then
1795     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1796   fi
1797   if test "$ac_cv_func_mmap_file" = "no"
1798   then
1799     AC_MSG_WARN([mmap() of files required but not found])
1800   fi
1801 fi
1802
1803 dnl atomic builtins are required for threading support.
1804 AC_MSG_CHECKING(for GCC atomic builtins)
1805 dnl Since we'll be using these atomic builtins in C++ files we should test
1806 dnl the C++ compiler.
1807 AC_LANG_PUSH([C++])
1808 AC_LINK_IFELSE(
1809 [
1810   AC_LANG_SOURCE([[
1811     int main() {
1812       volatile unsigned long val = 1;
1813       __sync_synchronize();
1814       __sync_val_compare_and_swap(&val, 1, 0);
1815       __sync_add_and_fetch(&val, 1);
1816       __sync_sub_and_fetch(&val, 1);
1817       return 0;
1818     }
1819   ]])
1820 ],
1821 [
1822   AC_MSG_RESULT([yes])
1823   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1824 ],
1825 [
1826   AC_MSG_RESULT([no])
1827   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1828   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1829 ])
1830 AC_LANG_POP([C++])
1831
1832 dnl===-----------------------------------------------------------------------===
1833 dnl===
1834 dnl=== SECTION 9: Additional checks, variables, etc.
1835 dnl===
1836 dnl===-----------------------------------------------------------------------===
1837
1838 dnl Handle 32-bit linux systems running a 64-bit kernel.
1839 dnl This has to come after section 4 because it invokes the compiler.
1840 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1841   AC_IS_LINUX_MIXED
1842   if test "$llvm_cv_linux_mixed" = "yes"; then
1843     llvm_cv_target_arch="x86"
1844     ARCH="x86"
1845   fi
1846 fi
1847
1848 dnl Check whether __dso_handle is present
1849 AC_CHECK_FUNCS([__dso_handle])
1850
1851 dnl Propagate the shared library extension that the libltdl checks did to
1852 dnl the Makefiles so we can use it there too
1853 AC_SUBST(SHLIBEXT,$llvm_shlib_ext)
1854
1855 dnl Translate the various configuration directories and other basic
1856 dnl information into substitutions that will end up in Makefile.config.in
1857 dnl that these configured values can be used by the makefiles
1858 if test "${prefix}" = "NONE" ; then
1859   prefix="/usr/local"
1860 fi
1861 eval LLVM_PREFIX="${prefix}";
1862 eval LLVM_BINDIR="${prefix}/bin";
1863 eval LLVM_DATADIR="${prefix}/share/llvm";
1864 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1865 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1866 eval LLVM_INCLUDEDIR="${prefix}/include";
1867 eval LLVM_INFODIR="${prefix}/info";
1868 eval LLVM_MANDIR="${prefix}/man";
1869 LLVM_CONFIGTIME=`date`
1870 AC_SUBST(LLVM_PREFIX)
1871 AC_SUBST(LLVM_BINDIR)
1872 AC_SUBST(LLVM_DATADIR)
1873 AC_SUBST(LLVM_DOCSDIR)
1874 AC_SUBST(LLVM_ETCDIR)
1875 AC_SUBST(LLVM_INCLUDEDIR)
1876 AC_SUBST(LLVM_INFODIR)
1877 AC_SUBST(LLVM_MANDIR)
1878 AC_SUBST(LLVM_CONFIGTIME)
1879
1880 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1881 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1882   LLVM_CONFIGTIME="(timestamp not enabled)"
1883 fi
1884
1885 dnl Place the various directories into the config.h file as #defines so that we
1886 dnl can know about the installation paths within LLVM.
1887 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1888                    [Installation prefix directory])
1889 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1890                    [Installation directory for binary executables])
1891 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1892                    [Installation directory for data files])
1893 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1894                    [Installation directory for documentation])
1895 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1896                    [Installation directory for config files])
1897 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1898                    [Installation directory for include files])
1899 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1900                    [Installation directory for .info files])
1901 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1902                    [Installation directory for man pages])
1903 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1904                    [Time at which LLVM was configured])
1905 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
1906                    [Host triple LLVM will be executed on])
1907 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1908                    [Target triple LLVM will generate code for by default])
1909
1910 dnl Determine which bindings to build.
1911 if test "$BINDINGS_TO_BUILD" = auto ; then
1912   BINDINGS_TO_BUILD=""
1913   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1914     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1915   fi
1916 fi
1917 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1918
1919 dnl This isn't really configurey, but it avoids having to repeat the list in
1920 dnl other files.
1921 AC_SUBST(ALL_BINDINGS,ocaml)
1922
1923 dnl Do any work necessary to ensure that bindings have what they need.
1924 binding_prereqs_failed=0
1925 for a_binding in $BINDINGS_TO_BUILD ; do
1926   case "$a_binding" in
1927   ocaml)
1928     if test "x$OCAMLC" = x ; then
1929       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1930       binding_prereqs_failed=1
1931     fi
1932     if test "x$OCAMLDEP" = x ; then
1933       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1934       binding_prereqs_failed=1
1935     fi
1936     if test "x$OCAMLOPT" = x ; then
1937       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1938       dnl ocamlopt is optional!
1939     fi
1940     if test "x$with_ocaml_libdir" != xauto ; then
1941       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1942     else
1943       ocaml_stdlib="`"$OCAMLC" -where`"
1944       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1945       then
1946         # ocaml stdlib is beneath our prefix; use stdlib
1947         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1948       else
1949         # ocaml stdlib is outside our prefix; use libdir/ocaml
1950         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
1951       fi
1952     fi
1953     ;;
1954   esac
1955 done
1956 if test "$binding_prereqs_failed" = 1 ; then
1957   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1958 fi
1959
1960 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1961 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1962
1963 dnl Determine linker rpath flag
1964 if test "$llvm_cv_link_use_r" = "yes" ; then
1965   RPATH="-Wl,-R"
1966 else
1967   RPATH="-Wl,-rpath"
1968 fi
1969 AC_SUBST(RPATH)
1970
1971 dnl Determine linker rdynamic flag
1972 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1973   RDYNAMIC="-rdynamic"
1974 else
1975   RDYNAMIC=""
1976 fi
1977 AC_SUBST(RDYNAMIC)
1978
1979 dnl===-----------------------------------------------------------------------===
1980 dnl===
1981 dnl=== SECTION 10: Specify the output files and generate it
1982 dnl===
1983 dnl===-----------------------------------------------------------------------===
1984
1985 dnl Configure header files
1986 dnl WARNING: dnl If you add or remove any of the following config headers, then
1987 dnl you MUST also update Makefile so that the variable FilesToConfig
1988 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1989 dnl files can be updated automatically when their *.in sources change.
1990 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1991 AH_TOP([#ifndef CONFIG_H
1992 #define CONFIG_H])
1993 AH_BOTTOM([#endif])
1994
1995 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1996 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1997 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1998 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1999 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
2000
2001 dnl Configure the makefile's configuration data
2002 AC_CONFIG_FILES([Makefile.config])
2003
2004 dnl Configure the RPM spec file for LLVM
2005 AC_CONFIG_FILES([llvm.spec])
2006
2007 dnl Configure doxygen's configuration file
2008 AC_CONFIG_FILES([docs/doxygen.cfg])
2009
2010 dnl Configure clang, if present
2011 if test "${clang_src_root}" = ""; then
2012   clang_src_root="$srcdir/tools/clang"
2013 fi
2014 if test -f ${clang_src_root}/README.txt; then
2015   dnl Use variables to stay under 80 columns.
2016   configh="include/clang/Config/config.h"
2017   doxy="docs/doxygen.cfg"
2018   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
2019   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
2020 fi
2021
2022 dnl OCaml findlib META file
2023 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
2024
2025 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
2026 test "x$program_prefix" = "xNONE" && program_prefix=""
2027 AC_SUBST([program_prefix])
2028
2029
2030 dnl Do special configuration of Makefiles
2031 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2032 AC_CONFIG_MAKEFILE(Makefile)
2033 AC_CONFIG_MAKEFILE(Makefile.common)
2034 AC_CONFIG_MAKEFILE(examples/Makefile)
2035 AC_CONFIG_MAKEFILE(lib/Makefile)
2036 AC_CONFIG_MAKEFILE(test/Makefile)
2037 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2038 AC_CONFIG_MAKEFILE(unittests/Makefile)
2039 AC_CONFIG_MAKEFILE(tools/Makefile)
2040 AC_CONFIG_MAKEFILE(utils/Makefile)
2041 AC_CONFIG_MAKEFILE(projects/Makefile)
2042 AC_CONFIG_MAKEFILE(bindings/Makefile)
2043 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2044
2045 dnl Finally, crank out the output
2046 AC_OUTPUT