autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34
  35 AC_INIT([LLVM],[3.7.0svn],[http://llvm.org/bugs/])
  36
  37 LLVM_VERSION_MAJOR=3
  38 LLVM_VERSION_MINOR=7
  39 LLVM_VERSION_PATCH=0
  40 LLVM_VERSION_SUFFIX=svn
  41
  42 AC_DEFINE_UNQUOTED([LLVM_VERSION_MAJOR], $LLVM_VERSION_MAJOR, [Major version of the LLVM API])
  43 AC_DEFINE_UNQUOTED([LLVM_VERSION_MINOR], $LLVM_VERSION_MINOR, [Minor version of the LLVM API])
  44 AC_DEFINE_UNQUOTED([LLVM_VERSION_PATCH], $LLVM_VERSION_PATCH, [Patch version of the LLVM API])
  45 AC_DEFINE_UNQUOTED([LLVM_VERSION_STRING], "$PACKAGE_VERSION", [LLVM version string])
  46
  47 AC_SUBST([LLVM_VERSION_MAJOR])
  48 AC_SUBST([LLVM_VERSION_MINOR])
  49 AC_SUBST([LLVM_VERSION_PATCH])
  50 AC_SUBST([LLVM_VERSION_SUFFIX])
  51
  52 dnl Provide a copyright substitution and ensure the copyright notice is included
  53 dnl in the output of --version option of the generated configure script.
  54 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2015 University of Illinois at Urbana-Champaign."])
  55 AC_COPYRIGHT([Copyright (c) 2003-2015 University of Illinois at Urbana-Champaign.])
  56
  57 dnl Indicate that we require autoconf 2.60 or later.
  58 AC_PREREQ(2.60)
  59
  60 dnl Verify that the source directory is valid. This makes sure that we are
  61 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  62 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  63
  64 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  65 dnl various tools where the m4 autoconf macros are.
  66 AC_CONFIG_AUX_DIR([autoconf])
  67
  68 dnl Quit if the source directory has already been configured.
  69 dnl NOTE: This relies upon undocumented autoconf behavior.
  70 if test ${srcdir} != "." ; then
  71   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  72     AC_MSG_ERROR([Already configured in ${srcdir}])
  73   fi
  74 fi
  75
  76 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  77 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  78 : ${CFLAGS=}
  79 : ${CXXFLAGS=}
  80
  81 dnl We need to check for the compiler up here to avoid anything else
  82 dnl starting with a different one.
  83 AC_PROG_CC(clang gcc)
  84 AC_PROG_CXX(clang++ g++)
  85 AC_PROG_CPP
  86
  87 dnl If CXX is Clang, check that it can find and parse C++ standard library
  88 dnl headers.
  89 if test "$CXX" = "clang++" ; then
  90   AC_MSG_CHECKING([whether clang works])
  91   AC_LANG_PUSH([C++])
  92   dnl Note that space between 'include' and '(' is required.  There's a broken
  93   dnl regex in aclocal that otherwise will think that we call m4's include
  94   dnl builtin.
  95   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  96 #if __has_include (<cxxabi.h>)
  97 #include <cxxabi.h>
  98 #endif
  99 #if __has_include (<unwind.h>)
 100 #include <unwind.h>
 101 #endif
 102 ]])],
 103 [
 104   AC_MSG_RESULT([yes])
 105 ],
 106 [
 107   AC_MSG_RESULT([no])
 108   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
 109 ])
 110   AC_LANG_POP([C++])
 111 fi
 112
 113 dnl Set up variables that track whether the host compiler is GCC or Clang where
 114 dnl we can effectively sanity check them. We don't try to sanity check all the
 115 dnl other possible compilers.
 116 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
 117 AC_LANG_PUSH([C++])
 118 llvm_cv_cxx_compiler=unknown
 119 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
 120                                     #error
 121                                     #endif
 122                                     ]])],
 123                   llvm_cv_cxx_compiler=clang,
 124                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
 125                                                        #error
 126                                                        #endif
 127                                                        ]])],
 128                                      llvm_cv_cxx_compiler=gcc, [])])
 129 AC_LANG_POP([C++])
 130 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
 131
 132 dnl Configure all of the projects present in our source tree. While we could
 133 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 134 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 135 dnl Instead we match on the known projects.
 136
 137 dnl
 138 dnl One tricky part of doing this is that some projects depend upon other
 139 dnl projects.  For example, several projects rely upon the LLVM test suite.
 140 dnl We want to configure those projects first so that their object trees are
 141 dnl created before running the configure scripts of projects that depend upon
 142 dnl them.
 143 dnl
 144
 145 dnl Several projects use the LLVM test suite, so configure it next.
 146 if test -d ${srcdir}/projects/test-suite ; then
 147   AC_CONFIG_SUBDIRS([projects/test-suite])
 148 fi
 149
 150 dnl llvm-test is the old name of the test-suite, kept here for backwards
 151 dnl compatibility
 152 if test -d ${srcdir}/projects/llvm-test ; then
 153   AC_CONFIG_SUBDIRS([projects/llvm-test])
 154 fi
 155
 156 dnl Some projects use poolalloc; configure that next
 157 if test -d ${srcdir}/projects/poolalloc ; then
 158   AC_CONFIG_SUBDIRS([projects/poolalloc])
 159 fi
 160
 161 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 162   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 163 fi
 164
 165 dnl Check for all other projects
 166 for i in `ls ${srcdir}/projects`
 167 do
 168   if test -d ${srcdir}/projects/${i} ; then
 169     case ${i} in
 170       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 171       compiler-rt)       ;;
 172       test-suite)     ;;
 173       llvm-test)      ;;
 174       poolalloc)      ;;
 175       llvm-poolalloc) ;;
 176       *)
 177         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 178         ;;
 179     esac
 180   fi
 181 done
 182
 183 dnl Disable the build of polly, even if it is checked out into tools/polly.
 184 AC_ARG_ENABLE(polly,
 185               AS_HELP_STRING([--enable-polly],
 186                              [Use polly if available (default is YES)]),,
 187                              enableval=default)
 188 case "$enableval" in
 189   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 190   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 191   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 192   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 193 esac
 194
 195
 196 dnl Check if polly is checked out into tools/polly and configure it if
 197 dnl available.
 198 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 199   AC_SUBST(LLVM_HAS_POLLY,1)
 200   AC_CONFIG_SUBDIRS([tools/polly])
 201 fi
 202
 203 dnl===-----------------------------------------------------------------------===
 204 dnl===
 205 dnl=== SECTION 2: Architecture, target, and host checks
 206 dnl===
 207 dnl===-----------------------------------------------------------------------===
 208
 209 dnl Check the target for which we're compiling and the host that will do the
 210 dnl compilations. This will tell us which LLVM compiler will be used for
 211 dnl compiling SSA into object code. This needs to be done early because
 212 dnl following tests depend on it.
 213 AC_CANONICAL_TARGET
 214
 215 dnl Determine the platform type and cache its value. This helps us configure
 216 dnl the System library to the correct build platform.
 217 AC_CACHE_CHECK([type of operating system we're going to host on],
 218                [llvm_cv_os_type],
 219 [case $host in
 220   *-*-aix*)
 221     llvm_cv_link_all_option="-Wl,--whole-archive"
 222     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 223     llvm_cv_os_type="AIX"
 224     llvm_cv_platform_type="Unix" ;;
 225   *-*-irix*)
 226     llvm_cv_link_all_option="-Wl,--whole-archive"
 227     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 228     llvm_cv_os_type="IRIX"
 229     llvm_cv_platform_type="Unix" ;;
 230   *-*-cygwin*)
 231     llvm_cv_link_all_option="-Wl,--whole-archive"
 232     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 233     llvm_cv_os_type="Cygwin"
 234     llvm_cv_platform_type="Unix" ;;
 235   *-*-darwin*)
 236     llvm_cv_link_all_option="-Wl,-all_load"
 237     llvm_cv_no_link_all_option="-Wl,-noall_load"
 238     llvm_cv_os_type="Darwin"
 239     llvm_cv_platform_type="Unix" ;;
 240   *-*-minix*)
 241     llvm_cv_link_all_option="-Wl,-all_load"
 242     llvm_cv_no_link_all_option="-Wl,-noall_load"
 243     llvm_cv_os_type="Minix"
 244     llvm_cv_platform_type="Unix" ;;
 245   *-*-freebsd*)
 246     llvm_cv_link_all_option="-Wl,--whole-archive"
 247     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 248     llvm_cv_os_type="FreeBSD"
 249     llvm_cv_platform_type="Unix" ;;
 250   *-*-kfreebsd-gnu)
 251     llvm_cv_link_all_option="-Wl,--whole-archive"
 252     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 253     llvm_cv_os_type="GNU/kFreeBSD"
 254     llvm_cv_platform_type="Unix" ;;
 255   *-*-openbsd*)
 256     llvm_cv_link_all_option="-Wl,--whole-archive"
 257     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 258     llvm_cv_os_type="OpenBSD"
 259     llvm_cv_platform_type="Unix" ;;
 260   *-*-netbsd*)
 261     llvm_cv_link_all_option="-Wl,--whole-archive"
 262     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 263     llvm_cv_os_type="NetBSD"
 264     llvm_cv_platform_type="Unix" ;;
 265   *-*-dragonfly*)
 266     llvm_cv_link_all_option="-Wl,--whole-archive"
 267     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 268     llvm_cv_os_type="DragonFly"
 269     llvm_cv_platform_type="Unix" ;;
 270   *-*-bitrig*)
 271     llvm_cv_link_all_option="-Wl,--whole-archive"
 272     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 273     llvm_cv_os_type="Bitrig"
 274     llvm_cv_platform_type="Unix" ;;
 275   *-*-hpux*)
 276     llvm_cv_link_all_option="-Wl,--whole-archive"
 277     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 278     llvm_cv_os_type="HP-UX"
 279     llvm_cv_platform_type="Unix" ;;
 280   *-*-interix*)
 281     llvm_cv_link_all_option="-Wl,--whole-archive"
 282     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 283     llvm_cv_os_type="Interix"
 284     llvm_cv_platform_type="Unix" ;;
 285   *-*-linux*)
 286     llvm_cv_link_all_option="-Wl,--whole-archive"
 287     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 288     llvm_cv_os_type="Linux"
 289     llvm_cv_platform_type="Unix" ;;
 290   *-*-gnu*)
 291     llvm_cv_link_all_option="-Wl,--whole-archive"
 292     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 293     llvm_cv_os_type="GNU"
 294     llvm_cv_platform_type="Unix" ;;
 295   *-*-solaris*)
 296     llvm_cv_link_all_option="-Wl,-z,allextract"
 297     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 298     llvm_cv_os_type="SunOS"
 299     llvm_cv_platform_type="Unix" ;;
 300   *-*-win32*)
 301     llvm_cv_link_all_option="-Wl,--whole-archive"
 302     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 303     llvm_cv_os_type="Win32"
 304     llvm_cv_platform_type="Win32" ;;
 305   *-*-mingw*)
 306     llvm_cv_link_all_option="-Wl,--whole-archive"
 307     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 308     llvm_cv_os_type="MingW"
 309     llvm_cv_platform_type="Win32" ;;
 310   *-*-haiku*)
 311     llvm_cv_link_all_option="-Wl,--whole-archive"
 312     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 313     llvm_cv_os_type="Haiku"
 314     llvm_cv_platform_type="Unix" ;;
 315   *-unknown-eabi*)
 316     llvm_cv_link_all_option="-Wl,--whole-archive"
 317     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 318     llvm_cv_os_type="Freestanding"
 319     llvm_cv_platform_type="Unix" ;;
 320   *-unknown-elf*)
 321     llvm_cv_link_all_option="-Wl,--whole-archive"
 322     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 323     llvm_cv_os_type="Freestanding"
 324     llvm_cv_platform_type="Unix" ;;
 325   *)
 326     llvm_cv_link_all_option=""
 327     llvm_cv_no_link_all_option=""
 328     llvm_cv_os_type="Unknown"
 329     llvm_cv_platform_type="Unknown" ;;
 330 esac])
 331
 332 AC_CACHE_CHECK([type of operating system we're going to target],
 333                [llvm_cv_target_os_type],
 334 [case $target in
 335   *-*-aix*)
 336     llvm_cv_target_os_type="AIX" ;;
 337   *-*-irix*)
 338     llvm_cv_target_os_type="IRIX" ;;
 339   *-*-cygwin*)
 340     llvm_cv_target_os_type="Cygwin" ;;
 341   *-*-darwin*)
 342     llvm_cv_target_os_type="Darwin" ;;
 343   *-*-minix*)
 344     llvm_cv_target_os_type="Minix" ;;
 345   *-*-freebsd*)
 346     llvm_cv_target_os_type="FreeBSD" ;;
 347   *-*-kfreebsd-gnu)
 348     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 349   *-*-openbsd*)
 350     llvm_cv_target_os_type="OpenBSD" ;;
 351   *-*-netbsd*)
 352     llvm_cv_target_os_type="NetBSD" ;;
 353   *-*-dragonfly*)
 354     llvm_cv_target_os_type="DragonFly" ;;
 355   *-*-bitrig*)
 356     llvm_cv_target_os_type="Bitrig" ;;
 357   *-*-hpux*)
 358     llvm_cv_target_os_type="HP-UX" ;;
 359   *-*-interix*)
 360     llvm_cv_target_os_type="Interix" ;;
 361   *-*-linux*)
 362     llvm_cv_target_os_type="Linux" ;;
 363   *-*-gnu*)
 364     llvm_cv_target_os_type="GNU" ;;
 365   *-*-solaris*)
 366     llvm_cv_target_os_type="SunOS" ;;
 367   *-*-win32*)
 368     llvm_cv_target_os_type="Win32" ;;
 369   *-*-mingw*)
 370     llvm_cv_target_os_type="MingW" ;;
 371   *-*-haiku*)
 372     llvm_cv_target_os_type="Haiku" ;;
 373   *-*-rtems*)
 374     llvm_cv_target_os_type="RTEMS" ;;
 375   *-*-nacl*)
 376     llvm_cv_target_os_type="NativeClient" ;;
 377   *-unknown-eabi*)
 378     llvm_cv_target_os_type="Freestanding" ;;
 379   *-*-ps4)
 380     llvm_cv_target_os_type="PS4" ;;
 381   *)
 382     llvm_cv_target_os_type="Unknown" ;;
 383 esac])
 384
 385 dnl Make sure we aren't attempting to configure for an unknown system
 386 if test "$llvm_cv_os_type" = "Unknown" ; then
 387   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 388 fi
 389
 390 dnl Set the "OS" Makefile variable based on the platform type so the
 391 dnl makefile can configure itself to specific build hosts
 392 AC_SUBST(OS,$llvm_cv_os_type)
 393 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 394 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 395
 396 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 397 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 398 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 399
 400 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 401 dnl This is used by lib/Support to determine the basic kind of implementation
 402 dnl to use.
 403 case $llvm_cv_platform_type in
 404   Unix)
 405     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 406     AC_SUBST(LLVM_ON_UNIX,[1])
 407     AC_SUBST(LLVM_ON_WIN32,[0])
 408     ;;
 409   Win32)
 410     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 411     AC_SUBST(LLVM_ON_UNIX,[0])
 412     AC_SUBST(LLVM_ON_WIN32,[1])
 413     ;;
 414 esac
 415
 416 dnl Determine what our target architecture is and configure accordingly.
 417 dnl This will allow Makefiles to make a distinction between the hardware and
 418 dnl the OS.
 419 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 420 [case $target in
 421   i?86-*)                 llvm_cv_target_arch="x86" ;;
 422   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 423   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 424   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 425   arm64*-*)               llvm_cv_target_arch="AArch64" ;;
 426   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 427   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 428   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 429   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 430   xcore-*)                llvm_cv_target_arch="XCore" ;;
 431   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 432   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 433   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 434   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 435   *)                      llvm_cv_target_arch="Unknown" ;;
 436 esac])
 437
 438 if test "$llvm_cv_target_arch" = "Unknown" ; then
 439   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 440 fi
 441
 442 dnl Determine the LLVM native architecture for the target
 443 case "$llvm_cv_target_arch" in
 444     x86)     LLVM_NATIVE_ARCH="X86" ;;
 445     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 446     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 447 esac
 448
 449 dnl Define a substitution, ARCH, for the target architecture
 450 AC_SUBST(ARCH,$llvm_cv_target_arch)
 451 AC_SUBST(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCH)
 452
 453 dnl Determine what our host architecture.
 454 dnl This will allow MCJIT regress tests runs only for supported
 455 dnl platforms.
 456 case $host in
 457   i?86-*)                 host_arch="x86" ;;
 458   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 459   sparc*-*)               host_arch="Sparc" ;;
 460   powerpc*-*)             host_arch="PowerPC" ;;
 461   arm64*-*)               host_arch="AArch64" ;;
 462   arm*-*)                 host_arch="ARM" ;;
 463   aarch64*-*)             host_arch="AArch64" ;;
 464   mips-* | mips64-*)      host_arch="Mips" ;;
 465   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 466   xcore-*)                host_arch="XCore" ;;
 467   msp430-*)               host_arch="MSP430" ;;
 468   hexagon-*)              host_arch="Hexagon" ;;
 469   s390x-*)                host_arch="SystemZ" ;;
 470   *)                      host_arch="Unknown" ;;
 471 esac
 472
 473 if test "$host_arch" = "Unknown" ; then
 474   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 475 fi
 476
 477 AC_SUBST(HOST_ARCH,$host_arch)
 478
 479 dnl Check for build platform executable suffix if we're cross-compiling
 480 if test "$cross_compiling" = yes; then
 481   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 482   AC_BUILD_EXEEXT
 483   ac_build_prefix=${build_alias}-
 484   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 485   if test -z "$BUILD_CXX"; then
 486      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 487      if test -z "$BUILD_CXX"; then
 488        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 489      fi
 490   fi
 491 else
 492   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 493 fi
 494
 495 dnl Check to see if there's a .svn or .git directory indicating that this
 496 dnl build is being done from a checkout. This sets up several defaults for
 497 dnl the command line switches. When we build with a checkout directory,
 498 dnl we get a debug with assertions turned on. Without, we assume a source
 499 dnl release and we get an optimized build without assertions.
 500 dnl See --enable-optimized and --enable-assertions below
 501 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 502   cvsbuild="yes"
 503   optimize="no"
 504   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 505 else
 506   cvsbuild="no"
 507   optimize="yes"
 508 fi
 509
 510 dnl===-----------------------------------------------------------------------===
 511 dnl===
 512 dnl=== SECTION 3: Command line arguments for the configure script.
 513 dnl===
 514 dnl===-----------------------------------------------------------------------===
 515
 516 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 517 AC_ARG_ENABLE(libcpp,
 518               AS_HELP_STRING([--enable-libcpp],
 519                              [Use libc++ if available (default is NO)]),,
 520                              enableval=default)
 521 case "$enableval" in
 522   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 523   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 524   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 525   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 526 esac
 527
 528 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
 529 dnl be bypassed by passing a flag if necessary on a platform. We have to do
 530 dnl these checks here so that we have the configuration of the standard C++
 531 dnl library finished.
 532 AC_ARG_ENABLE(compiler-version-checks,
 533               AS_HELP_STRING([--enable-compiler-version-checks],
 534                              [Check the version of the host compiler (default is YES)]),,
 535                              enableval=default)
 536 case "$enableval" in
 537   no)
 538     ;;
 539   yes|default)
 540     AC_LANG_PUSH([C++])
 541     case "$llvm_cv_cxx_compiler" in
 542     clang)
 543       AC_MSG_CHECKING([whether Clang is new enough])
 544       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 545 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
 546 #error This version of Clang is too old to build LLVM
 547 #endif
 548 ]])],
 549           [AC_MSG_RESULT([yes])],
 550           [AC_MSG_RESULT([no])
 551            AC_MSG_ERROR([
 552 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
 553 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
 554 bypass these sanity checks.])])
 555
 556       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
 557       dnl are sometimes deeply confusing though. Here we test for an obvious
 558       dnl incomplete feature in 4.6's standard library that was completed in
 559       dnl 4.7's. We also have to disable this test if 'ENABLE_LIBCPP' is set
 560       dnl because the enable flags don't actually fix CXXFLAGS, they rely on
 561       dnl that happening in the Makefile.
 562       if test "$ENABLE_LIBCPP" -eq 0 ; then
 563         AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
 564         llvm_cv_old_cxxflags="$CXXFLAGS"
 565         CXXFLAGS="$CXXFLAGS -std=c++0x"
 566         AC_LINK_IFELSE([AC_LANG_SOURCE([[
 567 #include <atomic>
 568 std::atomic<float> x(0.0f);
 569 int main() { return (float)x; }
 570 ]])],
 571             [AC_MSG_RESULT([yes])],
 572             [AC_MSG_RESULT([no])
 573              AC_MSG_ERROR([
 574 We detected a missing feature in the standard C++ library that was known to be
 575 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
 576 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
 577 than 4.7. You will need to update your system and ensure Clang uses the newer
 578 standard library.
 579
 580 If this error is incorrect or you need to force things to work, you may pass
 581 '--disable-compiler-version-checks' to configure to bypass this test.])])
 582         CXXFLAGS="$llvm_cv_old_cxxflags"
 583       fi
 584       ;;
 585     gcc)
 586       AC_MSG_CHECKING([whether GCC is new enough])
 587       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 588 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 589 #error This version of GCC is too old to build LLVM
 590 #endif
 591 ]])],
 592           [AC_MSG_RESULT([yes])],
 593           [AC_MSG_RESULT([no])
 594            AC_MSG_ERROR([
 595 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
 596 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
 597 bypass these sanity checks.])])
 598       ;;
 599     unknown)
 600       ;;
 601     esac
 602     AC_LANG_POP([C++])
 603     ;;
 604   *)
 605     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
 606     ;;
 607 esac
 608
 609 dnl --enable-cxx1y : check whether or not to use -std=c++1y on the command line
 610 AC_ARG_ENABLE(cxx1y,
 611               AS_HELP_STRING([--enable-cxx1y],
 612                              [Use c++1y if available (default is NO)]),,
 613                              enableval=default)
 614 case "$enableval" in
 615   yes) AC_SUBST(ENABLE_CXX1Y,[1]) ;;
 616   no)  AC_SUBST(ENABLE_CXX1Y,[0]) ;;
 617   default) AC_SUBST(ENABLE_CXX1Y,[0]);;
 618   *) AC_MSG_ERROR([Invalid setting for --enable-cxx1y. Use "yes" or "no"]) ;;
 619 esac
 620
 621 dnl --enable-split-dwarf : check whether or not to use -gsplit-dwarf on the command
 622 dnl line
 623 AC_ARG_ENABLE(split-dwarf,
 624               AS_HELP_STRING([--enable-split-dwarf],
 625                              [Use split-dwarf if available (default is NO)]),,
 626                              enableval=default)
 627 case "$enableval" in
 628   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 629   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 630   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 631   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 632 esac
 633
 634 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 635 clang_arcmt="yes"
 636 AC_ARG_ENABLE(clang-arcmt,
 637               AS_HELP_STRING([--enable-clang-arcmt],
 638                              [Enable building of clang ARCMT (default is YES)]),
 639                              clang_arcmt="$enableval",
 640                              enableval="yes")
 641 case "$enableval" in
 642   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 643   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 644   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 645   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 646 esac
 647
 648 dnl --enable-clang-plugin-support: check whether to enable plugins in clang
 649 clang_plugin_support="yes"
 650 AC_ARG_ENABLE(clang-plugin-support,
 651               AS_HELP_STRING([--enable-clang-plugin-support],
 652                              [Enable plugin support in clang (default is YES)]),
 653                              clang_plugin_support="$enableval",
 654                              enableval="yes")
 655 case "$enableval" in
 656   yes) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]) ;;
 657   no)  AC_SUBST(CLANG_PLUGIN_SUPPORT,[0]) ;;
 658   default) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]);;
 659   *) AC_MSG_ERROR([Invalid setting for --enable-clang-plugin-support. Use "yes" or "no"]) ;;
 660 esac
 661
 662 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 663 clang_static_analyzer="yes"
 664 AC_ARG_ENABLE(clang-static-analyzer,
 665               AS_HELP_STRING([--enable-clang-static-analyzer],
 666                              [Enable building of clang Static Analyzer (default is YES)]),
 667                              clang_static_analyzer="$enableval",
 668                              enableval="yes")
 669 case "$enableval" in
 670   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 671   no)
 672     if test ${clang_arcmt} != "no" ; then
 673       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 674     fi
 675     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 676     ;;
 677   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 678   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 679 esac
 680
 681 dnl --enable-optimized : check whether they want to do an optimized build:
 682 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 683  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 684 if test ${enableval} = "no" ; then
 685   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 686 else
 687   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 688 fi
 689
 690 dnl --enable-profiling : check whether they want to do a profile build:
 691 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 692  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 693 if test ${enableval} = "no" ; then
 694   AC_SUBST(ENABLE_PROFILING,[[]])
 695 else
 696   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 697 fi
 698
 699 dnl --enable-assertions : check whether they want to turn on assertions or not:
 700 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 701   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 702 if test ${enableval} = "yes" ; then
 703   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 704   assertions_enabled="yes"
 705 else
 706   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 707   assertions_enabled="no"
 708 fi
 709
 710 dnl --enable-werror : check whether we want Werror on by default
 711 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 712   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 713 case "$enableval" in
 714   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 715   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 716   default) AC_SUBST(ENABLE_WERROR,[0]);;
 717   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 718 esac
 719
 720 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 721 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 722   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 723 if test ${enableval} = "yes" ; then
 724   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 725   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 726 else
 727   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 728   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 729 fi
 730
 731 dnl --enable-abi-breaking-checks : decide whether we should compile in asserts and
 732 dnl checks that make the build ABI incompatible with an llvm built without these
 733 dnl checks enabled.
 734 AC_ARG_ENABLE(abi-breaking-checks,AS_HELP_STRING(
 735   --enable-abi-breaking-checks,[Compile with abi-breaking asserts support (default is with-asserts)]),, enableval="with-asserts")
 736 case "$enableval" in
 737   with-asserts)  if test ${assertions_enabled} = "yes" ; then
 738                    AC_DEFINE([LLVM_ENABLE_ABI_BREAKING_CHECKS],[1],[Define to enable checks that alter the LLVM C++ ABI])
 739                  fi ;;
 740   yes) AC_DEFINE([LLVM_ENABLE_ABI_BREAKING_CHECKS],[1],[Define to enable checks that alter the LLVM C++ ABI]) ;;
 741   no) ;;
 742   *) AC_MSG_ERROR([Invalid setting for --enable-abi-breaking-checks.  Use "with-asserts", "yes" or "no"])
 743 esac
 744
 745 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 746 AC_ARG_ENABLE(debug-runtime,
 747    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 748 if test ${enableval} = "no" ; then
 749   AC_SUBST(DEBUG_RUNTIME,[[]])
 750 else
 751   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 752 fi
 753
 754 dnl --enable-debug-symbols : should even optimized compiler libraries
 755 dnl have debug symbols?
 756 AC_ARG_ENABLE(debug-symbols,
 757    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 758 if test ${enableval} = "no" ; then
 759   AC_SUBST(DEBUG_SYMBOLS,[[]])
 760 else
 761   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 762 fi
 763
 764 dnl --enable-keep-symbols : do not strip installed executables
 765 AC_ARG_ENABLE(keep-symbols,
 766    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 767 if test ${enableval} = "no" ; then
 768   AC_SUBST(KEEP_SYMBOLS,[[]])
 769 else
 770   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 771 fi
 772
 773 dnl --enable-jit: check whether they want to enable the jit
 774 AC_ARG_ENABLE(jit,
 775   AS_HELP_STRING(--enable-jit,
 776                  [Enable Just In Time Compiling (default is YES)]),,
 777   enableval=default)
 778 if test ${enableval} = "no"
 779 then
 780   AC_SUBST(JIT,[[]])
 781 else
 782   case "$llvm_cv_target_arch" in
 783     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 784     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 785     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 786     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 787     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 788     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 789     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 790     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 791     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 792     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 793     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 794     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 795   esac
 796 fi
 797
 798 TARGETS_WITH_JIT="ARM AArch64 Mips PowerPC SystemZ X86"
 799 AC_SUBST(TARGETS_WITH_JIT,$TARGETS_WITH_JIT)
 800
 801 dnl Allow enablement of building and installing docs
 802 AC_ARG_ENABLE(docs,
 803               AS_HELP_STRING([--enable-docs],
 804                              [Build documents (default is YES)]),,
 805                              enableval=default)
 806 case "$enableval" in
 807   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 808   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 809   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 810   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 811 esac
 812
 813 dnl Allow enablement of doxygen generated documentation
 814 AC_ARG_ENABLE(doxygen,
 815               AS_HELP_STRING([--enable-doxygen],
 816                              [Build doxygen documentation (default is NO)]),,
 817                              enableval=default)
 818 case "$enableval" in
 819   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 820   no|default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 821   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 822 esac
 823
 824 dnl Allow enablement of doxygen search engine
 825 AC_ARG_ENABLE(doxygen-search,
 826               AS_HELP_STRING([--enable-doxygen-search],
 827                              [Enable doxygen search support (default is NO)]),,
 828                              enableval=default)
 829 ENABLE_DOXYGEN_SEARCH="$enableval"
 830
 831 case "$enableval" in
 832   yes|no|default) ;;
 833   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen-search. Use "yes" or "no"]) ;;
 834 esac
 835
 836 AC_ARG_ENABLE(doxygen-external-search,
 837               AS_HELP_STRING([--enable-doxygen-external-search],
 838                              [Enable doxygen exteranl search (default is NO)]),,
 839                              enableval=default)
 840 ENABLE_DOXYGEN_EXTERNAL_SEARCH="$enableval"
 841
 842 case "$enableval" in
 843   yes)
 844     dnl To match with the CMake behavior, enable doxygen when
 845     dnl --enable-doxygen-external-search is enabled.
 846     case "$ENABLE_DOXYGEN_SEARCH" in
 847       yes|default) ENABLE_DOXYGEN_SEARCH="yes" ;;
 848       no) AC_MSG_ERROR([The option --enable-doxygen-external-search requires --enable-doxygen-search]) ;;
 849     esac
 850     ;;
 851   no|default) ;;
 852   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen-external-search. Use "yes" or "no"]) ;;
 853 esac
 854
 855 AC_ARG_WITH(doxygen-search-engine-url,
 856             AS_HELP_STRING([--with-doxygen-search-engine-url],
 857                            [Specify the external search engine for doxygen]),,)
 858 WITH_DOXYGEN_SEARCH_ENGINE_URL="$withval"
 859
 860 AC_ARG_WITH(doxygen-search-mappings,
 861             AS_HELP_STRING([--with-doxygen-search-mappings],
 862                            [Specify the extra search mapping for doxygen]),,)
 863 WITH_DOXYGEN_SEARCH_MAPPINGS="$withval"
 864
 865 case "$ENABLE_DOXYGEN_SEARCH" in
 866   yes)
 867     if test "$ENABLE_DOXYGEN" = "0" ; then
 868       AC_MSG_ERROR([The option --enable-doxygen-search requires --enable-doxygen.])
 869     fi
 870
 871     AC_SUBST(enable_searchengine,[YES])
 872
 873     case "$ENABLE_DOXYGEN_EXTERNAL_SEARCH" in
 874       yes)
 875         AC_SUBST(enable_external_search,[YES])
 876         AC_SUBST(enable_server_based_search,[YES])
 877         AC_SUBST(searchengine_url,["$WITH_DOXYGEN_SEARCH_ENGINE_URL"])
 878         AC_SUBST(extra_search_mappings,["$WITH_DOXYGEN_SEARCH_MAPPINGS"])
 879         ;;
 880
 881       no|default)
 882         AC_SUBST(enable_external_search,[NO])
 883         AC_SUBST(enable_server_based_search,[NO])
 884         AC_SUBST(searchengine_url,[])
 885         AC_SUBST(extra_search_mappings,[])
 886         ;;
 887     esac
 888     ;;
 889
 890   no|default)
 891     AC_SUBST(enable_searchengine,[NO])
 892     AC_SUBST(searchengine_url,[])
 893     AC_SUBST(enable_server_based_search,[NO])
 894     AC_SUBST(enable_external_search,[NO])
 895     AC_SUBST(extra_search_mappings,[])
 896     ;;
 897
 898   *)
 899     AC_MSG_ERROR([Invalid setting for --enable-doxygen-search. Use "yes" or "no"])
 900     ;;
 901 esac
 902
 903 dnl Allow enablement of doxygen generated Qt help files
 904 AC_ARG_ENABLE(doxygen-qt-help,
 905               AS_HELP_STRING([--enable-doxygen-qt-help],
 906                              [Build Qt help files (default is NO)]),,
 907                              enableval=default)
 908 case "$enableval" in
 909   yes)
 910     if test "$ENABLE_DOXYGEN" = "0" ; then
 911       AC_MSG_ERROR([The option --enable-doxygen-qt-help requires --enable-doxygen.])
 912     fi
 913
 914     AC_PATH_PROG(QHELPGENERATOR, [qhelpgenerator], [qhelpgenerator])
 915
 916     dnl Qt help file for llvm doxygen documentation
 917     AC_SUBST(llvm_doxygen_generate_qhp,[YES])
 918     AC_SUBST(llvm_doxygen_qch_filename,[org.llvm.qch])
 919     AC_SUBST(llvm_doxygen_qhp_namespace,[org.llvm])
 920     AC_SUBST(llvm_doxygen_qhelpgenerator_path,["$QHELPGENERATOR"])
 921     AC_SUBST(llvm_doxygen_qhp_cust_filter_name,["$PACKAGE_STRING"])
 922     AC_SUBST(llvm_doxygen_qhp_cust_filter_attrs,["$PACKAGE_NAME,$PACKAGE_VERSION"])
 923
 924     dnl Qt help file for clang doxygen documentation
 925     AC_SUBST(clang_doxygen_generate_qhp,[YES])
 926     AC_SUBST(clang_doxygen_qch_filename,[org.llvm.clang.qch])
 927     AC_SUBST(clang_doxygen_qhp_namespace,[org.llvm.clang])
 928     AC_SUBST(clang_doxygen_qhelpgenerator_path,["$QHELPGENERATOR"])
 929     AC_SUBST(clang_doxygen_qhp_cust_filter_name,["Clang $PACKAGE_VERSION"])
 930     AC_SUBST(clang_doxygen_qhp_cust_filter_attrs,["Clang,$PACKAGE_VERSION"])
 931     ;;
 932
 933   no|default)
 934     AC_SUBST(llvm_doxygen_generate_qhp,[NO])
 935     AC_SUBST(llvm_doxygen_qch_filename,[])
 936     AC_SUBST(llvm_doxygen_qhp_namespace,[])
 937     AC_SUBST(llvm_doxygen_qhelpgenerator_path,[])
 938     AC_SUBST(llvm_doxygen_qhp_cust_filter_name,[])
 939     AC_SUBST(llvm_doxygen_qhp_cust_filter_attrs,[])
 940
 941     AC_SUBST(clang_doxygen_generate_qhp,[NO])
 942     AC_SUBST(clang_doxygen_qch_filename,[])
 943     AC_SUBST(clang_doxygen_qhp_namespace,[])
 944     AC_SUBST(clang_doxygen_qhelpgenerator_path,[])
 945     AC_SUBST(clang_doxygen_qhp_cust_filter_name,["Clang $PACKAGE_VERSION"])
 946     AC_SUBST(clang_doxygen_qhp_cust_filter_attrs,["Clang,$PACKAGE_VERSION"])
 947     ;;
 948
 949   *)
 950     AC_MSG_ERROR([Invalid setting for --enable-doxygen-qt-help. Use "yes" or "no"]) ;;
 951 esac
 952
 953 dnl Allow disablement of threads
 954 AC_ARG_ENABLE(threads,
 955               AS_HELP_STRING([--enable-threads],
 956                              [Use threads if available (default is YES)]),,
 957                              enableval=default)
 958 case "$enableval" in
 959   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 960   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 961   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 962   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 963 esac
 964 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 965                    [Define if threads enabled])
 966
 967 dnl Allow disablement of pthread.h
 968 AC_ARG_ENABLE(pthreads,
 969               AS_HELP_STRING([--enable-pthreads],
 970                              [Use pthreads if available (default is YES)]),,
 971                              enableval=default)
 972 case "$enableval" in
 973   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 974   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 975   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 976   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 977 esac
 978
 979 dnl Allow disablement of zlib
 980 AC_ARG_ENABLE(zlib,
 981               AS_HELP_STRING([--enable-zlib],
 982                              [Use zlib for compression/decompression if
 983                               available (default is YES)]),,
 984                               enableval=default)
 985 case "$enableval" in
 986   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 987   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 988   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 989   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 990 esac
 991 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 992                    [Define if zlib is enabled])
 993
 994 dnl Allow building without position independent code
 995 AC_ARG_ENABLE(pic,
 996   AS_HELP_STRING([--enable-pic],
 997                  [Build LLVM with Position Independent Code (default is YES)]),,
 998                  enableval=default)
 999 case "$enableval" in
