autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.6svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *)
 179     llvm_cv_link_all_option=""
 180     llvm_cv_no_link_all_option=""
 181     llvm_cv_os_type="Unknown"
 182     llvm_cv_platform_type="Unknown" ;;
 183 esac])
 184
 185 dnl Make sure we aren't attempting to configure for an unknown system
 186 if test "$llvm_cv_os_type" = "Unknown" ; then
 187   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 188 fi
 189
 190 dnl Set the "OS" Makefile variable based on the platform type so the
 191 dnl makefile can configure itself to specific build hosts
 192 AC_SUBST(OS,$llvm_cv_os_type)
 193
 194 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 195 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 196 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 197
 198 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 199 dnl This is used by lib/System to determine the basic kind of implementation
 200 dnl to use.
 201 case $llvm_cv_platform_type in
 202   Unix)
 203     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 204     AC_SUBST(LLVM_ON_UNIX,[1])
 205     AC_SUBST(LLVM_ON_WIN32,[0])
 206     ;;
 207   Win32)
 208     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 209     AC_SUBST(LLVM_ON_UNIX,[0])
 210     AC_SUBST(LLVM_ON_WIN32,[1])
 211     ;;
 212 esac
 213
 214 dnl Determine what our target architecture is and configure accordingly.
 215 dnl This will allow Makefiles to make a distinction between the hardware and
 216 dnl the OS.
 217 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 218 [case $target in
 219   i?86-*)                 llvm_cv_target_arch="x86" ;;
 220   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 221   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 222   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 223   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 224   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 225   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 226   mips-*)                 llvm_cv_target_arch="Mips" ;;
 227   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 228   xcore-*)                llvm_cv_target_arch="XCore" ;;
 229   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 230   *)                      llvm_cv_target_arch="Unknown" ;;
 231 esac])
 232
 233 if test "$llvm_cv_target_arch" = "Unknown" ; then
 234   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 235 fi
 236
 237 # Determine the LLVM native architecture for the target
 238 case "$llvm_cv_target_arch" in
 239     x86)     LLVM_NATIVE_ARCH="X86" ;;
 240     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 241     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 242 esac
 243
 244 dnl Define a substitution, ARCH, for the target architecture
 245 AC_SUBST(ARCH,$llvm_cv_target_arch)
 246
 247 dnl Check for the endianness of the target
 248 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 249
 250 dnl Check for build platform executable suffix if we're crosscompiling
 251 if test "$cross_compiling" = yes; then
 252   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 253   AC_BUILD_EXEEXT
 254   ac_build_prefix=${build_alias}-
 255   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 256   if test -z "$BUILD_CXX"; then
 257      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 258      if test -z "$BUILD_CXX"; then
 259        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 260      fi
 261   fi
 262 else
 263   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 264 fi
 265
 266 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 267 dnl that this build is being done from a checkout. This sets up several
 268 dnl defaults for the command line switches. When we build with a CVS directory,
 269 dnl we get a debug with assertions turned on. Without, we assume a source
 270 dnl release and we get an optimized build without assertions.
 271 dnl See --enable-optimized and --enable-assertions below
 272 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 273   cvsbuild="yes"
 274   optimize="no"
 275   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 276 else
 277   cvsbuild="no"
 278   optimize="yes"
 279 fi
 280
 281 dnl===-----------------------------------------------------------------------===
 282 dnl===
 283 dnl=== SECTION 3: Command line arguments for the configure script.
 284 dnl===
 285 dnl===-----------------------------------------------------------------------===
 286
 287 dnl --enable-optimized : check whether they want to do an optimized build:
 288 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 289  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 290 if test ${enableval} = "no" ; then
 291   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 292 else
 293   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 294 fi
 295
 296 dnl --enable-profiling : check whether they want to do a profile build:
 297 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 298  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 299 if test ${enableval} = "no" ; then
 300   AC_SUBST(ENABLE_PROFILING,[[]])
 301 else
 302   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 303 fi
 304
 305 dnl --enable-assertions : check whether they want to turn on assertions or not:
 306 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 307   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 308 if test ${enableval} = "yes" ; then
 309   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 310 else
 311   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 312 fi
 313
 314 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 315 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 316   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 317 if test ${enableval} = "yes" ; then
 318   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 319   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 320 else
 321   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 322   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 323 fi
 324
 325 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 326 AC_ARG_ENABLE(debug-runtime,
 327    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 328 if test ${enableval} = "no" ; then
 329   AC_SUBST(DEBUG_RUNTIME,[[]])
 330 else
 331   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 332 fi
 333
 334 dnl --enable-jit: check whether they want to enable the jit
 335 AC_ARG_ENABLE(jit,
 336   AS_HELP_STRING(--enable-jit,
 337                  [Enable Just In Time Compiling (default is YES)]),,
 338   enableval=default)
 339 if test ${enableval} = "no"
 340 then
 341   AC_SUBST(JIT,[[]])
 342 else
 343   case "$llvm_cv_target_arch" in
 344     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 345     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 346     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 347     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 348     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 349     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 350     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 351     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 352     PIC16)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 353     XCore)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 354     MSP430)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 355     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 356   esac
 357 fi
 358
 359 dnl Allow enablement of doxygen generated documentation
 360 AC_ARG_ENABLE(doxygen,
 361               AS_HELP_STRING([--enable-doxygen],
 362                              [Build doxygen documentation (default is NO)]),,
 363                              enableval=default)
 364 case "$enableval" in
 365   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 366   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 367   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 368   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 369 esac
 370
 371 dnl Allow disablement of threads
 372 AC_ARG_ENABLE(threads,
 373               AS_HELP_STRING([--enable-threads],
 374                              [Use threads if available (default is YES)]),,
 375                              enableval=default)
 376 case "$enableval" in
 377   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 378   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 379   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 380   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 381 esac
 382 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 383
 384 dnl Allow building without position independent code
 385 AC_ARG_ENABLE(pic,
 386   AS_HELP_STRING([--enable-pic],
 387                  [Build LLVM with Position Independent Code (default is YES)]),,
 388                  enableval=default)
 389 case "$enableval" in
 390   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 391   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 392   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 393   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 394 esac
 395 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 396                    [Define if position independent code is enabled])
 397
 398 dnl Allow specific targets to be specified for building (or not)
 399 TARGETS_TO_BUILD=""
 400 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 401     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 402     enableval=all)
 403 case "$enableval" in
 404   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU PIC16 XCore MSP430 CBackend MSIL CppBackend" ;;
 405   host-only)
 406     case "$llvm_cv_target_arch" in
 407       x86)     TARGETS_TO_BUILD="X86" ;;
 408       x86_64)  TARGETS_TO_BUILD="X86" ;;
 409       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 410       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 411       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 412       IA64)    TARGETS_TO_BUILD="IA64" ;;
 413       ARM)     TARGETS_TO_BUILD="ARM" ;;
 414       Mips)    TARGETS_TO_BUILD="Mips" ;;
 415       CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
 416       PIC16)   TARGETS_TO_BUILD="PIC16" ;;
 417       XCore)   TARGETS_TO_BUILD="XCore" ;;
 418       MSP430)  TARGETS_TO_BUILD="MSP430" ;;
 419       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 420     esac
 421     ;;
 422   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 423       case "$a_target" in
 424         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 425         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 426         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 427         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 428         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 429         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 430         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 431         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 432         spu)     TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 433         pic16)   TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 434         xcore)   TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 435         msp430)  TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 436         cbe)     TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 437         msil)    TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 438         cpp)     TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 439         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 440       esac
 441   done
 442   ;;
 443 esac
 444 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 445
 446 # Determine whether we are building LLVM support for the native architecture.
 447 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 448 for a_target in $TARGETS_TO_BUILD; do
 449   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 450     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 451     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 452       [LLVM architecture name for the native architecture, if available])
 453   fi
 454 done
 455
 456 # Build the LLVM_TARGET and LLVM_ASM_PRINTER macro uses for
 457 # Targets.def and AsmPrinters.def.
 458 LLVM_ENUM_TARGETS=""
 459 LLVM_ENUM_ASM_PRINTERS=""
 460 for target_to_build in $TARGETS_TO_BUILD; do
 461   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 462   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 463     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 464   fi
 465 done
 466 AC_SUBST(LLVM_ENUM_TARGETS)
 467 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 468
 469 dnl Prevent the CBackend from using printf("%a") for floating point so older
 470 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 471 dnl can still compile the CBE's output
 472 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 473   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 474   enableval=default)
 475 case "$enableval" in
 476   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 477   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 478   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 479   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 480 esac
 481 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 482                    [Define if CBE is enabled for printf %a output])
 483
 484 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 485 AC_ARG_WITH(llvmgccdir,
 486   AS_HELP_STRING([--with-llvmgccdir],
 487     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 488     withval=default)
 489 case "$withval" in
 490   default) WITH_LLVMGCCDIR=default ;;
 491   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 492   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 493 esac
 494
 495 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 496 AC_ARG_WITH(llvmgcc,
 497   AS_HELP_STRING([--with-llvmgcc],
 498     [Specify location of llvm-gcc driver (default searches PATH)]),
 499     LLVMGCC=$with_llvmgcc
 500       WITH_LLVMGCCDIR="",)
 501
 502 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 503 AC_ARG_WITH(llvmgxx,
 504   AS_HELP_STRING([--with-llvmgxx],
 505     [Specify location of llvm-g++ driver (default searches PATH)]),
 506     LLVMGXX=$with_llvmgxx
 507     WITH_LLVMGCCDIR="",)
 508
 509 if test -n "$LLVMGCC"; then
 510    LLVMGCCCOMMAND="$LLVMGCC"
 511 fi
 512
 513 if test -n "$LLVMGXX"; then
 514    LLVMGXXCOMMAND="$LLVMGXX"
 515 fi
 516
 517 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 518    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 519 fi
 520
 521 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 522    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 523 fi
 524
 525 dnl Specify extra build options
 526 AC_ARG_WITH(extra-options,
 527   AS_HELP_STRING([--with-extra-options],
 528                  [Specify additional options to compile LLVM with]),,
 529                  withval=default)
 530 case "$withval" in
 531   default) EXTRA_OPTIONS= ;;
 532   *) EXTRA_OPTIONS=$withval ;;
 533 esac
 534 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 535
 536 dnl Allow specific bindings to be specified for building (or not)
 537 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 538     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 539     enableval=default)
 540 BINDINGS_TO_BUILD=""
 541 case "$enableval" in
 542   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 543   all ) BINDINGS_TO_BUILD="ocaml" ;;
 544   none | no) BINDINGS_TO_BUILD="" ;;
 545   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 546       case "$a_binding" in
 547         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 548         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 549       esac
 550   done
 551   ;;
 552 esac
 553
 554 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 555 dnl script for bindings/ocaml/configure, except that its auto value depends on
 556 dnl OCAMLC, which is found here to support tests.
 557 AC_ARG_WITH([ocaml-libdir],
 558   [AS_HELP_STRING([--with-ocaml-libdir],
 559     [Specify install location for ocaml bindings (default is stdlib)])],
 560   [],
 561   [withval=auto])
 562 case "$withval" in
 563   auto) with_ocaml_libdir="$withval" ;;
 564   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 565   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 566 esac
 567
 568 dnl Allow linking of LLVM with GPLv3 binutils code.
 569 AC_ARG_WITH(binutils-include,
 570   AS_HELP_STRING([--with-binutils-include],
 571     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 572   withval=default)
 573 case "$withval" in
 574   default) WITH_BINUTILS_INCDIR=default ;;
 575   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 576   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 577 esac
 578 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 579   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 580   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 581      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 582      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 583   fi
 584 fi
 585
 586 dnl --enable-libffi : check whether the user wants to turn off libffi:
 587 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 588   --enable-libffi,[Check for the presence of libffi (default is YES)]),,
 589   enableval=yes)
 590 case "$enableval" in
 591   yes) llvm_cv_enable_libffi="yes" ;;
 592   no)  llvm_cv_enable_libffi="no"  ;;
 593   *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 594 esac
 595
 596 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 597 if test "$llvm_cv_os_type" = "Win32" ; then
 598    llvmc_dynamic="yes"
 599 else
 600    llvmc_dynamic="no"
 601 fi
 602
 603 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 604 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 605 --enable-llvmc-dynamic,
 606 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 607 enableval=$llvmc_dynamic)
 608 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 609    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 610 else
 611    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 612 fi
 613
 614 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 615 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 616 --enable-llvmc-dynamic-plugins,
 617 [Enable dynamic LLVMC plugins (default is YES)]),,
 618 enableval=yes)
 619 if test ${enableval} = "yes" ; then
 620    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 621 else
 622    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 623 fi
 624
 625 dnl===-----------------------------------------------------------------------===
 626 dnl===
 627 dnl=== SECTION 4: Check for programs we need and that they are the right version
 628 dnl===
 629 dnl===-----------------------------------------------------------------------===
 630
 631 dnl Check for compilation tools
 632 AC_PROG_CPP
 633 AC_PROG_CC(gcc)
 634 AC_PROG_CXX(g++)
 635
 636 AC_PROG_NM
 637 AC_SUBST(NM)
 638
 639 dnl Check for the tools that the makefiles require
 640 AC_CHECK_GNU_MAKE
 641 AC_PROG_LN_S
 642 AC_PATH_PROG(CMP, [cmp], [cmp])
 643 AC_PATH_PROG(CP, [cp], [cp])
 644 AC_PATH_PROG(DATE, [date], [date])
 645 AC_PATH_PROG(FIND, [find], [find])
 646 AC_PATH_PROG(GREP, [grep], [grep])
 647 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 648 AC_PATH_PROG(MV,   [mv],   [mv])
 649 AC_PROG_RANLIB
 650 AC_PATH_PROG(RM,   [rm],   [rm])
 651 AC_PATH_PROG(SED,  [sed],  [sed])
 652 AC_PATH_PROG(TAR,  [tar],  [gtar])
 653 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 654
 655 dnl Looking for misc. graph plotting software
 656 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 657 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 658   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 659   dnl If we're targeting for mingw we should emit windows paths, not msys
 660   if test "$llvm_cv_os_type" = "MingW" ; then
 661     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 662   fi
 663   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 664    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 665 fi
 666 AC_PATH_PROG(DOT, [dot], [echo dot])
 667 if test "$DOT" != "echo dot" ; then
 668   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 669   dnl If we're targeting for mingw we should emit windows paths, not msys
 670   if test "$llvm_cv_os_type" = "MingW" ; then
 671     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 672   fi
 673   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 674    [Define to path to dot program if found or 'echo dot' otherwise])
 675 fi
 676 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 677 if test "$FDP" != "echo fdp" ; then
 678   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 679   dnl If we're targeting for mingw we should emit windows paths, not msys
 680   if test "$llvm_cv_os_type" = "MingW" ; then
 681     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 682   fi
 683   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 684    [Define to path to fdp program if found or 'echo fdp' otherwise])
 685 fi
 686 AC_PATH_PROG(NEATO, [neato], [echo neato])
 687 if test "$NEATO" != "echo neato" ; then
 688   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 689   dnl If we're targeting for mingw we should emit windows paths, not msys
 690   if test "$llvm_cv_os_type" = "MingW" ; then
 691     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 692   fi
 693   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 694    [Define to path to neato program if found or 'echo neato' otherwise])
 695 fi
 696 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 697 if test "$TWOPI" != "echo twopi" ; then
 698   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 699   dnl If we're targeting for mingw we should emit windows paths, not msys
 700   if test "$llvm_cv_os_type" = "MingW" ; then
 701     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 702   fi
 703   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 704    [Define to path to twopi program if found or 'echo twopi' otherwise])
 705 fi
 706 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 707 if test "$CIRCO" != "echo circo" ; then
 708   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 709   dnl If we're targeting for mingw we should emit windows paths, not msys
 710   if test "$llvm_cv_os_type" = "MingW" ; then
 711     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 712   fi
 713   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 714    [Define to path to circo program if found or 'echo circo' otherwise])
 715 fi
 716 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 717 if test "$GV" != "echo gv" ; then
 718   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 719   dnl If we're targeting for mingw we should emit windows paths, not msys
 720   if test "$llvm_cv_os_type" = "MingW" ; then
 721     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 722   fi
 723   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 724    [Define to path to gv program if found or 'echo gv' otherwise])
 725 fi
 726 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 727 if test "$DOTTY" != "echo dotty" ; then
 728   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 729   dnl If we're targeting for mingw we should emit windows paths, not msys
 730   if test "$llvm_cv_os_type" = "MingW" ; then
 731     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 732   fi
 733   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 734    [Define to path to dotty program if found or 'echo dotty' otherwise])
 735 fi
 736
 737 dnl Look for a sufficiently recent version of Perl.
 738 LLVM_PROG_PERL([5.006])
 739 AC_SUBST(PERL)
 740 if test x"$PERL" = xnone; then
 741    AC_SUBST(HAVE_PERL,0)
 742    AC_MSG_ERROR([perl is required but was not found, please install it])
 743 else
 744    AC_SUBST(HAVE_PERL,1)
 745 fi
 746
 747 dnl Find the install program
 748 AC_PROG_INSTALL
 749
 750 dnl Checks for documentation and testing tools that we can do without. If these
 751 dnl are not found then they are set to "true" which always succeeds but does
 752 dnl nothing. This just lets the build output show that we could have done
 753 dnl something if the tool was available.
 754 AC_PATH_PROG(BZIP2, [bzip2])
 755 AC_PATH_PROG(DOXYGEN, [doxygen])
 756 AC_PATH_PROG(GROFF, [groff])
 757 AC_PATH_PROG(GZIP, [gzip])
 758 AC_PATH_PROG(POD2HTML, [pod2html])
 759 AC_PATH_PROG(POD2MAN, [pod2man])
 760 AC_PATH_PROG(RUNTEST, [runtest])
 761 DJ_AC_PATH_TCLSH
 762 AC_PATH_PROG(ZIP, [zip])
 763 AC_PATH_PROGS(OCAMLC, [ocamlc])
 764 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 765 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 766 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 767 AC_PATH_PROGS(GAS, [gas as])
 768
 769 dnl Determine whether the linker supports the -R option.
 770 AC_LINK_USE_R
 771
 772 dnl Determine whether the linker supports the -export-dynamic option.
 773 AC_LINK_EXPORT_DYNAMIC
 774
 775 dnl Check for libtool and the library that has dlopen function (which must come
 776 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 777 dnl libtool).
 778 AC_LIBTOOL_DLOPEN
 779 AC_LIB_LTDL
 780 AC_PROG_LIBTOOL
 781
 782 if test "$lt_cv_dlopen_self" = "yes" ; then
 783   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 784               [Define if dlopen(0) will open the symbols of the program])
 785 fi
 786
 787
 788 if test "$WITH_LLVMGCCDIR" = "default" ; then
 789   LLVMGCC="llvm-gcc${EXEEXT}"
 790   LLVMGXX="llvm-g++${EXEEXT}"
 791   LLVMGCCCOMMAND="$LLVMGCC"
 792   LLVMGXXCOMMAND="$LLVMGXX"
 793   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 794   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 795   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 796   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 797 else
 798   if test -z "$LLVMGCC"; then
 799     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 800     LLVMGCCCOMMAND="$LLVMGCC"
 801   fi
 802   if test -z "$LLVMGXX"; then
 803     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 804     LLVMGXXCOMMAND="$LLVMGXX"
 805   fi
 806
 807   AC_SUBST(LLVMGCC,$LLVMGCC)
 808   AC_SUBST(LLVMGXX,$LLVMGXX)
 809   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 810   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 811 fi
 812
 813
 814 AC_MSG_CHECKING([tool compatibility])
 815
 816 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 817 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 818 dnl to support those options.
 819 dnl "icc" emits gcc signatures
 820 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 821 ICC=no
 822 IXX=no
 823 case $CC in
 824   icc*|icpc*)
 825     ICC=yes
 826     IXX=yes
 827     ;;
 828    *)
 829     ;;
 830 esac
 831
 832 if test "$GCC" != "yes" && test "$ICC" != "yes"
 833 then
 834   AC_MSG_ERROR([gcc|icc required but not found])
 835 fi
 836
 837 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 838 if test "$GXX" != "yes" && test "$IXX" != "yes"
 839 then
 840   AC_MSG_ERROR([g++|icc required but not found])
 841 fi
 842
 843 dnl Verify that GCC is version 3.0 or higher
 844 if test "$GCC" = "yes"
 845 then
 846   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 847 #error Unsupported GCC version
 848 #endif
 849 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 850 fi
 851
 852 dnl Check for GNU Make.  We use its extensions, so don't build without it
 853 if test -z "$llvm_cv_gnu_make_command"
 854 then
 855   AC_MSG_ERROR([GNU Make required but not found])
 856 fi
 857
 858 dnl Tool compatibility is okay if we make it here.
 859 AC_MSG_RESULT([ok])
 860
 861 dnl===-----------------------------------------------------------------------===
 862 dnl===
 863 dnl=== SECTION 5: Check for libraries
 864 dnl===
 865 dnl===-----------------------------------------------------------------------===
 866
 867 dnl libelf is for sparc only; we can ignore it if we don't have it
 868 AC_CHECK_LIB(elf, elf_begin)
 869 AC_CHECK_LIB(m,sin)
 870 if test "$llvm_cv_os_type" = "MingW" ; then
 871   AC_CHECK_LIB(imagehlp, main)
 872   AC_CHECK_LIB(psapi, main)
 873 fi
 874
 875 dnl dlopen() is required for plugin support.
 876 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 877                [Define if dlopen() is available on this platform.]),
 878                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 879
 880 dnl libffi is optional; used to call external functions from the interpreter
 881 if test "$llvm_cv_enable_libffi" = "yes" ; then
 882   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
 883                  [Define if libffi is available on this platform.]),
 884                  AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
 885 fi
 886
 887 dnl mallinfo is optional; the code can compile (minus features) without it
 888 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 889                [Define if mallinfo() is available on this platform.]))
 890
 891 dnl pthread locking functions are optional - but llvm will not be thread-safe
 892 dnl without locks.
 893 if test "$ENABLE_THREADS" -eq 1 ; then
 894   AC_CHECK_LIB(pthread,pthread_mutex_init)
 895   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 896                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 897                            [Have pthread_mutex_lock]))
 898   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
 899                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
 900                  [Have pthread_rwlock_init]))
 901   AC_SEARCH_LIBS(pthread_getspecific,pthread,
 902                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
 903                  [Have pthread_getspecific]))
 904 fi
 905
 906 dnl Allow extra x86-disassembler library
 907 AC_ARG_WITH(udis86,
 908   AS_HELP_STRING([--with-udis86=<path>],
 909     [Use udis86 external x86 disassembler library]),
 910     [
 911       AC_SUBST(USE_UDIS86, [1])
 912       case "$withval" in
 913         /usr/lib|yes) ;;
 914         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 915       esac
 916       AC_CHECK_LIB(udis86, ud_init, [], [
 917         echo "Error! You need to have libudis86 around."
 918         exit -1
 919       ])
 920     ],
 921     AC_SUBST(USE_UDIS86, [0]))
 922 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 923                    [Define if use udis86 library])
 924
 925 dnl Allow OProfile support for JIT output.
 926 AC_ARG_WITH(oprofile,
 927   AS_HELP_STRING([--with-oprofile=<prefix>],
 928     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
 929     [
 930       AC_SUBST(USE_OPROFILE, [1])
 931       case "$withval" in
 932         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
 933         *) llvm_cv_oppath="${withval}/lib/oprofile"
 934            CPPFLAGS="-I${withval}/include";;
 935       esac
 936       LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
 937       AC_SEARCH_LIBS(op_open_agent, opagent, [], [
 938         echo "Error! You need to have libopagent around."
 939         exit -1
 940       ])
 941       AC_CHECK_HEADER([opagent.h], [], [
 942         echo "Error! You need to have opagent.h around."
 943         exit -1
 944       ])
 945     ],
 946     [
 947       llvm_cv_old_LIBS="$LIBS"
 948       LIBS="$LIBS -L/usr/lib/oprofile -Wl,-rpath,/usr/lib/oprofile"
 949       dnl If either the library or header aren't present, omit oprofile support.
 950       AC_SEARCH_LIBS(op_open_agent, opagent,
 951                      [AC_SUBST(USE_OPROFILE, [1])],
 952                      [LIBS="$llvm_cv_old_LIBS"
 953                       AC_SUBST(USE_OPROFILE, [0])])
 954       AC_CHECK_HEADER([opagent.h], [], [
 955         LIBS="$llvm_cv_old_LIBS"
 956         AC_SUBST(USE_OPROFILE, [0])
 957       ])
 958     ])
 959 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
 960                    [Define if we have the oprofile JIT-support library])
 961
 962 dnl===-----------------------------------------------------------------------===
 963 dnl===
 964 dnl=== SECTION 6: Check for header files
 965 dnl===
 966 dnl===-----------------------------------------------------------------------===
 967
 968 dnl First, use autoconf provided macros for specific headers that we need
 969 dnl We don't check for ancient stuff or things that are guaranteed to be there
 970 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 971 dnl Generally we're looking for POSIX headers.
 972 AC_HEADER_DIRENT
 973 AC_HEADER_MMAP_ANONYMOUS
 974 AC_HEADER_STAT
 975 AC_HEADER_STDC
 976 AC_HEADER_SYS_WAIT
 977 AC_HEADER_TIME
 978
 979 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 980 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
 981 AC_CHECK_HEADERS([utime.h windows.h])
 982 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 983 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
 984 if test "$ENABLE_THREADS" -eq 1 ; then
 985   AC_CHECK_HEADERS(pthread.h,
 986                    AC_SUBST(HAVE_PTHREAD, 1),
 987                    AC_SUBST(HAVE_PTHREAD, 0))
 988 else
 989   AC_SUBST(HAVE_PTHREAD, 0)
 990 fi
 991
 992 dnl Try to find ffi.h.
 993 if test "$llvm_cv_enable_libffi" = "yes" ; then
 994   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
 995 fi
 996
 997 dnl===-----------------------------------------------------------------------===
 998 dnl===
 999 dnl=== SECTION 7: Check for types and structures
