autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.2svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [2], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2012 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2012 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl We need to check for the compiler up here to avoid anything else
  63 dnl starting with a different one.
  64 AC_PROG_CC(clang llvm-gcc gcc)
  65 AC_PROG_CXX(clang++ llvm-g++ g++)
  66 AC_PROG_CPP
  67
  68 dnl Configure all of the projects present in our source tree. While we could
  69 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  70 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  71 dnl Instead we match on the known projects.
  72
  73 dnl
  74 dnl One tricky part of doing this is that some projects depend upon other
  75 dnl projects.  For example, several projects rely upon the LLVM test suite.
  76 dnl We want to configure those projects first so that their object trees are
  77 dnl created before running the configure scripts of projects that depend upon
  78 dnl them.
  79 dnl
  80
  81 dnl Several projects use llvm-gcc, so configure that first
  82 if test -d ${srcdir}/projects/llvm-gcc ; then
  83   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  84 fi
  85
  86 dnl Several projects use the LLVM test suite, so configure it next.
  87 if test -d ${srcdir}/projects/test-suite ; then
  88   AC_CONFIG_SUBDIRS([projects/test-suite])
  89 fi
  90
  91 dnl llvm-test is the old name of the test-suite, kept here for backwards
  92 dnl compatibility
  93 if test -d ${srcdir}/projects/llvm-test ; then
  94   AC_CONFIG_SUBDIRS([projects/llvm-test])
  95 fi
  96
  97 dnl Some projects use poolalloc; configure that next
  98 if test -d ${srcdir}/projects/poolalloc ; then
  99   AC_CONFIG_SUBDIRS([projects/poolalloc])
 100 fi
 101
 102 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 103   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 104 fi
 105
 106 dnl Check for all other projects
 107 for i in `ls ${srcdir}/projects`
 108 do
 109   if test -d ${srcdir}/projects/${i} ; then
 110     case ${i} in
 111       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 112       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 113       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 114       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 115       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 116       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 117       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 118       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 119       compiler-rt)       ;;
 120       llvm-gcc)       ;;
 121       test-suite)     ;;
 122       llvm-test)      ;;
 123       poolalloc)      ;;
 124       llvm-poolalloc) ;;
 125       *)
 126         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 127         ;;
 128     esac
 129   fi
 130 done
 131
 132 dnl Disable the build of polly, even if it is checked out into tools/polly.
 133 AC_ARG_ENABLE(polly,
 134               AS_HELP_STRING([--enable-polly],
 135                              [Use polly if available (default is YES)]),,
 136                              enableval=default)
 137 case "$enableval" in
 138   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 139   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 140   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 141   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 142 esac
 143
 144
 145 dnl Check if polly is checked out into tools/polly and configure it if
 146 dnl available.
 147 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 148   AC_SUBST(LLVM_HAS_POLLY,1)
 149   AC_CONFIG_SUBDIRS([tools/polly])
 150 fi
 151
 152 dnl===-----------------------------------------------------------------------===
 153 dnl===
 154 dnl=== SECTION 2: Architecture, target, and host checks
 155 dnl===
 156 dnl===-----------------------------------------------------------------------===
 157
 158 dnl Check the target for which we're compiling and the host that will do the
 159 dnl compilations. This will tell us which LLVM compiler will be used for
 160 dnl compiling SSA into object code. This needs to be done early because
 161 dnl following tests depend on it.
 162 AC_CANONICAL_TARGET
 163
 164 dnl Determine the platform type and cache its value. This helps us configure
 165 dnl the System library to the correct build platform.
 166 AC_CACHE_CHECK([type of operating system we're going to host on],
 167                [llvm_cv_os_type],
 168 [case $host in
 169   *-*-aix*)
 170     llvm_cv_link_all_option="-Wl,--whole-archive"
 171     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 172     llvm_cv_os_type="AIX"
 173     llvm_cv_platform_type="Unix" ;;
 174   *-*-irix*)
 175     llvm_cv_link_all_option="-Wl,--whole-archive"
 176     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 177     llvm_cv_os_type="IRIX"
 178     llvm_cv_platform_type="Unix" ;;
 179   *-*-cygwin*)
 180     llvm_cv_link_all_option="-Wl,--whole-archive"
 181     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 182     llvm_cv_os_type="Cygwin"
 183     llvm_cv_platform_type="Unix" ;;
 184   *-*-darwin*)
 185     llvm_cv_link_all_option="-Wl,-all_load"
 186     llvm_cv_no_link_all_option="-Wl,-noall_load"
 187     llvm_cv_os_type="Darwin"
 188     llvm_cv_platform_type="Unix" ;;
 189   *-*-minix*)
 190     llvm_cv_link_all_option="-Wl,-all_load"
 191     llvm_cv_no_link_all_option="-Wl,-noall_load"
 192     llvm_cv_os_type="Minix"
 193     llvm_cv_platform_type="Unix" ;;
 194   *-*-freebsd* | *-*-kfreebsd-gnu)
 195     llvm_cv_link_all_option="-Wl,--whole-archive"
 196     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 197     llvm_cv_os_type="FreeBSD"
 198     llvm_cv_platform_type="Unix" ;;
 199   *-*-openbsd*)
 200     llvm_cv_link_all_option="-Wl,--whole-archive"
 201     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 202     llvm_cv_os_type="OpenBSD"
 203     llvm_cv_platform_type="Unix" ;;
 204   *-*-netbsd*)
 205     llvm_cv_link_all_option="-Wl,--whole-archive"
 206     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 207     llvm_cv_os_type="NetBSD"
 208     llvm_cv_platform_type="Unix" ;;
 209   *-*-dragonfly*)
 210     llvm_cv_link_all_option="-Wl,--whole-archive"
 211     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 212     llvm_cv_os_type="DragonFly"
 213     llvm_cv_platform_type="Unix" ;;
 214   *-*-hpux*)
 215     llvm_cv_link_all_option="-Wl,--whole-archive"
 216     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 217     llvm_cv_os_type="HP-UX"
 218     llvm_cv_platform_type="Unix" ;;
 219   *-*-interix*)
 220     llvm_cv_link_all_option="-Wl,--whole-archive"
 221     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 222     llvm_cv_os_type="Interix"
 223     llvm_cv_platform_type="Unix" ;;
 224   *-*-linux*)
 225     llvm_cv_link_all_option="-Wl,--whole-archive"
 226     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 227     llvm_cv_os_type="Linux"
 228     llvm_cv_platform_type="Unix" ;;
 229   *-*-gnu*)
 230     llvm_cv_link_all_option="-Wl,--whole-archive"
 231     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 232     llvm_cv_os_type="GNU"
 233     llvm_cv_platform_type="Unix" ;;
 234   *-*-solaris*)
 235     llvm_cv_link_all_option="-Wl,-z,allextract"
 236     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 237     llvm_cv_os_type="SunOS"
 238     llvm_cv_platform_type="Unix" ;;
 239   *-*-auroraux*)
 240     llvm_cv_link_all_option="-Wl,-z,allextract"
 241     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 242     llvm_cv_os_type="AuroraUX"
 243     llvm_cv_platform_type="Unix" ;;
 244   *-*-win32*)
 245     llvm_cv_link_all_option="-Wl,--whole-archive"
 246     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 247     llvm_cv_os_type="Win32"
 248     llvm_cv_platform_type="Win32" ;;
 249   *-*-mingw*)
 250     llvm_cv_link_all_option="-Wl,--whole-archive"
 251     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 252     llvm_cv_os_type="MingW"
 253     llvm_cv_platform_type="Win32" ;;
 254   *-*-haiku*)
 255     llvm_cv_link_all_option="-Wl,--whole-archive"
 256     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 257     llvm_cv_os_type="Haiku"
 258     llvm_cv_platform_type="Unix" ;;
 259   *-unknown-eabi*)
 260     llvm_cv_link_all_option="-Wl,--whole-archive"
 261     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 262     llvm_cv_os_type="Freestanding"
 263     llvm_cv_platform_type="Unix" ;;
 264   *-unknown-elf*)
 265     llvm_cv_link_all_option="-Wl,--whole-archive"
 266     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 267     llvm_cv_os_type="Freestanding"
 268     llvm_cv_platform_type="Unix" ;;
 269   *)
 270     llvm_cv_link_all_option=""
 271     llvm_cv_no_link_all_option=""
 272     llvm_cv_os_type="Unknown"
 273     llvm_cv_platform_type="Unknown" ;;
 274 esac])
 275
 276 AC_CACHE_CHECK([type of operating system we're going to target],
 277                [llvm_cv_target_os_type],
 278 [case $target in
 279   *-*-aix*)
 280     llvm_cv_target_os_type="AIX" ;;
 281   *-*-irix*)
 282     llvm_cv_target_os_type="IRIX" ;;
 283   *-*-cygwin*)
 284     llvm_cv_target_os_type="Cygwin" ;;
 285   *-*-darwin*)
 286     llvm_cv_target_os_type="Darwin" ;;
 287   *-*-minix*)
 288     llvm_cv_target_os_type="Minix" ;;
 289   *-*-freebsd* | *-*-kfreebsd-gnu)
 290     llvm_cv_target_os_type="FreeBSD" ;;
 291   *-*-openbsd*)
 292     llvm_cv_target_os_type="OpenBSD" ;;
 293   *-*-netbsd*)
 294     llvm_cv_target_os_type="NetBSD" ;;
 295   *-*-dragonfly*)
 296     llvm_cv_target_os_type="DragonFly" ;;
 297   *-*-hpux*)
 298     llvm_cv_target_os_type="HP-UX" ;;
 299   *-*-interix*)
 300     llvm_cv_target_os_type="Interix" ;;
 301   *-*-linux*)
 302     llvm_cv_target_os_type="Linux" ;;
 303   *-*-gnu*)
 304     llvm_cv_target_os_type="GNU" ;;
 305   *-*-solaris*)
 306     llvm_cv_target_os_type="SunOS" ;;
 307   *-*-auroraux*)
 308     llvm_cv_target_os_type="AuroraUX" ;;
 309   *-*-win32*)
 310     llvm_cv_target_os_type="Win32" ;;
 311   *-*-mingw*)
 312     llvm_cv_target_os_type="MingW" ;;
 313   *-*-haiku*)
 314     llvm_cv_target_os_type="Haiku" ;;
 315   *-*-rtems*)
 316     llvm_cv_target_os_type="RTEMS" ;;
 317   *-*-nacl*)
 318     llvm_cv_target_os_type="NativeClient" ;;
 319   *-unknown-eabi*)
 320     llvm_cv_target_os_type="Freestanding" ;;
 321   *)
 322     llvm_cv_target_os_type="Unknown" ;;
 323 esac])
 324
 325 dnl Make sure we aren't attempting to configure for an unknown system
 326 if test "$llvm_cv_os_type" = "Unknown" ; then
 327   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 328 fi
 329
 330 dnl Set the "OS" Makefile variable based on the platform type so the
 331 dnl makefile can configure itself to specific build hosts
 332 AC_SUBST(OS,$llvm_cv_os_type)
 333 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 334 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 335
 336 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 337 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 338 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 339
 340 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 341 dnl This is used by lib/Support to determine the basic kind of implementation
 342 dnl to use.
 343 case $llvm_cv_platform_type in
 344   Unix)
 345     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 346     AC_SUBST(LLVM_ON_UNIX,[1])
 347     AC_SUBST(LLVM_ON_WIN32,[0])
 348     ;;
 349   Win32)
 350     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 351     AC_SUBST(LLVM_ON_UNIX,[0])
 352     AC_SUBST(LLVM_ON_WIN32,[1])
 353     ;;
 354 esac
 355
 356 dnl Determine what our target architecture is and configure accordingly.
 357 dnl This will allow Makefiles to make a distinction between the hardware and
 358 dnl the OS.
 359 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 360 [case $target in
 361   i?86-*)                 llvm_cv_target_arch="x86" ;;
 362   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 363   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 364   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 365   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 366   mips-*)                 llvm_cv_target_arch="Mips" ;;
 367   mipsel-*)               llvm_cv_target_arch="Mips" ;;
 368   xcore-*)                llvm_cv_target_arch="XCore" ;;
 369   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 370   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 371   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 372   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 373   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 374   *)                      llvm_cv_target_arch="Unknown" ;;
 375 esac])
 376
 377 if test "$llvm_cv_target_arch" = "Unknown" ; then
 378   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 379 fi
 380
 381 dnl Determine the LLVM native architecture for the target
 382 case "$llvm_cv_target_arch" in
 383     x86)     LLVM_NATIVE_ARCH="X86" ;;
 384     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 385     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 386 esac
 387
 388 dnl Define a substitution, ARCH, for the target architecture
 389 AC_SUBST(ARCH,$llvm_cv_target_arch)
 390
 391 dnl Determine what our host architecture.
 392 dnl This will allow MCJIT regress tests runs only for supported
 393 dnl platforms.
 394 case $host in
 395   i?86-*)                 host_arch="x86" ;;
 396   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 397   sparc*-*)               host_arch="Sparc" ;;
 398   powerpc*-*)             host_arch="PowerPC" ;;
 399   arm*-*)                 host_arch="ARM" ;;
 400   mips-*)                 host_arch="Mips" ;;
 401   mipsel-*)               host_arch="Mips" ;;
 402   xcore-*)                host_arch="XCore" ;;
 403   msp430-*)               host_arch="MSP430" ;;
 404   hexagon-*)              host_arch="Hexagon" ;;
 405   mblaze-*)               host_arch="MBlaze" ;;
 406   ptx-*)                  host_arch="PTX" ;;
 407   *)                      host_arch="Unknown" ;;
 408 esac
 409
 410 if test "$host_arch" = "Unknown" ; then
 411   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 412 fi
 413
 414 AC_SUBST(HOST_ARCH,$host_arch)
 415
 416 dnl Check for the endianness of the target
 417 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 418
 419 dnl Check for build platform executable suffix if we're cross-compiling
 420 if test "$cross_compiling" = yes; then
 421   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 422   AC_BUILD_EXEEXT
 423   ac_build_prefix=${build_alias}-
 424   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 425   if test -z "$BUILD_CXX"; then
 426      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 427      if test -z "$BUILD_CXX"; then
 428        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 429      fi
 430   fi
 431 else
 432   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 433 fi
 434
 435 dnl Check to see if there's a .svn or .git directory indicating that this
 436 dnl build is being done from a checkout. This sets up several defaults for
 437 dnl the command line switches. When we build with a checkout directory,
 438 dnl we get a debug with assertions turned on. Without, we assume a source
 439 dnl release and we get an optimized build without assertions.
 440 dnl See --enable-optimized and --enable-assertions below
 441 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 442   cvsbuild="yes"
 443   optimize="no"
 444   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 445 else
 446   cvsbuild="no"
 447   optimize="yes"
 448 fi
 449
 450 dnl===-----------------------------------------------------------------------===
 451 dnl===
 452 dnl=== SECTION 3: Command line arguments for the configure script.
 453 dnl===
 454 dnl===-----------------------------------------------------------------------===
 455
 456 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 457 AC_ARG_ENABLE(libcpp,
 458               AS_HELP_STRING([--enable-libcpp],
 459                              [Use libc++ if available (default is NO)]),,
 460                              enableval=default)
 461 case "$enableval" in
 462   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 463   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 464   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 465   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 466 esac
 467
 468 dnl --enable-optimized : check whether they want to do an optimized build:
 469 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 470  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 471 if test ${enableval} = "no" ; then
 472   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 473 else
 474   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 475 fi
 476
 477 dnl --enable-profiling : check whether they want to do a profile build:
 478 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 479  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 480 if test ${enableval} = "no" ; then
 481   AC_SUBST(ENABLE_PROFILING,[[]])
 482 else
 483   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 484 fi
 485
 486 dnl --enable-assertions : check whether they want to turn on assertions or not:
 487 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 488   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 489 if test ${enableval} = "yes" ; then
 490   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 491 else
 492   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 493 fi
 494
 495 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 496 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 497   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 498 if test ${enableval} = "yes" ; then
 499   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 500   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 501 else
 502   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 503   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 504 fi
 505
 506 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 507 AC_ARG_ENABLE(debug-runtime,
 508    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 509 if test ${enableval} = "no" ; then
 510   AC_SUBST(DEBUG_RUNTIME,[[]])
 511 else
 512   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 513 fi
 514
 515 dnl --enable-debug-symbols : should even optimized compiler libraries
 516 dnl have debug symbols?
 517 AC_ARG_ENABLE(debug-symbols,
 518    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 519 if test ${enableval} = "no" ; then
 520   AC_SUBST(DEBUG_SYMBOLS,[[]])
 521 else
 522   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 523 fi
 524
 525 dnl --enable-jit: check whether they want to enable the jit
 526 AC_ARG_ENABLE(jit,
 527   AS_HELP_STRING(--enable-jit,
 528                  [Enable Just In Time Compiling (default is YES)]),,
 529   enableval=default)
 530 if test ${enableval} = "no"
 531 then
 532   AC_SUBST(JIT,[[]])
 533 else
 534   case "$llvm_cv_target_arch" in
 535     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 536     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 537     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 538     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 539     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 540     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 541     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 542     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 543     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 544     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 545     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 546     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 547     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 548   esac
 549 fi
 550
 551 dnl Allow enablement of building and installing docs
 552 AC_ARG_ENABLE(docs,
 553               AS_HELP_STRING([--enable-docs],
 554                              [Build documents (default is YES)]),,
 555                              enableval=default)
 556 case "$enableval" in
 557   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 558   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 559   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 560   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 561 esac
 562
 563 dnl Allow enablement of doxygen generated documentation
 564 AC_ARG_ENABLE(doxygen,
 565               AS_HELP_STRING([--enable-doxygen],
 566                              [Build doxygen documentation (default is NO)]),,
 567                              enableval=default)
 568 case "$enableval" in
 569   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 570   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 571   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 572   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 573 esac
 574
 575 dnl Allow disablement of threads
 576 AC_ARG_ENABLE(threads,
 577               AS_HELP_STRING([--enable-threads],
 578                              [Use threads if available (default is YES)]),,
 579                              enableval=default)
 580 case "$enableval" in
 581   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 582   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 583   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 584   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 585 esac
 586 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 587                    [Define if threads enabled])
 588
 589 dnl Allow disablement of pthread.h
 590 AC_ARG_ENABLE(pthreads,
 591               AS_HELP_STRING([--enable-pthreads],
 592                              [Use pthreads if available (default is YES)]),,
 593                              enableval=default)
 594 case "$enableval" in
 595   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 596   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 597   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 598   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 599 esac
 600
 601 dnl Allow building without position independent code
 602 AC_ARG_ENABLE(pic,
 603   AS_HELP_STRING([--enable-pic],
 604                  [Build LLVM with Position Independent Code (default is YES)]),,
 605                  enableval=default)
 606 case "$enableval" in
 607   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 608   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 609   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 610   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 611 esac
 612 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 613                    [Define if position independent code is enabled])
 614
 615 dnl Allow building a shared library and linking tools against it.
 616 AC_ARG_ENABLE(shared,
 617   AS_HELP_STRING([--enable-shared],
 618                  [Build a shared library and link tools against it (default is NO)]),,
 619                  enableval=default)
 620 case "$enableval" in
 621   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 622   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 623   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 624   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 625 esac
 626
 627 dnl Allow libstdc++ is embedded in LLVM.dll.
 628 AC_ARG_ENABLE(embed-stdcxx,
 629   AS_HELP_STRING([--enable-embed-stdcxx],
 630                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 631                  enableval=default)
 632 case "$enableval" in
 633   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 634   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 635   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 636   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 637 esac
 638
 639 dnl Enable embedding timestamp information into build.
 640 AC_ARG_ENABLE(timestamps,
 641   AS_HELP_STRING([--enable-timestamps],
 642                  [Enable embedding timestamp information in build (default is YES)]),,
 643                  enableval=default)
 644 case "$enableval" in
 645   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 646   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 647   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 648   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 649 esac
 650 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 651                    [Define if timestamp information (e.g., __DATE___) is allowed])
 652
 653 dnl Allow specific targets to be specified for building (or not)
 654 TARGETS_TO_BUILD=""
 655 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 656     [Build specific host targets: all or target1,target2,... Valid targets are:
 657      host, x86, x86_64, sparc, powerpc, arm, mips, spu, hexagon,
 658      xcore, msp430, ptx, nvptx, and cpp (default=all)]),,
 659     enableval=all)
 660 if test "$enableval" = host-only ; then
 661   enableval=host
 662 fi
 663 case "$enableval" in
 664   all) TARGETS_TO_BUILD="X86 Sparc PowerPC ARM Mips CellSPU XCore MSP430 CppBackend MBlaze PTX NVPTX Hexagon" ;;
 665   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 666       case "$a_target" in
 667         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 668         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 669         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 670         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 671         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 672         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 673         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 674         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 675         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 676         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 677         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 678         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 679         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 680         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 681         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 682         host) case "$llvm_cv_target_arch" in
 683             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 684             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 685             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 686             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 687             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 688             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 689             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 690             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 691             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 692             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 693             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 694             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 695             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 696             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 697           esac ;;
 698         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 699       esac
 700   done
 701   ;;
 702 esac
 703 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 704
 705 dnl Determine whether we are building LLVM support for the native architecture.
 706 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 707 for a_target in $TARGETS_TO_BUILD; do
 708   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 709     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 710       [LLVM architecture name for the native architecture, if available])
 711     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 712     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 713     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 714     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 715     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 716       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 717     fi
 718     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 719       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 720     fi
 721     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 722       [LLVM name for the native Target init function, if available])
 723     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 724       [LLVM name for the native TargetInfo init function, if available])
 725     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 726       [LLVM name for the native target MC init function, if available])
 727     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 728       [LLVM name for the native AsmPrinter init function, if available])
 729     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 730       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 731        [LLVM name for the native AsmParser init function, if available])
 732     fi
 733     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 734       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 735        [LLVM name for the native Disassembler init function, if available])
 736     fi
 737   fi
 738 done
 739
 740 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 741 dnl target feature def files.
 742 LLVM_ENUM_TARGETS=""
 743 LLVM_ENUM_ASM_PRINTERS=""
 744 LLVM_ENUM_ASM_PARSERS=""
 745 LLVM_ENUM_DISASSEMBLERS=""
 746 for target_to_build in $TARGETS_TO_BUILD; do
 747   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 748   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 749     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 750   fi
 751   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 752     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 753   fi
 754   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 755     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 756   fi
 757 done
 758 AC_SUBST(LLVM_ENUM_TARGETS)
 759 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 760 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 761 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 762
 763 dnl Override the option to use for optimized builds.
 764 AC_ARG_WITH(optimize-option,
 765   AS_HELP_STRING([--with-optimize-option],
 766                  [Select the compiler options to use for optimized builds]),,
 767                  withval=default)
 768 AC_MSG_CHECKING([optimization flags])
 769 case "$withval" in
 770   default)
 771     case "$llvm_cv_os_type" in
 772     FreeBSD) optimize_option=-O2 ;;
 773     MingW) optimize_option=-O2 ;;
 774     *)     optimize_option=-O3 ;;
 775     esac ;;
 776   *) optimize_option="$withval" ;;
 777 esac
 778 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 779 AC_MSG_RESULT([$optimize_option])
 780
 781 dnl Specify extra build options
 782 AC_ARG_WITH(extra-options,
 783   AS_HELP_STRING([--with-extra-options],
 784                  [Specify additional options to compile LLVM with]),,
 785                  withval=default)
 786 case "$withval" in
 787   default) EXTRA_OPTIONS= ;;
 788   *) EXTRA_OPTIONS=$withval ;;
 789 esac
 790 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 791
 792 dnl Specify extra linker build options
 793 AC_ARG_WITH(extra-ld-options,
 794   AS_HELP_STRING([--with-extra-ld-options],
 795                  [Specify additional options to link LLVM with]),,
 796                  withval=default)
 797 case "$withval" in
 798   default) EXTRA_LD_OPTIONS= ;;
 799   *) EXTRA_LD_OPTIONS=$withval ;;
 800 esac
 801 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 802
 803 dnl Allow specific bindings to be specified for building (or not)
 804 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 805     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 806     enableval=default)
 807 BINDINGS_TO_BUILD=""
 808 case "$enableval" in
 809   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 810   all ) BINDINGS_TO_BUILD="ocaml" ;;
 811   none | no) BINDINGS_TO_BUILD="" ;;
 812   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 813       case "$a_binding" in
 814         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 815         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 816       esac
 817   done
 818   ;;
 819 esac
 820
 821 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 822 dnl script for bindings/ocaml/configure, except that its auto value depends on
 823 dnl OCAMLC, which is found here to support tests.
 824 AC_ARG_WITH([ocaml-libdir],
 825   [AS_HELP_STRING([--with-ocaml-libdir],
 826     [Specify install location for ocaml bindings (default is stdlib)])],
 827   [],
 828   [withval=auto])
 829 case "$withval" in
 830   auto) with_ocaml_libdir="$withval" ;;
 831   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 832   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 833 esac
 834
 835 AC_ARG_WITH(clang-srcdir,
 836   AS_HELP_STRING([--with-clang-srcdir],
 837     [Directory to the out-of-tree Clang source]),,
 838     withval="-")
 839 case "$withval" in
 840   -) clang_src_root="" ;;
 841   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 842   *) clang_src_root="$ac_pwd/$withval" ;;
 843 esac
 844 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
 845
 846 AC_ARG_WITH(clang-resource-dir,
 847   AS_HELP_STRING([--with-clang-resource-dir],
 848     [Relative directory from the Clang binary for resource files]),,
 849     withval="")
 850 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 851                    [Relative directory for resource files])
 852
 853 AC_ARG_WITH(c-include-dirs,
 854   AS_HELP_STRING([--with-c-include-dirs],
 855     [Colon separated list of directories clang will search for headers]),,
 856     withval="")
 857 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 858                    [Directories clang will search for headers])
 859
 860 # Clang normally uses the system c++ headers and libraries. With this option,
 861 # clang will use the ones provided by a gcc installation instead. This option should
 862 # be passed the same value that was used with --prefix when configuring gcc.
 863 AC_ARG_WITH(gcc-toolchain,
 864   AS_HELP_STRING([--with-gcc-toolchain],
 865     [Directory where gcc is installed.]),,
 866     withval="")
 867 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
 868                    [Directory where gcc is installed.])
 869
 870 AC_ARG_WITH(default-sysroot,
 871   AS_HELP_STRING([--with-default-sysroot],
 872     [Add --sysroot=<path> to all compiler invocations.]),,
 873     withval="")
 874 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
 875                    [Default <path> to all compiler invocations for --sysroot=<path>.])
 876
 877 dnl Allow linking of LLVM with GPLv3 binutils code.
 878 AC_ARG_WITH(binutils-include,
 879   AS_HELP_STRING([--with-binutils-include],
 880     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 881   withval=default)
 882 case "$withval" in
 883   default) WITH_BINUTILS_INCDIR=default ;;
 884   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 885   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 886 esac
 887 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 888   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 889   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 890      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 891      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 892   fi
 893 fi
 894
 895 dnl Specify the URL where bug reports should be submitted.
 896 AC_ARG_WITH(bug-report-url,
 897   AS_HELP_STRING([--with-bug-report-url],
 898     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 899     withval="http://llvm.org/bugs/")
 900 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 901                    [Bug report URL.])
 902
 903 dnl --enable-libffi : check whether the user wants to turn off libffi:
 904 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 905   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 906   [case "$enableval" in
 907     yes) llvm_cv_enable_libffi="yes" ;;
 908     no)  llvm_cv_enable_libffi="no"  ;;
 909     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 910   esac],
 911   llvm_cv_enable_libffi=no)
 912
 913 AC_ARG_WITH(internal-prefix,
 914   AS_HELP_STRING([--with-internal-prefix],
 915     [Installation directory for internal files]),,
 916     withval="")
 917 AC_SUBST(INTERNAL_PREFIX,[$withval])
 918
 919 dnl===-----------------------------------------------------------------------===
 920 dnl===
 921 dnl=== SECTION 4: Check for programs we need and that they are the right version
 922 dnl===
 923 dnl===-----------------------------------------------------------------------===
 924
 925 AC_PROG_NM
 926 AC_SUBST(NM)
 927
 928 dnl Check for the tools that the makefiles require
 929 AC_CHECK_GNU_MAKE
 930 AC_PROG_LN_S
 931 AC_PATH_PROG(CMP, [cmp], [cmp])
 932 AC_PATH_PROG(CP, [cp], [cp])
 933 AC_PATH_PROG(DATE, [date], [date])
 934 AC_PATH_PROG(FIND, [find], [find])
 935 AC_PATH_PROG(GREP, [grep], [grep])
 936 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 937 AC_PATH_PROG(MV,   [mv],   [mv])
 938 AC_PROG_RANLIB
 939 AC_CHECK_TOOL(AR, ar, false)
 940 AC_PATH_PROG(RM,   [rm],   [rm])
 941 AC_PATH_PROG(SED,  [sed],  [sed])
 942 AC_PATH_PROG(TAR,  [tar],  [gtar])
 943 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 944
 945 dnl Looking for misc. graph plotting software
 946 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 947 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 948   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 949   dnl If we're targeting for mingw we should emit windows paths, not msys
 950   if test "$llvm_cv_os_type" = "MingW" ; then
 951     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 952   fi
 953   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 954    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 955 fi
 956 AC_PATH_PROG(DOT, [dot], [echo dot])
 957 if test "$DOT" != "echo dot" ; then
 958   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 959   dnl If we're targeting for mingw we should emit windows paths, not msys
 960   if test "$llvm_cv_os_type" = "MingW" ; then
 961     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 962   fi
 963   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 964    [Define to path to dot program if found or 'echo dot' otherwise])
 965 fi
 966 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 967 if test "$FDP" != "echo fdp" ; then
 968   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 969   dnl If we're targeting for mingw we should emit windows paths, not msys
 970   if test "$llvm_cv_os_type" = "MingW" ; then
 971     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 972   fi
 973   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 974    [Define to path to fdp program if found or 'echo fdp' otherwise])
 975 fi
 976 AC_PATH_PROG(NEATO, [neato], [echo neato])
 977 if test "$NEATO" != "echo neato" ; then
 978   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 979   dnl If we're targeting for mingw we should emit windows paths, not msys
 980   if test "$llvm_cv_os_type" = "MingW" ; then
 981     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 982   fi
 983   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 984    [Define to path to neato program if found or 'echo neato' otherwise])
 985 fi
 986 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 987 if test "$TWOPI" != "echo twopi" ; then
 988   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 989   dnl If we're targeting for mingw we should emit windows paths, not msys
 990   if test "$llvm_cv_os_type" = "MingW" ; then
 991     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 992   fi
 993   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 994    [Define to path to twopi program if found or 'echo twopi' otherwise])
 995 fi
 996 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 997 if test "$CIRCO" != "echo circo" ; then
 998   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 999   dnl If we're targeting for mingw we should emit windows paths, not msys