1000   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
1001   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
1002   default) AC_SUBST(ENABLE_PIC,[1]) ;;
1003   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
1004 esac
1005 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
1006                    [Define if position independent code is enabled])
1007
1008 dnl Allow building a shared library and linking tools against it.
1009 AC_ARG_ENABLE(shared,
1010   AS_HELP_STRING([--enable-shared],
1011                  [Build a shared library and link tools against it (default is NO)]),,
1012                  enableval=default)
1013 case "$enableval" in
1014   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
1015   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
1016   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
1017   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
1018 esac
1019
1020 dnl Allow libstdc++ is embedded in LLVM.dll.
1021 AC_ARG_ENABLE(embed-stdcxx,
1022   AS_HELP_STRING([--enable-embed-stdcxx],
1023                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
1024                  enableval=default)
1025 case "$enableval" in
1026   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
1027   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
1028   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
1029   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
1030 esac
1031
1032 dnl Enable embedding timestamp information into build.
1033 AC_ARG_ENABLE(timestamps,
1034   AS_HELP_STRING([--enable-timestamps],
1035                  [Enable embedding timestamp information in build (default is YES)]),,
1036                  enableval=default)
1037 case "$enableval" in
1038   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
1039   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
1040   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
1041   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
1042 esac
1043 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
1044                    [Define if timestamp information (e.g., __DATE__) is allowed])
1045
1046 dnl Enable support for showing backtraces.
1047 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
1048   [--enable-backtraces],
1049   [Enable embedding backtraces on crash (default is YES)]),
1050   [case "$enableval" in
1051     yes) llvm_cv_enable_backtraces="yes" ;;
1052     no)  llvm_cv_enable_backtraces="no"  ;;
1053     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
1054   esac],
1055   llvm_cv_enable_backtraces="yes")
1056 if test "$llvm_cv_enable_backtraces" = "yes" ; then
1057   AC_DEFINE([ENABLE_BACKTRACES],[1],
1058             [Define if you want backtraces on crash])
1059 fi
1060
1061 dnl Enable installing platform specific signal handling overrides, for improved
1062 dnl CrashRecovery support or interaction with crash reporting software. This
1063 dnl support may be inappropriate for some clients embedding LLVM as a library.
1064 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
1065   [--enable-crash-overrides],
1066   [Enable crash handling overrides (default is YES)]),
1067   [case "$enableval" in
1068     yes) llvm_cv_enable_crash_overrides="yes" ;;
1069     no)  llvm_cv_enable_crash_overrides="no"  ;;
1070     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
1071   esac],
1072   llvm_cv_enable_crash_overrides="yes")
1073 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
1074   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
1075             [Define to enable crash handling overrides])
1076 fi
1077
1078 dnl List all possible targets
1079 ALL_TARGETS="X86 Sparc PowerPC ARM AArch64 Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600"
1080 AC_SUBST(ALL_TARGETS,$ALL_TARGETS)
1081
1082 dnl Allow specific targets to be specified for building (or not)
1083 TARGETS_TO_BUILD=""
1084 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
1085     [Build specific host targets: all or target1,target2,... Valid targets are:
1086      host, x86, x86_64, sparc, powerpc, arm64, arm, aarch64, mips, hexagon,
1087      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
1088     enableval=all)
1089 if test "$enableval" = host-only ; then
1090   enableval=host
1091 fi
1092 case "$enableval" in
1093   all) TARGETS_TO_BUILD="$ALL_TARGETS" ;;
1094   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
1095       case "$a_target" in
1096         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1097         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1098         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
1099         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
1100         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1101         arm64)    TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1102         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
1103         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1104         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1105         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1106         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1107         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
1108         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
1109         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
1110         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
1111         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
1112         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
1113         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
1114         host) case "$llvm_cv_target_arch" in
1115             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1116             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1117             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
1118             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
1119             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1120             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
1121             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1122             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
1123             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
1124             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
1125             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
1126             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
1127             *)       AC_MSG_ERROR([Can not set target to build]) ;;
1128           esac ;;
1129         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
1130       esac
1131   done
1132   ;;
1133 esac
1134
1135 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
1136     [Build experimental host targets: disable or target1,target2,...
1137      (default=disable)]),,
1138     enableval=disable)
1139
1140 if test ${enableval} != "disable"
1141 then
1142   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
1143 fi
1144
1145 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
1146
1147 dnl Determine whether we are building LLVM support for the native architecture.
1148 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
1149 for a_target in $TARGETS_TO_BUILD; do
1150   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
1151     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
1152       [LLVM architecture name for the native architecture, if available])
1153     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
1154     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
1155     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
1156     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
1157     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1158       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
1159     fi
1160     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1161       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
1162     fi
1163     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
1164       [LLVM name for the native Target init function, if available])
1165     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
1166       [LLVM name for the native TargetInfo init function, if available])
1167     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
1168       [LLVM name for the native target MC init function, if available])
1169     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1170       [LLVM name for the native AsmPrinter init function, if available])
1171     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1172       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1173        [LLVM name for the native AsmParser init function, if available])
1174     fi
1175     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1176       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1177        [LLVM name for the native Disassembler init function, if available])
1178     fi
1179   fi
1180 done
1181
1182 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1183 dnl target feature def files.
1184 LLVM_ENUM_TARGETS=""
1185 LLVM_ENUM_ASM_PRINTERS=""
1186 LLVM_ENUM_ASM_PARSERS=""
1187 LLVM_ENUM_DISASSEMBLERS=""
1188 for target_to_build in $TARGETS_TO_BUILD; do
1189   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1190   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1191     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1192   fi
1193   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1194     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1195   fi
1196   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1197     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1198   fi
1199 done
1200 AC_SUBST(LLVM_ENUM_TARGETS)
1201 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1202 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1203 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1204
1205 dnl Override the option to use for optimized builds.
1206 AC_ARG_WITH(optimize-option,
1207   AS_HELP_STRING([--with-optimize-option],
1208                  [Select the compiler options to use for optimized builds]),,
1209                  withval=default)
1210 AC_MSG_CHECKING([optimization flags])
1211 case "$withval" in
1212   default)
1213     case "$llvm_cv_os_type" in
1214     FreeBSD) optimize_option=-O2 ;;
1215     MingW) optimize_option=-O2 ;;
1216     *)     optimize_option=-O3 ;;
1217     esac ;;
1218   *) optimize_option="$withval" ;;
1219 esac
1220 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1221 AC_MSG_RESULT([$optimize_option])
1222
1223 dnl Specify extra build options
1224 AC_ARG_WITH(extra-options,
1225   AS_HELP_STRING([--with-extra-options],
1226                  [Specify additional options to compile LLVM with]),,
1227                  withval=default)
1228 case "$withval" in
1229   default) EXTRA_OPTIONS= ;;
1230   *) EXTRA_OPTIONS=$withval ;;
1231 esac
1232 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1233
1234 dnl Specify extra linker build options
1235 AC_ARG_WITH(extra-ld-options,
1236   AS_HELP_STRING([--with-extra-ld-options],
1237                  [Specify additional options to link LLVM with]),,
1238                  withval=default)
1239 case "$withval" in
1240   default) EXTRA_LD_OPTIONS= ;;
1241   *) EXTRA_LD_OPTIONS=$withval ;;
1242 esac
1243 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1244
1245 dnl Allow specific bindings to be specified for building (or not)
1246 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1247     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1248     enableval=default)
1249 BINDINGS_TO_BUILD=""
1250 case "$enableval" in
1251   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1252   all ) BINDINGS_TO_BUILD="ocaml" ;;
1253   none | no) BINDINGS_TO_BUILD="" ;;
1254   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1255       case "$a_binding" in
1256         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1257         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1258       esac
1259   done
1260   ;;
1261 esac
1262
1263 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1264 dnl script for bindings/ocaml/configure, except that its auto value depends on
1265 dnl OCAMLC, which is found here to support tests.
1266 AC_ARG_WITH([ocaml-libdir],
1267   [AS_HELP_STRING([--with-ocaml-libdir],
1268     [Specify install location for ocaml bindings (default is stdlib)])],
1269   [],
1270   [withval=auto])
1271 case "$withval" in
1272   auto) with_ocaml_libdir="$withval" ;;
1273   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1274   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1275 esac
1276
1277 AC_ARG_WITH(clang-srcdir,
1278   AS_HELP_STRING([--with-clang-srcdir],
1279     [Directory to the out-of-tree Clang source]),,
1280     withval="-")
1281 case "$withval" in
1282   -) clang_src_root="" ;;
1283   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1284   *) clang_src_root="$ac_pwd/$withval" ;;
1285 esac
1286 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1287
1288 AC_ARG_WITH(clang-resource-dir,
1289   AS_HELP_STRING([--with-clang-resource-dir],
1290     [Relative directory from the Clang binary for resource files]),,
1291     withval="")
1292 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1293                    [Relative directory for resource files])
1294
1295 AC_ARG_WITH(c-include-dirs,
1296   AS_HELP_STRING([--with-c-include-dirs],
1297     [Colon separated list of directories clang will search for headers]),,
1298     withval="")
1299 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1300                    [Directories clang will search for headers])
1301
1302 # Clang normally uses the system c++ headers and libraries. With this option,
1303 # clang will use the ones provided by a gcc installation instead. This option should
1304 # be passed the same value that was used with --prefix when configuring gcc.
1305 AC_ARG_WITH(gcc-toolchain,
1306   AS_HELP_STRING([--with-gcc-toolchain],
1307     [Directory where gcc is installed.]),,
1308     withval="")
1309 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1310                    [Directory where gcc is installed.])
1311
1312 AC_ARG_WITH(default-sysroot,
1313   AS_HELP_STRING([--with-default-sysroot],
1314     [Add --sysroot=<path> to all compiler invocations.]),,
1315     withval="")
1316 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1317                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1318
1319 dnl Allow linking of LLVM with GPLv3 binutils code.
1320 AC_ARG_WITH(binutils-include,
1321   AS_HELP_STRING([--with-binutils-include],
1322     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1323   withval=default)
1324 case "$withval" in
1325   default) WITH_BINUTILS_INCDIR=default ;;
1326   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1327   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1328 esac
1329 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1330   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1331   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1332      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1333      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1334   fi
1335 fi
1336
1337 dnl Specify the URL where bug reports should be submitted.
1338 AC_ARG_WITH(bug-report-url,
1339   AS_HELP_STRING([--with-bug-report-url],
1340     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1341     withval="http://llvm.org/bugs/")
1342 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1343                    [Bug report URL.])
1344
1345 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1346 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1347   [--enable-terminfo],
1348   [Query the terminfo database if available (default is YES)]),
1349   [case "$enableval" in
1350     yes) llvm_cv_enable_terminfo="yes" ;;
1351     no)  llvm_cv_enable_terminfo="no"  ;;
1352     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1353   esac],
1354   llvm_cv_enable_terminfo="yes")
1355 case "$llvm_cv_enable_terminfo" in
1356   yes) AC_SUBST(ENABLE_TERMINFO,[1]) ;;
1357   no)  AC_SUBST(ENABLE_TERMINFO,[0]) ;;
1358 esac
1359
1360 dnl --enable-libedit: check whether the user wants to turn off libedit.
1361 AC_ARG_ENABLE(libedit,AS_HELP_STRING(
1362   [--enable-libedit],
1363   [Use libedit if available (default is YES)]),
1364   [case "$enableval" in
1365     yes) llvm_cv_enable_libedit="yes" ;;
1366     no)  llvm_cv_enable_libedit="no"  ;;
1367     *) AC_MSG_ERROR([Invalid setting for --enable-libedit. Use "yes" or "no"]) ;;
1368   esac],
1369   llvm_cv_enable_libedit="yes")
1370
1371 dnl --enable-libffi : check whether the user wants to turn off libffi:
1372 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1373   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1374   [case "$enableval" in
1375     yes) llvm_cv_enable_libffi="yes" ;;
1376     no)  llvm_cv_enable_libffi="no"  ;;
1377     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1378   esac],
1379   llvm_cv_enable_libffi=no)
1380
1381 AC_ARG_WITH(internal-prefix,
1382   AS_HELP_STRING([--with-internal-prefix],
1383     [Installation directory for internal files]),,
1384     withval="")
1385 AC_SUBST(INTERNAL_PREFIX,[$withval])
1386
1387 dnl===-----------------------------------------------------------------------===
1388 dnl===
1389 dnl=== SECTION 4: Check for programs we need and that they are the right version
1390 dnl===
1391 dnl===-----------------------------------------------------------------------===
1392
1393 dnl Check for the tools that the makefiles require
1394 AC_CHECK_GNU_MAKE
1395 AC_PROG_LN_S
1396 AC_PATH_PROG(NM, [nm], [nm])
1397 AC_PATH_PROG(CMP, [cmp], [cmp])
1398 AC_PATH_PROG(CP, [cp], [cp])
1399 AC_PATH_PROG(DATE, [date], [date])
1400 AC_PATH_PROG(FIND, [find], [find])
1401 AC_PATH_PROG(GREP, [grep], [grep])
1402 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1403 AC_PATH_PROG(MV,   [mv],   [mv])
1404 AC_PROG_RANLIB
1405 AC_CHECK_TOOL(AR, ar, false)
1406 AC_PATH_PROG(RM,   [rm],   [rm])
1407 AC_PATH_PROG(SED,  [sed],  [sed])
1408 AC_PATH_PROG(TAR,  [tar],  [gtar])
1409 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1410
1411 dnl Looking for misc. graph plotting software
1412 AC_PATH_PROG(DOT, [dot], [echo dot])
1413 if test "$DOT" != "echo dot" ; then
1414   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1415   dnl If we're targeting for mingw we should emit windows paths, not msys
1416   if test "$llvm_cv_os_type" = "MingW" ; then
1417     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1418   fi
1419   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1420    [Define to path to dot program if found or 'echo dot' otherwise])
1421 fi
1422
1423 dnl Find the install program
1424 AC_PROG_INSTALL
1425 dnl Prepend src dir to install path dir if it's a relative path
1426 dnl This is a hack for installs that take place in something other
1427 dnl than the top level.
1428 case "$INSTALL" in
1429  [[\\/$]]* | ?:[[\\/]]* ) ;;
1430  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1431 esac
1432
1433 dnl Checks for documentation and testing tools that we can do without. If these
1434 dnl are not found then they are set to "true" which always succeeds but does
1435 dnl nothing. This just lets the build output show that we could have done
1436 dnl something if the tool was available.
1437 AC_PATH_PROG(BZIP2, [bzip2])
1438 AC_PATH_PROG(CAT, [cat])
1439 AC_PATH_PROG(DOXYGEN, [doxygen])
1440 AC_PATH_PROG(GROFF, [groff])
1441 AC_PATH_PROG(GZIPBIN, [gzip])
1442 AC_PATH_PROG(PDFROFF, [pdfroff])
1443 AC_PATH_PROG(ZIP, [zip])
1444 AC_PATH_PROG(GO, [go])
1445 AC_PATH_PROGS(OCAMLFIND, [ocamlfind])
1446 AC_PATH_PROGS(GAS, [gas as])
1447
1448 dnl Get the version of the linker in use.
1449 AC_LINK_GET_VERSION
1450
1451 dnl Determine whether the linker supports the -R option.
1452 AC_LINK_USE_R
1453
1454 dnl Determine whether the compiler supports the -rdynamic option.
1455 AC_LINK_EXPORT_DYNAMIC
1456
1457 dnl Determine whether the linker supports the --version-script option.
1458 AC_LINK_VERSION_SCRIPT
1459
1460 AC_CHECK_HEADERS([errno.h])
1461
1462 case "$llvm_cv_os_type" in
1463   Cygwin|MingW|Win32) llvm_shlib_ext=.dll ;;
1464   Darwin) llvm_shlib_ext=.dylib ;;
1465   *) llvm_shlib_ext=.so ;;
1466 esac
1467
1468 AC_DEFINE_UNQUOTED([LTDL_SHLIB_EXT], ["$llvm_shlib_ext"], [The shared library extension])
1469
1470 AC_MSG_CHECKING([tool compatibility])
1471
1472 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1473 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1474 dnl to support those options.
1475 dnl "icc" emits gcc signatures
1476 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1477 ICC=no
1478 IXX=no
1479 case $CC in
1480   icc*|icpc*)
1481     ICC=yes
1482     IXX=yes
1483     ;;
1484    *)
1485     ;;
1486 esac
1487
1488 if test "$GCC" != "yes" && test "$ICC" != "yes"
1489 then
1490   AC_MSG_ERROR([gcc|icc required but not found])
1491 fi
1492
1493 dnl Ensure that compilation tools are compatible with GCC extensions
1494 if test "$GXX" != "yes" && test "$IXX" != "yes"
1495 then
1496   AC_MSG_ERROR([g++|clang++|icc required but not found])
1497 fi
1498
1499 dnl Verify that GCC is version 3.0 or higher
1500 if test "$GCC" = "yes"
1501 then
1502   AC_COMPILE_IFELSE(
1503 [
1504   AC_LANG_SOURCE([[
1505     #if !defined(__GNUC__) || __GNUC__ < 3
1506     #error Unsupported GCC version
1507     #endif
1508   ]])
1509 ],
1510 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1511 fi
1512
1513 dnl Check for GNU Make.  We use its extensions, so don't build without it
1514 if test -z "$llvm_cv_gnu_make_command"
1515 then
1516   AC_MSG_ERROR([GNU Make required but not found])
1517 fi
1518
1519 dnl Tool compatibility is okay if we make it here.
1520 AC_MSG_RESULT([ok])
1521
1522 dnl Check optional compiler flags.
1523 AC_MSG_CHECKING([optional compiler flags])
1524 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1525 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1526 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1527
1528 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1529 dnl false positives, so disable it.
1530 NO_UNINITIALIZED=
1531 NO_MAYBE_UNINITIALIZED=
1532 if test "$GXX" = "yes"
1533 then
1534   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1535   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1536   dnl known to be uninitialized from cases which might be uninitialized.  We
1537   dnl still want to catch the first kind of errors.
1538   if test -z "$NO_MAYBE_UNINITIALIZED"
1539   then
1540     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1541   fi
1542 fi
1543
1544 dnl Check for misbehaving -Wcomment (gcc-4.7 has this) and maybe add
1545 dnl -Wno-comment to the flags.
1546 no_comment=
1547 llvm_cv_old_cxxflags="$CXXFLAGS"
1548 CXXFLAGS="$CXXFLAGS -Wcomment -Werror"
1549 AC_COMPILE_IFELSE(
1550 [
1551   AC_LANG_SOURCE([[// Comment \o\
1552 // Another comment
1553 int main() { return 0; }
1554   ]])
1555 ],
1556 [
1557   no_comment=-Wno-comment
1558 ],
1559 [])
1560 AC_SUBST(NO_COMMENT, [$no_comment])
1561 CXXFLAGS="$llvm_cv_old_cxxflags"
1562
1563 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED $NO_COMMENT])
1564
1565 AC_ARG_WITH([python],
1566             [AS_HELP_STRING([--with-python], [path to python])],
1567             [PYTHON="$withval"])
1568
1569 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1570   AC_MSG_CHECKING([for python])
1571   AC_MSG_RESULT([user defined: $with_python])
1572 else
1573   if test -n "$PYTHON" ; then
1574     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1575   fi
1576
1577   AC_PATH_PROG([PYTHON], [python python2 python27],
1578                [AC_MSG_RESULT([not found])
1579                 AC_MSG_ERROR([could not find python 2.7 or higher])])
1580 fi
1581
1582 AC_MSG_CHECKING([for python >= 2.7])
1583 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1584 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1585 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1586 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1587 if test "$ac_python_version_major" -gt "2" || \
1588    (test "$ac_python_version_major" -eq "2" && \
1589     test "$ac_python_version_minor" -ge "7") ; then
1590   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1591 else
1592   AC_MSG_RESULT([not found])
1593   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.7])
1594 fi
1595
1596 dnl===-----------------------------------------------------------------------===
1597 dnl===
1598 dnl=== SECTION 5: Check for libraries
1599 dnl===
1600 dnl===-----------------------------------------------------------------------===
1601
1602 AC_CHECK_LIB(m,sin)
1603 if test "$llvm_cv_os_type" = "MingW" ; then
1604   AC_CHECK_LIB(imagehlp, main)
1605   AC_CHECK_LIB(psapi, main)
1606   AC_CHECK_LIB(shell32, main)
1607 fi
1608
1609 dnl dlopen() is required for plugin support.
1610 AC_SEARCH_LIBS(dlopen,dl,LLVM_DEFINE_SUBST([HAVE_DLOPEN],[1],
1611                [Define if dlopen() is available on this platform.]),
1612                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1613
1614 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1615 dnl macros to detect whether clock_gettime is available, this just finds the
1616 dnl right libraries to link with.
1617 AC_SEARCH_LIBS(clock_gettime,rt)
1618
1619 dnl The curses library is optional; used for querying terminal info
1620 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1621   dnl We need the has_color functionality in curses for it to be useful.
1622   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1623                  LLVM_DEFINE_SUBST([HAVE_TERMINFO],[1],
1624                                    [Define if the setupterm() function is supported this platform.]))
1625 fi
1626
1627 dnl The libedit library is optional; used by lib/LineEditor
1628 if test "$llvm_cv_enable_libedit" = "yes" ; then
1629   AC_SEARCH_LIBS(el_init,edit,
1630                  AC_DEFINE([HAVE_LIBEDIT],[1],
1631                            [Define if libedit is available on this platform.]))
1632 fi
1633
1634 dnl libffi is optional; used to call external functions from the interpreter
1635 if test "$llvm_cv_enable_libffi" = "yes" ; then
1636   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1637                  [Define if libffi is available on this platform.]),
1638                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1639 fi
1640
1641 dnl mallinfo is optional; the code can compile (minus features) without it
1642 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1643                [Define if mallinfo() is available on this platform.]))
1644
1645 dnl pthread locking functions are optional - but llvm will not be thread-safe
1646 dnl without locks.
1647 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1648   AC_CHECK_LIB(pthread, pthread_mutex_init)
1649   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1650                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1651                            [Have pthread_mutex_lock]))
1652   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1653                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1654                  [Have pthread_rwlock_init]))
1655   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1656                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1657                  [Have pthread_getspecific]))
1658 fi
1659
1660 dnl zlib is optional; used for compression/uncompression
1661 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1662   AC_CHECK_LIB(z, compress2)
1663 fi
1664
1665 dnl Allow OProfile support for JIT output.
1666 AC_ARG_WITH(oprofile,
1667   AS_HELP_STRING([--with-oprofile=<prefix>],
1668     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1669     [
1670       AC_SUBST(USE_OPROFILE, [1])
1671       case "$withval" in
1672         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1673         no) llvm_cv_oppath=
1674             AC_SUBST(USE_OPROFILE, [0]) ;;
1675         *) llvm_cv_oppath="${withval}/lib/oprofile"
1676            CPPFLAGS="-I${withval}/include";;
1677       esac
1678       case $llvm_cv_os_type in
1679         Linux)
1680           if test -n "$llvm_cv_oppath" ; then
1681             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1682             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1683             dnl libbfd is not included properly in libopagent in some Debian
1684             dnl versions.  If libbfd isn't found at all, we assume opagent works
1685             dnl anyway.
1686             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1687             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1688               echo "Error! You need to have libopagent around."
1689               exit 1
1690             ])
1691             AC_CHECK_HEADER([opagent.h], [], [
1692               echo "Error! You need to have opagent.h around."
1693               exit 1
1694               ])
1695           fi ;;
1696         *)
1697           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1698       esac
1699     ],
1700     [
1701       AC_SUBST(USE_OPROFILE, [0])
1702     ])
1703 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1704                    [Define if we have the oprofile JIT-support library])
1705
1706 dnl Enable support for Intel JIT Events API.
1707 AC_ARG_WITH(intel-jitevents,
1708   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1709     [
1710        case "$withval" in
1711           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1712           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1713           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1714        esac
1715
1716       case $llvm_cv_os_type in
1717         Linux|Win32|Cygwin|MingW) ;;
1718         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1719       esac
1720
1721       case "$llvm_cv_target_arch" in
1722         x86|x86_64) ;;
1723         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1724       esac
1725     ],
1726     [
1727       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1728     ])
1729 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1730                    [Define if we have the Intel JIT API runtime support library])
1731
1732 dnl Check for libxml2
1733 dnl Right now we're just checking for the existence, we could also check for a
1734 dnl particular version via --version on xml2-config
1735 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1736
1737 AC_MSG_CHECKING(for libxml2 includes)
1738 if test "x$XML2CONFIG" = "x"; then
1739  AC_MSG_RESULT(xml2-config not found)
1740 else
1741  LIBXML2_INC=`$XML2CONFIG --cflags`
1742  AC_MSG_RESULT($LIBXML2_INC)
1743  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1744                                 LIBXML2_LIBS="-lxml2"])
1745 fi
1746 AC_SUBST(LIBXML2_LIBS)
1747 AC_SUBST(LIBXML2_INC)
1748
1749 dnl===-----------------------------------------------------------------------===
1750 dnl===
1751 dnl=== SECTION 6: Check for header files
1752 dnl===
1753 dnl===-----------------------------------------------------------------------===
1754
1755 dnl First, use autoconf provided macros for specific headers that we need
1756 dnl We don't check for ancient stuff or things that are guaranteed to be there
1757 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1758 dnl Generally we're looking for POSIX headers.
1759 AC_HEADER_DIRENT
1760 AC_HEADER_MMAP_ANONYMOUS
1761 AC_HEADER_STAT
1762 AC_HEADER_SYS_WAIT
1763 AC_HEADER_TIME
1764
1765 AC_LANG_PUSH([C++])
1766 dnl size_t must be defined before including cxxabi.h on FreeBSD 10.0.
1767 AC_CHECK_HEADERS([cxxabi.h], [], [],
1768 [#include <stddef.h>
1769 ])
1770 AC_LANG_POP([C++])
1771
1772 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1773 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1774 AC_CHECK_HEADERS([utime.h])
1775 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1776 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1777 AC_CHECK_HEADERS([valgrind/valgrind.h])
1778 AC_CHECK_HEADERS([fenv.h])
1779 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1780 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1781   AC_CHECK_HEADERS(pthread.h,
1782                    AC_SUBST(HAVE_PTHREAD, 1),
1783                    AC_SUBST(HAVE_PTHREAD, 0))
1784 else
1785   AC_SUBST(HAVE_PTHREAD, 0)
1786 fi
1787 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1788   AC_CHECK_HEADERS(zlib.h,
1789                    AC_SUBST(HAVE_LIBZ, 1),
1790                    AC_SUBST(HAVE_LIBZ, 0))
1791 else
1792   AC_SUBST(HAVE_LIBZ, 0)
1793 fi
1794
1795 dnl Try to find ffi.h.
1796 if test "$llvm_cv_enable_libffi" = "yes" ; then
1797   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1798 fi
1799
1800 dnl Try to find Darwin specific crash reporting libraries.
1801 AC_CHECK_HEADERS([CrashReporterClient.h])
1802
1803 dnl Try to find Darwin specific crash reporting global.
1804 AC_MSG_CHECKING([__crashreporter_info__])
1805 AC_LINK_IFELSE(
1806 [
1807   AC_LANG_SOURCE([[
1808     extern const char *__crashreporter_info__;
1809     int main() {
1810       __crashreporter_info__ = "test";
1811       return 0;
1812     }
1813   ]])
1814 ],
1815 [
1816   AC_MSG_RESULT([yes])
1817   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1818 ],
1819 [
1820   AC_MSG_RESULT([no])
1821   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1822 ])
1823
1824 dnl===-----------------------------------------------------------------------===
1825 dnl===
1826 dnl=== SECTION 7: Check for types and structures
1827 dnl===
1828 dnl===-----------------------------------------------------------------------===
1829
1830 AC_HUGE_VAL_CHECK
1831 AC_TYPE_PID_T
1832 AC_TYPE_SIZE_T
1833 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1834 AC_STRUCT_TM
1835 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1836 AC_CHECK_TYPES([uint64_t],,
1837          AC_CHECK_TYPES([u_int64_t],,
1838          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1839
1840 dnl===-----------------------------------------------------------------------===
1841 dnl===
1842 dnl=== SECTION 8: Check for specific functions needed
1843 dnl===
1844 dnl===-----------------------------------------------------------------------===
1845
1846 AC_CHECK_FUNCS([backtrace getcwd ])
1847 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1848 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1849 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1850 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1851 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1852 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1853 AC_CHECK_FUNCS([futimes futimens])
1854 AC_C_PRINTF_A
1855 AC_FUNC_RAND48
1856
1857 dnl Check for arc4random accessible via AC_INCLUDES_DEFAULT.
1858 AC_CHECK_DECLS([arc4random])
1859
1860 dnl Check the declaration "Secure API" on Windows environments.
1861 AC_CHECK_DECLS([strerror_s])
1862
1863 dnl Check symbols in libgcc.a for JIT on Mingw.
1864 if test "$llvm_cv_os_type" = "MingW" ; then
1865   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1866   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1867   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1868   AC_CHECK_LIB(gcc,__chkstk_ms,AC_DEFINE([HAVE___CHKSTK_MS],[1],[Have host's __chkstk_ms]))
1869   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1870   AC_CHECK_LIB(gcc,___chkstk_ms,AC_DEFINE([HAVE____CHKSTK_MS],[1],[Have host's ___chkstk_ms]))
1871
1872   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1873   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1874   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1875   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1876   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1877   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1878   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1879   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1880   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1881   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1882
1883   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1884   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1885 fi
1886
1887 dnl Check Win32 API EnumerateLoadedModules.
1888 if test "$llvm_cv_os_type" = "MingW" ; then
1889   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1890   AC_COMPILE_IFELSE(
1891 [
1892   AC_LANG_SOURCE([[
1893     #include <windows.h>
1894     #include <imagehlp.h>
1895     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1896     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1897   ]])
1898 ],
1899 [
1900   AC_MSG_RESULT([yes])
1901   llvm_cv_win32_elmcb_pcstr="PCSTR"
1902 ],
1903 [
1904   AC_MSG_RESULT([no])
1905   llvm_cv_win32_elmcb_pcstr="PSTR"
1906 ])
1907   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1908 fi
1909
1910 dnl Check for mmap support.We also need to know if /dev/zero is required to
1911 dnl be opened for allocating RWX memory.
1912 dnl Make sure we aren't attempting to configure for an unknown system
1913 if test "$llvm_cv_platform_type" = "Unix" ; then
1914   AC_FUNC_MMAP
1915   AC_FUNC_MMAP_FILE
1916   AC_NEED_DEV_ZERO_FOR_MMAP
1917
1918   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1919   then
1920     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1921   fi
1922   if test "$ac_cv_func_mmap_file" = "no"
1923   then
1924     AC_MSG_WARN([mmap() of files required but not found])
1925   fi
1926 fi
1927
1928 dnl atomic builtins are required for threading support.
1929 AC_MSG_CHECKING(for GCC atomic builtins)
1930 dnl Since we'll be using these atomic builtins in C++ files we should test
1931 dnl the C++ compiler.
1932 AC_LANG_PUSH([C++])
1933 AC_LINK_IFELSE(
1934 [
1935   AC_LANG_SOURCE([[
1936     int main() {
1937       volatile unsigned long val = 1;
1938       __sync_synchronize();
1939       __sync_val_compare_and_swap(&val, 1, 0);
1940       __sync_add_and_fetch(&val, 1);
1941       __sync_sub_and_fetch(&val, 1);
1942       return 0;
1943     }
1944   ]])
1945 ],
1946 [
1947   AC_MSG_RESULT([yes])
1948   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1949 ],
1950 [
1951   AC_MSG_RESULT([no])
1952   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1953   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1954 ])
1955 AC_LANG_POP([C++])
1956
1957 dnl===-----------------------------------------------------------------------===
1958 dnl===
1959 dnl=== SECTION 9: Additional checks, variables, etc.
1960 dnl===
1961 dnl===-----------------------------------------------------------------------===
1962
1963 dnl Handle 32-bit linux systems running a 64-bit kernel.
1964 dnl This has to come after section 4 because it invokes the compiler.
1965 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1966   AC_IS_LINUX_MIXED
1967   if test "$llvm_cv_linux_mixed" = "yes"; then
1968     llvm_cv_target_arch="x86"
1969     ARCH="x86"
1970   fi
1971 fi
1972
1973 dnl Check whether __dso_handle is present
1974 AC_CHECK_FUNCS([__dso_handle])
1975
1976 dnl Propagate the shared library extension that the libltdl checks did to
1977 dnl the Makefiles so we can use it there too
1978 AC_SUBST(SHLIBEXT,$llvm_shlib_ext)
1979
1980 dnl Translate the various configuration directories and other basic
1981 dnl information into substitutions that will end up in Makefile.config.in
1982 dnl that these configured values can be used by the makefiles
1983 if test "${prefix}" = "NONE" ; then
1984   prefix="/usr/local"
1985 fi
1986 eval LLVM_PREFIX="${prefix}";
1987 eval LLVM_BINDIR="${prefix}/bin";
1988 eval LLVM_DATADIR="${prefix}/share/llvm";
1989 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1990 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1991 eval LLVM_INCLUDEDIR="${prefix}/include";
1992 eval LLVM_INFODIR="${prefix}/info";
1993 eval LLVM_MANDIR="${prefix}/man";
1994 LLVM_CONFIGTIME=`date`
1995 AC_SUBST(LLVM_PREFIX)
1996 AC_SUBST(LLVM_BINDIR)
1997 AC_SUBST(LLVM_DATADIR)
1998 AC_SUBST(LLVM_DOCSDIR)
1999 AC_SUBST(LLVM_ETCDIR)
2000 AC_SUBST(LLVM_INCLUDEDIR)
2001 AC_SUBST(LLVM_INFODIR)
2002 AC_SUBST(LLVM_MANDIR)
2003 AC_SUBST(LLVM_CONFIGTIME)
2004
2005 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
2006 if test "${ENABLE_TIMESTAMPS}" = "0"; then
2007   LLVM_CONFIGTIME="(timestamp not enabled)"
2008 fi
2009
2010 dnl Place the various directories into the config.h file as #defines so that we
2011 dnl can know about the installation paths within LLVM.
2012 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
2013                    [Installation prefix directory])
2014 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
2015                    [Installation directory for binary executables])
2016 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
2017                    [Installation directory for data files])
2018 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
2019                    [Installation directory for documentation])
2020 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
2021                    [Installation directory for config files])
2022 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
2023                    [Installation directory for include files])
2024 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
2025                    [Installation directory for .info files])
2026 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
2027                    [Installation directory for man pages])
2028 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
2029                    [Time at which LLVM was configured])
2030 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
2031                    [Host triple LLVM will be executed on])
2032 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
2033                    [Target triple LLVM will generate code for by default])
2034
2035 dnl Determine which bindings to build.
2036 if test "$BINDINGS_TO_BUILD" = auto ; then
2037   BINDINGS_TO_BUILD=""
2038   if test "x$OCAMLFIND" != x ; then
2039     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
2040   fi
2041   if test "x$GO" != x ; then
2042     if $GO run ${srcdir}/bindings/go/conftest.go ; then
2043       BINDINGS_TO_BUILD="go $BINDINGS_TO_BUILD"
2044     fi
2045   fi
2046 fi
2047 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
2048
2049 dnl Do any work necessary to ensure that bindings have what they need.
2050 binding_prereqs_failed=0
2051 for a_binding in $BINDINGS_TO_BUILD ; do
2052   case "$a_binding" in
2053   ocaml)
2054     if test "x$OCAMLFIND" = x ; then
2055       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlfind not found. Try configure OCAMLFIND=/path/to/ocamlfind])
2056       binding_prereqs_failed=1
2057     fi
2058
2059     if $OCAMLFIND opt -version >/dev/null 2>/dev/null ; then
2060       HAVE_OCAMLOPT=1
2061     else
2062       HAVE_OCAMLOPT=0
2063     fi
2064     AC_SUBST(HAVE_OCAMLOPT)
2065
2066     if ! $OCAMLFIND query ctypes >/dev/null 2>/dev/null; then
2067       AC_MSG_WARN([--enable-bindings=ocaml specified, but ctypes is not installed])
2068       binding_prereqs_failed=1
2069     fi
2070
2071     if $OCAMLFIND query oUnit >/dev/null 2>/dev/null; then
2072       HAVE_OCAML_OUNIT=1
2073     else
2074       HAVE_OCAML_OUNIT=0
2075       AC_MSG_WARN([--enable-bindings=ocaml specified, but OUnit 2 is not installed. Tests will not run])
2076       dnl oUnit is optional!
2077     fi
2078     AC_SUBST(HAVE_OCAML_OUNIT)
2079
2080     if test "x$with_ocaml_libdir" != xauto ; then
2081       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
2082     else
2083       ocaml_stdlib="`"$OCAMLFIND" ocamlc -where`"
2084       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
2085       then
2086         # ocaml stdlib is beneath our prefix; use stdlib
2087         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
2088       else
2089         # ocaml stdlib is outside our prefix; use libdir/ocaml
2090         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
2091       fi
2092     fi
2093     ;;
2094   go)
2095     if test "x$GO" = x ; then
2096       AC_MSG_WARN([--enable-bindings=go specified, but go not found. Try configure GO=/path/to/go])
2097       binding_prereqs_failed=1
2098     else
2099       if $GO run ${srcdir}/bindings/go/conftest.go ; then
2100         :
2101       else
2102         AC_MSG_WARN([--enable-bindings=go specified, but need at least Go 1.2. Try configure GO=/path/to/go])
2103         binding_prereqs_failed=1
2104       fi
2105     fi
2106     ;;
2107   esac
2108 done
2109 if test "$binding_prereqs_failed" = 1 ; then
2110   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
2111 fi
2112
2113 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
2114 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
2115
2116 dnl Determine linker rpath flag
2117 if test "$llvm_cv_link_use_r" = "yes" ; then
2118   RPATH="-Wl,-R"
2119 else
2120   RPATH="-Wl,-rpath"
2121 fi
2122 AC_SUBST(RPATH)
2123
2124 dnl Determine linker rdynamic flag
2125 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
2126   RDYNAMIC="-rdynamic"
2127 else
2128   RDYNAMIC=""
2129 fi
2130 AC_SUBST(RDYNAMIC)
2131
2132 dnl===-----------------------------------------------------------------------===
2133 dnl===
2134 dnl=== SECTION 10: Specify the output files and generate it
2135 dnl===
2136 dnl===-----------------------------------------------------------------------===
2137
2138 dnl Configure header files
2139 dnl WARNING: dnl If you add or remove any of the following config headers, then
2140 dnl you MUST also update Makefile so that the variable FilesToConfig
2141 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
2142 dnl files can be updated automatically when their *.in sources change.
2143 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
2144 AH_TOP([#ifndef CONFIG_H
2145 #define CONFIG_H])
2146 AH_BOTTOM([#endif])
2147
2148 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
2149 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
2150 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
2151 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
2152 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
2153
2154 dnl Configure the makefile's configuration data
2155 AC_CONFIG_FILES([Makefile.config])
2156
2157 dnl Configure the RPM spec file for LLVM
2158 AC_CONFIG_FILES([llvm.spec])
2159
2160 dnl Configure doxygen's configuration file
2161 AC_CONFIG_FILES([docs/doxygen.cfg])
2162
2163 dnl Configure clang, if present
2164 if test "${clang_src_root}" = ""; then
2165   clang_src_root="$srcdir/tools/clang"
2166 fi
2167 if test -f ${clang_src_root}/README.txt; then
2168   dnl Clang supports build systems which use the multilib libdir suffix.
2169   dnl The autoconf system doesn't support this so stub out that variable.
2170   AC_DEFINE_UNQUOTED(CLANG_LIBDIR_SUFFIX,"",
2171                      [Multilib suffix for libdir.])
2172
2173   dnl Use variables to stay under 80 columns.
2174   configh="include/clang/Config/config.h"
2175   doxy="docs/doxygen.cfg"
2176   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
2177   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
2178 fi
2179
2180 dnl OCaml findlib META file
2181 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
2182
2183 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
2184 test "x$program_prefix" = "xNONE" && program_prefix=""
2185 AC_SUBST([program_prefix])
2186
2187
2188 dnl Do special configuration of Makefiles
2189 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2190 AC_CONFIG_MAKEFILE(Makefile)
2191 AC_CONFIG_MAKEFILE(Makefile.common)
2192 AC_CONFIG_MAKEFILE(examples/Makefile)
2193 AC_CONFIG_MAKEFILE(lib/Makefile)
2194 AC_CONFIG_MAKEFILE(test/Makefile)
2195 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2196 AC_CONFIG_MAKEFILE(unittests/Makefile)
2197 AC_CONFIG_MAKEFILE(tools/Makefile)
2198 AC_CONFIG_MAKEFILE(utils/Makefile)
2199 AC_CONFIG_MAKEFILE(projects/Makefile)
2200 AC_CONFIG_MAKEFILE(bindings/Makefile)
2201 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2202
2203 dnl Finally, crank out the output
2204 AC_OUTPUT