autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34
  35 AC_INIT([LLVM],[3.5.0svn],[http://llvm.org/bugs/])
  36
  37 LLVM_VERSION_MAJOR=3
  38 LLVM_VERSION_MINOR=5
  39 LLVM_VERSION_PATCH=0
  40 LLVM_VERSION_SUFFIX=svn
  41
  42 AC_DEFINE_UNQUOTED([LLVM_VERSION_MAJOR], $LLVM_VERSION_MAJOR, [Major version of the LLVM API])
  43 AC_DEFINE_UNQUOTED([LLVM_VERSION_MINOR], $LLVM_VERSION_MINOR, [Minor version of the LLVM API])
  44 AC_DEFINE_UNQUOTED([LLVM_VERSION_PATCH], $LLVM_VERSION_PATCH, [Patch version of the LLVM API])
  45
  46 AC_SUBST([LLVM_VERSION_MAJOR])
  47 AC_SUBST([LLVM_VERSION_MINOR])
  48 AC_SUBST([LLVM_VERSION_PATCH])
  49 AC_SUBST([LLVM_VERSION_SUFFIX])
  50
  51 dnl Provide a copyright substitution and ensure the copyright notice is included
  52 dnl in the output of --version option of the generated configure script.
  53 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign."])
  54 AC_COPYRIGHT([Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign.])
  55
  56 dnl Indicate that we require autoconf 2.60 or later.
  57 AC_PREREQ(2.60)
  58
  59 dnl Verify that the source directory is valid. This makes sure that we are
  60 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  61 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  62
  63 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  64 dnl various tools where the m4 autoconf macros are.
  65 AC_CONFIG_AUX_DIR([autoconf])
  66
  67 dnl Quit if the source directory has already been configured.
  68 dnl NOTE: This relies upon undocumented autoconf behavior.
  69 if test ${srcdir} != "." ; then
  70   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  71     AC_MSG_ERROR([Already configured in ${srcdir}])
  72   fi
  73 fi
  74
  75 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  76 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  77 : ${CFLAGS=}
  78 : ${CXXFLAGS=}
  79
  80 dnl We need to check for the compiler up here to avoid anything else
  81 dnl starting with a different one.
  82 AC_PROG_CC(clang gcc)
  83 AC_PROG_CXX(clang++ g++)
  84 AC_PROG_CPP
  85
  86 dnl If CXX is Clang, check that it can find and parse C++ standard library
  87 dnl headers.
  88 if test "$CXX" = "clang++" ; then
  89   AC_MSG_CHECKING([whether clang works])
  90   AC_LANG_PUSH([C++])
  91   dnl Note that space between 'include' and '(' is required.  There's a broken
  92   dnl regex in aclocal that otherwise will think that we call m4's include
  93   dnl builtin.
  94   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  95 #if __has_include (<cxxabi.h>)
  96 #include <cxxabi.h>
  97 #endif
  98 #if __has_include (<unwind.h>)
  99 #include <unwind.h>
 100 #endif
 101 ]])],
 102 [
 103   AC_MSG_RESULT([yes])
 104 ],
 105 [
 106   AC_MSG_RESULT([no])
 107   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
 108 ])
 109   AC_LANG_POP([C++])
 110 fi
 111
 112 dnl Set up variables that track whether the host compiler is GCC or Clang where
 113 dnl we can effectively sanity check them. We don't try to sanity check all the
 114 dnl other possible compilers.
 115 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
 116 AC_LANG_PUSH([C++])
 117 llvm_cv_cxx_compiler=unknown
 118 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
 119                                     #error
 120                                     #endif
 121                                     ]])],
 122                   llvm_cv_cxx_compiler=clang,
 123                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
 124                                                        #error
 125                                                        #endif
 126                                                        ]])],
 127                                      llvm_cv_cxx_compiler=gcc, [])])
 128 AC_LANG_POP([C++])
 129 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
 130
 131 dnl Configure all of the projects present in our source tree. While we could
 132 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 133 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 134 dnl Instead we match on the known projects.
 135
 136 dnl
 137 dnl One tricky part of doing this is that some projects depend upon other
 138 dnl projects.  For example, several projects rely upon the LLVM test suite.
 139 dnl We want to configure those projects first so that their object trees are
 140 dnl created before running the configure scripts of projects that depend upon
 141 dnl them.
 142 dnl
 143
 144 dnl Several projects use the LLVM test suite, so configure it next.
 145 if test -d ${srcdir}/projects/test-suite ; then
 146   AC_CONFIG_SUBDIRS([projects/test-suite])
 147 fi
 148
 149 dnl llvm-test is the old name of the test-suite, kept here for backwards
 150 dnl compatibility
 151 if test -d ${srcdir}/projects/llvm-test ; then
 152   AC_CONFIG_SUBDIRS([projects/llvm-test])
 153 fi
 154
 155 dnl Some projects use poolalloc; configure that next
 156 if test -d ${srcdir}/projects/poolalloc ; then
 157   AC_CONFIG_SUBDIRS([projects/poolalloc])
 158 fi
 159
 160 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 161   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 162 fi
 163
 164 dnl Check for all other projects
 165 for i in `ls ${srcdir}/projects`
 166 do
 167   if test -d ${srcdir}/projects/${i} ; then
 168     case ${i} in
 169       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 170       compiler-rt)       ;;
 171       test-suite)     ;;
 172       llvm-test)      ;;
 173       poolalloc)      ;;
 174       llvm-poolalloc) ;;
 175       *)
 176         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 177         ;;
 178     esac
 179   fi
 180 done
 181
 182 dnl Disable the build of polly, even if it is checked out into tools/polly.
 183 AC_ARG_ENABLE(polly,
 184               AS_HELP_STRING([--enable-polly],
 185                              [Use polly if available (default is YES)]),,
 186                              enableval=default)
 187 case "$enableval" in
 188   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 189   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 190   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 191   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 192 esac
 193
 194
 195 dnl Check if polly is checked out into tools/polly and configure it if
 196 dnl available.
 197 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 198   AC_SUBST(LLVM_HAS_POLLY,1)
 199   AC_CONFIG_SUBDIRS([tools/polly])
 200 fi
 201
 202 dnl===-----------------------------------------------------------------------===
 203 dnl===
 204 dnl=== SECTION 2: Architecture, target, and host checks
 205 dnl===
 206 dnl===-----------------------------------------------------------------------===
 207
 208 dnl Check the target for which we're compiling and the host that will do the
 209 dnl compilations. This will tell us which LLVM compiler will be used for
 210 dnl compiling SSA into object code. This needs to be done early because
 211 dnl following tests depend on it.
 212 AC_CANONICAL_TARGET
 213
 214 dnl Determine the platform type and cache its value. This helps us configure
 215 dnl the System library to the correct build platform.
 216 AC_CACHE_CHECK([type of operating system we're going to host on],
 217                [llvm_cv_os_type],
 218 [case $host in
 219   *-*-aix*)
 220     llvm_cv_link_all_option="-Wl,--whole-archive"
 221     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 222     llvm_cv_os_type="AIX"
 223     llvm_cv_platform_type="Unix" ;;
 224   *-*-irix*)
 225     llvm_cv_link_all_option="-Wl,--whole-archive"
 226     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 227     llvm_cv_os_type="IRIX"
 228     llvm_cv_platform_type="Unix" ;;
 229   *-*-cygwin*)
 230     llvm_cv_link_all_option="-Wl,--whole-archive"
 231     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 232     llvm_cv_os_type="Cygwin"
 233     llvm_cv_platform_type="Unix" ;;
 234   *-*-darwin*)
 235     llvm_cv_link_all_option="-Wl,-all_load"
 236     llvm_cv_no_link_all_option="-Wl,-noall_load"
 237     llvm_cv_os_type="Darwin"
 238     llvm_cv_platform_type="Unix" ;;
 239   *-*-minix*)
 240     llvm_cv_link_all_option="-Wl,-all_load"
 241     llvm_cv_no_link_all_option="-Wl,-noall_load"
 242     llvm_cv_os_type="Minix"
 243     llvm_cv_platform_type="Unix" ;;
 244   *-*-freebsd*)
 245     llvm_cv_link_all_option="-Wl,--whole-archive"
 246     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 247     llvm_cv_os_type="FreeBSD"
 248     llvm_cv_platform_type="Unix" ;;
 249   *-*-kfreebsd-gnu)
 250     llvm_cv_link_all_option="-Wl,--whole-archive"
 251     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 252     llvm_cv_os_type="GNU/kFreeBSD"
 253     llvm_cv_platform_type="Unix" ;;
 254   *-*-openbsd*)
 255     llvm_cv_link_all_option="-Wl,--whole-archive"
 256     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 257     llvm_cv_os_type="OpenBSD"
 258     llvm_cv_platform_type="Unix" ;;
 259   *-*-netbsd*)
 260     llvm_cv_link_all_option="-Wl,--whole-archive"
 261     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 262     llvm_cv_os_type="NetBSD"
 263     llvm_cv_platform_type="Unix" ;;
 264   *-*-dragonfly*)
 265     llvm_cv_link_all_option="-Wl,--whole-archive"
 266     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 267     llvm_cv_os_type="DragonFly"
 268     llvm_cv_platform_type="Unix" ;;
 269   *-*-hpux*)
 270     llvm_cv_link_all_option="-Wl,--whole-archive"
 271     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 272     llvm_cv_os_type="HP-UX"
 273     llvm_cv_platform_type="Unix" ;;
 274   *-*-interix*)
 275     llvm_cv_link_all_option="-Wl,--whole-archive"
 276     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 277     llvm_cv_os_type="Interix"
 278     llvm_cv_platform_type="Unix" ;;
 279   *-*-linux*)
 280     llvm_cv_link_all_option="-Wl,--whole-archive"
 281     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 282     llvm_cv_os_type="Linux"
 283     llvm_cv_platform_type="Unix" ;;
 284   *-*-gnu*)
 285     llvm_cv_link_all_option="-Wl,--whole-archive"
 286     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 287     llvm_cv_os_type="GNU"
 288     llvm_cv_platform_type="Unix" ;;
 289   *-*-solaris*)
 290     llvm_cv_link_all_option="-Wl,-z,allextract"
 291     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 292     llvm_cv_os_type="SunOS"
 293     llvm_cv_platform_type="Unix" ;;
 294   *-*-auroraux*)
 295     llvm_cv_link_all_option="-Wl,-z,allextract"
 296     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 297     llvm_cv_os_type="AuroraUX"
 298     llvm_cv_platform_type="Unix" ;;
 299   *-*-win32*)
 300     llvm_cv_link_all_option="-Wl,--whole-archive"
 301     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 302     llvm_cv_os_type="Win32"
 303     llvm_cv_platform_type="Win32" ;;
 304   *-*-mingw*)
 305     llvm_cv_link_all_option="-Wl,--whole-archive"
 306     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 307     llvm_cv_os_type="MingW"
 308     llvm_cv_platform_type="Win32" ;;
 309   *-*-haiku*)
 310     llvm_cv_link_all_option="-Wl,--whole-archive"
 311     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 312     llvm_cv_os_type="Haiku"
 313     llvm_cv_platform_type="Unix" ;;
 314   *-unknown-eabi*)
 315     llvm_cv_link_all_option="-Wl,--whole-archive"
 316     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 317     llvm_cv_os_type="Freestanding"
 318     llvm_cv_platform_type="Unix" ;;
 319   *-unknown-elf*)
 320     llvm_cv_link_all_option="-Wl,--whole-archive"
 321     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 322     llvm_cv_os_type="Freestanding"
 323     llvm_cv_platform_type="Unix" ;;
 324   *)
 325     llvm_cv_link_all_option=""
 326     llvm_cv_no_link_all_option=""
 327     llvm_cv_os_type="Unknown"
 328     llvm_cv_platform_type="Unknown" ;;
 329 esac])
 330
 331 AC_CACHE_CHECK([type of operating system we're going to target],
 332                [llvm_cv_target_os_type],
 333 [case $target in
 334   *-*-aix*)
 335     llvm_cv_target_os_type="AIX" ;;
 336   *-*-irix*)
 337     llvm_cv_target_os_type="IRIX" ;;
 338   *-*-cygwin*)
 339     llvm_cv_target_os_type="Cygwin" ;;
 340   *-*-darwin*)
 341     llvm_cv_target_os_type="Darwin" ;;
 342   *-*-minix*)
 343     llvm_cv_target_os_type="Minix" ;;
 344   *-*-freebsd*)
 345     llvm_cv_target_os_type="FreeBSD" ;;
 346   *-*-kfreebsd-gnu)
 347     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 348   *-*-openbsd*)
 349     llvm_cv_target_os_type="OpenBSD" ;;
 350   *-*-netbsd*)
 351     llvm_cv_target_os_type="NetBSD" ;;
 352   *-*-dragonfly*)
 353     llvm_cv_target_os_type="DragonFly" ;;
 354   *-*-hpux*)
 355     llvm_cv_target_os_type="HP-UX" ;;
 356   *-*-interix*)
 357     llvm_cv_target_os_type="Interix" ;;
 358   *-*-linux*)
 359     llvm_cv_target_os_type="Linux" ;;
 360   *-*-gnu*)
 361     llvm_cv_target_os_type="GNU" ;;
 362   *-*-solaris*)
 363     llvm_cv_target_os_type="SunOS" ;;
 364   *-*-auroraux*)
 365     llvm_cv_target_os_type="AuroraUX" ;;
 366   *-*-win32*)
 367     llvm_cv_target_os_type="Win32" ;;
 368   *-*-mingw*)
 369     llvm_cv_target_os_type="MingW" ;;
 370   *-*-haiku*)
 371     llvm_cv_target_os_type="Haiku" ;;
 372   *-*-rtems*)
 373     llvm_cv_target_os_type="RTEMS" ;;
 374   *-*-nacl*)
 375     llvm_cv_target_os_type="NativeClient" ;;
 376   *-unknown-eabi*)
 377     llvm_cv_target_os_type="Freestanding" ;;
 378   *)
 379     llvm_cv_target_os_type="Unknown" ;;
 380 esac])
 381
 382 dnl Make sure we aren't attempting to configure for an unknown system
 383 if test "$llvm_cv_os_type" = "Unknown" ; then
 384   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 385 fi
 386
 387 dnl Set the "OS" Makefile variable based on the platform type so the
 388 dnl makefile can configure itself to specific build hosts
 389 AC_SUBST(OS,$llvm_cv_os_type)
 390 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 391 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 392
 393 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 394 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 395 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 396
 397 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 398 dnl This is used by lib/Support to determine the basic kind of implementation
 399 dnl to use.
 400 case $llvm_cv_platform_type in
 401   Unix)
 402     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 403     AC_SUBST(LLVM_ON_UNIX,[1])
 404     AC_SUBST(LLVM_ON_WIN32,[0])
 405     ;;
 406   Win32)
 407     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 408     AC_SUBST(LLVM_ON_UNIX,[0])
 409     AC_SUBST(LLVM_ON_WIN32,[1])
 410     ;;
 411 esac
 412
 413 dnl Determine what our target architecture is and configure accordingly.
 414 dnl This will allow Makefiles to make a distinction between the hardware and
 415 dnl the OS.
 416 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 417 [case $target in
 418   i?86-*)                 llvm_cv_target_arch="x86" ;;
 419   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 420   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 421   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 422   arm64*-*)               llvm_cv_target_arch="ARM64" ;;
 423   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 424   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 425   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 426   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 427   xcore-*)                llvm_cv_target_arch="XCore" ;;
 428   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 429   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 430   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 431   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 432   *)                      llvm_cv_target_arch="Unknown" ;;
 433 esac])
 434
 435 if test "$llvm_cv_target_arch" = "Unknown" ; then
 436   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 437 fi
 438
 439 dnl Determine the LLVM native architecture for the target
 440 case "$llvm_cv_target_arch" in
 441     x86)     LLVM_NATIVE_ARCH="X86" ;;
 442     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 443     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 444 esac
 445
 446 dnl Define a substitution, ARCH, for the target architecture
 447 AC_SUBST(ARCH,$llvm_cv_target_arch)
 448 AC_SUBST(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCH)
 449
 450 dnl Determine what our host architecture.
 451 dnl This will allow MCJIT regress tests runs only for supported
 452 dnl platforms.
 453 case $host in
 454   i?86-*)                 host_arch="x86" ;;
 455   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 456   sparc*-*)               host_arch="Sparc" ;;
 457   powerpc*-*)             host_arch="PowerPC" ;;
 458   arm64*-*)               host_arch="ARM64" ;;
 459   arm*-*)                 host_arch="ARM" ;;
 460   aarch64*-*)             host_arch="AArch64" ;;
 461   mips-* | mips64-*)      host_arch="Mips" ;;
 462   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 463   xcore-*)                host_arch="XCore" ;;
 464   msp430-*)               host_arch="MSP430" ;;
 465   hexagon-*)              host_arch="Hexagon" ;;
 466   s390x-*)                host_arch="SystemZ" ;;
 467   *)                      host_arch="Unknown" ;;
 468 esac
 469
 470 if test "$host_arch" = "Unknown" ; then
 471   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 472 fi
 473
 474 AC_SUBST(HOST_ARCH,$host_arch)
 475
 476 dnl Check for build platform executable suffix if we're cross-compiling
 477 if test "$cross_compiling" = yes; then
 478   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 479   AC_BUILD_EXEEXT
 480   ac_build_prefix=${build_alias}-
 481   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 482   if test -z "$BUILD_CXX"; then
 483      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 484      if test -z "$BUILD_CXX"; then
 485        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 486      fi
 487   fi
 488 else
 489   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 490 fi
 491
 492 dnl Check to see if there's a .svn or .git directory indicating that this
 493 dnl build is being done from a checkout. This sets up several defaults for
 494 dnl the command line switches. When we build with a checkout directory,
 495 dnl we get a debug with assertions turned on. Without, we assume a source
 496 dnl release and we get an optimized build without assertions.
 497 dnl See --enable-optimized and --enable-assertions below
 498 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 499   cvsbuild="yes"
 500   optimize="no"
 501   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 502 else
 503   cvsbuild="no"
 504   optimize="yes"
 505 fi
 506
 507 dnl===-----------------------------------------------------------------------===
 508 dnl===
 509 dnl=== SECTION 3: Command line arguments for the configure script.
 510 dnl===
 511 dnl===-----------------------------------------------------------------------===
 512
 513 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 514 AC_ARG_ENABLE(libcpp,
 515               AS_HELP_STRING([--enable-libcpp],
 516                              [Use libc++ if available (default is NO)]),,
 517                              enableval=default)
 518 case "$enableval" in
 519   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 520   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 521   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 522   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 523 esac
 524
 525 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
 526 dnl be bypassed by passing a flag if necessary on a platform. We have to do
 527 dnl these checks here so that we have the configuration of the standard C++
 528 dnl library finished.
 529 AC_ARG_ENABLE(compiler-version-checks,
 530               AS_HELP_STRING([--enable-compiler-version-checks],
 531                              [Check the version of the host compiler (default is YES)]),,
 532                              enableval=default)
 533 case "$enableval" in
 534   no)
 535     ;;
 536   yes|default)
 537     AC_LANG_PUSH([C++])
 538     case "$llvm_cv_cxx_compiler" in
 539     clang)
 540       AC_MSG_CHECKING([whether Clang is new enough])
 541       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 542 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
 543 #error This version of Clang is too old to build LLVM
 544 #endif
 545 ]])],
 546           [AC_MSG_RESULT([yes])],
 547           [AC_MSG_RESULT([no])
 548            AC_MSG_ERROR([
 549 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
 550 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
 551 bypass these sanity checks.])])
 552
 553       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
 554       dnl are sometimes deeply confusing though. Here we test for an obvious
 555       dnl incomplete feature in 4.6's standard library that was completed in
 556       dnl 4.7's. We also have to disable this test if 'ENABLE_LIBCPP' is set
 557       dnl because the enable flags don't actually fix CXXFLAGS, they rely on
 558       dnl that happening in the Makefile.
 559       if test "$ENABLE_LIBCPP" -eq 0 ; then
 560         AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
 561         llvm_cv_old_cxxflags="$CXXFLAGS"
 562         CXXFLAGS="$CXXFLAGS -std=c++0x"
 563         AC_LINK_IFELSE([AC_LANG_SOURCE([[
 564 #include <atomic>
 565 std::atomic<float> x(0.0f);
 566 int main() { return (float)x; }
 567 ]])],
 568             [AC_MSG_RESULT([yes])],
 569             [AC_MSG_RESULT([no])
 570              AC_MSG_ERROR([
 571 We detected a missing feature in the standard C++ library that was known to be
 572 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
 573 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
 574 than 4.7. You will need to update your system and ensure Clang uses the newer
 575 standard library.
 576
 577 If this error is incorrect or you need to force things to work, you may pass
 578 '--disable-compiler-version-checks' to configure to bypass this test.])])
 579         CXXFLAGS="$llvm_cv_old_cxxflags"
 580       fi
 581       ;;
 582     gcc)
 583       AC_MSG_CHECKING([whether GCC is new enough])
 584       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 585 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 586 #error This version of GCC is too old to build LLVM
 587 #endif
 588 ]])],
 589           [AC_MSG_RESULT([yes])],
 590           [AC_MSG_RESULT([no])
 591            AC_MSG_ERROR([
 592 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
 593 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
 594 bypass these sanity checks.])])
 595       ;;
 596     unknown)
 597       ;;
 598     esac
 599     AC_LANG_POP([C++])
 600     ;;
 601   *)
 602     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
 603     ;;
 604 esac
 605
 606 dnl --enable-cxx1y : check whether or not to use -std=c++1y on the command line
 607 AC_ARG_ENABLE(cxx1y,
 608               AS_HELP_STRING([--enable-cxx1y],
 609                              [Use c++1y if available (default is NO)]),,
 610                              enableval=default)
 611 case "$enableval" in
 612   yes) AC_SUBST(ENABLE_CXX1Y,[1]) ;;
 613   no)  AC_SUBST(ENABLE_CXX1Y,[0]) ;;
 614   default) AC_SUBST(ENABLE_CXX1Y,[0]);;
 615   *) AC_MSG_ERROR([Invalid setting for --enable-cxx1y. Use "yes" or "no"]) ;;
 616 esac
 617
 618 dnl --enable-split-dwarf : check whether or not to use -gsplit-dwarf on the command
 619 dnl line
 620 AC_ARG_ENABLE(split-dwarf,
 621               AS_HELP_STRING([--enable-split-dwarf],
 622                              [Use split-dwarf if available (default is NO)]),,
 623                              enableval=default)
 624 case "$enableval" in
 625   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 626   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 627   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 628   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 629 esac
 630
 631 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 632 clang_arcmt="yes"
 633 AC_ARG_ENABLE(clang-arcmt,
 634               AS_HELP_STRING([--enable-clang-arcmt],
 635                              [Enable building of clang ARCMT (default is YES)]),
 636                              clang_arcmt="$enableval",
 637                              enableval="yes")
 638 case "$enableval" in
 639   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 640   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 641   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 642   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 643 esac
 644
 645 dnl --enable-clang-plugin-support: check whether to enable plugins in clang
 646 clang_plugin_support="yes"
 647 AC_ARG_ENABLE(clang-plugin-support,
 648               AS_HELP_STRING([--enable-clang-plugin-support],
 649                              [Enable plugin support in clang (default is YES)]),
 650                              clang_plugin_support="$enableval",
 651                              enableval="yes")
 652 case "$enableval" in
 653   yes) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]) ;;
 654   no)  AC_SUBST(CLANG_PLUGIN_SUPPORT,[0]) ;;
 655   default) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]);;
 656   *) AC_MSG_ERROR([Invalid setting for --enable-clang-plugin-support. Use "yes" or "no"]) ;;
 657 esac
 658
 659 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 660 clang_static_analyzer="yes"
 661 AC_ARG_ENABLE(clang-static-analyzer,
 662               AS_HELP_STRING([--enable-clang-static-analyzer],
 663                              [Enable building of clang Static Analyzer (default is YES)]),
 664                              clang_static_analyzer="$enableval",
 665                              enableval="yes")
 666 case "$enableval" in
 667   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 668   no)
 669     if test ${clang_arcmt} != "no" ; then
 670       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 671     fi
 672     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 673     ;;
 674   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 675   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 676 esac
 677
 678 dnl --enable-clang-rewriter: check whether to enable clang rewriter
 679 AC_ARG_ENABLE(clang-rewriter,
 680               AS_HELP_STRING([--enable-clang-rewriter],
 681                              [Enable building of clang rewriter (default is YES)]),,
 682                              enableval="yes")
 683 case "$enableval" in
 684   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
 685   no)
 686     if test ${clang_arcmt} != "no" ; then
 687       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
 688     fi
 689     if test ${clang_static_analyzer} != "no" ; then
 690       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
 691     fi
 692     AC_SUBST(ENABLE_CLANG_REWRITER,[0])
 693     ;;
 694   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
 695   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
 696 esac
 697
 698 dnl --enable-optimized : check whether they want to do an optimized build:
 699 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 700  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 701 if test ${enableval} = "no" ; then
 702   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 703 else
 704   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 705 fi
 706
 707 dnl --enable-profiling : check whether they want to do a profile build:
 708 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 709  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 710 if test ${enableval} = "no" ; then
 711   AC_SUBST(ENABLE_PROFILING,[[]])
 712 else
 713   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 714 fi
 715
 716 dnl --enable-assertions : check whether they want to turn on assertions or not:
 717 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 718   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 719 if test ${enableval} = "yes" ; then
 720   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 721 else
 722   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 723 fi
 724
 725 dnl --enable-werror : check whether we want Werror on by default
 726 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 727   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 728 case "$enableval" in
 729   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 730   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 731   default) AC_SUBST(ENABLE_WERROR,[0]);;
 732   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 733 esac
 734
 735 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 736 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 737   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 738 if test ${enableval} = "yes" ; then
 739   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 740   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 741 else
 742   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 743   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 744 fi
 745
 746 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 747 AC_ARG_ENABLE(debug-runtime,
 748    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 749 if test ${enableval} = "no" ; then
 750   AC_SUBST(DEBUG_RUNTIME,[[]])
 751 else
 752   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 753 fi
 754
 755 dnl --enable-debug-symbols : should even optimized compiler libraries
 756 dnl have debug symbols?
 757 AC_ARG_ENABLE(debug-symbols,
 758    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 759 if test ${enableval} = "no" ; then
 760   AC_SUBST(DEBUG_SYMBOLS,[[]])
 761 else
 762   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 763 fi
 764
 765 dnl --enable-keep-symbols : do not strip installed executables
 766 AC_ARG_ENABLE(keep-symbols,
 767    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 768 if test ${enableval} = "no" ; then
 769   AC_SUBST(KEEP_SYMBOLS,[[]])
 770 else
 771   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 772 fi
 773
 774 dnl --enable-jit: check whether they want to enable the jit
 775 AC_ARG_ENABLE(jit,
 776   AS_HELP_STRING(--enable-jit,
 777                  [Enable Just In Time Compiling (default is YES)]),,
 778   enableval=default)
 779 if test ${enableval} = "no"
 780 then
 781   AC_SUBST(JIT,[[]])
 782 else
 783   case "$llvm_cv_target_arch" in
 784     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 785     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 786     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 787     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 788     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 789     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 790     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 791     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 792     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 793     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 794     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 795     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 796     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 797   esac
 798 fi
 799
 800 TARGETS_WITH_JIT="AArch64 ARM ARM64 Mips PowerPC SystemZ X86"
 801 AC_SUBST(TARGETS_WITH_JIT,$TARGETS_WITH_JIT)
 802
 803 dnl Allow enablement of building and installing docs
 804 AC_ARG_ENABLE(docs,
 805               AS_HELP_STRING([--enable-docs],
 806                              [Build documents (default is YES)]),,
 807                              enableval=default)
 808 case "$enableval" in
 809   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 810   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 811   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 812   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 813 esac
 814
 815 dnl Allow enablement of doxygen generated documentation
 816 AC_ARG_ENABLE(doxygen,
 817               AS_HELP_STRING([--enable-doxygen],
 818                              [Build doxygen documentation (default is NO)]),,
 819                              enableval=default)
 820 case "$enableval" in
 821   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 822   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 823   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 824   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 825 esac
 826
 827 dnl Allow disablement of threads
 828 AC_ARG_ENABLE(threads,
 829               AS_HELP_STRING([--enable-threads],
 830                              [Use threads if available (default is YES)]),,
 831                              enableval=default)
 832 case "$enableval" in
 833   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 834   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 835   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 836   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 837 esac
 838 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 839                    [Define if threads enabled])
 840
 841 dnl Allow disablement of pthread.h
 842 AC_ARG_ENABLE(pthreads,
 843               AS_HELP_STRING([--enable-pthreads],
 844                              [Use pthreads if available (default is YES)]),,
 845                              enableval=default)
 846 case "$enableval" in
 847   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 848   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 849   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 850   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 851 esac
 852
 853 dnl Allow disablement of zlib
 854 AC_ARG_ENABLE(zlib,
 855               AS_HELP_STRING([--enable-zlib],
 856                              [Use zlib for compression/decompression if
 857                               available (default is YES)]),,
 858                               enableval=default)
 859 case "$enableval" in
 860   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 861   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 862   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 863   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 864 esac
 865 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 866                    [Define if zlib is enabled])
 867
 868 dnl Allow building without position independent code
 869 AC_ARG_ENABLE(pic,
 870   AS_HELP_STRING([--enable-pic],
 871                  [Build LLVM with Position Independent Code (default is YES)]),,
 872                  enableval=default)
 873 case "$enableval" in
 874   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 875   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 876   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 877   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 878 esac
 879 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 880                    [Define if position independent code is enabled])
 881
 882 dnl Allow building a shared library and linking tools against it.
 883 AC_ARG_ENABLE(shared,
 884   AS_HELP_STRING([--enable-shared],
 885                  [Build a shared library and link tools against it (default is NO)]),,
 886                  enableval=default)
 887 case "$enableval" in
 888   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 889   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 890   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 891   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 892 esac
 893
 894 dnl Allow libstdc++ is embedded in LLVM.dll.
 895 AC_ARG_ENABLE(embed-stdcxx,
 896   AS_HELP_STRING([--enable-embed-stdcxx],
 897                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 898                  enableval=default)
 899 case "$enableval" in
 900   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 901   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 902   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 903   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 904 esac
 905
 906 dnl Enable embedding timestamp information into build.
 907 AC_ARG_ENABLE(timestamps,
 908   AS_HELP_STRING([--enable-timestamps],
 909                  [Enable embedding timestamp information in build (default is YES)]),,
 910                  enableval=default)
 911 case "$enableval" in
 912   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 913   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 914   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 915   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 916 esac
 917 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 918                    [Define if timestamp information (e.g., __DATE__) is allowed])
 919
 920 dnl Enable support for showing backtraces.
 921 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
 922   [--enable-backtraces],
 923   [Enable embedding backtraces on crash (default is YES)]),
 924   [case "$enableval" in
 925     yes) llvm_cv_enable_backtraces="yes" ;;
 926     no)  llvm_cv_enable_backtraces="no"  ;;
 927     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 928   esac],
 929   llvm_cv_enable_backtraces="yes")
 930 if test "$llvm_cv_enable_backtraces" = "yes" ; then
 931   AC_DEFINE([ENABLE_BACKTRACES],[1],
 932             [Define if you want backtraces on crash])
 933 fi
 934
 935 dnl Enable installing platform specific signal handling overrides, for improved
 936 dnl CrashRecovery support or interaction with crash reporting software. This
 937 dnl support may be inappropriate for some clients embedding LLVM as a library.
 938 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
 939   [--enable-crash-overrides],
 940   [Enable crash handling overrides (default is YES)]),
 941   [case "$enableval" in
 942     yes) llvm_cv_enable_crash_overrides="yes" ;;
 943     no)  llvm_cv_enable_crash_overrides="no"  ;;
 944     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
 945   esac],
 946   llvm_cv_enable_crash_overrides="yes")
 947 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
 948   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
 949             [Define to enable crash handling overrides])
 950 fi
 951
 952 dnl List all possible targets
 953 ALL_TARGETS="X86 Sparc PowerPC AArch64 ARM ARM64 Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600"
 954 AC_SUBST(ALL_TARGETS,$ALL_TARGETS)
 955
 956 dnl Allow specific targets to be specified for building (or not)
 957 TARGETS_TO_BUILD=""
 958 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 959     [Build specific host targets: all or target1,target2,... Valid targets are:
 960      host, x86, x86_64, sparc, powerpc, arm64, arm, aarch64, mips, hexagon,
 961      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
 962     enableval=all)
 963 if test "$enableval" = host-only ; then
 964   enableval=host
 965 fi
 966 case "$enableval" in
 967   all) TARGETS_TO_BUILD="$ALL_TARGETS" ;;
 968   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 969       case "$a_target" in
 970         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 971         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 972         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 973         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 974         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 975         arm64)    TARGETS_TO_BUILD="ARM64 $TARGETS_TO_BUILD" ;;
 976         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 977         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 978         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 979         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 980         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 981         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 982         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 983         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 984         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 985         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 986         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 987         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
 988         host) case "$llvm_cv_target_arch" in
 989             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 990             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 991             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 992             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 993             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 994             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 995             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 996             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 997             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 998             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 999             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