1000 dnl===
1001 dnl===-----------------------------------------------------------------------===
1002
1003 AC_HUGE_VAL_CHECK
1004 AC_TYPE_PID_T
1005 AC_TYPE_SIZE_T
1006 AC_TYPE_SIGNAL
1007 AC_STRUCT_TM
1008 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1009 AC_CHECK_TYPES([uint64_t],,
1010          AC_CHECK_TYPES([u_int64_t],,
1011          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1012
1013 dnl===-----------------------------------------------------------------------===
1014 dnl===
1015 dnl=== SECTION 8: Check for specific functions needed
1016 dnl===
1017 dnl===-----------------------------------------------------------------------===
1018
1019 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1020 AC_CHECK_FUNCS([powf fmodf strtof round ])
1021 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1022 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1023 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup ])
1024 AC_CHECK_FUNCS([strerror strerror_r strerror_s ])
1025 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1026 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1027 AC_C_PRINTF_A
1028 AC_FUNC_ALLOCA
1029 AC_FUNC_RAND48
1030
1031 dnl Check for variations in the Standard C++ library and STL. These macros are
1032 dnl provided by LLVM in the autoconf/m4 directory.
1033 AC_CXX_HAVE_STD_ITERATOR
1034 AC_CXX_HAVE_BI_ITERATOR
1035 AC_CXX_HAVE_FWD_ITERATOR
1036 AC_FUNC_ISNAN
1037 AC_FUNC_ISINF
1038
1039 dnl Check for mmap support.We also need to know if /dev/zero is required to
1040 dnl be opened for allocating RWX memory.
1041 dnl Make sure we aren't attempting to configure for an unknown system
1042 if test "$llvm_cv_platform_type" = "Unix" ; then
1043   AC_FUNC_MMAP
1044   AC_FUNC_MMAP_FILE
1045   AC_NEED_DEV_ZERO_FOR_MMAP
1046
1047   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1048   then
1049     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1050   fi
1051   if test "$ac_cv_func_mmap_file" = "no"
1052   then
1053     AC_MSG_WARN([mmap() of files required but not found])
1054   fi
1055 fi
1056
1057 dnl atomic builtins are required for threading support.
1058 AC_MSG_CHECKING(for GCC atomic builtins)
1059 AC_LINK_IFELSE(
1060   AC_LANG_SOURCE(
1061     [[int main() {
1062         volatile unsigned long val = 1;
1063         __sync_synchronize();
1064         __sync_val_compare_and_swap(&val, 1, 0);
1065         __sync_add_and_fetch(&val, 1);
1066         __sync_sub_and_fetch(&val, 1);
1067         return 0;
1068       }
1069     ]]),
1070   AC_MSG_RESULT(yes)
1071   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1072   AC_MSG_RESULT(no)
1073   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1074   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1075
1076
1077 dnl===-----------------------------------------------------------------------===
1078 dnl===
1079 dnl=== SECTION 9: Additional checks, variables, etc.
1080 dnl===
1081 dnl===-----------------------------------------------------------------------===
1082
1083 dnl Check, whether __dso_handle is present
1084 AC_CHECK_FUNCS([__dso_handle])
1085
1086 dnl See if the llvm-gcc executable can compile to LLVM assembly
1087 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1088 [llvm_cv_llvmgcc_sanity="no"
1089 if test -x "$LLVMGCC" ; then
1090   cp /dev/null conftest.c
1091   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1092       grep 'target datalayout =' > /dev/null 2>&1
1093   if test $? -eq 0 ; then
1094     llvm_cv_llvmgcc_sanity="yes"
1095   fi
1096   rm conftest.c
1097 fi])
1098
1099 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1100 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1101   AC_MSG_CHECKING([llvm-gcc component support])
1102   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1103   AC_SUBST(LLVMCC1,$llvmcc1path)
1104   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1105   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1106   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1107   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1108   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
1109   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
1110   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
1111   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
1112   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
1113   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
1114   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1115   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1116   AC_MSG_RESULT([ok])
1117 fi
1118
1119 dnl Propagate the shared library extension that the libltdl checks did to
1120 dnl the Makefiles so we can use it there too
1121 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1122
1123 # Translate the various configuration directories and other basic
1124 # information into substitutions that will end up in Makefile.config.in
1125 # that these configured values can be used by the makefiles
1126 if test "${prefix}" = "NONE" ; then
1127   prefix="/usr/local"
1128 fi
1129 eval LLVM_PREFIX="${prefix}";
1130 eval LLVM_BINDIR="${prefix}/bin";
1131 eval LLVM_LIBDIR="${prefix}/lib";
1132 eval LLVM_DATADIR="${prefix}/share/llvm";
1133 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
1134 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1135 eval LLVM_INCLUDEDIR="${prefix}/include";
1136 eval LLVM_INFODIR="${prefix}/info";
1137 eval LLVM_MANDIR="${prefix}/man";
1138 LLVM_CONFIGTIME=`date`
1139 AC_SUBST(LLVM_PREFIX)
1140 AC_SUBST(LLVM_BINDIR)
1141 AC_SUBST(LLVM_LIBDIR)
1142 AC_SUBST(LLVM_DATADIR)
1143 AC_SUBST(LLVM_DOCSDIR)
1144 AC_SUBST(LLVM_ETCDIR)
1145 AC_SUBST(LLVM_INCLUDEDIR)
1146 AC_SUBST(LLVM_INFODIR)
1147 AC_SUBST(LLVM_MANDIR)
1148 AC_SUBST(LLVM_CONFIGTIME)
1149
1150 # Place the various directores into the config.h file as #defines so that we
1151 # can know about the installation paths within LLVM.
1152 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1153                    [Installation prefix directory])
1154 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1155                    [Installation directory for binary executables])
1156 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1157                    [Installation directory for libraries])
1158 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1159                    [Installation directory for data files])
1160 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1161                    [Installation directory for documentation])
1162 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1163                    [Installation directory for config files])
1164 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1165                    [Installation directory for include files])
1166 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1167                    [Installation directory for .info files])
1168 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1169                    [Installation directory for man pages])
1170 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1171                    [Time at which LLVM was configured])
1172 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1173                    [Host triple we were built on])
1174
1175 # Determine which bindings to build.
1176 if test "$BINDINGS_TO_BUILD" = auto ; then
1177   BINDINGS_TO_BUILD=""
1178   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1179     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1180   fi
1181 fi
1182 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1183
1184 # This isn't really configurey, but it avoids having to repeat the list in
1185 # other files.
1186 AC_SUBST(ALL_BINDINGS,ocaml)
1187
1188 # Do any work necessary to ensure that bindings have what they need.
1189 binding_prereqs_failed=0
1190 for a_binding in $BINDINGS_TO_BUILD ; do
1191   case "$a_binding" in
1192   ocaml)
1193     if test "x$OCAMLC" = x ; then
1194       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1195       binding_prereqs_failed=1
1196     fi
1197     if test "x$OCAMLDEP" = x ; then
1198       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1199       binding_prereqs_failed=1
1200     fi
1201     if test "x$OCAMLOPT" = x ; then
1202       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1203       dnl ocamlopt is optional!
1204     fi
1205     if test "x$with_ocaml_libdir" != xauto ; then
1206       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1207     else
1208       ocaml_stdlib="`"$OCAMLC" -where`"
1209       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1210       then
1211         # ocaml stdlib is beneath our prefix; use stdlib
1212         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1213       else
1214         # ocaml stdlib is outside our prefix; use libdir/ocaml
1215         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1216       fi
1217     fi
1218     ;;
1219   esac
1220 done
1221 if test "$binding_prereqs_failed" = 1 ; then
1222   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1223 fi
1224
1225 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1226 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1227
1228 dnl Determine linker rpath flag
1229 if test "$llvm_cv_link_use_r" = "yes" ; then
1230   RPATH="-Wl,-R"
1231 else
1232   RPATH="-Wl,-rpath"
1233 fi
1234 AC_SUBST(RPATH)
1235
1236 dnl Determine linker rdynamic flag
1237 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1238   RDYNAMIC="-Wl,-export-dynamic"
1239 else
1240   RDYNAMIC=""
1241 fi
1242 AC_SUBST(RDYNAMIC)
1243
1244 dnl===-----------------------------------------------------------------------===
1245 dnl===
1246 dnl=== SECTION 10: Specify the output files and generate it
1247 dnl===
1248 dnl===-----------------------------------------------------------------------===
1249
1250 dnl Configure header files
1251 dnl WARNING: dnl If you add or remove any of the following config headers, then
1252 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1253 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1254 dnl files can be updated automatically when their *.in sources change.
1255 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1256 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1257 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1258 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1259 AC_CONFIG_HEADERS([include/llvm/ADT/iterator.h])
1260
1261 dnl Configure the makefile's configuration data
1262 AC_CONFIG_FILES([Makefile.config])
1263
1264 dnl Configure the RPM spec file for LLVM
1265 AC_CONFIG_FILES([llvm.spec])
1266
1267 dnl Configure doxygen's configuration file
1268 AC_CONFIG_FILES([docs/doxygen.cfg])
1269
1270 dnl Configure llvmc's Base plugin
1271 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1272
1273 dnl Do the first stage of configuration for llvm-config.in.
1274 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1275
1276 dnl Do special configuration of Makefiles
1277 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1278 AC_CONFIG_MAKEFILE(Makefile)
1279 AC_CONFIG_MAKEFILE(Makefile.common)
1280 AC_CONFIG_MAKEFILE(examples/Makefile)
1281 AC_CONFIG_MAKEFILE(lib/Makefile)
1282 AC_CONFIG_MAKEFILE(runtime/Makefile)
1283 AC_CONFIG_MAKEFILE(test/Makefile)
1284 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1285 AC_CONFIG_MAKEFILE(unittests/Makefile)
1286 AC_CONFIG_MAKEFILE(tools/Makefile)
1287 AC_CONFIG_MAKEFILE(utils/Makefile)
1288 AC_CONFIG_MAKEFILE(projects/Makefile)
1289 AC_CONFIG_MAKEFILE(bindings/Makefile)
1290 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1291
1292 dnl Finally, crank out the output
1293 AC_OUTPUT