1000   if test "$llvm_cv_os_type" = "MingW" ; then
1001     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1002   fi
1003   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1004    [Define to path to circo program if found or 'echo circo' otherwise])
1005 fi
1006 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1007 if test "$GV" != "echo gv" ; then
1008   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1009   dnl If we're targeting for mingw we should emit windows paths, not msys
1010   if test "$llvm_cv_os_type" = "MingW" ; then
1011     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1012   fi
1013   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1014    [Define to path to gv program if found or 'echo gv' otherwise])
1015 fi
1016 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1017 if test "$DOTTY" != "echo dotty" ; then
1018   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1019   dnl If we're targeting for mingw we should emit windows paths, not msys
1020   if test "$llvm_cv_os_type" = "MingW" ; then
1021     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1022   fi
1023   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1024    [Define to path to dotty program if found or 'echo dotty' otherwise])
1025 fi
1026 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1027 if test "$XDOT_PY" != "echo xdot.py" ; then
1028   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1029   dnl If we're targeting for mingw we should emit windows paths, not msys
1030   if test "$llvm_cv_os_type" = "MingW" ; then
1031     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1032   fi
1033   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1034    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1035 fi
1036
1037 dnl Find the install program
1038 AC_PROG_INSTALL
1039 dnl Prepend src dir to install path dir if it's a relative path
1040 dnl This is a hack for installs that take place in something other
1041 dnl than the top level.
1042 case "$INSTALL" in
1043  [[\\/$]]* | ?:[[\\/]]* ) ;;
1044  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1045 esac
1046
1047 dnl Checks for documentation and testing tools that we can do without. If these
1048 dnl are not found then they are set to "true" which always succeeds but does
1049 dnl nothing. This just lets the build output show that we could have done
1050 dnl something if the tool was available.
1051 AC_PATH_PROG(BZIP2, [bzip2])
1052 AC_PATH_PROG(CAT, [cat])
1053 AC_PATH_PROG(DOXYGEN, [doxygen])
1054 AC_PATH_PROG(GROFF, [groff])
1055 AC_PATH_PROG(GZIPBIN, [gzip])
1056 AC_PATH_PROG(PDFROFF, [pdfroff])
1057 AC_PATH_PROG(RUNTEST, [runtest])
1058 DJ_AC_PATH_TCLSH
1059 AC_PATH_PROG(ZIP, [zip])
1060 AC_PATH_PROGS(OCAMLC, [ocamlc])
1061 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1062 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1063 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1064 AC_PATH_PROGS(GAS, [gas as])
1065
1066 dnl Get the version of the linker in use.
1067 AC_LINK_GET_VERSION
1068
1069 dnl Determine whether the linker supports the -R option.
1070 AC_LINK_USE_R
1071
1072 dnl Determine whether the linker supports the -export-dynamic option.
1073 AC_LINK_EXPORT_DYNAMIC
1074
1075 dnl Determine whether the linker supports the --version-script option.
1076 AC_LINK_VERSION_SCRIPT
1077
1078 dnl Check for libtool and the library that has dlopen function (which must come
1079 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1080 dnl libtool).
1081 AC_LIBTOOL_DLOPEN
1082 AC_LIB_LTDL
1083
1084 AC_MSG_CHECKING([tool compatibility])
1085
1086 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1087 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1088 dnl to support those options.
1089 dnl "icc" emits gcc signatures
1090 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1091 ICC=no
1092 IXX=no
1093 case $CC in
1094   icc*|icpc*)
1095     ICC=yes
1096     IXX=yes
1097     ;;
1098    *)
1099     ;;
1100 esac
1101
1102 if test "$GCC" != "yes" && test "$ICC" != "yes"
1103 then
1104   AC_MSG_ERROR([gcc|icc required but not found])
1105 fi
1106
1107 dnl Ensure that compilation tools are compatible with GCC extensions
1108 if test "$GXX" != "yes" && test "$IXX" != "yes"
1109 then
1110   AC_MSG_ERROR([g++|clang++|icc required but not found])
1111 fi
1112
1113 dnl Verify that GCC is version 3.0 or higher
1114 if test "$GCC" = "yes"
1115 then
1116   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1117 #error Unsupported GCC version
1118 #endif
1119 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1120 fi
1121
1122 dnl Check for GNU Make.  We use its extensions, so don't build without it
1123 if test -z "$llvm_cv_gnu_make_command"
1124 then
1125   AC_MSG_ERROR([GNU Make required but not found])
1126 fi
1127
1128 dnl Tool compatibility is okay if we make it here.
1129 AC_MSG_RESULT([ok])
1130
1131 dnl Check optional compiler flags.
1132 AC_MSG_CHECKING([optional compiler flags])
1133 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1134 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1135 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1136 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT])
1137
1138 dnl===-----------------------------------------------------------------------===
1139 dnl===
1140 dnl=== SECTION 5: Check for libraries
1141 dnl===
1142 dnl===-----------------------------------------------------------------------===
1143
1144 AC_CHECK_LIB(m,sin)
1145 if test "$llvm_cv_os_type" = "MingW" ; then
1146   AC_CHECK_LIB(imagehlp, main)
1147   AC_CHECK_LIB(psapi, main)
1148 fi
1149
1150 dnl dlopen() is required for plugin support.
1151 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1152                [Define if dlopen() is available on this platform.]),
1153                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1154
1155 dnl libffi is optional; used to call external functions from the interpreter
1156 if test "$llvm_cv_enable_libffi" = "yes" ; then
1157   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1158                  [Define if libffi is available on this platform.]),
1159                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1160 fi
1161
1162 dnl mallinfo is optional; the code can compile (minus features) without it
1163 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1164                [Define if mallinfo() is available on this platform.]))
1165
1166 dnl pthread locking functions are optional - but llvm will not be thread-safe
1167 dnl without locks.
1168 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1169   AC_CHECK_LIB(pthread, pthread_mutex_init)
1170   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1171                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1172                            [Have pthread_mutex_lock]))
1173   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1174                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1175                  [Have pthread_rwlock_init]))
1176   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1177                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1178                  [Have pthread_getspecific]))
1179 fi
1180
1181 dnl Allow extra x86-disassembler library
1182 AC_ARG_WITH(udis86,
1183   AS_HELP_STRING([--with-udis86=<path>],
1184     [Use udis86 external x86 disassembler library]),
1185     [
1186       AC_SUBST(USE_UDIS86, [1])
1187       case "$withval" in
1188         /usr/lib|yes) ;;
1189         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1190       esac
1191       AC_CHECK_LIB(udis86, ud_init, [], [
1192         echo "Error! You need to have libudis86 around."
1193         exit -1
1194       ])
1195     ],
1196     AC_SUBST(USE_UDIS86, [0]))
1197 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1198                    [Define if use udis86 library])
1199
1200 dnl Allow OProfile support for JIT output.
1201 AC_ARG_WITH(oprofile,
1202   AS_HELP_STRING([--with-oprofile=<prefix>],
1203     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1204     [
1205       AC_SUBST(USE_OPROFILE, [1])
1206       case "$withval" in
1207         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1208         no) llvm_cv_oppath=
1209             AC_SUBST(USE_OPROFILE, [0]) ;;
1210         *) llvm_cv_oppath="${withval}/lib/oprofile"
1211            CPPFLAGS="-I${withval}/include";;
1212       esac
1213       case $llvm_cv_os_type in
1214         Linux)
1215           if test -n "$llvm_cv_oppath" ; then
1216             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1217             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1218             dnl libbfd is not included properly in libopagent in some Debian
1219             dnl versions.  If libbfd isn't found at all, we assume opagent works
1220             dnl anyway.
1221             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1222             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1223               echo "Error! You need to have libopagent around."
1224               exit -1
1225             ])
1226             AC_CHECK_HEADER([opagent.h], [], [
1227               echo "Error! You need to have opagent.h around."
1228               exit -1
1229               ])
1230           fi ;;
1231         *)
1232           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1233       esac
1234     ],
1235     [
1236       AC_SUBST(USE_OPROFILE, [0])
1237     ])
1238 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1239                    [Define if we have the oprofile JIT-support library])
1240
1241 dnl Enable support for Intel JIT Events API.
1242 AC_ARG_WITH(intel-jitevents,
1243   AS_HELP_STRING([--with-intel-jitevents=<vtune-amplifier-dir>],
1244     [Specify location of run-time support library for Intel JIT API (default=/opt/intel/vtune_amplifier_xe_2011)]),
1245     [
1246       case $llvm_cv_os_type in
1247         Linux|Win32|Cygwin|MingW) ;;
1248         *)
1249           AC_MSG_ERROR([
1250             Intel JIT API support is available on Linux and Windows only."]) ;;
1251       esac
1252
1253       AC_SUBST(USE_INTEL_JITEVENTS, [1])
1254       case "$llvm_cv_target_arch" in
1255         x86)    llvm_intel_jitevents_archdir="lib32";;
1256         x86_64) llvm_intel_jitevents_archdir="lib64";;
1257         *)      echo "Target architecture $llvm_cv_target_arch does not support Intel JIT Events API"
1258                 exit -1;;
1259       esac
1260       INTEL_JITEVENTS_INCDIR="/opt/intel/vtune_amplifier_xe_2011/include"
1261       INTEL_JITEVENTS_LIBDIR="/opt/intel/vtune_amplifier_xe_2011/$llvm_intel_jitevents_archdir"
1262       case "$withval" in
1263         /* | [[A-Za-z]]:[[\\/]]*) INTEL_JITEVENTS_INCDIR=$withval/include
1264                                   INTEL_JITEVENTS_LIBDIR=$withval/$llvm_intel_jitevents_archdir ;;
1265         *) ;;
1266       esac
1267
1268       AC_SUBST(INTEL_JITEVENTS_INCDIR)
1269       AC_SUBST(INTEL_JITEVENTS_LIBDIR)
1270
1271       LIBS="$LIBS -L${INTEL_JITEVENTS_LIBDIR}"
1272       CPPFLAGS="$CPPFLAGS -I$INTEL_JITEVENTS_INCDIR"
1273
1274       AC_SEARCH_LIBS(iJIT_IsProfilingActive, jitprofiling, [], [
1275         echo "Error! Cannot find libjitprofiling.a. Please check path specified in flag --with-intel-jitevents"
1276         exit -1
1277       ])
1278       AC_CHECK_HEADER([jitprofiling.h], [], [
1279         echo "Error! Cannot find jitprofiling.h. Please check path specified in flag --with-intel-jitevents"
1280         exit -1
1281       ])
1282
1283     ],
1284     [
1285       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1286     ])
1287 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1288                    [Define if we have the Intel JIT API runtime support library])
1289
1290 dnl===-----------------------------------------------------------------------===
1291 dnl===
1292 dnl=== SECTION 6: Check for header files
1293 dnl===
1294 dnl===-----------------------------------------------------------------------===
1295
1296 dnl First, use autoconf provided macros for specific headers that we need
1297 dnl We don't check for ancient stuff or things that are guaranteed to be there
1298 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1299 dnl Generally we're looking for POSIX headers.
1300 AC_HEADER_DIRENT
1301 AC_HEADER_MMAP_ANONYMOUS
1302 AC_HEADER_STAT
1303 AC_HEADER_SYS_WAIT
1304 AC_HEADER_TIME
1305
1306 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1307 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1308 AC_CHECK_HEADERS([utime.h windows.h])
1309 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1310 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1311 AC_CHECK_HEADERS([valgrind/valgrind.h])
1312 AC_CHECK_HEADERS([fenv.h])
1313 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1314   AC_CHECK_HEADERS(pthread.h,
1315                    AC_SUBST(HAVE_PTHREAD, 1),
1316                    AC_SUBST(HAVE_PTHREAD, 0))
1317 else
1318   AC_SUBST(HAVE_PTHREAD, 0)
1319 fi
1320
1321 dnl Try to find ffi.h.
1322 if test "$llvm_cv_enable_libffi" = "yes" ; then
1323   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1324 fi
1325
1326 dnl Try to find Darwin specific crash reporting libraries.
1327 AC_CHECK_HEADERS([CrashReporterClient.h])
1328
1329 dnl Try to find Darwin specific crash reporting global.
1330 AC_MSG_CHECKING([__crashreporter_info__])
1331 AC_LINK_IFELSE(
1332   AC_LANG_SOURCE(
1333     [[extern const char *__crashreporter_info__;
1334       int main() {
1335         __crashreporter_info__ = "test";
1336         return 0;
1337       }
1338     ]]),
1339   AC_MSG_RESULT(yes)
1340   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1341   AC_MSG_RESULT(no)
1342   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1343             Define if __crashreporter_info__ exists.))
1344
1345 dnl===-----------------------------------------------------------------------===
1346 dnl===
1347 dnl=== SECTION 7: Check for types and structures
1348 dnl===
1349 dnl===-----------------------------------------------------------------------===
1350
1351 AC_HUGE_VAL_CHECK
1352 AC_TYPE_PID_T
1353 AC_TYPE_SIZE_T
1354 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1355 AC_STRUCT_TM
1356 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1357 AC_CHECK_TYPES([uint64_t],,
1358          AC_CHECK_TYPES([u_int64_t],,
1359          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1360
1361 dnl===-----------------------------------------------------------------------===
1362 dnl===
1363 dnl=== SECTION 8: Check for specific functions needed
1364 dnl===
1365 dnl===-----------------------------------------------------------------------===
1366
1367 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1368 AC_CHECK_FUNCS([powf fmodf strtof round ])
1369 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1370 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1371 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit strdup ])
1372 AC_CHECK_FUNCS([strerror strerror_r setenv arc4random ])
1373 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1374 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1375 AC_C_PRINTF_A
1376 AC_FUNC_RAND48
1377
1378 dnl Check the declaration "Secure API" on Windows environments.
1379 AC_CHECK_DECLS([strerror_s])
1380
1381 dnl Check symbols in libgcc.a for JIT on Mingw.
1382 if test "$llvm_cv_os_type" = "MingW" ; then
1383   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1384   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1385   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1386   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1387
1388   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1389   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1390   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1391   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1392   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1393   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1394   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1395   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1396   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1397   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1398
1399   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1400   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1401 fi
1402
1403 dnl Check Win32 API EnumerateLoadedModules.
1404 if test "$llvm_cv_os_type" = "MingW" ; then
1405   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1406   AC_COMPILE_IFELSE([[#include <windows.h>
1407 #include <imagehlp.h>
1408 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1409 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1410 [
1411   AC_MSG_RESULT([yes])
1412   llvm_cv_win32_elmcb_pcstr="PCSTR"
1413 ],
1414 [
1415   AC_MSG_RESULT([no])
1416   llvm_cv_win32_elmcb_pcstr="PSTR"
1417 ])
1418   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1419 fi
1420
1421 dnl Check for variations in the Standard C++ library and STL. These macros are
1422 dnl provided by LLVM in the autoconf/m4 directory.
1423 AC_FUNC_ISNAN
1424 AC_FUNC_ISINF
1425
1426 dnl Check for mmap support.We also need to know if /dev/zero is required to
1427 dnl be opened for allocating RWX memory.
1428 dnl Make sure we aren't attempting to configure for an unknown system
1429 if test "$llvm_cv_platform_type" = "Unix" ; then
1430   AC_FUNC_MMAP
1431   AC_FUNC_MMAP_FILE
1432   AC_NEED_DEV_ZERO_FOR_MMAP
1433
1434   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1435   then
1436     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1437   fi
1438   if test "$ac_cv_func_mmap_file" = "no"
1439   then
1440     AC_MSG_WARN([mmap() of files required but not found])
1441   fi
1442 fi
1443
1444 dnl atomic builtins are required for threading support.
1445 AC_MSG_CHECKING(for GCC atomic builtins)
1446 dnl Since we'll be using these atomic builtins in C++ files we should test
1447 dnl the C++ compiler.
1448 AC_LANG_PUSH([C++])
1449 AC_LINK_IFELSE(
1450   AC_LANG_SOURCE(
1451     [[int main() {
1452         volatile unsigned long val = 1;
1453         __sync_synchronize();
1454         __sync_val_compare_and_swap(&val, 1, 0);
1455         __sync_add_and_fetch(&val, 1);
1456         __sync_sub_and_fetch(&val, 1);
1457         return 0;
1458       }
1459     ]]),
1460   AC_LANG_POP([C++])
1461   AC_MSG_RESULT(yes)
1462   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1463   AC_MSG_RESULT(no)
1464   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1465   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1466
1467 dnl===-----------------------------------------------------------------------===
1468 dnl===
1469 dnl=== SECTION 9: Additional checks, variables, etc.
1470 dnl===
1471 dnl===-----------------------------------------------------------------------===
1472
1473 dnl Handle 32-bit linux systems running a 64-bit kernel.
1474 dnl This has to come after section 4 because it invokes the compiler.
1475 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1476   AC_IS_LINUX_MIXED
1477   if test "$llvm_cv_linux_mixed" = "yes"; then
1478     llvm_cv_target_arch="x86"
1479     ARCH="x86"
1480   fi
1481 fi
1482
1483 dnl Check whether __dso_handle is present
1484 AC_CHECK_FUNCS([__dso_handle])
1485
1486 dnl Propagate the shared library extension that the libltdl checks did to
1487 dnl the Makefiles so we can use it there too
1488 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1489
1490 dnl Propagate the run-time library path variable that the libltdl
1491 dnl checks found to the Makefiles so we can use it there too
1492 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1493
1494 dnl Translate the various configuration directories and other basic
1495 dnl information into substitutions that will end up in Makefile.config.in
1496 dnl that these configured values can be used by the makefiles
1497 if test "${prefix}" = "NONE" ; then
1498   prefix="/usr/local"
1499 fi
1500 eval LLVM_PREFIX="${prefix}";
1501 eval LLVM_BINDIR="${prefix}/bin";
1502 eval LLVM_LIBDIR="${prefix}/lib";
1503 eval LLVM_DATADIR="${prefix}/share/llvm";
1504 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1505 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1506 eval LLVM_INCLUDEDIR="${prefix}/include";
1507 eval LLVM_INFODIR="${prefix}/info";
1508 eval LLVM_MANDIR="${prefix}/man";
1509 LLVM_CONFIGTIME=`date`
1510 AC_SUBST(LLVM_PREFIX)
1511 AC_SUBST(LLVM_BINDIR)
1512 AC_SUBST(LLVM_LIBDIR)
1513 AC_SUBST(LLVM_DATADIR)
1514 AC_SUBST(LLVM_DOCSDIR)
1515 AC_SUBST(LLVM_ETCDIR)
1516 AC_SUBST(LLVM_INCLUDEDIR)
1517 AC_SUBST(LLVM_INFODIR)
1518 AC_SUBST(LLVM_MANDIR)
1519 AC_SUBST(LLVM_CONFIGTIME)
1520
1521 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1522 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1523   LLVM_CONFIGTIME="(timestamp not enabled)"
1524 fi
1525
1526 dnl Place the various directories into the config.h file as #defines so that we
1527 dnl can know about the installation paths within LLVM.
1528 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1529                    [Installation prefix directory])
1530 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1531                    [Installation directory for binary executables])
1532 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1533                    [Installation directory for libraries])
1534 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1535                    [Installation directory for data files])
1536 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1537                    [Installation directory for documentation])
1538 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1539                    [Installation directory for config files])
1540 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1541                    [Installation directory for include files])
1542 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1543                    [Installation directory for .info files])
1544 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1545                    [Installation directory for man pages])
1546 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1547                    [Time at which LLVM was configured])
1548 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1549                    [Target triple LLVM will generate code for by default])
1550
1551 dnl Determine which bindings to build.
1552 if test "$BINDINGS_TO_BUILD" = auto ; then
1553   BINDINGS_TO_BUILD=""
1554   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1555     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1556   fi
1557 fi
1558 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1559
1560 dnl This isn't really configurey, but it avoids having to repeat the list in
1561 dnl other files.
1562 AC_SUBST(ALL_BINDINGS,ocaml)
1563
1564 dnl Do any work necessary to ensure that bindings have what they need.
1565 binding_prereqs_failed=0
1566 for a_binding in $BINDINGS_TO_BUILD ; do
1567   case "$a_binding" in
1568   ocaml)
1569     if test "x$OCAMLC" = x ; then
1570       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1571       binding_prereqs_failed=1
1572     fi
1573     if test "x$OCAMLDEP" = x ; then
1574       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1575       binding_prereqs_failed=1
1576     fi
1577     if test "x$OCAMLOPT" = x ; then
1578       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1579       dnl ocamlopt is optional!
1580     fi
1581     if test "x$with_ocaml_libdir" != xauto ; then
1582       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1583     else
1584       ocaml_stdlib="`"$OCAMLC" -where`"
1585       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1586       then
1587         # ocaml stdlib is beneath our prefix; use stdlib
1588         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1589       else
1590         # ocaml stdlib is outside our prefix; use libdir/ocaml
1591         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1592       fi
1593     fi
1594     ;;
1595   esac
1596 done
1597 if test "$binding_prereqs_failed" = 1 ; then
1598   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1599 fi
1600
1601 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1602 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1603
1604 dnl Determine linker rpath flag
1605 if test "$llvm_cv_link_use_r" = "yes" ; then
1606   RPATH="-Wl,-R"
1607 else
1608   RPATH="-Wl,-rpath"
1609 fi
1610 AC_SUBST(RPATH)
1611
1612 dnl Determine linker rdynamic flag
1613 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1614   RDYNAMIC="-Wl,-export-dynamic"
1615 else
1616   RDYNAMIC=""
1617 fi
1618 AC_SUBST(RDYNAMIC)
1619
1620 dnl===-----------------------------------------------------------------------===
1621 dnl===
1622 dnl=== SECTION 10: Specify the output files and generate it
1623 dnl===
1624 dnl===-----------------------------------------------------------------------===
1625
1626 dnl Configure header files
1627 dnl WARNING: dnl If you add or remove any of the following config headers, then
1628 dnl you MUST also update Makefile so that the variable FilesToConfig
1629 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1630 dnl files can be updated automatically when their *.in sources change.
1631 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1632 AH_TOP([#ifndef CONFIG_H
1633 #define CONFIG_H])
1634 AH_BOTTOM([#endif])
1635
1636 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1637 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1638 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1639 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1640 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1641
1642 dnl Configure the makefile's configuration data
1643 AC_CONFIG_FILES([Makefile.config])
1644
1645 dnl Configure the RPM spec file for LLVM
1646 AC_CONFIG_FILES([llvm.spec])
1647
1648 dnl Configure doxygen's configuration file
1649 AC_CONFIG_FILES([docs/doxygen.cfg])
1650
1651 dnl Configure clang, if present
1652 if test "${clang_src_root}" = ""; then
1653   clang_src_root="$srcdir/tools/clang"
1654 fi
1655 if test -f ${clang_src_root}/README.txt; then
1656   dnl Use variables to stay under 80 columns.
1657   configh="include/clang/Config/config.h"
1658   doxy="docs/doxygen.cfg"
1659   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
1660   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
1661 fi
1662
1663 dnl OCaml findlib META file
1664 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1665
1666 dnl Do special configuration of Makefiles
1667 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1668 AC_CONFIG_MAKEFILE(Makefile)
1669 AC_CONFIG_MAKEFILE(Makefile.common)
1670 AC_CONFIG_MAKEFILE(examples/Makefile)
1671 AC_CONFIG_MAKEFILE(lib/Makefile)
1672 AC_CONFIG_MAKEFILE(runtime/Makefile)
1673 AC_CONFIG_MAKEFILE(test/Makefile)
1674 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1675 AC_CONFIG_MAKEFILE(unittests/Makefile)
1676 AC_CONFIG_MAKEFILE(tools/Makefile)
1677 AC_CONFIG_MAKEFILE(utils/Makefile)
1678 AC_CONFIG_MAKEFILE(projects/Makefile)
1679 AC_CONFIG_MAKEFILE(bindings/Makefile)
1680 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1681
1682 dnl Finally, crank out the output
1683 AC_OUTPUT