1000             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
1001             *)       AC_MSG_ERROR([Can not set target to build]) ;;
1002           esac ;;
1003         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
1004       esac
1005   done
1006   ;;
1007 esac
1008
1009 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
1010     [Build experimental host targets: disable or target1,target2,...
1011      (default=disable)]),,
1012     enableval=disable)
1013
1014 if test ${enableval} != "disable"
1015 then
1016   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
1017 fi
1018
1019 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
1020
1021 dnl Determine whether we are building LLVM support for the native architecture.
1022 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
1023 for a_target in $TARGETS_TO_BUILD; do
1024   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
1025     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
1026       [LLVM architecture name for the native architecture, if available])
1027     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
1028     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
1029     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
1030     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
1031     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1032       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
1033     fi
1034     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1035       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
1036     fi
1037     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
1038       [LLVM name for the native Target init function, if available])
1039     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
1040       [LLVM name for the native TargetInfo init function, if available])
1041     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
1042       [LLVM name for the native target MC init function, if available])
1043     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1044       [LLVM name for the native AsmPrinter init function, if available])
1045     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1046       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1047        [LLVM name for the native AsmParser init function, if available])
1048     fi
1049     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1050       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1051        [LLVM name for the native Disassembler init function, if available])
1052     fi
1053   fi
1054 done
1055
1056 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1057 dnl target feature def files.
1058 LLVM_ENUM_TARGETS=""
1059 LLVM_ENUM_ASM_PRINTERS=""
1060 LLVM_ENUM_ASM_PARSERS=""
1061 LLVM_ENUM_DISASSEMBLERS=""
1062 for target_to_build in $TARGETS_TO_BUILD; do
1063   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1064   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1065     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1066   fi
1067   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1068     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1069   fi
1070   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1071     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1072   fi
1073 done
1074 AC_SUBST(LLVM_ENUM_TARGETS)
1075 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1076 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1077 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1078
1079 dnl Override the option to use for optimized builds.
1080 AC_ARG_WITH(optimize-option,
1081   AS_HELP_STRING([--with-optimize-option],
1082                  [Select the compiler options to use for optimized builds]),,
1083                  withval=default)
1084 AC_MSG_CHECKING([optimization flags])
1085 case "$withval" in
1086   default)
1087     case "$llvm_cv_os_type" in
1088     FreeBSD) optimize_option=-O2 ;;
1089     MingW) optimize_option=-O2 ;;
1090     *)     optimize_option=-O3 ;;
1091     esac ;;
1092   *) optimize_option="$withval" ;;
1093 esac
1094 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1095 AC_MSG_RESULT([$optimize_option])
1096
1097 dnl Specify extra build options
1098 AC_ARG_WITH(extra-options,
1099   AS_HELP_STRING([--with-extra-options],
1100                  [Specify additional options to compile LLVM with]),,
1101                  withval=default)
1102 case "$withval" in
1103   default) EXTRA_OPTIONS= ;;
1104   *) EXTRA_OPTIONS=$withval ;;
1105 esac
1106 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1107
1108 dnl Specify extra linker build options
1109 AC_ARG_WITH(extra-ld-options,
1110   AS_HELP_STRING([--with-extra-ld-options],
1111                  [Specify additional options to link LLVM with]),,
1112                  withval=default)
1113 case "$withval" in
1114   default) EXTRA_LD_OPTIONS= ;;
1115   *) EXTRA_LD_OPTIONS=$withval ;;
1116 esac
1117 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1118
1119 dnl Allow specific bindings to be specified for building (or not)
1120 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1121     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1122     enableval=default)
1123 BINDINGS_TO_BUILD=""
1124 case "$enableval" in
1125   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1126   all ) BINDINGS_TO_BUILD="ocaml" ;;
1127   none | no) BINDINGS_TO_BUILD="" ;;
1128   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1129       case "$a_binding" in
1130         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1131         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1132       esac
1133   done
1134   ;;
1135 esac
1136
1137 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1138 dnl script for bindings/ocaml/configure, except that its auto value depends on
1139 dnl OCAMLC, which is found here to support tests.
1140 AC_ARG_WITH([ocaml-libdir],
1141   [AS_HELP_STRING([--with-ocaml-libdir],
1142     [Specify install location for ocaml bindings (default is stdlib)])],
1143   [],
1144   [withval=auto])
1145 case "$withval" in
1146   auto) with_ocaml_libdir="$withval" ;;
1147   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1148   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1149 esac
1150
1151 AC_ARG_WITH(clang-srcdir,
1152   AS_HELP_STRING([--with-clang-srcdir],
1153     [Directory to the out-of-tree Clang source]),,
1154     withval="-")
1155 case "$withval" in
1156   -) clang_src_root="" ;;
1157   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1158   *) clang_src_root="$ac_pwd/$withval" ;;
1159 esac
1160 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1161
1162 AC_ARG_WITH(clang-resource-dir,
1163   AS_HELP_STRING([--with-clang-resource-dir],
1164     [Relative directory from the Clang binary for resource files]),,
1165     withval="")
1166 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1167                    [Relative directory for resource files])
1168
1169 AC_ARG_WITH(c-include-dirs,
1170   AS_HELP_STRING([--with-c-include-dirs],
1171     [Colon separated list of directories clang will search for headers]),,
1172     withval="")
1173 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1174                    [Directories clang will search for headers])
1175
1176 # Clang normally uses the system c++ headers and libraries. With this option,
1177 # clang will use the ones provided by a gcc installation instead. This option should
1178 # be passed the same value that was used with --prefix when configuring gcc.
1179 AC_ARG_WITH(gcc-toolchain,
1180   AS_HELP_STRING([--with-gcc-toolchain],
1181     [Directory where gcc is installed.]),,
1182     withval="")
1183 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1184                    [Directory where gcc is installed.])
1185
1186 AC_ARG_WITH(default-sysroot,
1187   AS_HELP_STRING([--with-default-sysroot],
1188     [Add --sysroot=<path> to all compiler invocations.]),,
1189     withval="")
1190 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1191                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1192
1193 dnl Allow linking of LLVM with GPLv3 binutils code.
1194 AC_ARG_WITH(binutils-include,
1195   AS_HELP_STRING([--with-binutils-include],
1196     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1197   withval=default)
1198 case "$withval" in
1199   default) WITH_BINUTILS_INCDIR=default ;;
1200   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1201   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1202 esac
1203 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1204   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1205   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1206      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1207      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1208   fi
1209 fi
1210
1211 dnl Specify the URL where bug reports should be submitted.
1212 AC_ARG_WITH(bug-report-url,
1213   AS_HELP_STRING([--with-bug-report-url],
1214     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1215     withval="http://llvm.org/bugs/")
1216 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1217                    [Bug report URL.])
1218
1219 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1220 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1221   [--enable-terminfo],
1222   [Query the terminfo database if available (default is YES)]),
1223   [case "$enableval" in
1224     yes) llvm_cv_enable_terminfo="yes" ;;
1225     no)  llvm_cv_enable_terminfo="no"  ;;
1226     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1227   esac],
1228   llvm_cv_enable_terminfo="yes")
1229 case "$llvm_cv_enable_terminfo" in
1230   yes) AC_SUBST(ENABLE_TERMINFO,[1]) ;;
1231   no)  AC_SUBST(ENABLE_TERMINFO,[0]) ;;
1232 esac
1233
1234 dnl --enable-libedit: check whether the user wants to turn off libedit.
1235 AC_ARG_ENABLE(libedit,AS_HELP_STRING(
1236   [--enable-libedit],
1237   [Use libedit if available (default is YES)]),
1238   [case "$enableval" in
1239     yes) llvm_cv_enable_libedit="yes" ;;
1240     no)  llvm_cv_enable_libedit="no"  ;;
1241     *) AC_MSG_ERROR([Invalid setting for --enable-libedit. Use "yes" or "no"]) ;;
1242   esac],
1243   llvm_cv_enable_libedit="yes")
1244
1245 dnl --enable-libffi : check whether the user wants to turn off libffi:
1246 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1247   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1248   [case "$enableval" in
1249     yes) llvm_cv_enable_libffi="yes" ;;
1250     no)  llvm_cv_enable_libffi="no"  ;;
1251     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1252   esac],
1253   llvm_cv_enable_libffi=no)
1254
1255 AC_ARG_WITH(internal-prefix,
1256   AS_HELP_STRING([--with-internal-prefix],
1257     [Installation directory for internal files]),,
1258     withval="")
1259 AC_SUBST(INTERNAL_PREFIX,[$withval])
1260
1261 dnl===-----------------------------------------------------------------------===
1262 dnl===
1263 dnl=== SECTION 4: Check for programs we need and that they are the right version
1264 dnl===
1265 dnl===-----------------------------------------------------------------------===
1266
1267 dnl Check for the tools that the makefiles require
1268 AC_CHECK_GNU_MAKE
1269 AC_PROG_LN_S
1270 AC_PATH_PROG(NM, [nm], [nm])
1271 AC_PATH_PROG(CMP, [cmp], [cmp])
1272 AC_PATH_PROG(CP, [cp], [cp])
1273 AC_PATH_PROG(DATE, [date], [date])
1274 AC_PATH_PROG(FIND, [find], [find])
1275 AC_PATH_PROG(GREP, [grep], [grep])
1276 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1277 AC_PATH_PROG(MV,   [mv],   [mv])
1278 AC_PROG_RANLIB
1279 AC_CHECK_TOOL(AR, ar, false)
1280 AC_PATH_PROG(RM,   [rm],   [rm])
1281 AC_PATH_PROG(SED,  [sed],  [sed])
1282 AC_PATH_PROG(TAR,  [tar],  [gtar])
1283 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1284
1285 dnl Looking for misc. graph plotting software
1286 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
1287 if test "$GRAPHVIZ" != "echo Graphviz" ; then
1288   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
1289   dnl If we're targeting for mingw we should emit windows paths, not msys
1290   if test "$llvm_cv_os_type" = "MingW" ; then
1291     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1292   fi
1293   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1294    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1295 fi
1296 AC_PATH_PROG(DOT, [dot], [echo dot])
1297 if test "$DOT" != "echo dot" ; then
1298   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1299   dnl If we're targeting for mingw we should emit windows paths, not msys
1300   if test "$llvm_cv_os_type" = "MingW" ; then
1301     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1302   fi
1303   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1304    [Define to path to dot program if found or 'echo dot' otherwise])
1305 fi
1306 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1307 if test "$FDP" != "echo fdp" ; then
1308   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1309   dnl If we're targeting for mingw we should emit windows paths, not msys
1310   if test "$llvm_cv_os_type" = "MingW" ; then
1311     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1312   fi
1313   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1314    [Define to path to fdp program if found or 'echo fdp' otherwise])
1315 fi
1316 AC_PATH_PROG(NEATO, [neato], [echo neato])
1317 if test "$NEATO" != "echo neato" ; then
1318   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1319   dnl If we're targeting for mingw we should emit windows paths, not msys
1320   if test "$llvm_cv_os_type" = "MingW" ; then
1321     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1322   fi
1323   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1324    [Define to path to neato program if found or 'echo neato' otherwise])
1325 fi
1326 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1327 if test "$TWOPI" != "echo twopi" ; then
1328   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1329   dnl If we're targeting for mingw we should emit windows paths, not msys
1330   if test "$llvm_cv_os_type" = "MingW" ; then
1331     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1332   fi
1333   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1334    [Define to path to twopi program if found or 'echo twopi' otherwise])
1335 fi
1336 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1337 if test "$CIRCO" != "echo circo" ; then
1338   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1339   dnl If we're targeting for mingw we should emit windows paths, not msys
1340   if test "$llvm_cv_os_type" = "MingW" ; then
1341     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1342   fi
1343   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1344    [Define to path to circo program if found or 'echo circo' otherwise])
1345 fi
1346 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1347 if test "$GV" != "echo gv" ; then
1348   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1349   dnl If we're targeting for mingw we should emit windows paths, not msys
1350   if test "$llvm_cv_os_type" = "MingW" ; then
1351     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1352   fi
1353   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1354    [Define to path to gv program if found or 'echo gv' otherwise])
1355 fi
1356 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1357 if test "$DOTTY" != "echo dotty" ; then
1358   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1359   dnl If we're targeting for mingw we should emit windows paths, not msys
1360   if test "$llvm_cv_os_type" = "MingW" ; then
1361     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1362   fi
1363   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1364    [Define to path to dotty program if found or 'echo dotty' otherwise])
1365 fi
1366 AC_PATH_PROGS(XDOT, [xdot xdot.py], [echo xdot])
1367 if test "$XDOT" != "echo xdot" ; then
1368   AC_DEFINE([HAVE_XDOT],[1],[Define if the xdot program is available])
1369   dnl If we're targeting for mingw we should emit windows paths, not msys
1370   if test "$llvm_cv_os_type" = "MingW" ; then
1371     XDOT=`echo $XDOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1372   fi
1373   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT],"$XDOT${EXEEXT}",
1374    [Define to path to xdot program if found or 'echo xdot' otherwise])
1375 fi
1376
1377 dnl Find the install program
1378 AC_PROG_INSTALL
1379 dnl Prepend src dir to install path dir if it's a relative path
1380 dnl This is a hack for installs that take place in something other
1381 dnl than the top level.
1382 case "$INSTALL" in
1383  [[\\/$]]* | ?:[[\\/]]* ) ;;
1384  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1385 esac
1386
1387 dnl Checks for documentation and testing tools that we can do without. If these
1388 dnl are not found then they are set to "true" which always succeeds but does
1389 dnl nothing. This just lets the build output show that we could have done
1390 dnl something if the tool was available.
1391 AC_PATH_PROG(BZIP2, [bzip2])
1392 AC_PATH_PROG(CAT, [cat])
1393 AC_PATH_PROG(DOXYGEN, [doxygen])
1394 AC_PATH_PROG(GROFF, [groff])
1395 AC_PATH_PROG(GZIPBIN, [gzip])
1396 AC_PATH_PROG(PDFROFF, [pdfroff])
1397 AC_PATH_PROG(ZIP, [zip])
1398 AC_PATH_PROGS(OCAMLC, [ocamlc])
1399 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1400 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1401 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1402 AC_PATH_PROGS(GAS, [gas as])
1403
1404 dnl Get the version of the linker in use.
1405 AC_LINK_GET_VERSION
1406
1407 dnl Determine whether the linker supports the -R option.
1408 AC_LINK_USE_R
1409
1410 dnl Determine whether the compiler supports the -rdynamic option.
1411 AC_LINK_EXPORT_DYNAMIC
1412
1413 dnl Determine whether the linker supports the --version-script option.
1414 AC_LINK_VERSION_SCRIPT
1415
1416 AC_CHECK_HEADERS([errno.h])
1417
1418 case "$llvm_cv_os_type" in
1419   Cygwin|MingW|Win32) llvm_shlib_ext=.dll ;;
1420   Darwin) llvm_shlib_ext=.dylib ;;
1421   *) llvm_shlib_ext=.so ;;
1422 esac
1423
1424 AC_DEFINE_UNQUOTED([LTDL_SHLIB_EXT], ["$llvm_shlib_ext"], [The shared library extension])
1425
1426 AC_MSG_CHECKING([tool compatibility])
1427
1428 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1429 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1430 dnl to support those options.
1431 dnl "icc" emits gcc signatures
1432 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1433 ICC=no
1434 IXX=no
1435 case $CC in
1436   icc*|icpc*)
1437     ICC=yes
1438     IXX=yes
1439     ;;
1440    *)
1441     ;;
1442 esac
1443
1444 if test "$GCC" != "yes" && test "$ICC" != "yes"
1445 then
1446   AC_MSG_ERROR([gcc|icc required but not found])
1447 fi
1448
1449 dnl Ensure that compilation tools are compatible with GCC extensions
1450 if test "$GXX" != "yes" && test "$IXX" != "yes"
1451 then
1452   AC_MSG_ERROR([g++|clang++|icc required but not found])
1453 fi
1454
1455 dnl Verify that GCC is version 3.0 or higher
1456 if test "$GCC" = "yes"
1457 then
1458   AC_COMPILE_IFELSE(
1459 [
1460   AC_LANG_SOURCE([[
1461     #if !defined(__GNUC__) || __GNUC__ < 3
1462     #error Unsupported GCC version
1463     #endif
1464   ]])
1465 ],
1466 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1467 fi
1468
1469 dnl Check for GNU Make.  We use its extensions, so don't build without it
1470 if test -z "$llvm_cv_gnu_make_command"
1471 then
1472   AC_MSG_ERROR([GNU Make required but not found])
1473 fi
1474
1475 dnl Tool compatibility is okay if we make it here.
1476 AC_MSG_RESULT([ok])
1477
1478 dnl Check optional compiler flags.
1479 AC_MSG_CHECKING([optional compiler flags])
1480 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1481 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1482 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1483
1484 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1485 dnl false positives, so disable it.
1486 NO_UNINITIALIZED=
1487 NO_MAYBE_UNINITIALIZED=
1488 if test "$GXX" = "yes"
1489 then
1490   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1491   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1492   dnl known to be uninitialized from cases which might be uninitialized.  We
1493   dnl still want to catch the first kind of errors.
1494   if test -z "$NO_MAYBE_UNINITIALIZED"
1495   then
1496     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1497   fi
1498 fi
1499 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1500
1501 AC_ARG_WITH([python],
1502             [AS_HELP_STRING([--with-python], [path to python])],
1503             [PYTHON="$withval"])
1504
1505 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1506   AC_MSG_CHECKING([for python])
1507   AC_MSG_RESULT([user defined: $with_python])
1508 else
1509   if test -n "$PYTHON" ; then
1510     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1511   fi
1512
1513   AC_PATH_PROG([PYTHON], [python python2 python26],
1514                [AC_MSG_RESULT([not found])
1515                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1516 fi
1517
1518 AC_MSG_CHECKING([for python >= 2.5])
1519 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1520 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1521 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1522 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1523 if test "$ac_python_version_major" -gt "2" || \
1524    (test "$ac_python_version_major" -eq "2" && \
1525     test "$ac_python_version_minor" -ge "5") ; then
1526   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1527 else
1528   AC_MSG_RESULT([not found])
1529   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1530 fi
1531
1532 dnl===-----------------------------------------------------------------------===
1533 dnl===
1534 dnl=== SECTION 5: Check for libraries
1535 dnl===
1536 dnl===-----------------------------------------------------------------------===
1537
1538 AC_CHECK_LIB(m,sin)
1539 if test "$llvm_cv_os_type" = "MingW" ; then
1540   AC_CHECK_LIB(imagehlp, main)
1541   AC_CHECK_LIB(psapi, main)
1542   AC_CHECK_LIB(shell32, main)
1543 fi
1544
1545 dnl dlopen() is required for plugin support.
1546 AC_SEARCH_LIBS(dlopen,dl,LLVM_DEFINE_SUBST([HAVE_DLOPEN],[1],
1547                [Define if dlopen() is available on this platform.]),
1548                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1549
1550 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1551 dnl macros to detect whether clock_gettime is available, this just finds the
1552 dnl right libraries to link with.
1553 AC_SEARCH_LIBS(clock_gettime,rt)
1554
1555 dnl The curses library is optional; used for querying terminal info
1556 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1557   dnl We need the has_color functionality in curses for it to be useful.
1558   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1559                  LLVM_DEFINE_SUBST([HAVE_TERMINFO],[1],
1560                                    [Define if the setupterm() function is supported this platform.]))
1561 fi
1562
1563 dnl The libedit library is optional; used by lib/LineEditor
1564 if test "$llvm_cv_enable_libedit" = "yes" ; then
1565   AC_SEARCH_LIBS(el_init,edit,
1566                  AC_DEFINE([HAVE_LIBEDIT],[1],
1567                            [Define if libedit is available on this platform.]))
1568 fi
1569
1570 dnl libffi is optional; used to call external functions from the interpreter
1571 if test "$llvm_cv_enable_libffi" = "yes" ; then
1572   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1573                  [Define if libffi is available on this platform.]),
1574                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1575 fi
1576
1577 dnl mallinfo is optional; the code can compile (minus features) without it
1578 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1579                [Define if mallinfo() is available on this platform.]))
1580
1581 dnl pthread locking functions are optional - but llvm will not be thread-safe
1582 dnl without locks.
1583 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1584   AC_CHECK_LIB(pthread, pthread_mutex_init)
1585   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1586                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1587                            [Have pthread_mutex_lock]))
1588   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1589                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1590                  [Have pthread_rwlock_init]))
1591   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1592                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1593                  [Have pthread_getspecific]))
1594 fi
1595
1596 dnl zlib is optional; used for compression/uncompression
1597 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1598   AC_CHECK_LIB(z, compress2)
1599 fi
1600
1601 dnl Allow extra x86-disassembler library
1602 AC_ARG_WITH(udis86,
1603   AS_HELP_STRING([--with-udis86=<path>],
1604     [Use udis86 external x86 disassembler library]),
1605     [
1606       AC_SUBST(USE_UDIS86, [1])
1607       case "$withval" in
1608         /usr/lib|yes) ;;
1609         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1610       esac
1611       AC_CHECK_LIB(udis86, ud_init, [], [
1612         echo "Error! You need to have libudis86 around."
1613         exit -1
1614       ])
1615     ],
1616     AC_SUBST(USE_UDIS86, [0]))
1617 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1618                    [Define if use udis86 library])
1619
1620 dnl Allow OProfile support for JIT output.
1621 AC_ARG_WITH(oprofile,
1622   AS_HELP_STRING([--with-oprofile=<prefix>],
1623     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1624     [
1625       AC_SUBST(USE_OPROFILE, [1])
1626       case "$withval" in
1627         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1628         no) llvm_cv_oppath=
1629             AC_SUBST(USE_OPROFILE, [0]) ;;
1630         *) llvm_cv_oppath="${withval}/lib/oprofile"
1631            CPPFLAGS="-I${withval}/include";;
1632       esac
1633       case $llvm_cv_os_type in
1634         Linux)
1635           if test -n "$llvm_cv_oppath" ; then
1636             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1637             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1638             dnl libbfd is not included properly in libopagent in some Debian
1639             dnl versions.  If libbfd isn't found at all, we assume opagent works
1640             dnl anyway.
1641             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1642             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1643               echo "Error! You need to have libopagent around."
1644               exit -1
1645             ])
1646             AC_CHECK_HEADER([opagent.h], [], [
1647               echo "Error! You need to have opagent.h around."
1648               exit -1
1649               ])
1650           fi ;;
1651         *)
1652           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1653       esac
1654     ],
1655     [
1656       AC_SUBST(USE_OPROFILE, [0])
1657     ])
1658 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1659                    [Define if we have the oprofile JIT-support library])
1660
1661 dnl Enable support for Intel JIT Events API.
1662 AC_ARG_WITH(intel-jitevents,
1663   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1664     [
1665        case "$withval" in
1666           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1667           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1668           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1669        esac
1670
1671       case $llvm_cv_os_type in
1672         Linux|Win32|Cygwin|MingW) ;;
1673         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1674       esac
1675
1676       case "$llvm_cv_target_arch" in
1677         x86|x86_64) ;;
1678         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1679       esac
1680     ],
1681     [
1682       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1683     ])
1684 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1685                    [Define if we have the Intel JIT API runtime support library])
1686
1687 dnl Check for libxml2
1688 dnl Right now we're just checking for the existence, we could also check for a
1689 dnl particular version via --version on xml2-config
1690 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1691
1692 AC_MSG_CHECKING(for libxml2 includes)
1693 if test "x$XML2CONFIG" = "x"; then
1694  AC_MSG_RESULT(xml2-config not found)
1695 else
1696  LIBXML2_INC=`$XML2CONFIG --cflags`
1697  AC_MSG_RESULT($LIBXML2_INC)
1698  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1699                                 LIBXML2_LIBS="-lxml2"])
1700 fi
1701 AC_SUBST(LIBXML2_LIBS)
1702 AC_SUBST(LIBXML2_INC)
1703
1704 dnl===-----------------------------------------------------------------------===
1705 dnl===
1706 dnl=== SECTION 6: Check for header files
1707 dnl===
1708 dnl===-----------------------------------------------------------------------===
1709
1710 dnl First, use autoconf provided macros for specific headers that we need
1711 dnl We don't check for ancient stuff or things that are guaranteed to be there
1712 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1713 dnl Generally we're looking for POSIX headers.
1714 AC_HEADER_DIRENT
1715 AC_HEADER_MMAP_ANONYMOUS
1716 AC_HEADER_STAT
1717 AC_HEADER_SYS_WAIT
1718 AC_HEADER_TIME
1719
1720 AC_LANG_PUSH([C++])
1721 AC_CHECK_HEADERS([cxxabi.h])
1722 AC_LANG_POP([C++])
1723 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1724 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1725 AC_CHECK_HEADERS([utime.h])
1726 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1727 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1728 AC_CHECK_HEADERS([valgrind/valgrind.h])
1729 AC_CHECK_HEADERS([fenv.h])
1730 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1731 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1732   AC_CHECK_HEADERS(pthread.h,
1733                    AC_SUBST(HAVE_PTHREAD, 1),
1734                    AC_SUBST(HAVE_PTHREAD, 0))
1735 else
1736   AC_SUBST(HAVE_PTHREAD, 0)
1737 fi
1738 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1739   AC_CHECK_HEADERS(zlib.h,
1740                    AC_SUBST(HAVE_LIBZ, 1),
1741                    AC_SUBST(HAVE_LIBZ, 0))
1742 else
1743   AC_SUBST(HAVE_LIBZ, 0)
1744 fi
1745
1746 dnl Try to find ffi.h.
1747 if test "$llvm_cv_enable_libffi" = "yes" ; then
1748   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1749 fi
1750
1751 dnl Try to find Darwin specific crash reporting libraries.
1752 AC_CHECK_HEADERS([CrashReporterClient.h])
1753
1754 dnl Try to find Darwin specific crash reporting global.
1755 AC_MSG_CHECKING([__crashreporter_info__])
1756 AC_LINK_IFELSE(
1757 [
1758   AC_LANG_SOURCE([[
1759     extern const char *__crashreporter_info__;
1760     int main() {
1761       __crashreporter_info__ = "test";
1762       return 0;
1763     }
1764   ]])
1765 ],
1766 [
1767   AC_MSG_RESULT([yes])
1768   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1769 ],
1770 [
1771   AC_MSG_RESULT([no])
1772   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1773 ])
1774
1775 dnl===-----------------------------------------------------------------------===
1776 dnl===
1777 dnl=== SECTION 7: Check for types and structures
1778 dnl===
1779 dnl===-----------------------------------------------------------------------===
1780
1781 AC_HUGE_VAL_CHECK
1782 AC_TYPE_PID_T
1783 AC_TYPE_SIZE_T
1784 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1785 AC_STRUCT_TM
1786 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1787 AC_CHECK_TYPES([uint64_t],,
1788          AC_CHECK_TYPES([u_int64_t],,
1789          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1790
1791 dnl===-----------------------------------------------------------------------===
1792 dnl===
1793 dnl=== SECTION 8: Check for specific functions needed
1794 dnl===
1795 dnl===-----------------------------------------------------------------------===
1796
1797 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1798 AC_CHECK_FUNCS([powf fmodf strtof round ])
1799 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1800 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1801 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1802 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1803 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1804 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1805 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1806 AC_CHECK_FUNCS([futimes futimens])
1807 AC_C_PRINTF_A
1808 AC_FUNC_RAND48
1809
1810 dnl Check for arc4random accessible via AC_INCLUDES_DEFAULT.
1811 AC_CHECK_DECLS([arc4random])
1812
1813 dnl Check the declaration "Secure API" on Windows environments.
1814 AC_CHECK_DECLS([strerror_s])
1815
1816 dnl Check symbols in libgcc.a for JIT on Mingw.
1817 if test "$llvm_cv_os_type" = "MingW" ; then
1818   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1819   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1820   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1821   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1822
1823   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1824   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1825   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1826   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1827   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1828   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1829   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1830   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1831   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1832   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1833
1834   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1835   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1836 fi
1837
1838 dnl Check Win32 API EnumerateLoadedModules.
1839 if test "$llvm_cv_os_type" = "MingW" ; then
1840   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1841   AC_COMPILE_IFELSE(
1842 [
1843   AC_LANG_SOURCE([[
1844     #include <windows.h>
1845     #include <imagehlp.h>
1846     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1847     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1848   ]])
1849 ],
1850 [
1851   AC_MSG_RESULT([yes])
1852   llvm_cv_win32_elmcb_pcstr="PCSTR"
1853 ],
1854 [
1855   AC_MSG_RESULT([no])
1856   llvm_cv_win32_elmcb_pcstr="PSTR"
1857 ])
1858   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1859 fi
1860
1861 dnl Check for variations in the Standard C++ library and STL. These macros are
1862 dnl provided by LLVM in the autoconf/m4 directory.
1863 AC_FUNC_ISNAN
1864 AC_FUNC_ISINF
1865
1866 dnl Check for mmap support.We also need to know if /dev/zero is required to
1867 dnl be opened for allocating RWX memory.
1868 dnl Make sure we aren't attempting to configure for an unknown system
1869 if test "$llvm_cv_platform_type" = "Unix" ; then
1870   AC_FUNC_MMAP
1871   AC_FUNC_MMAP_FILE
1872   AC_NEED_DEV_ZERO_FOR_MMAP
1873
1874   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1875   then
1876     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1877   fi
1878   if test "$ac_cv_func_mmap_file" = "no"
1879   then
1880     AC_MSG_WARN([mmap() of files required but not found])
1881   fi
1882 fi
1883
1884 dnl atomic builtins are required for threading support.
1885 AC_MSG_CHECKING(for GCC atomic builtins)
1886 dnl Since we'll be using these atomic builtins in C++ files we should test
1887 dnl the C++ compiler.
1888 AC_LANG_PUSH([C++])
1889 AC_LINK_IFELSE(
1890 [
1891   AC_LANG_SOURCE([[
1892     int main() {
1893       volatile unsigned long val = 1;
1894       __sync_synchronize();
1895       __sync_val_compare_and_swap(&val, 1, 0);
1896       __sync_add_and_fetch(&val, 1);
1897       __sync_sub_and_fetch(&val, 1);
1898       return 0;
1899     }
1900   ]])
1901 ],
1902 [
1903   AC_MSG_RESULT([yes])
1904   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1905 ],
1906 [
1907   AC_MSG_RESULT([no])
1908   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1909   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1910 ])
1911 AC_LANG_POP([C++])
1912
1913 dnl===-----------------------------------------------------------------------===
1914 dnl===
1915 dnl=== SECTION 9: Additional checks, variables, etc.
1916 dnl===
1917 dnl===-----------------------------------------------------------------------===
1918
1919 dnl Handle 32-bit linux systems running a 64-bit kernel.
1920 dnl This has to come after section 4 because it invokes the compiler.
1921 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1922   AC_IS_LINUX_MIXED
1923   if test "$llvm_cv_linux_mixed" = "yes"; then
1924     llvm_cv_target_arch="x86"
1925     ARCH="x86"
1926   fi
1927 fi
1928
1929 dnl Check whether __dso_handle is present
1930 AC_CHECK_FUNCS([__dso_handle])
1931
1932 dnl Propagate the shared library extension that the libltdl checks did to
1933 dnl the Makefiles so we can use it there too
1934 AC_SUBST(SHLIBEXT,$llvm_shlib_ext)
1935
1936 dnl Translate the various configuration directories and other basic
1937 dnl information into substitutions that will end up in Makefile.config.in
1938 dnl that these configured values can be used by the makefiles
1939 if test "${prefix}" = "NONE" ; then
1940   prefix="/usr/local"
1941 fi
1942 eval LLVM_PREFIX="${prefix}";
1943 eval LLVM_BINDIR="${prefix}/bin";
1944 eval LLVM_DATADIR="${prefix}/share/llvm";
1945 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1946 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1947 eval LLVM_INCLUDEDIR="${prefix}/include";
1948 eval LLVM_INFODIR="${prefix}/info";
1949 eval LLVM_MANDIR="${prefix}/man";
1950 LLVM_CONFIGTIME=`date`
1951 AC_SUBST(LLVM_PREFIX)
1952 AC_SUBST(LLVM_BINDIR)
1953 AC_SUBST(LLVM_DATADIR)
1954 AC_SUBST(LLVM_DOCSDIR)
1955 AC_SUBST(LLVM_ETCDIR)
1956 AC_SUBST(LLVM_INCLUDEDIR)
1957 AC_SUBST(LLVM_INFODIR)
1958 AC_SUBST(LLVM_MANDIR)
1959 AC_SUBST(LLVM_CONFIGTIME)
1960
1961 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1962 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1963   LLVM_CONFIGTIME="(timestamp not enabled)"
1964 fi
1965
1966 dnl Place the various directories into the config.h file as #defines so that we
1967 dnl can know about the installation paths within LLVM.
1968 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1969                    [Installation prefix directory])
1970 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1971                    [Installation directory for binary executables])
1972 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1973                    [Installation directory for data files])
1974 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1975                    [Installation directory for documentation])
1976 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1977                    [Installation directory for config files])
1978 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1979                    [Installation directory for include files])
1980 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1981                    [Installation directory for .info files])
1982 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1983                    [Installation directory for man pages])
1984 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1985                    [Time at which LLVM was configured])
1986 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
1987                    [Host triple LLVM will be executed on])
1988 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1989                    [Target triple LLVM will generate code for by default])
1990
1991 dnl Determine which bindings to build.
1992 if test "$BINDINGS_TO_BUILD" = auto ; then
1993   BINDINGS_TO_BUILD=""
1994   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1995     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1996   fi
1997 fi
1998 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1999
2000 dnl This isn't really configurey, but it avoids having to repeat the list in
2001 dnl other files.
2002 AC_SUBST(ALL_BINDINGS,ocaml)
2003
2004 dnl Do any work necessary to ensure that bindings have what they need.
2005 binding_prereqs_failed=0
2006 for a_binding in $BINDINGS_TO_BUILD ; do
2007   case "$a_binding" in
2008   ocaml)
2009     if test "x$OCAMLC" = x ; then
2010       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
2011       binding_prereqs_failed=1
2012     fi
2013     if test "x$OCAMLDEP" = x ; then
2014       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
2015       binding_prereqs_failed=1
2016     fi
2017     if test "x$OCAMLOPT" = x ; then
2018       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
2019       dnl ocamlopt is optional!
2020     fi
2021     if test "x$with_ocaml_libdir" != xauto ; then
2022       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
2023     else
2024       ocaml_stdlib="`"$OCAMLC" -where`"
2025       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
2026       then
2027         # ocaml stdlib is beneath our prefix; use stdlib
2028         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
2029       else
2030         # ocaml stdlib is outside our prefix; use libdir/ocaml
2031         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
2032       fi
2033     fi
2034     ;;
2035   esac
2036 done
2037 if test "$binding_prereqs_failed" = 1 ; then
2038   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
2039 fi
2040
2041 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
2042 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
2043
2044 dnl Determine linker rpath flag
2045 if test "$llvm_cv_link_use_r" = "yes" ; then
2046   RPATH="-Wl,-R"
2047 else
2048   RPATH="-Wl,-rpath"
2049 fi
2050 AC_SUBST(RPATH)
2051
2052 dnl Determine linker rdynamic flag
2053 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
2054   RDYNAMIC="-rdynamic"
2055 else
2056   RDYNAMIC=""
2057 fi
2058 AC_SUBST(RDYNAMIC)
2059
2060 dnl===-----------------------------------------------------------------------===
2061 dnl===
2062 dnl=== SECTION 10: Specify the output files and generate it
2063 dnl===
2064 dnl===-----------------------------------------------------------------------===
2065
2066 dnl Configure header files
2067 dnl WARNING: dnl If you add or remove any of the following config headers, then
2068 dnl you MUST also update Makefile so that the variable FilesToConfig
2069 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
2070 dnl files can be updated automatically when their *.in sources change.
2071 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
2072 AH_TOP([#ifndef CONFIG_H
2073 #define CONFIG_H])
2074 AH_BOTTOM([#endif])
2075
2076 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
2077 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
2078 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
2079 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
2080 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
2081
2082 dnl Configure the makefile's configuration data
2083 AC_CONFIG_FILES([Makefile.config])
2084
2085 dnl Configure the RPM spec file for LLVM
2086 AC_CONFIG_FILES([llvm.spec])
2087
2088 dnl Configure doxygen's configuration file
2089 AC_CONFIG_FILES([docs/doxygen.cfg])
2090
2091 dnl Configure clang, if present
2092 if test "${clang_src_root}" = ""; then
2093   clang_src_root="$srcdir/tools/clang"
2094 fi
2095 if test -f ${clang_src_root}/README.txt; then
2096   dnl Use variables to stay under 80 columns.
2097   configh="include/clang/Config/config.h"
2098   doxy="docs/doxygen.cfg"
2099   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
2100   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
2101 fi
2102
2103 dnl OCaml findlib META file
2104 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
2105
2106 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
2107 test "x$program_prefix" = "xNONE" && program_prefix=""
2108 AC_SUBST([program_prefix])
2109
2110
2111 dnl Do special configuration of Makefiles
2112 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2113 AC_CONFIG_MAKEFILE(Makefile)
2114 AC_CONFIG_MAKEFILE(Makefile.common)
2115 AC_CONFIG_MAKEFILE(examples/Makefile)
2116 AC_CONFIG_MAKEFILE(lib/Makefile)
2117 AC_CONFIG_MAKEFILE(test/Makefile)
2118 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2119 AC_CONFIG_MAKEFILE(unittests/Makefile)
2120 AC_CONFIG_MAKEFILE(tools/Makefile)
2121 AC_CONFIG_MAKEFILE(utils/Makefile)
2122 AC_CONFIG_MAKEFILE(projects/Makefile)
2123 AC_CONFIG_MAKEFILE(bindings/Makefile)
2124 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2125
2126 dnl Finally, crank out the output
2127 AC_OUTPUT