autoconf/configure.ac

   1 dnl Autoconf requirements
   2 dnl AC_INIT(package, version, bug-report-address)
   3 dnl information on the package
   4 dnl checks for programs
   5 dnl checks for libraries
   6 dnl checks for header files
   7 dnl checks for types
   8 dnl checks for structures
   9 dnl checks for compiler characteristics
  10 dnl checks for library functions
  11 dnl checks for system services
  12 dnl AC_CONFIG_FILES([file...])
  13 dnl AC_OUTPUT
  14
  15 dnl **************************************************************************
  16 dnl * Initialize
  17 dnl **************************************************************************
  18 AC_INIT([[[LLVM]]],[[[1.0]]],[llvmbugs@cs.uiuc.edu])
  19
  20 dnl Place all of the extra autoconf files into the config subdirectory
  21 AC_CONFIG_AUX_DIR([autoconf])
  22
  23 dnl Quit if the source directory has already been configured.
  24 dnl NOTE: This relies upon undocumented autoconf behavior.
  25 if test ${srcdir} != "."
  26 then
  27         if test -f ${srcdir}/include/Config/config.h
  28         then
  29                 AC_MSG_ERROR([Already configured in ${srcdir}])
  30         fi
  31 fi
  32
  33 if test -d ${srcdir}/projects/sample
  34 then
  35   AC_CONFIG_SUBDIRS(projects/sample)
  36 fi
  37
  38 if test -d ${srcdir}/projects/reopt
  39 then
  40   AC_CONFIG_SUBDIRS(projects/reopt)
  41 fi
  42
  43 if test -d ${srcdir}/projects/poolalloc
  44 then
  45   AC_CONFIG_SUBDIRS(projects/poolalloc)
  46 fi
  47
  48 dnl Configure a header file
  49 AC_CONFIG_HEADERS(include/Config/config.h)
  50 AC_CONFIG_MAKEFILE(Makefile)
  51 AC_CONFIG_MAKEFILE(Makefile.common)
  52 AC_CONFIG_MAKEFILE(lib/Makefile)
  53 AC_CONFIG_MAKEFILE(runtime/Makefile)
  54 AC_CONFIG_MAKEFILE(test/Makefile)
  55 AC_CONFIG_MAKEFILE(test/Makefile.tests)
  56 AC_CONFIG_MAKEFILE(test/QMTest/llvm.py)
  57 AC_CONFIG_MAKEFILE(test/QMTest/llvmdb.py)
  58 AC_CONFIG_MAKEFILE(test/Programs/Makefile)
  59 AC_CONFIG_MAKEFILE(test/Programs/Makefile.programs)
  60 AC_CONFIG_MAKEFILE(test/Programs/TEST.aa.Makefile)
  61 AC_CONFIG_MAKEFILE(test/Programs/TEST.dsgraph.report)
  62 AC_CONFIG_MAKEFILE(test/Programs/TEST.micro.report)
  63 AC_CONFIG_MAKEFILE(test/Programs/TEST.aa.report)
  64 AC_CONFIG_MAKEFILE(test/Programs/TEST.example.Makefile)
  65 AC_CONFIG_MAKEFILE(test/Programs/TEST.nightly.Makefile)
  66 AC_CONFIG_MAKEFILE(test/Programs/TEST.buildrepo.Makefile)
  67 AC_CONFIG_MAKEFILE(test/Programs/TEST.jit.Makefile)
  68 AC_CONFIG_MAKEFILE(test/Programs/TEST.nightly.report)
  69 AC_CONFIG_MAKEFILE(test/Programs/TEST.dsgraph.Makefile)
  70 AC_CONFIG_MAKEFILE(test/Programs/TEST.jit.report)
  71 AC_CONFIG_MAKEFILE(test/Programs/TEST.typesafe.Makefile)
  72 AC_CONFIG_MAKEFILE(test/Programs/TEST.dsgraph.gnuplot)
  73 AC_CONFIG_MAKEFILE(test/Programs/TEST.micro.Makefile)
  74 AC_CONFIG_MAKEFILE(test/Programs/External/Makefile)
  75 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/Makefile)
  76 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/Makefile.spec)
  77 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Makefile)
  78 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Makefile.multisrc)
  79 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/analyzer/test.in)
  80 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/distray/Makefile)
  81 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/distray/test.in)
  82 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/fourinarow/Makefile)
  83 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/fourinarow/test.in)
  84 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/mason/Makefile)
  85 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/mason/test.in)
  86 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/neural/Makefile)
  87 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/neural/test.in)
  88 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/pcompress2/Makefile)
  89 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/pcompress2/test.in)
  90 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/pifft/Makefile)
  91 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/FreeBench/pifft/test.in)
  92 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Makefile)
  93 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Makefile.singlesrc)
  94 AC_CONFIG_MAKEFILE(tools/Makefile)
  95 AC_CONFIG_MAKEFILE(utils/Makefile)
  96 AC_CONFIG_MAKEFILE(projects/Makefile)
  97 AC_CONFIG_MAKEFILE(projects/ModuleMaker/Makefile)
  98 AC_CONFIG_MAKEFILE(projects/ModuleMaker/Makefile.common)
  99 AC_CONFIG_MAKEFILE(projects/ModuleMaker/tools/Makefile)
 100 AC_CONFIG_MAKEFILE(projects/ModuleMaker/tools/ModuleMaker/Makefile)
 101 AC_CONFIG_MAKEFILE(projects/Stacker/Makefile)
 102 AC_CONFIG_MAKEFILE(projects/Stacker/lib/Makefile)
 103 AC_CONFIG_MAKEFILE(projects/Stacker/lib/compiler/Makefile)
 104 AC_CONFIG_MAKEFILE(projects/Stacker/lib/runtime/Makefile)
 105 AC_CONFIG_MAKEFILE(projects/Stacker/tools/Makefile)
 106 AC_CONFIG_MAKEFILE(projects/Stacker/tools/stkrc/Makefile)
 107 AC_CONFIG_MAKEFILE(projects/Stacker/test/Makefile)
 108 AC_CONFIG_MAKEFILE(projects/Stacker/samples/Makefile)
 109
 110 dnl **************************************************************************
 111 dnl * Determine which system we are building on
 112 dnl **************************************************************************
 113
 114 dnl Check the install program (needs to be done before canonical stuff)
 115 AC_PROG_INSTALL
 116
 117 dnl Check which host for which we're compiling.  This will tell us which LLVM
 118 dnl compiler will be used for compiling SSA into object code.
 119 AC_CANONICAL_TARGET
 120
 121 dnl Set the "OS" Makefile variable based on the system we are building on.
 122 dnl We will use the build machine information to set some variables.
 123 case $build in
 124         *-*-linux*)
 125              AC_SUBST(OS,[Linux])
 126                          if test -d /home/vadve/lattner/local/x86/llvm-gcc
 127                          then
 128                            AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/x86/llvm-gcc/])
 129                          fi
 130                  ;;
 131
 132         *-*-solaris*)
 133              AC_SUBST(OS,[SunOS])
 134                          if test -d /home/vadve/lattner/local/sparc/llvm-gcc
 135                          then
 136                    AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/sparc/llvm-gcc/])
 137                          fi
 138                  ;;
 139
 140         *-*-darwin*)
 141              AC_SUBST(OS,[Darwin])
 142                  ;;
 143
 144         *)       AC_SUBST(OS,[Unknown])
 145                  ;;
 146 esac
 147
 148 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
 149 dnl V9, since that is all that we support at the moment, and autoconf will only
 150 dnl tell us we're a sparc.
 151 case $target in
 152         sparc*-*-solaris*)  AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
 153                             ;;
 154 esac
 155
 156 dnl Determine what our target architecture is and configure accordingly.
 157 dnl This will allow Makefiles to make a distinction between the hardware and
 158 dnl the OS.
 159 case $target in
 160         i*86-*)           AC_SUBST(ARCH,[x86])
 161                           ;;
 162         sparc*-*)         AC_SUBST(ARCH,[Sparc])
 163                           ;;
 164         powerpc*-*)       AC_SUBST(ARCH,[PowerPC])
 165                           ;;
 166         *)                AC_SUBST(ARCH,[Unknown])
 167                           ;;
 168 esac
 169
 170 dnl **************************************************************************
 171 dnl * Check for programs.
 172 dnl **************************************************************************
 173
 174 dnl Check for compilation tools
 175 AC_PROG_CXX
 176 AC_PROG_CC(gcc)
 177 AC_PROG_CPP
 178
 179 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 180 if test "$GCC" != "yes"
 181 then
 182         AC_MSG_ERROR([gcc required but not found])
 183 fi
 184
 185 if test "$GXX" != "yes"
 186 then
 187         AC_MSG_ERROR([g++ required but not found])
 188 fi
 189
 190 dnl Verify that GCC is version 3.0 or higher
 191 gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 192 if test "$gccmajor" -lt "3"
 193 then
 194         AC_MSG_ERROR([gcc 3.x required])
 195 fi
 196
 197 dnl Check for GNU Make.  We use its extensions to, so don't build without it
 198 CHECK_GNU_MAKE
 199 if test -z "$_cv_gnu_make_command"
 200 then
 201         AC_MSG_ERROR([GNU Make required but not found])
 202 fi
 203
 204 dnl Check for compiler-compiler tools (reminds me of Little Caesar's Pizza)
 205 AC_PROG_FLEX
 206 AC_PROG_BISON
 207
 208 dnl Check for libtool
 209 AC_PROG_LIBTOOL
 210
 211 dnl Check for our special programs
 212 AC_PATH_PROG(RPWD,[pwd],[false])
 213 if test ${RPWD} = "false"
 214 then
 215         AC_MSG_ERROR([pwd required but not found])
 216 fi
 217
 218 AC_PATH_PROG(AR,[ar],[false])
 219 if test ${AR} = "false"
 220 then
 221         AC_MSG_ERROR([ar required but not found])
 222 fi
 223
 224 AC_PATH_PROG(SED,[sed],[false])
 225 if test ${SED} = "false"
 226 then
 227         AC_MSG_ERROR([sed required but not found])
 228 fi
 229
 230 AC_PATH_PROG(RM,[rm],[false])
 231 if test ${RM} = "false"
 232 then
 233         AC_MSG_ERROR([rm required but not found])
 234 fi
 235
 236 AC_PATH_PROG(ECHO,[echo],[false])
 237 if test ${ECHO} = "false"
 238 then
 239         AC_MSG_ERROR([echo required but not found])
 240 fi
 241
 242 AC_PATH_PROG(MKDIR,[mkdir],[false])
 243 if test ${MKDIR} = "false"
 244 then
 245         AC_MSG_ERROR([mkdir required but not found])
 246 fi
 247
 248 AC_PATH_PROG(DATE,[date],[false])
 249 if test ${DATE} = "false"
 250 then
 251         AC_MSG_ERROR([date required but not found])
 252 fi
 253
 254 AC_PATH_PROG(MV,[mv],[false])
 255 if test ${MV} = "false"
 256 then
 257         AC_MSG_ERROR([mv required but not found])
 258 fi
 259
 260 AC_PATH_PROG(DOT,[dot],[false])
 261
 262 AC_PATH_PROG(ETAGS,[etags],[false])
 263
 264 AC_PATH_PROG(PYTHON,[python],[false])
 265 if test ${PYTHON} = "false"
 266 then
 267         AC_MSG_WARN([python required but not found])
 268 fi
 269
 270 AC_PATH_PROG(QMTEST,[qmtest],[false])
 271 if test ${QMTEST} = "false"
 272 then
 273         AC_MSG_WARN([qmtest required but not found])
 274 fi
 275
 276 dnl Verify that the version of python available is high enough for qmtest
 277 pyversion=`$PYTHON -V 2>&1 | cut -d\  -f2`
 278 pymajor=`echo $pyversion | cut -d. -f1`
 279 pyminor=`echo $pyversion | cut -d. -f2`
 280
 281 if test "$pymajor" -ge "2"
 282 then
 283         if test "$pymajor" -eq "2"
 284         then
 285                 if test "$pyminor" -lt "2"
 286                 then
 287                         AC_MSG_WARN([Python 2.2 or greater required for qmtest])
 288                 fi
 289         fi
 290 else
 291         AC_MSG_WARN([Python 2.2 or greater required for qmtest])
 292 fi
 293
 294 dnl Verify that the source directory is valid
 295 AC_CONFIG_SRCDIR(["Makefile.config.in"])
 296
 297 dnl **************************************************************************
 298 dnl * Check for libraries.
 299 dnl **************************************************************************
 300
 301 dnl libelf is for sparc only; we can ignore it if we don't have it
 302 AC_CHECK_LIB(elf, elf_begin)
 303
 304 dnl dlopen() is required for plugin support.
 305 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],[Define if dlopen() is available on this platform.]),AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 306
 307 dnl mallinfo is optional; the code can compile (minus features) without it
 308 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],[Define if mallinfo() is available on this platform.]))
 309
 310 dnl
 311 dnl The math libraries are used by the test code, but not by the actual LLVM
 312 dnl code.
 313 dnl
 314 dnl AC_CHECK_LIB(m, cos)
 315
 316 dnl **************************************************************************
 317 dnl * Checks for header files.
 318 dnl *   Chances are, if the standard C or POSIX type header files are missing,
 319 dnl *   then LLVM just isn't going to compile.  However, it is possible that
 320 dnl *   the necessary functions/macros will be included from other
 321 dnl *   (non-standard and non-obvious) header files.
 322 dnl *
 323 dnl *   So, we'll be gracious, give it a chance, and try to go on without
 324 dnl *   them.
 325 dnl **************************************************************************
 326 AC_HEADER_STDC
 327 AC_HEADER_SYS_WAIT
 328
 329 dnl Check for ANSI C/POSIX header files
 330 AC_CHECK_HEADERS(assert.h fcntl.h limits.h sys/time.h unistd.h errno.h signal.h math.h)
 331
 332 dnl Check for system specific header files
 333 AC_CHECK_HEADERS(malloc.h sys/mman.h sys/resource.h)
 334
 335 dnl Check for header files associated with dlopen and friends
 336 AC_CHECK_HEADERS(dlfcn.h link.h)
 337
 338 dnl **************************************************************************
 339 dnl * Checks for typedefs, structures, and compiler characteristics.
 340 dnl **************************************************************************
 341
 342 dnl Check for const and inline keywords
 343 AC_C_CONST
 344 AC_C_INLINE
 345
 346 dnl Check for machine endian-ness
 347 AC_C_BIGENDIAN(AC_DEFINE([ENDIAN_BIG],[],[Define if the machine is Big-Endian]),AC_DEFINE([ENDIAN_LITTLE],[],[Define if the machine is Little-Endian]))
 348
 349 dnl Check for types
 350 AC_TYPE_PID_T
 351 AC_TYPE_SIZE_T
 352 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 353 AC_CHECK_TYPES([uint64_t],,AC_MSG_ERROR([Type uint64_t required but not found]))
 354 AC_HEADER_TIME
 355 AC_STRUCT_TM
 356
 357 dnl Check for various C features
 358 AC_C_PRINTF_A
 359
 360 dnl Check for C++ extensions
 361 AC_CXX_HAVE_HASH_MAP
 362 AC_CXX_HAVE_HASH_SET
 363 AC_CXX_HAVE_EXT_SLIST
 364 AC_CXX_HAVE_STD_ITERATOR
 365 AC_CXX_HAVE_BI_ITERATOR
 366 AC_CXX_HAVE_FWD_ITERATOR
 367
 368 dnl **************************************************************************
 369 dnl * Checks for library functions.
 370 dnl **************************************************************************
 371 AC_FUNC_ALLOCA
 372 AC_PROG_GCC_TRADITIONAL
 373 AC_FUNC_MEMCMP
 374 AC_FUNC_MMAP
 375 AC_FUNC_MMAP_FILE
 376 if test ${ac_cv_func_mmap_file} = "no"
 377 then
 378         AC_MSG_ERROR([mmap() of files required but not found])
 379 fi
 380 AC_HEADER_MMAP_ANONYMOUS
 381 AC_TYPE_SIGNAL
 382 AC_CHECK_FUNCS(getcwd gettimeofday strcspn strdup strerror strspn strstr strtod strtol strtoq strtoll)
 383
 384 dnl
 385 dnl Need to check mmap for MAP_PRIVATE, MAP_ANONYMOUS, MAP_ANON, MAP_FIXED
 386 dnl MAP_FIXED is only needed for Sparc
 387 dnl MAP_ANON is used for Sparc and BSD
 388 dnl Everyone should have MAP_PRIVATE
 389 dnl
 390
 391 dnl Check for certain functions (even if we've already found them) so that we
 392 dnl can quit with an error if they are unavailable.
 393 dnl
 394 dnl As the code is made more portable (i.e. less reliant on these functions,
 395 dnl these checks should go away.
 396 AC_CHECK_FUNC(mmap,,AC_MSG_ERROR([Function mmap() required but not found]))
 397 AC_CHECK_FUNC(mprotect,,AC_MSG_ERROR([Function mprotect() required but not found]))
 398
 399 dnl Determine if the linker supports the -R option.
 400 AC_LINK_USE_R()
 401
 402 dnl **************************************************************************
 403 dnl * Enable various compile-time options
 404 dnl **************************************************************************
 405
 406 dnl Purify Option
 407 AC_ARG_ENABLE(purify,AC_HELP_STRING([--enable-purify],[Compile with purify (default is NO)]),,enableval="no")
 408 if test ${enableval} = "no"
 409 then
 410         AC_SUBST(ENABLE_PURIFY,[[]])
 411 else
 412         AC_SUBST(ENABLE_PURIFY,[[ENABLE_PURIFY=1]])
 413 fi
 414
 415 dnl Optimized Option
 416 AC_ARG_ENABLE(optimized,AC_HELP_STRING([--enable-optimized],[Compile with optimizations enabled (default is NO)]),,enableval=no)
 417 if test ${enableval} = "no"
 418 then
 419         AC_SUBST(ENABLE_OPTIMIZED,[[]])
 420 else
 421         AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 422 fi
 423
 424 dnl Spec Benchmarks
 425 AC_ARG_ENABLE(spec2000,AC_HELP_STRING([--enable-spec],[Compile SPEC 2000 benchmarks (default is NO)]),,enableval=no)
 426 if test ${enableval} = "no"
 427 then
 428         if test -d /home/vadve/shared/benchmarks/speccpu2000/benchspec
 429         then
 430                 AC_SUBST(SPEC_ROOT,[/home/vadve/shared/benchmarks/speccpu2000/benchspec])
 431                 AC_SUBST(USE_SPEC,[[USE_SPEC=1]])
 432         else
 433                 AC_SUBST(USE_SPEC,[[]])
 434                 AC_SUBST(SPEC_ROOT,[])
 435         fi
 436 else
 437         if test ${enableval} = ""
 438         then
 439                 AC_SUBST(SPEC_ROOT,[/home/vadve/shared/benchmarks/speccpu2000/benchspec])
 440         else
 441                 AC_SUBST(SPEC_ROOT,[${enableval}])
 442         fi
 443         AC_SUBST(USE_SPEC,[[USE_SPEC=1]])
 444 fi
 445
 446 dnl Precompiled Bytecode Option
 447 AC_ARG_ENABLE(precompiled_bytecode,AC_HELP_STRING([--enable-precompiled_bytecode],[Use pre-compiled bytecode (default is NO)]),,enableval=no)
 448 if test ${enableval} = "no"
 449 then
 450         AC_SUBST(UPB,[[]])
 451 else
 452         AC_SUBST(UPB,[[USE_PRECOMPILED_BYTECODE=1]])
 453 fi
 454
 455
 456 dnl LLC Diff Option
 457 AC_ARG_ENABLE(llc_diffs,AC_HELP_STRING([--enable-llc_diffs],[Enable LLC Diffs when testing (default is YES)]),,enableval=yes)
 458 if test ${enableval} = "no"
 459 then
 460         AC_SUBST(DISABLE_LLC_DIFFS,[DISABLE_LLC_DIFFS:=1])
 461 else
 462         AC_SUBST(DISABLE_LLC_DIFFS,[[]])
 463 fi
 464
 465 dnl JIT Option
 466 AC_ARG_ENABLE(jit,AC_HELP_STRING([--enable-jit],[Enable Just In Time Compiling (default is YES)]),,enableval=default)
 467
 468 if test ${enableval} = "no"
 469 then
 470         AC_SUBST(JIT,[[]])
 471 else
 472         case $target in
 473                 *i*86*)
 474                         AC_SUBST(JIT,[[TARGET_HAS_JIT=1]])
 475                         ;;
 476                 *sparc*)
 477                         AC_SUBST(JIT,[[TARGET_HAS_JIT=1]])
 478                         ;;
 479                 *)
 480                         AC_SUBST(JIT,[[]])
 481                         ;;
 482         esac
 483 fi
 484
 485 dnl **************************************************************************
 486 dnl * Set the location of various third-party software packages
 487 dnl **************************************************************************
 488
 489 dnl Location of the LLVM C front end
 490 AC_ARG_WITH(llvmgccdir,AC_HELP_STRING([--with-llvmgccdir],[Location of LLVM GCC front-end]),AC_SUBST(LLVMGCCDIR,[$withval]))
 491
 492 AC_MSG_CHECKING([for llvm-gcc])
 493 LLVM_GCC_CHECK=no
 494 if test -d "$LLVMGCCDIR"
 495 then
 496         if test -x "$LLVMGCCDIR/bin/gcc"
 497         then
 498                 LLVM_GCC_CHECK="$LLVMGCCDIR/bin/gcc"
 499         fi
 500 fi
 501 llvmgccwarn=no
 502 AC_MSG_RESULT($LLVM_GCC_CHECK)
 503 if test "$LLVM_GCC_CHECK" = "no"
 504 then
 505     llvmgccwarn=yes
 506 fi
 507
 508 AC_MSG_CHECKING([whether llvm-gcc is sane])
 509 LLVM_GCC_SANE=no
 510 if test -x "$LLVM_GCC_CHECK"
 511 then
 512         cp /dev/null conftest.c
 513     "$LLVM_GCC_CHECK" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 514         if test $? -eq 0
 515         then
 516                 LLVM_GCC_SANE=yes
 517         fi
 518         rm conftest.c
 519 fi
 520 AC_MSG_RESULT($LLVM_GCC_SANE)
 521 if test "$LLVM_GCC_SANE" = "no"
 522 then
 523         llvmgccwarn=yes
 524 fi
 525
 526 dnl Location of the bytecode repository
 527 AC_ARG_WITH(bcrepos,AC_HELP_STRING([--with-bcrepos],[Location of Bytecode Repository]),AC_SUBST(BCR,[$withval]),AC_SUBST(BCR,[/home/vadve/lattner/LLVMPrograms]))
 528
 529 dnl Location of PAPI
 530 AC_ARG_WITH(papi,AC_HELP_STRING([--with-papi],[Location of PAPI]),AC_SUBST(PAPIDIR,[$withval]),AC_SUBST(PAPIDIR,[/home/vadve/shared/Sparc/papi-2.3.4.1]))
 531
 532 dnl Location of the purify program
 533 AC_ARG_WITH(purify,AC_HELP_STRING([--with-purify],[Location of purify program]),AC_SUBST(PURIFY,[$withval]))
 534
 535 dnl **************************************************************************
 536 dnl * Configure other software packages (via AC_CONFIG_SUBDIRS)
 537 dnl **************************************************************************
 538
 539 dnl **************************************************************************
 540 dnl * Create the output files
 541 dnl **************************************************************************
 542 AC_OUTPUT(Makefile.config)
 543
 544 if test $llvmgccwarn = yes
 545 then
 546         AC_MSG_WARN([***** llvm C/C++ front end was not found, or does not])
 547         AC_MSG_WARN([***** appear to be working.])
 548         AC_MSG_WARN([***** ])
 549         AC_MSG_WARN([***** Please check configure's --with-llvmgccdir option.])
 550         AC_MSG_WARN([***** Runtime libraries (in llvm/runtime) will not be built,])
 551         AC_MSG_WARN([***** but you should be able to build the llvm tools.])
 552 fi